Cleanup
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / view.qc
1
2 #include "announcer.qh"
3 #include "hook.qh"
4 #include "hud/all.qh"
5 #include "mapvoting.qh"
6 #include "scoreboard.qh"
7 #include "shownames.qh"
8 #include "quickmenu.qh"
9
10 #include "mutators/events.qh"
11
12 #include "../common/constants.qh"
13 #include "../common/debug.qh"
14 #include "../common/mapinfo.qh"
15 #include "../common/gamemodes/all.qh"
16 #include "../common/nades/all.qh"
17 #include "../common/stats.qh"
18 #include "../common/triggers/target/music.qh"
19 #include "../common/teams.qh"
20
21 #include "../common/vehicles/all.qh"
22 #include "../common/weapons/all.qh"
23 #include "../common/viewloc.qh"
24 #include "../common/minigames/cl_minigames.qh"
25 #include "../common/minigames/cl_minigames_hud.qh"
26
27 #include "../lib/csqcmodel/cl_player.qh"
28
29 #include "../lib/warpzone/client.qh"
30 #include "../lib/warpzone/common.qh"
31
32 entity porto;
33 vector polyline[16];
34 void Porto_Draw(entity this)
35 {
36         vector p, dir, ang, q, nextdir;
37         float portal_number, portal1_idx;
38
39         if(activeweapon != WEP_PORTO.m_id || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
40                 return;
41         if(g_balance_porto_secondary)
42                 return;
43         if(intermission == 1)
44                 return;
45         if(intermission == 2)
46                 return;
47         if (getstati(STAT_HEALTH) <= 0)
48                 return;
49
50         dir = view_forward;
51
52         if(angles_held_status)
53         {
54                 makevectors(angles_held);
55                 dir = v_forward;
56         }
57
58         p = view_origin;
59
60         polyline[0] = p;
61         int idx = 1;
62         portal_number = 0;
63         nextdir = dir;
64
65         for (;;)
66         {
67                 dir = nextdir;
68                 traceline(p, p + 65536 * dir, true, porto);
69                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
70                         return;
71                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
72                 p = trace_endpos;
73                 polyline[idx] = p;
74                 ++idx;
75                 if(idx >= 16)
76                         return;
77                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
78                         continue;
79                 ++portal_number;
80                 ang = vectoangles2(trace_plane_normal, dir);
81                 ang.x = -ang.x;
82                 makevectors(ang);
83                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
84                         return;
85                 if(portal_number == 1)
86                 {
87                         portal1_idx = idx;
88                         if(portal_number >= 2)
89                                 break;
90                 }
91         }
92
93         while(idx >= 2)
94         {
95                 p = polyline[idx-2];
96                 q = polyline[idx-1];
97                 if(idx == 2)
98                         p = p - view_up * 16;
99                 if(idx-1 >= portal1_idx)
100                 {
101                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
102                 }
103                 else
104                 {
105                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
106                 }
107                 --idx;
108         }
109 }
110
111 void Porto_Init()
112 {
113         porto = new(porto);
114         make_pure(porto);
115         porto.draw = Porto_Draw;
116         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
117 }
118
119 float drawtime;
120 float avgspeed;
121 vector GetCurrentFov(float fov)
122 {
123         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
124         float velocityzoom, curspeed;
125         vector v;
126
127         zoomsensitivity = autocvar_cl_zoomsensitivity;
128         zoomfactor = autocvar_cl_zoomfactor;
129         if(zoomfactor < 1 || zoomfactor > 30)
130                 zoomfactor = 2.5;
131         zoomspeed = autocvar_cl_zoomspeed;
132         if(zoomspeed >= 0)
133         if(zoomspeed < 0.5 || zoomspeed > 16)
134                         zoomspeed = 3.5;
135
136         zoomdir = button_zoom;
137         if(hud == HUD_NORMAL)
138         if(switchweapon == activeweapon)
139         if((activeweapon == WEP_VORTEX.m_id && vortex_scope) || (activeweapon == WEP_RIFLE.m_id && rifle_scope)) // do NOT use switchweapon here
140                 zoomdir += button_attack2;
141         if(spectatee_status > 0 || isdemo())
142         {
143                 if(spectatorbutton_zoom)
144                 {
145                         if(zoomdir)
146                                 zoomdir = 0;
147                         else
148                                 zoomdir = 1;
149                 }
150                 // fteqcc failed twice here already, don't optimize this
151         }
152
153         if(zoomdir) { zoomin_effect = 0; }
154
155         if(camera_active)
156         {
157                 current_viewzoom = min(1, current_viewzoom + drawframetime);
158         }
159         else if(autocvar_cl_spawnzoom && zoomin_effect)
160         {
161                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
162
163                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
164                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
165                 if(current_viewzoom == 1) { zoomin_effect = 0; }
166         }
167         else
168         {
169                 if(zoomspeed < 0) // instant zoom
170                 {
171                         if(zoomdir)
172                                 current_viewzoom = 1 / zoomfactor;
173                         else
174                                 current_viewzoom = 1;
175                 }
176                 else
177                 {
178                         if(zoomdir)
179                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
180                         else
181                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
182                 }
183         }
184
185         if(almost_equals(current_viewzoom, 1))
186                 current_zoomfraction = 0;
187         else if(almost_equals(current_viewzoom, 1/zoomfactor))
188                 current_zoomfraction = 1;
189         else
190                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
191
192         if(zoomsensitivity < 1)
193                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
194         else
195                 setsensitivityscale(1);
196
197         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
198         {
199                 if(intermission) { curspeed = 0; }
200                 else
201                 {
202
203                         makevectors(view_angles);
204                         v = pmove_vel;
205                         if(csqcplayer)
206                                 v = csqcplayer.velocity;
207
208                         switch(autocvar_cl_velocityzoom_type)
209                         {
210                                 case 3: curspeed = max(0, v_forward * v); break;
211                                 case 2: curspeed = (v_forward * v); break;
212                                 case 1: default: curspeed = vlen(v); break;
213                         }
214                 }
215
216                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
217                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
218                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
219
220                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
221         }
222         else
223                 velocityzoom = 1;
224
225         float frustumx, frustumy, fovx, fovy;
226         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
227         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
228         fovx = atan2(frustumx, 1) / M_PI * 360.0;
229         fovy = atan2(frustumy, 1) / M_PI * 360.0;
230
231         return '1 0 0' * fovx + '0 1 0' * fovy;
232 }
233
234 vector GetViewLocationFOV(float fov)
235 {
236         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
237         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
238         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
239         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
240         return '1 0 0' * fovx + '0 1 0' * fovy;
241 }
242
243 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
244 {
245         float fovx, fovy;
246         float width = (ov_worldmax.x - ov_worldmin.x);
247         float height = (ov_worldmax.y - ov_worldmin.y);
248         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
249         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
250         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
251         return '1 0 0' * fovx + '0 1 0' * fovy;
252 }
253
254 // this function must match W_SetupShot!
255 float zoomscript_caught;
256
257 vector wcross_origin;
258 float wcross_scale_prev, wcross_alpha_prev;
259 vector wcross_color_prev;
260 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
261 vector wcross_color_goal_prev;
262 float wcross_changedonetime;
263
264 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
265 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
266 float wcross_name_changestarttime, wcross_name_changedonetime;
267 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
268
269 float wcross_ring_prev;
270
271 entity trueaim;
272 entity trueaim_rifle;
273
274 const float SHOTTYPE_HITTEAM = 1;
275 const float SHOTTYPE_HITOBSTRUCTION = 2;
276 const float SHOTTYPE_HITWORLD = 3;
277 const float SHOTTYPE_HITENEMY = 4;
278
279 void TrueAim_Init()
280 {
281         trueaim = new(trueaim);
282         make_pure(trueaim);
283         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
284         trueaim_rifle = new(trueaim_rifle);
285         make_pure(trueaim_rifle);
286         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
287 }
288
289 float EnemyHitCheck()
290 {
291         float t, n;
292         wcross_origin = project_3d_to_2d(trace_endpos);
293         wcross_origin.z = 0;
294         if(trace_ent)
295                 n = trace_ent.entnum;
296         else
297                 n = trace_networkentity;
298         if(n < 1)
299                 return SHOTTYPE_HITWORLD;
300         if(n > maxclients)
301                 return SHOTTYPE_HITWORLD;
302         t = GetPlayerColor(n - 1);
303         if(teamplay)
304                 if(t == myteam)
305                         return SHOTTYPE_HITTEAM;
306         if(t == NUM_SPECTATOR)
307                 return SHOTTYPE_HITWORLD;
308         return SHOTTYPE_HITENEMY;
309 }
310
311 float TrueAimCheck()
312 {
313         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
314         vector vecs, trueaimpoint, w_shotorg;
315         vector mi, ma, dv;
316         float shottype;
317         entity ta;
318         float mv;
319
320         mi = ma = '0 0 0';
321         ta = trueaim;
322         mv = MOVE_NOMONSTERS;
323
324         switch(activeweapon) // WEAPONTODO
325         {
326                 case WEP_TUBA.m_id: // no aim
327                 case WEP_PORTO.m_id: // shoots from eye
328                 case WEP_NEXBALL.m_id: // shoots from eye
329                 case WEP_HOOK.m_id: // no trueaim
330                 case WEP_MORTAR.m_id: // toss curve
331                         return SHOTTYPE_HITWORLD;
332                 case WEP_VORTEX.m_id:
333                 case WEP_VAPORIZER.m_id:
334                         mv = MOVE_NORMAL;
335                         break;
336                 case WEP_RIFLE.m_id:
337                         ta = trueaim_rifle;
338                         mv = MOVE_NORMAL;
339                         if(zoomscript_caught)
340                         {
341                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
342                                 return EnemyHitCheck();
343                         }
344                         break;
345                 case WEP_DEVASTATOR.m_id: // projectile has a size!
346                         mi = '-3 -3 -3';
347                         ma = '3 3 3';
348                         break;
349                 case WEP_FIREBALL.m_id: // projectile has a size!
350                         mi = '-16 -16 -16';
351                         ma = '16 16 16';
352                         break;
353                 case WEP_SEEKER.m_id: // projectile has a size!
354                         mi = '-2 -2 -2';
355                         ma = '2 2 2';
356                         break;
357                 case WEP_ELECTRO.m_id: // projectile has a size!
358                         mi = '0 0 -3';
359                         ma = '0 0 -3';
360                         break;
361         }
362
363         vector traceorigin = getplayerorigin(player_localentnum-1) + (eZ * getstati(STAT_VIEWHEIGHT));
364
365         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
366
367         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
368         trueaimpoint = trace_endpos;
369
370         if(vlen(trueaimpoint - traceorigin) < g_trueaim_minrange)
371                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
372
373         if(vecs.x > 0)
374                 vecs.y = -vecs.y;
375         else
376                 vecs = '0 0 0';
377
378         dv = view_right * vecs.y + view_up * vecs.z;
379         w_shotorg = traceorigin + dv;
380
381         // now move the vecs forward as much as requested if possible
382         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
383         w_shotorg = trace_endpos - view_forward * nudge;
384
385         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
386         shottype = EnemyHitCheck();
387         if(shottype != SHOTTYPE_HITWORLD)
388                 return shottype;
389
390 #if 0
391         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
392         // or rather, I know why, but see no fix
393         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
394                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
395                 return SHOTTYPE_HITOBSTRUCTION;
396 #endif
397
398         return SHOTTYPE_HITWORLD;
399 }
400
401 void PostInit();
402 void CSQC_Demo_Camera();
403 float HUD_WouldDrawScoreboard();
404 float camera_mode;
405 const float CAMERA_FREE = 1;
406 const float CAMERA_CHASE = 2;
407 float reticle_type;
408 string reticle_image;
409 string NextFrameCommand;
410
411 vector freeze_org, freeze_ang;
412 entity nightvision_noise, nightvision_noise2;
413
414 const float MAX_TIME_DIFF = 5;
415 float pickup_crosshair_time, pickup_crosshair_size;
416 float hitindication_crosshair_size;
417 float use_vortex_chargepool;
418
419 float myhealth, myhealth_prev;
420 float myhealth_flash;
421
422 float old_blurradius, old_bluralpha;
423 float old_sharpen_intensity;
424
425 vector myhealth_gentlergb;
426
427 float contentavgalpha, liquidalpha_prev;
428 vector liquidcolor_prev;
429
430 float eventchase_current_distance;
431 float eventchase_running;
432 bool WantEventchase()
433 {SELFPARAM();
434         if(autocvar_cl_orthoview)
435                 return false;
436         if(intermission)
437                 return true;
438         if(self.viewloc)
439                 return true;
440         if(spectatee_status >= 0)
441         {
442                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
443                         return true;
444                 if(MUTATOR_CALLHOOK(WantEventchase, self))
445                         return true;
446                 if(autocvar_cl_eventchase_nexball && gametype == MAPINFO_TYPE_NEXBALL && !(WepSet_GetFromStat() & WepSet_FromWeapon(WEP_NEXBALL.m_id)))
447                         return true;
448                 if(autocvar_cl_eventchase_death && (getstati(STAT_HEALTH) <= 0))
449                 {
450                         if(autocvar_cl_eventchase_death == 2)
451                         {
452                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
453                                 if(self.velocity == '0 0 0' || eventchase_running)
454                                         return true;
455                         }
456                         else return true;
457                 }
458         }
459         return false;
460 }
461
462 void HUD_Crosshair_Vehicle()
463 {
464         if(hud != HUD_BUMBLEBEE_GUN)
465         {
466                 Vehicle info = get_vehicleinfo(hud);
467                 info.vr_crosshair(info);
468         }
469 }
470
471 vector damage_blurpostprocess, content_blurpostprocess;
472
473 float unaccounted_damage = 0;
474 void UpdateDamage()
475 {
476         // accumulate damage with each stat update
477         static float damage_total_prev = 0;
478         float damage_total = getstati(STAT_DAMAGE_DEALT_TOTAL);
479         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
480         damage_total_prev = damage_total;
481
482         static float damage_dealt_time_prev = 0;
483         float damage_dealt_time = getstatf(STAT_HIT_TIME);
484         if (damage_dealt_time != damage_dealt_time_prev)
485         {
486                 unaccounted_damage += unaccounted_damage_new;
487                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")", "\n");
488         }
489         damage_dealt_time_prev = damage_dealt_time;
490
491         // prevent hitsound when switching spectatee
492         static float spectatee_status_prev = 0;
493         if (spectatee_status != spectatee_status_prev)
494                 unaccounted_damage = 0;
495         spectatee_status_prev = spectatee_status;
496 }
497
498 void HitSound()
499 {
500         // varying sound pitch
501
502         static float hitsound_time_prev = 0;
503         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
504         float arc_hack = activeweapon == WEP_ARC.m_id && autocvar_cl_hitsound >= 2;
505         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
506         {
507                 if (autocvar_cl_hitsound && unaccounted_damage)
508                 {
509                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
510                         float a = autocvar_cl_hitsound_max_pitch;
511                         float b = autocvar_cl_hitsound_min_pitch;
512                         float c = autocvar_cl_hitsound_nom_damage;
513                         float x = unaccounted_damage;
514                         float pitch_shift = (b*x*(a-1) + a*c*(1-b)) / (x*(a-1) + c*(1-b));
515
516                         // if sound variation is disabled, set pitch_shift to 1
517                         if (autocvar_cl_hitsound == 1)
518                                 pitch_shift = 1;
519
520                         // if pitch shift is reversed, mirror in (max-min)/2 + min
521                         if (autocvar_cl_hitsound == 3)
522                         {
523                                 float mirror_value = (a-b)/2 + b;
524                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
525                         }
526
527                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift), "\n");
528
529                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
530                         // todo: normalize sound pressure levels? seems unnecessary
531
532                         sound7(world, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
533                 }
534                 unaccounted_damage = 0;
535                 hitsound_time_prev = time;
536         }
537
538         static float typehit_time_prev = 0;
539         float typehit_time = getstatf(STAT_TYPEHIT_TIME);
540         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
541         {
542                 sound(world, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
543                 typehit_time_prev = typehit_time;
544         }
545 }
546
547 void HUD_Crosshair()
548 {SELFPARAM();
549         static float rainbow_last_flicker;
550         static vector rainbow_prev_color;
551         entity e = self;
552         float f, i, j;
553         vector v;
554         if(!scoreboard_active && !camera_active && intermission != 2 &&
555                 spectatee_status != -1 && !csqcplayer.viewloc &&
556                 !HUD_MinigameMenu_IsOpened() )
557         {
558                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
559                         return;
560
561                 if (hud != HUD_NORMAL)
562                 {
563                         HUD_Crosshair_Vehicle();
564                         return;
565                 }
566
567                 string wcross_style;
568                 float wcross_alpha, wcross_resolution;
569                 wcross_style = autocvar_crosshair;
570                 if (wcross_style == "0")
571                         return;
572                 wcross_resolution = autocvar_crosshair_size;
573                 if (wcross_resolution == 0)
574                         return;
575                 wcross_alpha = autocvar_crosshair_alpha;
576                 if (wcross_alpha == 0)
577                         return;
578
579                 // TrueAim check
580                 float shottype;
581
582                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
583                 wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
584                 wcross_origin.z = 0;
585                 if(autocvar_crosshair_hittest)
586                 {
587                         vector wcross_oldorigin;
588                         wcross_oldorigin = wcross_origin;
589                         shottype = TrueAimCheck();
590                         if(shottype == SHOTTYPE_HITWORLD)
591                         {
592                                 v = wcross_origin - wcross_oldorigin;
593                                 v.x /= vid_conwidth;
594                                 v.y /= vid_conheight;
595                                 if(vlen(v) > 0.01)
596                                         shottype = SHOTTYPE_HITOBSTRUCTION;
597                         }
598                         if(!autocvar_crosshair_hittest_showimpact)
599                                 wcross_origin = wcross_oldorigin;
600                 }
601                 else
602                         shottype = SHOTTYPE_HITWORLD;
603
604                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
605                 string wcross_name = "";
606                 float wcross_scale, wcross_blur;
607
608                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
609                 {
610                         e = get_weaponinfo(switchingweapon);
611                         if(e)
612                         {
613                                 if(autocvar_crosshair_per_weapon)
614                                 {
615                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
616                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
617                                         //if (wcross_resolution == 0)
618                                                 //return;
619
620                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
621                                         wcross_resolution *= e.w_crosshair_size;
622                                         wcross_name = e.w_crosshair;
623                                 }
624                         }
625                 }
626
627                 if(wcross_name == "")
628                         wcross_name = strcat("gfx/crosshair", wcross_style);
629
630                 // MAIN CROSSHAIR COLOR DECISION
631                 switch(autocvar_crosshair_color_special)
632                 {
633                         case 1: // crosshair_color_per_weapon
634                         {
635                                 if(e)
636                                 {
637                                         wcross_color = e.wpcolor;
638                                         break;
639                                 }
640                                 else { goto normalcolor; }
641                         }
642
643                         case 2: // crosshair_color_by_health
644                         {
645                                 float x = getstati(STAT_HEALTH);
646
647                                 //x = red
648                                 //y = green
649                                 //z = blue
650
651                                 wcross_color.z = 0;
652
653                                 if(x > 200)
654                                 {
655                                         wcross_color.x = 0;
656                                         wcross_color.y = 1;
657                                 }
658                                 else if(x > 150)
659                                 {
660                                         wcross_color.x = 0.4 - (x-150)*0.02 * 0.4;
661                                         wcross_color.y = 0.9 + (x-150)*0.02 * 0.1;
662                                 }
663                                 else if(x > 100)
664                                 {
665                                         wcross_color.x = 1 - (x-100)*0.02 * 0.6;
666                                         wcross_color.y = 1 - (x-100)*0.02 * 0.1;
667                                         wcross_color.z = 1 - (x-100)*0.02;
668                                 }
669                                 else if(x > 50)
670                                 {
671                                         wcross_color.x = 1;
672                                         wcross_color.y = 1;
673                                         wcross_color.z = 0.2 + (x-50)*0.02 * 0.8;
674                                 }
675                                 else if(x > 20)
676                                 {
677                                         wcross_color.x = 1;
678                                         wcross_color.y = (x-20)*90/27/100;
679                                         wcross_color.z = (x-20)*90/27/100 * 0.2;
680                                 }
681                                 else
682                                 {
683                                         wcross_color.x = 1;
684                                         wcross_color.y = 0;
685                                 }
686                                 break;
687                         }
688
689                         case 3: // crosshair_color_rainbow
690                         {
691                                 if(time >= rainbow_last_flicker)
692                                 {
693                                         rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
694                                         rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
695                                 }
696                                 wcross_color = rainbow_prev_color;
697                                 break;
698                         }
699                         :normalcolor
700                         default: { wcross_color = stov(autocvar_crosshair_color); break; }
701                 }
702
703                 if(autocvar_crosshair_effect_scalefade)
704                 {
705                         wcross_scale = wcross_resolution;
706                         wcross_resolution = 1;
707                 }
708                 else
709                 {
710                         wcross_scale = 1;
711                 }
712
713                 if(autocvar_crosshair_pickup)
714                 {
715                         float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
716
717                         if(pickup_crosshair_time < stat_pickup_time)
718                         {
719                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
720                                         pickup_crosshair_size = 1;
721
722                                 pickup_crosshair_time = stat_pickup_time;
723                         }
724
725                         if(pickup_crosshair_size > 0)
726                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
727                         else
728                                 pickup_crosshair_size = 0;
729
730                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
731                 }
732
733                 // todo: make crosshair hit indication dependent on damage dealt
734                 if(autocvar_crosshair_hitindication)
735                 {
736                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
737
738                         if(unaccounted_damage)
739                         {
740                                 hitindication_crosshair_size = 1;
741                         }
742
743                         if(hitindication_crosshair_size > 0)
744                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
745                         else
746                                 hitindication_crosshair_size = 0;
747
748                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
749                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
750                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
751                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
752                 }
753
754                 if(shottype == SHOTTYPE_HITENEMY)
755                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
756                 if(shottype == SHOTTYPE_HITTEAM)
757                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
758
759                 f = fabs(autocvar_crosshair_effect_time);
760                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
761                 {
762                         wcross_changedonetime = time + f;
763                 }
764                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
765                 {
766                         wcross_name_changestarttime = time;
767                         wcross_name_changedonetime = time + f;
768                         if(wcross_name_goal_prev_prev)
769                                 strunzone(wcross_name_goal_prev_prev);
770                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
771                         wcross_name_goal_prev = strzone(wcross_name);
772                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
773                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
774                         wcross_resolution_goal_prev = wcross_resolution;
775                 }
776
777                 wcross_scale_goal_prev = wcross_scale;
778                 wcross_alpha_goal_prev = wcross_alpha;
779                 wcross_color_goal_prev = wcross_color;
780
781                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
782                 {
783                         wcross_blur = 1;
784                         wcross_alpha *= 0.75;
785                 }
786                 else
787                         wcross_blur = 0;
788                 // *_prev is at time-frametime
789                 // * is at wcross_changedonetime+f
790                 // what do we have at time?
791                 if(time < wcross_changedonetime)
792                 {
793                         f = frametime / (wcross_changedonetime - time + frametime);
794                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
795                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
796                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
797                 }
798
799                 wcross_scale_prev = wcross_scale;
800                 wcross_alpha_prev = wcross_alpha;
801                 wcross_color_prev = wcross_color;
802
803                 MUTATOR_CALLHOOK(UpdateCrosshair);
804
805                 wcross_scale *= 1 - autocvar__menu_alpha;
806                 wcross_alpha *= 1 - autocvar__menu_alpha;
807                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
808
809                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
810                 {
811                         // crosshair rings for weapon stats
812                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
813                         {
814                                 // declarations and stats
815                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
816                                 string ring_image = string_null, ring_inner_image = string_null;
817                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
818
819                                 ring_scale = autocvar_crosshair_ring_size;
820
821                                 float weapon_clipload, weapon_clipsize;
822                                 weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
823                                 weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
824
825                                 float ok_ammo_charge, ok_ammo_chargepool;
826                                 ok_ammo_charge = getstatf(STAT_OK_AMMO_CHARGE);
827                                 ok_ammo_chargepool = getstatf(STAT_OK_AMMO_CHARGEPOOL);
828
829                                 float vortex_charge, vortex_chargepool;
830                                 vortex_charge = getstatf(STAT_VORTEX_CHARGE);
831                                 vortex_chargepool = getstatf(STAT_VORTEX_CHARGEPOOL);
832
833                                 float arc_heat = getstatf(STAT_ARC_HEAT);
834
835                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
836                                         vortex_charge_movingavg = vortex_charge;
837
838
839                                 // handle the values
840                                 if (autocvar_crosshair_ring && activeweapon == WEP_VORTEX.m_id && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
841                                 {
842                                         if (vortex_chargepool || use_vortex_chargepool) {
843                                                 use_vortex_chargepool = 1;
844                                                 ring_inner_value = vortex_chargepool;
845                                         } else {
846                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
847                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
848                                         }
849
850                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
851                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
852                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
853
854                                         // draw the outer ring to show the current charge of the weapon
855                                         ring_value = vortex_charge;
856                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
857                                         ring_rgb = wcross_color;
858                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
859                                 }
860                                 else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER.m_id && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
861                                 {
862                                         ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
863                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
864                                         ring_rgb = wcross_color;
865                                         ring_image = "gfx/crosshair_ring.tga";
866                                 }
867                                 else if (activeweapon == WEP_HAGAR.m_id && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
868                                 {
869                                         ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
870                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
871                                         ring_rgb = wcross_color;
872                                         ring_image = "gfx/crosshair_ring.tga";
873                                 }
874                                 else if (ok_ammo_charge)
875                                 {
876                                         ring_value = ok_ammo_chargepool;
877                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
878                                         ring_rgb = wcross_color;
879                                         ring_image = "gfx/crosshair_ring.tga";
880                                 }
881                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
882                                 {
883                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
884                                         ring_scale = autocvar_crosshair_ring_reload_size;
885                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
886                                         ring_rgb = wcross_color;
887
888                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
889                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
890                                         if ((activeweapon == WEP_RIFLE.m_id) && (weapon_clipsize == 80))
891                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
892                                         else
893                                                 ring_image = "gfx/crosshair_ring.tga";
894                                 }
895                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && activeweapon == WEP_ARC.m_id )
896                                 {
897                                         ring_value = arc_heat;
898                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
899                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
900                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
901                                         ring_image = "gfx/crosshair_ring.tga";
902                                 }
903
904                                 // if in weapon switch animation, fade ring out/in
905                                 if(autocvar_crosshair_effect_time > 0)
906                                 {
907                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
908                                         if (f >= 1)
909                                         {
910                                                 wcross_ring_prev = ((ring_image) ? true : false);
911                                         }
912
913                                         if(wcross_ring_prev)
914                                         {
915                                                 if(f < 1)
916                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
917                                         }
918                                         else
919                                         {
920                                                 if(f < 1)
921                                                         ring_alpha *= bound(0, f, 1);
922                                         }
923                                 }
924
925                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
926                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
927
928                                 if (ring_value)
929                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
930                         }
931
932 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
933                         do \
934                         { \
935                                 if(wcross_blur > 0) \
936                                 { \
937                                         for(i = -2; i <= 2; ++i) \
938                                         for(j = -2; j <= 2; ++j) \
939                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
940                                 } \
941                                 else \
942                                 { \
943                                         M(0,0,sz,wcross_name,wcross_alpha); \
944                                 } \
945                         } \
946                         while(0)
947
948 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
949                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
950
951 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
952                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
953
954                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
955                         {
956                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
957                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
958                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
959                                 f = 1 - f;
960                         }
961                         else
962                         {
963                                 f = 1;
964                         }
965                         wcross_name_alpha_goal_prev = f;
966
967                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
968                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
969
970                         if(autocvar_crosshair_dot)
971                         {
972                                 vector wcross_color_old;
973                                 wcross_color_old = wcross_color;
974
975                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
976                                         wcross_color = stov(autocvar_crosshair_dot_color);
977
978                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
979                                 // FIXME why don't we use wcross_alpha here?cl_notice_run();
980                                 wcross_color = wcross_color_old;
981                         }
982                 }
983         }
984         else
985         {
986                 wcross_scale_prev = 0;
987                 wcross_alpha_prev = 0;
988                 wcross_scale_goal_prev = 0;
989                 wcross_alpha_goal_prev = 0;
990                 wcross_changedonetime = 0;
991                 if(wcross_name_goal_prev)
992                         strunzone(wcross_name_goal_prev);
993                 wcross_name_goal_prev = string_null;
994                 if(wcross_name_goal_prev_prev)
995                         strunzone(wcross_name_goal_prev_prev);
996                 wcross_name_goal_prev_prev = string_null;
997                 wcross_name_changestarttime = 0;
998                 wcross_name_changedonetime = 0;
999                 wcross_name_alpha_goal_prev = 0;
1000                 wcross_name_alpha_goal_prev_prev = 0;
1001                 wcross_resolution_goal_prev = 0;
1002                 wcross_resolution_goal_prev_prev = 0;
1003         }
1004 }
1005
1006 void HUD_Draw()
1007 {
1008         if(getstati(STAT_FROZEN))
1009                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, ((getstatf(STAT_REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * getstatf(STAT_REVIVE_PROGRESS)) + ('0 1 1' * getstatf(STAT_REVIVE_PROGRESS) * -1)) : '0.25 0.90 1'), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1010         else if (getstatf(STAT_HEALING_ORB)>time)
1011                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, NADE_TYPE_HEAL.m_color, autocvar_hud_colorflash_alpha*getstatf(STAT_HEALING_ORB_ALPHA), DRAWFLAG_ADDITIVE);
1012         if(!intermission)
1013         if(getstatf(STAT_NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1014         {
1015                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * getstatf(STAT_NADE_TIMER)) - ('0 1 1' * getstatf(STAT_NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1016                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1017         }
1018         else if(getstatf(STAT_REVIVE_PROGRESS))
1019         {
1020                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1021                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1022         }
1023
1024         if(autocvar_r_letterbox == 0)
1025                 if(autocvar_viewsize < 120)
1026                 {
1027                         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1028                                 Accuracy_LoadLevels();
1029
1030                         HUD_Main();
1031                         HUD_DrawScoreboard();
1032                 }
1033
1034         // crosshair goes VERY LAST
1035         UpdateDamage();
1036         HUD_Crosshair();
1037         HitSound();
1038 }
1039
1040 bool ov_enabled;
1041 float oldr_nearclip;
1042 float oldr_farclip_base;
1043 float oldr_farclip_world;
1044 float oldr_novis;
1045 float oldr_useportalculling;
1046 float oldr_useinfinitefarclip;
1047
1048 const int BUTTON_3 = 4;
1049 const int BUTTON_4 = 8;
1050 float cl_notice_run();
1051 float prev_myteam;
1052 int lasthud;
1053 float vh_notice_time;
1054 void WaypointSprite_Load();
1055 void CSQC_UpdateView(float w, float h)
1056 {SELFPARAM();
1057         entity e;
1058         float fov;
1059         float f;
1060         vector vf_size, vf_min;
1061         float a;
1062
1063         execute_next_frame();
1064
1065         ++framecount;
1066
1067         hud = getstati(STAT_HUD);
1068
1069         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1070                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1071
1072         lasthud = hud;
1073
1074         if(autocvar__hud_showbinds_reload) // menu can set this one
1075         {
1076                 db_close(binddb);
1077                 binddb = db_create();
1078                 cvar_set("_hud_showbinds_reload", "0");
1079         }
1080
1081         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1082                 view_quality = getproperty(VF_MINFPS_QUALITY);
1083         else
1084                 view_quality = 1;
1085
1086         button_attack2 = (input_buttons & BUTTON_3);
1087         button_zoom = (input_buttons & BUTTON_4);
1088
1089         vf_size = getpropertyvec(VF_SIZE);
1090         vf_min = getpropertyvec(VF_MIN);
1091         vid_width = vf_size.x;
1092         vid_height = vf_size.y;
1093
1094         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1095         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1096
1097         WaypointSprite_Load();
1098
1099         CSQCPlayer_SetCamera();
1100
1101         if(player_localentnum <= maxclients) // is it a client?
1102                 current_player = player_localentnum - 1;
1103         else // then player_localentnum is the vehicle I'm driving
1104                 current_player = player_localnum;
1105         myteam = GetPlayerColor(current_player);
1106
1107         if(myteam != prev_myteam)
1108         {
1109                 myteamcolors = colormapPaletteColor(myteam, 1);
1110                 FOREACH(hud_panels, true, LAMBDA(it.update_time = time));
1111                 prev_myteam = myteam;
1112         }
1113
1114         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
1115
1116         float is_dead = (getstati(STAT_HEALTH) <= 0);
1117
1118         // FIXME do we need this hack?
1119         if(isdemo())
1120         {
1121                 // in demos, input_buttons do not work
1122                 button_zoom = (autocvar__togglezoom == "-");
1123         }
1124         else if(button_zoom
1125                 && autocvar_cl_unpress_zoom_on_death
1126                 && (spectatee_status >= 0)
1127                 && (is_dead || intermission))
1128         {
1129                 // no zoom while dead or in intermission please
1130                 localcmd("-zoom\n");
1131                 button_zoom = false;
1132         }
1133
1134         // event chase camera
1135         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1136         {
1137                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1138                 float ons_roundlost = (gametype == MAPINFO_TYPE_ONSLAUGHT && getstati(STAT_ROUNDLOST));
1139                 entity gen = world;
1140
1141                 if(ons_roundlost)
1142                 {
1143                         entity e;
1144                         for(e = world; (e = find(e, classname, "onslaught_generator")); )
1145                         {
1146                                 if(e.health <= 0)
1147                                 {
1148                                         gen = e;
1149                                         break;
1150                                 }
1151                         }
1152                         if(!gen)
1153                                 ons_roundlost = FALSE; // don't enforce the 3rd person camera if there is no dead generator to show
1154                 }
1155                 if(WantEventchase() || (!autocvar_cl_orthoview && ons_roundlost))
1156                 {
1157                         eventchase_running = true;
1158
1159                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1160                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1161                         if(ons_roundlost) { current_view_origin = gen.origin; }
1162
1163                         // detect maximum viewoffset and use it
1164                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1165                         if(vehicle_chase && autocvar_cl_eventchase_vehicle_viewoffset) { view_offset = autocvar_cl_eventchase_vehicle_viewoffset; }
1166                         if(ons_roundlost) { view_offset = autocvar_cl_eventchase_generator_viewoffset; }
1167
1168                         if(view_offset)
1169                         {
1170                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, self);
1171                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1172                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1173                         }
1174
1175                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1176                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1177                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1178                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1179
1180                         // make the camera smooth back
1181                         float chase_distance = autocvar_cl_eventchase_distance;
1182                         if(vehicle_chase && autocvar_cl_eventchase_vehicle_distance) { chase_distance = autocvar_cl_eventchase_vehicle_distance; }
1183                         if(ons_roundlost) { chase_distance = autocvar_cl_eventchase_generator_distance; }
1184
1185                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1186                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1187                         else if(eventchase_current_distance != chase_distance)
1188                                 eventchase_current_distance = chase_distance;
1189
1190                         makevectors(view_angles);
1191
1192                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1193                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
1194
1195                         // If the boxtrace fails, revert back to line tracing.
1196                         if(!self.viewloc)
1197                         if(trace_startsolid)
1198                         {
1199                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1200                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
1201                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1202                         }
1203                         else { setproperty(VF_ORIGIN, trace_endpos); }
1204
1205                         if(!self.viewloc)
1206                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1207                 }
1208                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1209                 {
1210                         eventchase_running = false;
1211                         cvar_set("chase_active", "0");
1212                         eventchase_current_distance = 0; // start from 0 next time
1213                 }
1214         }
1215         // workaround for camera stuck between player's legs when using chase_active 1
1216         // because the engine stops updating the chase_active camera when the game ends
1217         else if(intermission)
1218         {
1219                 cvar_settemp("chase_active", "-1");
1220                 eventchase_current_distance = 0;
1221         }
1222
1223         // do lockview after event chase camera so that it still applies whenever necessary.
1224         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1225         {
1226                 setproperty(VF_ORIGIN, freeze_org);
1227                 setproperty(VF_ANGLES, freeze_ang);
1228         }
1229         else
1230         {
1231                 freeze_org = getpropertyvec(VF_ORIGIN);
1232                 freeze_ang = getpropertyvec(VF_ANGLES);
1233         }
1234
1235         WarpZone_FixView();
1236         //WarpZone_FixPMove();
1237
1238         vector ov_org = '0 0 0';
1239         vector ov_mid = '0 0 0';
1240         vector ov_worldmin = '0 0 0';
1241         vector ov_worldmax = '0 0 0';
1242         if(autocvar_cl_orthoview)
1243         {
1244                 ov_worldmin = mi_picmin;
1245                 ov_worldmax = mi_picmax;
1246
1247                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1248                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1249                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1250
1251                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1252                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1253
1254                 float ov_nearest = vlen(ov_org - vec3(
1255                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1256                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1257                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1258                 ));
1259
1260                 float ov_furthest = 0;
1261                 float dist = 0;
1262
1263                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1264                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1265                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1266                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1267                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1268                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1269                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1270                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1271
1272                 if(!ov_enabled)
1273                 {
1274                         oldr_nearclip = cvar("r_nearclip");
1275                         oldr_farclip_base = cvar("r_farclip_base");
1276                         oldr_farclip_world = cvar("r_farclip_world");
1277                         oldr_novis = cvar("r_novis");
1278                         oldr_useportalculling = cvar("r_useportalculling");
1279                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1280                 }
1281
1282                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1283                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1284                 cvar_settemp("r_farclip_world", "0");
1285                 cvar_settemp("r_novis", "1");
1286                 cvar_settemp("r_useportalculling", "0");
1287                 cvar_settemp("r_useinfinitefarclip", "0");
1288
1289                 setproperty(VF_ORIGIN, ov_org);
1290                 setproperty(VF_ANGLES, '90 0 0');
1291
1292                 ov_enabled = true;
1293
1294                 #if 0
1295                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1296                         vtos(ov_org),
1297                         vtos(getpropertyvec(VF_ANGLES)),
1298                         ov_distance,
1299                         ov_nearest,
1300                         ov_furthest);
1301                 #endif
1302         }
1303         else
1304         {
1305                 if(ov_enabled)
1306                 {
1307                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1308                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1309                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1310                         cvar_set("r_novis", ftos(oldr_novis));
1311                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1312                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1313                 }
1314                 ov_enabled = false;
1315         }
1316
1317         // Render the Scene
1318         view_origin = getpropertyvec(VF_ORIGIN);
1319         view_angles = getpropertyvec(VF_ANGLES);
1320         makevectors(view_angles);
1321         view_forward = v_forward;
1322         view_right = v_right;
1323         view_up = v_up;
1324
1325 #ifdef BLURTEST
1326         if(time > blurtest_time0 && time < blurtest_time1)
1327         {
1328                 float r, t;
1329
1330                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1331                 r = t * blurtest_radius;
1332                 f = 1 / pow(t, blurtest_power) - 1;
1333
1334                 cvar_set("r_glsl_postprocess", "1");
1335                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1336         }
1337         else
1338         {
1339                 cvar_set("r_glsl_postprocess", "0");
1340                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1341         }
1342 #endif
1343
1344         TargetMusic_Advance();
1345         Fog_Force();
1346
1347         if(drawtime == 0)
1348                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1349         else
1350                 drawframetime = bound(0.000001, time - drawtime, 1);
1351         drawtime = time;
1352
1353         // watch for gametype changes here...
1354         // in ParseStuffCMD the cmd isn't executed yet :/
1355         // might even be better to add the gametype to TE_CSQC_INIT...?
1356         if(!postinit)
1357                 PostInit();
1358
1359         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1360         {
1361                 if(calledhooks & HOOK_START)
1362                 {
1363                         localcmd("\ncl_hook_gameend\n");
1364                         calledhooks |= HOOK_END;
1365                 }
1366         }
1367
1368         Announcer();
1369
1370         fov = autocvar_fov;
1371         if(fov <= 59.5)
1372         {
1373                 if(!zoomscript_caught)
1374                 {
1375                         localcmd("+button9\n");
1376                         zoomscript_caught = 1;
1377                 }
1378         }
1379         else
1380         {
1381                 if(zoomscript_caught)
1382                 {
1383                         localcmd("-button9\n");
1384                         zoomscript_caught = 0;
1385                 }
1386         }
1387
1388         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1389
1390         // next WANTED weapon (for HUD)
1391         switchweapon = getstati(STAT_SWITCHWEAPON);
1392
1393         // currently switching-to weapon (for crosshair)
1394         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
1395
1396         // actually active weapon (for zoom)
1397         activeweapon = getstati(STAT_ACTIVEWEAPON);
1398
1399         f = (serverflags & SERVERFLAG_TEAMPLAY);
1400         if(f != teamplay)
1401         {
1402                 teamplay = f;
1403                 HUD_InitScores();
1404         }
1405
1406         if(last_switchweapon != switchweapon)
1407         {
1408                 weapontime = time;
1409                 last_switchweapon = switchweapon;
1410                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1411                 {
1412                         localcmd("-zoom\n");
1413                         button_zoom = false;
1414                 }
1415                 if(autocvar_cl_unpress_attack_on_weapon_switch)
1416                 {
1417                         localcmd("-fire\n");
1418                         localcmd("-fire2\n");
1419                         button_attack2 = false;
1420                 }
1421         }
1422         if(last_activeweapon != activeweapon)
1423         {
1424                 last_activeweapon = activeweapon;
1425
1426                 e = get_weaponinfo(activeweapon);
1427                 if(e.netname != "")
1428                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1429                 else
1430                         localcmd("\ncl_hook_activeweapon none\n");
1431         }
1432
1433         // ALWAYS Clear Current Scene First
1434         clearscene();
1435
1436         setproperty(VF_ORIGIN, view_origin);
1437         setproperty(VF_ANGLES, view_angles);
1438
1439         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1440         setproperty(VF_SIZE, vf_size);
1441         setproperty(VF_MIN, vf_min);
1442
1443         // Assign Standard Viewflags
1444         // Draw the World (and sky)
1445         setproperty(VF_DRAWWORLD, 1);
1446
1447         // Set the console size vars
1448         vid_conwidth = autocvar_vid_conwidth;
1449         vid_conheight = autocvar_vid_conheight;
1450         vid_pixelheight = autocvar_vid_pixelheight;
1451
1452         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1453         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1454         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1455
1456         // Camera for demo playback
1457         if(camera_active)
1458         {
1459                 if(autocvar_camera_enable)
1460                         CSQC_Demo_Camera();
1461                 else
1462                 {
1463                         cvar_set("chase_active", ftos(chase_active_backup));
1464                         cvar_set("cl_demo_mousegrab", "0");
1465                         camera_active = false;
1466                 }
1467         }
1468         else
1469         {
1470 #ifdef CAMERATEST
1471                 if(autocvar_camera_enable)
1472 #else
1473                 if(autocvar_camera_enable && isdemo())
1474 #endif
1475                 {
1476                         // Enable required Darkplaces cvars
1477                         chase_active_backup = autocvar_chase_active;
1478                         cvar_set("chase_active", "2");
1479                         cvar_set("cl_demo_mousegrab", "1");
1480                         camera_active = true;
1481                         camera_mode = false;
1482                 }
1483         }
1484
1485         // Draw the Crosshair
1486         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1487
1488         // Draw the Engine Status Bar (the default Quake HUD)
1489         setproperty(VF_DRAWENGINESBAR, 0);
1490
1491         // Update the mouse position
1492         /*
1493            mousepos_x = vid_conwidth;
1494            mousepos_y = vid_conheight;
1495            mousepos = mousepos*0.5 + getmousepos();
1496          */
1497
1498         for(entity e = NULL; (e = nextent(e)); ) if (e.draw) {
1499                 WITH(entity, self, e, e.draw(e));
1500         }
1501
1502         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1503         renderscene();
1504
1505         // now switch to 2D drawing mode by calling a 2D drawing function
1506         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1507         // next R_RenderScene call
1508         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1509
1510         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1511         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1512         {
1513                 // apply night vision effect
1514                 vector tc_00, tc_01, tc_10, tc_11;
1515                 vector rgb = '0 0 0';
1516
1517                 if(!nightvision_noise)
1518                 {
1519                         nightvision_noise = new(nightvision_noise);
1520                 }
1521                 if(!nightvision_noise2)
1522                 {
1523                         nightvision_noise2 = new(nightvision_noise2);
1524                 }
1525
1526                 // color tint in yellow
1527                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1528
1529                 // draw BG
1530                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1531                 rgb = '1 1 1';
1532                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1533                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1534                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1535                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1536                 tc_11 = tc_01 + tc_10 - tc_00;
1537                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1538                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1539                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1540                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1541                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1542                 R_EndPolygon();
1543
1544                 // draw FG
1545                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1546                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1547                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1548                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1549                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1550                 tc_11 = tc_01 + tc_10 - tc_00;
1551                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1552                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1553                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1554                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1555                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1556                 R_EndPolygon();
1557         }
1558
1559         if(autocvar_cl_reticle)
1560         {
1561                 Weapon wep = get_weaponinfo(activeweapon);
1562                 // Draw the aiming reticle for weapons that use it
1563                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
1564                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
1565                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
1566                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
1567                 {
1568                         // no zoom reticle while dead
1569                         reticle_type = 0;
1570                 }
1571                 else if(wep.wr_zoomreticle(wep) && autocvar_cl_reticle_weapon)
1572                 {
1573                         if(reticle_image != "") { reticle_type = 2; }
1574                         else { reticle_type = 0; }
1575                 }
1576                 else if(button_zoom || zoomscript_caught)
1577                 {
1578                         // normal zoom
1579                         reticle_type = 1;
1580                 }
1581
1582                 if(reticle_type)
1583                 {
1584                         if(autocvar_cl_reticle_stretch)
1585                         {
1586                                 reticle_size.x = vid_conwidth;
1587                                 reticle_size.y = vid_conheight;
1588                                 reticle_pos.x = 0;
1589                                 reticle_pos.y = 0;
1590                         }
1591                         else
1592                         {
1593                                 reticle_size.x = max(vid_conwidth, vid_conheight);
1594                                 reticle_size.y = max(vid_conwidth, vid_conheight);
1595                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
1596                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
1597                         }
1598
1599                         if(zoomscript_caught)
1600                                 f = 1;
1601                         else
1602                                 f = current_zoomfraction;
1603
1604                         if(f)
1605                         {
1606                                 switch(reticle_type)
1607                                 {
1608                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
1609                                         case 2: drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
1610                                 }
1611                         }
1612                 }
1613         }
1614         else
1615         {
1616                 if(reticle_type != 0) { reticle_type = 0; }
1617         }
1618
1619
1620         // improved polyblend
1621         if(autocvar_hud_contents)
1622         {
1623                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
1624                 vector liquidcolor;
1625
1626                 switch(pointcontents(view_origin))
1627                 {
1628                         case CONTENT_WATER:
1629                                 liquidalpha = autocvar_hud_contents_water_alpha;
1630                                 liquidcolor = stov(autocvar_hud_contents_water_color);
1631                                 incontent = 1;
1632                                 break;
1633
1634                         case CONTENT_LAVA:
1635                                 liquidalpha = autocvar_hud_contents_lava_alpha;
1636                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
1637                                 incontent = 1;
1638                                 break;
1639
1640                         case CONTENT_SLIME:
1641                                 liquidalpha = autocvar_hud_contents_slime_alpha;
1642                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
1643                                 incontent = 1;
1644                                 break;
1645
1646                         default:
1647                                 liquidalpha = 0;
1648                                 liquidcolor = '0 0 0';
1649                                 incontent = 0;
1650                                 break;
1651                 }
1652
1653                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
1654                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
1655                         contentfadetime = autocvar_hud_contents_fadeintime;
1656                         liquidalpha_prev = liquidalpha;
1657                         liquidcolor_prev = liquidcolor;
1658                 }
1659                 else
1660                         contentfadetime = autocvar_hud_contents_fadeouttime;
1661
1662                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
1663                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
1664
1665                 if(contentavgalpha)
1666                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
1667
1668                 if(autocvar_hud_postprocessing)
1669                 {
1670                         if(autocvar_hud_contents_blur && contentavgalpha)
1671                         {
1672                                 content_blurpostprocess.x = 1;
1673                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
1674                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
1675                         }
1676                         else
1677                         {
1678                                 content_blurpostprocess.x = 0;
1679                                 content_blurpostprocess.y = 0;
1680                                 content_blurpostprocess.z = 0;
1681                         }
1682                 }
1683         }
1684
1685         if(autocvar_hud_damage && !getstati(STAT_FROZEN))
1686         {
1687                 splash_size.x = max(vid_conwidth, vid_conheight);
1688                 splash_size.y = max(vid_conwidth, vid_conheight);
1689                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
1690                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
1691
1692                 float myhealth_flash_temp;
1693                 myhealth = getstati(STAT_HEALTH);
1694
1695                 // fade out
1696                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
1697                 // add new damage
1698                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
1699
1700                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
1701                 pain_threshold = autocvar_hud_damage_pain_threshold;
1702                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
1703                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
1704
1705                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
1706                 {
1707                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
1708                 }
1709
1710                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
1711
1712                 if(myhealth_prev < 1)
1713                 {
1714                         if(myhealth >= 1)
1715                         {
1716                                 myhealth_flash = 0; // just spawned, clear the flash immediately
1717                                 myhealth_flash_temp = 0;
1718                         }
1719                         else
1720                         {
1721                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
1722                         }
1723                 }
1724
1725                 if(spectatee_status == -1 || intermission)
1726                 {
1727                         myhealth_flash = 0; // observing, or match ended
1728                         myhealth_flash_temp = 0;
1729                 }
1730
1731                 myhealth_prev = myhealth;
1732
1733                 // IDEA: change damage color/picture based on player model for robot/alien species?
1734                 // pro: matches model better
1735                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
1736                 // maybe different reddish pics?
1737                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
1738                 {
1739                         if(autocvar_cl_gentle_damage == 2)
1740                         {
1741                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
1742                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
1743                         }
1744                         else
1745                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
1746
1747                         if(myhealth_flash_temp > 0)
1748                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1749                 }
1750                 else if(myhealth_flash_temp > 0)
1751                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1752
1753                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
1754                 {
1755                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
1756                         {
1757                                 damage_blurpostprocess.x = 1;
1758                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
1759                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
1760                         }
1761                         else
1762                         {
1763                                 damage_blurpostprocess.x = 0;
1764                                 damage_blurpostprocess.y = 0;
1765                                 damage_blurpostprocess.z = 0;
1766                         }
1767                 }
1768         }
1769
1770         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
1771         float e2 = (autocvar_hud_powerup != 0);
1772         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
1773         {
1774                 // enable or disable rendering types if they are used or not
1775                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
1776                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
1777
1778                 // blur postprocess handling done first (used by hud_damage and hud_contents)
1779                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
1780                 {
1781                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
1782                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
1783                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
1784                         {
1785                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
1786                                 old_blurradius = blurradius;
1787                                 old_bluralpha = bluralpha;
1788                         }
1789                 }
1790                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
1791                 {
1792                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1793                         old_blurradius = 0;
1794                         old_bluralpha = 0;
1795                 }
1796
1797                 // edge detection postprocess handling done second (used by hud_powerup)
1798                 float sharpen_intensity = 0, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
1799                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
1800                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
1801
1802                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
1803
1804                 if(autocvar_hud_powerup && sharpen_intensity > 0)
1805                 {
1806                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
1807                         {
1808                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
1809                                 old_sharpen_intensity = sharpen_intensity;
1810                         }
1811                 }
1812                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
1813                 {
1814                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
1815                         old_sharpen_intensity = 0;
1816                 }
1817
1818                 if(cvar("r_glsl_postprocess") == 0)
1819                         cvar_set("r_glsl_postprocess", "2");
1820         }
1821         else if(cvar("r_glsl_postprocess") == 2)
1822                 cvar_set("r_glsl_postprocess", "0");
1823
1824         /*if(gametype == MAPINFO_TYPE_CTF)
1825           {
1826           ctf_view();
1827           } else */
1828
1829         // draw 2D entities
1830         for (entity e = NULL; (e = nextent(e)); ) if (e.draw2d) {
1831                 WITH(entity, self, e, e.draw2d(e));
1832         }
1833         Draw_ShowNames_All();
1834         Debug_Draw();
1835
1836         scoreboard_active = HUD_WouldDrawScoreboard();
1837
1838         HUD_Draw();
1839
1840         if(NextFrameCommand)
1841         {
1842                 localcmd("\n", NextFrameCommand, "\n");
1843                 NextFrameCommand = string_null;
1844         }
1845
1846         // we must do this check AFTER a frame was rendered, or it won't work
1847         if(cs_project_is_b0rked == 0)
1848         {
1849                 string w0, h0;
1850                 w0 = ftos(autocvar_vid_conwidth);
1851                 h0 = ftos(autocvar_vid_conheight);
1852                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1853                 //setproperty(VF_FOV, '90 90 0');
1854                 setproperty(VF_ORIGIN, '0 0 0');
1855                 setproperty(VF_ANGLES, '0 0 0');
1856                 setproperty(VF_PERSPECTIVE, 1);
1857                 makevectors('0 0 0');
1858                 vector v1, v2;
1859                 cvar_set("vid_conwidth", "800");
1860                 cvar_set("vid_conheight", "600");
1861                 v1 = cs_project(v_forward);
1862                 cvar_set("vid_conwidth", "640");
1863                 cvar_set("vid_conheight", "480");
1864                 v2 = cs_project(v_forward);
1865                 if(v1 == v2)
1866                         cs_project_is_b0rked = 1;
1867                 else
1868                         cs_project_is_b0rked = -1;
1869                 cvar_set("vid_conwidth", w0);
1870                 cvar_set("vid_conheight", h0);
1871         }
1872
1873         if(autocvar__hud_configure)
1874                 HUD_Panel_Mouse();
1875         else if ( HUD_MinigameMenu_IsOpened() || minigame_isactive() )
1876                 HUD_Minigame_Mouse();
1877         else if(QuickMenu_IsOpened())
1878                 QuickMenu_Mouse();
1879         else
1880                 HUD_Radar_Mouse();
1881
1882         cl_notice_run();
1883
1884         // let's reset the view back to normal for the end
1885         setproperty(VF_MIN, '0 0 0');
1886         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1887 }
1888
1889
1890 // following vectors must be global to allow seamless switching between camera modes
1891 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1892 void CSQC_Demo_Camera()
1893 {
1894         float speed, attenuation, dimensions;
1895         vector tmp, delta;
1896
1897         if( autocvar_camera_reset || !camera_mode )
1898         {
1899                 camera_offset = '0 0 0';
1900                 current_angles = '0 0 0';
1901                 camera_direction = '0 0 0';
1902                 camera_offset.z += 30;
1903                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
1904                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
1905                 current_origin = view_origin;
1906                 current_camera_offset  = camera_offset;
1907                 cvar_set("camera_reset", "0");
1908                 camera_mode = CAMERA_CHASE;
1909         }
1910
1911         // Camera angles
1912         if( camera_roll )
1913                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
1914
1915         if(autocvar_camera_look_player)
1916         {
1917                 vector dir;
1918                 float n;
1919
1920                 dir = normalize(view_origin - current_position);
1921                 n = mouse_angles.z;
1922                 mouse_angles = vectoangles(dir);
1923                 mouse_angles.x = mouse_angles.x * -1;
1924                 mouse_angles.z = n;
1925         }
1926         else
1927         {
1928                 tmp = getmousepos() * 0.1;
1929                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1930                 {
1931                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
1932                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
1933                 }
1934         }
1935
1936         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
1937         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
1938         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
1939         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
1940
1941         // Fix difference when angles don't have the same sign
1942         delta = '0 0 0';
1943         if(mouse_angles.y < -60 && current_angles.y > 60)
1944                 delta = '0 360 0';
1945         if(mouse_angles.y > 60 && current_angles.y < -60)
1946                 delta = '0 -360 0';
1947
1948         if(autocvar_camera_look_player)
1949                 attenuation = autocvar_camera_look_attenuation;
1950         else
1951                 attenuation = autocvar_camera_speed_attenuation;
1952
1953         attenuation = 1 / max(1, attenuation);
1954         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1955
1956         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
1957         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
1958         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
1959         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
1960
1961         // Camera position
1962         tmp = '0 0 0';
1963         dimensions = 0;
1964
1965         if( camera_direction.x )
1966         {
1967                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
1968                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
1969                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1970                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
1971                 ++dimensions;
1972         }
1973
1974         if( camera_direction.y )
1975         {
1976                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
1977                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
1978                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
1979                 ++dimensions;
1980         }
1981
1982         if( camera_direction.z )
1983         {
1984                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
1985                 ++dimensions;
1986         }
1987
1988         if(autocvar_camera_free)
1989                 speed = autocvar_camera_speed_free;
1990         else
1991                 speed = autocvar_camera_speed_chase;
1992
1993         if(dimensions)
1994         {
1995                 speed = speed * sqrt(1 / dimensions);
1996                 camera_offset += tmp * speed;
1997         }
1998
1999         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2000
2001         // Camera modes
2002         if( autocvar_camera_free )
2003         {
2004                 if ( camera_mode == CAMERA_CHASE )
2005                 {
2006                         current_camera_offset = current_origin + current_camera_offset;
2007                         camera_offset = current_origin + camera_offset;
2008                 }
2009
2010                 camera_mode = CAMERA_FREE;
2011                 current_position = current_camera_offset;
2012         }
2013         else
2014         {
2015                 if ( camera_mode == CAMERA_FREE )
2016                 {
2017                         current_origin = view_origin;
2018                         camera_offset = camera_offset - current_origin;
2019                         current_camera_offset = current_camera_offset - current_origin;
2020                 }
2021
2022                 camera_mode = CAMERA_CHASE;
2023
2024                 if(autocvar_camera_chase_smoothly)
2025                         current_origin += (view_origin - current_origin) * attenuation;
2026                 else
2027                         current_origin = view_origin;
2028
2029                 current_position = current_origin + current_camera_offset;
2030         }
2031
2032         setproperty(VF_ANGLES, current_angles);
2033         setproperty(VF_ORIGIN, current_position);
2034 }