Merge branch 'master' into terencehill/menu_optimization
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / view.qc
1
2 #include "announcer.qh"
3 #include "hook.qh"
4 #include "hud/all.qh"
5 #include "mapvoting.qh"
6 #include "scoreboard.qh"
7 #include "shownames.qh"
8 #include "quickmenu.qh"
9
10 #include "mutators/events.qh"
11
12 #include "../common/anim.qh"
13 #include "../common/constants.qh"
14 #include "../common/debug.qh"
15 #include "../common/mapinfo.qh"
16 #include "../common/gamemodes/all.qh"
17 #include "../common/physics.qh"
18 #include "../common/stats.qh"
19 #include "../common/triggers/target/music.qh"
20 #include "../common/teams.qh"
21
22 #include "../common/vehicles/all.qh"
23 #include "../common/weapons/all.qh"
24 #include "../common/viewloc.qh"
25 #include "../common/minigames/cl_minigames.qh"
26 #include "../common/minigames/cl_minigames_hud.qh"
27
28 #include "../lib/csqcmodel/cl_player.qh"
29
30 #include "../lib/warpzone/client.qh"
31 #include "../lib/warpzone/common.qh"
32
33 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
34
35 float autocvar_cl_viewmodel_scale;
36
37 bool autocvar_cl_bobmodel;
38 float autocvar_cl_bobmodel_speed;
39 float autocvar_cl_bobmodel_side;
40 float autocvar_cl_bobmodel_up;
41
42 float autocvar_cl_followmodel;
43 float autocvar_cl_followmodel_side_speed;
44 float autocvar_cl_followmodel_side_highpass;
45 float autocvar_cl_followmodel_side_highpass1;
46 float autocvar_cl_followmodel_side_limit;
47 float autocvar_cl_followmodel_side_lowpass;
48 float autocvar_cl_followmodel_up_speed;
49 float autocvar_cl_followmodel_up_highpass;
50 float autocvar_cl_followmodel_up_highpass1;
51 float autocvar_cl_followmodel_up_limit;
52 float autocvar_cl_followmodel_up_lowpass;
53
54 float autocvar_cl_leanmodel;
55 float autocvar_cl_leanmodel_side_speed;
56 float autocvar_cl_leanmodel_side_highpass;
57 float autocvar_cl_leanmodel_side_highpass1;
58 float autocvar_cl_leanmodel_side_lowpass;
59 float autocvar_cl_leanmodel_side_limit;
60 float autocvar_cl_leanmodel_up_speed;
61 float autocvar_cl_leanmodel_up_highpass;
62 float autocvar_cl_leanmodel_up_highpass1;
63 float autocvar_cl_leanmodel_up_lowpass;
64 float autocvar_cl_leanmodel_up_limit;
65
66 #define lowpass(value, frac, ref_store, ret) MACRO_BEGIN \
67 { \
68         float __frac = bound(0, frac, 1); \
69         ret = ref_store = ref_store * (1 - __frac) + (value) * __frac; \
70 } MACRO_END
71
72 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
73 { \
74         float __ignore; lowpass(value, frac, ref_store, __ignore); \
75         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
76 } MACRO_END
77
78 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
79 { \
80         float __f; lowpass(value, frac, ref_store, __f); \
81         ret = (value) - __f; \
82 } MACRO_END
83
84 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
85 { \
86         float __f; lowpass_limited(value, frac, limit, ref_store, __f); \
87         ret = (value) - __f; \
88 } MACRO_END
89
90 #define lowpass3(value, fracx, fracy, fracz, ref_store, ref_out) MACRO_BEGIN \
91 { \
92         lowpass(value.x, fracx, ref_store.x, ref_out.x); \
93         lowpass(value.y, fracy, ref_store.y, ref_out.y); \
94         lowpass(value.z, fracz, ref_store.z, ref_out.z); \
95 } MACRO_END
96
97 #define highpass3(value, fracx, fracy, fracz, ref_store, ref_out) MACRO_BEGIN \
98 { \
99         highpass(value.x, fracx, ref_store.x, ref_out.x); \
100         highpass(value.y, fracy, ref_store.y, ref_out.y); \
101         highpass(value.z, fracz, ref_store.z, ref_out.z); \
102 } MACRO_END
103
104 #define highpass3_limited(value, fracx, limitx, fracy, limity, fracz, limitz, ref_store, ref_out) MACRO_BEGIN \
105 { \
106         highpass_limited(value.x, fracx, limitx, ref_store.x, ref_out.x); \
107         highpass_limited(value.y, fracy, limity, ref_store.y, ref_out.y); \
108         highpass_limited(value.z, fracz, limitz, ref_store.z, ref_out.z); \
109 } MACRO_END
110
111 void viewmodel_animate(entity this)
112 {
113         static float prevtime;
114         float frametime = (time - prevtime) * STAT(MOVEVARS_TIMESCALE);
115         prevtime = time;
116
117         if (autocvar_chase_active) return;
118         if (STAT(HEALTH) <= 0) return;
119
120         entity view = CSQCModel_server2csqc(player_localentnum - 1);
121
122         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
123         static bool oldonground;
124         static float hitgroundtime;
125         static float lastongroundtime;
126         if (clonground)
127         {
128                 float f = time; // cl.movecmd[0].time
129                 if (!oldonground)
130                         hitgroundtime = f;
131                 lastongroundtime = f;
132         }
133         oldonground = clonground;
134
135         vector gunorg = '0 0 0', gunangles = '0 0 0';
136         static vector gunorg_prev = '0 0 0', gunangles_prev = '0 0 0';
137
138         bool teleported = view.csqcmodel_teleported;
139
140         // 1. if we teleported, clear the frametime... the lowpass will recover the previous value then
141         if (teleported)
142         {
143                 // try to fix the first highpass; result is NOT
144                 // perfect! TODO find a better fix
145                 gunangles_prev = view_angles;
146                 gunorg_prev = view_origin;
147         }
148
149         static vector gunorg_highpass = '0 0 0';
150
151         // 2. for the gun origin, only keep the high frequency (non-DC) parts, which is "somewhat like velocity"
152         gunorg_highpass += gunorg_prev;
153         highpass3_limited(view_origin,
154                 frametime * autocvar_cl_followmodel_side_highpass1, autocvar_cl_followmodel_side_limit,
155                 frametime * autocvar_cl_followmodel_side_highpass1, autocvar_cl_followmodel_side_limit,
156                 frametime * autocvar_cl_followmodel_up_highpass1, autocvar_cl_followmodel_up_limit,
157                 gunorg_highpass, gunorg);
158         gunorg_prev = view_origin;
159         gunorg_highpass -= gunorg_prev;
160
161         static vector gunangles_highpass = '0 0 0';
162
163         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
164         gunangles_highpass += gunangles_prev;
165         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
166         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
167         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
168         highpass3_limited(view_angles,
169                 frametime * autocvar_cl_leanmodel_up_highpass1, autocvar_cl_leanmodel_up_limit,
170                 frametime * autocvar_cl_leanmodel_side_highpass1, autocvar_cl_leanmodel_side_limit,
171                 0, 0,
172                 gunangles_highpass, gunangles);
173         gunangles_prev = view_angles;
174         gunangles_highpass -= gunangles_prev;
175
176         // 3. calculate the RAW adjustment vectors
177         gunorg.x *= (autocvar_cl_followmodel ? -autocvar_cl_followmodel_side_speed : 0);
178         gunorg.y *= (autocvar_cl_followmodel ? -autocvar_cl_followmodel_side_speed : 0);
179         gunorg.z *= (autocvar_cl_followmodel ? -autocvar_cl_followmodel_up_speed : 0);
180
181         PITCH(gunangles) *= (autocvar_cl_leanmodel ? -autocvar_cl_leanmodel_up_speed : 0);
182         YAW(gunangles) *= (autocvar_cl_leanmodel ? -autocvar_cl_leanmodel_side_speed : 0);
183         ROLL(gunangles) = 0;
184
185         static vector gunorg_adjustment_highpass;
186         static vector gunorg_adjustment_lowpass;
187         static vector gunangles_adjustment_highpass;
188         static vector gunangles_adjustment_lowpass;
189
190         // 4. perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
191         //    trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
192         highpass3(gunorg,
193                 frametime * autocvar_cl_followmodel_side_highpass,
194                 frametime * autocvar_cl_followmodel_side_highpass,
195                 frametime * autocvar_cl_followmodel_up_highpass,
196                 gunorg_adjustment_highpass, gunorg);
197         lowpass3(gunorg,
198                 frametime * autocvar_cl_followmodel_side_lowpass,
199                 frametime * autocvar_cl_followmodel_side_lowpass,
200                 frametime * autocvar_cl_followmodel_up_lowpass,
201                 gunorg_adjustment_lowpass, gunorg);
202         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
203         highpass3(gunangles,
204                 frametime * autocvar_cl_leanmodel_up_highpass,
205                 frametime * autocvar_cl_leanmodel_side_highpass,
206                 0,
207                 gunangles_adjustment_highpass, gunangles);
208         lowpass3(gunangles,
209                 frametime * autocvar_cl_leanmodel_up_lowpass,
210                 frametime * autocvar_cl_leanmodel_side_lowpass,
211                 0,
212                 gunangles_adjustment_lowpass, gunangles);
213         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
214
215         // vertical view bobbing code
216         // TODO: cl_bob
217
218         // horizontal view bobbing code
219         // TODO: cl_bob2
220
221         // fall bobbing code
222         // causes the view to swing down and back up when touching the ground
223         // TODO: cl_bobfall
224
225         // gun model bobbing code
226         if (autocvar_cl_bobmodel)
227         {
228                 // calculate for swinging gun model
229                 // the gun bobs when running on the ground, but doesn't bob when you're in the air.
230                 // Sajt: I tried to smooth out the transitions between bob and no bob, which works
231                 // for the most part, but for some reason when you go through a message trigger or
232                 // pick up an item or anything like that it will momentarily jolt the gun.
233                 vector forward, right, up;
234                 float bspeed;
235                 float t = 1;
236                 float s = time * autocvar_cl_bobmodel_speed;
237                 if (clonground)
238                 {
239                         if (time - hitgroundtime < 0.2)
240                         {
241                                 // just hit the ground, speed the bob back up over the next 0.2 seconds
242                                 t = time - hitgroundtime;
243                                 t = bound(0, t, 0.2);
244                                 t *= 5;
245                         }
246                 }
247                 else
248                 {
249                         // recently left the ground, slow the bob down over the next 0.2 seconds
250                         t = time - lastongroundtime;
251                         t = 0.2 - bound(0, t, 0.2);
252                         t *= 5;
253                 }
254                 bspeed = xyspeed * 0.01;
255                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
256                 float bobr = bspeed * autocvar_cl_bobmodel_side * autocvar_cl_viewmodel_scale * sin(s) * t;
257                 gunorg += bobr * right;
258                 float bobu = bspeed * autocvar_cl_bobmodel_up * autocvar_cl_viewmodel_scale * cos(s * 2) * t;
259                 gunorg += bobu * up;
260         }
261         vector v = rotate(gunorg, YAW(view_angles) * DEG2RAD); // rotate world coordinates to relative ones
262         v.z = gunorg.z;
263         this.origin += v;
264         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
265         this.angles += gunangles;
266 }
267
268 .vector viewmodel_origin, viewmodel_angles;
269 .float weapon_nextthink;
270 .float weapon_eta_last;
271 .float weapon_switchdelay;
272
273 void viewmodel_draw(entity this)
274 {
275         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
276         float a = this.alpha;
277         int c = stof(getplayerkeyvalue(current_player, "colors"));
278         vector g;
279         Weapon wep = activeweapon;
280         if (!(g = wep.wr_glow(wep))) g = colormapPaletteColor(c & 0x0F, true) * 2;
281         entity me = CSQCModel_server2csqc(player_localentnum - 1);
282         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
283                 | EF_NODEPTHTEST)
284                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
285         for (entity e = this; e; e = e.weaponchild)
286         {
287                 e.drawmask = mask;
288                 e.alpha = a;
289                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
290                 e.glowmod = g;
291                 e.csqcmodel_effects = fx;
292                 WITH(entity, self, e, CSQCModel_Effects_Apply());
293         }
294         {
295                 static string name_last;
296                 string name = wep.mdl;
297                 if (name != name_last)
298                 {
299                         name_last = name;
300                         CL_WeaponEntity_SetModel(this, name);
301                         this.viewmodel_origin = this.origin;
302                         this.viewmodel_angles = this.angles;
303                 }
304                 anim_update(this);
305                 if (!this.animstate_override)
306                         anim_set(this, this.anim_idle, true, false, false);
307         }
308         float f = 0; // 0..1; 0: fully active
309         float eta = (this.weapon_nextthink - time) / STAT(WEAPONRATEFACTOR);
310         if (eta <= 0) f = this.weapon_eta_last;
311         else switch (this.state)
312         {
313                 case WS_RAISE:
314                 {
315                         f = eta / max(eta, this.weapon_switchdelay);
316                         break;
317                 }
318                 case WS_DROP:
319                 {
320                         f = 1 - eta / max(eta, this.weapon_switchdelay);
321                         break;
322                 }
323                 case WS_CLEAR:
324                 {
325                         f = 1;
326                         break;
327                 }
328         }
329         this.weapon_eta_last = f;
330         this.origin = this.viewmodel_origin;
331         this.angles = this.viewmodel_angles;
332         this.angles_x = (-90 * f * f);
333         viewmodel_animate(this);
334         setorigin(this, this.origin);
335 }
336
337 entity viewmodel;
338 STATIC_INIT(viewmodel) {
339     viewmodel = new(viewmodel);
340     make_pure(viewmodel);
341         viewmodel.draw = viewmodel_draw;
342 }
343
344 entity porto;
345 vector polyline[16];
346 void Porto_Draw(entity this)
347 {
348         vector p, dir, ang, q, nextdir;
349         float portal_number, portal1_idx;
350
351         if(activeweapon != WEP_PORTO || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
352                 return;
353         if(WEP_CVAR(porto, secondary))
354                 return;
355         if(intermission == 1)
356                 return;
357         if(intermission == 2)
358                 return;
359         if (STAT(HEALTH) <= 0)
360                 return;
361
362         dir = view_forward;
363
364         if(angles_held_status)
365         {
366                 makevectors(angles_held);
367                 dir = v_forward;
368         }
369
370         p = view_origin;
371
372         polyline[0] = p;
373         int idx = 1;
374         portal_number = 0;
375         nextdir = dir;
376
377         for (;;)
378         {
379                 dir = nextdir;
380                 traceline(p, p + 65536 * dir, true, porto);
381                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
382                         return;
383                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
384                 p = trace_endpos;
385                 polyline[idx] = p;
386                 ++idx;
387                 if(idx >= 16)
388                         return;
389                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
390                         continue;
391                 ++portal_number;
392                 ang = vectoangles2(trace_plane_normal, dir);
393                 ang.x = -ang.x;
394                 makevectors(ang);
395                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
396                         return;
397                 if(portal_number == 1)
398                 {
399                         portal1_idx = idx;
400                         if(portal_number >= 2)
401                                 break;
402                 }
403         }
404
405         while(idx >= 2)
406         {
407                 p = polyline[idx-2];
408                 q = polyline[idx-1];
409                 if(idx == 2)
410                         p = p - view_up * 16;
411                 if(idx-1 >= portal1_idx)
412                 {
413                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
414                 }
415                 else
416                 {
417                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
418                 }
419                 --idx;
420         }
421 }
422
423 void Porto_Init()
424 {
425         porto = new(porto);
426         make_pure(porto);
427         porto.draw = Porto_Draw;
428         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
429 }
430
431 float drawtime;
432 float avgspeed;
433 vector GetCurrentFov(float fov)
434 {
435         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
436         float velocityzoom, curspeed;
437         vector v;
438
439         zoomsensitivity = autocvar_cl_zoomsensitivity;
440         zoomfactor = autocvar_cl_zoomfactor;
441         if(zoomfactor < 1 || zoomfactor > 30)
442                 zoomfactor = 2.5;
443         zoomspeed = autocvar_cl_zoomspeed;
444         if(zoomspeed >= 0)
445         if(zoomspeed < 0.5 || zoomspeed > 16)
446                         zoomspeed = 3.5;
447
448         zoomdir = button_zoom;
449         if(hud == HUD_NORMAL)
450         if(switchweapon == activeweapon)
451         if((activeweapon == WEP_VORTEX && !WEP_CVAR(vortex, secondary)) || (activeweapon == WEP_RIFLE && !WEP_CVAR(rifle, secondary))) // do NOT use switchweapon here
452                 zoomdir += button_attack2;
453         if(spectatee_status > 0 || isdemo())
454         {
455                 if(spectatorbutton_zoom)
456                 {
457                         if(zoomdir)
458                                 zoomdir = 0;
459                         else
460                                 zoomdir = 1;
461                 }
462                 // fteqcc failed twice here already, don't optimize this
463         }
464
465         if(zoomdir) { zoomin_effect = 0; }
466
467         if(camera_active)
468         {
469                 current_viewzoom = min(1, current_viewzoom + drawframetime);
470         }
471         else if(autocvar_cl_spawnzoom && zoomin_effect)
472         {
473                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
474
475                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
476                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
477                 if(current_viewzoom == 1) { zoomin_effect = 0; }
478         }
479         else
480         {
481                 if(zoomspeed < 0) // instant zoom
482                 {
483                         if(zoomdir)
484                                 current_viewzoom = 1 / zoomfactor;
485                         else
486                                 current_viewzoom = 1;
487                 }
488                 else
489                 {
490                         if(zoomdir)
491                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
492                         else
493                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
494                 }
495         }
496
497         if(almost_equals(current_viewzoom, 1))
498                 current_zoomfraction = 0;
499         else if(almost_equals(current_viewzoom, 1/zoomfactor))
500                 current_zoomfraction = 1;
501         else
502                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
503
504         if(zoomsensitivity < 1)
505                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
506         else
507                 setsensitivityscale(1);
508
509         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
510         {
511                 if(intermission) { curspeed = 0; }
512                 else
513                 {
514
515                         makevectors(view_angles);
516                         v = pmove_vel;
517                         if(csqcplayer)
518                                 v = csqcplayer.velocity;
519
520                         switch(autocvar_cl_velocityzoom_type)
521                         {
522                                 case 3: curspeed = max(0, v_forward * v); break;
523                                 case 2: curspeed = (v_forward * v); break;
524                                 case 1: default: curspeed = vlen(v); break;
525                         }
526                 }
527
528                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
529                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
530                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
531
532                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
533         }
534         else
535                 velocityzoom = 1;
536
537         float frustumx, frustumy, fovx, fovy;
538         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
539         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
540         fovx = atan2(frustumx, 1) / M_PI * 360.0;
541         fovy = atan2(frustumy, 1) / M_PI * 360.0;
542
543         return '1 0 0' * fovx + '0 1 0' * fovy;
544 }
545
546 vector GetViewLocationFOV(float fov)
547 {
548         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
549         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
550         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
551         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
552         return '1 0 0' * fovx + '0 1 0' * fovy;
553 }
554
555 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
556 {
557         float fovx, fovy;
558         float width = (ov_worldmax.x - ov_worldmin.x);
559         float height = (ov_worldmax.y - ov_worldmin.y);
560         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
561         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
562         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
563         return '1 0 0' * fovx + '0 1 0' * fovy;
564 }
565
566 // this function must match W_SetupShot!
567 float zoomscript_caught;
568
569 vector wcross_origin;
570 float wcross_scale_prev, wcross_alpha_prev;
571 vector wcross_color_prev;
572 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
573 vector wcross_color_goal_prev;
574 float wcross_changedonetime;
575
576 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
577 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
578 float wcross_name_changestarttime, wcross_name_changedonetime;
579 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
580
581 float wcross_ring_prev;
582
583 entity trueaim;
584 entity trueaim_rifle;
585
586 const float SHOTTYPE_HITTEAM = 1;
587 const float SHOTTYPE_HITOBSTRUCTION = 2;
588 const float SHOTTYPE_HITWORLD = 3;
589 const float SHOTTYPE_HITENEMY = 4;
590
591 void TrueAim_Init()
592 {
593         trueaim = new(trueaim);
594         make_pure(trueaim);
595         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
596         trueaim_rifle = new(trueaim_rifle);
597         make_pure(trueaim_rifle);
598         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
599 }
600
601 float EnemyHitCheck()
602 {
603         float t, n;
604         wcross_origin = project_3d_to_2d(trace_endpos);
605         wcross_origin.z = 0;
606         if(trace_ent)
607                 n = trace_ent.entnum;
608         else
609                 n = trace_networkentity;
610         if(n < 1)
611                 return SHOTTYPE_HITWORLD;
612         if(n > maxclients)
613                 return SHOTTYPE_HITWORLD;
614         t = entcs_GetTeam(n - 1);
615         if(teamplay)
616                 if(t == myteam)
617                         return SHOTTYPE_HITTEAM;
618         if(t == NUM_SPECTATOR)
619                 return SHOTTYPE_HITWORLD;
620         return SHOTTYPE_HITENEMY;
621 }
622
623 float TrueAimCheck()
624 {
625         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
626         vector vecs, trueaimpoint, w_shotorg;
627         vector mi, ma, dv;
628         float shottype;
629         entity ta;
630         float mv;
631
632         mi = ma = '0 0 0';
633         ta = trueaim;
634         mv = MOVE_NOMONSTERS;
635
636         switch(activeweapon) // WEAPONTODO
637         {
638                 case WEP_TUBA: // no aim
639                 case WEP_PORTO: // shoots from eye
640                 case WEP_NEXBALL: // shoots from eye
641                 case WEP_HOOK: // no trueaim
642                 case WEP_MORTAR: // toss curve
643                         return SHOTTYPE_HITWORLD;
644                 case WEP_VORTEX:
645                 case WEP_VAPORIZER:
646                         mv = MOVE_NORMAL;
647                         break;
648                 case WEP_RIFLE:
649                         ta = trueaim_rifle;
650                         mv = MOVE_NORMAL;
651                         if(zoomscript_caught)
652                         {
653                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
654                                 return EnemyHitCheck();
655                         }
656                         break;
657                 case WEP_DEVASTATOR: // projectile has a size!
658                         mi = '-3 -3 -3';
659                         ma = '3 3 3';
660                         break;
661                 case WEP_FIREBALL: // projectile has a size!
662                         mi = '-16 -16 -16';
663                         ma = '16 16 16';
664                         break;
665                 case WEP_SEEKER: // projectile has a size!
666                         mi = '-2 -2 -2';
667                         ma = '2 2 2';
668                         break;
669                 case WEP_ELECTRO: // projectile has a size!
670                         mi = '0 0 -3';
671                         ma = '0 0 -3';
672                         break;
673         }
674
675         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
676
677         vecs = decompressShotOrigin(STAT(SHOTORG));
678
679         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
680         trueaimpoint = trace_endpos;
681
682         if(vlen(trueaimpoint - traceorigin) < g_trueaim_minrange)
683                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
684
685         if(vecs.x > 0)
686                 vecs.y = -vecs.y;
687         else
688                 vecs = '0 0 0';
689
690         dv = view_right * vecs.y + view_up * vecs.z;
691         w_shotorg = traceorigin + dv;
692
693         // now move the vecs forward as much as requested if possible
694         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
695         w_shotorg = trace_endpos - view_forward * nudge;
696
697         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
698         shottype = EnemyHitCheck();
699         if(shottype != SHOTTYPE_HITWORLD)
700                 return shottype;
701
702 #if 0
703         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
704         // or rather, I know why, but see no fix
705         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
706                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
707                 return SHOTTYPE_HITOBSTRUCTION;
708 #endif
709
710         return SHOTTYPE_HITWORLD;
711 }
712
713 void PostInit();
714 void CSQC_Demo_Camera();
715 float HUD_WouldDrawScoreboard();
716 float camera_mode;
717 const float CAMERA_FREE = 1;
718 const float CAMERA_CHASE = 2;
719 float reticle_type;
720 string reticle_image;
721 string NextFrameCommand;
722
723 vector freeze_org, freeze_ang;
724 entity nightvision_noise, nightvision_noise2;
725
726 const float MAX_TIME_DIFF = 5;
727 float pickup_crosshair_time, pickup_crosshair_size;
728 float hitindication_crosshair_size;
729 float use_vortex_chargepool;
730
731 float myhealth, myhealth_prev;
732 float myhealth_flash;
733
734 float old_blurradius, old_bluralpha;
735 float old_sharpen_intensity;
736
737 vector myhealth_gentlergb;
738
739 float contentavgalpha, liquidalpha_prev;
740 vector liquidcolor_prev;
741
742 float eventchase_current_distance;
743 float eventchase_running;
744 bool WantEventchase()
745 {SELFPARAM();
746         if(autocvar_cl_orthoview)
747                 return false;
748         if(intermission)
749                 return true;
750         if(self.viewloc)
751                 return true;
752         if(spectatee_status >= 0)
753         {
754                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
755                         return true;
756                 if(MUTATOR_CALLHOOK(WantEventchase, self))
757                         return true;
758                 if(autocvar_cl_eventchase_nexball && gametype == MAPINFO_TYPE_NEXBALL && !(WepSet_GetFromStat() & WEPSET(NEXBALL)))
759                         return true;
760                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
761                 {
762                         if(autocvar_cl_eventchase_death == 2)
763                         {
764                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
765                                 if(self.velocity == '0 0 0' || eventchase_running)
766                                         return true;
767                         }
768                         else return true;
769                 }
770         }
771         return false;
772 }
773
774 void HUD_Crosshair_Vehicle()
775 {
776         if(hud != HUD_BUMBLEBEE_GUN)
777         {
778                 Vehicle info = get_vehicleinfo(hud);
779                 info.vr_crosshair(info);
780         }
781 }
782
783 vector damage_blurpostprocess, content_blurpostprocess;
784
785 float unaccounted_damage = 0;
786 void UpdateDamage()
787 {
788         // accumulate damage with each stat update
789         static float damage_total_prev = 0;
790         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
791         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
792         damage_total_prev = damage_total;
793
794         static float damage_dealt_time_prev = 0;
795         float damage_dealt_time = STAT(HIT_TIME);
796         if (damage_dealt_time != damage_dealt_time_prev)
797         {
798                 unaccounted_damage += unaccounted_damage_new;
799                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")", "\n");
800         }
801         damage_dealt_time_prev = damage_dealt_time;
802
803         // prevent hitsound when switching spectatee
804         static float spectatee_status_prev = 0;
805         if (spectatee_status != spectatee_status_prev)
806                 unaccounted_damage = 0;
807         spectatee_status_prev = spectatee_status;
808 }
809
810 void HitSound()
811 {
812         // varying sound pitch
813
814         static float hitsound_time_prev = 0;
815         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
816         float arc_hack = activeweapon == WEP_ARC && autocvar_cl_hitsound >= 2;
817         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
818         {
819                 if (autocvar_cl_hitsound && unaccounted_damage)
820                 {
821                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
822                         float a = autocvar_cl_hitsound_max_pitch;
823                         float b = autocvar_cl_hitsound_min_pitch;
824                         float c = autocvar_cl_hitsound_nom_damage;
825                         float x = unaccounted_damage;
826                         float pitch_shift = (b*x*(a-1) + a*c*(1-b)) / (x*(a-1) + c*(1-b));
827
828                         // if sound variation is disabled, set pitch_shift to 1
829                         if (autocvar_cl_hitsound == 1)
830                                 pitch_shift = 1;
831
832                         // if pitch shift is reversed, mirror in (max-min)/2 + min
833                         if (autocvar_cl_hitsound == 3)
834                         {
835                                 float mirror_value = (a-b)/2 + b;
836                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
837                         }
838
839                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift), "\n");
840
841                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
842                         // todo: normalize sound pressure levels? seems unnecessary
843
844                         sound7(world, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
845                 }
846                 unaccounted_damage = 0;
847                 hitsound_time_prev = time;
848         }
849
850         static float typehit_time_prev = 0;
851         float typehit_time = STAT(TYPEHIT_TIME);
852         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
853         {
854                 sound(world, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
855                 typehit_time_prev = typehit_time;
856         }
857 }
858
859 void HUD_Crosshair()
860 {SELFPARAM();
861         static float rainbow_last_flicker;
862         static vector rainbow_prev_color;
863         entity e = self;
864         float f, i, j;
865         vector v;
866         if(!scoreboard_active && !camera_active && intermission != 2 &&
867                 spectatee_status != -1 && !csqcplayer.viewloc &&
868                 !HUD_MinigameMenu_IsOpened() )
869         {
870                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
871                         return;
872
873                 if (hud != HUD_NORMAL)
874                 {
875                         HUD_Crosshair_Vehicle();
876                         return;
877                 }
878
879                 string wcross_style;
880                 float wcross_alpha, wcross_resolution;
881                 wcross_style = autocvar_crosshair;
882                 if (wcross_style == "0")
883                         return;
884                 wcross_resolution = autocvar_crosshair_size;
885                 if (wcross_resolution == 0)
886                         return;
887                 wcross_alpha = autocvar_crosshair_alpha;
888                 if (wcross_alpha == 0)
889                         return;
890
891                 // TrueAim check
892                 float shottype;
893
894                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
895                 wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
896                 wcross_origin.z = 0;
897                 if(autocvar_crosshair_hittest)
898                 {
899                         vector wcross_oldorigin;
900                         wcross_oldorigin = wcross_origin;
901                         shottype = TrueAimCheck();
902                         if(shottype == SHOTTYPE_HITWORLD)
903                         {
904                                 v = wcross_origin - wcross_oldorigin;
905                                 v.x /= vid_conwidth;
906                                 v.y /= vid_conheight;
907                                 if(vlen(v) > 0.01)
908                                         shottype = SHOTTYPE_HITOBSTRUCTION;
909                         }
910                         if(!autocvar_crosshair_hittest_showimpact)
911                                 wcross_origin = wcross_oldorigin;
912                 }
913                 else
914                         shottype = SHOTTYPE_HITWORLD;
915
916                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
917                 string wcross_name = "";
918                 float wcross_scale, wcross_blur;
919
920                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
921                 {
922                         e = switchingweapon;
923                         if(e)
924                         {
925                                 if(autocvar_crosshair_per_weapon)
926                                 {
927                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
928                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
929                                         //if (wcross_resolution == 0)
930                                                 //return;
931
932                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
933                                         wcross_resolution *= e.w_crosshair_size;
934                                         wcross_name = e.w_crosshair;
935                                 }
936                         }
937                 }
938
939                 if(wcross_name == "")
940                         wcross_name = strcat("gfx/crosshair", wcross_style);
941
942                 // MAIN CROSSHAIR COLOR DECISION
943                 switch(autocvar_crosshair_color_special)
944                 {
945                         case 1: // crosshair_color_per_weapon
946                         {
947                                 if(e)
948                                 {
949                                         wcross_color = e.wpcolor;
950                                         break;
951                                 }
952                                 else { goto normalcolor; }
953                         }
954
955                         case 2: // crosshair_color_by_health
956                         {
957                                 float x = STAT(HEALTH);
958
959                                 //x = red
960                                 //y = green
961                                 //z = blue
962
963                                 wcross_color.z = 0;
964
965                                 if(x > 200)
966                                 {
967                                         wcross_color.x = 0;
968                                         wcross_color.y = 1;
969                                 }
970                                 else if(x > 150)
971                                 {
972                                         wcross_color.x = 0.4 - (x-150)*0.02 * 0.4;
973                                         wcross_color.y = 0.9 + (x-150)*0.02 * 0.1;
974                                 }
975                                 else if(x > 100)
976                                 {
977                                         wcross_color.x = 1 - (x-100)*0.02 * 0.6;
978                                         wcross_color.y = 1 - (x-100)*0.02 * 0.1;
979                                         wcross_color.z = 1 - (x-100)*0.02;
980                                 }
981                                 else if(x > 50)
982                                 {
983                                         wcross_color.x = 1;
984                                         wcross_color.y = 1;
985                                         wcross_color.z = 0.2 + (x-50)*0.02 * 0.8;
986                                 }
987                                 else if(x > 20)
988                                 {
989                                         wcross_color.x = 1;
990                                         wcross_color.y = (x-20)*90/27/100;
991                                         wcross_color.z = (x-20)*90/27/100 * 0.2;
992                                 }
993                                 else
994                                 {
995                                         wcross_color.x = 1;
996                                         wcross_color.y = 0;
997                                 }
998                                 break;
999                         }
1000
1001                         case 3: // crosshair_color_rainbow
1002                         {
1003                                 if(time >= rainbow_last_flicker)
1004                                 {
1005                                         rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
1006                                         rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
1007                                 }
1008                                 wcross_color = rainbow_prev_color;
1009                                 break;
1010                         }
1011                         :normalcolor
1012                         default: { wcross_color = stov(autocvar_crosshair_color); break; }
1013                 }
1014
1015                 if(autocvar_crosshair_effect_scalefade)
1016                 {
1017                         wcross_scale = wcross_resolution;
1018                         wcross_resolution = 1;
1019                 }
1020                 else
1021                 {
1022                         wcross_scale = 1;
1023                 }
1024
1025                 if(autocvar_crosshair_pickup)
1026                 {
1027                         float stat_pickup_time = STAT(LAST_PICKUP);
1028
1029                         if(pickup_crosshair_time < stat_pickup_time)
1030                         {
1031                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1032                                         pickup_crosshair_size = 1;
1033
1034                                 pickup_crosshair_time = stat_pickup_time;
1035                         }
1036
1037                         if(pickup_crosshair_size > 0)
1038                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1039                         else
1040                                 pickup_crosshair_size = 0;
1041
1042                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1043                 }
1044
1045                 // todo: make crosshair hit indication dependent on damage dealt
1046                 if(autocvar_crosshair_hitindication)
1047                 {
1048                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1049
1050                         if(unaccounted_damage)
1051                         {
1052                                 hitindication_crosshair_size = 1;
1053                         }
1054
1055                         if(hitindication_crosshair_size > 0)
1056                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1057                         else
1058                                 hitindication_crosshair_size = 0;
1059
1060                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1061                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1062                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1063                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1064                 }
1065
1066                 if(shottype == SHOTTYPE_HITENEMY)
1067                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1068                 if(shottype == SHOTTYPE_HITTEAM)
1069                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1070
1071                 f = fabs(autocvar_crosshair_effect_time);
1072                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1073                 {
1074                         wcross_changedonetime = time + f;
1075                 }
1076                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1077                 {
1078                         wcross_name_changestarttime = time;
1079                         wcross_name_changedonetime = time + f;
1080                         if(wcross_name_goal_prev_prev)
1081                                 strunzone(wcross_name_goal_prev_prev);
1082                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1083                         wcross_name_goal_prev = strzone(wcross_name);
1084                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1085                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1086                         wcross_resolution_goal_prev = wcross_resolution;
1087                 }
1088
1089                 wcross_scale_goal_prev = wcross_scale;
1090                 wcross_alpha_goal_prev = wcross_alpha;
1091                 wcross_color_goal_prev = wcross_color;
1092
1093                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1094                 {
1095                         wcross_blur = 1;
1096                         wcross_alpha *= 0.75;
1097                 }
1098                 else
1099                         wcross_blur = 0;
1100                 // *_prev is at time-frametime
1101                 // * is at wcross_changedonetime+f
1102                 // what do we have at time?
1103                 if(time < wcross_changedonetime)
1104                 {
1105                         f = frametime / (wcross_changedonetime - time + frametime);
1106                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1107                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1108                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1109                 }
1110
1111                 wcross_scale_prev = wcross_scale;
1112                 wcross_alpha_prev = wcross_alpha;
1113                 wcross_color_prev = wcross_color;
1114
1115                 MUTATOR_CALLHOOK(UpdateCrosshair);
1116
1117                 wcross_scale *= 1 - autocvar__menu_alpha;
1118                 wcross_alpha *= 1 - autocvar__menu_alpha;
1119                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1120
1121                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1122                 {
1123                         // crosshair rings for weapon stats
1124                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1125                         {
1126                                 // declarations and stats
1127                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1128                                 string ring_image = string_null, ring_inner_image = string_null;
1129                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1130
1131                                 ring_scale = autocvar_crosshair_ring_size;
1132
1133                                 float weapon_clipload, weapon_clipsize;
1134                                 weapon_clipload = STAT(WEAPON_CLIPLOAD);
1135                                 weapon_clipsize = STAT(WEAPON_CLIPSIZE);
1136
1137                                 float ok_ammo_charge, ok_ammo_chargepool;
1138                                 ok_ammo_charge = STAT(OK_AMMO_CHARGE);
1139                                 ok_ammo_chargepool = STAT(OK_AMMO_CHARGEPOOL);
1140
1141                                 float vortex_charge, vortex_chargepool;
1142                                 vortex_charge = STAT(VORTEX_CHARGE);
1143                                 vortex_chargepool = STAT(VORTEX_CHARGEPOOL);
1144
1145                                 float arc_heat = STAT(ARC_HEAT);
1146
1147                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1148                                         vortex_charge_movingavg = vortex_charge;
1149
1150
1151                                 // handle the values
1152                                 if (autocvar_crosshair_ring && activeweapon == WEP_VORTEX && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1153                                 {
1154                                         if (vortex_chargepool || use_vortex_chargepool) {
1155                                                 use_vortex_chargepool = 1;
1156                                                 ring_inner_value = vortex_chargepool;
1157                                         } else {
1158                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
1159                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
1160                                         }
1161
1162                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1163                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1164                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1165
1166                                         // draw the outer ring to show the current charge of the weapon
1167                                         ring_value = vortex_charge;
1168                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1169                                         ring_rgb = wcross_color;
1170                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1171                                 }
1172                                 else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1173                                 {
1174                                         ring_value = bound(0, STAT(LAYED_MINES) / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1175                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1176                                         ring_rgb = wcross_color;
1177                                         ring_image = "gfx/crosshair_ring.tga";
1178                                 }
1179                                 else if (activeweapon == WEP_HAGAR && STAT(HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1180                                 {
1181                                         ring_value = bound(0, STAT(HAGAR_LOAD) / WEP_CVAR_SEC(hagar, load_max), 1);
1182                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1183                                         ring_rgb = wcross_color;
1184                                         ring_image = "gfx/crosshair_ring.tga";
1185                                 }
1186                                 else if (ok_ammo_charge)
1187                                 {
1188                                         ring_value = ok_ammo_chargepool;
1189                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1190                                         ring_rgb = wcross_color;
1191                                         ring_image = "gfx/crosshair_ring.tga";
1192                                 }
1193                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1194                                 {
1195                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1196                                         ring_scale = autocvar_crosshair_ring_reload_size;
1197                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1198                                         ring_rgb = wcross_color;
1199
1200                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1201                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1202                                         if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1203                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1204                                         else
1205                                                 ring_image = "gfx/crosshair_ring.tga";
1206                                 }
1207                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && activeweapon == WEP_ARC )
1208                                 {
1209                                         ring_value = arc_heat;
1210                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1211                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1212                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1213                                         ring_image = "gfx/crosshair_ring.tga";
1214                                 }
1215
1216                                 // if in weapon switch animation, fade ring out/in
1217                                 if(autocvar_crosshair_effect_time > 0)
1218                                 {
1219                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1220                                         if (f >= 1)
1221                                         {
1222                                                 wcross_ring_prev = ((ring_image) ? true : false);
1223                                         }
1224
1225                                         if(wcross_ring_prev)
1226                                         {
1227                                                 if(f < 1)
1228                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1229                                         }
1230                                         else
1231                                         {
1232                                                 if(f < 1)
1233                                                         ring_alpha *= bound(0, f, 1);
1234                                         }
1235                                 }
1236
1237                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1238                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1239
1240                                 if (ring_value)
1241                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1242                         }
1243
1244 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1245                         MACRO_BEGIN { \
1246                                 if(wcross_blur > 0) \
1247                                 { \
1248                                         for(i = -2; i <= 2; ++i) \
1249                                         for(j = -2; j <= 2; ++j) \
1250                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1251                                 } \
1252                                 else \
1253                                 { \
1254                                         M(0,0,sz,wcross_name,wcross_alpha); \
1255                                 } \
1256                         } MACRO_END
1257
1258 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1259                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1260
1261 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1262                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1263
1264                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1265                         {
1266                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1267                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1268                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1269                                 f = 1 - f;
1270                         }
1271                         else
1272                         {
1273                                 f = 1;
1274                         }
1275                         wcross_name_alpha_goal_prev = f;
1276
1277                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1278                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1279
1280                         if(autocvar_crosshair_dot)
1281                         {
1282                                 vector wcross_color_old;
1283                                 wcross_color_old = wcross_color;
1284
1285                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1286                                         wcross_color = stov(autocvar_crosshair_dot_color);
1287
1288                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1289                                 // FIXME why don't we use wcross_alpha here?
1290                                 wcross_color = wcross_color_old;
1291                         }
1292                 }
1293         }
1294         else
1295         {
1296                 wcross_scale_prev = 0;
1297                 wcross_alpha_prev = 0;
1298                 wcross_scale_goal_prev = 0;
1299                 wcross_alpha_goal_prev = 0;
1300                 wcross_changedonetime = 0;
1301                 if(wcross_name_goal_prev)
1302                         strunzone(wcross_name_goal_prev);
1303                 wcross_name_goal_prev = string_null;
1304                 if(wcross_name_goal_prev_prev)
1305                         strunzone(wcross_name_goal_prev_prev);
1306                 wcross_name_goal_prev_prev = string_null;
1307                 wcross_name_changestarttime = 0;
1308                 wcross_name_changedonetime = 0;
1309                 wcross_name_alpha_goal_prev = 0;
1310                 wcross_name_alpha_goal_prev_prev = 0;
1311                 wcross_resolution_goal_prev = 0;
1312                 wcross_resolution_goal_prev_prev = 0;
1313         }
1314 }
1315
1316 void HUD_Draw()
1317 {
1318         vector rgb = '0 0 0';
1319         float a = 1;
1320         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1321         {
1322                 rgb = MUTATOR_ARGV(0, vector);
1323                 a = MUTATOR_ARGV(0, float);
1324         }
1325         else if(STAT(FROZEN))
1326         {
1327                 rgb = ((STAT(REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * STAT(REVIVE_PROGRESS)) + ('0 1 1' * STAT(REVIVE_PROGRESS) * -1)) : '0.25 0.90 1');
1328         }
1329         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, rgb, autocvar_hud_colorflash_alpha * a, DRAWFLAG_ADDITIVE);
1330         if(!intermission)
1331         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1332         {
1333                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * STAT(NADE_TIMER)) - ('0 1 1' * STAT(NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1334                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1335         }
1336         else if(STAT(REVIVE_PROGRESS))
1337         {
1338                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1339                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1340         }
1341
1342         if(autocvar_r_letterbox == 0)
1343                 if(autocvar_viewsize < 120)
1344                 {
1345                         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1346                                 Accuracy_LoadLevels();
1347
1348                         HUD_Main();
1349                         HUD_DrawScoreboard();
1350                 }
1351
1352         // crosshair goes VERY LAST
1353         UpdateDamage();
1354         HUD_Crosshair();
1355         HitSound();
1356 }
1357
1358 bool ov_enabled;
1359 float oldr_nearclip;
1360 float oldr_farclip_base;
1361 float oldr_farclip_world;
1362 float oldr_novis;
1363 float oldr_useportalculling;
1364 float oldr_useinfinitefarclip;
1365
1366 void cl_notice_run();
1367 float prev_myteam;
1368 int lasthud;
1369 float vh_notice_time;
1370 void WaypointSprite_Load();
1371 void CSQC_UpdateView(float w, float h)
1372 {SELFPARAM();
1373         entity e;
1374         float fov;
1375         float f;
1376         vector vf_size, vf_min;
1377         float a;
1378
1379         execute_next_frame();
1380
1381         ++framecount;
1382
1383         stats_get();
1384         hud = STAT(HUD);
1385
1386         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1387                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1388
1389         lasthud = hud;
1390
1391         if(autocvar__hud_showbinds_reload) // menu can set this one
1392         {
1393                 db_close(binddb);
1394                 binddb = db_create();
1395                 cvar_set("_hud_showbinds_reload", "0");
1396         }
1397
1398         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1399                 view_quality = getproperty(VF_MINFPS_QUALITY);
1400         else
1401                 view_quality = 1;
1402
1403         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(self);
1404         button_zoom = PHYS_INPUT_BUTTON_ZOOM(self);
1405
1406         vf_size = getpropertyvec(VF_SIZE);
1407         vf_min = getpropertyvec(VF_MIN);
1408         vid_width = vf_size.x;
1409         vid_height = vf_size.y;
1410
1411         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1412         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1413
1414         WaypointSprite_Load();
1415
1416         CSQCPlayer_SetCamera();
1417
1418         if(player_localentnum <= maxclients) // is it a client?
1419                 current_player = player_localentnum - 1;
1420         else // then player_localentnum is the vehicle I'm driving
1421                 current_player = player_localnum;
1422         myteam = entcs_GetTeam(current_player);
1423
1424         if(myteam != prev_myteam)
1425         {
1426                 myteamcolors = colormapPaletteColor(myteam, 1);
1427                 FOREACH(hud_panels, true, LAMBDA(it.update_time = time));
1428                 prev_myteam = myteam;
1429         }
1430
1431         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1432
1433         float is_dead = (STAT(HEALTH) <= 0);
1434
1435         // FIXME do we need this hack?
1436         if(isdemo())
1437         {
1438                 // in demos, input_buttons do not work
1439                 button_zoom = (autocvar__togglezoom == "-");
1440         }
1441         else if(button_zoom
1442                 && autocvar_cl_unpress_zoom_on_death
1443                 && (spectatee_status >= 0)
1444                 && (is_dead || intermission))
1445         {
1446                 // no zoom while dead or in intermission please
1447                 localcmd("-zoom\n");
1448                 button_zoom = false;
1449         }
1450
1451         // event chase camera
1452         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1453         {
1454                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1455                 float ons_roundlost = (gametype == MAPINFO_TYPE_ONSLAUGHT && STAT(ROUNDLOST));
1456                 entity gen = world;
1457
1458                 if(ons_roundlost)
1459                 {
1460                         entity e;
1461                         for(e = world; (e = find(e, classname, "onslaught_generator")); )
1462                         {
1463                                 if(e.health <= 0)
1464                                 {
1465                                         gen = e;
1466                                         break;
1467                                 }
1468                         }
1469                         if(!gen)
1470                                 ons_roundlost = FALSE; // don't enforce the 3rd person camera if there is no dead generator to show
1471                 }
1472                 if(WantEventchase() || (!autocvar_cl_orthoview && ons_roundlost))
1473                 {
1474                         eventchase_running = true;
1475
1476                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1477                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1478                         if(ons_roundlost) { current_view_origin = gen.origin; }
1479
1480                         // detect maximum viewoffset and use it
1481                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1482                         if(vehicle_chase && autocvar_cl_eventchase_vehicle_viewoffset) { view_offset = autocvar_cl_eventchase_vehicle_viewoffset; }
1483                         if(ons_roundlost) { view_offset = autocvar_cl_eventchase_generator_viewoffset; }
1484
1485                         if(view_offset)
1486                         {
1487                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, self);
1488                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1489                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1490                         }
1491
1492                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1493                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1494                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1495                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1496
1497                         // make the camera smooth back
1498                         float chase_distance = autocvar_cl_eventchase_distance;
1499                         if(vehicle_chase && autocvar_cl_eventchase_vehicle_distance) { chase_distance = autocvar_cl_eventchase_vehicle_distance; }
1500                         if(ons_roundlost) { chase_distance = autocvar_cl_eventchase_generator_distance; }
1501
1502                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1503                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1504                         else if(eventchase_current_distance != chase_distance)
1505                                 eventchase_current_distance = chase_distance;
1506
1507                         makevectors(view_angles);
1508
1509                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1510                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
1511
1512                         // If the boxtrace fails, revert back to line tracing.
1513                         if(!self.viewloc)
1514                         if(trace_startsolid)
1515                         {
1516                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1517                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
1518                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1519                         }
1520                         else { setproperty(VF_ORIGIN, trace_endpos); }
1521
1522                         if(!self.viewloc)
1523                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1524                 }
1525                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1526                 {
1527                         eventchase_running = false;
1528                         cvar_set("chase_active", "0");
1529                         eventchase_current_distance = 0; // start from 0 next time
1530                 }
1531         }
1532         // workaround for camera stuck between player's legs when using chase_active 1
1533         // because the engine stops updating the chase_active camera when the game ends
1534         else if(intermission)
1535         {
1536                 cvar_settemp("chase_active", "-1");
1537                 eventchase_current_distance = 0;
1538         }
1539
1540         // do lockview after event chase camera so that it still applies whenever necessary.
1541         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1542         {
1543                 setproperty(VF_ORIGIN, freeze_org);
1544                 setproperty(VF_ANGLES, freeze_ang);
1545         }
1546         else
1547         {
1548                 freeze_org = getpropertyvec(VF_ORIGIN);
1549                 freeze_ang = getpropertyvec(VF_ANGLES);
1550         }
1551
1552         WarpZone_FixView();
1553         //WarpZone_FixPMove();
1554
1555         vector ov_org = '0 0 0';
1556         vector ov_mid = '0 0 0';
1557         vector ov_worldmin = '0 0 0';
1558         vector ov_worldmax = '0 0 0';
1559         if(autocvar_cl_orthoview)
1560         {
1561                 ov_worldmin = mi_picmin;
1562                 ov_worldmax = mi_picmax;
1563
1564                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1565                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1566                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1567
1568                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1569                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1570
1571                 float ov_nearest = vlen(ov_org - vec3(
1572                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1573                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1574                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1575                 ));
1576
1577                 float ov_furthest = 0;
1578                 float dist = 0;
1579
1580                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1581                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1582                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1583                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1584                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1585                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1586                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1587                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1588
1589                 if(!ov_enabled)
1590                 {
1591                         oldr_nearclip = cvar("r_nearclip");
1592                         oldr_farclip_base = cvar("r_farclip_base");
1593                         oldr_farclip_world = cvar("r_farclip_world");
1594                         oldr_novis = cvar("r_novis");
1595                         oldr_useportalculling = cvar("r_useportalculling");
1596                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1597                 }
1598
1599                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1600                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1601                 cvar_settemp("r_farclip_world", "0");
1602                 cvar_settemp("r_novis", "1");
1603                 cvar_settemp("r_useportalculling", "0");
1604                 cvar_settemp("r_useinfinitefarclip", "0");
1605
1606                 setproperty(VF_ORIGIN, ov_org);
1607                 setproperty(VF_ANGLES, '90 0 0');
1608
1609                 ov_enabled = true;
1610
1611                 #if 0
1612                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1613                         vtos(ov_org),
1614                         vtos(getpropertyvec(VF_ANGLES)),
1615                         ov_distance,
1616                         ov_nearest,
1617                         ov_furthest);
1618                 #endif
1619         }
1620         else
1621         {
1622                 if(ov_enabled)
1623                 {
1624                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1625                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1626                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1627                         cvar_set("r_novis", ftos(oldr_novis));
1628                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1629                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1630                 }
1631                 ov_enabled = false;
1632         }
1633
1634         // Render the Scene
1635         view_origin = getpropertyvec(VF_ORIGIN);
1636         view_angles = getpropertyvec(VF_ANGLES);
1637         makevectors(view_angles);
1638         view_forward = v_forward;
1639         view_right = v_right;
1640         view_up = v_up;
1641
1642 #ifdef BLURTEST
1643         if(time > blurtest_time0 && time < blurtest_time1)
1644         {
1645                 float r, t;
1646
1647                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1648                 r = t * blurtest_radius;
1649                 f = 1 / pow(t, blurtest_power) - 1;
1650
1651                 cvar_set("r_glsl_postprocess", "1");
1652                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1653         }
1654         else
1655         {
1656                 cvar_set("r_glsl_postprocess", "0");
1657                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1658         }
1659 #endif
1660
1661         TargetMusic_Advance();
1662         Fog_Force();
1663
1664         if(drawtime == 0)
1665                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1666         else
1667                 drawframetime = bound(0.000001, time - drawtime, 1);
1668         drawtime = time;
1669
1670         // watch for gametype changes here...
1671         // in ParseStuffCMD the cmd isn't executed yet :/
1672         // might even be better to add the gametype to TE_CSQC_INIT...?
1673         if(!postinit)
1674                 PostInit();
1675
1676         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1677         {
1678                 if(calledhooks & HOOK_START)
1679                 {
1680                         localcmd("\ncl_hook_gameend\n");
1681                         calledhooks |= HOOK_END;
1682                 }
1683         }
1684
1685         Announcer();
1686
1687         fov = autocvar_fov;
1688         if(fov <= 59.5)
1689         {
1690                 if(!zoomscript_caught)
1691                 {
1692                         localcmd("+button9\n");
1693                         zoomscript_caught = 1;
1694                 }
1695         }
1696         else
1697         {
1698                 if(zoomscript_caught)
1699                 {
1700                         localcmd("-button9\n");
1701                         zoomscript_caught = 0;
1702                 }
1703         }
1704
1705         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1706
1707         // currently switching-to weapon (for crosshair)
1708         switchingweapon = Weapons_from(STAT(SWITCHINGWEAPON));
1709
1710         // actually active weapon (for zoom)
1711         activeweapon = Weapons_from(STAT(ACTIVEWEAPON));
1712
1713         switchweapon = Weapons_from(STAT(SWITCHWEAPON));
1714
1715         f = (serverflags & SERVERFLAG_TEAMPLAY);
1716         if(f != teamplay)
1717         {
1718                 teamplay = f;
1719                 HUD_InitScores();
1720         }
1721
1722         if(last_switchweapon != switchweapon)
1723         {
1724                 weapontime = time;
1725                 last_switchweapon = switchweapon;
1726                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1727                 {
1728                         localcmd("-zoom\n");
1729                         button_zoom = false;
1730                 }
1731                 if(autocvar_cl_unpress_attack_on_weapon_switch)
1732                 {
1733                         localcmd("-fire\n");
1734                         localcmd("-fire2\n");
1735                         button_attack2 = false;
1736                 }
1737         }
1738         if(last_activeweapon != activeweapon)
1739         {
1740                 last_activeweapon = activeweapon;
1741
1742                 e = activeweapon;
1743                 if(e.netname != "")
1744                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1745                 else
1746                         localcmd("\ncl_hook_activeweapon none\n");
1747         }
1748
1749         // ALWAYS Clear Current Scene First
1750         clearscene();
1751
1752         setproperty(VF_ORIGIN, view_origin);
1753         setproperty(VF_ANGLES, view_angles);
1754
1755         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1756         setproperty(VF_SIZE, vf_size);
1757         setproperty(VF_MIN, vf_min);
1758
1759         // Assign Standard Viewflags
1760         // Draw the World (and sky)
1761         setproperty(VF_DRAWWORLD, 1);
1762
1763         // Set the console size vars
1764         vid_conwidth = autocvar_vid_conwidth;
1765         vid_conheight = autocvar_vid_conheight;
1766         vid_pixelheight = autocvar_vid_pixelheight;
1767
1768         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1769         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1770         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1771
1772         // Camera for demo playback
1773         if(camera_active)
1774         {
1775                 if(autocvar_camera_enable)
1776                         CSQC_Demo_Camera();
1777                 else
1778                 {
1779                         cvar_set("chase_active", ftos(chase_active_backup));
1780                         cvar_set("cl_demo_mousegrab", "0");
1781                         camera_active = false;
1782                 }
1783         }
1784         else
1785         {
1786 #ifdef CAMERATEST
1787                 if(autocvar_camera_enable)
1788 #else
1789                 if(autocvar_camera_enable && isdemo())
1790 #endif
1791                 {
1792                         // Enable required Darkplaces cvars
1793                         chase_active_backup = autocvar_chase_active;
1794                         cvar_set("chase_active", "2");
1795                         cvar_set("cl_demo_mousegrab", "1");
1796                         camera_active = true;
1797                         camera_mode = false;
1798                 }
1799         }
1800
1801         // Draw the Crosshair
1802         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1803
1804         // Draw the Engine Status Bar (the default Quake HUD)
1805         setproperty(VF_DRAWENGINESBAR, 0);
1806
1807         // Update the mouse position
1808         /*
1809            mousepos_x = vid_conwidth;
1810            mousepos_y = vid_conheight;
1811            mousepos = mousepos*0.5 + getmousepos();
1812          */
1813
1814         FOREACH_ENTITY(it.draw, LAMBDA(WITH(entity, self, it, it.draw(it))));
1815
1816         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1817         renderscene();
1818
1819         // now switch to 2D drawing mode by calling a 2D drawing function
1820         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1821         // next R_RenderScene call
1822         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1823
1824         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1825         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1826         {
1827                 // apply night vision effect
1828                 vector tc_00, tc_01, tc_10, tc_11;
1829                 vector rgb = '0 0 0';
1830
1831                 if(!nightvision_noise)
1832                 {
1833                         nightvision_noise = new(nightvision_noise);
1834                 }
1835                 if(!nightvision_noise2)
1836                 {
1837                         nightvision_noise2 = new(nightvision_noise2);
1838                 }
1839
1840                 // color tint in yellow
1841                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1842
1843                 // draw BG
1844                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1845                 rgb = '1 1 1';
1846                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1847                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1848                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1849                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1850                 tc_11 = tc_01 + tc_10 - tc_00;
1851                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1852                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1853                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1854                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1855                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1856                 R_EndPolygon();
1857
1858                 // draw FG
1859                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1860                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1861                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1862                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1863                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1864                 tc_11 = tc_01 + tc_10 - tc_00;
1865                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1866                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1867                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1868                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1869                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1870                 R_EndPolygon();
1871         }
1872
1873         if(autocvar_cl_reticle)
1874         {
1875                 Weapon wep = activeweapon;
1876                 // Draw the aiming reticle for weapons that use it
1877                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
1878                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
1879                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
1880                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
1881                 {
1882                         // no zoom reticle while dead
1883                         reticle_type = 0;
1884                 }
1885                 else if(wep.wr_zoomreticle(wep) && autocvar_cl_reticle_weapon)
1886                 {
1887                         if(reticle_image != "") { reticle_type = 2; }
1888                         else { reticle_type = 0; }
1889                 }
1890                 else if(button_zoom || zoomscript_caught)
1891                 {
1892                         // normal zoom
1893                         reticle_type = 1;
1894                 }
1895
1896                 if(reticle_type)
1897                 {
1898                         if(autocvar_cl_reticle_stretch)
1899                         {
1900                                 reticle_size.x = vid_conwidth;
1901                                 reticle_size.y = vid_conheight;
1902                                 reticle_pos.x = 0;
1903                                 reticle_pos.y = 0;
1904                         }
1905                         else
1906                         {
1907                                 reticle_size.x = max(vid_conwidth, vid_conheight);
1908                                 reticle_size.y = max(vid_conwidth, vid_conheight);
1909                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
1910                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
1911                         }
1912
1913                         if(zoomscript_caught)
1914                                 f = 1;
1915                         else
1916                                 f = current_zoomfraction;
1917
1918                         if(f)
1919                         {
1920                                 switch(reticle_type)
1921                                 {
1922                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
1923                                         case 2: drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
1924                                 }
1925                         }
1926                 }
1927         }
1928         else
1929         {
1930                 if(reticle_type != 0) { reticle_type = 0; }
1931         }
1932
1933
1934         // improved polyblend
1935         if(autocvar_hud_contents)
1936         {
1937                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
1938                 vector liquidcolor;
1939
1940                 switch(pointcontents(view_origin))
1941                 {
1942                         case CONTENT_WATER:
1943                                 liquidalpha = autocvar_hud_contents_water_alpha;
1944                                 liquidcolor = stov(autocvar_hud_contents_water_color);
1945                                 incontent = 1;
1946                                 break;
1947
1948                         case CONTENT_LAVA:
1949                                 liquidalpha = autocvar_hud_contents_lava_alpha;
1950                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
1951                                 incontent = 1;
1952                                 break;
1953
1954                         case CONTENT_SLIME:
1955                                 liquidalpha = autocvar_hud_contents_slime_alpha;
1956                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
1957                                 incontent = 1;
1958                                 break;
1959
1960                         default:
1961                                 liquidalpha = 0;
1962                                 liquidcolor = '0 0 0';
1963                                 incontent = 0;
1964                                 break;
1965                 }
1966
1967                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
1968                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
1969                         contentfadetime = autocvar_hud_contents_fadeintime;
1970                         liquidalpha_prev = liquidalpha;
1971                         liquidcolor_prev = liquidcolor;
1972                 }
1973                 else
1974                         contentfadetime = autocvar_hud_contents_fadeouttime;
1975
1976                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
1977                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
1978
1979                 if(contentavgalpha)
1980                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
1981
1982                 if(autocvar_hud_postprocessing)
1983                 {
1984                         if(autocvar_hud_contents_blur && contentavgalpha)
1985                         {
1986                                 content_blurpostprocess.x = 1;
1987                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
1988                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
1989                         }
1990                         else
1991                         {
1992                                 content_blurpostprocess.x = 0;
1993                                 content_blurpostprocess.y = 0;
1994                                 content_blurpostprocess.z = 0;
1995                         }
1996                 }
1997         }
1998
1999         if(autocvar_hud_damage && !STAT(FROZEN))
2000         {
2001                 splash_size.x = max(vid_conwidth, vid_conheight);
2002                 splash_size.y = max(vid_conwidth, vid_conheight);
2003                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2004                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2005
2006                 float myhealth_flash_temp;
2007                 myhealth = STAT(HEALTH);
2008
2009                 // fade out
2010                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2011                 // add new damage
2012                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2013
2014                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2015                 pain_threshold = autocvar_hud_damage_pain_threshold;
2016                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2017                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2018
2019                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2020                 {
2021                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2022                 }
2023
2024                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2025
2026                 if(myhealth_prev < 1)
2027                 {
2028                         if(myhealth >= 1)
2029                         {
2030                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2031                                 myhealth_flash_temp = 0;
2032                         }
2033                         else
2034                         {
2035                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2036                         }
2037                 }
2038
2039                 if(spectatee_status == -1 || intermission)
2040                 {
2041                         myhealth_flash = 0; // observing, or match ended
2042                         myhealth_flash_temp = 0;
2043                 }
2044
2045                 myhealth_prev = myhealth;
2046
2047                 // IDEA: change damage color/picture based on player model for robot/alien species?
2048                 // pro: matches model better
2049                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2050                 // maybe different reddish pics?
2051                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2052                 {
2053                         if(autocvar_cl_gentle_damage == 2)
2054                         {
2055                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2056                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
2057                         }
2058                         else
2059                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2060
2061                         if(myhealth_flash_temp > 0)
2062                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2063                 }
2064                 else if(myhealth_flash_temp > 0)
2065                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2066
2067                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2068                 {
2069                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2070                         {
2071                                 damage_blurpostprocess.x = 1;
2072                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2073                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2074                         }
2075                         else
2076                         {
2077                                 damage_blurpostprocess.x = 0;
2078                                 damage_blurpostprocess.y = 0;
2079                                 damage_blurpostprocess.z = 0;
2080                         }
2081                 }
2082         }
2083
2084         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2085         float e2 = (autocvar_hud_powerup != 0);
2086         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2087         {
2088                 // enable or disable rendering types if they are used or not
2089                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2090                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2091
2092                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2093                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2094                 {
2095                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2096                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2097                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2098                         {
2099                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2100                                 old_blurradius = blurradius;
2101                                 old_bluralpha = bluralpha;
2102                         }
2103                 }
2104                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2105                 {
2106                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2107                         old_blurradius = 0;
2108                         old_bluralpha = 0;
2109                 }
2110
2111                 // edge detection postprocess handling done second (used by hud_powerup)
2112                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2113                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2114                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2115
2116                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2117
2118                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2119                 {
2120                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2121                         {
2122                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2123                                 old_sharpen_intensity = sharpen_intensity;
2124                         }
2125                 }
2126                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2127                 {
2128                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2129                         old_sharpen_intensity = 0;
2130                 }
2131
2132                 if(cvar("r_glsl_postprocess") == 0)
2133                         cvar_set("r_glsl_postprocess", "2");
2134         }
2135         else if(cvar("r_glsl_postprocess") == 2)
2136                 cvar_set("r_glsl_postprocess", "0");
2137
2138         /*if(gametype == MAPINFO_TYPE_CTF)
2139           {
2140           ctf_view();
2141           } else */
2142
2143         // draw 2D entities
2144         FOREACH_ENTITY(it.draw2d, LAMBDA(WITH(entity, self, it, it.draw2d(it))));
2145         Draw_ShowNames_All();
2146         Debug_Draw();
2147
2148         scoreboard_active = HUD_WouldDrawScoreboard();
2149
2150         HUD_Draw();
2151
2152         if(NextFrameCommand)
2153         {
2154                 localcmd("\n", NextFrameCommand, "\n");
2155                 NextFrameCommand = string_null;
2156         }
2157
2158         // we must do this check AFTER a frame was rendered, or it won't work
2159         if(cs_project_is_b0rked == 0)
2160         {
2161                 string w0, h0;
2162                 w0 = ftos(autocvar_vid_conwidth);
2163                 h0 = ftos(autocvar_vid_conheight);
2164                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2165                 //setproperty(VF_FOV, '90 90 0');
2166                 setproperty(VF_ORIGIN, '0 0 0');
2167                 setproperty(VF_ANGLES, '0 0 0');
2168                 setproperty(VF_PERSPECTIVE, 1);
2169                 makevectors('0 0 0');
2170                 vector v1, v2;
2171                 cvar_set("vid_conwidth", "800");
2172                 cvar_set("vid_conheight", "600");
2173                 v1 = cs_project(v_forward);
2174                 cvar_set("vid_conwidth", "640");
2175                 cvar_set("vid_conheight", "480");
2176                 v2 = cs_project(v_forward);
2177                 if(v1 == v2)
2178                         cs_project_is_b0rked = 1;
2179                 else
2180                         cs_project_is_b0rked = -1;
2181                 cvar_set("vid_conwidth", w0);
2182                 cvar_set("vid_conheight", h0);
2183         }
2184
2185         if(autocvar__hud_configure)
2186                 HUD_Panel_Mouse();
2187         else if ( HUD_MinigameMenu_IsOpened() || minigame_isactive() )
2188                 HUD_Minigame_Mouse();
2189         else if(QuickMenu_IsOpened())
2190                 QuickMenu_Mouse();
2191         else
2192                 HUD_Radar_Mouse();
2193
2194         cl_notice_run();
2195
2196         // let's reset the view back to normal for the end
2197         setproperty(VF_MIN, '0 0 0');
2198         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2199 }
2200
2201
2202 // following vectors must be global to allow seamless switching between camera modes
2203 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2204 void CSQC_Demo_Camera()
2205 {
2206         float speed, attenuation, dimensions;
2207         vector tmp, delta;
2208
2209         if( autocvar_camera_reset || !camera_mode )
2210         {
2211                 camera_offset = '0 0 0';
2212                 current_angles = '0 0 0';
2213                 camera_direction = '0 0 0';
2214                 camera_offset.z += 30;
2215                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2216                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2217                 current_origin = view_origin;
2218                 current_camera_offset  = camera_offset;
2219                 cvar_set("camera_reset", "0");
2220                 camera_mode = CAMERA_CHASE;
2221         }
2222
2223         // Camera angles
2224         if( camera_roll )
2225                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2226
2227         if(autocvar_camera_look_player)
2228         {
2229                 vector dir;
2230                 float n;
2231
2232                 dir = normalize(view_origin - current_position);
2233                 n = mouse_angles.z;
2234                 mouse_angles = vectoangles(dir);
2235                 mouse_angles.x = mouse_angles.x * -1;
2236                 mouse_angles.z = n;
2237         }
2238         else
2239         {
2240                 tmp = getmousepos() * 0.1;
2241                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
2242                 {
2243                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2244                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2245                 }
2246         }
2247
2248         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2249         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2250         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2251         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2252
2253         // Fix difference when angles don't have the same sign
2254         delta = '0 0 0';
2255         if(mouse_angles.y < -60 && current_angles.y > 60)
2256                 delta = '0 360 0';
2257         if(mouse_angles.y > 60 && current_angles.y < -60)
2258                 delta = '0 -360 0';
2259
2260         if(autocvar_camera_look_player)
2261                 attenuation = autocvar_camera_look_attenuation;
2262         else
2263                 attenuation = autocvar_camera_speed_attenuation;
2264
2265         attenuation = 1 / max(1, attenuation);
2266         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2267
2268         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2269         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2270         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2271         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2272
2273         // Camera position
2274         tmp = '0 0 0';
2275         dimensions = 0;
2276
2277         if( camera_direction.x )
2278         {
2279                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2280                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2281                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2282                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2283                 ++dimensions;
2284         }
2285
2286         if( camera_direction.y )
2287         {
2288                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2289                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2290                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2291                 ++dimensions;
2292         }
2293
2294         if( camera_direction.z )
2295         {
2296                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2297                 ++dimensions;
2298         }
2299
2300         if(autocvar_camera_free)
2301                 speed = autocvar_camera_speed_free;
2302         else
2303                 speed = autocvar_camera_speed_chase;
2304
2305         if(dimensions)
2306         {
2307                 speed = speed * sqrt(1 / dimensions);
2308                 camera_offset += tmp * speed;
2309         }
2310
2311         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2312
2313         // Camera modes
2314         if( autocvar_camera_free )
2315         {
2316                 if ( camera_mode == CAMERA_CHASE )
2317                 {
2318                         current_camera_offset = current_origin + current_camera_offset;
2319                         camera_offset = current_origin + camera_offset;
2320                 }
2321
2322                 camera_mode = CAMERA_FREE;
2323                 current_position = current_camera_offset;
2324         }
2325         else
2326         {
2327                 if ( camera_mode == CAMERA_FREE )
2328                 {
2329                         current_origin = view_origin;
2330                         camera_offset = camera_offset - current_origin;
2331                         current_camera_offset = current_camera_offset - current_origin;
2332                 }
2333
2334                 camera_mode = CAMERA_CHASE;
2335
2336                 if(autocvar_camera_chase_smoothly)
2337                         current_origin += (view_origin - current_origin) * attenuation;
2338                 else
2339                         current_origin = view_origin;
2340
2341                 current_position = current_origin + current_camera_offset;
2342         }
2343
2344         setproperty(VF_ANGLES, current_angles);
2345         setproperty(VF_ORIGIN, current_position);
2346 }