qcsrc/client/view.qc

   1
   2 #include "announcer.qh"
   3 #include "hook.qh"
   4 #include "hud.qh"
   5 #include "hud_config.qh"
   6 #include "mapvoting.qh"
   7 #include "scoreboard.qh"
   8 #include "shownames.qh"
   9 #include "quickmenu.qh"
  10
  11 #include "mutators/events.qh"
  12
  13 #include "../common/constants.qh"
  14 #include "../common/mapinfo.qh"
  15 #include "../common/nades/all.qh"
  16 #include "../common/stats.qh"
  17 #include "../common/triggers/target/music.qh"
  18 #include "../common/teams.qh"
  19
  20 #include "../common/vehicles/all.qh"
  21 #include "../common/weapons/all.qh"
  22 #include "../common/viewloc.qh"
  23 #include "../common/minigames/cl_minigames.qh"
  24 #include "../common/minigames/cl_minigames_hud.qh"
  25
  26 #include "../csqcmodellib/cl_player.qh"
  27
  28 #include "../warpzonelib/client.qh"
  29 #include "../warpzonelib/common.qh"
  30
  31 entity porto;
  32 vector polyline[16];
  33 void Porto_Draw(entity this)
  34 {
  35         vector p, dir, ang, q, nextdir;
  36         float portal_number, portal1_idx;
  37
  38         if(activeweapon != WEP_PORTO.m_id || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
  39                 return;
  40         if(g_balance_porto_secondary)
  41                 return;
  42         if(intermission == 1)
  43                 return;
  44         if(intermission == 2)
  45                 return;
  46         if (getstati(STAT_HEALTH) <= 0)
  47                 return;
  48
  49         dir = view_forward;
  50
  51         if(angles_held_status)
  52         {
  53                 makevectors(angles_held);
  54                 dir = v_forward;
  55         }
  56
  57         p = view_origin;
  58
  59         polyline[0] = p;
  60         int idx = 1;
  61         portal_number = 0;
  62         nextdir = dir;
  63
  64         for (;;)
  65         {
  66                 dir = nextdir;
  67                 traceline(p, p + 65536 * dir, true, porto);
  68                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  69                         return;
  70                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  71                 p = trace_endpos;
  72                 polyline[idx] = p;
  73                 ++idx;
  74                 if(idx >= 16)
  75                         return;
  76                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  77                         continue;
  78                 ++portal_number;
  79                 ang = vectoangles2(trace_plane_normal, dir);
  80                 ang.x = -ang.x;
  81                 makevectors(ang);
  82                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  83                         return;
  84                 if(portal_number == 1)
  85                 {
  86                         portal1_idx = idx;
  87                         if(portal_number >= 2)
  88                                 break;
  89                 }
  90         }
  91
  92         while(idx >= 2)
  93         {
  94                 p = polyline[idx-2];
  95                 q = polyline[idx-1];
  96                 if(idx == 2)
  97                         p = p - view_up * 16;
  98                 if(idx-1 >= portal1_idx)
  99                 {
 100                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
 101                 }
 102                 else
 103                 {
 104                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
 105                 }
 106                 --idx;
 107         }
 108 }
 109
 110 void Porto_Init()
 111 {
 112         porto = spawn();
 113         porto.classname = "porto";
 114         porto.draw = Porto_Draw;
 115         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 116 }
 117
 118 float drawtime;
 119 float avgspeed;
 120 vector GetCurrentFov(float fov)
 121 {
 122         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 123         float velocityzoom, curspeed;
 124         vector v;
 125
 126         zoomsensitivity = autocvar_cl_zoomsensitivity;
 127         zoomfactor = autocvar_cl_zoomfactor;
 128         if(zoomfactor < 1 || zoomfactor > 30)
 129                 zoomfactor = 2.5;
 130         zoomspeed = autocvar_cl_zoomspeed;
 131         if(zoomspeed >= 0)
 132         if(zoomspeed < 0.5 || zoomspeed > 16)
 133                         zoomspeed = 3.5;
 134
 135         zoomdir = button_zoom;
 136         if(hud == HUD_NORMAL)
 137         if(switchweapon == activeweapon)
 138         if((activeweapon == WEP_VORTEX.m_id && vortex_scope) || (activeweapon == WEP_RIFLE.m_id && rifle_scope)) // do NOT use switchweapon here
 139                 zoomdir += button_attack2;
 140         if(spectatee_status > 0 || isdemo())
 141         {
 142                 if(spectatorbutton_zoom)
 143                 {
 144                         if(zoomdir)
 145                                 zoomdir = 0;
 146                         else
 147                                 zoomdir = 1;
 148                 }
 149                 // fteqcc failed twice here already, don't optimize this
 150         }
 151
 152         if(zoomdir) { zoomin_effect = 0; }
 153
 154         if(camera_active)
 155         {
 156                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 157         }
 158         else if(autocvar_cl_spawnzoom && zoomin_effect)
 159         {
 160                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 161
 162                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 163                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 164                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 165         }
 166         else
 167         {
 168                 if(zoomspeed < 0) // instant zoom
 169                 {
 170                         if(zoomdir)
 171                                 current_viewzoom = 1 / zoomfactor;
 172                         else
 173                                 current_viewzoom = 1;
 174                 }
 175                 else
 176                 {
 177                         if(zoomdir)
 178                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 179                         else
 180                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 181                 }
 182         }
 183
 184         if(almost_equals(current_viewzoom, 1))
 185                 current_zoomfraction = 0;
 186         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 187                 current_zoomfraction = 1;
 188         else
 189                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 190
 191         if(zoomsensitivity < 1)
 192                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 193         else
 194                 setsensitivityscale(1);
 195
 196         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 197         {
 198                 if(intermission) { curspeed = 0; }
 199                 else
 200                 {
 201
 202                         makevectors(view_angles);
 203                         v = pmove_vel;
 204                         if(csqcplayer)
 205                                 v = csqcplayer.velocity;
 206
 207                         switch(autocvar_cl_velocityzoom_type)
 208                         {
 209                                 case 3: curspeed = max(0, v_forward * v); break;
 210                                 case 2: curspeed = (v_forward * v); break;
 211                                 case 1: default: curspeed = vlen(v); break;
 212                         }
 213                 }
 214
 215                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 216                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 217                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 218
 219                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 220         }
 221         else
 222                 velocityzoom = 1;
 223
 224         float frustumx, frustumy, fovx, fovy;
 225         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 226         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 227         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 228         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 229
 230         return '1 0 0' * fovx + '0 1 0' * fovy;
 231 }
 232
 233 vector GetViewLocationFOV(float fov)
 234 {
 235         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 236         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 237         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 238         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 239         return '1 0 0' * fovx + '0 1 0' * fovy;
 240 }
 241
 242 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 243 {
 244         float fovx, fovy;
 245         float width = (ov_worldmax.x - ov_worldmin.x);
 246         float height = (ov_worldmax.y - ov_worldmin.y);
 247         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 248         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 249         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 250         return '1 0 0' * fovx + '0 1 0' * fovy;
 251 }
 252
 253 // this function must match W_SetupShot!
 254 float zoomscript_caught;
 255
 256 vector wcross_origin;
 257 float wcross_scale_prev, wcross_alpha_prev;
 258 vector wcross_color_prev;
 259 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 260 vector wcross_color_goal_prev;
 261 float wcross_changedonetime;
 262
 263 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 264 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 265 float wcross_name_changestarttime, wcross_name_changedonetime;
 266 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 267
 268 float wcross_ring_prev;
 269
 270 entity trueaim;
 271 entity trueaim_rifle;
 272
 273 const float SHOTTYPE_HITTEAM = 1;
 274 const float SHOTTYPE_HITOBSTRUCTION = 2;
 275 const float SHOTTYPE_HITWORLD = 3;
 276 const float SHOTTYPE_HITENEMY = 4;
 277
 278 void TrueAim_Init()
 279 {
 280         trueaim = spawn();
 281         trueaim.classname = "trueaim";
 282         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 283         trueaim_rifle = spawn();
 284         trueaim_rifle.classname = "trueaim_rifle";
 285         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 286 }
 287
 288 float EnemyHitCheck()
 289 {
 290         float t, n;
 291         wcross_origin = project_3d_to_2d(trace_endpos);
 292         wcross_origin.z = 0;
 293         if(trace_ent)
 294                 n = trace_ent.entnum;
 295         else
 296                 n = trace_networkentity;
 297         if(n < 1)
 298                 return SHOTTYPE_HITWORLD;
 299         if(n > maxclients)
 300                 return SHOTTYPE_HITWORLD;
 301         t = GetPlayerColor(n - 1);
 302         if(teamplay)
 303                 if(t == myteam)
 304                         return SHOTTYPE_HITTEAM;
 305         if(t == NUM_SPECTATOR)
 306                 return SHOTTYPE_HITWORLD;
 307         return SHOTTYPE_HITENEMY;
 308 }
 309
 310 float TrueAimCheck()
 311 {
 312         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 313         vector vecs, trueaimpoint, w_shotorg;
 314         vector mi, ma, dv;
 315         float shottype;
 316         entity ta;
 317         float mv;
 318
 319         mi = ma = '0 0 0';
 320         ta = trueaim;
 321         mv = MOVE_NOMONSTERS;
 322
 323         switch(activeweapon) // WEAPONTODO
 324         {
 325                 case WEP_TUBA.m_id: // no aim
 326                 case WEP_PORTO.m_id: // shoots from eye
 327                 case WEP_NEXBALL.m_id: // shoots from eye
 328                 case WEP_HOOK.m_id: // no trueaim
 329                 case WEP_MORTAR.m_id: // toss curve
 330                         return SHOTTYPE_HITWORLD;
 331                 case WEP_VORTEX.m_id:
 332                 case WEP_VAPORIZER.m_id:
 333                         mv = MOVE_NORMAL;
 334                         break;
 335                 case WEP_RIFLE.m_id:
 336                         ta = trueaim_rifle;
 337                         mv = MOVE_NORMAL;
 338                         if(zoomscript_caught)
 339                         {
 340                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 341                                 return EnemyHitCheck();
 342                         }
 343                         break;
 344                 case WEP_DEVASTATOR.m_id: // projectile has a size!
 345                         mi = '-3 -3 -3';
 346                         ma = '3 3 3';
 347                         break;
 348                 case WEP_FIREBALL.m_id: // projectile has a size!
 349                         mi = '-16 -16 -16';
 350                         ma = '16 16 16';
 351                         break;
 352                 case WEP_SEEKER.m_id: // projectile has a size!
 353                         mi = '-2 -2 -2';
 354                         ma = '2 2 2';
 355                         break;
 356                 case WEP_ELECTRO.m_id: // projectile has a size!
 357                         mi = '0 0 -3';
 358                         ma = '0 0 -3';
 359                         break;
 360         }
 361
 362         vector traceorigin = getplayerorigin(player_localentnum-1) + (eZ * getstati(STAT_VIEWHEIGHT));
 363
 364         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 365
 366         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 367         trueaimpoint = trace_endpos;
 368
 369         if(vlen(trueaimpoint - traceorigin) < g_trueaim_minrange)
 370                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 371
 372         if(vecs.x > 0)
 373                 vecs.y = -vecs.y;
 374         else
 375                 vecs = '0 0 0';
 376
 377         dv = view_right * vecs.y + view_up * vecs.z;
 378         w_shotorg = traceorigin + dv;
 379
 380         // now move the vecs forward as much as requested if possible
 381         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 382         w_shotorg = trace_endpos - view_forward * nudge;
 383
 384         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 385         shottype = EnemyHitCheck();
 386         if(shottype != SHOTTYPE_HITWORLD)
 387                 return shottype;
 388
 389 #if 0
 390         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 391         // or rather, I know why, but see no fix
 392         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 393                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 394                 return SHOTTYPE_HITOBSTRUCTION;
 395 #endif
 396
 397         return SHOTTYPE_HITWORLD;
 398 }
 399
 400 void CSQC_common_hud(void);
 401
 402 void PostInit(void);
 403 void CSQC_Demo_Camera();
 404 float HUD_WouldDrawScoreboard();
 405 float camera_mode;
 406 const float CAMERA_FREE = 1;
 407 const float CAMERA_CHASE = 2;
 408 float reticle_type;
 409 string reticle_image;
 410 string NextFrameCommand;
 411
 412 vector freeze_org, freeze_ang;
 413 entity nightvision_noise, nightvision_noise2;
 414
 415 const float MAX_TIME_DIFF = 5;
 416 float pickup_crosshair_time, pickup_crosshair_size;
 417 float hitindication_crosshair_size;
 418 float use_vortex_chargepool;
 419
 420 float myhealth, myhealth_prev;
 421 float myhealth_flash;
 422
 423 float old_blurradius, old_bluralpha;
 424 float old_sharpen_intensity;
 425
 426 vector myhealth_gentlergb;
 427
 428 float contentavgalpha, liquidalpha_prev;
 429 vector liquidcolor_prev;
 430
 431 float eventchase_current_distance;
 432 float eventchase_running;
 433 bool WantEventchase()
 434 {SELFPARAM();
 435         if(autocvar_cl_orthoview)
 436                 return false;
 437         if(intermission)
 438                 return true;
 439         if(self.viewloc)
 440                 return true;
 441         if(spectatee_status >= 0)
 442         {
 443                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 444                         return true;
 445                 if(MUTATOR_CALLHOOK(WantEventchase, self))
 446                         return true;
 447                 if(autocvar_cl_eventchase_nexball && gametype == MAPINFO_TYPE_NEXBALL && !(WepSet_GetFromStat() & WepSet_FromWeapon(WEP_NEXBALL.m_id)))
 448                         return true;
 449                 if(autocvar_cl_eventchase_death && (getstati(STAT_HEALTH) <= 0))
 450                 {
 451                         if(autocvar_cl_eventchase_death == 2)
 452                         {
 453                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 454                                 if(self.velocity == '0 0 0' || eventchase_running)
 455                                         return true;
 456                         }
 457                         else return true;
 458                 }
 459         }
 460         return false;
 461 }
 462
 463 vector damage_blurpostprocess, content_blurpostprocess;
 464
 465 float unaccounted_damage = 0;
 466 void UpdateDamage()
 467 {
 468         // accumulate damage with each stat update
 469         static float damage_total_prev = 0;
 470         float damage_total = getstati(STAT_DAMAGE_DEALT_TOTAL);
 471         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 472         damage_total_prev = damage_total;
 473
 474         static float damage_dealt_time_prev = 0;
 475         float damage_dealt_time = getstatf(STAT_HIT_TIME);
 476         if (damage_dealt_time != damage_dealt_time_prev)
 477         {
 478                 unaccounted_damage += unaccounted_damage_new;
 479                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")", "\n");
 480         }
 481         damage_dealt_time_prev = damage_dealt_time;
 482
 483         // prevent hitsound when switching spectatee
 484         static float spectatee_status_prev = 0;
 485         if (spectatee_status != spectatee_status_prev)
 486                 unaccounted_damage = 0;
 487         spectatee_status_prev = spectatee_status;
 488 }
 489
 490 void UpdateHitsound()
 491 {
 492         // varying sound pitch
 493
 494         static float hitsound_time_prev = 0;
 495         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 496         float arc_hack = activeweapon == WEP_ARC.m_id && autocvar_cl_hitsound >= 2;
 497         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 498         {
 499                 if (autocvar_cl_hitsound && unaccounted_damage)
 500                 {
 501                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 502                         float a = autocvar_cl_hitsound_max_pitch;
 503                         float b = autocvar_cl_hitsound_min_pitch;
 504                         float c = autocvar_cl_hitsound_nom_damage;
 505                         float x = unaccounted_damage;
 506                         float pitch_shift = (b*x*(a-1) + a*c*(1-b)) / (x*(a-1) + c*(1-b));
 507
 508                         // if sound variation is disabled, set pitch_shift to 1
 509                         if (autocvar_cl_hitsound == 1)
 510                                 pitch_shift = 1;
 511
 512                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 513                         if (autocvar_cl_hitsound == 3)
 514                         {
 515                                 float mirror_value = (a-b)/2 + b;
 516                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 517                         }
 518
 519                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift), "\n");
 520
 521                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 522                         // todo: normalize sound pressure levels? seems unnecessary
 523
 524                         sound7(world, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 525                 }
 526                 unaccounted_damage = 0;
 527                 hitsound_time_prev = time;
 528         }
 529
 530         static float typehit_time_prev = 0;
 531         float typehit_time = getstatf(STAT_TYPEHIT_TIME);
 532         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 533         {
 534                 sound(world, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 535                 typehit_time_prev = typehit_time;
 536         }
 537 }
 538
 539 void UpdateCrosshair()
 540 {SELFPARAM();
 541         static float rainbow_last_flicker;
 542     static vector rainbow_prev_color;
 543         entity e = self;
 544         float f, i, j;
 545         vector v;
 546         if(getstati(STAT_FROZEN))
 547                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, ((getstatf(STAT_REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * getstatf(STAT_REVIVE_PROGRESS)) + ('0 1 1' * getstatf(STAT_REVIVE_PROGRESS) * -1)) : '0.25 0.90 1'), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 548         else if (getstatf(STAT_HEALING_ORB)>time)
 549                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, NADE_TYPE_HEAL.m_color, autocvar_hud_colorflash_alpha*getstatf(STAT_HEALING_ORB_ALPHA), DRAWFLAG_ADDITIVE);
 550         if(!intermission)
 551         if(getstatf(STAT_NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
 552         {
 553                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * getstatf(STAT_NADE_TIMER)) - ('0 1 1' * getstatf(STAT_NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 554                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
 555         }
 556         else if(getstatf(STAT_REVIVE_PROGRESS))
 557         {
 558                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 559                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
 560         }
 561
 562         if(autocvar_r_letterbox == 0)
 563                 if(autocvar_viewsize < 120)
 564                         CSQC_common_hud();
 565
 566         // crosshair goes VERY LAST
 567         if(!scoreboard_active && !camera_active && intermission != 2 &&
 568                 spectatee_status != -1 && hud == HUD_NORMAL && !csqcplayer.viewloc &&
 569                 !HUD_MinigameMenu_IsOpened() )
 570         {
 571                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 572                         return;
 573
 574                 string wcross_style;
 575                 float wcross_alpha, wcross_resolution;
 576                 wcross_style = autocvar_crosshair;
 577                 if (wcross_style == "0")
 578                         return;
 579                 wcross_resolution = autocvar_crosshair_size;
 580                 if (wcross_resolution == 0)
 581                         return;
 582                 wcross_alpha = autocvar_crosshair_alpha;
 583                 if (wcross_alpha == 0)
 584                         return;
 585
 586                 // TrueAim check
 587                 float shottype;
 588
 589                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 590                 wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 591                 wcross_origin.z = 0;
 592                 if(autocvar_crosshair_hittest)
 593                 {
 594                         vector wcross_oldorigin;
 595                         wcross_oldorigin = wcross_origin;
 596                         shottype = TrueAimCheck();
 597                         if(shottype == SHOTTYPE_HITWORLD)
 598                         {
 599                                 v = wcross_origin - wcross_oldorigin;
 600                                 v.x /= vid_conwidth;
 601                                 v.y /= vid_conheight;
 602                                 if(vlen(v) > 0.01)
 603                                         shottype = SHOTTYPE_HITOBSTRUCTION;
 604                         }
 605                         if(!autocvar_crosshair_hittest_showimpact)
 606                                 wcross_origin = wcross_oldorigin;
 607                 }
 608                 else
 609                         shottype = SHOTTYPE_HITWORLD;
 610
 611                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
 612                 string wcross_name = "";
 613                 float wcross_scale, wcross_blur;
 614
 615                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
 616                 {
 617                         e = get_weaponinfo(switchingweapon);
 618                         if(e)
 619                         {
 620                                 if(autocvar_crosshair_per_weapon)
 621                                 {
 622                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
 623                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 624                                         //if (wcross_resolution == 0)
 625                                                 //return;
 626
 627                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 628                                         wcross_resolution *= e.w_crosshair_size;
 629                                         wcross_name = e.w_crosshair;
 630                                 }
 631                         }
 632                 }
 633
 634                 if(wcross_name == "")
 635                         wcross_name = strcat("gfx/crosshair", wcross_style);
 636
 637                 // MAIN CROSSHAIR COLOR DECISION
 638                 switch(autocvar_crosshair_color_special)
 639                 {
 640                         case 1: // crosshair_color_per_weapon
 641                         {
 642                                 if(e)
 643                                 {
 644                                         wcross_color = e.wpcolor;
 645                                         break;
 646                                 }
 647                                 else { goto normalcolor; }
 648                         }
 649
 650                         case 2: // crosshair_color_by_health
 651                         {
 652                                 float x = getstati(STAT_HEALTH);
 653
 654                                 //x = red
 655                                 //y = green
 656                                 //z = blue
 657
 658                                 wcross_color.z = 0;
 659
 660                                 if(x > 200)
 661                                 {
 662                                         wcross_color.x = 0;
 663                                         wcross_color.y = 1;
 664                                 }
 665                                 else if(x > 150)
 666                                 {
 667                                         wcross_color.x = 0.4 - (x-150)*0.02 * 0.4;
 668                                         wcross_color.y = 0.9 + (x-150)*0.02 * 0.1;
 669                                 }
 670                                 else if(x > 100)
 671                                 {
 672                                         wcross_color.x = 1 - (x-100)*0.02 * 0.6;
 673                                         wcross_color.y = 1 - (x-100)*0.02 * 0.1;
 674                                         wcross_color.z = 1 - (x-100)*0.02;
 675                                 }
 676                                 else if(x > 50)
 677                                 {
 678                                         wcross_color.x = 1;
 679                                         wcross_color.y = 1;
 680                                         wcross_color.z = 0.2 + (x-50)*0.02 * 0.8;
 681                                 }
 682                                 else if(x > 20)
 683                                 {
 684                                         wcross_color.x = 1;
 685                                         wcross_color.y = (x-20)*90/27/100;
 686                                         wcross_color.z = (x-20)*90/27/100 * 0.2;
 687                                 }
 688                                 else
 689                                 {
 690                                         wcross_color.x = 1;
 691                                         wcross_color.y = 0;
 692                                 }
 693                                 break;
 694                         }
 695
 696                         case 3: // crosshair_color_rainbow
 697                         {
 698                                 if(time >= rainbow_last_flicker)
 699                                 {
 700                                         rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
 701                                         rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
 702                                 }
 703                                 wcross_color = rainbow_prev_color;
 704                                 break;
 705                         }
 706                         :normalcolor
 707                         default: { wcross_color = stov(autocvar_crosshair_color); break; }
 708                 }
 709
 710                 if(autocvar_crosshair_effect_scalefade)
 711                 {
 712                         wcross_scale = wcross_resolution;
 713                         wcross_resolution = 1;
 714                 }
 715                 else
 716                 {
 717                         wcross_scale = 1;
 718                 }
 719
 720                 if(autocvar_crosshair_pickup)
 721                 {
 722                         float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
 723
 724                         if(pickup_crosshair_time < stat_pickup_time)
 725                         {
 726                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
 727                                         pickup_crosshair_size = 1;
 728
 729                                 pickup_crosshair_time = stat_pickup_time;
 730                         }
 731
 732                         if(pickup_crosshair_size > 0)
 733                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
 734                         else
 735                                 pickup_crosshair_size = 0;
 736
 737                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
 738                 }
 739
 740                 // todo: make crosshair hit indication dependent on damage dealt
 741                 if(autocvar_crosshair_hitindication)
 742                 {
 743                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
 744
 745                         if(unaccounted_damage)
 746                         {
 747                                 hitindication_crosshair_size = 1;
 748                         }
 749
 750                         if(hitindication_crosshair_size > 0)
 751                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
 752                         else
 753                                 hitindication_crosshair_size = 0;
 754
 755                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
 756                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
 757                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
 758                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
 759                 }
 760
 761                 if(shottype == SHOTTYPE_HITENEMY)
 762                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
 763                 if(shottype == SHOTTYPE_HITTEAM)
 764                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
 765
 766                 f = fabs(autocvar_crosshair_effect_time);
 767                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
 768                 {
 769                         wcross_changedonetime = time + f;
 770                 }
 771                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
 772                 {
 773                         wcross_name_changestarttime = time;
 774                         wcross_name_changedonetime = time + f;
 775                         if(wcross_name_goal_prev_prev)
 776                                 strunzone(wcross_name_goal_prev_prev);
 777                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
 778                         wcross_name_goal_prev = strzone(wcross_name);
 779                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
 780                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
 781                         wcross_resolution_goal_prev = wcross_resolution;
 782                 }
 783
 784                 wcross_scale_goal_prev = wcross_scale;
 785                 wcross_alpha_goal_prev = wcross_alpha;
 786                 wcross_color_goal_prev = wcross_color;
 787
 788                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
 789                 {
 790                         wcross_blur = 1;
 791                         wcross_alpha *= 0.75;
 792                 }
 793                 else
 794                         wcross_blur = 0;
 795                 // *_prev is at time-frametime
 796                 // * is at wcross_changedonetime+f
 797                 // what do we have at time?
 798                 if(time < wcross_changedonetime)
 799                 {
 800                         f = frametime / (wcross_changedonetime - time + frametime);
 801                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
 802                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
 803                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
 804                 }
 805
 806                 wcross_scale_prev = wcross_scale;
 807                 wcross_alpha_prev = wcross_alpha;
 808                 wcross_color_prev = wcross_color;
 809
 810                 MUTATOR_CALLHOOK(UpdateCrosshair);
 811
 812                 wcross_scale *= 1 - autocvar__menu_alpha;
 813                 wcross_alpha *= 1 - autocvar__menu_alpha;
 814                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
 815
 816                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
 817                 {
 818                         // crosshair rings for weapon stats
 819                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
 820                         {
 821                                 // declarations and stats
 822                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
 823                                 string ring_image = string_null, ring_inner_image = string_null;
 824                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
 825
 826                                 ring_scale = autocvar_crosshair_ring_size;
 827
 828                                 float weapon_clipload, weapon_clipsize;
 829                                 weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
 830                                 weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
 831
 832                                 float ok_ammo_charge, ok_ammo_chargepool;
 833                                 ok_ammo_charge = getstatf(STAT_OK_AMMO_CHARGE);
 834                                 ok_ammo_chargepool = getstatf(STAT_OK_AMMO_CHARGEPOOL);
 835
 836                                 float vortex_charge, vortex_chargepool;
 837                                 vortex_charge = getstatf(STAT_VORTEX_CHARGE);
 838                                 vortex_chargepool = getstatf(STAT_VORTEX_CHARGEPOOL);
 839
 840                                 float arc_heat = getstatf(STAT_ARC_HEAT);
 841
 842                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
 843                                         vortex_charge_movingavg = vortex_charge;
 844
 845
 846                                 // handle the values
 847                                 if (autocvar_crosshair_ring && activeweapon == WEP_VORTEX.m_id && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
 848                                 {
 849                                         if (vortex_chargepool || use_vortex_chargepool) {
 850                                                 use_vortex_chargepool = 1;
 851                                                 ring_inner_value = vortex_chargepool;
 852                                         } else {
 853                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
 854                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
 855                                         }
 856
 857                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
 858                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
 859                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
 860
 861                                         // draw the outer ring to show the current charge of the weapon
 862                                         ring_value = vortex_charge;
 863                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
 864                                         ring_rgb = wcross_color;
 865                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
 866                                 }
 867                                 else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER.m_id && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
 868                                 {
 869                                         ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
 870                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
 871                                         ring_rgb = wcross_color;
 872                                         ring_image = "gfx/crosshair_ring.tga";
 873                                 }
 874                                 else if (activeweapon == WEP_HAGAR.m_id && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
 875                                 {
 876                                         ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
 877                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
 878                                         ring_rgb = wcross_color;
 879                                         ring_image = "gfx/crosshair_ring.tga";
 880                                 }
 881                                 else if (ok_ammo_charge)
 882                                 {
 883                                         ring_value = ok_ammo_chargepool;
 884                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
 885                                         ring_rgb = wcross_color;
 886                                         ring_image = "gfx/crosshair_ring.tga";
 887                                 }
 888                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
 889                                 {
 890                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
 891                                         ring_scale = autocvar_crosshair_ring_reload_size;
 892                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
 893                                         ring_rgb = wcross_color;
 894
 895                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
 896                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
 897                                         if ((activeweapon == WEP_RIFLE.m_id) && (weapon_clipsize == 80))
 898                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
 899                                         else
 900                                                 ring_image = "gfx/crosshair_ring.tga";
 901                                 }
 902                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && activeweapon == WEP_ARC.m_id )
 903                                 {
 904                                         ring_value = arc_heat;
 905                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
 906                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
 907                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
 908                                         ring_image = "gfx/crosshair_ring.tga";
 909                                 }
 910
 911                                 // if in weapon switch animation, fade ring out/in
 912                                 if(autocvar_crosshair_effect_time > 0)
 913                                 {
 914                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
 915                                         if (f >= 1)
 916                                         {
 917                                                 wcross_ring_prev = ((ring_image) ? true : false);
 918                                         }
 919
 920                                         if(wcross_ring_prev)
 921                                         {
 922                                                 if(f < 1)
 923                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
 924                                         }
 925                                         else
 926                                         {
 927                                                 if(f < 1)
 928                                                         ring_alpha *= bound(0, f, 1);
 929                                         }
 930                                 }
 931
 932                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
 933                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
 934
 935                                 if (ring_value)
 936                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
 937                         }
 938
 939 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
 940                         do \
 941                         { \
 942                                 if(wcross_blur > 0) \
 943                                 { \
 944                                         for(i = -2; i <= 2; ++i) \
 945                                         for(j = -2; j <= 2; ++j) \
 946                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
 947                                 } \
 948                                 else \
 949                                 { \
 950                                         M(0,0,sz,wcross_name,wcross_alpha); \
 951                                 } \
 952                         } \
 953                         while(0)
 954
 955 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
 956                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
 957
 958 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
 959                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
 960
 961                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
 962                         {
 963                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
 964                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
 965                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
 966                                 f = 1 - f;
 967                         }
 968                         else
 969                         {
 970                                 f = 1;
 971                         }
 972                         wcross_name_alpha_goal_prev = f;
 973
 974                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
 975                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
 976
 977                         if(autocvar_crosshair_dot)
 978                         {
 979                                 vector wcross_color_old;
 980                                 wcross_color_old = wcross_color;
 981
 982                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
 983                                         wcross_color = stov(autocvar_crosshair_dot_color);
 984
 985                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
 986                                 // FIXME why don't we use wcross_alpha here?cl_notice_run();
 987                                 wcross_color = wcross_color_old;
 988                         }
 989                 }
 990         }
 991         else
 992         {
 993                 wcross_scale_prev = 0;
 994                 wcross_alpha_prev = 0;
 995                 wcross_scale_goal_prev = 0;
 996                 wcross_alpha_goal_prev = 0;
 997                 wcross_changedonetime = 0;
 998                 if(wcross_name_goal_prev)
 999                         strunzone(wcross_name_goal_prev);
1000                 wcross_name_goal_prev = string_null;
1001                 if(wcross_name_goal_prev_prev)
1002                         strunzone(wcross_name_goal_prev_prev);
1003                 wcross_name_goal_prev_prev = string_null;
1004                 wcross_name_changestarttime = 0;
1005                 wcross_name_changedonetime = 0;
1006                 wcross_name_alpha_goal_prev = 0;
1007                 wcross_name_alpha_goal_prev_prev = 0;
1008                 wcross_resolution_goal_prev = 0;
1009                 wcross_resolution_goal_prev_prev = 0;
1010         }
1011 }
1012
1013 bool ov_enabled;
1014 float oldr_nearclip;
1015 float oldr_farclip_base;
1016 float oldr_farclip_world;
1017 float oldr_novis;
1018 float oldr_useportalculling;
1019 float oldr_useinfinitefarclip;
1020
1021 const int BUTTON_3 = 4;
1022 const int BUTTON_4 = 8;
1023 float cl_notice_run();
1024 float prev_myteam;
1025 int lasthud;
1026 float vh_notice_time;
1027 void WaypointSprite_Load();
1028 void CSQC_UpdateView(float w, float h)
1029 {SELFPARAM();
1030         entity e;
1031         float fov;
1032         float f;
1033         vector vf_size, vf_min;
1034         float a;
1035
1036         execute_next_frame();
1037
1038         ++framecount;
1039
1040         hud = getstati(STAT_HUD);
1041
1042         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1043                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1044
1045         lasthud = hud;
1046
1047         if(autocvar__hud_showbinds_reload) // menu can set this one
1048         {
1049                 db_close(binddb);
1050                 binddb = db_create();
1051                 cvar_set("_hud_showbinds_reload", "0");
1052         }
1053
1054         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1055                 view_quality = getproperty(VF_MINFPS_QUALITY);
1056         else
1057                 view_quality = 1;
1058
1059         button_attack2 = (input_buttons & BUTTON_3);
1060         button_zoom = (input_buttons & BUTTON_4);
1061
1062         vf_size = getpropertyvec(VF_SIZE);
1063         vf_min = getpropertyvec(VF_MIN);
1064         vid_width = vf_size.x;
1065         vid_height = vf_size.y;
1066
1067         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1068         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1069
1070         WaypointSprite_Load();
1071
1072         CSQCPlayer_SetCamera();
1073
1074         if(player_localentnum <= maxclients) // is it a client?
1075                 current_player = player_localentnum - 1;
1076         else // then player_localentnum is the vehicle I'm driving
1077                 current_player = player_localnum;
1078         myteam = GetPlayerColor(current_player);
1079
1080         if(myteam != prev_myteam)
1081         {
1082                 myteamcolors = colormapPaletteColor(myteam, 1);
1083                 FOREACH(hud_panels, true, LAMBDA(it.update_time = time));
1084                 prev_myteam = myteam;
1085         }
1086
1087         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
1088
1089         float is_dead = (getstati(STAT_HEALTH) <= 0);
1090
1091         // FIXME do we need this hack?
1092         if(isdemo())
1093         {
1094                 // in demos, input_buttons do not work
1095                 button_zoom = (autocvar__togglezoom == "-");
1096         }
1097         else if(button_zoom
1098                 && autocvar_cl_unpress_zoom_on_death
1099                 && (spectatee_status >= 0)
1100                 && (is_dead || intermission))
1101         {
1102                 // no zoom while dead or in intermission please
1103                 localcmd("-zoom\n");
1104                 button_zoom = false;
1105         }
1106
1107         // event chase camera
1108         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1109         {
1110                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1111                 float ons_roundlost = (gametype == MAPINFO_TYPE_ONSLAUGHT && getstati(STAT_ROUNDLOST));
1112                 entity gen = world;
1113
1114                 if(ons_roundlost)
1115                 {
1116                         entity e;
1117                         for(e = world; (e = find(e, classname, "onslaught_generator")); )
1118                         {
1119                                 if(e.health <= 0)
1120                                 {
1121                                         gen = e;
1122                                         break;
1123                                 }
1124                         }
1125                         if(!gen)
1126                                 ons_roundlost = FALSE; // don't enforce the 3rd person camera if there is no dead generator to show
1127                 }
1128                 if(WantEventchase() || (!autocvar_cl_orthoview && ons_roundlost))
1129                 {
1130                         eventchase_running = true;
1131
1132                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1133                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1134                         if(ons_roundlost) { current_view_origin = gen.origin; }
1135
1136                         // detect maximum viewoffset and use it
1137                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1138                         if(vehicle_chase && autocvar_cl_eventchase_vehicle_viewoffset) { view_offset = autocvar_cl_eventchase_vehicle_viewoffset; }
1139                         if(ons_roundlost) { view_offset = autocvar_cl_eventchase_generator_viewoffset; }
1140
1141                         if(view_offset)
1142                         {
1143                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, self);
1144                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1145                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1146                         }
1147
1148                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1149                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1150                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1151                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1152
1153                         // make the camera smooth back
1154                         float chase_distance = autocvar_cl_eventchase_distance;
1155                         if(vehicle_chase && autocvar_cl_eventchase_vehicle_distance) { chase_distance = autocvar_cl_eventchase_vehicle_distance; }
1156                         if(ons_roundlost) { chase_distance = autocvar_cl_eventchase_generator_distance; }
1157
1158                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1159                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1160                         else if(eventchase_current_distance != chase_distance)
1161                                 eventchase_current_distance = chase_distance;
1162
1163                         makevectors(view_angles);
1164
1165                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1166                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
1167
1168                         // If the boxtrace fails, revert back to line tracing.
1169                         if(!self.viewloc)
1170                         if(trace_startsolid)
1171                         {
1172                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1173                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
1174                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1175                         }
1176                         else { setproperty(VF_ORIGIN, trace_endpos); }
1177
1178                         if(!self.viewloc)
1179                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1180                 }
1181                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1182                 {
1183                         eventchase_running = false;
1184                         cvar_set("chase_active", "0");
1185                         eventchase_current_distance = 0; // start from 0 next time
1186                 }
1187         }
1188         // workaround for camera stuck between player's legs when using chase_active 1
1189         // because the engine stops updating the chase_active camera when the game ends
1190         else if(intermission)
1191         {
1192                 cvar_settemp("chase_active", "-1");
1193                 eventchase_current_distance = 0;
1194         }
1195
1196         // do lockview after event chase camera so that it still applies whenever necessary.
1197         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1198         {
1199                 setproperty(VF_ORIGIN, freeze_org);
1200                 setproperty(VF_ANGLES, freeze_ang);
1201         }
1202         else
1203         {
1204                 freeze_org = getpropertyvec(VF_ORIGIN);
1205                 freeze_ang = getpropertyvec(VF_ANGLES);
1206         }
1207
1208         WarpZone_FixView();
1209         //WarpZone_FixPMove();
1210
1211         vector ov_org = '0 0 0';
1212         vector ov_mid = '0 0 0';
1213         vector ov_worldmin = '0 0 0';
1214         vector ov_worldmax = '0 0 0';
1215         if(autocvar_cl_orthoview)
1216         {
1217                 ov_worldmin = mi_picmin;
1218                 ov_worldmax = mi_picmax;
1219
1220                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1221                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1222                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1223
1224                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1225                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1226
1227                 float ov_nearest = vlen(ov_org - vec3(
1228                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1229                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1230                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1231                 ));
1232
1233                 float ov_furthest = 0;
1234                 float dist = 0;
1235
1236                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1237                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1238                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1239                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1240                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1241                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1242                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1243                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1244
1245                 if(!ov_enabled)
1246                 {
1247                         oldr_nearclip = cvar("r_nearclip");
1248                         oldr_farclip_base = cvar("r_farclip_base");
1249                         oldr_farclip_world = cvar("r_farclip_world");
1250                         oldr_novis = cvar("r_novis");
1251                         oldr_useportalculling = cvar("r_useportalculling");
1252                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1253                 }
1254
1255                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1256                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1257                 cvar_settemp("r_farclip_world", "0");
1258                 cvar_settemp("r_novis", "1");
1259                 cvar_settemp("r_useportalculling", "0");
1260                 cvar_settemp("r_useinfinitefarclip", "0");
1261
1262                 setproperty(VF_ORIGIN, ov_org);
1263                 setproperty(VF_ANGLES, '90 0 0');
1264
1265                 ov_enabled = true;
1266
1267                 #if 0
1268                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1269                         vtos(ov_org),
1270                         vtos(getpropertyvec(VF_ANGLES)),
1271                         ov_distance,
1272                         ov_nearest,
1273                         ov_furthest);
1274                 #endif
1275         }
1276         else
1277         {
1278                 if(ov_enabled)
1279                 {
1280                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1281                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1282                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1283                         cvar_set("r_novis", ftos(oldr_novis));
1284                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1285                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1286                 }
1287                 ov_enabled = false;
1288         }
1289
1290         // Render the Scene
1291         view_origin = getpropertyvec(VF_ORIGIN);
1292         view_angles = getpropertyvec(VF_ANGLES);
1293         makevectors(view_angles);
1294         view_forward = v_forward;
1295         view_right = v_right;
1296         view_up = v_up;
1297
1298 #ifdef BLURTEST
1299         if(time > blurtest_time0 && time < blurtest_time1)
1300         {
1301                 float r, t;
1302
1303                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1304                 r = t * blurtest_radius;
1305                 f = 1 / pow(t, blurtest_power) - 1;
1306
1307                 cvar_set("r_glsl_postprocess", "1");
1308                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1309         }
1310         else
1311         {
1312                 cvar_set("r_glsl_postprocess", "0");
1313                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1314         }
1315 #endif
1316
1317         TargetMusic_Advance();
1318         Fog_Force();
1319
1320         if(drawtime == 0)
1321                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1322         else
1323                 drawframetime = bound(0.000001, time - drawtime, 1);
1324         drawtime = time;
1325
1326         // watch for gametype changes here...
1327         // in ParseStuffCMD the cmd isn't executed yet :/
1328         // might even be better to add the gametype to TE_CSQC_INIT...?
1329         if(!postinit)
1330                 PostInit();
1331
1332         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1333         {
1334                 if(calledhooks & HOOK_START)
1335                 {
1336                         localcmd("\ncl_hook_gameend\n");
1337                         calledhooks |= HOOK_END;
1338                 }
1339         }
1340
1341         Announcer();
1342
1343         fov = autocvar_fov;
1344         if(fov <= 59.5)
1345         {
1346                 if(!zoomscript_caught)
1347                 {
1348                         localcmd("+button9\n");
1349                         zoomscript_caught = 1;
1350                 }
1351         }
1352         else
1353         {
1354                 if(zoomscript_caught)
1355                 {
1356                         localcmd("-button9\n");
1357                         zoomscript_caught = 0;
1358                 }
1359         }
1360
1361         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1362
1363         // next WANTED weapon (for HUD)
1364         switchweapon = getstati(STAT_SWITCHWEAPON);
1365
1366         // currently switching-to weapon (for crosshair)
1367         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
1368
1369         // actually active weapon (for zoom)
1370         activeweapon = getstati(STAT_ACTIVEWEAPON);
1371
1372         f = (serverflags & SERVERFLAG_TEAMPLAY);
1373         if(f != teamplay)
1374         {
1375                 teamplay = f;
1376                 HUD_InitScores();
1377         }
1378
1379         if(last_switchweapon != switchweapon)
1380         {
1381                 weapontime = time;
1382                 last_switchweapon = switchweapon;
1383                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1384                 {
1385                         localcmd("-zoom\n");
1386                         button_zoom = false;
1387                 }
1388                 if(autocvar_cl_unpress_attack_on_weapon_switch)
1389                 {
1390                         localcmd("-fire\n");
1391                         localcmd("-fire2\n");
1392                         button_attack2 = false;
1393                 }
1394         }
1395         if(last_activeweapon != activeweapon)
1396         {
1397                 last_activeweapon = activeweapon;
1398
1399                 e = get_weaponinfo(activeweapon);
1400                 if(e.netname != "")
1401                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1402                 else
1403                         localcmd("\ncl_hook_activeweapon none\n");
1404         }
1405
1406         // ALWAYS Clear Current Scene First
1407         clearscene();
1408
1409         setproperty(VF_ORIGIN, view_origin);
1410         setproperty(VF_ANGLES, view_angles);
1411
1412         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1413         setproperty(VF_SIZE, vf_size);
1414         setproperty(VF_MIN, vf_min);
1415
1416         // Assign Standard Viewflags
1417         // Draw the World (and sky)
1418         setproperty(VF_DRAWWORLD, 1);
1419
1420         // Set the console size vars
1421         vid_conwidth = autocvar_vid_conwidth;
1422         vid_conheight = autocvar_vid_conheight;
1423         vid_pixelheight = autocvar_vid_pixelheight;
1424
1425         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1426         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1427         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1428
1429         // Camera for demo playback
1430         if(camera_active)
1431         {
1432                 if(autocvar_camera_enable)
1433                         CSQC_Demo_Camera();
1434                 else
1435                 {
1436                         cvar_set("chase_active", ftos(chase_active_backup));
1437                         cvar_set("cl_demo_mousegrab", "0");
1438                         camera_active = false;
1439                 }
1440         }
1441         else
1442         {
1443 #ifdef CAMERATEST
1444                 if(autocvar_camera_enable)
1445 #else
1446                 if(autocvar_camera_enable && isdemo())
1447 #endif
1448                 {
1449                         // Enable required Darkplaces cvars
1450                         chase_active_backup = autocvar_chase_active;
1451                         cvar_set("chase_active", "2");
1452                         cvar_set("cl_demo_mousegrab", "1");
1453                         camera_active = true;
1454                         camera_mode = false;
1455                 }
1456         }
1457
1458         // Draw the Crosshair
1459         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1460
1461         // Draw the Engine Status Bar (the default Quake HUD)
1462         setproperty(VF_DRAWENGINESBAR, 0);
1463
1464         // Update the mouse position
1465         /*
1466            mousepos_x = vid_conwidth;
1467            mousepos_y = vid_conheight;
1468            mousepos = mousepos*0.5 + getmousepos();
1469          */
1470
1471         for(entity e = NULL; (e = nextent(e)); ) if (e.draw) {
1472                 WITH(entity, self, e, e.draw(e));
1473         }
1474
1475         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1476         renderscene();
1477
1478         // now switch to 2D drawing mode by calling a 2D drawing function
1479         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1480         // next R_RenderScene call
1481         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1482
1483         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1484         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1485         {
1486                 // apply night vision effect
1487                 vector tc_00, tc_01, tc_10, tc_11;
1488                 vector rgb = '0 0 0';
1489
1490                 if(!nightvision_noise)
1491                 {
1492                         nightvision_noise = spawn();
1493                         nightvision_noise.classname = "nightvision_noise";
1494                 }
1495                 if(!nightvision_noise2)
1496                 {
1497                         nightvision_noise2 = spawn();
1498                         nightvision_noise2.classname = "nightvision_noise2";
1499                 }
1500
1501                 // color tint in yellow
1502                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1503
1504                 // draw BG
1505                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1506                 rgb = '1 1 1';
1507                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1508                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1509                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1510                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1511                 tc_11 = tc_01 + tc_10 - tc_00;
1512                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1513                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1514                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1515                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1516                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1517                 R_EndPolygon();
1518
1519                 // draw FG
1520                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1521                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1522                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1523                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1524                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1525                 tc_11 = tc_01 + tc_10 - tc_00;
1526                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1527                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1528                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1529                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1530                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1531                 R_EndPolygon();
1532         }
1533
1534         if(autocvar_cl_reticle)
1535         {
1536                 Weapon wep = get_weaponinfo(activeweapon);
1537                 // Draw the aiming reticle for weapons that use it
1538                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
1539                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
1540                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
1541                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
1542                 {
1543                         // no zoom reticle while dead
1544                         reticle_type = 0;
1545                 }
1546                 else if(wep.wr_zoomreticle(wep) && autocvar_cl_reticle_weapon)
1547                 {
1548                         if(reticle_image != "") { reticle_type = 2; }
1549                         else { reticle_type = 0; }
1550                 }
1551                 else if(button_zoom || zoomscript_caught)
1552                 {
1553                         // normal zoom
1554                         reticle_type = 1;
1555                 }
1556
1557                 if(reticle_type)
1558                 {
1559                         if(autocvar_cl_reticle_stretch)
1560                         {
1561                                 reticle_size.x = vid_conwidth;
1562                                 reticle_size.y = vid_conheight;
1563                                 reticle_pos.x = 0;
1564                                 reticle_pos.y = 0;
1565                         }
1566                         else
1567                         {
1568                                 reticle_size.x = max(vid_conwidth, vid_conheight);
1569                                 reticle_size.y = max(vid_conwidth, vid_conheight);
1570                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
1571                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
1572                         }
1573
1574                         if(zoomscript_caught)
1575                                 f = 1;
1576                         else
1577                                 f = current_zoomfraction;
1578
1579                         if(f)
1580                         {
1581                                 switch(reticle_type)
1582                                 {
1583                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
1584                                         case 2: drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
1585                                 }
1586                         }
1587                 }
1588         }
1589         else
1590         {
1591                 if(reticle_type != 0) { reticle_type = 0; }
1592         }
1593
1594
1595         // improved polyblend
1596         if(autocvar_hud_contents)
1597         {
1598                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
1599                 vector liquidcolor;
1600
1601                 switch(pointcontents(view_origin))
1602                 {
1603                         case CONTENT_WATER:
1604                                 liquidalpha = autocvar_hud_contents_water_alpha;
1605                                 liquidcolor = stov(autocvar_hud_contents_water_color);
1606                                 incontent = 1;
1607                                 break;
1608
1609                         case CONTENT_LAVA:
1610                                 liquidalpha = autocvar_hud_contents_lava_alpha;
1611                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
1612                                 incontent = 1;
1613                                 break;
1614
1615                         case CONTENT_SLIME:
1616                                 liquidalpha = autocvar_hud_contents_slime_alpha;
1617                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
1618                                 incontent = 1;
1619                                 break;
1620
1621                         default:
1622                                 liquidalpha = 0;
1623                                 liquidcolor = '0 0 0';
1624                                 incontent = 0;
1625                                 break;
1626                 }
1627
1628                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
1629                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
1630                         contentfadetime = autocvar_hud_contents_fadeintime;
1631                         liquidalpha_prev = liquidalpha;
1632                         liquidcolor_prev = liquidcolor;
1633                 }
1634                 else
1635                         contentfadetime = autocvar_hud_contents_fadeouttime;
1636
1637                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
1638                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
1639
1640                 if(contentavgalpha)
1641                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
1642
1643                 if(autocvar_hud_postprocessing)
1644                 {
1645                         if(autocvar_hud_contents_blur && contentavgalpha)
1646                         {
1647                                 content_blurpostprocess.x = 1;
1648                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
1649                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
1650                         }
1651                         else
1652                         {
1653                                 content_blurpostprocess.x = 0;
1654                                 content_blurpostprocess.y = 0;
1655                                 content_blurpostprocess.z = 0;
1656                         }
1657                 }
1658         }
1659
1660         if(autocvar_hud_damage && !getstati(STAT_FROZEN))
1661         {
1662                 splash_size.x = max(vid_conwidth, vid_conheight);
1663                 splash_size.y = max(vid_conwidth, vid_conheight);
1664                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
1665                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
1666
1667                 float myhealth_flash_temp;
1668                 myhealth = getstati(STAT_HEALTH);
1669
1670                 // fade out
1671                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
1672                 // add new damage
1673                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
1674
1675                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
1676                 pain_threshold = autocvar_hud_damage_pain_threshold;
1677                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
1678                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
1679
1680                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
1681                 {
1682                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
1683                 }
1684
1685                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
1686
1687                 if(myhealth_prev < 1)
1688                 {
1689                         if(myhealth >= 1)
1690                         {
1691                                 myhealth_flash = 0; // just spawned, clear the flash immediately
1692                                 myhealth_flash_temp = 0;
1693                         }
1694                         else
1695                         {
1696                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
1697                         }
1698                 }
1699
1700                 if(spectatee_status == -1 || intermission)
1701                 {
1702                         myhealth_flash = 0; // observing, or match ended
1703                         myhealth_flash_temp = 0;
1704                 }
1705
1706                 myhealth_prev = myhealth;
1707
1708                 // IDEA: change damage color/picture based on player model for robot/alien species?
1709                 // pro: matches model better
1710                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
1711                 // maybe different reddish pics?
1712                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
1713                 {
1714                         if(autocvar_cl_gentle_damage == 2)
1715                         {
1716                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
1717                                 {
1718                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
1719                                 }
1720                         }
1721                         else
1722                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
1723
1724                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1725                 }
1726                 else
1727                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1728
1729                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
1730                 {
1731                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
1732                         {
1733                                 damage_blurpostprocess.x = 1;
1734                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
1735                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
1736                         }
1737                         else
1738                         {
1739                                 damage_blurpostprocess.x = 0;
1740                                 damage_blurpostprocess.y = 0;
1741                                 damage_blurpostprocess.z = 0;
1742                         }
1743                 }
1744         }
1745
1746         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
1747         float e2 = (autocvar_hud_powerup != 0);
1748         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
1749         {
1750                 // enable or disable rendering types if they are used or not
1751                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
1752                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
1753
1754                 // blur postprocess handling done first (used by hud_damage and hud_contents)
1755                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
1756                 {
1757                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
1758                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
1759                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
1760                         {
1761                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
1762                                 old_blurradius = blurradius;
1763                                 old_bluralpha = bluralpha;
1764                         }
1765                 }
1766                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
1767                 {
1768                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1769                         old_blurradius = 0;
1770                         old_bluralpha = 0;
1771                 }
1772
1773                 // edge detection postprocess handling done second (used by hud_powerup)
1774                 float sharpen_intensity = 0, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
1775                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
1776                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
1777
1778                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
1779
1780                 if(autocvar_hud_powerup && sharpen_intensity > 0)
1781                 {
1782                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
1783                         {
1784                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
1785                                 old_sharpen_intensity = sharpen_intensity;
1786                         }
1787                 }
1788                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
1789                 {
1790                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
1791                         old_sharpen_intensity = 0;
1792                 }
1793
1794                 if(cvar("r_glsl_postprocess") == 0)
1795                         cvar_set("r_glsl_postprocess", "2");
1796         }
1797         else if(cvar("r_glsl_postprocess") == 2)
1798                 cvar_set("r_glsl_postprocess", "0");
1799
1800         if(menu_visible)
1801                 menu_show();
1802
1803         /*if(gametype == MAPINFO_TYPE_CTF)
1804           {
1805           ctf_view();
1806           } else */
1807
1808         // draw 2D entities
1809         for (entity e = NULL; (e = nextent(e)); ) if (e.draw2d) {
1810                 WITH(entity, self, e, e.draw2d(e));
1811         }
1812         Draw_ShowNames_All();
1813
1814         scoreboard_active = HUD_WouldDrawScoreboard();
1815
1816         UpdateDamage();
1817         UpdateCrosshair();
1818         UpdateHitsound();
1819
1820         if(NextFrameCommand)
1821         {
1822                 localcmd("\n", NextFrameCommand, "\n");
1823                 NextFrameCommand = string_null;
1824         }
1825
1826         // we must do this check AFTER a frame was rendered, or it won't work
1827         if(cs_project_is_b0rked == 0)
1828         {
1829                 string w0, h0;
1830                 w0 = ftos(autocvar_vid_conwidth);
1831                 h0 = ftos(autocvar_vid_conheight);
1832                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1833                 //setproperty(VF_FOV, '90 90 0');
1834                 setproperty(VF_ORIGIN, '0 0 0');
1835                 setproperty(VF_ANGLES, '0 0 0');
1836                 setproperty(VF_PERSPECTIVE, 1);
1837                 makevectors('0 0 0');
1838                 vector v1, v2;
1839                 cvar_set("vid_conwidth", "800");
1840                 cvar_set("vid_conheight", "600");
1841                 v1 = cs_project(v_forward);
1842                 cvar_set("vid_conwidth", "640");
1843                 cvar_set("vid_conheight", "480");
1844                 v2 = cs_project(v_forward);
1845                 if(v1 == v2)
1846                         cs_project_is_b0rked = 1;
1847                 else
1848                         cs_project_is_b0rked = -1;
1849                 cvar_set("vid_conwidth", w0);
1850                 cvar_set("vid_conheight", h0);
1851         }
1852
1853         if(autocvar__hud_configure)
1854                 HUD_Panel_Mouse();
1855         else if ( HUD_MinigameMenu_IsOpened() || minigame_isactive() )
1856                 HUD_Minigame_Mouse();
1857         else if(QuickMenu_IsOpened())
1858                 QuickMenu_Mouse();
1859         else
1860                 HUD_Radar_Mouse();
1861
1862     if(hud && !intermission)
1863     if(hud == HUD_BUMBLEBEE_GUN)
1864         CSQC_BUMBLE_GUN_HUD();
1865     else {
1866         Vehicle info = get_vehicleinfo(hud);
1867                 info.vr_hud(info);
1868         }
1869
1870         cl_notice_run();
1871
1872         // let's reset the view back to normal for the end
1873         setproperty(VF_MIN, '0 0 0');
1874         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1875 }
1876
1877
1878 void CSQC_common_hud(void)
1879 {
1880         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1881                 Accuracy_LoadLevels();
1882
1883         HUD_Main(); // always run these functions for alpha checks
1884         HUD_DrawScoreboard();
1885
1886         // scoreboard/accuracy, map/gametype voting screen
1887         if (scoreboard_active || intermission == 2)
1888                 HUD_Reset();
1889 }
1890
1891
1892 // following vectors must be global to allow seamless switching between camera modes
1893 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1894 void CSQC_Demo_Camera()
1895 {
1896         float speed, attenuation, dimensions;
1897         vector tmp, delta;
1898
1899         if( autocvar_camera_reset || !camera_mode )
1900         {
1901                 camera_offset = '0 0 0';
1902                 current_angles = '0 0 0';
1903                 camera_direction = '0 0 0';
1904                 camera_offset.z += 30;
1905                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
1906                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
1907                 current_origin = view_origin;
1908                 current_camera_offset  = camera_offset;
1909                 cvar_set("camera_reset", "0");
1910                 camera_mode = CAMERA_CHASE;
1911         }
1912
1913         // Camera angles
1914         if( camera_roll )
1915                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
1916
1917         if(autocvar_camera_look_player)
1918         {
1919                 vector dir;
1920                 float n;
1921
1922                 dir = normalize(view_origin - current_position);
1923                 n = mouse_angles.z;
1924                 mouse_angles = vectoangles(dir);
1925                 mouse_angles.x = mouse_angles.x * -1;
1926                 mouse_angles.z = n;
1927         }
1928         else
1929         {
1930                 tmp = getmousepos() * 0.1;
1931                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1932                 {
1933                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
1934                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
1935                 }
1936         }
1937
1938         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
1939         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
1940         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
1941         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
1942
1943         // Fix difference when angles don't have the same sign
1944         delta = '0 0 0';
1945         if(mouse_angles.y < -60 && current_angles.y > 60)
1946                 delta = '0 360 0';
1947         if(mouse_angles.y > 60 && current_angles.y < -60)
1948                 delta = '0 -360 0';
1949
1950         if(autocvar_camera_look_player)
1951                 attenuation = autocvar_camera_look_attenuation;
1952         else
1953                 attenuation = autocvar_camera_speed_attenuation;
1954
1955         attenuation = 1 / max(1, attenuation);
1956         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1957
1958         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
1959         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
1960         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
1961         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
1962
1963         // Camera position
1964         tmp = '0 0 0';
1965         dimensions = 0;
1966
1967         if( camera_direction.x )
1968         {
1969                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
1970                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
1971                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1972                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
1973                 ++dimensions;
1974         }
1975
1976         if( camera_direction.y )
1977         {
1978                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
1979                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
1980                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
1981                 ++dimensions;
1982         }
1983
1984         if( camera_direction.z )
1985         {
1986                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
1987                 ++dimensions;
1988         }
1989
1990         if(autocvar_camera_free)
1991                 speed = autocvar_camera_speed_free;
1992         else
1993                 speed = autocvar_camera_speed_chase;
1994
1995         if(dimensions)
1996         {
1997                 speed = speed * sqrt(1 / dimensions);
1998                 camera_offset += tmp * speed;
1999         }
2000
2001         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2002
2003         // Camera modes
2004         if( autocvar_camera_free )
2005         {
2006                 if ( camera_mode == CAMERA_CHASE )
2007                 {
2008                         current_camera_offset = current_origin + current_camera_offset;
2009                         camera_offset = current_origin + camera_offset;
2010                 }
2011
2012                 camera_mode = CAMERA_FREE;
2013                 current_position = current_camera_offset;
2014         }
2015         else
2016         {
2017                 if ( camera_mode == CAMERA_FREE )
2018                 {
2019                         current_origin = view_origin;
2020                         camera_offset = camera_offset - current_origin;
2021                         current_camera_offset = current_camera_offset - current_origin;
2022                 }
2023
2024                 camera_mode = CAMERA_CHASE;
2025
2026                 if(autocvar_camera_chase_smoothly)
2027                         current_origin += (view_origin - current_origin) * attenuation;
2028                 else
2029                         current_origin = view_origin;
2030
2031                 current_position = current_origin + current_camera_offset;
2032         }
2033
2034         setproperty(VF_ANGLES, current_angles);
2035         setproperty(VF_ORIGIN, current_position);
2036 }