qcsrc/client/shownames.qc

   1 // self.isactive = player is in range and coordinates/status (health and armor) are up to date
   2 // self.origin = player origin TODO: should maybe move this so it's the origin of the shownames tag already in SSQC for culling?
   3 // self.healthvalue
   4 // self.armorvalue
   5 // self.sameteam = player is on same team as local client
   6 // self.fadedelay = time to wait before name tag starts fading in for enemies
   7 // self.pointtime = last time you pointed at this player
   8 //
   9 const float SHOWNAMES_FADESPEED = 4;
  10 const float SHOWNAMES_FADEDELAY = 0.4;
  11 void Draw_ShowNames(entity ent)
  12 {
  13         if(!autocvar_hud_shownames)
  14                 return;
  15
  16 #ifdef COMPAT_XON050_ENGINE
  17         if((ent.sv_entnum == player_localentnum) || (ent.sv_entnum == spectatee_status)) // ent is me or person i'm spectating
  18 #else
  19         if(ent.sv_entnum == player_localentnum) // ent is me or person i'm spectating
  20 #endif
  21                 if not (autocvar_hud_shownames_self && autocvar_chase_active)
  22                         return;
  23
  24         makevectors(view_angles);
  25
  26         if(ent.sameteam || (!ent.sameteam && autocvar_hud_shownames_enemies))
  27         {
  28                 ent.origin_z += autocvar_hud_shownames_offset;
  29
  30                 float hit;
  31                 if(ent.sameteam && !autocvar_hud_shownames_crosshairdistance)
  32                 {
  33                         hit = 1;
  34                 }
  35                 else
  36                 {
  37                         traceline(view_origin, ent.origin, MOVE_NORMAL, ent);
  38                         if(trace_fraction < 1 && trace_networkentity != ent.sv_entnum)
  39                                 hit = 0;
  40                         else
  41                                 hit = 1;
  42                 }
  43
  44                 // handle tag fading
  45                 float overlap, onscreen, crosshairdistance;
  46                 vector o, eo;
  47
  48                 o = project_3d_to_2d(ent.origin);
  49
  50                 if(autocvar_hud_shownames_antioverlap)
  51                 {
  52                         // fade tag out if another tag that is closer to you overlaps
  53                         entity e;
  54                         for(e = world; (e = find(e, classname, "shownames_tag")); )
  55                         {
  56                                 if(e == ent)
  57                                         continue;
  58                                 eo = project_3d_to_2d(e.origin);
  59                                 if not(eo_z < 0 || eo_x < 0 || eo_y < 0 || eo_x > vid_conwidth || eo_y > vid_conheight)
  60                                 {
  61                                         eo_z = 0;
  62                                         if(vlen((eX * o_x + eY * o_y) - eo) < autocvar_hud_shownames_antioverlap_distance && vlen(ent.origin - view_origin) > vlen(e.origin - view_origin))
  63                                         {
  64                                                 overlap = TRUE;
  65                                                 break;
  66                                         }
  67                                 }
  68                         }
  69                 }
  70
  71                 onscreen = (o_z >= 0 && o_x >= 0 && o_y >= 0 && o_x <= vid_conwidth && o_y <= vid_conheight);
  72                 crosshairdistance = sqrt( pow(o_x - vid_conwidth/2, 2) + pow(o_y - vid_conheight/2, 2) );
  73
  74                 if(autocvar_hud_shownames_crosshairdistance)
  75                 {
  76                         if(autocvar_hud_shownames_crosshairdistance > crosshairdistance)
  77                                 ent.pointtime = time;
  78
  79                         if not(ent.pointtime + autocvar_hud_shownames_crosshairdistance_time > time)
  80                                 overlap = TRUE;
  81                         else
  82                                 overlap = (autocvar_hud_shownames_crosshairdistance_antioverlap ? overlap : FALSE); // override what antioverlap says unless allowed by cvar.
  83                 }
  84
  85                 if(!ent.fadedelay)
  86                         ent.fadedelay = time + SHOWNAMES_FADEDELAY;
  87
  88                 if(!ent.sameteam && (!onscreen || !hit)) // out of view, fade out
  89                 {
  90                         ent.alpha = max(0, ent.alpha - SHOWNAMES_FADESPEED * frametime);
  91                         ent.fadedelay = 0; // reset fade in delay, enemy has left the view
  92                 }
  93                 else if(ent.healthvalue < 1) // dead player, fade out slowly
  94                         ent.alpha = max(0, ent.alpha - SHOWNAMES_FADESPEED * 0.25 * frametime);
  95                 else if(overlap) // tag overlap detected, fade out
  96                         ent.alpha = max(0, ent.alpha - SHOWNAMES_FADESPEED * frametime);
  97                 else if(ent.sameteam) // fade in for team mates
  98                         ent.alpha = min(1, ent.alpha + SHOWNAMES_FADESPEED * frametime);
  99                 else if(time > ent.fadedelay) // fade in for enemies
 100                         ent.alpha = min(1, ent.alpha + SHOWNAMES_FADESPEED * frametime);
 101
 102                 if(!ent.alpha)
 103                         return;
 104
 105                 float dist;
 106                 dist = vlen(ent.origin - view_origin);
 107
 108                 float a;
 109                 a = autocvar_hud_shownames_alpha;
 110                 a *= ent.alpha;
 111                 if(autocvar_hud_shownames_maxdistance)
 112                 {
 113                         if(dist >= autocvar_hud_shownames_maxdistance)
 114                                 return;
 115                         a *= ((autocvar_hud_shownames_maxdistance - autocvar_hud_shownames_mindistance) - max(0, dist - autocvar_hud_shownames_mindistance)) / (autocvar_hud_shownames_maxdistance - autocvar_hud_shownames_mindistance);
 116                 }
 117
 118                 if(!a)
 119                         return;
 120
 121                 float resize;
 122                 resize = 1;
 123                 if(autocvar_hud_shownames_resize) // limit resize so its never smaller than 0.5... gets unreadable
 124                         resize = 0.5 + 0.5 * ((autocvar_hud_shownames_maxdistance - autocvar_hud_shownames_mindistance) - max(0, dist - autocvar_hud_shownames_mindistance)) / (autocvar_hud_shownames_maxdistance - autocvar_hud_shownames_mindistance);
 125
 126                 // draw the sprite image
 127                 if(o_z >= 0)
 128                 {
 129                         o_z = 0;
 130
 131                         vector myPos, mySize;
 132                         mySize = (eX * autocvar_hud_shownames_aspect + eY) * autocvar_hud_shownames_fontsize;
 133                         myPos = o - '0.5 0 0' * mySize_x - '0 1 0' * mySize_y;
 134
 135                         // size scaling
 136                         mySize_x *= resize;
 137                         mySize_y *= resize;
 138
 139                         myPos_x += 0.5 * (mySize_x / resize - mySize_x);
 140                         myPos_y += (mySize_y / resize - mySize_y);
 141
 142                         vector namepos; // this is where the origin of the string
 143                         float namewidth;
 144
 145                         namepos = myPos;
 146                         namewidth = mySize_x;
 147
 148                         if(autocvar_hud_shownames_status && teamplay)
 149                         {
 150                                 if(ent.sameteam)
 151                                 {
 152                                         if(ent.healthvalue > 0)
 153                                         {
 154                                                 HUD_Panel_DrawProgressBar(namepos + '0 1 0' * autocvar_hud_shownames_fontsize * resize, eX * 0.5 * mySize_x + eY * resize * autocvar_hud_shownames_statusbar_height, "nametag_statusbar", ent.healthvalue/autocvar_hud_panel_healtharmor_maxhealth, 0, 1, '1 0 0', a, DRAWFLAG_NORMAL);
 155
 156                                                 if(ent.armorvalue > 0)
 157                                                         HUD_Panel_DrawProgressBar(namepos + '0 1 0' * autocvar_hud_shownames_fontsize * resize + eX * 0.5 * mySize_x, eX * 0.5 * mySize_x + eY * resize * autocvar_hud_shownames_statusbar_height, "nametag_statusbar", ent.armorvalue/autocvar_hud_panel_healtharmor_maxarmor, 0, 0, '0 1 0', a, DRAWFLAG_NORMAL);
 158                                         }
 159                                 }
 160                         }
 161
 162                         string s;
 163                         s = GetPlayerName(ent.sv_entnum-1);
 164                         if((autocvar_hud_shownames_decolorize == 1 && teamplay) || autocvar_hud_shownames_decolorize == 2)
 165                                 s = playername(s, GetPlayerColor(ent.sv_entnum-1));
 166
 167                         drawfontscale = '1 1 0' * resize;
 168                         s = textShortenToWidth(s, namewidth, '1 1 0' * autocvar_hud_shownames_fontsize, stringwidth_colors);
 169
 170                         float width;
 171                         width = stringwidth(s, TRUE, '1 1 0' * autocvar_hud_shownames_fontsize);
 172
 173                         if (width != namewidth)
 174                                 namepos_x += (namewidth - width) / 2;
 175                         drawcolorcodedstring(namepos, s, '1 1 0' * autocvar_hud_shownames_fontsize, a, DRAWFLAG_NORMAL);
 176                         drawfontscale = '1 1 0';
 177                 }
 178         }
 179 }
 180
 181 entity shownames_ent[255];
 182 void Draw_ShowNames_All()
 183 {
 184         float i;
 185         for(i = 0; i < maxclients; ++i)
 186         {
 187                 float t;
 188                 t = GetPlayerColor(i);
 189                 if(t == COLOR_SPECTATOR)
 190                         continue;
 191
 192                 entity e;
 193                 e = shownames_ent[i];
 194                 if(!e)
 195                 {
 196                         e = spawn();
 197                         e.classname = "shownames_tag";
 198                         e.sv_entnum = i+1;
 199                         shownames_ent[i] = e;
 200                 }
 201
 202                 entity entcs;
 203                 entcs = entcs_receiver[i];
 204                 if(entcs)
 205                 {
 206                         e.healthvalue = entcs.healthvalue;
 207                         e.armorvalue = entcs.armorvalue;
 208                         e.sameteam = 1; /* (teamplay && (t == myteam)); */
 209                 }
 210                 else
 211                 {
 212                         e.healthvalue = 2342;
 213                         e.armorvalue = 0;
 214                         e.sameteam = 0;
 215                 }
 216
 217                 e.origin = getplayerorigin(i);
 218                 if(e.origin == GETPLAYERORIGIN_ERROR)
 219                         continue;
 220
 221                 Draw_ShowNames(e);
 222         }
 223 }