qcsrc/client/view.qc

   1
   2 #include "announcer.qh"
   3 #include "hud/all.qh"
   4 #include "mapvoting.qh"
   5 #include "scoreboard.qh"
   6 #include "shownames.qh"
   7 #include "quickmenu.qh"
   8
   9 #include "mutators/events.qh"
  10
  11 #include "../common/anim.qh"
  12 #include "../common/constants.qh"
  13 #include "../common/debug.qh"
  14 #include "../common/mapinfo.qh"
  15 #include <common/gamemodes/all.qh>
  16 #include "../common/physics/player.qh"
  17 #include "../common/stats.qh"
  18 #include "../common/triggers/target/music.qh"
  19 #include "../common/teams.qh"
  20
  21 #include <common/vehicles/all.qh>
  22 #include <common/weapons/all.qh>
  23 #include "../common/viewloc.qh"
  24 #include "../common/minigames/cl_minigames.qh"
  25 #include "../common/minigames/cl_minigames_hud.qh"
  26
  27 #include "../lib/csqcmodel/cl_player.qh"
  28
  29 #include "../lib/warpzone/client.qh"
  30 #include "../lib/warpzone/common.qh"
  31
  32 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
  33
  34 float autocvar_cl_viewmodel_scale;
  35
  36 bool autocvar_cl_bobmodel;
  37 float autocvar_cl_bobmodel_speed;
  38 float autocvar_cl_bobmodel_side;
  39 float autocvar_cl_bobmodel_up;
  40
  41 float autocvar_cl_followmodel;
  42 float autocvar_cl_followmodel_speed = 0.3;
  43 float autocvar_cl_followmodel_limit = 135;
  44 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
  45 float autocvar_cl_followmodel_highpass = 0.05;
  46 float autocvar_cl_followmodel_lowpass = 0.03;
  47 bool autocvar_cl_followmodel_velocity_absolute;
  48
  49 float autocvar_cl_leanmodel;
  50 float autocvar_cl_leanmodel_speed = 0.3;
  51 float autocvar_cl_leanmodel_limit = 30;
  52 float autocvar_cl_leanmodel_highpass1 = 0.2;
  53 float autocvar_cl_leanmodel_highpass = 0.2;
  54 float autocvar_cl_leanmodel_lowpass = 0.05;
  55
  56 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
  57 #define lowpass(value, frac, ref_store, ret) MACRO_BEGIN \
  58 { \
  59         ret = ref_store = ref_store * (1 - frac) + (value) * frac; \
  60 } MACRO_END
  61
  62 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  63 { \
  64         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  65         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  66 } MACRO_END
  67
  68 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
  69 { \
  70         float __f = 0; lowpass(value, frac, ref_store, __f); \
  71         ret = (value) - __f; \
  72 } MACRO_END
  73
  74 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  75 { \
  76         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
  77         ret = (value) - __f; \
  78 } MACRO_END
  79
  80 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  81 { \
  82         lowpass(value.x, frac, ref_store.x, ref_out.x); \
  83         lowpass(value.y, frac, ref_store.y, ref_out.y); \
  84 } MACRO_END
  85
  86 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  87 { \
  88         highpass(value.x, frac, ref_store.x, ref_out.x); \
  89         highpass(value.y, frac, ref_store.y, ref_out.y); \
  90 } MACRO_END
  91
  92 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
  93 { \
  94         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
  95         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
  96 } MACRO_END
  97
  98 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
  99 { \
 100         lowpass(value.x, frac, ref_store.x, ref_out.x); \
 101         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 102         lowpass(value.z, frac, ref_store.z, ref_out.z); \
 103 } MACRO_END
 104
 105 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 106 { \
 107         highpass(value.x, frac, ref_store.x, ref_out.x); \
 108         highpass(value.y, frac, ref_store.y, ref_out.y); \
 109         highpass(value.z, frac, ref_store.z, ref_out.z); \
 110 } MACRO_END
 111
 112 void viewmodel_animate(entity this)
 113 {
 114         static float prevtime;
 115         float frametime = (time - prevtime);
 116         prevtime = time;
 117
 118         if (autocvar_chase_active) return;
 119         if (STAT(HEALTH) <= 0) return;
 120
 121         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 122
 123         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 124         static bool oldonground;
 125         static float hitgroundtime;
 126         if (clonground)
 127         {
 128                 float f = time; // cl.movecmd[0].time
 129                 if (!oldonground)
 130                         hitgroundtime = f;
 131         }
 132         oldonground = clonground;
 133
 134
 135         bool teleported = view.csqcmodel_teleported;
 136
 137         float frac;
 138         if(autocvar_cl_followmodel)
 139         {
 140                 vector gunorg = '0 0 0';
 141                 static vector vel_average;
 142                 static vector gunorg_prev = '0 0 0';
 143                 static vector gunorg_adjustment_highpass;
 144                 static vector gunorg_adjustment_lowpass;
 145
 146                 vector vel;
 147                 if(autocvar_cl_followmodel_velocity_absolute)
 148                         vel = view.velocity;
 149                 else
 150                 {
 151                         vector forward, right = '0 0 0', up = '0 0 0';
 152                         MAKEVECTORS(makevectors, view_angles, forward, right, up);
 153                         vel.x = view.velocity * forward;
 154                         vel.y = view.velocity * right * -1;
 155                         vel.z = view.velocity * up;
 156                 }
 157
 158                 vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
 159                 vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
 160                 vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
 161
 162                 frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
 163                 lowpass3(vel, frac, vel_average, gunorg);
 164
 165                 gunorg *= -autocvar_cl_followmodel_speed * 0.042;
 166
 167                 // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 168                 // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 169                 frac = avg_factor(autocvar_cl_followmodel_highpass);
 170                 highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
 171                 frac = avg_factor(autocvar_cl_followmodel_lowpass);
 172                 lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
 173
 174                 if(autocvar_cl_followmodel_velocity_absolute)
 175                 {
 176                         vector fixed_gunorg;
 177                         vector forward, right = '0 0 0', up = '0 0 0';
 178                         MAKEVECTORS(makevectors, view_angles, forward, right, up);
 179                         fixed_gunorg.x = gunorg * forward;
 180                         fixed_gunorg.y = gunorg * right * -1;
 181                         fixed_gunorg.z = gunorg * up;
 182                         gunorg = fixed_gunorg;
 183                 }
 184
 185                 this.origin += gunorg;
 186         }
 187
 188         if(autocvar_cl_leanmodel)
 189         {
 190                 vector gunangles = '0 0 0';
 191                 static vector gunangles_prev = '0 0 0';
 192                 static vector gunangles_highpass = '0 0 0';
 193                 static vector gunangles_adjustment_highpass;
 194                 static vector gunangles_adjustment_lowpass;
 195
 196                 if (teleported)
 197                         gunangles_prev = view_angles;
 198
 199                 // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 200                 gunangles_highpass += gunangles_prev;
 201                 PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 202                 YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 203                 ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 204                 frac = avg_factor(autocvar_cl_leanmodel_highpass1);
 205                 highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
 206                 gunangles_prev = view_angles;
 207                 gunangles_highpass -= gunangles_prev;
 208
 209                 PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
 210                 YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
 211
 212                 // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 213                 frac = avg_factor(autocvar_cl_leanmodel_highpass);
 214                 highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
 215                 frac = avg_factor(autocvar_cl_leanmodel_lowpass);
 216                 lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
 217
 218                 gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 219                 this.angles += gunangles;
 220         }
 221
 222         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 223
 224         // vertical view bobbing code
 225         // TODO: cl_bob
 226
 227         // horizontal view bobbing code
 228         // TODO: cl_bob2
 229
 230         // fall bobbing code
 231         // causes the view to swing down and back up when touching the ground
 232         // TODO: cl_bobfall
 233
 234         // gun model bobbing code
 235         if (autocvar_cl_bobmodel)
 236         {
 237                 // calculate for swinging gun model
 238                 // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 239                 float bspeed;
 240                 static float bobmodel_scale = 0;
 241                 float s = time * autocvar_cl_bobmodel_speed;
 242                 if (clonground)
 243                 {
 244                         if (time - hitgroundtime > 0.05)
 245                                 bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
 246                 }
 247                 else
 248                         bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
 249                 if(bobmodel_scale)
 250                 {
 251                         bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
 252                         vector gunorg = '0 0 0';
 253                         gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
 254                         gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
 255
 256                         this.origin += gunorg;
 257                 }
 258         }
 259 }
 260
 261 .vector viewmodel_origin, viewmodel_angles;
 262 .float weapon_nextthink;
 263 .float weapon_eta_last;
 264 .float weapon_switchdelay;
 265
 266 void viewmodel_draw(entity this)
 267 {
 268         if(!activeweapon)
 269                 return;
 270         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 271         float a = this.alpha;
 272         static bool wasinvehicle;
 273         bool invehicle = player_localentnum > maxclients;
 274         if (invehicle) a = -1;
 275         else if (wasinvehicle) a = 1;
 276         wasinvehicle = invehicle;
 277         Weapon wep = activeweapon;
 278         int c = stof(getplayerkeyvalue(current_player, "colors"));
 279         vector g = weaponentity_glowmod(wep, c);
 280         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 281         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 282                 | EF_NODEPTHTEST)
 283                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 284         for (entity e = this; e; e = e.weaponchild)
 285         {
 286                 e.drawmask = mask;
 287                 e.alpha = a;
 288                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 289                 e.glowmod = g;
 290                 e.csqcmodel_effects = fx;
 291                 CSQCModel_Effects_Apply(e);
 292         }
 293         {
 294                 static string name_last;
 295                 string name = wep.mdl;
 296                 if (name != name_last)
 297                 {
 298                         name_last = name;
 299                         CL_WeaponEntity_SetModel(this, name);
 300                         this.viewmodel_origin = this.origin;
 301                         this.viewmodel_angles = this.angles;
 302                 }
 303                 anim_update(this);
 304                 if (!this.animstate_override)
 305                         anim_set(this, this.anim_idle, true, false, false);
 306         }
 307         float f = 0; // 0..1; 0: fully active
 308         float eta = (this.weapon_nextthink - time) / STAT(WEAPONRATEFACTOR);
 309         if (eta <= 0) f = this.weapon_eta_last;
 310         else switch (this.state)
 311         {
 312                 case WS_RAISE:
 313                 {
 314                         f = eta / max(eta, this.weapon_switchdelay);
 315                         break;
 316                 }
 317                 case WS_DROP:
 318                 {
 319                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 320                         break;
 321                 }
 322                 case WS_CLEAR:
 323                 {
 324                         f = 1;
 325                         break;
 326                 }
 327         }
 328         this.weapon_eta_last = f;
 329         this.origin = this.viewmodel_origin;
 330         this.angles = this.viewmodel_angles;
 331         this.angles_x = (-90 * f * f);
 332         viewmodel_animate(this);
 333         setorigin(this, this.origin);
 334 }
 335
 336 entity viewmodel;
 337 STATIC_INIT(viewmodel) {
 338     viewmodel = new(viewmodel);
 339     make_pure(viewmodel);
 340 }
 341
 342 entity porto;
 343 vector polyline[16];
 344 void Porto_Draw(entity this)
 345 {
 346         vector p, dir, ang, q, nextdir;
 347         float portal_number, portal1_idx;
 348
 349         if(activeweapon != WEP_PORTO || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
 350                 return;
 351         if(WEP_CVAR(porto, secondary))
 352                 return;
 353         if(intermission == 1)
 354                 return;
 355         if(intermission == 2)
 356                 return;
 357         if (STAT(HEALTH) <= 0)
 358                 return;
 359
 360         dir = view_forward;
 361
 362         if(angles_held_status)
 363         {
 364                 makevectors(angles_held);
 365                 dir = v_forward;
 366         }
 367
 368         p = view_origin;
 369
 370         polyline[0] = p;
 371         int idx = 1;
 372         portal_number = 0;
 373         nextdir = dir;
 374
 375         for (;;)
 376         {
 377                 dir = nextdir;
 378                 traceline(p, p + 65536 * dir, true, porto);
 379                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 380                         return;
 381                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
 382                 p = trace_endpos;
 383                 polyline[idx] = p;
 384                 ++idx;
 385                 if(idx >= 16)
 386                         return;
 387                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 388                         continue;
 389                 ++portal_number;
 390                 ang = vectoangles2(trace_plane_normal, dir);
 391                 ang.x = -ang.x;
 392                 makevectors(ang);
 393                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 394                         return;
 395                 if(portal_number == 1)
 396                 {
 397                         portal1_idx = idx;
 398                         if(portal_number >= 2)
 399                                 break;
 400                 }
 401         }
 402
 403         while(idx >= 2)
 404         {
 405                 p = polyline[idx-2];
 406                 q = polyline[idx-1];
 407                 if(idx == 2)
 408                         p = p - view_up * 16;
 409                 if(idx-1 >= portal1_idx)
 410                 {
 411                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
 412                 }
 413                 else
 414                 {
 415                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
 416                 }
 417                 --idx;
 418         }
 419 }
 420
 421 void Porto_Init()
 422 {
 423         porto = new(porto);
 424         make_pure(porto);
 425         porto.draw = Porto_Draw;
 426         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 427 }
 428
 429 float drawtime;
 430 float avgspeed;
 431 vector GetCurrentFov(float fov)
 432 {
 433         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 434         float velocityzoom, curspeed;
 435         vector v;
 436
 437         zoomsensitivity = autocvar_cl_zoomsensitivity;
 438         zoomfactor = autocvar_cl_zoomfactor;
 439         if(zoomfactor < 1 || zoomfactor > 30)
 440                 zoomfactor = 2.5;
 441         zoomspeed = autocvar_cl_zoomspeed;
 442         if(zoomspeed >= 0)
 443         if(zoomspeed < 0.5 || zoomspeed > 16)
 444                         zoomspeed = 3.5;
 445
 446         zoomdir = button_zoom;
 447         if(hud == HUD_NORMAL)
 448         if(switchweapon == activeweapon)
 449         if((activeweapon == WEP_VORTEX && !WEP_CVAR(vortex, secondary)) || (activeweapon == WEP_RIFLE && !WEP_CVAR(rifle, secondary))) // do NOT use switchweapon here
 450                 zoomdir += button_attack2;
 451         if(spectatee_status > 0 || isdemo())
 452         {
 453                 if(spectatorbutton_zoom)
 454                 {
 455                         if(zoomdir)
 456                                 zoomdir = 0;
 457                         else
 458                                 zoomdir = 1;
 459                 }
 460                 // fteqcc failed twice here already, don't optimize this
 461         }
 462
 463         if(zoomdir) { zoomin_effect = 0; }
 464
 465         if(camera_active)
 466         {
 467                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 468         }
 469         else if(autocvar_cl_spawnzoom && zoomin_effect)
 470         {
 471                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 472
 473                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 474                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 475                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 476         }
 477         else
 478         {
 479                 if(zoomspeed < 0) // instant zoom
 480                 {
 481                         if(zoomdir)
 482                                 current_viewzoom = 1 / zoomfactor;
 483                         else
 484                                 current_viewzoom = 1;
 485                 }
 486                 else
 487                 {
 488                         if(zoomdir)
 489                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 490                         else
 491                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 492                 }
 493         }
 494
 495         if(almost_equals(current_viewzoom, 1))
 496                 current_zoomfraction = 0;
 497         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 498                 current_zoomfraction = 1;
 499         else
 500                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 501
 502         if(zoomsensitivity < 1)
 503                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 504         else
 505                 setsensitivityscale(1);
 506
 507         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 508         {
 509                 if(intermission) { curspeed = 0; }
 510                 else
 511                 {
 512
 513                         makevectors(view_angles);
 514                         v = pmove_vel;
 515                         if(csqcplayer)
 516                                 v = csqcplayer.velocity;
 517
 518                         switch(autocvar_cl_velocityzoom_type)
 519                         {
 520                                 case 3: curspeed = max(0, v_forward * v); break;
 521                                 case 2: curspeed = (v_forward * v); break;
 522                                 case 1: default: curspeed = vlen(v); break;
 523                         }
 524                 }
 525
 526                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 527                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 528                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 529
 530                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 531         }
 532         else
 533                 velocityzoom = 1;
 534
 535         float frustumx, frustumy, fovx, fovy;
 536         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 537         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 538         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 539         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 540
 541         return '1 0 0' * fovx + '0 1 0' * fovy;
 542 }
 543
 544 vector GetViewLocationFOV(float fov)
 545 {
 546         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 547         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 548         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 549         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 550         return '1 0 0' * fovx + '0 1 0' * fovy;
 551 }
 552
 553 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 554 {
 555         float fovx, fovy;
 556         float width = (ov_worldmax.x - ov_worldmin.x);
 557         float height = (ov_worldmax.y - ov_worldmin.y);
 558         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 559         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 560         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 561         return '1 0 0' * fovx + '0 1 0' * fovy;
 562 }
 563
 564 // this function must match W_SetupShot!
 565 float zoomscript_caught;
 566
 567 vector wcross_origin;
 568 float wcross_scale_prev, wcross_alpha_prev;
 569 vector wcross_color_prev;
 570 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 571 vector wcross_color_goal_prev;
 572 float wcross_changedonetime;
 573
 574 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 575 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 576 float wcross_name_changestarttime, wcross_name_changedonetime;
 577 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 578
 579 float wcross_ring_prev;
 580
 581 entity trueaim;
 582 entity trueaim_rifle;
 583
 584 const float SHOTTYPE_HITTEAM = 1;
 585 const float SHOTTYPE_HITOBSTRUCTION = 2;
 586 const float SHOTTYPE_HITWORLD = 3;
 587 const float SHOTTYPE_HITENEMY = 4;
 588
 589 void TrueAim_Init()
 590 {
 591         trueaim = new(trueaim);
 592         make_pure(trueaim);
 593         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 594         trueaim_rifle = new(trueaim_rifle);
 595         make_pure(trueaim_rifle);
 596         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 597 }
 598
 599 float EnemyHitCheck()
 600 {
 601         float t, n;
 602         wcross_origin = project_3d_to_2d(trace_endpos);
 603         wcross_origin.z = 0;
 604         if(trace_ent)
 605                 n = trace_ent.entnum;
 606         else
 607                 n = trace_networkentity;
 608         if(n < 1)
 609                 return SHOTTYPE_HITWORLD;
 610         if(n > maxclients)
 611                 return SHOTTYPE_HITWORLD;
 612         t = entcs_GetTeam(n - 1);
 613         if(teamplay)
 614                 if(t == myteam)
 615                         return SHOTTYPE_HITTEAM;
 616         if(t == NUM_SPECTATOR)
 617                 return SHOTTYPE_HITWORLD;
 618         return SHOTTYPE_HITENEMY;
 619 }
 620
 621 float TrueAimCheck()
 622 {
 623         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 624         vector vecs, trueaimpoint, w_shotorg;
 625         vector mi, ma, dv;
 626         float shottype;
 627         entity ta;
 628         float mv;
 629
 630         mi = ma = '0 0 0';
 631         ta = trueaim;
 632         mv = MOVE_NOMONSTERS;
 633
 634         switch(activeweapon) // WEAPONTODO
 635         {
 636                 case WEP_TUBA: // no aim
 637                 case WEP_PORTO: // shoots from eye
 638                 case WEP_NEXBALL: // shoots from eye
 639                 case WEP_HOOK: // no trueaim
 640                 case WEP_MORTAR: // toss curve
 641                         return SHOTTYPE_HITWORLD;
 642                 case WEP_VORTEX:
 643                 case WEP_VAPORIZER:
 644                         mv = MOVE_NORMAL;
 645                         break;
 646                 case WEP_RIFLE:
 647                         ta = trueaim_rifle;
 648                         mv = MOVE_NORMAL;
 649                         if(zoomscript_caught)
 650                         {
 651                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 652                                 return EnemyHitCheck();
 653                         }
 654                         break;
 655                 case WEP_DEVASTATOR: // projectile has a size!
 656                         mi = '-3 -3 -3';
 657                         ma = '3 3 3';
 658                         break;
 659                 case WEP_FIREBALL: // projectile has a size!
 660                         mi = '-16 -16 -16';
 661                         ma = '16 16 16';
 662                         break;
 663                 case WEP_SEEKER: // projectile has a size!
 664                         mi = '-2 -2 -2';
 665                         ma = '2 2 2';
 666                         break;
 667                 case WEP_ELECTRO: // projectile has a size!
 668                         mi = '0 0 -3';
 669                         ma = '0 0 -3';
 670                         break;
 671         }
 672
 673         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
 674
 675         vecs = decompressShotOrigin(STAT(SHOTORG));
 676
 677         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 678         trueaimpoint = trace_endpos;
 679
 680         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
 681                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 682
 683         if(vecs.x > 0)
 684                 vecs.y = -vecs.y;
 685         else
 686                 vecs = '0 0 0';
 687
 688         dv = view_right * vecs.y + view_up * vecs.z;
 689         w_shotorg = traceorigin + dv;
 690
 691         // now move the vecs forward as much as requested if possible
 692         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 693         w_shotorg = trace_endpos - view_forward * nudge;
 694
 695         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 696         shottype = EnemyHitCheck();
 697         if(shottype != SHOTTYPE_HITWORLD)
 698                 return shottype;
 699
 700 #if 0
 701         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 702         // or rather, I know why, but see no fix
 703         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 704                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 705                 return SHOTTYPE_HITOBSTRUCTION;
 706 #endif
 707
 708         return SHOTTYPE_HITWORLD;
 709 }
 710
 711 void PostInit();
 712 void CSQC_Demo_Camera();
 713 float HUD_WouldDrawScoreboard();
 714 float camera_mode;
 715 const float CAMERA_FREE = 1;
 716 const float CAMERA_CHASE = 2;
 717 float reticle_type;
 718 string reticle_image;
 719 string NextFrameCommand;
 720
 721 vector freeze_org, freeze_ang;
 722 entity nightvision_noise, nightvision_noise2;
 723
 724 const float MAX_TIME_DIFF = 5;
 725 float pickup_crosshair_time, pickup_crosshair_size;
 726 float hitindication_crosshair_size;
 727 float use_vortex_chargepool;
 728
 729 float myhealth, myhealth_prev;
 730 float myhealth_flash;
 731
 732 float old_blurradius, old_bluralpha;
 733 float old_sharpen_intensity;
 734
 735 vector myhealth_gentlergb;
 736
 737 float contentavgalpha, liquidalpha_prev;
 738 vector liquidcolor_prev;
 739
 740 float eventchase_current_distance;
 741 float eventchase_running;
 742 bool WantEventchase(entity this)
 743 {
 744         if(autocvar_cl_orthoview)
 745                 return false;
 746         if(intermission)
 747                 return true;
 748         if(this.viewloc)
 749                 return true;
 750         if(spectatee_status >= 0)
 751         {
 752                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 753                         return true;
 754                 if(MUTATOR_CALLHOOK(WantEventchase, this))
 755                         return true;
 756                 if(autocvar_cl_eventchase_nexball && gametype == MAPINFO_TYPE_NEXBALL && !(WepSet_GetFromStat() & WEPSET(NEXBALL)))
 757                         return true;
 758                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
 759                 {
 760                         if(autocvar_cl_eventchase_death == 2)
 761                         {
 762                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 763                                 if(this.velocity == '0 0 0' || eventchase_running)
 764                                         return true;
 765                         }
 766                         else return true;
 767                 }
 768         }
 769         return false;
 770 }
 771
 772 void HUD_Crosshair_Vehicle()
 773 {
 774         if(hud != HUD_BUMBLEBEE_GUN)
 775         {
 776                 Vehicle info = Vehicles_from(hud);
 777                 info.vr_crosshair(info);
 778         }
 779 }
 780
 781 vector damage_blurpostprocess, content_blurpostprocess;
 782
 783 float unaccounted_damage = 0;
 784 void UpdateDamage()
 785 {
 786         // accumulate damage with each stat update
 787         static float damage_total_prev = 0;
 788         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 789         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 790         damage_total_prev = damage_total;
 791
 792         static float damage_dealt_time_prev = 0;
 793         float damage_dealt_time = STAT(HIT_TIME);
 794         if (damage_dealt_time != damage_dealt_time_prev)
 795         {
 796                 unaccounted_damage += unaccounted_damage_new;
 797                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")", "\n");
 798         }
 799         damage_dealt_time_prev = damage_dealt_time;
 800
 801         // prevent hitsound when switching spectatee
 802         static float spectatee_status_prev = 0;
 803         if (spectatee_status != spectatee_status_prev)
 804                 unaccounted_damage = 0;
 805         spectatee_status_prev = spectatee_status;
 806 }
 807
 808 void HitSound()
 809 {
 810         // varying sound pitch
 811
 812         static float hitsound_time_prev = 0;
 813         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 814         float arc_hack = activeweapon == WEP_ARC && autocvar_cl_hitsound >= 2;
 815         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 816         {
 817                 if (autocvar_cl_hitsound && unaccounted_damage)
 818                 {
 819                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 820                         float a = autocvar_cl_hitsound_max_pitch;
 821                         float b = autocvar_cl_hitsound_min_pitch;
 822                         float c = autocvar_cl_hitsound_nom_damage;
 823                         float x = unaccounted_damage;
 824                         float pitch_shift = (b*x*(a-1) + a*c*(1-b)) / (x*(a-1) + c*(1-b));
 825
 826                         // if sound variation is disabled, set pitch_shift to 1
 827                         if (autocvar_cl_hitsound == 1)
 828                                 pitch_shift = 1;
 829
 830                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 831                         if (autocvar_cl_hitsound == 3)
 832                         {
 833                                 float mirror_value = (a-b)/2 + b;
 834                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 835                         }
 836
 837                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift), "\n");
 838
 839                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 840                         // todo: normalize sound pressure levels? seems unnecessary
 841
 842                         sound7(world, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 843                 }
 844                 unaccounted_damage = 0;
 845                 hitsound_time_prev = time;
 846         }
 847
 848         static float typehit_time_prev = 0;
 849         float typehit_time = STAT(TYPEHIT_TIME);
 850         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 851         {
 852                 sound(world, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 853                 typehit_time_prev = typehit_time;
 854         }
 855 }
 856
 857 void HUD_Crosshair()
 858 {SELFPARAM();
 859         static float rainbow_last_flicker;
 860         static vector rainbow_prev_color;
 861         entity e = this;
 862         float f, i, j;
 863         vector v;
 864         if(!scoreboard_active && !camera_active && intermission != 2 &&
 865                 spectatee_status != -1 && !csqcplayer.viewloc &&
 866                 !HUD_MinigameMenu_IsOpened() )
 867         {
 868                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 869                         return;
 870
 871                 if (hud != HUD_NORMAL)
 872                 {
 873                         HUD_Crosshair_Vehicle();
 874                         return;
 875                 }
 876
 877                 string wcross_style;
 878                 float wcross_alpha, wcross_resolution;
 879                 wcross_style = autocvar_crosshair;
 880                 if (wcross_style == "0")
 881                         return;
 882                 wcross_resolution = autocvar_crosshair_size;
 883                 if (wcross_resolution == 0)
 884                         return;
 885                 wcross_alpha = autocvar_crosshair_alpha;
 886                 if (wcross_alpha == 0)
 887                         return;
 888
 889                 // TrueAim check
 890                 float shottype;
 891
 892                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 893                 wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 894                 wcross_origin.z = 0;
 895                 if(autocvar_crosshair_hittest)
 896                 {
 897                         vector wcross_oldorigin;
 898                         wcross_oldorigin = wcross_origin;
 899                         shottype = TrueAimCheck();
 900                         if(shottype == SHOTTYPE_HITWORLD)
 901                         {
 902                                 v = wcross_origin - wcross_oldorigin;
 903                                 v.x /= vid_conwidth;
 904                                 v.y /= vid_conheight;
 905                                 if(vlen(v) > 0.01)
 906                                         shottype = SHOTTYPE_HITOBSTRUCTION;
 907                         }
 908                         if(!autocvar_crosshair_hittest_showimpact)
 909                                 wcross_origin = wcross_oldorigin;
 910                 }
 911                 else
 912                         shottype = SHOTTYPE_HITWORLD;
 913
 914                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
 915                 string wcross_name = "";
 916                 float wcross_scale, wcross_blur;
 917
 918                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
 919                 {
 920                         e = switchingweapon;
 921                         if(e)
 922                         {
 923                                 if(autocvar_crosshair_per_weapon)
 924                                 {
 925                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
 926                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 927                                         //if (wcross_resolution == 0)
 928                                                 //return;
 929
 930                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 931                                         wcross_resolution *= e.w_crosshair_size;
 932                                         wcross_name = e.w_crosshair;
 933                                 }
 934                         }
 935                 }
 936
 937                 if(wcross_name == "")
 938                         wcross_name = strcat("gfx/crosshair", wcross_style);
 939
 940                 // MAIN CROSSHAIR COLOR DECISION
 941                 switch(autocvar_crosshair_color_special)
 942                 {
 943                         case 1: // crosshair_color_per_weapon
 944                         {
 945                                 if(e)
 946                                 {
 947                                         wcross_color = e.wpcolor;
 948                                         break;
 949                                 }
 950                                 else { goto normalcolor; }
 951                         }
 952
 953                         case 2: // crosshair_color_by_health
 954                         {
 955                                 float x = STAT(HEALTH);
 956
 957                                 //x = red
 958                                 //y = green
 959                                 //z = blue
 960
 961                                 wcross_color.z = 0;
 962
 963                                 if(x > 200)
 964                                 {
 965                                         wcross_color.x = 0;
 966                                         wcross_color.y = 1;
 967                                 }
 968                                 else if(x > 150)
 969                                 {
 970                                         wcross_color.x = 0.4 - (x-150)*0.02 * 0.4;
 971                                         wcross_color.y = 0.9 + (x-150)*0.02 * 0.1;
 972                                 }
 973                                 else if(x > 100)
 974                                 {
 975                                         wcross_color.x = 1 - (x-100)*0.02 * 0.6;
 976                                         wcross_color.y = 1 - (x-100)*0.02 * 0.1;
 977                                         wcross_color.z = 1 - (x-100)*0.02;
 978                                 }
 979                                 else if(x > 50)
 980                                 {
 981                                         wcross_color.x = 1;
 982                                         wcross_color.y = 1;
 983                                         wcross_color.z = 0.2 + (x-50)*0.02 * 0.8;
 984                                 }
 985                                 else if(x > 20)
 986                                 {
 987                                         wcross_color.x = 1;
 988                                         wcross_color.y = (x-20)*90/27/100;
 989                                         wcross_color.z = (x-20)*90/27/100 * 0.2;
 990                                 }
 991                                 else
 992                                 {
 993                                         wcross_color.x = 1;
 994                                         wcross_color.y = 0;
 995                                 }
 996                                 break;
 997                         }
 998
 999                         case 3: // crosshair_color_rainbow
1000                         {
1001                                 if(time >= rainbow_last_flicker)
1002                                 {
1003                                         rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
1004                                         rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
1005                                 }
1006                                 wcross_color = rainbow_prev_color;
1007                                 break;
1008                         }
1009                         :normalcolor
1010                         default: { wcross_color = stov(autocvar_crosshair_color); break; }
1011                 }
1012
1013                 if(autocvar_crosshair_effect_scalefade)
1014                 {
1015                         wcross_scale = wcross_resolution;
1016                         wcross_resolution = 1;
1017                 }
1018                 else
1019                 {
1020                         wcross_scale = 1;
1021                 }
1022
1023                 if(autocvar_crosshair_pickup)
1024                 {
1025                         float stat_pickup_time = STAT(LAST_PICKUP);
1026
1027                         if(pickup_crosshair_time < stat_pickup_time)
1028                         {
1029                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1030                                         pickup_crosshair_size = 1;
1031
1032                                 pickup_crosshair_time = stat_pickup_time;
1033                         }
1034
1035                         if(pickup_crosshair_size > 0)
1036                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1037                         else
1038                                 pickup_crosshair_size = 0;
1039
1040                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1041                 }
1042
1043                 // todo: make crosshair hit indication dependent on damage dealt
1044                 if(autocvar_crosshair_hitindication)
1045                 {
1046                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1047
1048                         if(unaccounted_damage)
1049                         {
1050                                 hitindication_crosshair_size = 1;
1051                         }
1052
1053                         if(hitindication_crosshair_size > 0)
1054                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1055                         else
1056                                 hitindication_crosshair_size = 0;
1057
1058                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1059                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1060                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1061                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1062                 }
1063
1064                 if(shottype == SHOTTYPE_HITENEMY)
1065                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1066                 if(shottype == SHOTTYPE_HITTEAM)
1067                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1068
1069                 f = fabs(autocvar_crosshair_effect_time);
1070                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1071                 {
1072                         wcross_changedonetime = time + f;
1073                 }
1074                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1075                 {
1076                         wcross_name_changestarttime = time;
1077                         wcross_name_changedonetime = time + f;
1078                         if(wcross_name_goal_prev_prev)
1079                                 strunzone(wcross_name_goal_prev_prev);
1080                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1081                         wcross_name_goal_prev = strzone(wcross_name);
1082                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1083                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1084                         wcross_resolution_goal_prev = wcross_resolution;
1085                 }
1086
1087                 wcross_scale_goal_prev = wcross_scale;
1088                 wcross_alpha_goal_prev = wcross_alpha;
1089                 wcross_color_goal_prev = wcross_color;
1090
1091                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1092                 {
1093                         wcross_blur = 1;
1094                         wcross_alpha *= 0.75;
1095                 }
1096                 else
1097                         wcross_blur = 0;
1098                 // *_prev is at time-frametime
1099                 // * is at wcross_changedonetime+f
1100                 // what do we have at time?
1101                 if(time < wcross_changedonetime)
1102                 {
1103                         f = frametime / (wcross_changedonetime - time + frametime);
1104                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1105                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1106                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1107                 }
1108
1109                 wcross_scale_prev = wcross_scale;
1110                 wcross_alpha_prev = wcross_alpha;
1111                 wcross_color_prev = wcross_color;
1112
1113                 MUTATOR_CALLHOOK(UpdateCrosshair);
1114
1115                 wcross_scale *= 1 - autocvar__menu_alpha;
1116                 wcross_alpha *= 1 - autocvar__menu_alpha;
1117                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1118
1119                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1120                 {
1121                         // crosshair rings for weapon stats
1122                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1123                         {
1124                                 // declarations and stats
1125                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1126                                 string ring_image = string_null, ring_inner_image = string_null;
1127                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1128
1129                                 ring_scale = autocvar_crosshair_ring_size;
1130
1131                                 float weapon_clipload, weapon_clipsize;
1132                                 weapon_clipload = STAT(WEAPON_CLIPLOAD);
1133                                 weapon_clipsize = STAT(WEAPON_CLIPSIZE);
1134
1135                                 float ok_ammo_charge, ok_ammo_chargepool;
1136                                 ok_ammo_charge = STAT(OK_AMMO_CHARGE);
1137                                 ok_ammo_chargepool = STAT(OK_AMMO_CHARGEPOOL);
1138
1139                                 float vortex_charge, vortex_chargepool;
1140                                 vortex_charge = STAT(VORTEX_CHARGE);
1141                                 vortex_chargepool = STAT(VORTEX_CHARGEPOOL);
1142
1143                                 float arc_heat = STAT(ARC_HEAT);
1144
1145                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1146                                         vortex_charge_movingavg = vortex_charge;
1147
1148
1149                                 // handle the values
1150                                 if (autocvar_crosshair_ring && activeweapon == WEP_VORTEX && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1151                                 {
1152                                         if (vortex_chargepool || use_vortex_chargepool) {
1153                                                 use_vortex_chargepool = 1;
1154                                                 ring_inner_value = vortex_chargepool;
1155                                         } else {
1156                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
1157                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
1158                                         }
1159
1160                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1161                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1162                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1163
1164                                         // draw the outer ring to show the current charge of the weapon
1165                                         ring_value = vortex_charge;
1166                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1167                                         ring_rgb = wcross_color;
1168                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1169                                 }
1170                                 else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1171                                 {
1172                                         ring_value = bound(0, STAT(LAYED_MINES) / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1173                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1174                                         ring_rgb = wcross_color;
1175                                         ring_image = "gfx/crosshair_ring.tga";
1176                                 }
1177                                 else if (activeweapon == WEP_HAGAR && STAT(HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1178                                 {
1179                                         ring_value = bound(0, STAT(HAGAR_LOAD) / WEP_CVAR_SEC(hagar, load_max), 1);
1180                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1181                                         ring_rgb = wcross_color;
1182                                         ring_image = "gfx/crosshair_ring.tga";
1183                                 }
1184                                 else if (ok_ammo_charge)
1185                                 {
1186                                         ring_value = ok_ammo_chargepool;
1187                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1188                                         ring_rgb = wcross_color;
1189                                         ring_image = "gfx/crosshair_ring.tga";
1190                                 }
1191                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1192                                 {
1193                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1194                                         ring_scale = autocvar_crosshair_ring_reload_size;
1195                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1196                                         ring_rgb = wcross_color;
1197
1198                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1199                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1200                                         if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1201                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1202                                         else
1203                                                 ring_image = "gfx/crosshair_ring.tga";
1204                                 }
1205                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && activeweapon == WEP_ARC )
1206                                 {
1207                                         ring_value = arc_heat;
1208                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1209                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1210                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1211                                         ring_image = "gfx/crosshair_ring.tga";
1212                                 }
1213
1214                                 // if in weapon switch animation, fade ring out/in
1215                                 if(autocvar_crosshair_effect_time > 0)
1216                                 {
1217                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1218                                         if (f >= 1)
1219                                         {
1220                                                 wcross_ring_prev = ((ring_image) ? true : false);
1221                                         }
1222
1223                                         if(wcross_ring_prev)
1224                                         {
1225                                                 if(f < 1)
1226                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1227                                         }
1228                                         else
1229                                         {
1230                                                 if(f < 1)
1231                                                         ring_alpha *= bound(0, f, 1);
1232                                         }
1233                                 }
1234
1235                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1236                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1237
1238                                 if (ring_value)
1239                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1240                         }
1241
1242 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1243                         MACRO_BEGIN { \
1244                                 if(wcross_blur > 0) \
1245                                 { \
1246                                         for(i = -2; i <= 2; ++i) \
1247                                         for(j = -2; j <= 2; ++j) \
1248                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1249                                 } \
1250                                 else \
1251                                 { \
1252                                         M(0,0,sz,wcross_name,wcross_alpha); \
1253                                 } \
1254                         } MACRO_END
1255
1256 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1257                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1258
1259 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1260                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1261
1262                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1263                         {
1264                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1265                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1266                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1267                                 f = 1 - f;
1268                         }
1269                         else
1270                         {
1271                                 f = 1;
1272                         }
1273                         wcross_name_alpha_goal_prev = f;
1274
1275                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1276                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1277
1278                         if(autocvar_crosshair_dot)
1279                         {
1280                                 vector wcross_color_old;
1281                                 wcross_color_old = wcross_color;
1282
1283                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1284                                         wcross_color = stov(autocvar_crosshair_dot_color);
1285
1286                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1287                                 // FIXME why don't we use wcross_alpha here?
1288                                 wcross_color = wcross_color_old;
1289                         }
1290                 }
1291         }
1292         else
1293         {
1294                 wcross_scale_prev = 0;
1295                 wcross_alpha_prev = 0;
1296                 wcross_scale_goal_prev = 0;
1297                 wcross_alpha_goal_prev = 0;
1298                 wcross_changedonetime = 0;
1299                 if(wcross_name_goal_prev)
1300                         strunzone(wcross_name_goal_prev);
1301                 wcross_name_goal_prev = string_null;
1302                 if(wcross_name_goal_prev_prev)
1303                         strunzone(wcross_name_goal_prev_prev);
1304                 wcross_name_goal_prev_prev = string_null;
1305                 wcross_name_changestarttime = 0;
1306                 wcross_name_changedonetime = 0;
1307                 wcross_name_alpha_goal_prev = 0;
1308                 wcross_name_alpha_goal_prev_prev = 0;
1309                 wcross_resolution_goal_prev = 0;
1310                 wcross_resolution_goal_prev_prev = 0;
1311         }
1312 }
1313
1314 void HUD_Draw()
1315 {
1316         vector rgb = '0 0 0';
1317         float a = 1;
1318         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1319         {
1320                 rgb = MUTATOR_ARGV(0, vector);
1321                 a = MUTATOR_ARGV(0, float);
1322         }
1323         else if(STAT(FROZEN))
1324         {
1325                 rgb = ((STAT(REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * STAT(REVIVE_PROGRESS)) + ('0 1 1' * STAT(REVIVE_PROGRESS) * -1)) : '0.25 0.90 1');
1326         }
1327         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, rgb, autocvar_hud_colorflash_alpha * a, DRAWFLAG_ADDITIVE);
1328         if(!intermission)
1329         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1330         {
1331                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * STAT(NADE_TIMER)) - ('0 1 1' * STAT(NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1332                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1333         }
1334         else if(STAT(REVIVE_PROGRESS))
1335         {
1336                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1337                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1338         }
1339
1340         if(autocvar_r_letterbox == 0)
1341                 if(autocvar_viewsize < 120)
1342                 {
1343                         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1344                                 Accuracy_LoadLevels();
1345
1346                         HUD_Main();
1347                         HUD_DrawScoreboard();
1348                 }
1349
1350         // crosshair goes VERY LAST
1351         UpdateDamage();
1352         HUD_Crosshair();
1353         HitSound();
1354 }
1355
1356 bool ov_enabled;
1357 float oldr_nearclip;
1358 float oldr_farclip_base;
1359 float oldr_farclip_world;
1360 float oldr_novis;
1361 float oldr_useportalculling;
1362 float oldr_useinfinitefarclip;
1363
1364 void cl_notice_run();
1365 float prev_myteam;
1366 int lasthud;
1367 float vh_notice_time;
1368 void WaypointSprite_Load();
1369 void CSQC_UpdateView(float w, float h)
1370 {SELFPARAM();
1371         entity e;
1372         float fov;
1373         float f;
1374         vector vf_size, vf_min;
1375         float a;
1376
1377         execute_next_frame();
1378
1379         ++framecount;
1380
1381         stats_get();
1382         hud = STAT(HUD);
1383
1384         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1385                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1386
1387         lasthud = hud;
1388
1389         if(autocvar__hud_showbinds_reload) // menu can set this one
1390         {
1391                 db_close(binddb);
1392                 binddb = db_create();
1393                 cvar_set("_hud_showbinds_reload", "0");
1394         }
1395
1396         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1397                 view_quality = getproperty(VF_MINFPS_QUALITY);
1398         else
1399                 view_quality = 1;
1400
1401         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1402         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1403
1404         vf_size = getpropertyvec(VF_SIZE);
1405         vf_min = getpropertyvec(VF_MIN);
1406         vid_width = vf_size.x;
1407         vid_height = vf_size.y;
1408
1409         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1410         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1411
1412         WaypointSprite_Load();
1413
1414         CSQCPlayer_SetCamera();
1415
1416         if(player_localentnum <= maxclients) // is it a client?
1417                 current_player = player_localentnum - 1;
1418         else // then player_localentnum is the vehicle I'm driving
1419                 current_player = player_localnum;
1420         myteam = entcs_GetTeam(current_player);
1421
1422         if(myteam != prev_myteam)
1423         {
1424                 myteamcolors = colormapPaletteColor(myteam, 1);
1425                 FOREACH(hud_panels, true, LAMBDA(it.update_time = time));
1426                 prev_myteam = myteam;
1427         }
1428
1429         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1430
1431         float is_dead = (STAT(HEALTH) <= 0);
1432
1433         // FIXME do we need this hack?
1434         if(isdemo())
1435         {
1436                 // in demos, input_buttons do not work
1437                 button_zoom = (autocvar__togglezoom == "-");
1438         }
1439         else if(button_zoom
1440                 && autocvar_cl_unpress_zoom_on_death
1441                 && (spectatee_status >= 0)
1442                 && (is_dead || intermission))
1443         {
1444                 // no zoom while dead or in intermission please
1445                 localcmd("-zoom\n");
1446                 button_zoom = false;
1447         }
1448
1449         // event chase camera
1450         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1451         {
1452                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1453                 float ons_roundlost = (gametype == MAPINFO_TYPE_ONSLAUGHT && STAT(ROUNDLOST));
1454                 entity gen = world;
1455
1456                 float vehicle_viewdist = 0;
1457                 vector vehicle_viewofs = '0 0 0';
1458
1459                 if(vehicle_chase)
1460                 {
1461                         if(hud != HUD_BUMBLEBEE_GUN)
1462                         {
1463                                 Vehicle info = Vehicles_from(hud);
1464                                 vehicle_viewdist = info.height;
1465                                 vehicle_viewofs = info.view_ofs;
1466                         }
1467                 }
1468
1469                 if(ons_roundlost)
1470                 {
1471                         FOREACH_ENTITY_CLASS("onslaught_generator", it.health <= 0, LAMBDA(
1472                                 gen = it;
1473                                 break;
1474                         ));
1475                         if(!gen)
1476                                 ons_roundlost = false; // don't enforce the 3rd person camera if there is no dead generator to show
1477                 }
1478                 if(WantEventchase(self) || (!autocvar_cl_orthoview && ons_roundlost))
1479                 {
1480                         eventchase_running = true;
1481
1482                         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1483                         if(!local_player)
1484                                 local_player = self; // fall back!
1485
1486                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1487                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1488                         if(ons_roundlost) { current_view_origin = gen.origin; }
1489
1490                         // detect maximum viewoffset and use it
1491                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1492                         if(vehicle_chase)
1493                         {
1494                                 if(vehicle_viewofs)
1495                                         view_offset = vehicle_viewofs;
1496                                 else
1497                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
1498                         }
1499                         if(ons_roundlost) { view_offset = autocvar_cl_eventchase_generator_viewoffset; }
1500
1501                         if(view_offset)
1502                         {
1503                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, self);
1504                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1505                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1506                         }
1507
1508                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1509                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1510                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1511                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1512
1513                         // make the camera smooth back
1514                         float chase_distance = autocvar_cl_eventchase_distance;
1515                         if(vehicle_chase)
1516                         {
1517                                 if(vehicle_viewofs)
1518                                         chase_distance = vehicle_viewdist;
1519                                 else
1520                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
1521                         }
1522                         if(ons_roundlost) { chase_distance = autocvar_cl_eventchase_generator_distance; }
1523
1524                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1525                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1526                         else if(eventchase_current_distance != chase_distance)
1527                                 eventchase_current_distance = chase_distance;
1528
1529                         makevectors(view_angles);
1530
1531                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1532                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
1533
1534                         // If the boxtrace fails, revert back to line tracing.
1535                         if(!local_player.viewloc)
1536                         if(trace_startsolid)
1537                         {
1538                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1539                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
1540                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1541                         }
1542                         else { setproperty(VF_ORIGIN, trace_endpos); }
1543
1544                         if(!local_player.viewloc)
1545                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1546                 }
1547                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1548                 {
1549                         eventchase_running = false;
1550                         cvar_set("chase_active", "0");
1551                         eventchase_current_distance = 0; // start from 0 next time
1552                 }
1553         }
1554         // workaround for camera stuck between player's legs when using chase_active 1
1555         // because the engine stops updating the chase_active camera when the game ends
1556         else if(intermission)
1557         {
1558                 cvar_settemp("chase_active", "-1");
1559                 eventchase_current_distance = 0;
1560         }
1561
1562         // do lockview after event chase camera so that it still applies whenever necessary.
1563         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1564         {
1565                 setproperty(VF_ORIGIN, freeze_org);
1566                 setproperty(VF_ANGLES, freeze_ang);
1567         }
1568         else
1569         {
1570                 freeze_org = getpropertyvec(VF_ORIGIN);
1571                 freeze_ang = getpropertyvec(VF_ANGLES);
1572         }
1573
1574         WarpZone_FixView();
1575         //WarpZone_FixPMove();
1576
1577         vector ov_org = '0 0 0';
1578         vector ov_mid = '0 0 0';
1579         vector ov_worldmin = '0 0 0';
1580         vector ov_worldmax = '0 0 0';
1581         if(autocvar_cl_orthoview)
1582         {
1583                 ov_worldmin = mi_picmin;
1584                 ov_worldmax = mi_picmax;
1585
1586                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1587                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1588                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1589
1590                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1591                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1592
1593                 float ov_nearest = vlen(ov_org - vec3(
1594                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1595                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1596                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1597                 ));
1598
1599                 float ov_furthest = 0;
1600                 float dist = 0;
1601
1602                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1603                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1604                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1605                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1606                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1607                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1608                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1609                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1610
1611                 if(!ov_enabled)
1612                 {
1613                         oldr_nearclip = cvar("r_nearclip");
1614                         oldr_farclip_base = cvar("r_farclip_base");
1615                         oldr_farclip_world = cvar("r_farclip_world");
1616                         oldr_novis = cvar("r_novis");
1617                         oldr_useportalculling = cvar("r_useportalculling");
1618                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1619                 }
1620
1621                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1622                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1623                 cvar_settemp("r_farclip_world", "0");
1624                 cvar_settemp("r_novis", "1");
1625                 cvar_settemp("r_useportalculling", "0");
1626                 cvar_settemp("r_useinfinitefarclip", "0");
1627
1628                 setproperty(VF_ORIGIN, ov_org);
1629                 setproperty(VF_ANGLES, '90 0 0');
1630
1631                 ov_enabled = true;
1632
1633                 #if 0
1634                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1635                         vtos(ov_org),
1636                         vtos(getpropertyvec(VF_ANGLES)),
1637                         ov_distance,
1638                         ov_nearest,
1639                         ov_furthest);
1640                 #endif
1641         }
1642         else
1643         {
1644                 if(ov_enabled)
1645                 {
1646                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1647                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1648                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1649                         cvar_set("r_novis", ftos(oldr_novis));
1650                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1651                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1652                 }
1653                 ov_enabled = false;
1654         }
1655
1656         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
1657         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
1658         viewmodel_draw(viewmodel);
1659
1660         // Render the Scene
1661         view_origin = getpropertyvec(VF_ORIGIN);
1662         view_angles = getpropertyvec(VF_ANGLES);
1663         makevectors(view_angles);
1664         view_forward = v_forward;
1665         view_right = v_right;
1666         view_up = v_up;
1667
1668 #ifdef BLURTEST
1669         if(time > blurtest_time0 && time < blurtest_time1)
1670         {
1671                 float r, t;
1672
1673                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1674                 r = t * blurtest_radius;
1675                 f = 1 / pow(t, blurtest_power) - 1;
1676
1677                 cvar_set("r_glsl_postprocess", "1");
1678                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1679         }
1680         else
1681         {
1682                 cvar_set("r_glsl_postprocess", "0");
1683                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1684         }
1685 #endif
1686
1687         TargetMusic_Advance();
1688         Fog_Force();
1689
1690         if(drawtime == 0)
1691                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1692         else
1693                 drawframetime = bound(0.000001, time - drawtime, 1);
1694         drawtime = time;
1695
1696         // watch for gametype changes here...
1697         // in ParseStuffCMD the cmd isn't executed yet :/
1698         // might even be better to add the gametype to TE_CSQC_INIT...?
1699         if(!postinit)
1700                 PostInit();
1701
1702         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1703         {
1704                 if(calledhooks & HOOK_START)
1705                 {
1706                         localcmd("\ncl_hook_gameend\n");
1707                         calledhooks |= HOOK_END;
1708                 }
1709         }
1710
1711         Announcer();
1712
1713         fov = autocvar_fov;
1714         if(fov <= 59.5)
1715         {
1716                 if(!zoomscript_caught)
1717                 {
1718                         localcmd("+button9\n");
1719                         zoomscript_caught = 1;
1720                 }
1721         }
1722         else
1723         {
1724                 if(zoomscript_caught)
1725                 {
1726                         localcmd("-button9\n");
1727                         zoomscript_caught = 0;
1728                 }
1729         }
1730
1731         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1732
1733         // currently switching-to weapon (for crosshair)
1734         switchingweapon = Weapons_from(STAT(SWITCHINGWEAPON));
1735
1736         // actually active weapon (for zoom)
1737         activeweapon = Weapons_from(STAT(ACTIVEWEAPON));
1738
1739         switchweapon = Weapons_from(STAT(SWITCHWEAPON));
1740
1741         f = (serverflags & SERVERFLAG_TEAMPLAY);
1742         if(f != teamplay)
1743         {
1744                 teamplay = f;
1745                 HUD_InitScores();
1746         }
1747
1748         if(last_switchweapon != switchweapon)
1749         {
1750                 weapontime = time;
1751                 last_switchweapon = switchweapon;
1752                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1753                 {
1754                         localcmd("-zoom\n");
1755                         button_zoom = false;
1756                 }
1757                 if(autocvar_cl_unpress_attack_on_weapon_switch)
1758                 {
1759                         localcmd("-fire\n");
1760                         localcmd("-fire2\n");
1761                         button_attack2 = false;
1762                 }
1763         }
1764         if(last_activeweapon != activeweapon)
1765         {
1766                 last_activeweapon = activeweapon;
1767
1768                 e = activeweapon;
1769                 if(e.netname != "")
1770                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1771                 else
1772                         localcmd("\ncl_hook_activeweapon none\n");
1773         }
1774
1775         // ALWAYS Clear Current Scene First
1776         clearscene();
1777
1778         setproperty(VF_ORIGIN, view_origin);
1779         setproperty(VF_ANGLES, view_angles);
1780
1781         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1782         setproperty(VF_SIZE, vf_size);
1783         setproperty(VF_MIN, vf_min);
1784
1785         // Assign Standard Viewflags
1786         // Draw the World (and sky)
1787         setproperty(VF_DRAWWORLD, 1);
1788
1789         // Set the console size vars
1790         vid_conwidth = autocvar_vid_conwidth;
1791         vid_conheight = autocvar_vid_conheight;
1792         vid_pixelheight = autocvar_vid_pixelheight;
1793
1794         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1795         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1796         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1797
1798         // Camera for demo playback
1799         if(camera_active)
1800         {
1801                 if(autocvar_camera_enable)
1802                         CSQC_Demo_Camera();
1803                 else
1804                 {
1805                         cvar_set("chase_active", ftos(chase_active_backup));
1806                         cvar_set("cl_demo_mousegrab", "0");
1807                         camera_active = false;
1808                 }
1809         }
1810         else
1811         {
1812 #ifdef CAMERATEST
1813                 if(autocvar_camera_enable)
1814 #else
1815                 if(autocvar_camera_enable && isdemo())
1816 #endif
1817                 {
1818                         // Enable required Darkplaces cvars
1819                         chase_active_backup = autocvar_chase_active;
1820                         cvar_set("chase_active", "2");
1821                         cvar_set("cl_demo_mousegrab", "1");
1822                         camera_active = true;
1823                         camera_mode = false;
1824                 }
1825         }
1826
1827         // Draw the Crosshair
1828         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1829
1830         // Draw the Engine Status Bar (the default Quake HUD)
1831         setproperty(VF_DRAWENGINESBAR, 0);
1832
1833         // Update the mouse position
1834         /*
1835            mousepos_x = vid_conwidth;
1836            mousepos_y = vid_conheight;
1837            mousepos = mousepos*0.5 + getmousepos();
1838          */
1839
1840         FOREACH_ENTITY(it.draw, LAMBDA(it.draw(it)));
1841
1842         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1843         renderscene();
1844
1845         // now switch to 2D drawing mode by calling a 2D drawing function
1846         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1847         // next R_RenderScene call
1848         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1849
1850         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1851         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1852         {
1853                 // apply night vision effect
1854                 vector tc_00, tc_01, tc_10, tc_11;
1855                 vector rgb = '0 0 0';
1856
1857                 if(!nightvision_noise)
1858                 {
1859                         nightvision_noise = new(nightvision_noise);
1860                 }
1861                 if(!nightvision_noise2)
1862                 {
1863                         nightvision_noise2 = new(nightvision_noise2);
1864                 }
1865
1866                 // color tint in yellow
1867                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1868
1869                 // draw BG
1870                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1871                 rgb = '1 1 1';
1872                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1873                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1874                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1875                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1876                 tc_11 = tc_01 + tc_10 - tc_00;
1877                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1878                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1879                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1880                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1881                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1882                 R_EndPolygon();
1883
1884                 // draw FG
1885                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1886                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1887                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1888                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1889                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1890                 tc_11 = tc_01 + tc_10 - tc_00;
1891                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1892                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1893                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1894                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1895                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1896                 R_EndPolygon();
1897         }
1898
1899         if(autocvar_cl_reticle)
1900         {
1901                 Weapon wep = activeweapon;
1902                 // Draw the aiming reticle for weapons that use it
1903                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
1904                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
1905                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
1906                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
1907                 {
1908                         // no zoom reticle while dead
1909                         reticle_type = 0;
1910                 }
1911                 else if(wep.wr_zoomreticle(wep) && autocvar_cl_reticle_weapon)
1912                 {
1913                         if(reticle_image != "") { reticle_type = 2; }
1914                         else { reticle_type = 0; }
1915                 }
1916                 else if(button_zoom || zoomscript_caught)
1917                 {
1918                         // normal zoom
1919                         reticle_type = 1;
1920                 }
1921
1922                 if(reticle_type)
1923                 {
1924                         if(autocvar_cl_reticle_stretch)
1925                         {
1926                                 reticle_size.x = vid_conwidth;
1927                                 reticle_size.y = vid_conheight;
1928                                 reticle_pos.x = 0;
1929                                 reticle_pos.y = 0;
1930                         }
1931                         else
1932                         {
1933                                 reticle_size.x = max(vid_conwidth, vid_conheight);
1934                                 reticle_size.y = max(vid_conwidth, vid_conheight);
1935                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
1936                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
1937                         }
1938
1939                         if(zoomscript_caught)
1940                                 f = 1;
1941                         else
1942                                 f = current_zoomfraction;
1943
1944                         if(f)
1945                         {
1946                                 switch(reticle_type)
1947                                 {
1948                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
1949                                         case 2: drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
1950                                 }
1951                         }
1952                 }
1953         }
1954         else
1955         {
1956                 if(reticle_type != 0) { reticle_type = 0; }
1957         }
1958
1959
1960         // improved polyblend
1961         if(autocvar_hud_contents)
1962         {
1963                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
1964                 vector liquidcolor;
1965
1966                 switch(pointcontents(view_origin))
1967                 {
1968                         case CONTENT_WATER:
1969                                 liquidalpha = autocvar_hud_contents_water_alpha;
1970                                 liquidcolor = stov(autocvar_hud_contents_water_color);
1971                                 incontent = 1;
1972                                 break;
1973
1974                         case CONTENT_LAVA:
1975                                 liquidalpha = autocvar_hud_contents_lava_alpha;
1976                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
1977                                 incontent = 1;
1978                                 break;
1979
1980                         case CONTENT_SLIME:
1981                                 liquidalpha = autocvar_hud_contents_slime_alpha;
1982                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
1983                                 incontent = 1;
1984                                 break;
1985
1986                         default:
1987                                 liquidalpha = 0;
1988                                 liquidcolor = '0 0 0';
1989                                 incontent = 0;
1990                                 break;
1991                 }
1992
1993                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
1994                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
1995                         contentfadetime = autocvar_hud_contents_fadeintime;
1996                         liquidalpha_prev = liquidalpha;
1997                         liquidcolor_prev = liquidcolor;
1998                 }
1999                 else
2000                         contentfadetime = autocvar_hud_contents_fadeouttime;
2001
2002                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
2003                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
2004
2005                 if(contentavgalpha)
2006                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
2007
2008                 if(autocvar_hud_postprocessing)
2009                 {
2010                         if(autocvar_hud_contents_blur && contentavgalpha)
2011                         {
2012                                 content_blurpostprocess.x = 1;
2013                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
2014                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
2015                         }
2016                         else
2017                         {
2018                                 content_blurpostprocess.x = 0;
2019                                 content_blurpostprocess.y = 0;
2020                                 content_blurpostprocess.z = 0;
2021                         }
2022                 }
2023         }
2024
2025         if(autocvar_hud_damage && !STAT(FROZEN))
2026         {
2027                 splash_size.x = max(vid_conwidth, vid_conheight);
2028                 splash_size.y = max(vid_conwidth, vid_conheight);
2029                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2030                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2031
2032                 float myhealth_flash_temp;
2033                 myhealth = STAT(HEALTH);
2034
2035                 // fade out
2036                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2037                 // add new damage
2038                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2039
2040                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2041                 pain_threshold = autocvar_hud_damage_pain_threshold;
2042                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2043                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2044
2045                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2046                 {
2047                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2048                 }
2049
2050                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2051
2052                 if(myhealth_prev < 1)
2053                 {
2054                         if(myhealth >= 1)
2055                         {
2056                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2057                                 myhealth_flash_temp = 0;
2058                         }
2059                         else
2060                         {
2061                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2062                         }
2063                 }
2064
2065                 if(spectatee_status == -1 || intermission)
2066                 {
2067                         myhealth_flash = 0; // observing, or match ended
2068                         myhealth_flash_temp = 0;
2069                 }
2070
2071                 myhealth_prev = myhealth;
2072
2073                 // IDEA: change damage color/picture based on player model for robot/alien species?
2074                 // pro: matches model better
2075                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2076                 // maybe different reddish pics?
2077                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2078                 {
2079                         if(autocvar_cl_gentle_damage == 2)
2080                         {
2081                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2082                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
2083                         }
2084                         else
2085                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2086
2087                         if(myhealth_flash_temp > 0)
2088                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2089                 }
2090                 else if(myhealth_flash_temp > 0)
2091                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2092
2093                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2094                 {
2095                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2096                         {
2097                                 damage_blurpostprocess.x = 1;
2098                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2099                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2100                         }
2101                         else
2102                         {
2103                                 damage_blurpostprocess.x = 0;
2104                                 damage_blurpostprocess.y = 0;
2105                                 damage_blurpostprocess.z = 0;
2106                         }
2107                 }
2108         }
2109
2110         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2111         float e2 = (autocvar_hud_powerup != 0);
2112         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2113         {
2114                 // enable or disable rendering types if they are used or not
2115                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2116                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2117
2118                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2119                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2120                 {
2121                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2122                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2123                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2124                         {
2125                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2126                                 old_blurradius = blurradius;
2127                                 old_bluralpha = bluralpha;
2128                         }
2129                 }
2130                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2131                 {
2132                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2133                         old_blurradius = 0;
2134                         old_bluralpha = 0;
2135                 }
2136
2137                 // edge detection postprocess handling done second (used by hud_powerup)
2138                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2139                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2140                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2141
2142                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2143
2144                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2145                 {
2146                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2147                         {
2148                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2149                                 old_sharpen_intensity = sharpen_intensity;
2150                         }
2151                 }
2152                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2153                 {
2154                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2155                         old_sharpen_intensity = 0;
2156                 }
2157
2158                 if(cvar("r_glsl_postprocess") == 0)
2159                         cvar_set("r_glsl_postprocess", "2");
2160         }
2161         else if(cvar("r_glsl_postprocess") == 2)
2162                 cvar_set("r_glsl_postprocess", "0");
2163
2164         /*if(gametype == MAPINFO_TYPE_CTF)
2165           {
2166           ctf_view();
2167           } else */
2168
2169         // draw 2D entities
2170         FOREACH_ENTITY(it.draw2d, LAMBDA(it.draw2d(it)));
2171         Draw_ShowNames_All();
2172         Debug_Draw();
2173
2174         scoreboard_active = HUD_WouldDrawScoreboard();
2175
2176         HUD_Draw();
2177
2178         if(NextFrameCommand)
2179         {
2180                 localcmd("\n", NextFrameCommand, "\n");
2181                 NextFrameCommand = string_null;
2182         }
2183
2184         // we must do this check AFTER a frame was rendered, or it won't work
2185         if(cs_project_is_b0rked == 0)
2186         {
2187                 string w0, h0;
2188                 w0 = ftos(autocvar_vid_conwidth);
2189                 h0 = ftos(autocvar_vid_conheight);
2190                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2191                 //setproperty(VF_FOV, '90 90 0');
2192                 setproperty(VF_ORIGIN, '0 0 0');
2193                 setproperty(VF_ANGLES, '0 0 0');
2194                 setproperty(VF_PERSPECTIVE, 1);
2195                 makevectors('0 0 0');
2196                 vector v1, v2;
2197                 cvar_set("vid_conwidth", "800");
2198                 cvar_set("vid_conheight", "600");
2199                 v1 = cs_project(v_forward);
2200                 cvar_set("vid_conwidth", "640");
2201                 cvar_set("vid_conheight", "480");
2202                 v2 = cs_project(v_forward);
2203                 if(v1 == v2)
2204                         cs_project_is_b0rked = 1;
2205                 else
2206                         cs_project_is_b0rked = -1;
2207                 cvar_set("vid_conwidth", w0);
2208                 cvar_set("vid_conheight", h0);
2209         }
2210
2211         if(autocvar__hud_configure)
2212                 HUD_Panel_Mouse();
2213         else if ( HUD_MinigameMenu_IsOpened() || minigame_isactive() )
2214                 HUD_Minigame_Mouse();
2215         else if(QuickMenu_IsOpened())
2216                 QuickMenu_Mouse();
2217         else
2218                 HUD_Radar_Mouse();
2219
2220         cl_notice_run();
2221         unpause_update();
2222         Net_Flush();
2223
2224         // let's reset the view back to normal for the end
2225         setproperty(VF_MIN, '0 0 0');
2226         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2227 }
2228
2229
2230 // following vectors must be global to allow seamless switching between camera modes
2231 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2232 void CSQC_Demo_Camera()
2233 {
2234         float speed, attenuation, dimensions;
2235         vector tmp, delta;
2236
2237         if( autocvar_camera_reset || !camera_mode )
2238         {
2239                 camera_offset = '0 0 0';
2240                 current_angles = '0 0 0';
2241                 camera_direction = '0 0 0';
2242                 camera_offset.z += 30;
2243                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2244                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2245                 current_origin = view_origin;
2246                 current_camera_offset  = camera_offset;
2247                 cvar_set("camera_reset", "0");
2248                 camera_mode = CAMERA_CHASE;
2249         }
2250
2251         // Camera angles
2252         if( camera_roll )
2253                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2254
2255         if(autocvar_camera_look_player)
2256         {
2257                 vector dir;
2258                 float n;
2259
2260                 dir = normalize(view_origin - current_position);
2261                 n = mouse_angles.z;
2262                 mouse_angles = vectoangles(dir);
2263                 mouse_angles.x = mouse_angles.x * -1;
2264                 mouse_angles.z = n;
2265         }
2266         else
2267         {
2268                 tmp = getmousepos() * 0.1;
2269                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2270                 {
2271                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2272                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2273                 }
2274         }
2275
2276         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2277         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2278         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2279         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2280
2281         // Fix difference when angles don't have the same sign
2282         delta = '0 0 0';
2283         if(mouse_angles.y < -60 && current_angles.y > 60)
2284                 delta = '0 360 0';
2285         if(mouse_angles.y > 60 && current_angles.y < -60)
2286                 delta = '0 -360 0';
2287
2288         if(autocvar_camera_look_player)
2289                 attenuation = autocvar_camera_look_attenuation;
2290         else
2291                 attenuation = autocvar_camera_speed_attenuation;
2292
2293         attenuation = 1 / max(1, attenuation);
2294         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2295
2296         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2297         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2298         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2299         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2300
2301         // Camera position
2302         tmp = '0 0 0';
2303         dimensions = 0;
2304
2305         if( camera_direction.x )
2306         {
2307                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2308                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2309                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2310                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2311                 ++dimensions;
2312         }
2313
2314         if( camera_direction.y )
2315         {
2316                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2317                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2318                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2319                 ++dimensions;
2320         }
2321
2322         if( camera_direction.z )
2323         {
2324                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2325                 ++dimensions;
2326         }
2327
2328         if(autocvar_camera_free)
2329                 speed = autocvar_camera_speed_free;
2330         else
2331                 speed = autocvar_camera_speed_chase;
2332
2333         if(dimensions)
2334         {
2335                 speed = speed * sqrt(1 / dimensions);
2336                 camera_offset += tmp * speed;
2337         }
2338
2339         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2340
2341         // Camera modes
2342         if( autocvar_camera_free )
2343         {
2344                 if ( camera_mode == CAMERA_CHASE )
2345                 {
2346                         current_camera_offset = current_origin + current_camera_offset;
2347                         camera_offset = current_origin + camera_offset;
2348                 }
2349
2350                 camera_mode = CAMERA_FREE;
2351                 current_position = current_camera_offset;
2352         }
2353         else
2354         {
2355                 if ( camera_mode == CAMERA_FREE )
2356                 {
2357                         current_origin = view_origin;
2358                         camera_offset = camera_offset - current_origin;
2359                         current_camera_offset = current_camera_offset - current_origin;
2360                 }
2361
2362                 camera_mode = CAMERA_CHASE;
2363
2364                 if(autocvar_camera_chase_smoothly)
2365                         current_origin += (view_origin - current_origin) * attenuation;
2366                 else
2367                         current_origin = view_origin;
2368
2369                 current_position = current_origin + current_camera_offset;
2370         }
2371
2372         setproperty(VF_ANGLES, current_angles);
2373         setproperty(VF_ORIGIN, current_position);
2374 }