qcsrc/client/quickmenu.qc

   1 #include "_all.qh"
   2
   3 #include "hud_config.qh"
   4
   5 #include "../dpdefs/keycodes.qh"
   6
   7 // QUICKMENU_MAXLINES must be <= 10
   8 const int QUICKMENU_MAXLINES = 10;
   9 // visible entries are loaded from QuickMenu_Buffer into QuickMenu_Page_* arrays
  10 string QuickMenu_Page_Command[QUICKMENU_MAXLINES];
  11 string QuickMenu_Page_Description[QUICKMENU_MAXLINES];
  12 int QuickMenu_Page_Command_Type[QUICKMENU_MAXLINES];
  13 int QuickMenu_Page_Entries;
  14 int QuickMenu_Page;
  15 int QuickMenu_Page_ActivatedEntry = -1;
  16 bool QuickMenu_Page_ActivatedEntry_Close;
  17 float QuickMenu_Page_ActivatedEntry_Time;
  18 bool QuickMenu_IsLastPage;
  19 // all the entries are loaded into QuickMenu_Buffer
  20 // each entry (submenu or command) is composed of 2 entries
  21 const int QUICKMENU_MAXENTRIES = 256;
  22 const int QUICKMENU_BUFFER_MAXENTRIES = 2 * QUICKMENU_MAXENTRIES;
  23 int QuickMenu_Buffer = -1;
  24 int QuickMenu_Buffer_Size;
  25 int QuickMenu_Buffer_Index;
  26 string QuickMenu_CurrentSubMenu;
  27 float QuickMenu_TimeOut;
  28 // if s1 is not empty s will be displayed as command otherwise as submenu
  29 void QuickMenu_Page_LoadEntry(int i, string s, string s1)
  30 {
  31         //printf("^xc80 entry %d: %s, %s\n", i, s, s1);
  32         if (QuickMenu_Page_Description[i])
  33                 strunzone(QuickMenu_Page_Description[i]);
  34         QuickMenu_Page_Description[i] = strzone(s);
  35         if (QuickMenu_Page_Command[i])
  36                 strunzone(QuickMenu_Page_Command[i]);
  37         QuickMenu_Page_Command[i] = strzone(s1);
  38 }
  39
  40 void QuickMenu_Page_ClearEntry(int i)
  41 {
  42         if (QuickMenu_Page_Description[i])
  43                 strunzone(QuickMenu_Page_Description[i]);
  44         QuickMenu_Page_Description[i] = string_null;
  45         if (QuickMenu_Page_Command[i])
  46                 strunzone(QuickMenu_Page_Command[i]);
  47         QuickMenu_Page_Command[i] = string_null;
  48 }
  49
  50 float QuickMenu_Page_Load(string target_submenu, float new_page);
  51 void QuickMenu_Default(string submenu);
  52 bool QuickMenu_Open(string mode, string submenu)
  53 {
  54         int fh = -1;
  55         string s;
  56
  57         if(mode == "")
  58         {
  59                 if(autocvar_hud_panel_quickmenu_file == "" || autocvar_hud_panel_quickmenu_file == "0")
  60                         mode = "default";
  61                 else
  62                         mode = "file";
  63         }
  64
  65         if(mode == "file")
  66         {
  67                 if(autocvar_hud_panel_quickmenu_file == "" || autocvar_hud_panel_quickmenu_file == "0")
  68                         printf("No file name is set in hud_panel_quickmenu_file, loading default quickmenu\n");
  69                 else
  70                 {
  71                         fh = fopen(autocvar_hud_panel_quickmenu_file, FILE_READ);
  72                         if(fh < 0)
  73                                 printf("Couldn't open file \"%s\", loading default quickmenu\n", autocvar_hud_panel_quickmenu_file);
  74                 }
  75                 if(fh < 0)
  76                         mode = "default";
  77         }
  78
  79         if(mode == "default")
  80         {
  81                 QuickMenu_Buffer = buf_create();
  82                 if(QuickMenu_Buffer < 0)
  83                         return false;
  84
  85                 QuickMenu_Default(submenu);
  86         }
  87         else if(mode == "file")
  88         {
  89                 QuickMenu_Buffer = buf_create();
  90                 if(QuickMenu_Buffer < 0)
  91                 {
  92                         fclose(fh);
  93                         return false;
  94                 }
  95
  96                 QuickMenu_Buffer_Size = 0;
  97                 while((s = fgets(fh)) && QuickMenu_Buffer_Size < QUICKMENU_BUFFER_MAXENTRIES)
  98                 {
  99                         // first skip invalid entries, so we don't check them anymore
 100                         float argc;
 101                         argc = tokenize_console(s);
 102                         if(argc == 0 || argv(0) == "")
 103                                 continue;
 104                         if(argc == 1)
 105                                 bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat("S", argv(0))); // Submenu
 106                         else if(argc == 2)
 107                         {
 108                                 if(argv(1) == "")
 109                                         continue;
 110                                 bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat("T", argv(0))); // command Title
 111                                 ++QuickMenu_Buffer_Size;
 112                                 bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat("C", argv(1))); // command
 113                         }
 114                         else if(argc == 3)
 115                         {
 116                                 // check for special keywords
 117                                 float teamplayers = 0, without_me = 0;
 118                                 switch(argv(2))
 119                                 {
 120                                         case "ALLPLAYERS_BUT_ME":               without_me = 1; // fall through
 121                                         case "ALLPLAYERS":                              teamplayers = 0; break;
 122                                         case "OWNTEAMPLAYERS_BUT_ME":   without_me = 1; // fall through
 123                                         case "OWNTEAMPLAYERS":                  teamplayers = 1; break;
 124                                         case "ENEMYTEAMPLAYERS":                teamplayers = 2; break;
 125                                         default: continue;
 126                                 }
 127
 128                                 if(QuickMenu_Buffer_Size + 3 < QUICKMENU_BUFFER_MAXENTRIES)
 129                                 {
 130                                         bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat("S", argv(0))); // Submenu
 131                                         ++QuickMenu_Buffer_Size;
 132                                         bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat("T", ftos(teamplayers), ftos(without_me))); // command arguments
 133                                         ++QuickMenu_Buffer_Size;
 134                                         bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat("P", argv(1))); // command for each player
 135                                         ++QuickMenu_Buffer_Size;
 136                                         bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat("S", argv(0))); // Submenu
 137                                 }
 138                         }
 139                         ++QuickMenu_Buffer_Size;
 140                 }
 141                 fclose(fh);
 142         }
 143         else
 144         {
 145                 printf("Unrecognized mode %s\n", mode);
 146                 return false;
 147         }
 148
 149         if (QuickMenu_Buffer_Size <= 0)
 150         {
 151                 buf_del(QuickMenu_Buffer);
 152                 QuickMenu_Buffer = -1;
 153                 return false;
 154         }
 155
 156         if(mode == "file")
 157                 QuickMenu_Page_Load(submenu, 0);
 158         else
 159                 QuickMenu_Page_Load("", 0);
 160
 161         hud_panel_quickmenu = 1;
 162         if(autocvar_hud_cursormode)
 163                 setcursormode(1);
 164         hudShiftState = 0;
 165
 166         QuickMenu_TimeOut = time + autocvar_hud_panel_quickmenu_time;
 167         return true;
 168 }
 169
 170 void QuickMenu_Buffer_Close()
 171 {
 172         if (QuickMenu_Buffer >= 0)
 173         {
 174                 buf_del(QuickMenu_Buffer);
 175                 QuickMenu_Buffer = -1;
 176                 QuickMenu_Buffer_Size = 0;
 177         }
 178 }
 179
 180 void QuickMenu_Close()
 181 {
 182         if (QuickMenu_CurrentSubMenu)
 183                 strunzone(QuickMenu_CurrentSubMenu);
 184         QuickMenu_CurrentSubMenu = string_null;
 185         int i;
 186         for (i = 0; i < QUICKMENU_MAXLINES; ++i)
 187                 QuickMenu_Page_ClearEntry(i);
 188         QuickMenu_Page_Entries = 0;
 189         hud_panel_quickmenu = 0;
 190         mouseClicked = 0;
 191         prevMouseClicked = 0;
 192         QuickMenu_Buffer_Close();
 193
 194         if(autocvar_hud_cursormode)
 195         if(!mv_active)
 196                 setcursormode(0);
 197 }
 198
 199 // It assumes submenu open tag is already detected
 200 void QuickMenu_skip_submenu(string submenu)
 201 {
 202         string s, z_submenu;
 203         z_submenu = strzone(submenu);
 204         for(++QuickMenu_Buffer_Index ; QuickMenu_Buffer_Index < QuickMenu_Buffer_Size; ++QuickMenu_Buffer_Index)
 205         {
 206                 s = bufstr_get(QuickMenu_Buffer, QuickMenu_Buffer_Index);
 207                 if(substring(s, 0, 1) != "S")
 208                         continue;
 209                 if(substring(s, 1, -1) == z_submenu) // submenu end
 210                         break;
 211                 QuickMenu_skip_submenu(substring(s, 1, -1));
 212         }
 213         strunzone(z_submenu);
 214 }
 215
 216 bool QuickMenu_IsOpened()
 217 {
 218         return (QuickMenu_Page_Entries > 0);
 219 }
 220
 221 void HUD_Quickmenu_PlayerListEntries(string cmd, int teamplayers, float without_me);
 222 bool HUD_Quickmenu_PlayerListEntries_Create(string cmd, int teamplayers, float without_me)
 223 {
 224         int i;
 225         for(i = 0; i < QUICKMENU_MAXLINES; ++i)
 226                 QuickMenu_Page_ClearEntry(i);
 227         QuickMenu_Buffer_Close();
 228
 229         QuickMenu_Buffer = buf_create();
 230         if(QuickMenu_Buffer < 0)
 231                 return false;
 232
 233         HUD_Quickmenu_PlayerListEntries(cmd, teamplayers, without_me);
 234
 235         if(QuickMenu_Buffer_Size <= 0)
 236         {
 237                 buf_del(QuickMenu_Buffer);
 238                 QuickMenu_Buffer = -1;
 239                 return false;
 240         }
 241         return true;
 242 }
 243
 244 // new_page 0 means page 0, new_page != 0 means next page
 245 int QuickMenu_Buffer_Index_Prev;
 246 bool QuickMenu_Page_Load(string target_submenu, int new_page)
 247 {
 248         string s = string_null, cmd = string_null, z_submenu;
 249
 250         if (new_page == 0)
 251                 QuickMenu_Page = 0;
 252         else
 253                 ++QuickMenu_Page;
 254
 255         z_submenu = strzone(target_submenu);
 256         if (QuickMenu_CurrentSubMenu)
 257                 strunzone(QuickMenu_CurrentSubMenu);
 258         QuickMenu_CurrentSubMenu = strzone(z_submenu);
 259
 260         QuickMenu_IsLastPage = true;
 261         QuickMenu_Page_Entries = 0;
 262
 263         QuickMenu_Buffer_Index = 0;
 264         if (z_submenu != "")
 265         {
 266                 // skip everything until the submenu open tag is found
 267                 for( ; QuickMenu_Buffer_Index < QuickMenu_Buffer_Size; ++QuickMenu_Buffer_Index)
 268                 {
 269                         s = bufstr_get(QuickMenu_Buffer, QuickMenu_Buffer_Index);
 270                         if(substring(s, 0, 1) == "S" && substring(s, 1, -1) == z_submenu)
 271                         {
 272                                 // printf("^3 beginning of %s\n", z_submenu);
 273                                 ++QuickMenu_Buffer_Index;
 274                                 break; // target_submenu found!
 275                         }
 276                         // printf("^1 skipping %s\n", s);
 277                 }
 278                 if(QuickMenu_Buffer_Index == QuickMenu_Buffer_Size)
 279                         printf("Couldn't find submenu \"%s\"\n", z_submenu);
 280         }
 281
 282         // only the last page can contain up to QUICKMENU_MAXLINES entries
 283         // the other ones contain only (QUICKMENU_MAXLINES - 2) entries
 284         // so that the panel can show an empty row and "Continue..."
 285         float first_entry = QuickMenu_Page * (QUICKMENU_MAXLINES - 2);
 286         int entry_num = 0; // counts entries in target_submenu
 287         for( ; QuickMenu_Buffer_Index < QuickMenu_Buffer_Size; ++QuickMenu_Buffer_Index)
 288         {
 289                 s = bufstr_get(QuickMenu_Buffer, QuickMenu_Buffer_Index);
 290
 291                 if(z_submenu != "" && substring(s, 1, -1) == z_submenu)
 292                 {
 293                         // printf("^3 end of %s\n", z_submenu);
 294                         break;
 295                 }
 296
 297                 if(entry_num >= first_entry)
 298                 {
 299                         ++QuickMenu_Page_Entries;
 300                         if(QuickMenu_Page_Entries == QUICKMENU_MAXLINES - 2)
 301                                 QuickMenu_Buffer_Index_Prev = QuickMenu_Buffer_Index;
 302                         else if(QuickMenu_Page_Entries == QUICKMENU_MAXLINES)
 303                         {
 304                                 QuickMenu_Page_ClearEntry(QUICKMENU_MAXLINES - 1);
 305                                 QuickMenu_Buffer_Index = QuickMenu_Buffer_Index_Prev;
 306                                 QuickMenu_IsLastPage = false;
 307                                 break;
 308                         }
 309                 }
 310
 311                 // NOTE: entries are loaded starting from 1, not from 0
 312                 if(substring(s, 0, 1) == "S") // submenu
 313                 {
 314                         if(entry_num >= first_entry)
 315                                 QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, substring(s, 1, -1), "");
 316                         QuickMenu_skip_submenu(substring(s, 1, -1));
 317                 }
 318                 else if(entry_num >= first_entry && substring(s, 0, 1) == "T")
 319                 {
 320                         ++QuickMenu_Buffer_Index;
 321                         cmd = bufstr_get(QuickMenu_Buffer, QuickMenu_Buffer_Index);
 322                         string command_code = substring(cmd, 0, 1);
 323                         if(command_code == "C")
 324                                 cmd = substring(cmd, 1, -1);
 325                         else if(command_code == "P")
 326                         {
 327                                 // throw away the current quickmenu buffer and load a new one
 328                                 cmd = substring(cmd, 1, -1);
 329                                 strunzone(z_submenu);
 330                                 if(HUD_Quickmenu_PlayerListEntries_Create(cmd, stof(substring(s, 1, 1)), stof(substring(s, 2, 1))))
 331                                         return QuickMenu_Page_Load("", 0);
 332                                 QuickMenu_Close();
 333                                 return false;
 334                         }
 335
 336                         tokenize_console(cmd);
 337                         QuickMenu_Page_Command_Type[QuickMenu_Page_Entries] = (argv(1) && argv(0) == "toggle");
 338
 339                         QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, substring(s, 1, -1), cmd);
 340                 }
 341
 342                 ++entry_num;
 343         }
 344         strunzone(z_submenu);
 345         if (QuickMenu_Page_Entries == 0)
 346         {
 347                 QuickMenu_Close();
 348                 return false;
 349         }
 350         QuickMenu_TimeOut = time + autocvar_hud_panel_quickmenu_time;
 351         return true;
 352 }
 353
 354 bool QuickMenu_ActionForNumber(int num)
 355 {
 356         if (!QuickMenu_IsLastPage)
 357         {
 358                 if (num < 0 || num >= QUICKMENU_MAXLINES)
 359                         return false;
 360                 if (num == QUICKMENU_MAXLINES - 1)
 361                         return false;
 362                 if (num == 0)
 363                 {
 364                         QuickMenu_Page_Load(QuickMenu_CurrentSubMenu, +1);
 365                         return false;
 366                 }
 367         } else if (num <= 0 || num > QuickMenu_Page_Entries)
 368                 return false;
 369
 370         if (QuickMenu_Page_Command[num] != "")
 371         {
 372                 localcmd(strcat("\n", QuickMenu_Page_Command[num], "\n"));
 373                 QuickMenu_TimeOut = time + autocvar_hud_panel_quickmenu_time;
 374                 return true;
 375         }
 376         if (QuickMenu_Page_Description[num] != "")
 377                 QuickMenu_Page_Load(QuickMenu_Page_Description[num], 0);
 378         return false;
 379 }
 380
 381 void QuickMenu_Page_ActiveEntry(float entry_num)
 382 {
 383         QuickMenu_Page_ActivatedEntry = entry_num;
 384         QuickMenu_Page_ActivatedEntry_Time = time + 0.1;
 385         if(QuickMenu_Page_Command[QuickMenu_Page_ActivatedEntry])
 386         {
 387                 bool f = QuickMenu_ActionForNumber(QuickMenu_Page_ActivatedEntry);
 388                 // toggle commands don't close the quickmenu
 389                 if(QuickMenu_Page_Command_Type[QuickMenu_Page_ActivatedEntry] == 1)
 390                         QuickMenu_Page_ActivatedEntry_Close = false;
 391                 else
 392                         QuickMenu_Page_ActivatedEntry_Close = (f && !(hudShiftState & S_CTRL));
 393         }
 394         else
 395                 QuickMenu_Page_ActivatedEntry_Close = (!(hudShiftState & S_CTRL));
 396 }
 397
 398 bool QuickMenu_InputEvent(float bInputType, float nPrimary, float nSecondary)
 399 {
 400         // we only care for keyboard events
 401         if(bInputType == 2)
 402                 return false;
 403
 404         if(!QuickMenu_IsOpened() || autocvar__hud_configure || mv_active)
 405                 return false;
 406
 407         if(bInputType == 3)
 408         {
 409                 mousepos.x = nPrimary;
 410                 mousepos.y = nSecondary;
 411                 return true;
 412         }
 413
 414         // allow console bind to work
 415         string con_keys;
 416         float keys;
 417         con_keys = findkeysforcommand("toggleconsole", 0);
 418         keys = tokenize(con_keys); // findkeysforcommand returns data for this
 419
 420         bool hit_con_bind = false;
 421         int i;
 422         for (i = 0; i < keys; ++i)
 423         {
 424                 if(nPrimary == stof(argv(i)))
 425                         hit_con_bind = true;
 426         }
 427
 428         if(bInputType == 0) {
 429                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
 430                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 431                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 432         }
 433         else if(bInputType == 1) {
 434                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 435                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 436                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 437         }
 438
 439         if(nPrimary == K_ESCAPE)
 440         {
 441                 if (bInputType == 1)
 442                         return true;
 443                 QuickMenu_Close();
 444         }
 445         else if(nPrimary >= '0' && nPrimary <= '9')
 446         {
 447                 if (bInputType == 1)
 448                         return true;
 449                 QuickMenu_Page_ActiveEntry(stof(chr2str(nPrimary)));
 450         }
 451         if(nPrimary == K_MOUSE1)
 452         {
 453                 if(bInputType == 0) // key pressed
 454                         mouseClicked |= S_MOUSE1;
 455                 else if(bInputType == 1) // key released
 456                         mouseClicked -= (mouseClicked & S_MOUSE1);
 457         }
 458         else if(nPrimary == K_MOUSE2)
 459         {
 460                 if(bInputType == 0) // key pressed
 461                         mouseClicked |= S_MOUSE2;
 462                 else if(bInputType == 1) // key released
 463                         mouseClicked -= (mouseClicked & S_MOUSE2);
 464         }
 465         else if(hit_con_bind)
 466                 return false;
 467
 468         return true;
 469 }
 470
 471 void QuickMenu_Mouse()
 472 {
 473         if(mv_active) return;
 474
 475         if(!mouseClicked)
 476         if(prevMouseClicked & S_MOUSE2)
 477         {
 478                 QuickMenu_Close();
 479                 return;
 480         }
 481
 482         if(!autocvar_hud_cursormode)
 483         {
 484                 mousepos = mousepos + getmousepos() * autocvar_menu_mouse_speed;
 485
 486                 mousepos.x = bound(0, mousepos.x, vid_conwidth);
 487                 mousepos.y = bound(0, mousepos.y, vid_conheight);
 488         }
 489
 490         HUD_Panel_UpdateCvars();
 491
 492         if(panel_bg_padding)
 493         {
 494                 panel_pos += '1 1 0' * panel_bg_padding;
 495                 panel_size -= '2 2 0' * panel_bg_padding;
 496         }
 497
 498         float first_entry_pos, entries_height;
 499         vector fontsize;
 500         fontsize = '1 1 0' * (panel_size.y / QUICKMENU_MAXLINES);
 501         first_entry_pos = panel_pos.y + ((QUICKMENU_MAXLINES - QuickMenu_Page_Entries) * fontsize.y) / 2;
 502         entries_height = panel_size.y - ((QUICKMENU_MAXLINES - QuickMenu_Page_Entries) * fontsize.y);
 503
 504         if (mousepos.x >= panel_pos.x && mousepos.y >= first_entry_pos && mousepos.x <= panel_pos.x + panel_size.x && mousepos.y <= first_entry_pos + entries_height)
 505         {
 506                 float entry_num;
 507                 entry_num = floor((mousepos.y - first_entry_pos) / fontsize.y);
 508                 if (QuickMenu_IsLastPage || entry_num != QUICKMENU_MAXLINES - 2)
 509                 {
 510                         panel_pos.y = first_entry_pos + entry_num * fontsize.y;
 511                         vector color;
 512                         if(mouseClicked & S_MOUSE1)
 513                                 color = '0.5 1 0.5';
 514                         else if(hudShiftState & S_CTRL)
 515                                 color = '1 1 0.3';
 516                         else
 517                                 color = '1 1 1';
 518                         drawfill(panel_pos, eX * panel_size.x + eY * fontsize.y, color, .2, DRAWFLAG_NORMAL);
 519
 520                         if(!mouseClicked && (prevMouseClicked & S_MOUSE1))
 521                                 QuickMenu_Page_ActiveEntry((entry_num < QUICKMENU_MAXLINES - 1) ? entry_num + 1 : 0);
 522                 }
 523         }
 524
 525         vector cursorsize = '32 32 0';
 526         drawpic(mousepos, strcat("gfx/menu/", autocvar_menu_skin, "/cursor.tga"), cursorsize, '1 1 1', 0.8, DRAWFLAG_NORMAL);
 527
 528         prevMouseClicked = mouseClicked;
 529 }
 530
 531 void HUD_Quickmenu_DrawEntry(vector pos, string desc, string option, vector fontsize)
 532 {
 533         string entry;
 534         float offset;
 535         float desc_width = panel_size.x;
 536         if(option)
 537         {
 538                 string pic = strcat(hud_skin_path, "/", option);
 539                 if(precache_pic(pic) == "")
 540                         pic = strcat("gfx/hud/default/", option);
 541                 vector option_size = '1 1 0' * fontsize.y * 0.8;
 542                 desc_width -= option_size.x;
 543                 drawpic(pos + eX * desc_width + eY * (fontsize.y - option_size.y) / 2, pic, option_size, '1 1 1', panel_fg_alpha, DRAWFLAG_ADDITIVE);
 544                 desc_width -= fontsize.x / 4;
 545         }
 546         entry = textShortenToWidth(desc, desc_width, fontsize, stringwidth_colors);
 547         if (autocvar_hud_panel_quickmenu_align > 0)
 548         {
 549                 float real_desc_width = stringwidth_colors(entry, fontsize);
 550                 offset = (desc_width - real_desc_width) * min(autocvar_hud_panel_quickmenu_align, 1);
 551
 552                 if(option)
 553                 {
 554                         // when there's enough room align description regardless the checkbox
 555                         float extra_offset = (panel_size.x - desc_width) * min(autocvar_hud_panel_quickmenu_align, 1);
 556                         if(offset + real_desc_width + extra_offset < desc_width)
 557                                 offset += extra_offset;
 558                         else
 559                                 offset = max(0, desc_width - real_desc_width);
 560                 }
 561                 drawcolorcodedstring(pos + eX * offset, entry, fontsize, panel_fg_alpha, DRAWFLAG_ADDITIVE);
 562         }
 563         else
 564                 drawcolorcodedstring(pos, entry, fontsize, panel_fg_alpha, DRAWFLAG_ADDITIVE);
 565 }
 566
 567 void HUD_QuickMenu(void)
 568 {
 569         if(!autocvar__hud_configure)
 570         {
 571                 if (hud_configure_prev && hud_configure_prev != -1)
 572                         QuickMenu_Close();
 573
 574                 if(!hud_draw_maximized) return;
 575                 if(mv_active) return;
 576                 //if(!autocvar_hud_panel_quickmenu) return;
 577                 if(!hud_panel_quickmenu) return;
 578
 579                 if(time > QuickMenu_TimeOut)
 580                 {
 581                         QuickMenu_Close();
 582                         return;
 583                 }
 584         }
 585         else
 586         {
 587                 if(!QuickMenu_IsOpened())
 588                 {
 589                         QuickMenu_Page_Entries = 1;
 590                         QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, sprintf(_("Submenu%d"), QuickMenu_Page_Entries), "");
 591                         ++QuickMenu_Page_Entries;
 592                         QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, sprintf(_("Submenu%d"), QuickMenu_Page_Entries), "");
 593                         ++QuickMenu_Page_Entries;
 594                         // although real command doesn't matter here, it must not be empty
 595                         // otherwise the entry is displayed like a submenu
 596                         for (; QuickMenu_Page_Entries < QUICKMENU_MAXLINES - 1; ++QuickMenu_Page_Entries)
 597                                 QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, sprintf(_("Command%d"), QuickMenu_Page_Entries), "-");
 598                         ++QuickMenu_Page_Entries;
 599                         QuickMenu_Page_ClearEntry(QuickMenu_Page_Entries);
 600                         QuickMenu_IsLastPage = false;
 601                 }
 602         }
 603
 604         HUD_Panel_UpdateCvars();
 605
 606         HUD_Panel_DrawBg(1);
 607
 608         if(panel_bg_padding)
 609         {
 610                 panel_pos += '1 1 0' * panel_bg_padding;
 611                 panel_size -= '2 2 0' * panel_bg_padding;
 612         }
 613
 614         int i;
 615         vector fontsize;
 616         string color;
 617         fontsize = '1 1 0' * (panel_size.y / QUICKMENU_MAXLINES);
 618
 619         if (!QuickMenu_IsLastPage)
 620         {
 621                 color = "^5";
 622                 HUD_Quickmenu_DrawEntry(panel_pos + eY * (panel_size.y - fontsize.y), sprintf("%d: %s%s", 0, color, _("Continue...")), string_null, fontsize);
 623         }
 624         else
 625                 panel_pos.y += ((QUICKMENU_MAXLINES - QuickMenu_Page_Entries) * fontsize.y) / 2;
 626
 627         for (i = 1; i <= QuickMenu_Page_Entries; ++i) {
 628                 if (QuickMenu_Page_Description[i] == "")
 629                         break;
 630                 string option = string_null;
 631                 if (QuickMenu_Page_Command[i] == "")
 632                         color = "^4";
 633                 else
 634                 {
 635                         color = "^3";
 636                         if(QuickMenu_Page_Command_Type[i] == 1) // toggle command
 637                         {
 638                                 int end = strstrofs(QuickMenu_Page_Command[i], ";", 0);
 639                                 if(end < 0)
 640                                         tokenize_console(QuickMenu_Page_Command[i]);
 641                                 else
 642                                         tokenize_console(substring(QuickMenu_Page_Command[i], 0, end));
 643
 644                                 //if(argv(1) && argv(0) == "toggle") // already checked
 645                                 {
 646                                         // "enable feature xxx" "toggle xxx" (or "toggle xxx 1 0")
 647                                         // "disable feature xxx" "toggle xxx 0 1"
 648                                         float ON_value = 1, OFF_value = 0;
 649                                         if(argv(2))
 650                                                 ON_value = stof(argv(2));
 651
 652                                         if(argv(3))
 653                                                 OFF_value = stof(argv(3));
 654                                         else
 655                                                 OFF_value = !ON_value;
 656
 657                                         float value = cvar(argv(1));
 658                                         if(value == ON_value)
 659                                                 option = "checkbox_checked";
 660                                         else if(value == OFF_value)
 661                                                 option = "checkbox_empty";
 662                                         else
 663                                                 option = "checkbox_undefined";
 664                                 }
 665                         }
 666                 }
 667                 HUD_Quickmenu_DrawEntry(panel_pos, sprintf("%d: %s%s", i, color, QuickMenu_Page_Description[i]), option, fontsize);
 668
 669                 if(QuickMenu_Page_ActivatedEntry_Time && time < QuickMenu_Page_ActivatedEntry_Time
 670                         && QuickMenu_Page_ActivatedEntry == i)
 671                         drawfill(panel_pos, eX * panel_size.x + eY * fontsize.y, '0.5 1 0.5', .2, DRAWFLAG_NORMAL);
 672
 673                 panel_pos.y += fontsize.y;
 674         }
 675
 676         if(QuickMenu_Page_ActivatedEntry >= 0 && time >= QuickMenu_Page_ActivatedEntry_Time)
 677         {
 678                 if(!QuickMenu_Page_Command[QuickMenu_Page_ActivatedEntry])
 679                 {
 680                         bool f = QuickMenu_ActionForNumber(QuickMenu_Page_ActivatedEntry);
 681                         if(f && QuickMenu_Page_ActivatedEntry_Close)
 682                                 QuickMenu_Close();
 683                 }
 684                 else if(QuickMenu_Page_ActivatedEntry_Close)
 685                         QuickMenu_Close();
 686                 QuickMenu_Page_ActivatedEntry = -1;
 687                 QuickMenu_Page_ActivatedEntry_Time = 0;
 688         }
 689 }
 690
 691
 692 #define QUICKMENU_SMENU(submenu,eng_submenu) { \
 693         if(target_submenu == eng_submenu && target_submenu_found) \
 694                 return; /* target_submenu entries are now loaded, exit */ \
 695         if(QuickMenu_Buffer_Size < QUICKMENU_BUFFER_MAXENTRIES) \
 696                 bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat("S", submenu)); \
 697         ++QuickMenu_Buffer_Size; \
 698         if(target_submenu == eng_submenu && !target_submenu_found) { \
 699                 QuickMenu_Buffer_Size = 0; /* enable load of next entries */ \
 700                 target_submenu_found = true; \
 701         } \
 702 }
 703
 704 #define QUICKMENU_ENTRY(title,command) { \
 705         if(QuickMenu_Buffer_Size + 1 < QUICKMENU_BUFFER_MAXENTRIES) \
 706         { \
 707                 bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat("T", title)); \
 708                 ++QuickMenu_Buffer_Size; \
 709                 bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat("C", command)); \
 710         } \
 711         ++QuickMenu_Buffer_Size; \
 712 }
 713
 714 #define QUICKMENU_SMENU_PL(submenu,eng_submenu,command,teamplayers,without_me) { \
 715         if(QuickMenu_Buffer_Size + 3 < QUICKMENU_BUFFER_MAXENTRIES) {\
 716                 QUICKMENU_SMENU(submenu,eng_submenu) \
 717                 bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat("T", ftos(teamplayers), ftos(without_me))); \
 718                 ++QuickMenu_Buffer_Size; \
 719                 bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat("P", command)); \
 720                 ++QuickMenu_Buffer_Size; \
 721                 QUICKMENU_SMENU(submenu,eng_submenu) \
 722         } \
 723 }
 724
 725
 726
 727 // useful to Translate a string inside the Command
 728 #define QUICKMENU_ENTRY_TC(title,command,text,translated_text) {\
 729         if(prvm_language == "en") \
 730                 QUICKMENU_ENTRY(title, sprintf(command, text)) \
 731         else if(!autocvar_hud_panel_quickmenu_translatecommands || translated_text == text) \
 732                 QUICKMENU_ENTRY(strcat("(en)", title), sprintf(command, text)) \
 733         else \
 734                 QUICKMENU_ENTRY(strcat("(", prvm_language, ")", title), sprintf(command, translated_text)) \
 735 }
 736
 737 void HUD_Quickmenu_PlayerListEntries(string cmd, float teamplayers, float without_me)
 738 {
 739         entity pl;
 740         if(teamplayers && !team_count)
 741                 return;
 742
 743         for(pl = players.sort_next; pl; pl = pl.sort_next)
 744         {
 745                 if(teamplayers == 1 && (pl.team != myteam || pl.team == NUM_SPECTATOR)) // only own team players
 746                         continue;
 747                 if(teamplayers == 2 && (pl.team == myteam || pl.team == NUM_SPECTATOR)) // only enemy team players
 748                         continue;
 749                 if(without_me && pl.sv_entnum == player_localnum)
 750                         continue;
 751                 QUICKMENU_ENTRY(GetPlayerName(pl.sv_entnum), sprintf(cmd, GetPlayerName(pl.sv_entnum)))
 752         }
 753
 754         return;
 755 }
 756
 757
 758 // Specifying target_submenu, this function only loads entries inside target_submenu
 759 // NOTE: alternatively we could have loaded the whole default quickmenu and
 760 // then called QuickMenu_Page_Load(target_submenu, 0);
 761 // but this sytem is more reliable since we can always refer to target_submenu
 762 // with the English title even if a translation is active
 763 void QuickMenu_Default(string target_submenu)
 764 {
 765         bool target_submenu_found = false;
 766         if(target_submenu != "")
 767                 QuickMenu_Buffer_Size = QUICKMENU_BUFFER_MAXENTRIES; // forbids load of next entries until target_submenu
 768
 769         QUICKMENU_SMENU(CTX(_("QMCMD^Chat")), "Chat")
 770                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^nice one")), "say %s", ":-) / nice one", CTX(_("QMCMD^:-) / nice one")))
 771                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^good game")), "say %s", "good game", CTX(_("QMCMD^good game")))
 772                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^hi / good luck")), "say %s", "hi / good luck and have fun", CTX(_("QMCMD^hi / good luck and have fun")))
 773         QUICKMENU_SMENU(CTX(_("QMCMD^Chat")), "Chat")
 774
 775         if(teamplay)
 776         {
 777         QUICKMENU_SMENU(CTX(_("QMCMD^Team chat")), "Team chat")
 778                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^quad soon")), "say_team %s", "quad soon", CTX(_("QMCMD^quad soon")))
 779                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^free item, icon")), "say_team %s; g_waypointsprite_team_here_p", "free item %x^7 (l:%y^7)", CTX(_("QMCMD^free item %x^7 (l:%y^7)")))
 780                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^took item, icon")), "say_team %s; g_waypointsprite_team_here", "took item (l:%l^7)", CTX(_("QMCMD^took item (l:%l^7)")))
 781                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^negative")), "say_team %s", "negative", CTX(_("QMCMD^negative")))
 782                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^positive")), "say_team %s", "positive", CTX(_("QMCMD^positive")))
 783                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^need help, icon")), "say_team %s; g_waypointsprite_team_helpme; cmd voice needhelp", "need help (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^need help (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 784                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^enemy seen, icon")), "say_team %s; g_waypointsprite_team_danger_p; cmd voice incoming", "enemy seen (l:%y^7)", CTX(_("QMCMD^enemy seen (l:%y^7)")))
 785                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^flag seen, icon")), "say_team %s; g_waypointsprite_team_here_p; cmd voice seenflag", "flag seen (l:%y^7)", CTX(_("QMCMD^flag seen (l:%y^7)")))
 786                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^defending, icon")), "say_team %s; g_waypointsprite_team_here", "defending (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^defending (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 787                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^roaming, icon")), "say_team %s; g_waypointsprite_team_here", "roaming (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^roaming (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 788                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^attacking, icon")), "say_team %s; g_waypointsprite_team_here", "attacking (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^attacking (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 789                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^killed flag, icon")), "say_team %s; g_waypointsprite_team_here_p", "killed flagcarrier (l:%y^7)", CTX(_("QMCMD^killed flagcarrier (l:%y^7)")))
 790                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^dropped flag, icon")), "say_team %s; g_waypointsprite_team_here_d", "dropped flag (l:%d^7)", CTX(_("QMCMD^dropped flag (l:%d^7)")))
 791                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^drop gun, icon")), "say_team %s; g_waypointsprite_team_here; wait; dropweapon", "dropped gun %w^7 (l:%l^7)", CTX(_("QMCMD^dropped gun %w^7 (l:%l^7)")))
 792                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^drop flag/key, icon")), "say_team %s; g_waypointsprite_team_here; wait; +use", "dropped flag/key %w^7 (l:%l^7)", CTX(_("QMCMD^dropped flag/key %w^7 (l:%l^7)")))
 793         QUICKMENU_SMENU(CTX(_("QMCMD^Team chat")), "Team chat")
 794         }
 795
 796         QUICKMENU_SMENU_PL(CTX(_("QMCMD^Send private message to")), "Send private message to", "commandmode tell \"%s^7\"", 0, 1)
 797
 798         QUICKMENU_SMENU(CTX(_("QMCMD^Settings")), "Settings")
 799                 QUICKMENU_SMENU(CTX(_("QMCMD^View/HUD settings")), "View/HUD settings")
 800                         QUICKMENU_ENTRY(CTX(_("QMCMD^3rd person view")), "toggle chase_active")
 801                         QUICKMENU_ENTRY(CTX(_("QMCMD^Player models like mine")), "toggle cl_forceplayermodels")
 802                         QUICKMENU_ENTRY(CTX(_("QMCMD^Names above players")), "toggle hud_shownames")
 803                         QUICKMENU_ENTRY(CTX(_("QMCMD^Crosshair per weapon")), "toggle crosshair_per_weapon")
 804                         QUICKMENU_ENTRY(CTX(_("QMCMD^FPS")), "toggle hud_panel_engineinfo")
 805                         QUICKMENU_ENTRY(CTX(_("QMCMD^Net graph")), "toggle shownetgraph")
 806                 QUICKMENU_SMENU(CTX(_("QMCMD^View/HUD settings")), "View/HUD settings")
 807
 808                 QUICKMENU_SMENU(CTX(_("QMCMD^Sound settings")), "Sound settings")
 809                         QUICKMENU_ENTRY(CTX(_("QMCMD^Hit sound")), "toggle cl_hitsound")
 810                         QUICKMENU_ENTRY(CTX(_("QMCMD^Chat sound")), "toggle con_chatsound")
 811                 QUICKMENU_SMENU(CTX(_("QMCMD^Sound settings")), "Sound settings")
 812
 813                 if(spectatee_status > 0)
 814                 {
 815                 QUICKMENU_SMENU(CTX(_("QMCMD^Spectator camera")), "Spectator camera")
 816                         QUICKMENU_ENTRY(CTX(_("QMCMD^1st person")), "chase_active 0; -use")
 817                         QUICKMENU_ENTRY(CTX(_("QMCMD^3rd person around player")), "chase_active 1; +use")
 818                         QUICKMENU_ENTRY(CTX(_("QMCMD^3rd person behind")), "chase_active 1; -use")
 819                 QUICKMENU_SMENU(CTX(_("QMCMD^Spectator camera")), "Spectator camera")
 820                 }
 821
 822                 if(spectatee_status == -1)
 823                 {
 824                 QUICKMENU_SMENU(CTX(_("QMCMD^Observer camera")), "Observer camera")
 825                         QUICKMENU_ENTRY(CTX(_("QMCMD^Increase speed")), "weapnext")
 826                         QUICKMENU_ENTRY(CTX(_("QMCMD^Decrease speed")), "weapprev")
 827                         QUICKMENU_ENTRY(CTX(_("QMCMD^Wall collision off")), "+use")
 828                         QUICKMENU_ENTRY(CTX(_("QMCMD^Wall collision on")), "-use")
 829                 QUICKMENU_SMENU(CTX(_("QMCMD^Observer camera")), "Observer camera")
 830                 }
 831
 832                 QUICKMENU_ENTRY(CTX(_("QMCMD^Fullscreen")), "toggle vid_fullscreen; vid_restart")
 833                 if(prvm_language != "en")
 834                 QUICKMENU_ENTRY(CTX(_("QMCMD^Translate chat messages")), "toggle hud_panel_quickmenu_translatecommands")
 835         QUICKMENU_SMENU(CTX(_("QMCMD^Settings")), "Settings")
 836
 837         QUICKMENU_SMENU(CTX(_("QMCMD^Call a vote")), "Call a vote")
 838                 QUICKMENU_ENTRY(CTX(_("QMCMD^Restart the map")), "vcall restart")
 839                 QUICKMENU_ENTRY(CTX(_("QMCMD^End match")), "vcall endmatch")
 840                 if(getstatf(STAT_TIMELIMIT) > 0)
 841                 {
 842                 QUICKMENU_ENTRY(CTX(_("QMCMD^Reduce match time")), "vcall reducematchtime")
 843                 QUICKMENU_ENTRY(CTX(_("QMCMD^Extend match time")), "vcall extendmatchtime")
 844                 }
 845                 if(teamplay)
 846                 QUICKMENU_ENTRY(CTX(_("QMCMD^Shuffle teams")), "vcall shuffleteams")
 847         QUICKMENU_SMENU(CTX(_("QMCMD^Call a vote")), "Call a vote")
 848
 849         if(target_submenu != "" && !target_submenu_found)
 850         {
 851                 printf("Couldn't find submenu \"%s\"\n", target_submenu);
 852                 if(prvm_language != "en")
 853                         printf("^3Warning: submenu must be in English\n", target_submenu);
 854                 QuickMenu_Buffer_Size = 0;
 855         }
 856 }
 857 #undef QUICKMENU_SMENU
 858 #undef QUICKMENU_ENTRY
 859 #undef QUICKMENU_ENTRY_TC