qcsrc/client/mapvoting.qc

   1 float mv_num_maps;
   2
   3 float mv_active;
   4 string mv_maps[MAPVOTE_COUNT];
   5 string mv_pics[MAPVOTE_COUNT];
   6 string mv_pk3[MAPVOTE_COUNT];
   7 float mv_preview[MAPVOTE_COUNT];
   8 float mv_votes[MAPVOTE_COUNT];
   9 entity mv_pk3list;
  10 float mv_abstain;
  11 float mv_ownvote;
  12 float mv_detail;
  13 float mv_timeout;
  14 float mv_maps_mask;
  15 float mv_top2_time;
  16 float mv_top2_alpha;
  17
  18 vector mv_mousepos;
  19 float mv_selection;
  20
  21 string MapVote_FormatMapItem(float id, string map, float count, float maxwidth, vector fontsize)
  22 {
  23         string pre, post;
  24         pre = sprintf("%d. ", id+1);
  25         if(mv_detail)
  26         {
  27                 if(count == 1)
  28                         post = _(" (1 vote)");
  29                 else if(count >= 0)
  30                         post = sprintf(_(" (%d votes)"), count);
  31         }
  32         else
  33                 post = "";
  34         maxwidth -= stringwidth(pre, FALSE, fontsize) + stringwidth(post, FALSE, fontsize);
  35         map = textShortenToWidth(map, maxwidth, fontsize, stringwidth_nocolors);
  36         return strcat(pre, map, post);
  37 }
  38
  39 vector MapVote_RGB(float id, float count)
  40 {
  41         if(count < 0)
  42                 return '1 1 1';
  43         if(id == mv_ownvote)
  44                 return '0 1 0';
  45         else if (id == mv_selection)
  46                 return '1 1 0';
  47         else
  48                 return '1 1 1';
  49 }
  50
  51 void MapVote_DrawMapItem(vector pos, float isize, float tsize, string map, string pic, float count, float id)
  52 {
  53         vector img_size;
  54         vector rgb;
  55         string label;
  56         float text_size;
  57
  58         isize -= hud_fontsize_y; // respect the text when calculating the image size
  59
  60         rgb = MapVote_RGB(id, count);
  61
  62         img_size_y = isize;
  63         img_size_x = isize / 0.75; // 4:3 x can be stretched easily, height is defined in isize
  64
  65         pos_y = pos_y + img_size_y;
  66
  67         label = MapVote_FormatMapItem(id, map, count, tsize, hud_fontsize);
  68
  69         text_size = stringwidth(label, false, hud_fontsize);
  70
  71         float theAlpha;
  72         if (count < 0 && mv_top2_alpha)
  73                 theAlpha = mv_top2_alpha;
  74         else
  75                 theAlpha = 1;
  76
  77         pos_x -= text_size*0.5;
  78         drawstring(pos, label, hud_fontsize, rgb, theAlpha, DRAWFLAG_NORMAL);
  79
  80         pos_x = pos_x + text_size*0.5 - img_size_x*0.5;
  81         pos_y = pos_y - img_size_y;
  82
  83         pos += autocvar_scoreboard_border_thickness * '1 1 0';
  84         img_size -= (autocvar_scoreboard_border_thickness * 2) * '1 1 0';
  85         if(pic == "")
  86         {
  87                 drawfill(pos, img_size, '.5 .5 .5', .7 * theAlpha, DRAWFLAG_NORMAL);
  88         }
  89         else
  90         {
  91                 if(drawgetimagesize(pic) == '0 0 0')
  92                         drawpic(pos, draw_UseSkinFor("nopreview_map"), img_size, '1 1 1', theAlpha, DRAWFLAG_NORMAL);
  93                 else
  94                         drawpic(pos, pic, img_size, '1 1 1', theAlpha, DRAWFLAG_NORMAL);
  95         }
  96
  97         if(id == mv_ownvote)
  98                 drawborderlines(autocvar_scoreboard_border_thickness, pos, img_size, rgb, theAlpha, DRAWFLAG_NORMAL);
  99         else
 100                 drawborderlines(autocvar_scoreboard_border_thickness, pos, img_size, '0 0 0', theAlpha, DRAWFLAG_NORMAL);
 101
 102         if(id == mv_selection && count >= 0)
 103                 drawfill(pos, img_size, '1 1 1', 0.1, DRAWFLAG_NORMAL);
 104 }
 105
 106 void MapVote_DrawAbstain(vector pos, float isize, float tsize, float count, float id)
 107 {
 108         vector rgb;
 109         float text_size;
 110         string label;
 111
 112         rgb = MapVote_RGB(id, count);
 113
 114         pos_y = pos_y + hud_fontsize_y;
 115
 116         label = MapVote_FormatMapItem(id, _("Don't care"), count, tsize, hud_fontsize);
 117
 118         text_size = stringwidth(label, false, hud_fontsize);
 119
 120         pos_x -= text_size*0.5;
 121         drawstring(pos, label, hud_fontsize, rgb, 1, DRAWFLAG_NORMAL);
 122 }
 123
 124 vector MapVote_GridVec(vector gridspec, float i, float m)
 125 {
 126         float r;
 127         r = mod(i, m);
 128         return
 129                 '1 0 0' * (gridspec_x * r)
 130                 +
 131                 '0 1 0' * (gridspec_y * (i - r) / m);
 132 }
 133
 134 float MapVote_Selection(vector topleft, vector cellsize, float rows, float columns)
 135 {
 136         float cell;
 137         float c, r;
 138
 139         cell = -1;
 140
 141         for (r = 0; r < rows; ++r)
 142                 for (c = 0; c < columns; ++c)
 143                 {
 144                         if (mv_mousepos_x >= topleft_x + cellsize_x *  c &&
 145                                 mv_mousepos_x <= topleft_x + cellsize_x * (c + 1) &&
 146                                 mv_mousepos_y >= topleft_y + cellsize_y *  r &&
 147                                 mv_mousepos_y <= topleft_y + cellsize_y * (r + 1))
 148                         {
 149                                 cell = r * columns + c;
 150                                 break;
 151                         }
 152                 }
 153
 154         if (cell >= mv_num_maps)
 155                 cell = -1;
 156
 157         if (mv_abstain && cell < 0)
 158                 return mv_num_maps;
 159
 160         return cell;
 161 }
 162
 163 void MapVote_Draw()
 164 {
 165         string map;
 166         float i, tmp;
 167         vector pos;
 168         float isize;
 169         float center;
 170         float columns, rows;
 171         float tsize;
 172         vector dist;
 173
 174         if(!mv_active)
 175                 return;
 176
 177         mv_mousepos = mv_mousepos + getmousepos();
 178
 179         mv_mousepos_x = bound(0, mv_mousepos_x, vid_conwidth);
 180         mv_mousepos_y = bound(0, mv_mousepos_y, vid_conheight);
 181
 182         center = (vid_conwidth - 1)/2;
 183         xmin = vid_conwidth*0.05; // 5% border must suffice
 184         xmax = vid_conwidth - xmin;
 185         ymin = 20;
 186         i = autocvar_con_chatpos; //*autocvar_con_chatsize;
 187         if(i < 0)
 188                 ymax = vid_conheight + (i - autocvar_con_chat) * autocvar_con_chatsize;
 189         if(i >= 0 || ymax < (vid_conheight*0.5))
 190                 ymax = vid_conheight - ymin;
 191
 192         hud_fontsize = HUD_GetFontsize("hud_fontsize");
 193
 194         pos_y = ymin;
 195         pos_z = 0;
 196
 197         draw_beginBoldFont();
 198         map = _("Vote for a map");
 199         pos_x = center - stringwidth(map, false, '12 0 0');
 200         drawstring(pos, map, '24 24 0', '1 1 1', 1, DRAWFLAG_NORMAL);
 201         pos_y += 26;
 202
 203         i = ceil(max(0, mv_timeout - time));
 204         map = sprintf(_("%d seconds left"), i);
 205         pos_x = center - stringwidth(map, false, '8 0 0');
 206         drawstring(pos, map, '16 16 0', '0 1 0', 1, DRAWFLAG_NORMAL);
 207         pos_y += 22;
 208         pos_x = xmin;
 209         draw_endBoldFont();
 210
 211         // base for multi-column stuff...
 212         ymin = pos_y;
 213         if(mv_abstain)
 214                 mv_num_maps -= 1;
 215
 216         if(mv_num_maps > 3)
 217         {
 218                 columns = 3;
 219         } else {
 220                 columns = mv_num_maps;
 221         }
 222         rows = ceil(mv_num_maps / columns);
 223
 224         dist_x = (xmax - xmin) / columns;
 225         dist_y = (ymax - pos_y) / rows;
 226         tsize = dist_x - 10;
 227         isize = min(dist_y - 10, 0.75 * tsize);
 228
 229         mv_selection = MapVote_Selection(pos, dist, rows, columns);
 230
 231         pos_x += (xmax - xmin) / (2 * columns);
 232         pos_y += (dist_y - isize) / 2;
 233         ymax -= isize;
 234
 235         if (mv_top2_time)
 236                 mv_top2_alpha = max(0.2, 1 - (time - mv_top2_time)*(time - mv_top2_time));
 237
 238         for(i = 0; i < mv_num_maps; ++i)
 239         {
 240                 tmp = mv_votes[i]; // FTEQCC bug: too many array accesses in the function call screw it up
 241                 map = mv_maps[i];
 242                 if(mv_preview[i])
 243                         MapVote_DrawMapItem(pos + MapVote_GridVec(dist, i, columns), isize, tsize, map, mv_pics[i], tmp, i);
 244                 else
 245                         MapVote_DrawMapItem(pos + MapVote_GridVec(dist, i, columns), isize, tsize, map, "", tmp, i);
 246         }
 247
 248         if(mv_abstain)
 249                 ++mv_num_maps;
 250
 251         if(mv_abstain && i < mv_num_maps) {
 252                 tmp = mv_votes[i];
 253                 pos_y = ymax + isize - hud_fontsize_y;
 254                 pos_x = (xmax+xmin)*0.5;
 255                 MapVote_DrawAbstain(pos, isize, xmax - xmin, tmp, i);
 256         }
 257
 258         drawpic(mv_mousepos, strcat("gfx/menu/", autocvar_menu_skin, "/cursor.tga"), '32 32 0', '1 1 1', autocvar_hud_panel_fg_alpha, DRAWFLAG_NORMAL);
 259 }
 260
 261 void Cmd_MapVote_MapDownload(float argc)
 262 {
 263         float id;
 264         entity pak;
 265
 266         if(argc != 2 || !mv_pk3list)
 267         {
 268                 print(_("mv_mapdownload: ^3You're not supposed to use this command on your own!\n"));
 269                 return;
 270         }
 271
 272         id = stof(argv(1));
 273         for(pak = mv_pk3list; pak; pak = pak.chain)
 274                 if(pak.sv_entnum == id)
 275                         break;
 276
 277         if(!pak || pak.sv_entnum != id) {
 278                 print(_("^1Error:^7 Couldn't find pak index.\n"));
 279                 return;
 280         }
 281
 282         if(PreviewExists(pak.message))
 283         {
 284                 mv_preview[id] = true;
 285                 return;
 286         } else {
 287                 print(_("Requesting preview...\n"));
 288                 localcmd(strcat("\ncmd mv_getpicture ", ftos(id), "\n"));
 289         }
 290 }
 291
 292 void MapVote_CheckPK3(string pic, string pk3, float id)
 293 {
 294         entity pak;
 295         pak = spawn();
 296         pak.netname = pk3;
 297         pak.message = pic;
 298         pak.sv_entnum = id;
 299
 300         pak.chain = mv_pk3list;
 301         mv_pk3list = pak;
 302
 303         if(pk3 != "")
 304         {
 305                 localcmd(strcat("\ncurl --pak ", pk3, "; wait; cl_cmd mv_download ", ftos(id), "\n"));
 306         }
 307         else
 308         {
 309                 Cmd_MapVote_MapDownload(tokenize_console(strcat("mv_download ", ftos(id))));
 310         }
 311 }
 312
 313 void MapVote_CheckPic(string pic, string pk3, float id)
 314 {
 315         // never try to retrieve a pic for the "don't care" 'map'
 316         if(mv_abstain && id == mv_num_maps - 1)
 317                 return;
 318
 319         if(PreviewExists(pic))
 320         {
 321                 mv_preview[id] = true;
 322                 return;
 323         }
 324         MapVote_CheckPK3(pic, pk3, id);
 325 }
 326
 327 #define NUM_SSDIRS 4
 328 string ssdirs[NUM_SSDIRS];
 329 float n_ssdirs;
 330 void MapVote_Init()
 331 {
 332         float i, j, power;
 333         string map, pk3, s;
 334
 335         precache_sound ("misc/invshot.wav");
 336
 337         mv_active = 1;
 338
 339         mv_mousepos = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 340         mv_selection = -1;
 341
 342         for(n_ssdirs = 0; ; ++n_ssdirs)
 343         {
 344                 s = ReadString();
 345                 if(s == "")
 346                         break;
 347                 if(n_ssdirs < NUM_SSDIRS)
 348                         ssdirs[n_ssdirs] = s;
 349         }
 350         n_ssdirs = min(n_ssdirs, NUM_SSDIRS);
 351
 352         mv_num_maps = min(MAPVOTE_COUNT, ReadByte());
 353         mv_abstain = ReadByte();
 354         if(mv_abstain)
 355                 mv_abstain = 1; // must be 1 for bool-true, makes stuff easier
 356         mv_detail = ReadByte();
 357
 358         mv_ownvote = -1;
 359         mv_timeout = ReadCoord();
 360
 361         if(mv_num_maps <= 8)
 362                 mv_maps_mask = ReadByte();
 363         else
 364                 mv_maps_mask = ReadShort();
 365
 366         // Assume mv_pk3list is world, there should only be 1 mapvote per round
 367         mv_pk3list = world; // I'm still paranoid!
 368
 369         for(i = 0, power = 1; i < mv_num_maps; ++i, power *= 2)
 370         {
 371                 mv_votes[i] = 0;
 372
 373                 if(mv_maps_mask & power)
 374                 {
 375                         map = strzone(ReadString());
 376                         pk3 = strzone(ReadString());
 377                         j = bound(0, ReadByte(), n_ssdirs - 1);
 378
 379                         mv_maps[i] = map;
 380                         mv_pk3[i] = pk3;
 381                         map = strzone(strcat(ssdirs[j], "/", map));
 382                         mv_pics[i] = map;
 383
 384                         mv_preview[i] = false;
 385
 386                         MapVote_CheckPic(map, pk3, i);
 387                 }
 388                 else
 389                 {
 390                         mv_maps[i] = strzone("if-you-see-this-the-code-is-broken");
 391                         mv_pk3[i] = strzone("if-you-see-this-the-code-is-broken");
 392                         mv_pics[i] = strzone("if-you-see-this-the-code-is-broken");
 393                         mv_preview[i] = false;
 394                 }
 395         }
 396
 397         for(i = 0; i < n_ssdirs; ++i)
 398                 ssdirs[n_ssdirs] = string_null;
 399         n_ssdirs = 0;
 400 }
 401
 402 float MapVote_InputEvent(float bInputType, float nPrimary, float nSecondary)
 403 {
 404         float imp;
 405
 406         if (!mv_active)
 407                 return false;
 408
 409         if (bInputType != 0)
 410                 return false;
 411
 412         if ('0' <= nPrimary && nPrimary <= '9')
 413         {
 414                 imp = nPrimary - '0';
 415                 if (imp == 0) imp = 10;
 416                 localcmd(strcat("\nimpulse ", ftos(imp), "\n"));
 417                 return true;
 418         }
 419         switch(nPrimary)
 420         {
 421                 case K_KP_1: localcmd("\nimpulse 1\n"); return true;
 422                 case K_KP_2: localcmd("\nimpulse 2\n"); return true;
 423                 case K_KP_3: localcmd("\nimpulse 3\n"); return true;
 424                 case K_KP_4: localcmd("\nimpulse 4\n"); return true;
 425                 case K_KP_5: localcmd("\nimpulse 5\n"); return true;
 426                 case K_KP_6: localcmd("\nimpulse 6\n"); return true;
 427                 case K_KP_7: localcmd("\nimpulse 7\n"); return true;
 428                 case K_KP_8: localcmd("\nimpulse 8\n"); return true;
 429                 case K_KP_9: localcmd("\nimpulse 9\n"); return true;
 430                 case K_KP_0: localcmd("\nimpulse 10\n"); return true;
 431         }
 432
 433         if (nPrimary == K_MOUSE1)
 434                 if (mv_selection >= 0)
 435                 {
 436                         imp = min(mv_selection + 1, mv_num_maps);
 437                         localcmd(strcat("\nimpulse ", ftos(imp), "\n"));
 438                         return true;
 439                 }
 440
 441         return false;
 442 }
 443
 444 void MapVote_UpdateMask()
 445 {
 446         float i, power;
 447         float oldmask;
 448
 449         oldmask = mv_maps_mask;
 450         if(mv_num_maps <= 8)
 451                 mv_maps_mask = ReadByte();
 452         else
 453                 mv_maps_mask = ReadShort();
 454
 455         if(oldmask & mv_maps_mask != oldmask)
 456                 if(oldmask & mv_maps_mask == mv_maps_mask)
 457                          sound(world, CH_INFO, "misc_invshot.wav", VOL_BASE, ATTN_NONE);
 458
 459         // remove votes that no longer apply
 460         for(i = 0, power = 1; i < mv_num_maps; ++i, power *= 2)
 461                 if not(mv_maps_mask & power)
 462                         mv_votes[i] = -1;
 463
 464         mv_top2_time = time;
 465 }
 466
 467 void MapVote_UpdateVotes()
 468 {
 469         float i, power;
 470         for(i = 0, power = 1; i < mv_num_maps; ++i, power *= 2)
 471         {
 472                 if(mv_maps_mask & power)
 473                 {
 474                         if(mv_detail)
 475                                 mv_votes[i] = ReadByte();
 476                         else
 477                                 mv_votes[i] = 0;
 478                 }
 479                 else
 480                         mv_votes[i] = -1;
 481         }
 482
 483         mv_ownvote = ReadByte()-1;
 484 }
 485
 486 void Ent_MapVote()
 487 {
 488         float sf;
 489
 490         sf = ReadByte();
 491
 492         if(sf & 1)
 493                 MapVote_Init();
 494
 495         if(sf & 2)
 496                 MapVote_UpdateMask();
 497
 498         if(sf & 4)
 499                 MapVote_UpdateVotes();
 500 }
 501
 502 void Net_MapVote_Picture()
 503 {
 504         float type;
 505         type = ReadByte();
 506         mv_preview[type] = true;
 507         mv_pics[type] = strzone(ReadPicture());
 508 }