qcsrc/client/view.qc

   1
   2 #include "announcer.qh"
   3 #include "hook.qh"
   4 #include "hud.qh"
   5 #include "hud_config.qh"
   6 #include "mapvoting.qh"
   7 #include "scoreboard.qh"
   8 #include "shownames.qh"
   9 #include "quickmenu.qh"
  10
  11 #include "mutators/events.qh"
  12
  13 #include "../common/anim.qh"
  14 #include "../common/constants.qh"
  15 #include "../common/mapinfo.qh"
  16 #include "../common/gamemodes/all.qh"
  17 #include "../common/nades/all.qh"
  18 #include "../common/stats.qh"
  19 #include "../common/triggers/target/music.qh"
  20 #include "../common/teams.qh"
  21
  22 #include "../common/vehicles/all.qh"
  23 #include "../common/weapons/all.qh"
  24 #include "../common/viewloc.qh"
  25 #include "../common/minigames/cl_minigames.qh"
  26 #include "../common/minigames/cl_minigames_hud.qh"
  27
  28 #include "../lib/csqcmodel/cl_player.qh"
  29
  30 #include "../lib/warpzone/client.qh"
  31 #include "../lib/warpzone/common.qh"
  32
  33 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
  34
  35 void viewmodel_draw(entity this)
  36 {
  37         int mask = (intermission || (getstati(STAT_HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
  38         float a = this.alpha;
  39         int c = stof(getplayerkeyvalue(current_player, "colors"));
  40         vector g = this.glowmod; // TODO: completely clientside: colormapPaletteColor(c & 0x0F, true) * 2;
  41         entity me = CSQCModel_server2csqc(player_localentnum);
  42         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
  43                 | EF_NODEPTHTEST)
  44                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
  45         for (entity e = this; e; e = e.weaponchild)
  46         {
  47                 e.drawmask = mask;
  48                 e.alpha = a;
  49                 e.colormap = c;
  50                 e.glowmod = g;
  51                 e.csqcmodel_effects = fx;
  52                 WITH(entity, self, e, CSQCModel_Effects_Apply());
  53         }
  54         {
  55                 static string name_last;
  56                 string name = get_weaponinfo(activeweapon).mdl;
  57                 if (name != name_last)
  58                 {
  59                         name_last = name;
  60                         CL_WeaponEntity_SetModel(this, name);
  61                         updateanim(this);
  62                         if (!this.animstate_override)
  63                                 setanim(this, this.anim_idle, true, false, false);
  64                 }
  65         }
  66         float eta = (getstatf(STAT_WEAPON_NEXTTHINK) - time); // TODO: / W_WeaponRateFactor();
  67         float f = 0; // 0..1; 0: fully active
  68         switch (this.state)
  69         {
  70                 case WS_RAISE:
  71                 {
  72                         // entity newwep = Weapons_from(activeweapon);
  73                         float delay = 0.2; // TODO: newwep.switchdelay_raise;
  74                         f = eta / max(eta, delay);
  75                         this.angles_x = -90 * f * f;
  76                         break;
  77                 }
  78                 case WS_DROP:
  79                 {
  80                         // entity oldwep = Weapons_from(activeweapon);
  81                         float delay = 0.2; // TODO: newwep.switchdelay_drop;
  82                         f = 1 - eta / max(eta, delay);
  83                         this.angles_x = -90 * f * f;
  84                         break;
  85                 }
  86                 case WS_CLEAR:
  87                 {
  88                         f = 1;
  89                         break;
  90                 }
  91         }
  92         this.angles_x = -90 * f * f;
  93 }
  94
  95 entity viewmodel;
  96 STATIC_INIT(viewmodel) {
  97     viewmodel = new(viewmodel);
  98         viewmodel.draw = viewmodel_draw;
  99 }
 100
 101 entity porto;
 102 vector polyline[16];
 103 void Porto_Draw(entity this)
 104 {
 105         vector p, dir, ang, q, nextdir;
 106         float portal_number, portal1_idx;
 107
 108         if(activeweapon != WEP_PORTO.m_id || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
 109                 return;
 110         if(g_balance_porto_secondary)
 111                 return;
 112         if(intermission == 1)
 113                 return;
 114         if(intermission == 2)
 115                 return;
 116         if (getstati(STAT_HEALTH) <= 0)
 117                 return;
 118
 119         dir = view_forward;
 120
 121         if(angles_held_status)
 122         {
 123                 makevectors(angles_held);
 124                 dir = v_forward;
 125         }
 126
 127         p = view_origin;
 128
 129         polyline[0] = p;
 130         int idx = 1;
 131         portal_number = 0;
 132         nextdir = dir;
 133
 134         for (;;)
 135         {
 136                 dir = nextdir;
 137                 traceline(p, p + 65536 * dir, true, porto);
 138                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 139                         return;
 140                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
 141                 p = trace_endpos;
 142                 polyline[idx] = p;
 143                 ++idx;
 144                 if(idx >= 16)
 145                         return;
 146                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 147                         continue;
 148                 ++portal_number;
 149                 ang = vectoangles2(trace_plane_normal, dir);
 150                 ang.x = -ang.x;
 151                 makevectors(ang);
 152                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 153                         return;
 154                 if(portal_number == 1)
 155                 {
 156                         portal1_idx = idx;
 157                         if(portal_number >= 2)
 158                                 break;
 159                 }
 160         }
 161
 162         while(idx >= 2)
 163         {
 164                 p = polyline[idx-2];
 165                 q = polyline[idx-1];
 166                 if(idx == 2)
 167                         p = p - view_up * 16;
 168                 if(idx-1 >= portal1_idx)
 169                 {
 170                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
 171                 }
 172                 else
 173                 {
 174                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
 175                 }
 176                 --idx;
 177         }
 178 }
 179
 180 void Porto_Init()
 181 {
 182         porto = spawn();
 183         porto.classname = "porto";
 184         porto.draw = Porto_Draw;
 185         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 186 }
 187
 188 float drawtime;
 189 float avgspeed;
 190 vector GetCurrentFov(float fov)
 191 {
 192         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 193         float velocityzoom, curspeed;
 194         vector v;
 195
 196         zoomsensitivity = autocvar_cl_zoomsensitivity;
 197         zoomfactor = autocvar_cl_zoomfactor;
 198         if(zoomfactor < 1 || zoomfactor > 30)
 199                 zoomfactor = 2.5;
 200         zoomspeed = autocvar_cl_zoomspeed;
 201         if(zoomspeed >= 0)
 202         if(zoomspeed < 0.5 || zoomspeed > 16)
 203                         zoomspeed = 3.5;
 204
 205         zoomdir = button_zoom;
 206         if(hud == HUD_NORMAL)
 207         if(switchweapon == activeweapon)
 208         if((activeweapon == WEP_VORTEX.m_id && vortex_scope) || (activeweapon == WEP_RIFLE.m_id && rifle_scope)) // do NOT use switchweapon here
 209                 zoomdir += button_attack2;
 210         if(spectatee_status > 0 || isdemo())
 211         {
 212                 if(spectatorbutton_zoom)
 213                 {
 214                         if(zoomdir)
 215                                 zoomdir = 0;
 216                         else
 217                                 zoomdir = 1;
 218                 }
 219                 // fteqcc failed twice here already, don't optimize this
 220         }
 221
 222         if(zoomdir) { zoomin_effect = 0; }
 223
 224         if(camera_active)
 225         {
 226                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 227         }
 228         else if(autocvar_cl_spawnzoom && zoomin_effect)
 229         {
 230                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 231
 232                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 233                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 234                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 235         }
 236         else
 237         {
 238                 if(zoomspeed < 0) // instant zoom
 239                 {
 240                         if(zoomdir)
 241                                 current_viewzoom = 1 / zoomfactor;
 242                         else
 243                                 current_viewzoom = 1;
 244                 }
 245                 else
 246                 {
 247                         if(zoomdir)
 248                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 249                         else
 250                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 251                 }
 252         }
 253
 254         if(almost_equals(current_viewzoom, 1))
 255                 current_zoomfraction = 0;
 256         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 257                 current_zoomfraction = 1;
 258         else
 259                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 260
 261         if(zoomsensitivity < 1)
 262                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 263         else
 264                 setsensitivityscale(1);
 265
 266         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 267         {
 268                 if(intermission) { curspeed = 0; }
 269                 else
 270                 {
 271
 272                         makevectors(view_angles);
 273                         v = pmove_vel;
 274                         if(csqcplayer)
 275                                 v = csqcplayer.velocity;
 276
 277                         switch(autocvar_cl_velocityzoom_type)
 278                         {
 279                                 case 3: curspeed = max(0, v_forward * v); break;
 280                                 case 2: curspeed = (v_forward * v); break;
 281                                 case 1: default: curspeed = vlen(v); break;
 282                         }
 283                 }
 284
 285                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 286                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 287                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 288
 289                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 290         }
 291         else
 292                 velocityzoom = 1;
 293
 294         float frustumx, frustumy, fovx, fovy;
 295         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 296         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 297         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 298         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 299
 300         return '1 0 0' * fovx + '0 1 0' * fovy;
 301 }
 302
 303 vector GetViewLocationFOV(float fov)
 304 {
 305         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 306         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 307         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 308         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 309         return '1 0 0' * fovx + '0 1 0' * fovy;
 310 }
 311
 312 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 313 {
 314         float fovx, fovy;
 315         float width = (ov_worldmax.x - ov_worldmin.x);
 316         float height = (ov_worldmax.y - ov_worldmin.y);
 317         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 318         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 319         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 320         return '1 0 0' * fovx + '0 1 0' * fovy;
 321 }
 322
 323 // this function must match W_SetupShot!
 324 float zoomscript_caught;
 325
 326 vector wcross_origin;
 327 float wcross_scale_prev, wcross_alpha_prev;
 328 vector wcross_color_prev;
 329 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 330 vector wcross_color_goal_prev;
 331 float wcross_changedonetime;
 332
 333 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 334 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 335 float wcross_name_changestarttime, wcross_name_changedonetime;
 336 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 337
 338 float wcross_ring_prev;
 339
 340 entity trueaim;
 341 entity trueaim_rifle;
 342
 343 const float SHOTTYPE_HITTEAM = 1;
 344 const float SHOTTYPE_HITOBSTRUCTION = 2;
 345 const float SHOTTYPE_HITWORLD = 3;
 346 const float SHOTTYPE_HITENEMY = 4;
 347
 348 void TrueAim_Init()
 349 {
 350         trueaim = spawn();
 351         trueaim.classname = "trueaim";
 352         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 353         trueaim_rifle = spawn();
 354         trueaim_rifle.classname = "trueaim_rifle";
 355         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 356 }
 357
 358 float EnemyHitCheck()
 359 {
 360         float t, n;
 361         wcross_origin = project_3d_to_2d(trace_endpos);
 362         wcross_origin.z = 0;
 363         if(trace_ent)
 364                 n = trace_ent.entnum;
 365         else
 366                 n = trace_networkentity;
 367         if(n < 1)
 368                 return SHOTTYPE_HITWORLD;
 369         if(n > maxclients)
 370                 return SHOTTYPE_HITWORLD;
 371         t = GetPlayerColor(n - 1);
 372         if(teamplay)
 373                 if(t == myteam)
 374                         return SHOTTYPE_HITTEAM;
 375         if(t == NUM_SPECTATOR)
 376                 return SHOTTYPE_HITWORLD;
 377         return SHOTTYPE_HITENEMY;
 378 }
 379
 380 float TrueAimCheck()
 381 {
 382         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 383         vector vecs, trueaimpoint, w_shotorg;
 384         vector mi, ma, dv;
 385         float shottype;
 386         entity ta;
 387         float mv;
 388
 389         mi = ma = '0 0 0';
 390         ta = trueaim;
 391         mv = MOVE_NOMONSTERS;
 392
 393         switch(activeweapon) // WEAPONTODO
 394         {
 395                 case WEP_TUBA.m_id: // no aim
 396                 case WEP_PORTO.m_id: // shoots from eye
 397                 case WEP_NEXBALL.m_id: // shoots from eye
 398                 case WEP_HOOK.m_id: // no trueaim
 399                 case WEP_MORTAR.m_id: // toss curve
 400                         return SHOTTYPE_HITWORLD;
 401                 case WEP_VORTEX.m_id:
 402                 case WEP_VAPORIZER.m_id:
 403                         mv = MOVE_NORMAL;
 404                         break;
 405                 case WEP_RIFLE.m_id:
 406                         ta = trueaim_rifle;
 407                         mv = MOVE_NORMAL;
 408                         if(zoomscript_caught)
 409                         {
 410                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 411                                 return EnemyHitCheck();
 412                         }
 413                         break;
 414                 case WEP_DEVASTATOR.m_id: // projectile has a size!
 415                         mi = '-3 -3 -3';
 416                         ma = '3 3 3';
 417                         break;
 418                 case WEP_FIREBALL.m_id: // projectile has a size!
 419                         mi = '-16 -16 -16';
 420                         ma = '16 16 16';
 421                         break;
 422                 case WEP_SEEKER.m_id: // projectile has a size!
 423                         mi = '-2 -2 -2';
 424                         ma = '2 2 2';
 425                         break;
 426                 case WEP_ELECTRO.m_id: // projectile has a size!
 427                         mi = '0 0 -3';
 428                         ma = '0 0 -3';
 429                         break;
 430         }
 431
 432         vector traceorigin = getplayerorigin(player_localentnum-1) + (eZ * getstati(STAT_VIEWHEIGHT));
 433
 434         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 435
 436         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 437         trueaimpoint = trace_endpos;
 438
 439         if(vlen(trueaimpoint - traceorigin) < g_trueaim_minrange)
 440                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 441
 442         if(vecs.x > 0)
 443                 vecs.y = -vecs.y;
 444         else
 445                 vecs = '0 0 0';
 446
 447         dv = view_right * vecs.y + view_up * vecs.z;
 448         w_shotorg = traceorigin + dv;
 449
 450         // now move the vecs forward as much as requested if possible
 451         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 452         w_shotorg = trace_endpos - view_forward * nudge;
 453
 454         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 455         shottype = EnemyHitCheck();
 456         if(shottype != SHOTTYPE_HITWORLD)
 457                 return shottype;
 458
 459 #if 0
 460         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 461         // or rather, I know why, but see no fix
 462         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 463                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 464                 return SHOTTYPE_HITOBSTRUCTION;
 465 #endif
 466
 467         return SHOTTYPE_HITWORLD;
 468 }
 469
 470 void PostInit(void);
 471 void CSQC_Demo_Camera();
 472 float HUD_WouldDrawScoreboard();
 473 float camera_mode;
 474 const float CAMERA_FREE = 1;
 475 const float CAMERA_CHASE = 2;
 476 float reticle_type;
 477 string reticle_image;
 478 string NextFrameCommand;
 479
 480 vector freeze_org, freeze_ang;
 481 entity nightvision_noise, nightvision_noise2;
 482
 483 const float MAX_TIME_DIFF = 5;
 484 float pickup_crosshair_time, pickup_crosshair_size;
 485 float hitindication_crosshair_size;
 486 float use_vortex_chargepool;
 487
 488 float myhealth, myhealth_prev;
 489 float myhealth_flash;
 490
 491 float old_blurradius, old_bluralpha;
 492 float old_sharpen_intensity;
 493
 494 vector myhealth_gentlergb;
 495
 496 float contentavgalpha, liquidalpha_prev;
 497 vector liquidcolor_prev;
 498
 499 float eventchase_current_distance;
 500 float eventchase_running;
 501 bool WantEventchase()
 502 {SELFPARAM();
 503         if(autocvar_cl_orthoview)
 504                 return false;
 505         if(intermission)
 506                 return true;
 507         if(self.viewloc)
 508                 return true;
 509         if(spectatee_status >= 0)
 510         {
 511                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 512                         return true;
 513                 if(MUTATOR_CALLHOOK(WantEventchase, self))
 514                         return true;
 515                 if(autocvar_cl_eventchase_nexball && gametype == MAPINFO_TYPE_NEXBALL && !(WepSet_GetFromStat() & WepSet_FromWeapon(WEP_NEXBALL.m_id)))
 516                         return true;
 517                 if(autocvar_cl_eventchase_death && (getstati(STAT_HEALTH) <= 0))
 518                 {
 519                         if(autocvar_cl_eventchase_death == 2)
 520                         {
 521                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 522                                 if(self.velocity == '0 0 0' || eventchase_running)
 523                                         return true;
 524                         }
 525                         else return true;
 526                 }
 527         }
 528         return false;
 529 }
 530
 531 void HUD_Crosshair_Vehicle()
 532 {
 533         if(hud != HUD_BUMBLEBEE_GUN)
 534         {
 535                 Vehicle info = get_vehicleinfo(hud);
 536                 info.vr_crosshair(info);
 537         }
 538 }
 539
 540 vector damage_blurpostprocess, content_blurpostprocess;
 541
 542 float unaccounted_damage = 0;
 543 void UpdateDamage()
 544 {
 545         // accumulate damage with each stat update
 546         static float damage_total_prev = 0;
 547         float damage_total = getstati(STAT_DAMAGE_DEALT_TOTAL);
 548         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 549         damage_total_prev = damage_total;
 550
 551         static float damage_dealt_time_prev = 0;
 552         float damage_dealt_time = getstatf(STAT_HIT_TIME);
 553         if (damage_dealt_time != damage_dealt_time_prev)
 554         {
 555                 unaccounted_damage += unaccounted_damage_new;
 556                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")", "\n");
 557         }
 558         damage_dealt_time_prev = damage_dealt_time;
 559
 560         // prevent hitsound when switching spectatee
 561         static float spectatee_status_prev = 0;
 562         if (spectatee_status != spectatee_status_prev)
 563                 unaccounted_damage = 0;
 564         spectatee_status_prev = spectatee_status;
 565 }
 566
 567 void HitSound()
 568 {
 569         // varying sound pitch
 570
 571         static float hitsound_time_prev = 0;
 572         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 573         float arc_hack = activeweapon == WEP_ARC.m_id && autocvar_cl_hitsound >= 2;
 574         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 575         {
 576                 if (autocvar_cl_hitsound && unaccounted_damage)
 577                 {
 578                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 579                         float a = autocvar_cl_hitsound_max_pitch;
 580                         float b = autocvar_cl_hitsound_min_pitch;
 581                         float c = autocvar_cl_hitsound_nom_damage;
 582                         float x = unaccounted_damage;
 583                         float pitch_shift = (b*x*(a-1) + a*c*(1-b)) / (x*(a-1) + c*(1-b));
 584
 585                         // if sound variation is disabled, set pitch_shift to 1
 586                         if (autocvar_cl_hitsound == 1)
 587                                 pitch_shift = 1;
 588
 589                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 590                         if (autocvar_cl_hitsound == 3)
 591                         {
 592                                 float mirror_value = (a-b)/2 + b;
 593                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 594                         }
 595
 596                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift), "\n");
 597
 598                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 599                         // todo: normalize sound pressure levels? seems unnecessary
 600
 601                         sound7(world, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 602                 }
 603                 unaccounted_damage = 0;
 604                 hitsound_time_prev = time;
 605         }
 606
 607         static float typehit_time_prev = 0;
 608         float typehit_time = getstatf(STAT_TYPEHIT_TIME);
 609         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 610         {
 611                 sound(world, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 612                 typehit_time_prev = typehit_time;
 613         }
 614 }
 615
 616 void HUD_Crosshair()
 617 {SELFPARAM();
 618         static float rainbow_last_flicker;
 619         static vector rainbow_prev_color;
 620         entity e = self;
 621         float f, i, j;
 622         vector v;
 623         if(!scoreboard_active && !camera_active && intermission != 2 &&
 624                 spectatee_status != -1 && !csqcplayer.viewloc &&
 625                 !HUD_MinigameMenu_IsOpened() )
 626         {
 627                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 628                         return;
 629
 630                 if (hud != HUD_NORMAL)
 631                 {
 632                         HUD_Crosshair_Vehicle();
 633                         return;
 634                 }
 635
 636                 string wcross_style;
 637                 float wcross_alpha, wcross_resolution;
 638                 wcross_style = autocvar_crosshair;
 639                 if (wcross_style == "0")
 640                         return;
 641                 wcross_resolution = autocvar_crosshair_size;
 642                 if (wcross_resolution == 0)
 643                         return;
 644                 wcross_alpha = autocvar_crosshair_alpha;
 645                 if (wcross_alpha == 0)
 646                         return;
 647
 648                 // TrueAim check
 649                 float shottype;
 650
 651                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 652                 wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 653                 wcross_origin.z = 0;
 654                 if(autocvar_crosshair_hittest)
 655                 {
 656                         vector wcross_oldorigin;
 657                         wcross_oldorigin = wcross_origin;
 658                         shottype = TrueAimCheck();
 659                         if(shottype == SHOTTYPE_HITWORLD)
 660                         {
 661                                 v = wcross_origin - wcross_oldorigin;
 662                                 v.x /= vid_conwidth;
 663                                 v.y /= vid_conheight;
 664                                 if(vlen(v) > 0.01)
 665                                         shottype = SHOTTYPE_HITOBSTRUCTION;
 666                         }
 667                         if(!autocvar_crosshair_hittest_showimpact)
 668                                 wcross_origin = wcross_oldorigin;
 669                 }
 670                 else
 671                         shottype = SHOTTYPE_HITWORLD;
 672
 673                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
 674                 string wcross_name = "";
 675                 float wcross_scale, wcross_blur;
 676
 677                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
 678                 {
 679                         e = get_weaponinfo(switchingweapon);
 680                         if(e)
 681                         {
 682                                 if(autocvar_crosshair_per_weapon)
 683                                 {
 684                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
 685                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 686                                         //if (wcross_resolution == 0)
 687                                                 //return;
 688
 689                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 690                                         wcross_resolution *= e.w_crosshair_size;
 691                                         wcross_name = e.w_crosshair;
 692                                 }
 693                         }
 694                 }
 695
 696                 if(wcross_name == "")
 697                         wcross_name = strcat("gfx/crosshair", wcross_style);
 698
 699                 // MAIN CROSSHAIR COLOR DECISION
 700                 switch(autocvar_crosshair_color_special)
 701                 {
 702                         case 1: // crosshair_color_per_weapon
 703                         {
 704                                 if(e)
 705                                 {
 706                                         wcross_color = e.wpcolor;
 707                                         break;
 708                                 }
 709                                 else { goto normalcolor; }
 710                         }
 711
 712                         case 2: // crosshair_color_by_health
 713                         {
 714                                 float x = getstati(STAT_HEALTH);
 715
 716                                 //x = red
 717                                 //y = green
 718                                 //z = blue
 719
 720                                 wcross_color.z = 0;
 721
 722                                 if(x > 200)
 723                                 {
 724                                         wcross_color.x = 0;
 725                                         wcross_color.y = 1;
 726                                 }
 727                                 else if(x > 150)
 728                                 {
 729                                         wcross_color.x = 0.4 - (x-150)*0.02 * 0.4;
 730                                         wcross_color.y = 0.9 + (x-150)*0.02 * 0.1;
 731                                 }
 732                                 else if(x > 100)
 733                                 {
 734                                         wcross_color.x = 1 - (x-100)*0.02 * 0.6;
 735                                         wcross_color.y = 1 - (x-100)*0.02 * 0.1;
 736                                         wcross_color.z = 1 - (x-100)*0.02;
 737                                 }
 738                                 else if(x > 50)
 739                                 {
 740                                         wcross_color.x = 1;
 741                                         wcross_color.y = 1;
 742                                         wcross_color.z = 0.2 + (x-50)*0.02 * 0.8;
 743                                 }
 744                                 else if(x > 20)
 745                                 {
 746                                         wcross_color.x = 1;
 747                                         wcross_color.y = (x-20)*90/27/100;
 748                                         wcross_color.z = (x-20)*90/27/100 * 0.2;
 749                                 }
 750                                 else
 751                                 {
 752                                         wcross_color.x = 1;
 753                                         wcross_color.y = 0;
 754                                 }
 755                                 break;
 756                         }
 757
 758                         case 3: // crosshair_color_rainbow
 759                         {
 760                                 if(time >= rainbow_last_flicker)
 761                                 {
 762                                         rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
 763                                         rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
 764                                 }
 765                                 wcross_color = rainbow_prev_color;
 766                                 break;
 767                         }
 768                         :normalcolor
 769                         default: { wcross_color = stov(autocvar_crosshair_color); break; }
 770                 }
 771
 772                 if(autocvar_crosshair_effect_scalefade)
 773                 {
 774                         wcross_scale = wcross_resolution;
 775                         wcross_resolution = 1;
 776                 }
 777                 else
 778                 {
 779                         wcross_scale = 1;
 780                 }
 781
 782                 if(autocvar_crosshair_pickup)
 783                 {
 784                         float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
 785
 786                         if(pickup_crosshair_time < stat_pickup_time)
 787                         {
 788                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
 789                                         pickup_crosshair_size = 1;
 790
 791                                 pickup_crosshair_time = stat_pickup_time;
 792                         }
 793
 794                         if(pickup_crosshair_size > 0)
 795                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
 796                         else
 797                                 pickup_crosshair_size = 0;
 798
 799                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
 800                 }
 801
 802                 // todo: make crosshair hit indication dependent on damage dealt
 803                 if(autocvar_crosshair_hitindication)
 804                 {
 805                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
 806
 807                         if(unaccounted_damage)
 808                         {
 809                                 hitindication_crosshair_size = 1;
 810                         }
 811
 812                         if(hitindication_crosshair_size > 0)
 813                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
 814                         else
 815                                 hitindication_crosshair_size = 0;
 816
 817                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
 818                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
 819                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
 820                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
 821                 }
 822
 823                 if(shottype == SHOTTYPE_HITENEMY)
 824                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
 825                 if(shottype == SHOTTYPE_HITTEAM)
 826                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
 827
 828                 f = fabs(autocvar_crosshair_effect_time);
 829                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
 830                 {
 831                         wcross_changedonetime = time + f;
 832                 }
 833                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
 834                 {
 835                         wcross_name_changestarttime = time;
 836                         wcross_name_changedonetime = time + f;
 837                         if(wcross_name_goal_prev_prev)
 838                                 strunzone(wcross_name_goal_prev_prev);
 839                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
 840                         wcross_name_goal_prev = strzone(wcross_name);
 841                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
 842                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
 843                         wcross_resolution_goal_prev = wcross_resolution;
 844                 }
 845
 846                 wcross_scale_goal_prev = wcross_scale;
 847                 wcross_alpha_goal_prev = wcross_alpha;
 848                 wcross_color_goal_prev = wcross_color;
 849
 850                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
 851                 {
 852                         wcross_blur = 1;
 853                         wcross_alpha *= 0.75;
 854                 }
 855                 else
 856                         wcross_blur = 0;
 857                 // *_prev is at time-frametime
 858                 // * is at wcross_changedonetime+f
 859                 // what do we have at time?
 860                 if(time < wcross_changedonetime)
 861                 {
 862                         f = frametime / (wcross_changedonetime - time + frametime);
 863                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
 864                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
 865                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
 866                 }
 867
 868                 wcross_scale_prev = wcross_scale;
 869                 wcross_alpha_prev = wcross_alpha;
 870                 wcross_color_prev = wcross_color;
 871
 872                 MUTATOR_CALLHOOK(UpdateCrosshair);
 873
 874                 wcross_scale *= 1 - autocvar__menu_alpha;
 875                 wcross_alpha *= 1 - autocvar__menu_alpha;
 876                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
 877
 878                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
 879                 {
 880                         // crosshair rings for weapon stats
 881                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
 882                         {
 883                                 // declarations and stats
 884                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
 885                                 string ring_image = string_null, ring_inner_image = string_null;
 886                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
 887
 888                                 ring_scale = autocvar_crosshair_ring_size;
 889
 890                                 float weapon_clipload, weapon_clipsize;
 891                                 weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
 892                                 weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
 893
 894                                 float ok_ammo_charge, ok_ammo_chargepool;
 895                                 ok_ammo_charge = getstatf(STAT_OK_AMMO_CHARGE);
 896                                 ok_ammo_chargepool = getstatf(STAT_OK_AMMO_CHARGEPOOL);
 897
 898                                 float vortex_charge, vortex_chargepool;
 899                                 vortex_charge = getstatf(STAT_VORTEX_CHARGE);
 900                                 vortex_chargepool = getstatf(STAT_VORTEX_CHARGEPOOL);
 901
 902                                 float arc_heat = getstatf(STAT_ARC_HEAT);
 903
 904                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
 905                                         vortex_charge_movingavg = vortex_charge;
 906
 907
 908                                 // handle the values
 909                                 if (autocvar_crosshair_ring && activeweapon == WEP_VORTEX.m_id && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
 910                                 {
 911                                         if (vortex_chargepool || use_vortex_chargepool) {
 912                                                 use_vortex_chargepool = 1;
 913                                                 ring_inner_value = vortex_chargepool;
 914                                         } else {
 915                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
 916                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
 917                                         }
 918
 919                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
 920                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
 921                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
 922
 923                                         // draw the outer ring to show the current charge of the weapon
 924                                         ring_value = vortex_charge;
 925                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
 926                                         ring_rgb = wcross_color;
 927                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
 928                                 }
 929                                 else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER.m_id && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
 930                                 {
 931                                         ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
 932                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
 933                                         ring_rgb = wcross_color;
 934                                         ring_image = "gfx/crosshair_ring.tga";
 935                                 }
 936                                 else if (activeweapon == WEP_HAGAR.m_id && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
 937                                 {
 938                                         ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
 939                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
 940                                         ring_rgb = wcross_color;
 941                                         ring_image = "gfx/crosshair_ring.tga";
 942                                 }
 943                                 else if (ok_ammo_charge)
 944                                 {
 945                                         ring_value = ok_ammo_chargepool;
 946                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
 947                                         ring_rgb = wcross_color;
 948                                         ring_image = "gfx/crosshair_ring.tga";
 949                                 }
 950                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
 951                                 {
 952                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
 953                                         ring_scale = autocvar_crosshair_ring_reload_size;
 954                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
 955                                         ring_rgb = wcross_color;
 956
 957                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
 958                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
 959                                         if ((activeweapon == WEP_RIFLE.m_id) && (weapon_clipsize == 80))
 960                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
 961                                         else
 962                                                 ring_image = "gfx/crosshair_ring.tga";
 963                                 }
 964                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && activeweapon == WEP_ARC.m_id )
 965                                 {
 966                                         ring_value = arc_heat;
 967                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
 968                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
 969                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
 970                                         ring_image = "gfx/crosshair_ring.tga";
 971                                 }
 972
 973                                 // if in weapon switch animation, fade ring out/in
 974                                 if(autocvar_crosshair_effect_time > 0)
 975                                 {
 976                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
 977                                         if (f >= 1)
 978                                         {
 979                                                 wcross_ring_prev = ((ring_image) ? true : false);
 980                                         }
 981
 982                                         if(wcross_ring_prev)
 983                                         {
 984                                                 if(f < 1)
 985                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
 986                                         }
 987                                         else
 988                                         {
 989                                                 if(f < 1)
 990                                                         ring_alpha *= bound(0, f, 1);
 991                                         }
 992                                 }
 993
 994                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
 995                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
 996
 997                                 if (ring_value)
 998                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
 999                         }
1000
1001 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1002                         do \
1003                         { \
1004                                 if(wcross_blur > 0) \
1005                                 { \
1006                                         for(i = -2; i <= 2; ++i) \
1007                                         for(j = -2; j <= 2; ++j) \
1008                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1009                                 } \
1010                                 else \
1011                                 { \
1012                                         M(0,0,sz,wcross_name,wcross_alpha); \
1013                                 } \
1014                         } \
1015                         while(0)
1016
1017 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1018                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1019
1020 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1021                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1022
1023                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1024                         {
1025                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1026                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1027                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1028                                 f = 1 - f;
1029                         }
1030                         else
1031                         {
1032                                 f = 1;
1033                         }
1034                         wcross_name_alpha_goal_prev = f;
1035
1036                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1037                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1038
1039                         if(autocvar_crosshair_dot)
1040                         {
1041                                 vector wcross_color_old;
1042                                 wcross_color_old = wcross_color;
1043
1044                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1045                                         wcross_color = stov(autocvar_crosshair_dot_color);
1046
1047                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1048                                 // FIXME why don't we use wcross_alpha here?cl_notice_run();
1049                                 wcross_color = wcross_color_old;
1050                         }
1051                 }
1052         }
1053         else
1054         {
1055                 wcross_scale_prev = 0;
1056                 wcross_alpha_prev = 0;
1057                 wcross_scale_goal_prev = 0;
1058                 wcross_alpha_goal_prev = 0;
1059                 wcross_changedonetime = 0;
1060                 if(wcross_name_goal_prev)
1061                         strunzone(wcross_name_goal_prev);
1062                 wcross_name_goal_prev = string_null;
1063                 if(wcross_name_goal_prev_prev)
1064                         strunzone(wcross_name_goal_prev_prev);
1065                 wcross_name_goal_prev_prev = string_null;
1066                 wcross_name_changestarttime = 0;
1067                 wcross_name_changedonetime = 0;
1068                 wcross_name_alpha_goal_prev = 0;
1069                 wcross_name_alpha_goal_prev_prev = 0;
1070                 wcross_resolution_goal_prev = 0;
1071                 wcross_resolution_goal_prev_prev = 0;
1072         }
1073 }
1074
1075 void HUD_Draw()
1076 {
1077         if(getstati(STAT_FROZEN))
1078                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, ((getstatf(STAT_REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * getstatf(STAT_REVIVE_PROGRESS)) + ('0 1 1' * getstatf(STAT_REVIVE_PROGRESS) * -1)) : '0.25 0.90 1'), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1079         else if (getstatf(STAT_HEALING_ORB)>time)
1080                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, NADE_TYPE_HEAL.m_color, autocvar_hud_colorflash_alpha*getstatf(STAT_HEALING_ORB_ALPHA), DRAWFLAG_ADDITIVE);
1081         if(!intermission)
1082         if(getstatf(STAT_NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1083         {
1084                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * getstatf(STAT_NADE_TIMER)) - ('0 1 1' * getstatf(STAT_NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1085                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1086         }
1087         else if(getstatf(STAT_REVIVE_PROGRESS))
1088         {
1089                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1090                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1091         }
1092
1093         if(autocvar_r_letterbox == 0)
1094                 if(autocvar_viewsize < 120)
1095                 {
1096                         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1097                                 Accuracy_LoadLevels();
1098
1099                         HUD_Main();
1100                         HUD_DrawScoreboard();
1101                 }
1102
1103         // crosshair goes VERY LAST
1104         UpdateDamage();
1105         HUD_Crosshair();
1106         HitSound();
1107 }
1108
1109 bool ov_enabled;
1110 float oldr_nearclip;
1111 float oldr_farclip_base;
1112 float oldr_farclip_world;
1113 float oldr_novis;
1114 float oldr_useportalculling;
1115 float oldr_useinfinitefarclip;
1116
1117 const int BUTTON_3 = 4;
1118 const int BUTTON_4 = 8;
1119 float cl_notice_run();
1120 float prev_myteam;
1121 int lasthud;
1122 float vh_notice_time;
1123 void WaypointSprite_Load();
1124 void CSQC_UpdateView(float w, float h)
1125 {SELFPARAM();
1126         entity e;
1127         float fov;
1128         float f;
1129         vector vf_size, vf_min;
1130         float a;
1131
1132         execute_next_frame();
1133
1134         ++framecount;
1135
1136         hud = getstati(STAT_HUD);
1137
1138         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1139                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1140
1141         lasthud = hud;
1142
1143         if(autocvar__hud_showbinds_reload) // menu can set this one
1144         {
1145                 db_close(binddb);
1146                 binddb = db_create();
1147                 cvar_set("_hud_showbinds_reload", "0");
1148         }
1149
1150         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1151                 view_quality = getproperty(VF_MINFPS_QUALITY);
1152         else
1153                 view_quality = 1;
1154
1155         button_attack2 = (input_buttons & BUTTON_3);
1156         button_zoom = (input_buttons & BUTTON_4);
1157
1158         vf_size = getpropertyvec(VF_SIZE);
1159         vf_min = getpropertyvec(VF_MIN);
1160         vid_width = vf_size.x;
1161         vid_height = vf_size.y;
1162
1163         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1164         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1165
1166         WaypointSprite_Load();
1167
1168         CSQCPlayer_SetCamera();
1169
1170         if(player_localentnum <= maxclients) // is it a client?
1171                 current_player = player_localentnum - 1;
1172         else // then player_localentnum is the vehicle I'm driving
1173                 current_player = player_localnum;
1174         myteam = GetPlayerColor(current_player);
1175
1176         if(myteam != prev_myteam)
1177         {
1178                 myteamcolors = colormapPaletteColor(myteam, 1);
1179                 FOREACH(hud_panels, true, LAMBDA(it.update_time = time));
1180                 prev_myteam = myteam;
1181         }
1182
1183         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
1184
1185         float is_dead = (getstati(STAT_HEALTH) <= 0);
1186
1187         // FIXME do we need this hack?
1188         if(isdemo())
1189         {
1190                 // in demos, input_buttons do not work
1191                 button_zoom = (autocvar__togglezoom == "-");
1192         }
1193         else if(button_zoom
1194                 && autocvar_cl_unpress_zoom_on_death
1195                 && (spectatee_status >= 0)
1196                 && (is_dead || intermission))
1197         {
1198                 // no zoom while dead or in intermission please
1199                 localcmd("-zoom\n");
1200                 button_zoom = false;
1201         }
1202
1203         // event chase camera
1204         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1205         {
1206                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1207                 float ons_roundlost = (gametype == MAPINFO_TYPE_ONSLAUGHT && getstati(STAT_ROUNDLOST));
1208                 entity gen = world;
1209
1210                 if(ons_roundlost)
1211                 {
1212                         entity e;
1213                         for(e = world; (e = find(e, classname, "onslaught_generator")); )
1214                         {
1215                                 if(e.health <= 0)
1216                                 {
1217                                         gen = e;
1218                                         break;
1219                                 }
1220                         }
1221                         if(!gen)
1222                                 ons_roundlost = FALSE; // don't enforce the 3rd person camera if there is no dead generator to show
1223                 }
1224                 if(WantEventchase() || (!autocvar_cl_orthoview && ons_roundlost))
1225                 {
1226                         eventchase_running = true;
1227
1228                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1229                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1230                         if(ons_roundlost) { current_view_origin = gen.origin; }
1231
1232                         // detect maximum viewoffset and use it
1233                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1234                         if(vehicle_chase && autocvar_cl_eventchase_vehicle_viewoffset) { view_offset = autocvar_cl_eventchase_vehicle_viewoffset; }
1235                         if(ons_roundlost) { view_offset = autocvar_cl_eventchase_generator_viewoffset; }
1236
1237                         if(view_offset)
1238                         {
1239                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, self);
1240                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1241                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1242                         }
1243
1244                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1245                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1246                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1247                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1248
1249                         // make the camera smooth back
1250                         float chase_distance = autocvar_cl_eventchase_distance;
1251                         if(vehicle_chase && autocvar_cl_eventchase_vehicle_distance) { chase_distance = autocvar_cl_eventchase_vehicle_distance; }
1252                         if(ons_roundlost) { chase_distance = autocvar_cl_eventchase_generator_distance; }
1253
1254                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1255                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1256                         else if(eventchase_current_distance != chase_distance)
1257                                 eventchase_current_distance = chase_distance;
1258
1259                         makevectors(view_angles);
1260
1261                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1262                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
1263
1264                         // If the boxtrace fails, revert back to line tracing.
1265                         if(!self.viewloc)
1266                         if(trace_startsolid)
1267                         {
1268                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1269                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
1270                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1271                         }
1272                         else { setproperty(VF_ORIGIN, trace_endpos); }
1273
1274                         if(!self.viewloc)
1275                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1276                 }
1277                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1278                 {
1279                         eventchase_running = false;
1280                         cvar_set("chase_active", "0");
1281                         eventchase_current_distance = 0; // start from 0 next time
1282                 }
1283         }
1284         // workaround for camera stuck between player's legs when using chase_active 1
1285         // because the engine stops updating the chase_active camera when the game ends
1286         else if(intermission)
1287         {
1288                 cvar_settemp("chase_active", "-1");
1289                 eventchase_current_distance = 0;
1290         }
1291
1292         // do lockview after event chase camera so that it still applies whenever necessary.
1293         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1294         {
1295                 setproperty(VF_ORIGIN, freeze_org);
1296                 setproperty(VF_ANGLES, freeze_ang);
1297         }
1298         else
1299         {
1300                 freeze_org = getpropertyvec(VF_ORIGIN);
1301                 freeze_ang = getpropertyvec(VF_ANGLES);
1302         }
1303
1304         WarpZone_FixView();
1305         //WarpZone_FixPMove();
1306
1307         vector ov_org = '0 0 0';
1308         vector ov_mid = '0 0 0';
1309         vector ov_worldmin = '0 0 0';
1310         vector ov_worldmax = '0 0 0';
1311         if(autocvar_cl_orthoview)
1312         {
1313                 ov_worldmin = mi_picmin;
1314                 ov_worldmax = mi_picmax;
1315
1316                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1317                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1318                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1319
1320                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1321                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1322
1323                 float ov_nearest = vlen(ov_org - vec3(
1324                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1325                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1326                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1327                 ));
1328
1329                 float ov_furthest = 0;
1330                 float dist = 0;
1331
1332                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1333                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1334                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1335                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1336                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1337                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1338                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1339                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1340
1341                 if(!ov_enabled)
1342                 {
1343                         oldr_nearclip = cvar("r_nearclip");
1344                         oldr_farclip_base = cvar("r_farclip_base");
1345                         oldr_farclip_world = cvar("r_farclip_world");
1346                         oldr_novis = cvar("r_novis");
1347                         oldr_useportalculling = cvar("r_useportalculling");
1348                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1349                 }
1350
1351                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1352                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1353                 cvar_settemp("r_farclip_world", "0");
1354                 cvar_settemp("r_novis", "1");
1355                 cvar_settemp("r_useportalculling", "0");
1356                 cvar_settemp("r_useinfinitefarclip", "0");
1357
1358                 setproperty(VF_ORIGIN, ov_org);
1359                 setproperty(VF_ANGLES, '90 0 0');
1360
1361                 ov_enabled = true;
1362
1363                 #if 0
1364                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1365                         vtos(ov_org),
1366                         vtos(getpropertyvec(VF_ANGLES)),
1367                         ov_distance,
1368                         ov_nearest,
1369                         ov_furthest);
1370                 #endif
1371         }
1372         else
1373         {
1374                 if(ov_enabled)
1375                 {
1376                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1377                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1378                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1379                         cvar_set("r_novis", ftos(oldr_novis));
1380                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1381                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1382                 }
1383                 ov_enabled = false;
1384         }
1385
1386         // Render the Scene
1387         view_origin = getpropertyvec(VF_ORIGIN);
1388         view_angles = getpropertyvec(VF_ANGLES);
1389         makevectors(view_angles);
1390         view_forward = v_forward;
1391         view_right = v_right;
1392         view_up = v_up;
1393
1394 #ifdef BLURTEST
1395         if(time > blurtest_time0 && time < blurtest_time1)
1396         {
1397                 float r, t;
1398
1399                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1400                 r = t * blurtest_radius;
1401                 f = 1 / pow(t, blurtest_power) - 1;
1402
1403                 cvar_set("r_glsl_postprocess", "1");
1404                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1405         }
1406         else
1407         {
1408                 cvar_set("r_glsl_postprocess", "0");
1409                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1410         }
1411 #endif
1412
1413         TargetMusic_Advance();
1414         Fog_Force();
1415
1416         if(drawtime == 0)
1417                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1418         else
1419                 drawframetime = bound(0.000001, time - drawtime, 1);
1420         drawtime = time;
1421
1422         // watch for gametype changes here...
1423         // in ParseStuffCMD the cmd isn't executed yet :/
1424         // might even be better to add the gametype to TE_CSQC_INIT...?
1425         if(!postinit)
1426                 PostInit();
1427
1428         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1429         {
1430                 if(calledhooks & HOOK_START)
1431                 {
1432                         localcmd("\ncl_hook_gameend\n");
1433                         calledhooks |= HOOK_END;
1434                 }
1435         }
1436
1437         Announcer();
1438
1439         fov = autocvar_fov;
1440         if(fov <= 59.5)
1441         {
1442                 if(!zoomscript_caught)
1443                 {
1444                         localcmd("+button9\n");
1445                         zoomscript_caught = 1;
1446                 }
1447         }
1448         else
1449         {
1450                 if(zoomscript_caught)
1451                 {
1452                         localcmd("-button9\n");
1453                         zoomscript_caught = 0;
1454                 }
1455         }
1456
1457         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1458
1459         // next WANTED weapon (for HUD)
1460         switchweapon = getstati(STAT_SWITCHWEAPON);
1461
1462         // currently switching-to weapon (for crosshair)
1463         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
1464
1465         // actually active weapon (for zoom)
1466         activeweapon = getstati(STAT_ACTIVEWEAPON);
1467
1468         f = (serverflags & SERVERFLAG_TEAMPLAY);
1469         if(f != teamplay)
1470         {
1471                 teamplay = f;
1472                 HUD_InitScores();
1473         }
1474
1475         if(last_switchweapon != switchweapon)
1476         {
1477                 weapontime = time;
1478                 last_switchweapon = switchweapon;
1479                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1480                 {
1481                         localcmd("-zoom\n");
1482                         button_zoom = false;
1483                 }
1484                 if(autocvar_cl_unpress_attack_on_weapon_switch)
1485                 {
1486                         localcmd("-fire\n");
1487                         localcmd("-fire2\n");
1488                         button_attack2 = false;
1489                 }
1490         }
1491         if(last_activeweapon != activeweapon)
1492         {
1493                 last_activeweapon = activeweapon;
1494
1495                 e = get_weaponinfo(activeweapon);
1496                 if(e.netname != "")
1497                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1498                 else
1499                         localcmd("\ncl_hook_activeweapon none\n");
1500         }
1501
1502         // ALWAYS Clear Current Scene First
1503         clearscene();
1504
1505         setproperty(VF_ORIGIN, view_origin);
1506         setproperty(VF_ANGLES, view_angles);
1507
1508         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1509         setproperty(VF_SIZE, vf_size);
1510         setproperty(VF_MIN, vf_min);
1511
1512         // Assign Standard Viewflags
1513         // Draw the World (and sky)
1514         setproperty(VF_DRAWWORLD, 1);
1515
1516         // Set the console size vars
1517         vid_conwidth = autocvar_vid_conwidth;
1518         vid_conheight = autocvar_vid_conheight;
1519         vid_pixelheight = autocvar_vid_pixelheight;
1520
1521         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1522         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1523         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1524
1525         // Camera for demo playback
1526         if(camera_active)
1527         {
1528                 if(autocvar_camera_enable)
1529                         CSQC_Demo_Camera();
1530                 else
1531                 {
1532                         cvar_set("chase_active", ftos(chase_active_backup));
1533                         cvar_set("cl_demo_mousegrab", "0");
1534                         camera_active = false;
1535                 }
1536         }
1537         else
1538         {
1539 #ifdef CAMERATEST
1540                 if(autocvar_camera_enable)
1541 #else
1542                 if(autocvar_camera_enable && isdemo())
1543 #endif
1544                 {
1545                         // Enable required Darkplaces cvars
1546                         chase_active_backup = autocvar_chase_active;
1547                         cvar_set("chase_active", "2");
1548                         cvar_set("cl_demo_mousegrab", "1");
1549                         camera_active = true;
1550                         camera_mode = false;
1551                 }
1552         }
1553
1554         // Draw the Crosshair
1555         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1556
1557         // Draw the Engine Status Bar (the default Quake HUD)
1558         setproperty(VF_DRAWENGINESBAR, 0);
1559
1560         // Update the mouse position
1561         /*
1562            mousepos_x = vid_conwidth;
1563            mousepos_y = vid_conheight;
1564            mousepos = mousepos*0.5 + getmousepos();
1565          */
1566
1567         for(entity e = NULL; (e = nextent(e)); ) if (e.draw) {
1568                 WITH(entity, self, e, e.draw(e));
1569         }
1570
1571         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1572         renderscene();
1573
1574         // now switch to 2D drawing mode by calling a 2D drawing function
1575         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1576         // next R_RenderScene call
1577         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1578
1579         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1580         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1581         {
1582                 // apply night vision effect
1583                 vector tc_00, tc_01, tc_10, tc_11;
1584                 vector rgb = '0 0 0';
1585
1586                 if(!nightvision_noise)
1587                 {
1588                         nightvision_noise = spawn();
1589                         nightvision_noise.classname = "nightvision_noise";
1590                 }
1591                 if(!nightvision_noise2)
1592                 {
1593                         nightvision_noise2 = spawn();
1594                         nightvision_noise2.classname = "nightvision_noise2";
1595                 }
1596
1597                 // color tint in yellow
1598                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1599
1600                 // draw BG
1601                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1602                 rgb = '1 1 1';
1603                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1604                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1605                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1606                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1607                 tc_11 = tc_01 + tc_10 - tc_00;
1608                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1609                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1610                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1611                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1612                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1613                 R_EndPolygon();
1614
1615                 // draw FG
1616                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1617                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1618                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1619                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1620                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1621                 tc_11 = tc_01 + tc_10 - tc_00;
1622                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1623                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1624                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1625                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1626                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1627                 R_EndPolygon();
1628         }
1629
1630         if(autocvar_cl_reticle)
1631         {
1632                 Weapon wep = get_weaponinfo(activeweapon);
1633                 // Draw the aiming reticle for weapons that use it
1634                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
1635                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
1636                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
1637                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
1638                 {
1639                         // no zoom reticle while dead
1640                         reticle_type = 0;
1641                 }
1642                 else if(wep.wr_zoomreticle(wep) && autocvar_cl_reticle_weapon)
1643                 {
1644                         if(reticle_image != "") { reticle_type = 2; }
1645                         else { reticle_type = 0; }
1646                 }
1647                 else if(button_zoom || zoomscript_caught)
1648                 {
1649                         // normal zoom
1650                         reticle_type = 1;
1651                 }
1652
1653                 if(reticle_type)
1654                 {
1655                         if(autocvar_cl_reticle_stretch)
1656                         {
1657                                 reticle_size.x = vid_conwidth;
1658                                 reticle_size.y = vid_conheight;
1659                                 reticle_pos.x = 0;
1660                                 reticle_pos.y = 0;
1661                         }
1662                         else
1663                         {
1664                                 reticle_size.x = max(vid_conwidth, vid_conheight);
1665                                 reticle_size.y = max(vid_conwidth, vid_conheight);
1666                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
1667                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
1668                         }
1669
1670                         if(zoomscript_caught)
1671                                 f = 1;
1672                         else
1673                                 f = current_zoomfraction;
1674
1675                         if(f)
1676                         {
1677                                 switch(reticle_type)
1678                                 {
1679                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
1680                                         case 2: drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
1681                                 }
1682                         }
1683                 }
1684         }
1685         else
1686         {
1687                 if(reticle_type != 0) { reticle_type = 0; }
1688         }
1689
1690
1691         // improved polyblend
1692         if(autocvar_hud_contents)
1693         {
1694                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
1695                 vector liquidcolor;
1696
1697                 switch(pointcontents(view_origin))
1698                 {
1699                         case CONTENT_WATER:
1700                                 liquidalpha = autocvar_hud_contents_water_alpha;
1701                                 liquidcolor = stov(autocvar_hud_contents_water_color);
1702                                 incontent = 1;
1703                                 break;
1704
1705                         case CONTENT_LAVA:
1706                                 liquidalpha = autocvar_hud_contents_lava_alpha;
1707                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
1708                                 incontent = 1;
1709                                 break;
1710
1711                         case CONTENT_SLIME:
1712                                 liquidalpha = autocvar_hud_contents_slime_alpha;
1713                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
1714                                 incontent = 1;
1715                                 break;
1716
1717                         default:
1718                                 liquidalpha = 0;
1719                                 liquidcolor = '0 0 0';
1720                                 incontent = 0;
1721                                 break;
1722                 }
1723
1724                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
1725                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
1726                         contentfadetime = autocvar_hud_contents_fadeintime;
1727                         liquidalpha_prev = liquidalpha;
1728                         liquidcolor_prev = liquidcolor;
1729                 }
1730                 else
1731                         contentfadetime = autocvar_hud_contents_fadeouttime;
1732
1733                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
1734                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
1735
1736                 if(contentavgalpha)
1737                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
1738
1739                 if(autocvar_hud_postprocessing)
1740                 {
1741                         if(autocvar_hud_contents_blur && contentavgalpha)
1742                         {
1743                                 content_blurpostprocess.x = 1;
1744                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
1745                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
1746                         }
1747                         else
1748                         {
1749                                 content_blurpostprocess.x = 0;
1750                                 content_blurpostprocess.y = 0;
1751                                 content_blurpostprocess.z = 0;
1752                         }
1753                 }
1754         }
1755
1756         if(autocvar_hud_damage && !getstati(STAT_FROZEN))
1757         {
1758                 splash_size.x = max(vid_conwidth, vid_conheight);
1759                 splash_size.y = max(vid_conwidth, vid_conheight);
1760                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
1761                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
1762
1763                 float myhealth_flash_temp;
1764                 myhealth = getstati(STAT_HEALTH);
1765
1766                 // fade out
1767                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
1768                 // add new damage
1769                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
1770
1771                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
1772                 pain_threshold = autocvar_hud_damage_pain_threshold;
1773                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
1774                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
1775
1776                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
1777                 {
1778                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
1779                 }
1780
1781                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
1782
1783                 if(myhealth_prev < 1)
1784                 {
1785                         if(myhealth >= 1)
1786                         {
1787                                 myhealth_flash = 0; // just spawned, clear the flash immediately
1788                                 myhealth_flash_temp = 0;
1789                         }
1790                         else
1791                         {
1792                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
1793                         }
1794                 }
1795
1796                 if(spectatee_status == -1 || intermission)
1797                 {
1798                         myhealth_flash = 0; // observing, or match ended
1799                         myhealth_flash_temp = 0;
1800                 }
1801
1802                 myhealth_prev = myhealth;
1803
1804                 // IDEA: change damage color/picture based on player model for robot/alien species?
1805                 // pro: matches model better
1806                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
1807                 // maybe different reddish pics?
1808                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
1809                 {
1810                         if(autocvar_cl_gentle_damage == 2)
1811                         {
1812                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
1813                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
1814                         }
1815                         else
1816                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
1817
1818                         if(myhealth_flash_temp > 0)
1819                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1820                 }
1821                 else if(myhealth_flash_temp > 0)
1822                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1823
1824                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
1825                 {
1826                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
1827                         {
1828                                 damage_blurpostprocess.x = 1;
1829                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
1830                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
1831                         }
1832                         else
1833                         {
1834                                 damage_blurpostprocess.x = 0;
1835                                 damage_blurpostprocess.y = 0;
1836                                 damage_blurpostprocess.z = 0;
1837                         }
1838                 }
1839         }
1840
1841         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
1842         float e2 = (autocvar_hud_powerup != 0);
1843         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
1844         {
1845                 // enable or disable rendering types if they are used or not
1846                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
1847                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
1848
1849                 // blur postprocess handling done first (used by hud_damage and hud_contents)
1850                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
1851                 {
1852                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
1853                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
1854                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
1855                         {
1856                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
1857                                 old_blurradius = blurradius;
1858                                 old_bluralpha = bluralpha;
1859                         }
1860                 }
1861                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
1862                 {
1863                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1864                         old_blurradius = 0;
1865                         old_bluralpha = 0;
1866                 }
1867
1868                 // edge detection postprocess handling done second (used by hud_powerup)
1869                 float sharpen_intensity = 0, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
1870                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
1871                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
1872
1873                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
1874
1875                 if(autocvar_hud_powerup && sharpen_intensity > 0)
1876                 {
1877                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
1878                         {
1879                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
1880                                 old_sharpen_intensity = sharpen_intensity;
1881                         }
1882                 }
1883                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
1884                 {
1885                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
1886                         old_sharpen_intensity = 0;
1887                 }
1888
1889                 if(cvar("r_glsl_postprocess") == 0)
1890                         cvar_set("r_glsl_postprocess", "2");
1891         }
1892         else if(cvar("r_glsl_postprocess") == 2)
1893                 cvar_set("r_glsl_postprocess", "0");
1894
1895         if(menu_visible)
1896                 menu_show();
1897
1898         /*if(gametype == MAPINFO_TYPE_CTF)
1899           {
1900           ctf_view();
1901           } else */
1902
1903         // draw 2D entities
1904         for (entity e = NULL; (e = nextent(e)); ) if (e.draw2d) {
1905                 WITH(entity, self, e, e.draw2d(e));
1906         }
1907         Draw_ShowNames_All();
1908
1909         scoreboard_active = HUD_WouldDrawScoreboard();
1910
1911         HUD_Draw();
1912
1913         if(NextFrameCommand)
1914         {
1915                 localcmd("\n", NextFrameCommand, "\n");
1916                 NextFrameCommand = string_null;
1917         }
1918
1919         // we must do this check AFTER a frame was rendered, or it won't work
1920         if(cs_project_is_b0rked == 0)
1921         {
1922                 string w0, h0;
1923                 w0 = ftos(autocvar_vid_conwidth);
1924                 h0 = ftos(autocvar_vid_conheight);
1925                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1926                 //setproperty(VF_FOV, '90 90 0');
1927                 setproperty(VF_ORIGIN, '0 0 0');
1928                 setproperty(VF_ANGLES, '0 0 0');
1929                 setproperty(VF_PERSPECTIVE, 1);
1930                 makevectors('0 0 0');
1931                 vector v1, v2;
1932                 cvar_set("vid_conwidth", "800");
1933                 cvar_set("vid_conheight", "600");
1934                 v1 = cs_project(v_forward);
1935                 cvar_set("vid_conwidth", "640");
1936                 cvar_set("vid_conheight", "480");
1937                 v2 = cs_project(v_forward);
1938                 if(v1 == v2)
1939                         cs_project_is_b0rked = 1;
1940                 else
1941                         cs_project_is_b0rked = -1;
1942                 cvar_set("vid_conwidth", w0);
1943                 cvar_set("vid_conheight", h0);
1944         }
1945
1946         if(autocvar__hud_configure)
1947                 HUD_Panel_Mouse();
1948         else if ( HUD_MinigameMenu_IsOpened() || minigame_isactive() )
1949                 HUD_Minigame_Mouse();
1950         else if(QuickMenu_IsOpened())
1951                 QuickMenu_Mouse();
1952         else
1953                 HUD_Radar_Mouse();
1954
1955         cl_notice_run();
1956
1957         // let's reset the view back to normal for the end
1958         setproperty(VF_MIN, '0 0 0');
1959         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1960 }
1961
1962
1963 // following vectors must be global to allow seamless switching between camera modes
1964 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1965 void CSQC_Demo_Camera()
1966 {
1967         float speed, attenuation, dimensions;
1968         vector tmp, delta;
1969
1970         if( autocvar_camera_reset || !camera_mode )
1971         {
1972                 camera_offset = '0 0 0';
1973                 current_angles = '0 0 0';
1974                 camera_direction = '0 0 0';
1975                 camera_offset.z += 30;
1976                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
1977                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
1978                 current_origin = view_origin;
1979                 current_camera_offset  = camera_offset;
1980                 cvar_set("camera_reset", "0");
1981                 camera_mode = CAMERA_CHASE;
1982         }
1983
1984         // Camera angles
1985         if( camera_roll )
1986                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
1987
1988         if(autocvar_camera_look_player)
1989         {
1990                 vector dir;
1991                 float n;
1992
1993                 dir = normalize(view_origin - current_position);
1994                 n = mouse_angles.z;
1995                 mouse_angles = vectoangles(dir);
1996                 mouse_angles.x = mouse_angles.x * -1;
1997                 mouse_angles.z = n;
1998         }
1999         else
2000         {
2001                 tmp = getmousepos() * 0.1;
2002                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
2003                 {
2004                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2005                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2006                 }
2007         }
2008
2009         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2010         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2011         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2012         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2013
2014         // Fix difference when angles don't have the same sign
2015         delta = '0 0 0';
2016         if(mouse_angles.y < -60 && current_angles.y > 60)
2017                 delta = '0 360 0';
2018         if(mouse_angles.y > 60 && current_angles.y < -60)
2019                 delta = '0 -360 0';
2020
2021         if(autocvar_camera_look_player)
2022                 attenuation = autocvar_camera_look_attenuation;
2023         else
2024                 attenuation = autocvar_camera_speed_attenuation;
2025
2026         attenuation = 1 / max(1, attenuation);
2027         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2028
2029         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2030         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2031         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2032         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2033
2034         // Camera position
2035         tmp = '0 0 0';
2036         dimensions = 0;
2037
2038         if( camera_direction.x )
2039         {
2040                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2041                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2042                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2043                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2044                 ++dimensions;
2045         }
2046
2047         if( camera_direction.y )
2048         {
2049                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2050                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2051                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2052                 ++dimensions;
2053         }
2054
2055         if( camera_direction.z )
2056         {
2057                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2058                 ++dimensions;
2059         }
2060
2061         if(autocvar_camera_free)
2062                 speed = autocvar_camera_speed_free;
2063         else
2064                 speed = autocvar_camera_speed_chase;
2065
2066         if(dimensions)
2067         {
2068                 speed = speed * sqrt(1 / dimensions);
2069                 camera_offset += tmp * speed;
2070         }
2071
2072         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2073
2074         // Camera modes
2075         if( autocvar_camera_free )
2076         {
2077                 if ( camera_mode == CAMERA_CHASE )
2078                 {
2079                         current_camera_offset = current_origin + current_camera_offset;
2080                         camera_offset = current_origin + camera_offset;
2081                 }
2082
2083                 camera_mode = CAMERA_FREE;
2084                 current_position = current_camera_offset;
2085         }
2086         else
2087         {
2088                 if ( camera_mode == CAMERA_FREE )
2089                 {
2090                         current_origin = view_origin;
2091                         camera_offset = camera_offset - current_origin;
2092                         current_camera_offset = current_camera_offset - current_origin;
2093                 }
2094
2095                 camera_mode = CAMERA_CHASE;
2096
2097                 if(autocvar_camera_chase_smoothly)
2098                         current_origin += (view_origin - current_origin) * attenuation;
2099                 else
2100                         current_origin = view_origin;
2101
2102                 current_position = current_origin + current_camera_offset;
2103         }
2104
2105         setproperty(VF_ANGLES, current_angles);
2106         setproperty(VF_ORIGIN, current_position);
2107 }