qcsrc/client/player_skeleton.qc

   1 #include "player_skeleton.qh"
   2
   3 #include "mutators/events.qh"
   4 #include "../lib/csqcmodel/cl_player.qh"
   5 #include "../lib/warpzone/anglestransform.qh"
   6
   7 .float v_angle_x;
   8 .float v_angle_save_x;
   9
  10 class(Skeleton) .float skeleton_info_modelindex;
  11 class(Skeleton) .float skeleton_info_skin;
  12 const int BONETYPE_LOWER = 0;
  13 const int BONETYPE_UPPER = 1;
  14 const int MAX_BONES = 128;
  15 class(Skeleton) .float skeleton_bonetype[MAX_BONES];
  16 class(Skeleton) .float skeleton_numbones;
  17
  18 void skeleton_loadinfo(entity e)
  19 {
  20         int i;
  21         if(e.skeleton_info_modelindex == e.modelindex && e.skeleton_info_skin == e.skin)
  22                 return;
  23         e.bone_upperbody = 0;
  24         e.bone_weapon = gettagindex(e, "weapon");
  25         if(!e.bone_weapon)
  26                 e.bone_weapon = gettagindex(e, "tag_weapon");
  27         if(!e.bone_weapon)
  28                 e.bone_weapon = gettagindex(e, "bip01 r hand");
  29         MUTATOR_CALLHOOK(Skeleton_CheckBones, e);
  30         for(i = 0; i < MAX_AIM_BONES; ++i)
  31         {
  32                 e.(bone_aim[i]) = 0;
  33                 e.(bone_aimweight[i]) = 0;
  34         }
  35         e.fixbone = 0;
  36         if(get_model_parameters(e.model, e.skin))
  37         {
  38                 if(get_model_parameters_bone_upperbody)
  39                         e.bone_upperbody = gettagindex(e, get_model_parameters_bone_upperbody);
  40                 if(e.bone_upperbody)
  41                         e.fixbone = get_model_parameters_fixbone;
  42                 if(get_model_parameters_bone_weapon)
  43                         e.bone_weapon = gettagindex(e, get_model_parameters_bone_weapon);
  44                 MUTATOR_CALLHOOK(Skeleton_CheckModel, e);
  45                 for(i = 0; i < MAX_AIM_BONES; ++i)
  46                 {
  47                         if(get_model_parameters_bone_aim[i])
  48                                 e.(bone_aim[i]) = gettagindex(e, get_model_parameters_bone_aim[i]);
  49                         if(e.bone_aim[i])
  50                                 e.(bone_aimweight[i]) = get_model_parameters_bone_aimweight[i];
  51                 }
  52         }
  53         else
  54                 LOG_TRACE("No model parameters for ", e.model);
  55         //dprint(e.model, " uses ", ftos(e.bone_upperbody), " ", ftos(e.fixbone), "\n");
  56         get_model_parameters(string_null, 0);
  57         e.skeleton_info_modelindex = e.modelindex;
  58         e.skeleton_info_skin = e.skin;
  59         if(e.skeletonindex)
  60         {
  61                 skel_delete(e.skeletonindex);
  62                 e.skeletonindex = 0;
  63         }
  64 }
  65
  66 void skeleton_markbones(entity e)
  67 {
  68         float s = e.skeletonindex;
  69         float n = (e.skeleton_numbones = skel_get_numbones(s));
  70         int i;
  71         for(i = 1; i <= n; ++i)
  72         {
  73                 float t = BONETYPE_LOWER;
  74                 int p = skel_get_boneparent(s, i);
  75                 if(p > 0)
  76                         t = e.(skeleton_bonetype[p-1]);
  77                 if(i == e.bone_upperbody)
  78                         t = BONETYPE_UPPER;
  79                 e.(skeleton_bonetype[i-1]) = t;
  80         }
  81 }
  82
  83 void skel_set_boneabs(float s, int bone, vector absorg)
  84 {
  85     TC(int, bone);
  86         vector absang = fixedvectoangles2(v_forward, v_up);
  87
  88         vector parentorg = skel_get_boneabs(s, skel_get_boneparent(s, bone));
  89         vector parentang = fixedvectoangles2(v_forward, v_up);
  90
  91         vector relang = AnglesTransform_LeftDivide(parentang, absang);
  92         vector relorg = AnglesTransform_Apply(AnglesTransform_Invert(parentang), absorg - parentorg);
  93
  94         fixedmakevectors(relang);
  95         skel_set_bone(s, bone, relorg);
  96
  97         /*
  98         vector neworg = skel_get_boneabs(s, bone);
  99         printf("ANG: want: %v, got: %v\n", absang, fixedvectoangles2(v_forward, v_up));
 100         printf("ORG: want: %v, got: %v\n", absorg, neworg);
 101         */
 102 }
 103
 104 void free_skeleton_from_frames(entity e)
 105 {
 106         if(e.skeletonindex)
 107         {
 108                 skel_delete(e.skeletonindex);
 109                 e.skeletonindex = 0;
 110         }
 111 }
 112
 113 void skeleton_from_frames(entity e, bool is_dead)
 114 {
 115     TC(bool, is_dead);
 116         float m = e.modelindex;
 117         if(!e.skeletonindex)
 118         {
 119                 e.skeletonindex = skel_create(m);
 120                 skeleton_markbones(e);
 121         }
 122         float s = e.skeletonindex;
 123         if(!s)
 124                 return;
 125         float n = e.skeleton_numbones;
 126         float savelerpfrac = e.lerpfrac;
 127         float savelerpfrac3 = e.lerpfrac3;
 128         float savelerpfrac4 = e.lerpfrac4;
 129
 130         vector fixbone_oldangles = '0 0 0';
 131         if(e.fixbone)
 132         {
 133                 // make all bones BONETYPE_UPPER
 134                 e.lerpfrac = 0;
 135                 e.lerpfrac3 = savelerpfrac3 * 2;
 136                 e.lerpfrac4 = 0;
 137                 // build skeleton
 138                 skel_build(s, e, m, 0, 1, n);
 139                 // get hip bone
 140                 skel_get_boneabs(s, e.bone_upperbody);
 141                 fixbone_oldangles = fixedvectoangles2(v_forward, v_up);
 142         }
 143         int bone;
 144         for(bone = 0; bone < n; )
 145         {
 146                 float firstbone = bone;
 147                 float bonetype = e.skeleton_bonetype[bone];
 148                 for(++bone; (bone < n) && (e.skeleton_bonetype[bone] == bonetype); ++bone)
 149                         ;
 150                 if(bonetype == BONETYPE_UPPER)
 151                 {
 152                         // only show frames 1+3 (upper body)
 153                         e.lerpfrac = 0;
 154                         e.lerpfrac3 = savelerpfrac3 * 2;
 155                         e.lerpfrac4 = 0;
 156                 }
 157                 else
 158                 {
 159                         // only show frames 2+4 (lower body)
 160                         e.lerpfrac = savelerpfrac * 2;
 161                         e.lerpfrac3 = 0;
 162                         e.lerpfrac4 = savelerpfrac4 * 2;
 163                 }
 164                 //printf("Run: bone %d to %d, type %d\n", firstbone + 1, bone, bonetype);
 165                 //printf("frame %d %d %d %d lerpfrac * %d %d %d\n", e.frame, e.frame2, e.frame3, e.frame4, e.lerpfrac, e.lerpfrac3, e.lerpfrac4);
 166                 skel_build(s, e, m, 0, firstbone + 1, bone);
 167         }
 168         e.lerpfrac = savelerpfrac;
 169         e.lerpfrac3 = savelerpfrac3;
 170         e.lerpfrac4 = savelerpfrac4;
 171
 172         if(e.fixbone)
 173         {
 174                 // FIX IT
 175                 vector org = skel_get_boneabs(s, e.bone_upperbody);
 176                 fixedmakevectors(fixbone_oldangles);
 177                 skel_set_boneabs(s, e.bone_upperbody, org);
 178         }
 179
 180         if(!is_dead)
 181         {
 182                 if(e == csqcplayer)
 183                 {
 184                         if(intermission)
 185                         {
 186                                 if(!e.v_angle_save_x)
 187                                         e.v_angle_save_x = input_angles.x;
 188                                 e.v_angle_x = e.v_angle_save_x;
 189                         }
 190                         else
 191                                 e.v_angle_x = input_angles.x;
 192                 }
 193                 int i;
 194                 for(i = 0; i < MAX_AIM_BONES; ++i)
 195                 {
 196                         if(e.(bone_aim[i]))
 197                         {
 198                                 vector aim = '1 0 0' * bound(-90, e.v_angle_x, 90) * e.(bone_aimweight[i]);
 199                                 vector org = skel_get_boneabs(s, e.(bone_aim[i]));
 200                                 vector ang_cur = fixedvectoangles2(v_forward, v_up);
 201                                 vector ang = AnglesTransform_Multiply(aim, ang_cur);
 202                                 fixedmakevectors(ang);
 203                                 skel_set_boneabs(s, e.(bone_aim[i]), org);
 204                         }
 205                 }
 206         }
 207 }