qcsrc/client/quickmenu.qc

   1 // QUICKMENU_MAXLINES must be <= 10
   2 const int QUICKMENU_MAXLINES = 10;
   3 // visible etries are loaded from QuickMenu_Buffer into QuickMenu_Page_* arrays
   4 string QuickMenu_Page_Command[QUICKMENU_MAXLINES];
   5 string QuickMenu_Page_Description[QUICKMENU_MAXLINES];
   6 int QuickMenu_Page_Entries;
   7 int QuickMenu_Page;
   8 int QuickMenu_Page_ActivatedEntry = -1;
   9 bool QuickMenu_Page_ActivatedEntry_Close;
  10 float QuickMenu_Page_ActivatedEntry_Time;
  11 bool QuickMenu_IsLastPage;
  12 // all the entries are loaded into QuickMenu_Buffer
  13 // each entry (submenu or command) is composed of 2 entries
  14 const int QUICKMENU_MAXENTRIES = 256;
  15 const int QUICKMENU_BUFFER_MAXENTRIES = 2 * QUICKMENU_MAXENTRIES;
  16 int QuickMenu_Buffer = -1;
  17 int QuickMenu_Buffer_Size;
  18 int QuickMenu_Buffer_Index;
  19 string QuickMenu_CurrentSubMenu;
  20 float QuickMenu_TimeOut;
  21 // if s1 is not empty s will be displayed as command otherwise as submenu
  22 void QuickMenu_Page_LoadEntry(int i, string s, string s1)
  23 {
  24         //printf("^xc80 entry %d: %s, %s\n", i, s, s1);
  25         if (QuickMenu_Page_Description[i])
  26                 strunzone(QuickMenu_Page_Description[i]);
  27         QuickMenu_Page_Description[i] = strzone(s);
  28         if (QuickMenu_Page_Command[i])
  29                 strunzone(QuickMenu_Page_Command[i]);
  30         QuickMenu_Page_Command[i] = strzone(s1);
  31 }
  32 void QuickMenu_Page_ClearEntry(int i)
  33 {
  34         if (QuickMenu_Page_Description[i])
  35                 strunzone(QuickMenu_Page_Description[i]);
  36         QuickMenu_Page_Description[i] = string_null;
  37         if (QuickMenu_Page_Command[i])
  38                 strunzone(QuickMenu_Page_Command[i]);
  39         QuickMenu_Page_Command[i] = string_null;
  40 }
  41
  42 float QuickMenu_Page_Load(string target_submenu, float new_page);
  43 void QuickMenu_Default(string submenu);
  44 bool QuickMenu_Open(string mode, string submenu)
  45 {
  46         int fh = -1;
  47         string s;
  48
  49         if(mode == "")
  50         {
  51                 if(autocvar_hud_panel_quickmenu_file == "" || autocvar_hud_panel_quickmenu_file == "0")
  52                         mode = "default";
  53                 else
  54                         mode = "file";
  55         }
  56
  57         if(mode == "default")
  58         {
  59                 QuickMenu_Buffer = buf_create();
  60                 if(QuickMenu_Buffer < 0)
  61                         return false;
  62
  63                 QuickMenu_Default(submenu);
  64         }
  65         else if(mode == "file")
  66         {
  67                 if(autocvar_hud_panel_quickmenu_file != "")
  68                 if(autocvar_hud_panel_quickmenu_file != "0")
  69                         fh = fopen(autocvar_hud_panel_quickmenu_file, FILE_READ);
  70                 if(fh < 0)
  71                 {
  72                         printf("Couldn't open file \"%s\"\n", autocvar_hud_panel_quickmenu_file);
  73                         return false;
  74                 }
  75
  76                 QuickMenu_Buffer = buf_create();
  77                 if(QuickMenu_Buffer < 0)
  78                 {
  79                         fclose(fh);
  80                         return false;
  81                 }
  82
  83                 QuickMenu_Buffer_Size = 0;
  84                 while((s = fgets(fh)) && QuickMenu_Buffer_Size < QUICKMENU_BUFFER_MAXENTRIES)
  85                 {
  86                         // first skip invalid entries, so we don't check them anymore
  87                         float argc;
  88                         argc = tokenize_console(s);
  89                         if(argc == 0 || argv(0) == "" || substring(argv(0), 0, 2) == "////")
  90                                 continue;
  91                         if(argc == 1)
  92                                 bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat("S", argv(0))); // Submenu
  93                         else if(argc == 2)
  94                         {
  95                                 if(argv(1) == "")
  96                                         continue;
  97                                 bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat("T", argv(0))); // command Title
  98                                 ++QuickMenu_Buffer_Size;
  99                                 bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat("C", argv(1))); // command
 100                         }
 101                         else if(argc == 3)
 102                         {
 103                                 // check for special keywords
 104                                 float teamplayers = 0, without_me = 0;
 105                                 switch(argv(2))
 106                                 {
 107                                         case "ALLPLAYERS_BUT_ME":               without_me = 1;
 108                                         case "ALLPLAYERS":                              teamplayers = 0; break;
 109                                         case "OWNTEAMPLAYERS_BUT_ME":   without_me = 1;
 110                                         case "OWNTEAMPLAYERS":                  teamplayers = 1; break;
 111                                         case "ENEMYTEAMPLAYERS":                teamplayers = 2; break;
 112                                         default: continue;
 113                                 }
 114
 115                                 if(QuickMenu_Buffer_Size + 3 < QUICKMENU_BUFFER_MAXENTRIES)
 116                                 {
 117                                         bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat("S", argv(0))); // Submenu
 118                                         ++QuickMenu_Buffer_Size;
 119                                         bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat("T", ftos(teamplayers), ftos(without_me))); // command arguments
 120                                         ++QuickMenu_Buffer_Size;
 121                                         bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat("P", argv(1))); // command for each player
 122                                         ++QuickMenu_Buffer_Size;
 123                                         bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat("S", argv(0))); // Submenu
 124                                 }
 125                         }
 126                         ++QuickMenu_Buffer_Size;
 127                 }
 128                 fclose(fh);
 129         }
 130         else
 131         {
 132                 printf("Unrecognized mode %s\n", mode);
 133                 return false;
 134         }
 135
 136         if (QuickMenu_Buffer_Size <= 0)
 137         {
 138                 buf_del(QuickMenu_Buffer);
 139                 QuickMenu_Buffer = -1;
 140                 return false;
 141         }
 142
 143         if(mode == "file")
 144                 QuickMenu_Page_Load(submenu, 0);
 145         else
 146                 QuickMenu_Page_Load("", 0);
 147
 148         hud_panel_quickmenu = 1;
 149         if(autocvar_hud_cursormode)
 150                 setcursormode(1);
 151         hudShiftState = 0;
 152
 153         QuickMenu_TimeOut = time + autocvar_hud_panel_quickmenu_time;
 154         return true;
 155 }
 156
 157 void QuickMenu_Buffer_Close()
 158 {
 159         if (QuickMenu_Buffer >= 0)
 160         {
 161                 buf_del(QuickMenu_Buffer);
 162                 QuickMenu_Buffer = -1;
 163                 QuickMenu_Buffer_Size = 0;
 164         }
 165 }
 166
 167 void QuickMenu_Close()
 168 {
 169         if (QuickMenu_CurrentSubMenu)
 170                 strunzone(QuickMenu_CurrentSubMenu);
 171         QuickMenu_CurrentSubMenu = string_null;
 172         int i;
 173         for (i = 0; i < QUICKMENU_MAXLINES; ++i)
 174                 QuickMenu_Page_ClearEntry(i);
 175         QuickMenu_Page_Entries = 0;
 176         hud_panel_quickmenu = 0;
 177         mouseClicked = 0;
 178         prevMouseClicked = 0;
 179         QuickMenu_Buffer_Close();
 180
 181         if(autocvar_hud_cursormode)
 182         if(!mv_active)
 183                 setcursormode(0);
 184 }
 185
 186 // It assumes submenu open tag is already detected
 187 void QuickMenu_skip_submenu(string submenu)
 188 {
 189         string s, z_submenu;
 190         z_submenu = strzone(submenu);
 191         for(++QuickMenu_Buffer_Index ; QuickMenu_Buffer_Index < QuickMenu_Buffer_Size; ++QuickMenu_Buffer_Index)
 192         {
 193                 s = bufstr_get(QuickMenu_Buffer, QuickMenu_Buffer_Index);
 194                 if(substring(s, 0, 1) != "S")
 195                         continue;
 196                 if(substring(s, 1, -1) == z_submenu) // submenu end
 197                         break;
 198                 QuickMenu_skip_submenu(substring(s, 1, -1));
 199         }
 200         strunzone(z_submenu);
 201 }
 202
 203 bool QuickMenu_IsOpened()
 204 {
 205         return (QuickMenu_Page_Entries > 0);
 206 }
 207
 208 void HUD_Quickmenu_PlayerListEntries(string cmd, int teamplayers, float without_me);
 209 bool HUD_Quickmenu_PlayerListEntries_Create(string cmd, int teamplayers, float without_me)
 210 {
 211         int i;
 212         for(i = 0; i < QUICKMENU_MAXLINES; ++i)
 213                 QuickMenu_Page_ClearEntry(i);
 214         QuickMenu_Buffer_Close();
 215
 216         QuickMenu_Buffer = buf_create();
 217         if(QuickMenu_Buffer < 0)
 218                 return false;
 219
 220         HUD_Quickmenu_PlayerListEntries(cmd, teamplayers, without_me);
 221
 222         if(QuickMenu_Buffer_Size <= 0)
 223         {
 224                 buf_del(QuickMenu_Buffer);
 225                 QuickMenu_Buffer = -1;
 226                 return false;
 227         }
 228         return true;
 229 }
 230
 231 // new_page 0 means page 0, new_page != 0 means next page
 232 int QuickMenu_Buffer_Index_Prev;
 233 bool QuickMenu_Page_Load(string target_submenu, int new_page)
 234 {
 235         string s = string_null, cmd = string_null, z_submenu;
 236
 237         if (new_page == 0)
 238                 QuickMenu_Page = 0;
 239         else
 240                 ++QuickMenu_Page;
 241
 242         z_submenu = strzone(target_submenu);
 243         if (QuickMenu_CurrentSubMenu)
 244                 strunzone(QuickMenu_CurrentSubMenu);
 245         QuickMenu_CurrentSubMenu = strzone(z_submenu);
 246
 247         QuickMenu_IsLastPage = true;
 248         QuickMenu_Page_Entries = 0;
 249
 250         QuickMenu_Buffer_Index = 0;
 251         if (z_submenu != "")
 252         {
 253                 // skip everything until the submenu open tag is found
 254                 for( ; QuickMenu_Buffer_Index < QuickMenu_Buffer_Size; ++QuickMenu_Buffer_Index)
 255                 {
 256                         s = bufstr_get(QuickMenu_Buffer, QuickMenu_Buffer_Index);
 257                         if(substring(s, 0, 1) == "S" && substring(s, 1, -1) == z_submenu)
 258                         {
 259                                 // printf("^3 beginning of %s\n", z_submenu);
 260                                 ++QuickMenu_Buffer_Index;
 261                                 break; // target_submenu found!
 262                         }
 263                         // printf("^1 skipping %s\n", s);
 264                 }
 265                 if(QuickMenu_Buffer_Index == QuickMenu_Buffer_Size)
 266                         printf("Couldn't find submenu \"%s\"\n", z_submenu);
 267         }
 268
 269         // only the last page can contain up to QUICKMENU_MAXLINES entries
 270         // the other ones contain only (QUICKMENU_MAXLINES - 2) entries
 271         // so that the panel can show an empty row and "Continue..."
 272         float first_entry = QuickMenu_Page * (QUICKMENU_MAXLINES - 2);
 273         int entry_num = 0; // counts entries in target_submenu
 274         for( ; QuickMenu_Buffer_Index < QuickMenu_Buffer_Size; ++QuickMenu_Buffer_Index)
 275         {
 276                 s = bufstr_get(QuickMenu_Buffer, QuickMenu_Buffer_Index);
 277
 278                 if(z_submenu != "" && substring(s, 1, -1) == z_submenu)
 279                 {
 280                         // printf("^3 end of %s\n", z_submenu);
 281                         break;
 282                 }
 283
 284                 if(entry_num >= first_entry)
 285                 {
 286                         ++QuickMenu_Page_Entries;
 287                         if(QuickMenu_Page_Entries == QUICKMENU_MAXLINES - 2)
 288                                 QuickMenu_Buffer_Index_Prev = QuickMenu_Buffer_Index;
 289                         else if(QuickMenu_Page_Entries == QUICKMENU_MAXLINES)
 290                         {
 291                                 QuickMenu_Page_ClearEntry(QUICKMENU_MAXLINES - 1);
 292                                 QuickMenu_Buffer_Index = QuickMenu_Buffer_Index_Prev;
 293                                 QuickMenu_IsLastPage = false;
 294                                 break;
 295                         }
 296                 }
 297
 298                 // NOTE: entries are loaded starting from 1, not from 0
 299                 if(substring(s, 0, 1) == "S") // submenu
 300                 {
 301                         if(entry_num >= first_entry)
 302                                 QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, substring(s, 1, -1), "");
 303                         QuickMenu_skip_submenu(substring(s, 1, -1));
 304                 }
 305                 else if(entry_num >= first_entry && substring(s, 0, 1) == "T")
 306                 {
 307                         ++QuickMenu_Buffer_Index;
 308                         cmd = bufstr_get(QuickMenu_Buffer, QuickMenu_Buffer_Index);
 309                         string command_code = substring(cmd, 0, 1);
 310                         if(command_code == "C")
 311                                 cmd = substring(cmd, 1, -1);
 312                         else if(command_code == "P")
 313                         {
 314                                 // throw away the current quickmenu buffer and load a new one
 315                                 cmd = substring(cmd, 1, -1);
 316                                 strunzone(z_submenu);
 317                                 if(HUD_Quickmenu_PlayerListEntries_Create(cmd, stof(substring(s, 1, 1)), stof(substring(s, 2, 1))))
 318                                         return QuickMenu_Page_Load("", 0);
 319                                 QuickMenu_Close();
 320                                 return false;
 321                         }
 322                         QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, substring(s, 1, -1), cmd);
 323                 }
 324
 325                 ++entry_num;
 326         }
 327         strunzone(z_submenu);
 328         if (QuickMenu_Page_Entries == 0)
 329         {
 330                 QuickMenu_Close();
 331                 return false;
 332         }
 333         QuickMenu_TimeOut = time + autocvar_hud_panel_quickmenu_time;
 334         return true;
 335 }
 336
 337 bool QuickMenu_ActionForNumber(int num)
 338 {
 339         if (!QuickMenu_IsLastPage)
 340         {
 341                 if (num < 0 || num >= QUICKMENU_MAXLINES)
 342                         return false;
 343                 if (num == QUICKMENU_MAXLINES - 1)
 344                         return false;
 345                 if (num == 0)
 346                 {
 347                         QuickMenu_Page_Load(QuickMenu_CurrentSubMenu, +1);
 348                         return false;
 349                 }
 350         } else if (num <= 0 || num > QuickMenu_Page_Entries)
 351                 return false;
 352
 353         if (QuickMenu_Page_Command[num] != "")
 354         {
 355                 localcmd(strcat("\n", QuickMenu_Page_Command[num], "\n"));
 356                 return true;
 357         }
 358         if (QuickMenu_Page_Description[num] != "")
 359                 QuickMenu_Page_Load(QuickMenu_Page_Description[num], 0);
 360         return false;
 361 }
 362
 363 void QuickMenu_Page_ActiveEntry(float entry_num)
 364 {
 365         QuickMenu_Page_ActivatedEntry = entry_num;
 366         QuickMenu_Page_ActivatedEntry_Time = time + 0.1;
 367         QuickMenu_Page_ActivatedEntry_Close = (!(hudShiftState & S_CTRL));
 368 }
 369
 370 bool QuickMenu_InputEvent(float bInputType, float nPrimary, float nSecondary)
 371 {
 372         // we only care for keyboard events
 373         if(bInputType == 2)
 374                 return false;
 375
 376         if(!QuickMenu_IsOpened() || autocvar__hud_configure || mv_active)
 377                 return false;
 378
 379         if(bInputType == 3)
 380         {
 381                 mousepos_x = nPrimary;
 382                 mousepos_y = nSecondary;
 383                 return true;
 384         }
 385
 386         // allow console bind to work
 387         string con_keys;
 388         float keys;
 389         con_keys = findkeysforcommand("toggleconsole", 0);
 390         keys = tokenize(con_keys); // findkeysforcommand returns data for this
 391
 392         bool hit_con_bind = false;
 393         int i;
 394         for (i = 0; i < keys; ++i)
 395         {
 396                 if(nPrimary == stof(argv(i)))
 397                         hit_con_bind = true;
 398         }
 399
 400         if(bInputType == 0) {
 401                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
 402                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 403                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 404         }
 405         else if(bInputType == 1) {
 406                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 407                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 408                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 409         }
 410
 411         if(nPrimary == K_ESCAPE)
 412         {
 413                 if (bInputType == 1)
 414                         return true;
 415                 QuickMenu_Close();
 416         }
 417         else if(nPrimary >= '0' && nPrimary <= '9')
 418         {
 419                 if (bInputType == 1)
 420                         return true;
 421                 QuickMenu_Page_ActiveEntry(stof(chr2str(nPrimary)));
 422         }
 423         if(nPrimary == K_MOUSE1)
 424         {
 425                 if(bInputType == 0) // key pressed
 426                         mouseClicked |= S_MOUSE1;
 427                 else if(bInputType == 1) // key released
 428                         mouseClicked -= (mouseClicked & S_MOUSE1);
 429         }
 430         else if(nPrimary == K_MOUSE2)
 431         {
 432                 if(bInputType == 0) // key pressed
 433                         mouseClicked |= S_MOUSE2;
 434                 else if(bInputType == 1) // key released
 435                         mouseClicked -= (mouseClicked & S_MOUSE2);
 436         }
 437         else if(hit_con_bind)
 438                 return false;
 439
 440         return true;
 441 }
 442
 443 void QuickMenu_Mouse()
 444 {
 445         if(mv_active) return;
 446
 447         if(!mouseClicked)
 448         if(prevMouseClicked & S_MOUSE2)
 449         {
 450                 QuickMenu_Close();
 451                 return;
 452         }
 453
 454         if(!autocvar_hud_cursormode)
 455         {
 456                 mousepos = mousepos + getmousepos() * autocvar_menu_mouse_speed;
 457
 458                 mousepos_x = bound(0, mousepos_x, vid_conwidth);
 459                 mousepos_y = bound(0, mousepos_y, vid_conheight);
 460         }
 461
 462         HUD_Panel_UpdateCvars();
 463
 464         if(panel_bg_padding)
 465         {
 466                 panel_pos += '1 1 0' * panel_bg_padding;
 467                 panel_size -= '2 2 0' * panel_bg_padding;
 468         }
 469
 470         float first_entry_pos, entries_height;
 471         vector fontsize;
 472         fontsize = '1 1 0' * (panel_size_y / QUICKMENU_MAXLINES);
 473         first_entry_pos = panel_pos_y + ((QUICKMENU_MAXLINES - QuickMenu_Page_Entries) * fontsize_y) / 2;
 474         entries_height = panel_size_y - ((QUICKMENU_MAXLINES - QuickMenu_Page_Entries) * fontsize_y);
 475
 476         if (mousepos_x >= panel_pos_x && mousepos_y >= first_entry_pos && mousepos_x <= panel_pos_x + panel_size_x && mousepos_y <= first_entry_pos + entries_height)
 477         {
 478                 float entry_num;
 479                 entry_num = floor((mousepos_y - first_entry_pos) / fontsize_y);
 480                 if (QuickMenu_IsLastPage || entry_num != QUICKMENU_MAXLINES - 2)
 481                 {
 482                         panel_pos_y = first_entry_pos + entry_num * fontsize_y;
 483                         vector color;
 484                         if(mouseClicked & S_MOUSE1)
 485                                 color = '0.5 1 0.5';
 486                         else if(hudShiftState & S_CTRL)
 487                                 color = '1 1 0.3';
 488                         else
 489                                 color = '1 1 1';
 490                         drawfill(panel_pos, eX * panel_size_x + eY * fontsize_y, color, .2, DRAWFLAG_NORMAL);
 491
 492                         if(!mouseClicked && (prevMouseClicked & S_MOUSE1))
 493                                 QuickMenu_Page_ActiveEntry((entry_num < QUICKMENU_MAXLINES - 1) ? entry_num + 1 : 0);
 494                 }
 495         }
 496
 497         vector cursorsize = '32 32 0';
 498         drawpic(mousepos, strcat("gfx/menu/", autocvar_menu_skin, "/cursor.tga"), cursorsize, '1 1 1', 0.8, DRAWFLAG_NORMAL);
 499
 500         prevMouseClicked = mouseClicked;
 501 }
 502
 503 void HUD_Quickmenu_DrawEntry(vector pos, string s, vector fontsize)
 504 {
 505         string entry;
 506         float offset;
 507         entry = textShortenToWidth(s, panel_size_x, fontsize, stringwidth_colors);
 508         if (autocvar_hud_panel_quickmenu_align > 0)
 509         {
 510                 offset = (panel_size_x - stringwidth_colors(entry, fontsize)) * min(autocvar_hud_panel_quickmenu_align, 1);
 511                 drawcolorcodedstring(pos + eX * offset, entry, fontsize, panel_fg_alpha, DRAWFLAG_ADDITIVE);
 512         }
 513         else
 514                 drawcolorcodedstring(pos, entry, fontsize, panel_fg_alpha, DRAWFLAG_ADDITIVE);
 515 }
 516
 517 void HUD_QuickMenu(void)
 518 {
 519         if(!autocvar__hud_configure)
 520         {
 521                 if (hud_configure_prev && hud_configure_prev != -1)
 522                         QuickMenu_Close();
 523
 524                 if(!hud_draw_maximized) return;
 525                 if(mv_active) return;
 526                 //if(!autocvar_hud_panel_quickmenu) return;
 527                 if(!hud_panel_quickmenu) return;
 528
 529                 if(time > QuickMenu_TimeOut)
 530                 {
 531                         QuickMenu_Close();
 532                         return;
 533                 }
 534         }
 535         else
 536         {
 537                 if(!QuickMenu_IsOpened())
 538                 {
 539                         QuickMenu_Page_Entries = 1;
 540                         QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, sprintf(_("Submenu%d"), QuickMenu_Page_Entries), "");
 541                         ++QuickMenu_Page_Entries;
 542                         QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, sprintf(_("Submenu%d"), QuickMenu_Page_Entries), "");
 543                         ++QuickMenu_Page_Entries;
 544                         // although real command doesn't matter here, it must not be empty
 545                         // otherwise the entry is displayed like a submenu
 546                         for (; QuickMenu_Page_Entries < QUICKMENU_MAXLINES - 1; ++QuickMenu_Page_Entries)
 547                                 QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, sprintf(_("Command%d"), QuickMenu_Page_Entries), "-");
 548                         ++QuickMenu_Page_Entries;
 549                         QuickMenu_Page_ClearEntry(QuickMenu_Page_Entries);
 550                         QuickMenu_IsLastPage = false;
 551                 }
 552         }
 553
 554         HUD_Panel_UpdateCvars();
 555
 556         HUD_Panel_DrawBg(1);
 557
 558         if(panel_bg_padding)
 559         {
 560                 panel_pos += '1 1 0' * panel_bg_padding;
 561                 panel_size -= '2 2 0' * panel_bg_padding;
 562         }
 563
 564         int i;
 565         vector fontsize;
 566         string color;
 567         fontsize = '1 1 0' * (panel_size_y / QUICKMENU_MAXLINES);
 568
 569         if (!QuickMenu_IsLastPage)
 570         {
 571                 color = "^5";
 572                 HUD_Quickmenu_DrawEntry(panel_pos + eY * (panel_size_y - fontsize_y), sprintf("%d: %s%s", 0, color, _("Continue...")), fontsize);
 573         }
 574         else
 575                 panel_pos_y += ((QUICKMENU_MAXLINES - QuickMenu_Page_Entries) * fontsize_y) / 2;
 576
 577         for (i = 1; i <= QuickMenu_Page_Entries; ++i) {
 578                 if (QuickMenu_Page_Description[i] == "")
 579                         break;
 580                 if (QuickMenu_Page_Command[i] == "")
 581                         color = "^4";
 582                 else
 583                         color = "^3";
 584                 HUD_Quickmenu_DrawEntry(panel_pos, sprintf("%d: %s%s", i, color, QuickMenu_Page_Description[i]), fontsize);
 585
 586                 if(QuickMenu_Page_ActivatedEntry_Time && time < QuickMenu_Page_ActivatedEntry_Time
 587                         && QuickMenu_Page_ActivatedEntry == i)
 588                         drawfill(panel_pos, eX * panel_size_x + eY * fontsize_y, '0.5 1 0.5', .2, DRAWFLAG_NORMAL);
 589
 590                 panel_pos_y += fontsize_y;
 591         }
 592
 593         if(QuickMenu_Page_ActivatedEntry >= 0 && time >= QuickMenu_Page_ActivatedEntry_Time)
 594         {
 595                 bool f = QuickMenu_ActionForNumber(QuickMenu_Page_ActivatedEntry);
 596                 if(f && QuickMenu_Page_ActivatedEntry_Close)
 597                         QuickMenu_Close();
 598                 QuickMenu_Page_ActivatedEntry = -1;
 599                 QuickMenu_Page_ActivatedEntry_Time = 0;
 600         }
 601 }
 602
 603
 604 #define QUICKMENU_SMENU(submenu,eng_submenu) { \
 605         if(target_submenu == eng_submenu && target_submenu_found) \
 606                 return; /* target_submenu entries are now loaded, exit */ \
 607         if(QuickMenu_Buffer_Size < QUICKMENU_BUFFER_MAXENTRIES) \
 608                 bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat("S", submenu)); \
 609         ++QuickMenu_Buffer_Size; \
 610         if(target_submenu == eng_submenu && !target_submenu_found) { \
 611                 QuickMenu_Buffer_Size = 0; /* enable load of next entries */ \
 612                 target_submenu_found = true; \
 613         } \
 614 }
 615
 616 #define QUICKMENU_ENTRY(title,command) { \
 617         if(QuickMenu_Buffer_Size + 1 < QUICKMENU_BUFFER_MAXENTRIES) \
 618         { \
 619                 bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat("T", title)); \
 620                 ++QuickMenu_Buffer_Size; \
 621                 bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat("C", command)); \
 622         } \
 623         ++QuickMenu_Buffer_Size; \
 624 }
 625
 626 #define QUICKMENU_SMENU_PL(submenu,eng_submenu,command,teamplayers,without_me) { \
 627         if(QuickMenu_Buffer_Size + 3 < QUICKMENU_BUFFER_MAXENTRIES) {\
 628                 QUICKMENU_SMENU(submenu,eng_submenu) \
 629                 bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat("T", ftos(teamplayers), ftos(without_me))); \
 630                 ++QuickMenu_Buffer_Size; \
 631                 bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat("P", command)); \
 632                 ++QuickMenu_Buffer_Size; \
 633                 QUICKMENU_SMENU(submenu,eng_submenu) \
 634         } \
 635 }
 636
 637
 638
 639 // useful to Translate a string inside the Command
 640 #define QUICKMENU_ENTRY_TC(title,command,text,translated_text) {\
 641         if(prvm_language == "en") \
 642                 QUICKMENU_ENTRY(title, sprintf(command, text)) \
 643         else if(!autocvar_hud_panel_quickmenu_translatecommands || translated_text == text) \
 644                 QUICKMENU_ENTRY(strcat("(en)", title), sprintf(command, text)) \
 645         else \
 646                 QUICKMENU_ENTRY(strcat("(", prvm_language, ")", title), sprintf(command, translated_text)) \
 647 }
 648
 649 void HUD_Quickmenu_PlayerListEntries(string cmd, float teamplayers, float without_me)
 650 {
 651         entity pl;
 652         if(teamplayers && !team_count)
 653                 return;
 654
 655         for(pl = players.sort_next; pl; pl = pl.sort_next)
 656         {
 657                 if(teamplayers == 1 && (pl.team != myteam || pl.team == NUM_SPECTATOR)) // only own team players
 658                         continue;
 659                 if(teamplayers == 2 && (pl.team == myteam || pl.team == NUM_SPECTATOR)) // only enemy team players
 660                         continue;
 661                 if(without_me && pl.sv_entnum == player_localnum)
 662                         continue;
 663                 QUICKMENU_ENTRY(GetPlayerName(pl.sv_entnum), sprintf(cmd, GetPlayerName(pl.sv_entnum)))
 664         }
 665
 666         return;
 667 }
 668
 669
 670 // Specifying target_submenu, this function only loads entries inside target_submenu
 671 // NOTE: alternatively we could have loaded the whole default quickmenu and
 672 // then called QuickMenu_Page_Load(target_submenu, 0);
 673 // but this sytem is more reliable since we can always refer to target_submenu
 674 // with the English title even if a translation is active
 675 void QuickMenu_Default(string target_submenu)
 676 {
 677         bool target_submenu_found = false;
 678         if(target_submenu != "")
 679                 QuickMenu_Buffer_Size = QUICKMENU_BUFFER_MAXENTRIES; // forbids load of next entries until target_submenu
 680
 681         QUICKMENU_SMENU(CTX(_("QMCMD^Chat")), "Chat")
 682                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^nice one")), "say %s", ":-) / nice one", CTX(_("QMCMD^:-) / nice one")))
 683                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^good game")), "say %s", "good game", CTX(_("QMCMD^good game")))
 684                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^hi / good luck")), "say %s", "hi / good luck and have fun", CTX(_("QMCMD^hi / good luck and have fun")))
 685         QUICKMENU_SMENU(CTX(_("QMCMD^Chat")), "Chat")
 686
 687         if(teamplay)
 688         {
 689         QUICKMENU_SMENU(CTX(_("QMCMD^Team chat")), "Team chat")
 690                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^quad soon")), "say_team %s", "quad soon", CTX(_("QMCMD^quad soon")))
 691                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^free item, icon")), "say_team %s; g_waypointsprite_team_here_p", "free item %x^7 (l:%y^7)", CTX(_("QMCMD^free item %x^7 (l:%y^7)")))
 692                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^took item, icon")), "say_team %s; g_waypointsprite_team_here", "took item (l:%l^7)", CTX(_("QMCMD^took item (l:%l^7)")))
 693                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^negative")), "say_team %s", "negative", CTX(_("QMCMD^negative")))
 694                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^positive")), "say_team %s", "positive", CTX(_("QMCMD^positive")))
 695                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^need help, icon")), "say_team %s; g_waypointsprite_team_helpme; cmd voice needhelp", "need help (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^need help (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 696                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^enemy seen, icon")), "say_team %s; g_waypointsprite_team_danger_p; cmd voice incoming", "enemy seen (l:%y^7)", CTX(_("QMCMD^enemy seen (l:%y^7)")))
 697                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^flag seen, icon")), "say_team %s; g_waypointsprite_team_here_p; cmd voice seenflag", "flag seen (l:%y^7)", CTX(_("QMCMD^flag seen (l:%y^7)")))
 698                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^defending, icon")), "say_team %s; g_waypointsprite_team_here", "defending (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^defending (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 699                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^roaming, icon")), "say_team %s; g_waypointsprite_team_here", "roaming (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^roaming (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 700                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^attacking, icon")), "say_team %s; g_waypointsprite_team_here", "attacking (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^attacking (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 701                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^killed flag, icon")), "say_team %s; g_waypointsprite_team_here_p", "killed flagcarrier (l:%y^7)", CTX(_("QMCMD^killed flagcarrier (l:%y^7)")))
 702                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^dropped flag, icon")), "say_team %s; g_waypointsprite_team_here_d", "dropped flag (l:%d^7)", CTX(_("QMCMD^dropped flag (l:%d^7)")))
 703                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^drop gun, icon")), "say_team %s; g_waypointsprite_team_here; wait; dropweapon", "dropped gun %w^7 (l:%l^7)", CTX(_("QMCMD^dropped gun %w^7 (l:%l^7)")))
 704                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^drop flag/key, icon")), "say_team %s; g_waypointsprite_team_here; wait; +use", "dropped flag/key %w^7 (l:%l^7)", CTX(_("QMCMD^dropped flag/key %w^7 (l:%l^7)")))
 705         QUICKMENU_SMENU(CTX(_("QMCMD^Team chat")), "Team chat")
 706         }
 707
 708         QUICKMENU_SMENU_PL(CTX(_("QMCMD^Send private message to")), "Send private message to", "commandmode tell \"%s\" ^7", 0, 1)
 709
 710         QUICKMENU_SMENU(CTX(_("QMCMD^Settings")), "Settings")
 711                 QUICKMENU_SMENU(CTX(_("QMCMD^View/HUD settings")), "View/HUD settings")
 712                         QUICKMENU_ENTRY(CTX(_("QMCMD^1st/3rd person view")), "toggle chase_active")
 713                         QUICKMENU_ENTRY(CTX(_("QMCMD^Player models like mine on/off")), "toggle cl_forceplayermodels")
 714                         QUICKMENU_ENTRY(CTX(_("QMCMD^Names above players on/off")), "toggle hud_shownames")
 715                         QUICKMENU_ENTRY(CTX(_("QMCMD^Crosshair per weapon on/off")), "toggle crosshair_per_weapon")
 716                         QUICKMENU_ENTRY(CTX(_("QMCMD^FPS on/off")), "toggle hud_panel_engineinfo")
 717                         QUICKMENU_ENTRY(CTX(_("QMCMD^Net graph on/off")), "toggle shownetgraph")
 718                 QUICKMENU_SMENU(CTX(_("QMCMD^View/HUD settings")), "View/HUD settings")
 719
 720                 QUICKMENU_SMENU(CTX(_("QMCMD^Sound settings")), "Sound settings")
 721                         QUICKMENU_ENTRY(CTX(_("QMCMD^Hit sound on/off")), "toggle cl_hitsound")
 722                         QUICKMENU_ENTRY(CTX(_("QMCMD^Chat sound on/off")), "toggle cl_chatsound")
 723                 QUICKMENU_SMENU(CTX(_("QMCMD^Sound settings")), "Sound settings")
 724
 725                 if(spectatee_status > 0)
 726                 {
 727                 QUICKMENU_SMENU(CTX(_("QMCMD^Spectator camera")), "Spectator camera")
 728                         QUICKMENU_ENTRY(CTX(_("QMCMD^1st person")), "chase_active 0; -use")
 729                         QUICKMENU_ENTRY(CTX(_("QMCMD^3rd person around player")), "chase_active 1; +use")
 730                         QUICKMENU_ENTRY(CTX(_("QMCMD^3rd person behind")), "chase_active 1; -use")
 731                 QUICKMENU_SMENU(CTX(_("QMCMD^Spectator camera")), "Spectator camera")
 732                 }
 733
 734                 if(spectatee_status == -1)
 735                 {
 736                 QUICKMENU_SMENU(CTX(_("QMCMD^Observer camera")), "Observer camera")
 737                         QUICKMENU_ENTRY(CTX(_("QMCMD^Increase speed")), "weapnext")
 738                         QUICKMENU_ENTRY(CTX(_("QMCMD^Decrease speed")), "weapprev")
 739                         QUICKMENU_ENTRY(CTX(_("QMCMD^Wall collision off")), "+use")
 740                         QUICKMENU_ENTRY(CTX(_("QMCMD^Wall collision on")), "-use")
 741                 QUICKMENU_SMENU(CTX(_("QMCMD^Observer camera")), "Observer camera")
 742                 }
 743
 744                 QUICKMENU_ENTRY(CTX(_("QMCMD^toggle fullscreen")), "toggle vid_fullscreen; vid_restart")
 745                 if(prvm_language != "en")
 746                 QUICKMENU_ENTRY(CTX(_("QMCMD^Translate chat messages on/off")), "toggle hud_panel_quickmenu_translatecommands")
 747         QUICKMENU_SMENU(CTX(_("QMCMD^Settings")), "Settings")
 748
 749         QUICKMENU_SMENU(CTX(_("QMCMD^Call a vote")), "Call a vote")
 750                 QUICKMENU_ENTRY(CTX(_("QMCMD^Restart the map")), "vcall restart")
 751                 QUICKMENU_ENTRY(CTX(_("QMCMD^End match")), "vcall endmatch")
 752                 if(getstatf(STAT_TIMELIMIT) > 0)
 753                 {
 754                 QUICKMENU_ENTRY(CTX(_("QMCMD^Reduce match time")), "vcall reducematchtime")
 755                 QUICKMENU_ENTRY(CTX(_("QMCMD^Extend match time")), "vcall extendmatchtime")
 756                 }
 757                 if(teamplay)
 758                 QUICKMENU_ENTRY(CTX(_("QMCMD^Shuffle teams")), "vcall shuffleteams")
 759         QUICKMENU_SMENU(CTX(_("QMCMD^Call a vote")), "Call a vote")
 760
 761         if(target_submenu != "" && !target_submenu_found)
 762         {
 763                 printf("Couldn't find submenu \"%s\"\n", target_submenu);
 764                 if(prvm_language != "en")
 765                         printf("^3Warning: submenu must be in English\n", target_submenu);
 766                 QuickMenu_Buffer_Size = 0;
 767         }
 768 }
 769 #undef QUICKMENU_SMENU
 770 #undef QUICKMENU_ENTRY
 771 #undef QUICKMENU_ENTRY_TC