Rename a few parameters and locals named x, y, z
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / view.qc
1 #include "view.qh"
2
3 #include "announcer.qh"
4 #include "hud/_mod.qh"
5 #include "mapvoting.qh"
6 #include "shownames.qh"
7 #include "hud/panel/scoreboard.qh"
8 #include "hud/panel/quickmenu.qh"
9
10 #include "mutators/events.qh"
11
12 #include <common/animdecide.qh>
13 #include <common/ent_cs.qh>
14 #include <common/anim.qh>
15 #include <common/constants.qh>
16 #include <common/net_linked.qh>
17 #include <common/debug.qh>
18 #include <common/mapinfo.qh>
19 #include <common/gamemodes/_mod.qh>
20 #include <common/physics/player.qh>
21 #include <common/stats.qh>
22 #include <common/triggers/target/music.qh>
23 #include <common/teams.qh>
24
25 #include <common/weapons/weapon/tuba.qh>
26
27 #include <common/vehicles/all.qh>
28 #include <common/weapons/_all.qh>
29 #include <common/viewloc.qh>
30 #include <common/minigames/cl_minigames.qh>
31 #include <common/minigames/cl_minigames_hud.qh>
32
33 #include <lib/csqcmodel/cl_player.qh>
34 #include <lib/csqcmodel/cl_model.qh>
35 #include "csqcmodel_hooks.qh"
36
37 #include <lib/warpzone/client.qh>
38 #include <lib/warpzone/common.qh>
39
40 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
41
42 float autocvar_cl_viewmodel_scale;
43
44 bool autocvar_cl_bobmodel;
45 float autocvar_cl_bobmodel_speed;
46 float autocvar_cl_bobmodel_side;
47 float autocvar_cl_bobmodel_up;
48
49 float autocvar_cl_followmodel;
50 float autocvar_cl_followmodel_speed = 0.3;
51 float autocvar_cl_followmodel_limit = 135;
52 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
53 float autocvar_cl_followmodel_highpass = 0.05;
54 float autocvar_cl_followmodel_lowpass = 0.03;
55 bool autocvar_cl_followmodel_velocity_absolute;
56
57 float autocvar_cl_leanmodel;
58 float autocvar_cl_leanmodel_speed = 0.3;
59 float autocvar_cl_leanmodel_limit = 30;
60 float autocvar_cl_leanmodel_highpass1 = 0.2;
61 float autocvar_cl_leanmodel_highpass = 0.2;
62 float autocvar_cl_leanmodel_lowpass = 0.05;
63
64 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
65 #define lowpass(value, frac, ref_store, ret) MACRO_BEGIN \
66 { \
67         ret = ref_store = ref_store * (1 - frac) + (value) * frac; \
68 } MACRO_END
69
70 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
71 { \
72         float __ignore; lowpass(value, frac, ref_store, __ignore); \
73         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
74 } MACRO_END
75
76 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
77 { \
78         float __f = 0; lowpass(value, frac, ref_store, __f); \
79         ret = (value) - __f; \
80 } MACRO_END
81
82 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
83 { \
84         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
85         ret = (value) - __f; \
86 } MACRO_END
87
88 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
89 { \
90         lowpass(value.x, frac, ref_store.x, ref_out.x); \
91         lowpass(value.y, frac, ref_store.y, ref_out.y); \
92 } MACRO_END
93
94 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
95 { \
96         highpass(value.x, frac, ref_store.x, ref_out.x); \
97         highpass(value.y, frac, ref_store.y, ref_out.y); \
98 } MACRO_END
99
100 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
101 { \
102         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
103         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
104 } MACRO_END
105
106 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
107 { \
108         lowpass(value.x, frac, ref_store.x, ref_out.x); \
109         lowpass(value.y, frac, ref_store.y, ref_out.y); \
110         lowpass(value.z, frac, ref_store.z, ref_out.z); \
111 } MACRO_END
112
113 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
114 { \
115         highpass(value.x, frac, ref_store.x, ref_out.x); \
116         highpass(value.y, frac, ref_store.y, ref_out.y); \
117         highpass(value.z, frac, ref_store.z, ref_out.z); \
118 } MACRO_END
119
120 void calc_followmodel_ofs(entity view)
121 {
122         if(cl_followmodel_time == time)
123                 return; // cl_followmodel_ofs already calculated for this frame
124
125         float frac;
126         vector gunorg = '0 0 0';
127         static vector vel_average;
128         static vector gunorg_prev = '0 0 0';
129         static vector gunorg_adjustment_highpass;
130         static vector gunorg_adjustment_lowpass;
131
132         vector vel;
133         if (autocvar_cl_followmodel_velocity_absolute)
134                 vel = view.velocity;
135         else
136         {
137                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
138                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
139                 vel.x = view.velocity * forward;
140                 vel.y = view.velocity * right * -1;
141                 vel.z = view.velocity * up;
142         }
143
144         vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
145         vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
146         vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
147
148         frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
149         lowpass3(vel, frac, vel_average, gunorg);
150
151         gunorg *= -autocvar_cl_followmodel_speed * 0.042;
152
153         // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
154         // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
155         frac = avg_factor(autocvar_cl_followmodel_highpass);
156         highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
157         frac = avg_factor(autocvar_cl_followmodel_lowpass);
158         lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
159
160         if (autocvar_cl_followmodel_velocity_absolute)
161         {
162                 vector fixed_gunorg;
163                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
164                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
165                 fixed_gunorg.x = gunorg * forward;
166                 fixed_gunorg.y = gunorg * right * -1;
167                 fixed_gunorg.z = gunorg * up;
168                 gunorg = fixed_gunorg;
169         }
170
171         cl_followmodel_ofs = gunorg;
172         cl_followmodel_time = time;
173 }
174
175 vector leanmodel_ofs(entity view)
176 {
177         float frac;
178         vector gunangles = '0 0 0';
179         static vector gunangles_prev = '0 0 0';
180         static vector gunangles_highpass = '0 0 0';
181         static vector gunangles_adjustment_highpass;
182         static vector gunangles_adjustment_lowpass;
183
184         if (view.csqcmodel_teleported)
185                 gunangles_prev = view_angles;
186
187         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
188         gunangles_highpass += gunangles_prev;
189         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
190         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
191         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
192         frac = avg_factor(autocvar_cl_leanmodel_highpass1);
193         highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
194         gunangles_prev = view_angles;
195         gunangles_highpass -= gunangles_prev;
196
197         PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
198         YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
199
200         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
201         frac = avg_factor(autocvar_cl_leanmodel_highpass);
202         highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
203         frac = avg_factor(autocvar_cl_leanmodel_lowpass);
204         lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
205
206         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
207
208         return gunangles;
209 }
210
211 vector bobmodel_ofs(entity view)
212 {
213         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
214         static bool oldonground;
215         static float hitgroundtime;
216         if (clonground)
217         {
218                 float f = time; // cl.movecmd[0].time
219                 if (!oldonground)
220                         hitgroundtime = f;
221         }
222         oldonground = clonground;
223
224         // calculate for swinging gun model
225         // the gun bobs when running on the ground, but doesn't bob when you're in the air.
226         vector gunorg = '0 0 0';
227         static float bobmodel_scale = 0;
228         static float time_ofs = 0; // makes the effect always restart in the same way
229         if (clonground)
230         {
231                 if (time - hitgroundtime > 0.05)
232                         bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
233         }
234         else
235                 bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
236
237         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
238         if (bobmodel_scale && xyspeed)
239         {
240                 float bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
241                 float s = (time - time_ofs) * autocvar_cl_bobmodel_speed;
242                 gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
243                 gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
244         }
245         else
246                 time_ofs = time;
247
248         return gunorg;
249 }
250
251 void viewmodel_animate(entity this)
252 {
253         if (autocvar_chase_active) return;
254         if (STAT(HEALTH) <= 0) return;
255
256         entity view = CSQCModel_server2csqc(player_localentnum - 1);
257
258         if (autocvar_cl_followmodel)
259         {
260                 calc_followmodel_ofs(view);
261                 this.origin += cl_followmodel_ofs;
262         }
263
264         if (autocvar_cl_leanmodel)
265                 this.angles += leanmodel_ofs(view);
266
267         // vertical view bobbing code
268         // TODO: cl_bob
269
270         // horizontal view bobbing code
271         // TODO: cl_bob2
272
273         // fall bobbing code
274         // causes the view to swing down and back up when touching the ground
275         // TODO: cl_bobfall
276
277         // gun model bobbing code
278         if (autocvar_cl_bobmodel)
279                 this.origin += bobmodel_ofs(view);
280 }
281
282 .vector viewmodel_origin, viewmodel_angles;
283 .float weapon_nextthink;
284 .float weapon_eta_last;
285 .float weapon_switchdelay;
286
287 void viewmodel_draw(entity this)
288 {
289         if(!activeweapon || !autocvar_r_drawviewmodel)
290                 return;
291         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
292         float a = this.alpha;
293         static bool wasinvehicle;
294         bool invehicle = player_localentnum > maxclients;
295         if (invehicle) a = -1;
296         else if (wasinvehicle) a = 1;
297         wasinvehicle = invehicle;
298         Weapon wep = activeweapon;
299         int c = entcs_GetClientColors(current_player);
300         vector g = weaponentity_glowmod(wep, NULL, c);
301         entity me = CSQCModel_server2csqc(player_localentnum - 1);
302         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
303                 | EF_NODEPTHTEST)
304                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
305         for (entity e = this; e; e = e.weaponchild)
306         {
307                 e.drawmask = mask;
308                 e.alpha = a;
309                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
310                 e.glowmod = g;
311                 e.csqcmodel_effects = fx;
312                 CSQCModel_Effects_Apply(e);
313         }
314         {
315                 static string name_last;
316                 string name = wep.mdl;
317                 if(wep == WEP_TUBA)
318                 {
319                         name = (this.tuba_instrument == 0) ? "tuba" :
320                            (this.tuba_instrument == 1) ? "akordeon" :
321                                                      "kleinbottle";
322                 }
323                 bool swap = name != name_last;
324                 // if (swap)
325                 {
326                         name_last = name;
327                         CL_WeaponEntity_SetModel(this, name, swap);
328                         this.viewmodel_origin = this.origin;
329                         this.viewmodel_angles = this.angles;
330                 }
331                 anim_update(this);
332                 if (!this.animstate_override && !this.animstate_looping)
333                         anim_set(this, this.anim_idle, true, false, false);
334         }
335         float f = 0; // 0..1; 0: fully active
336         float rate = STAT(WEAPONRATEFACTOR);
337         float eta = rate ? ((this.weapon_nextthink - time) / rate) : 0;
338         if (eta <= 0) f = this.weapon_eta_last;
339         else switch (this.state)
340         {
341                 case WS_RAISE:
342                 {
343                         f = eta / max(eta, this.weapon_switchdelay);
344                         break;
345                 }
346                 case WS_DROP:
347                 {
348                         f = 1 - eta / max(eta, this.weapon_switchdelay);
349                         break;
350                 }
351                 case WS_CLEAR:
352                 {
353                         f = 1;
354                         break;
355                 }
356         }
357         this.weapon_eta_last = f;
358         this.origin = this.viewmodel_origin;
359         this.angles = this.viewmodel_angles;
360         this.angles_x = (-90 * f * f);
361         viewmodel_animate(this);
362         setorigin(this, this.origin);
363 }
364
365 entity viewmodel;
366 STATIC_INIT(viewmodel) {
367     viewmodel = new(viewmodel);
368 }
369
370 void Porto_Draw(entity this);
371 STATIC_INIT(Porto)
372 {
373         entity e = new_pure(porto);
374         e.draw = Porto_Draw;
375         IL_PUSH(g_drawables, e);
376         e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
377 }
378
379 const int polyline_length = 16;
380 vector polyline[polyline_length];
381 void Porto_Draw(entity this)
382 {
383         if (activeweapon != WEP_PORTO) return;
384         if (spectatee_status) return;
385         if (WEP_CVAR(porto, secondary)) return;
386         if (intermission == 1) return;
387         if (intermission == 2) return;
388         if (STAT(HEALTH) <= 0) return;
389
390         vector pos = view_origin;
391         vector dir = view_forward;
392         if (angles_held_status)
393         {
394                 makevectors(angles_held);
395                 dir = v_forward;
396         }
397
398         polyline[0] = pos;
399
400         int portal_number = 0, portal1_idx = 1, portal_max = 2;
401         int n = 1 + 2;  // 2 lines == 3 points
402         for (int idx = 0; idx < n && idx < polyline_length - 1; )
403         {
404                 traceline(pos, pos + 65536 * dir, true, this);
405                 dir = reflect(dir, trace_plane_normal);
406                 pos = trace_endpos;
407                 polyline[++idx] = pos;
408                 if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
409                 {
410                         n += 1;
411                         continue;
412                 }
413                 if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
414                 {
415                         n = max(2, idx);
416                         break;
417                 }
418                 // check size
419                 {
420                         vector ang = vectoangles2(trace_plane_normal, dir);
421                         ang.x = -ang.x;
422                         makevectors(ang);
423                         if (!CheckWireframeBox(this, pos - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
424                         {
425                                 n = max(2, idx);
426                                 break;
427                         }
428                 }
429                 portal_number += 1;
430                 if (portal_number >= portal_max) break;
431                 if (portal_number == 1) portal1_idx = idx;
432         }
433         for (int idx = 0; idx < n - 1; ++idx)
434         {
435                 vector p = polyline[idx], q = polyline[idx + 1];
436                 if (idx == 0) p -= view_up * 16;  // line from player
437                 vector rgb = (idx < portal1_idx) ? '1 0 0' : '0 0 1';
438                 Draw_CylindricLine(p, q, 4, "", 1, 0, rgb, 0.5, DRAWFLAG_NORMAL, view_origin);
439         }
440 }
441
442 float drawtime;
443 float avgspeed;
444 vector GetCurrentFov(float fov)
445 {
446         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
447         float velocityzoom, curspeed;
448         vector v;
449
450         zoomsensitivity = autocvar_cl_zoomsensitivity;
451         zoomfactor = autocvar_cl_zoomfactor;
452         if(zoomfactor < 1 || zoomfactor > 30)
453                 zoomfactor = 2.5;
454         zoomspeed = autocvar_cl_zoomspeed;
455         if(zoomspeed >= 0)
456         if(zoomspeed < 0.5 || zoomspeed > 16)
457                         zoomspeed = 3.5;
458
459         zoomdir = button_zoom;
460         if(hud == HUD_NORMAL && !spectatee_status)
461         if(switchweapon == activeweapon)
462         if((activeweapon == WEP_VORTEX && !WEP_CVAR(vortex, secondary)) || (activeweapon == WEP_RIFLE && !WEP_CVAR(rifle, secondary))) // do NOT use switchweapon here
463                 zoomdir += button_attack2;
464         if(spectatee_status > 0 || isdemo())
465         {
466                 if(spectatorbutton_zoom)
467                 {
468                         if(zoomdir)
469                                 zoomdir = 0;
470                         else
471                                 zoomdir = 1;
472                 }
473                 // fteqcc failed twice here already, don't optimize this
474         }
475
476         if(zoomdir) { zoomin_effect = 0; }
477
478         if(camera_active)
479         {
480                 current_viewzoom = min(1, current_viewzoom + drawframetime);
481         }
482         else if(autocvar_cl_spawnzoom && zoomin_effect)
483         {
484                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
485
486                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
487                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
488                 if(current_viewzoom == 1) { zoomin_effect = 0; }
489         }
490         else
491         {
492                 if(zoomspeed < 0) // instant zoom
493                 {
494                         if(zoomdir)
495                                 current_viewzoom = 1 / zoomfactor;
496                         else
497                                 current_viewzoom = 1;
498                 }
499                 else
500                 {
501                         if(zoomdir)
502                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
503                         else
504                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
505                 }
506         }
507
508         if(almost_equals(current_viewzoom, 1))
509                 current_zoomfraction = 0;
510         else if(almost_equals(current_viewzoom, 1/zoomfactor))
511                 current_zoomfraction = 1;
512         else
513                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
514
515         if(zoomsensitivity < 1)
516                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
517         else
518                 setsensitivityscale(1);
519
520         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
521         {
522                 if(intermission) { curspeed = 0; }
523                 else
524                 {
525
526                         makevectors(view_angles);
527                         v = pmove_vel;
528                         if(csqcplayer)
529                                 v = csqcplayer.velocity;
530
531                         switch(autocvar_cl_velocityzoom_type)
532                         {
533                                 case 3: curspeed = max(0, v_forward * v); break;
534                                 case 2: curspeed = (v_forward * v); break;
535                                 case 1: default: curspeed = vlen(v); break;
536                         }
537                 }
538
539                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
540                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
541                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
542
543                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
544         }
545         else
546                 velocityzoom = 1;
547
548         float frustumx, frustumy, fovx, fovy;
549         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
550         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
551         fovx = atan2(frustumx, 1) / M_PI * 360.0;
552         fovy = atan2(frustumy, 1) / M_PI * 360.0;
553
554         return '1 0 0' * fovx + '0 1 0' * fovy;
555 }
556
557 vector GetViewLocationFOV(float fov)
558 {
559         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
560         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
561         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
562         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
563         return '1 0 0' * fovx + '0 1 0' * fovy;
564 }
565
566 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
567 {
568         float fovx, fovy;
569         float width = (ov_worldmax.x - ov_worldmin.x);
570         float height = (ov_worldmax.y - ov_worldmin.y);
571         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
572         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
573         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
574         return '1 0 0' * fovx + '0 1 0' * fovy;
575 }
576
577 // this function must match W_SetupShot!
578 float zoomscript_caught;
579
580 vector wcross_origin;
581 float wcross_scale_prev, wcross_alpha_prev;
582 vector wcross_color_prev;
583 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
584 vector wcross_color_goal_prev;
585 float wcross_changedonetime;
586
587 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
588 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
589 float wcross_name_changestarttime, wcross_name_changedonetime;
590 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
591
592 float wcross_ring_prev;
593
594 entity trueaim;
595 entity trueaim_rifle;
596
597 const float SHOTTYPE_HITTEAM = 1;
598 const float SHOTTYPE_HITOBSTRUCTION = 2;
599 const float SHOTTYPE_HITWORLD = 3;
600 const float SHOTTYPE_HITENEMY = 4;
601
602 void TrueAim_Init()
603 {
604         (trueaim = new_pure(trueaim)).dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
605         (trueaim_rifle = new_pure(trueaim_rifle)).dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
606 }
607
608 float EnemyHitCheck()
609 {
610         float t, n;
611         wcross_origin = project_3d_to_2d(trace_endpos);
612         wcross_origin.z = 0;
613         if(trace_ent)
614                 n = trace_ent.entnum;
615         else
616                 n = trace_networkentity;
617         if(n < 1)
618                 return SHOTTYPE_HITWORLD;
619         if(n > maxclients)
620                 return SHOTTYPE_HITWORLD;
621         t = entcs_GetTeam(n - 1);
622         if(teamplay)
623                 if(t == myteam)
624                         return SHOTTYPE_HITTEAM;
625         if(t == NUM_SPECTATOR)
626                 return SHOTTYPE_HITWORLD;
627         return SHOTTYPE_HITENEMY;
628 }
629
630 float TrueAimCheck()
631 {
632         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
633         vector vecs, trueaimpoint, w_shotorg;
634         vector mi, ma, dv;
635         float shottype;
636         entity ta;
637         float mv;
638
639         mi = ma = '0 0 0';
640         ta = trueaim;
641         mv = MOVE_NOMONSTERS;
642
643         switch(activeweapon) // WEAPONTODO
644         {
645                 case WEP_TUBA: // no aim
646                 case WEP_PORTO: // shoots from eye
647                 case WEP_NEXBALL: // shoots from eye
648                 case WEP_HOOK: // no trueaim
649                 case WEP_MORTAR: // toss curve
650                         return SHOTTYPE_HITWORLD;
651                 case WEP_VORTEX:
652                 case WEP_VAPORIZER:
653                         mv = MOVE_NORMAL;
654                         break;
655                 case WEP_RIFLE:
656                         ta = trueaim_rifle;
657                         mv = MOVE_NORMAL;
658                         if(zoomscript_caught)
659                         {
660                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
661                                 return EnemyHitCheck();
662                         }
663                         break;
664                 case WEP_DEVASTATOR: // projectile has a size!
665                         mi = '-3 -3 -3';
666                         ma = '3 3 3';
667                         break;
668                 case WEP_FIREBALL: // projectile has a size!
669                         mi = '-16 -16 -16';
670                         ma = '16 16 16';
671                         break;
672                 case WEP_SEEKER: // projectile has a size!
673                         mi = '-2 -2 -2';
674                         ma = '2 2 2';
675                         break;
676                 case WEP_ELECTRO: // projectile has a size!
677                         mi = '0 0 -3';
678                         ma = '0 0 -3';
679                         break;
680         }
681
682         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
683
684         vecs = decompressShotOrigin(STAT(SHOTORG));
685
686         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
687         trueaimpoint = trace_endpos;
688
689         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
690                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
691
692         if(vecs.x > 0)
693                 vecs.y = -vecs.y;
694         else
695                 vecs = '0 0 0';
696
697         dv = view_right * vecs.y + view_up * vecs.z;
698         w_shotorg = traceorigin + dv;
699
700         // now move the vecs forward as much as requested if possible
701         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
702         w_shotorg = trace_endpos - view_forward * nudge;
703
704         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
705         shottype = EnemyHitCheck();
706         if(shottype != SHOTTYPE_HITWORLD)
707                 return shottype;
708
709 #if 0
710         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
711         // or rather, I know why, but see no fix
712         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
713                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
714                 return SHOTTYPE_HITOBSTRUCTION;
715 #endif
716
717         return SHOTTYPE_HITWORLD;
718 }
719
720 void PostInit();
721 void CSQC_Demo_Camera();
722 float camera_mode;
723 const float CAMERA_FREE = 1;
724 const float CAMERA_CHASE = 2;
725 float reticle_type;
726 string reticle_image;
727 string NextFrameCommand;
728
729 vector freeze_org, freeze_ang;
730 entity nightvision_noise, nightvision_noise2;
731
732 const float MAX_TIME_DIFF = 5;
733 float pickup_crosshair_time, pickup_crosshair_size;
734 float hitindication_crosshair_size;
735 float use_vortex_chargepool;
736
737 float myhealth, myhealth_prev;
738 float myhealth_flash;
739
740 float old_blurradius, old_bluralpha;
741 float old_sharpen_intensity;
742
743 vector myhealth_gentlergb;
744
745 float contentavgalpha, liquidalpha_prev;
746 vector liquidcolor_prev;
747
748 float eventchase_current_distance;
749 float eventchase_running;
750 bool WantEventchase(entity this)
751 {
752         if(autocvar_cl_orthoview)
753                 return false;
754         if(intermission)
755                 return true;
756         if(this.viewloc)
757                 return true;
758         if(spectatee_status >= 0)
759         {
760                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
761                         return true;
762                 if(MUTATOR_CALLHOOK(WantEventchase, this))
763                         return true;
764                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
765                 {
766                         if(autocvar_cl_eventchase_death == 2)
767                         {
768                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
769                                 if(this.velocity == '0 0 0' || eventchase_running)
770                                         return true;
771                         }
772                         else return true;
773                 }
774         }
775         return false;
776 }
777
778 void HUD_Crosshair_Vehicle(entity this)
779 {
780         if(hud != HUD_BUMBLEBEE_GUN)
781         {
782                 Vehicle info = Vehicles_from(hud);
783                 info.vr_crosshair(info, this);
784         }
785 }
786
787 vector damage_blurpostprocess, content_blurpostprocess;
788
789 float unaccounted_damage = 0;
790 void UpdateDamage()
791 {
792         // accumulate damage with each stat update
793         static float damage_total_prev = 0;
794         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
795         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
796         damage_total_prev = damage_total;
797
798         static float damage_dealt_time_prev = 0;
799         float damage_dealt_time = STAT(HIT_TIME);
800         if (damage_dealt_time != damage_dealt_time_prev)
801         {
802                 unaccounted_damage += unaccounted_damage_new;
803                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")");
804         }
805         damage_dealt_time_prev = damage_dealt_time;
806
807         // prevent hitsound when switching spectatee
808         static float spectatee_status_prev = 0;
809         if (spectatee_status != spectatee_status_prev)
810                 unaccounted_damage = 0;
811         spectatee_status_prev = spectatee_status;
812 }
813
814 void HitSound()
815 {
816         // varying sound pitch
817
818         static float hitsound_time_prev = 0;
819         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
820         float arc_hack = activeweapon == WEP_ARC && autocvar_cl_hitsound >= 2;
821         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
822         {
823                 if (autocvar_cl_hitsound && unaccounted_damage)
824                 {
825                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
826                         float a = autocvar_cl_hitsound_max_pitch;
827                         float b = autocvar_cl_hitsound_min_pitch;
828                         float c = autocvar_cl_hitsound_nom_damage;
829                         float d = unaccounted_damage;
830                         float pitch_shift = (b*d*(a-1) + a*c*(1-b)) / (d*(a-1) + c*(1-b));
831
832                         // if sound variation is disabled, set pitch_shift to 1
833                         if (autocvar_cl_hitsound == 1)
834                                 pitch_shift = 1;
835
836                         // if pitch shift is reversed, mirror in (max-min)/2 + min
837                         if (autocvar_cl_hitsound == 3)
838                         {
839                                 float mirror_value = (a-b)/2 + b;
840                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
841                         }
842
843                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift));
844
845                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
846                         // todo: normalize sound pressure levels? seems unnecessary
847
848                         sound7(NULL, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
849                 }
850                 unaccounted_damage = 0;
851                 hitsound_time_prev = time;
852         }
853
854         static float typehit_time_prev = 0;
855         float typehit_time = STAT(TYPEHIT_TIME);
856         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
857         {
858                 sound(NULL, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
859                 typehit_time_prev = typehit_time;
860         }
861 }
862
863 vector crosshair_getcolor(entity this, float health_stat)
864 {
865         static float rainbow_last_flicker;
866         static vector rainbow_prev_color;
867         vector wcross_color = '0 0 0';
868         switch(autocvar_crosshair_color_special)
869         {
870                 case 1: // crosshair_color_per_weapon
871                 {
872                         if(this != WEP_Null && hud == HUD_NORMAL)
873                         {
874                                 wcross_color = this.wpcolor;
875                                 break;
876                         }
877                         else { goto normalcolor; }
878                 }
879
880                 case 2: // crosshair_color_by_health
881                 {
882                         float hp = health_stat;
883
884                         //x = red
885                         //y = green
886                         //z = blue
887
888                         wcross_color.z = 0;
889
890                         if(hp > 200)
891                         {
892                                 wcross_color.x = 0;
893                                 wcross_color.y = 1;
894                         }
895                         else if(hp > 150)
896                         {
897                                 wcross_color.x = 0.4 - (hp-150)*0.02 * 0.4;
898                                 wcross_color.y = 0.9 + (hp-150)*0.02 * 0.1;
899                         }
900                         else if(hp > 100)
901                         {
902                                 wcross_color.x = 1 - (hp-100)*0.02 * 0.6;
903                                 wcross_color.y = 1 - (hp-100)*0.02 * 0.1;
904                                 wcross_color.z = 1 - (hp-100)*0.02;
905                         }
906                         else if(hp > 50)
907                         {
908                                 wcross_color.x = 1;
909                                 wcross_color.y = 1;
910                                 wcross_color.z = 0.2 + (hp-50)*0.02 * 0.8;
911                         }
912                         else if(hp > 20)
913                         {
914                                 wcross_color.x = 1;
915                                 wcross_color.y = (hp-20)*90/27/100;
916                                 wcross_color.z = (hp-20)*90/27/100 * 0.2;
917                         }
918                         else
919                         {
920                                 wcross_color.x = 1;
921                                 wcross_color.y = 0;
922                         }
923                         break;
924                 }
925
926                 case 3: // crosshair_color_rainbow
927                 {
928                         if(time >= rainbow_last_flicker)
929                         {
930                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
931                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
932                         }
933                         wcross_color = rainbow_prev_color;
934                         break;
935                 }
936 LABEL(normalcolor)
937                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
938         }
939
940         return wcross_color;
941 }
942
943 void HUD_Crosshair(entity this)
944 {
945         float f, i, j;
946         vector v;
947         if(!scoreboard_active && !camera_active && intermission != 2 &&
948                 spectatee_status != -1 && !csqcplayer.viewloc && !MUTATOR_CALLHOOK(DrawCrosshair) &&
949                 !HUD_MinigameMenu_IsOpened() )
950         {
951                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
952                         return;
953
954                 if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
955                         return;
956
957                 if (hud != HUD_NORMAL)
958                 {
959                         HUD_Crosshair_Vehicle(this);
960                         return;
961                 }
962
963                 string wcross_style;
964                 float wcross_alpha, wcross_resolution;
965                 wcross_style = autocvar_crosshair;
966                 if (wcross_style == "0")
967                         return;
968                 wcross_resolution = autocvar_crosshair_size;
969                 if (wcross_resolution == 0)
970                         return;
971                 wcross_alpha = autocvar_crosshair_alpha;
972                 if (wcross_alpha == 0)
973                         return;
974
975                 // TrueAim check
976                 float shottype;
977
978                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
979                 wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
980                 wcross_origin.z = 0;
981                 if(autocvar_crosshair_hittest)
982                 {
983                         vector wcross_oldorigin;
984                         wcross_oldorigin = wcross_origin;
985                         shottype = TrueAimCheck();
986                         if(shottype == SHOTTYPE_HITWORLD)
987                         {
988                                 v = wcross_origin - wcross_oldorigin;
989                                 v.x /= vid_conwidth;
990                                 v.y /= vid_conheight;
991                                 if(vdist(v, >, 0.01))
992                                         shottype = SHOTTYPE_HITOBSTRUCTION;
993                         }
994                         if(!autocvar_crosshair_hittest_showimpact)
995                                 wcross_origin = wcross_oldorigin;
996                 }
997                 else
998                         shottype = SHOTTYPE_HITWORLD;
999
1000                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1001                 string wcross_name = "";
1002                 float wcross_scale, wcross_blur;
1003
1004         entity e = WEP_Null;
1005                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1006                 {
1007                         e = switchingweapon;
1008                         if(e)
1009                         {
1010                                 if(autocvar_crosshair_per_weapon)
1011                                 {
1012                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
1013                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1014                                         //if (wcross_resolution == 0)
1015                                                 //return;
1016
1017                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1018                                         wcross_resolution *= e.w_crosshair_size;
1019                                         wcross_name = e.w_crosshair;
1020                                 }
1021                         }
1022                 }
1023
1024                 if(wcross_name == "")
1025                         wcross_name = strcat("gfx/crosshair", wcross_style);
1026
1027                 // MAIN CROSSHAIR COLOR DECISION
1028                 wcross_color = crosshair_getcolor(e, STAT(HEALTH));
1029
1030                 if(autocvar_crosshair_effect_scalefade)
1031                 {
1032                         wcross_scale = wcross_resolution;
1033                         wcross_resolution = 1;
1034                 }
1035                 else
1036                 {
1037                         wcross_scale = 1;
1038                 }
1039
1040                 if(autocvar_crosshair_pickup)
1041                 {
1042                         float stat_pickup_time = STAT(LAST_PICKUP);
1043
1044                         if(pickup_crosshair_time < stat_pickup_time)
1045                         {
1046                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1047                                         pickup_crosshair_size = 1;
1048
1049                                 pickup_crosshair_time = stat_pickup_time;
1050                         }
1051
1052                         if(pickup_crosshair_size > 0)
1053                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1054                         else
1055                                 pickup_crosshair_size = 0;
1056
1057                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1058                 }
1059
1060                 // todo: make crosshair hit indication dependent on damage dealt
1061                 if(autocvar_crosshair_hitindication)
1062                 {
1063                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1064
1065                         if(unaccounted_damage)
1066                         {
1067                                 hitindication_crosshair_size = 1;
1068                         }
1069
1070                         if(hitindication_crosshair_size > 0)
1071                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1072                         else
1073                                 hitindication_crosshair_size = 0;
1074
1075                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1076                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1077                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1078                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1079                 }
1080
1081                 if(shottype == SHOTTYPE_HITENEMY)
1082                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1083                 if(shottype == SHOTTYPE_HITTEAM)
1084                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1085
1086                 f = fabs(autocvar_crosshair_effect_time);
1087                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1088                 {
1089                         wcross_changedonetime = time + f;
1090                 }
1091                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1092                 {
1093                         wcross_name_changestarttime = time;
1094                         wcross_name_changedonetime = time + f;
1095                         if(wcross_name_goal_prev_prev)
1096                                 strunzone(wcross_name_goal_prev_prev);
1097                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1098                         wcross_name_goal_prev = strzone(wcross_name);
1099                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1100                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1101                         wcross_resolution_goal_prev = wcross_resolution;
1102                 }
1103
1104                 wcross_scale_goal_prev = wcross_scale;
1105                 wcross_alpha_goal_prev = wcross_alpha;
1106                 wcross_color_goal_prev = wcross_color;
1107
1108                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1109                 {
1110                         wcross_blur = 1;
1111                         wcross_alpha *= 0.75;
1112                 }
1113                 else
1114                         wcross_blur = 0;
1115                 // *_prev is at time-frametime
1116                 // * is at wcross_changedonetime+f
1117                 // what do we have at time?
1118                 if(time < wcross_changedonetime)
1119                 {
1120                         f = frametime / (wcross_changedonetime - time + frametime);
1121                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1122                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1123                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1124                 }
1125
1126                 wcross_scale_prev = wcross_scale;
1127                 wcross_alpha_prev = wcross_alpha;
1128                 wcross_color_prev = wcross_color;
1129
1130                 MUTATOR_CALLHOOK(UpdateCrosshair);
1131
1132                 wcross_scale *= 1 - autocvar__menu_alpha;
1133                 wcross_alpha *= 1 - autocvar__menu_alpha;
1134                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1135
1136                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1137                 {
1138                         // crosshair rings for weapon stats
1139                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1140                         {
1141                                 // declarations and stats
1142                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1143                                 string ring_image = string_null, ring_inner_image = string_null;
1144                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1145
1146                                 ring_scale = autocvar_crosshair_ring_size;
1147
1148                                 float weapon_clipload, weapon_clipsize;
1149                                 weapon_clipload = STAT(WEAPON_CLIPLOAD);
1150                                 weapon_clipsize = STAT(WEAPON_CLIPSIZE);
1151
1152                                 float ok_ammo_charge, ok_ammo_chargepool;
1153                                 ok_ammo_charge = STAT(OK_AMMO_CHARGE);
1154                                 ok_ammo_chargepool = STAT(OK_AMMO_CHARGEPOOL);
1155
1156                                 float vortex_charge, vortex_chargepool;
1157                                 vortex_charge = STAT(VORTEX_CHARGE);
1158                                 vortex_chargepool = STAT(VORTEX_CHARGEPOOL);
1159
1160                                 float arc_heat = STAT(ARC_HEAT);
1161
1162                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1163                                         vortex_charge_movingavg = vortex_charge;
1164
1165
1166                                 // handle the values
1167                                 if (autocvar_crosshair_ring && activeweapon == WEP_VORTEX && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1168                                 {
1169                                         if (vortex_chargepool || use_vortex_chargepool) {
1170                                                 use_vortex_chargepool = 1;
1171                                                 ring_inner_value = vortex_chargepool;
1172                                         } else {
1173                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
1174                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
1175                                         }
1176
1177                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1178                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1179                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1180
1181                                         // draw the outer ring to show the current charge of the weapon
1182                                         ring_value = vortex_charge;
1183                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1184                                         ring_rgb = wcross_color;
1185                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1186                                 }
1187                                 else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1188                                 {
1189                                         ring_value = bound(0, STAT(LAYED_MINES) / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1190                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1191                                         ring_rgb = wcross_color;
1192                                         ring_image = "gfx/crosshair_ring.tga";
1193                                 }
1194                                 else if (activeweapon == WEP_HAGAR && STAT(HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1195                                 {
1196                                         ring_value = bound(0, STAT(HAGAR_LOAD) / WEP_CVAR_SEC(hagar, load_max), 1);
1197                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1198                                         ring_rgb = wcross_color;
1199                                         ring_image = "gfx/crosshair_ring.tga";
1200                                 }
1201                                 else if (ok_ammo_charge)
1202                                 {
1203                                         ring_value = ok_ammo_chargepool;
1204                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1205                                         ring_rgb = wcross_color;
1206                                         ring_image = "gfx/crosshair_ring.tga";
1207                                 }
1208                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1209                                 {
1210                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1211                                         ring_scale = autocvar_crosshair_ring_reload_size;
1212                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1213                                         ring_rgb = wcross_color;
1214
1215                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1216                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1217                                         if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1218                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1219                                         else
1220                                                 ring_image = "gfx/crosshair_ring.tga";
1221                                 }
1222                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && activeweapon == WEP_ARC )
1223                                 {
1224                                         ring_value = arc_heat;
1225                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1226                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1227                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1228                                         ring_image = "gfx/crosshair_ring.tga";
1229                                 }
1230
1231                                 // if in weapon switch animation, fade ring out/in
1232                                 if(autocvar_crosshair_effect_time > 0)
1233                                 {
1234                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1235                                         if (f >= 1)
1236                                         {
1237                                                 wcross_ring_prev = ((ring_image) ? true : false);
1238                                         }
1239
1240                                         if(wcross_ring_prev)
1241                                         {
1242                                                 if(f < 1)
1243                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1244                                         }
1245                                         else
1246                                         {
1247                                                 if(f < 1)
1248                                                         ring_alpha *= bound(0, f, 1);
1249                                         }
1250                                 }
1251
1252                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1253                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1254
1255                                 if (ring_value)
1256                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1257                         }
1258
1259 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1260                         MACRO_BEGIN { \
1261                                 if(wcross_blur > 0) \
1262                                 { \
1263                                         for(i = -2; i <= 2; ++i) \
1264                                         for(j = -2; j <= 2; ++j) \
1265                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1266                                 } \
1267                                 else \
1268                                 { \
1269                                         M(0,0,sz,wcross_name,wcross_alpha); \
1270                                 } \
1271                         } MACRO_END
1272
1273 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1274                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1275
1276 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1277                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1278
1279                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1280                         {
1281                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1282                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1283                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1284                                 f = 1 - f;
1285                         }
1286                         else
1287                         {
1288                                 f = 1;
1289                         }
1290                         wcross_name_alpha_goal_prev = f;
1291
1292                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1293                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1294
1295                         if(autocvar_crosshair_dot)
1296                         {
1297                                 vector wcross_color_old;
1298                                 wcross_color_old = wcross_color;
1299
1300                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1301                                         wcross_color = stov(autocvar_crosshair_dot_color);
1302
1303                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1304                                 // FIXME why don't we use wcross_alpha here?
1305                                 wcross_color = wcross_color_old;
1306                         }
1307                 }
1308         }
1309         else
1310         {
1311                 wcross_scale_prev = 0;
1312                 wcross_alpha_prev = 0;
1313                 wcross_scale_goal_prev = 0;
1314                 wcross_alpha_goal_prev = 0;
1315                 wcross_changedonetime = 0;
1316                 if(wcross_name_goal_prev)
1317                         strunzone(wcross_name_goal_prev);
1318                 wcross_name_goal_prev = string_null;
1319                 if(wcross_name_goal_prev_prev)
1320                         strunzone(wcross_name_goal_prev_prev);
1321                 wcross_name_goal_prev_prev = string_null;
1322                 wcross_name_changestarttime = 0;
1323                 wcross_name_changedonetime = 0;
1324                 wcross_name_alpha_goal_prev = 0;
1325                 wcross_name_alpha_goal_prev_prev = 0;
1326                 wcross_resolution_goal_prev = 0;
1327                 wcross_resolution_goal_prev_prev = 0;
1328         }
1329 }
1330
1331 void HUD_Draw(entity this)
1332 {
1333         // if we don't know gametype and scores yet avoid drawing the scoreboard
1334         // also in the very first frames, player state may be inconsistent so avoid drawing the hud at all
1335         // e.g. since initial player's health is 0 hud would display the hud_damage effect,
1336         // cl_deathscoreboard would show the scoreboard and so on
1337         if(!gametype)
1338                 return;
1339
1340         if(!intermission)
1341         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1342         {
1343                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, M_ARGV(0, vector), autocvar_hud_colorflash_alpha * M_ARGV(1, float), DRAWFLAG_ADDITIVE);
1344         }
1345         else if(STAT(FROZEN))
1346         {
1347                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, ((STAT(REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * STAT(REVIVE_PROGRESS)) + ('0 1 1' * STAT(REVIVE_PROGRESS) * -1)) : '0.25 0.90 1'), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1348         }
1349         if(!intermission)
1350         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1351         {
1352                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * STAT(NADE_TIMER)) - ('0 1 1' * STAT(NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1353                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1354         }
1355         else if(STAT(CAPTURE_PROGRESS))
1356         {
1357                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(CAPTURE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1358                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Capture progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1359         }
1360         else if(STAT(REVIVE_PROGRESS))
1361         {
1362                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1363                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1364         }
1365
1366         if(autocvar_r_letterbox == 0)
1367                 if(autocvar_viewsize < 120)
1368                 {
1369                         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1370                                 Accuracy_LoadLevels();
1371
1372                         HUD_Main();
1373                         HUD_Scale_Disable();
1374                 }
1375
1376         // crosshair goes VERY LAST
1377         UpdateDamage();
1378         HUD_Crosshair(this);
1379         HitSound();
1380 }
1381
1382 bool ov_enabled;
1383 float oldr_nearclip;
1384 float oldr_farclip_base;
1385 float oldr_farclip_world;
1386 float oldr_novis;
1387 float oldr_useportalculling;
1388 float oldr_useinfinitefarclip;
1389
1390 void cl_notice_run();
1391
1392 float prev_myteam;
1393 int lasthud;
1394 float vh_notice_time;
1395 void WaypointSprite_Load();
1396 void CSQC_UpdateView(entity this, float w, float h)
1397 {
1398     TC(int, w); TC(int, h);
1399         entity e;
1400         float fov;
1401         float f;
1402         vector vf_size, vf_min;
1403         float a;
1404
1405         execute_next_frame();
1406
1407         ++framecount;
1408
1409         stats_get();
1410         hud = STAT(HUD);
1411
1412         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1413                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1414
1415         lasthud = hud;
1416
1417         HUD_Scale_Disable();
1418
1419         if(autocvar__hud_showbinds_reload) // menu can set this one
1420         {
1421                 db_close(binddb);
1422                 binddb = db_create();
1423                 cvar_set("_hud_showbinds_reload", "0");
1424         }
1425
1426         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1427                 view_quality = getproperty(VF_MINFPS_QUALITY);
1428         else
1429                 view_quality = 1;
1430
1431         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1432         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1433
1434         vf_size = getpropertyvec(VF_SIZE);
1435         vf_min = getpropertyvec(VF_MIN);
1436         vid_width = vf_size.x;
1437         vid_height = vf_size.y;
1438
1439         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1440         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1441
1442         WaypointSprite_Load();
1443
1444         CSQCPlayer_SetCamera();
1445
1446         if(player_localentnum <= maxclients) // is it a client?
1447                 current_player = player_localentnum - 1;
1448         else // then player_localentnum is the vehicle I'm driving
1449                 current_player = player_localnum;
1450         myteam = entcs_GetTeam(current_player);
1451
1452         if(myteam != prev_myteam)
1453         {
1454                 myteamcolors = colormapPaletteColor(myteam, 1);
1455                 FOREACH(hud_panels, true, it.update_time = time);
1456                 prev_myteam = myteam;
1457         }
1458
1459         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1460
1461         float is_dead = (STAT(HEALTH) <= 0);
1462
1463         // FIXME do we need this hack?
1464         if(isdemo())
1465         {
1466                 // in demos, input_buttons do not work
1467                 button_zoom = (autocvar__togglezoom == "-");
1468         }
1469         else if(button_zoom
1470                 && autocvar_cl_unpress_zoom_on_death
1471                 && (spectatee_status >= 0)
1472                 && (is_dead || intermission))
1473         {
1474                 // no zoom while dead or in intermission please
1475                 localcmd("-zoom\n");
1476                 button_zoom = false;
1477         }
1478
1479         // event chase camera
1480         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1481         {
1482                 if(STAT(CAMERA_SPECTATOR))
1483                 {
1484                         if(spectatee_status > 0)
1485                         {
1486                                 if(!autocvar_chase_active)
1487                                 {
1488                                         cvar_set("chase_active", "-2");
1489                                         goto skip_eventchase_death;
1490                                 }
1491                         }
1492                         else if(autocvar_chase_active == -2)
1493                                 cvar_set("chase_active", "0");
1494
1495                         if(autocvar_chase_active == -2)
1496                                 goto skip_eventchase_death;
1497                 }
1498                 else if(autocvar_chase_active == -2)
1499                         cvar_set("chase_active", "0");
1500
1501                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1502
1503                 float vehicle_viewdist = 0;
1504                 vector vehicle_viewofs = '0 0 0';
1505
1506                 if(vehicle_chase)
1507                 {
1508                         if(hud != HUD_BUMBLEBEE_GUN)
1509                         {
1510                                 Vehicle info = Vehicles_from(hud);
1511                                 vehicle_viewdist = info.height;
1512                                 vehicle_viewofs = info.view_ofs;
1513                         }
1514                 }
1515
1516                 if(WantEventchase(this))
1517                 {
1518                         vector current_view_origin_override = '0 0 0';
1519                         vector view_offset_override = '0 0 0';
1520                         float chase_distance_override = 0;
1521                         bool custom_eventchase = MUTATOR_CALLHOOK(CustomizeEventchase, this);
1522                         if(custom_eventchase)
1523                         {
1524                                 current_view_origin_override = M_ARGV(0, vector);
1525                                 view_offset_override = M_ARGV(1, vector);
1526                                 chase_distance_override = M_ARGV(0, float);
1527                         }
1528                         eventchase_running = true;
1529
1530                         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1531                         if(!local_player)
1532                                 local_player = this; // fall back!
1533
1534                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1535                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1536                         if (custom_eventchase)
1537                                 current_view_origin = current_view_origin_override;
1538
1539                         // detect maximum viewoffset and use it
1540                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1541                         if(vehicle_chase)
1542                         {
1543                                 if(vehicle_viewofs)
1544                                         view_offset = vehicle_viewofs;
1545                                 else
1546                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
1547                         }
1548                         if (custom_eventchase)
1549                                 view_offset = view_offset_override;
1550
1551                         if(view_offset)
1552                         {
1553                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, this);
1554                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1555                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1556                         }
1557
1558                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1559                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1560                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1561                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1562
1563                         // make the camera smooth back
1564                         float chase_distance = autocvar_cl_eventchase_distance;
1565                         if(vehicle_chase)
1566                         {
1567                                 if(vehicle_viewofs)
1568                                         chase_distance = vehicle_viewdist;
1569                                 else
1570                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
1571                         }
1572                         if (custom_eventchase)
1573                                 chase_distance = chase_distance_override;
1574
1575                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1576                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1577                         else if(eventchase_current_distance != chase_distance)
1578                                 eventchase_current_distance = chase_distance;
1579
1580                         makevectors(view_angles);
1581
1582                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1583                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, this);
1584
1585                         // If the boxtrace fails, revert back to line tracing.
1586                         if(!local_player.viewloc)
1587                         if(trace_startsolid)
1588                         {
1589                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1590                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, this);
1591                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1592                         }
1593                         else { setproperty(VF_ORIGIN, trace_endpos); }
1594
1595                         if(!local_player.viewloc)
1596                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1597                 }
1598                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1599                 {
1600                         eventchase_running = false;
1601                         cvar_set("chase_active", "0");
1602                         eventchase_current_distance = 0; // start from 0 next time
1603                 }
1604         }
1605         // workaround for camera stuck between player's legs when using chase_active 1
1606         // because the engine stops updating the chase_active camera when the game ends
1607         else if(intermission)
1608         {
1609                 cvar_settemp("chase_active", "-1");
1610                 eventchase_current_distance = 0;
1611         }
1612
1613         LABEL(skip_eventchase_death);
1614
1615         // do lockview after event chase camera so that it still applies whenever necessary.
1616         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1617         {
1618                 setproperty(VF_ORIGIN, freeze_org);
1619                 setproperty(VF_ANGLES, freeze_ang);
1620         }
1621         else
1622         {
1623                 freeze_org = getpropertyvec(VF_ORIGIN);
1624                 freeze_ang = getpropertyvec(VF_ANGLES);
1625         }
1626
1627         WarpZone_FixView();
1628         //WarpZone_FixPMove();
1629
1630         vector ov_org = '0 0 0';
1631         vector ov_mid = '0 0 0';
1632         vector ov_worldmin = '0 0 0';
1633         vector ov_worldmax = '0 0 0';
1634         if(autocvar_cl_orthoview)
1635         {
1636                 ov_worldmin = mi_picmin;
1637                 ov_worldmax = mi_picmax;
1638
1639                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1640                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1641                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1642
1643                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1644                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1645
1646                 float ov_nearest = vlen(ov_org - vec3(
1647                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1648                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1649                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1650                 ));
1651
1652                 float ov_furthest = 0;
1653                 float dist = 0;
1654
1655                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1656                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1657                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1658                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1659                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1660                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1661                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1662                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1663
1664                 if(!ov_enabled)
1665                 {
1666                         oldr_nearclip = cvar("r_nearclip");
1667                         oldr_farclip_base = cvar("r_farclip_base");
1668                         oldr_farclip_world = cvar("r_farclip_world");
1669                         oldr_novis = cvar("r_novis");
1670                         oldr_useportalculling = cvar("r_useportalculling");
1671                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1672                 }
1673
1674                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1675                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1676                 cvar_settemp("r_farclip_world", "0");
1677                 cvar_settemp("r_novis", "1");
1678                 cvar_settemp("r_useportalculling", "0");
1679                 cvar_settemp("r_useinfinitefarclip", "0");
1680
1681                 setproperty(VF_ORIGIN, ov_org);
1682                 setproperty(VF_ANGLES, '90 0 0');
1683
1684                 ov_enabled = true;
1685
1686                 #if 0
1687                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1688                         vtos(ov_org),
1689                         vtos(getpropertyvec(VF_ANGLES)),
1690                         ov_distance,
1691                         ov_nearest,
1692                         ov_furthest);
1693                 #endif
1694         }
1695         else
1696         {
1697                 if(ov_enabled)
1698                 {
1699                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1700                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1701                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1702                         cvar_set("r_novis", ftos(oldr_novis));
1703                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1704                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1705                 }
1706                 ov_enabled = false;
1707         }
1708
1709         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
1710         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
1711         viewmodel_draw(viewmodel);
1712
1713         // Render the Scene
1714         view_origin = getpropertyvec(VF_ORIGIN);
1715         view_angles = getpropertyvec(VF_ANGLES);
1716         makevectors(view_angles);
1717         view_forward = v_forward;
1718         view_right = v_right;
1719         view_up = v_up;
1720
1721 #ifdef BLURTEST
1722         if(time > blurtest_time0 && time < blurtest_time1)
1723         {
1724                 float r, t;
1725
1726                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1727                 r = t * blurtest_radius;
1728                 f = 1 / pow(t, blurtest_power) - 1;
1729
1730                 cvar_set("r_glsl_postprocess", "1");
1731                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1732         }
1733         else
1734         {
1735                 cvar_set("r_glsl_postprocess", "0");
1736                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1737         }
1738 #endif
1739
1740         TargetMusic_Advance();
1741         Fog_Force();
1742
1743         if(drawtime == 0)
1744                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1745         else
1746                 drawframetime = bound(0.000001, time - drawtime, 1);
1747         drawtime = time;
1748
1749         // watch for gametype changes here...
1750         // in ParseStuffCMD the cmd isn't executed yet :/
1751         // might even be better to add the gametype to TE_CSQC_INIT...?
1752         if(!postinit)
1753                 PostInit();
1754
1755         if(intermission && !gameover_time)
1756                 gameover_time = time;
1757
1758         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1759         {
1760                 if(calledhooks & HOOK_START)
1761                 {
1762                         localcmd("\ncl_hook_gameend\n");
1763                         calledhooks |= HOOK_END;
1764                 }
1765         }
1766
1767         Announcer();
1768
1769         fov = autocvar_fov;
1770         if(fov <= 59.5)
1771         {
1772                 if(!zoomscript_caught)
1773                 {
1774                         localcmd("+button9\n");
1775                         zoomscript_caught = 1;
1776                 }
1777         }
1778         else
1779         {
1780                 if(zoomscript_caught)
1781                 {
1782                         localcmd("-button9\n");
1783                         zoomscript_caught = 0;
1784                 }
1785         }
1786
1787         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1788
1789         // currently switching-to weapon (for crosshair)
1790         switchingweapon = Weapons_from(STAT(SWITCHINGWEAPON));
1791
1792         // actually active weapon (for zoom)
1793         activeweapon = Weapons_from(STAT(ACTIVEWEAPON));
1794
1795         switchweapon = Weapons_from(STAT(SWITCHWEAPON));
1796
1797         if(last_switchweapon != switchweapon)
1798         {
1799                 weapontime = time;
1800                 last_switchweapon = switchweapon;
1801                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1802                 {
1803                         localcmd("-zoom\n");
1804                         button_zoom = false;
1805                 }
1806                 if(autocvar_cl_unpress_attack_on_weapon_switch)
1807                 {
1808                         localcmd("-fire\n");
1809                         localcmd("-fire2\n");
1810                         button_attack2 = false;
1811                 }
1812         }
1813         if(last_activeweapon != activeweapon)
1814         {
1815                 last_activeweapon = activeweapon;
1816
1817                 e = activeweapon;
1818                 if(e.netname != "")
1819                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1820                 else
1821                         localcmd("\ncl_hook_activeweapon none\n");
1822         }
1823
1824         // ALWAYS Clear Current Scene First
1825         clearscene();
1826
1827         setproperty(VF_ORIGIN, view_origin);
1828         setproperty(VF_ANGLES, view_angles);
1829
1830         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1831         setproperty(VF_SIZE, vf_size);
1832         setproperty(VF_MIN, vf_min);
1833
1834         // Assign Standard Viewflags
1835         // Draw the World (and sky)
1836         setproperty(VF_DRAWWORLD, 1);
1837
1838         // Set the console size vars
1839         vid_conwidth = autocvar_vid_conwidth;
1840         vid_conheight = autocvar_vid_conheight;
1841         vid_pixelheight = autocvar_vid_pixelheight;
1842
1843         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1844         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1845         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1846
1847         if(camera_active) // Camera for demo playback
1848         {
1849                 if(autocvar_camera_enable)
1850                         CSQC_Demo_Camera();
1851                 else
1852                 {
1853                         cvar_set("chase_active", ftos(chase_active_backup));
1854                         cvar_set("cl_demo_mousegrab", "0");
1855                         camera_active = false;
1856                 }
1857         }
1858         else
1859         {
1860 #ifdef CAMERATEST
1861                 if(autocvar_camera_enable)
1862 #else
1863                 if(autocvar_camera_enable && isdemo())
1864 #endif
1865                 {
1866                         // Enable required Darkplaces cvars
1867                         chase_active_backup = autocvar_chase_active;
1868                         cvar_set("chase_active", "2");
1869                         cvar_set("cl_demo_mousegrab", "1");
1870                         camera_active = true;
1871                         camera_mode = false;
1872                 }
1873         }
1874
1875         // Draw the Crosshair
1876         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1877
1878         // Draw the Engine Status Bar (the default Quake HUD)
1879         setproperty(VF_DRAWENGINESBAR, 0);
1880
1881         // Update the mouse position
1882         /*
1883            mousepos_x = vid_conwidth;
1884            mousepos_y = vid_conheight;
1885            mousepos = mousepos*0.5 + getmousepos();
1886          */
1887
1888         IL_EACH(g_drawables, it.draw, it.draw(it));
1889
1890         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1891         renderscene();
1892
1893         // now switch to 2D drawing mode by calling a 2D drawing function
1894         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1895         // next R_RenderScene call
1896         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1897
1898         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1899         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1900         {
1901                 // apply night vision effect
1902                 vector tc_00, tc_01, tc_10, tc_11;
1903                 vector rgb = '0 0 0';
1904
1905                 if(!nightvision_noise)
1906                 {
1907                         nightvision_noise = new(nightvision_noise);
1908                 }
1909                 if(!nightvision_noise2)
1910                 {
1911                         nightvision_noise2 = new(nightvision_noise2);
1912                 }
1913
1914                 // color tint in yellow
1915                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1916
1917                 // draw BG
1918                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1919                 rgb = '1 1 1';
1920                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1921                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1922                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1923                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1924                 tc_11 = tc_01 + tc_10 - tc_00;
1925                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1926                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1927                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1928                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1929                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1930                 R_EndPolygon();
1931
1932                 // draw FG
1933                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1934                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1935                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1936                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1937                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1938                 tc_11 = tc_01 + tc_10 - tc_00;
1939                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1940                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1941                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1942                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1943                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1944                 R_EndPolygon();
1945         }
1946
1947         if(autocvar_cl_reticle)
1948         {
1949                 Weapon wep = activeweapon;
1950                 // Draw the aiming reticle for weapons that use it
1951                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
1952                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
1953                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
1954                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
1955                 {
1956                         // no zoom reticle while dead
1957                         reticle_type = 0;
1958                 }
1959                 else if(wep.wr_zoomreticle(wep) && autocvar_cl_reticle_weapon)
1960                 {
1961                         if(reticle_image != "") { reticle_type = 2; }
1962                         else { reticle_type = 0; }
1963                 }
1964                 else if(button_zoom || zoomscript_caught)
1965                 {
1966                         // normal zoom
1967                         reticle_type = 1;
1968                 }
1969
1970                 if(reticle_type)
1971                 {
1972                         if(autocvar_cl_reticle_stretch)
1973                         {
1974                                 reticle_size.x = vid_conwidth;
1975                                 reticle_size.y = vid_conheight;
1976                                 reticle_pos.x = 0;
1977                                 reticle_pos.y = 0;
1978                         }
1979                         else
1980                         {
1981                                 reticle_size.x = max(vid_conwidth, vid_conheight);
1982                                 reticle_size.y = max(vid_conwidth, vid_conheight);
1983                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
1984                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
1985                         }
1986
1987                         if(zoomscript_caught)
1988                                 f = 1;
1989                         else
1990                                 f = current_zoomfraction;
1991
1992                         if(f)
1993                         {
1994                                 switch(reticle_type)
1995                                 {
1996                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
1997                                         case 2: drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
1998                                 }
1999                         }
2000                 }
2001         }
2002         else
2003         {
2004                 if(reticle_type != 0) { reticle_type = 0; }
2005         }
2006
2007
2008         // improved polyblend
2009         if(autocvar_hud_contents)
2010         {
2011                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
2012                 vector liquidcolor;
2013
2014                 switch(pointcontents(view_origin))
2015                 {
2016                         case CONTENT_WATER:
2017                                 liquidalpha = autocvar_hud_contents_water_alpha;
2018                                 liquidcolor = stov(autocvar_hud_contents_water_color);
2019                                 incontent = 1;
2020                                 break;
2021
2022                         case CONTENT_LAVA:
2023                                 liquidalpha = autocvar_hud_contents_lava_alpha;
2024                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
2025                                 incontent = 1;
2026                                 break;
2027
2028                         case CONTENT_SLIME:
2029                                 liquidalpha = autocvar_hud_contents_slime_alpha;
2030                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
2031                                 incontent = 1;
2032                                 break;
2033
2034                         default:
2035                                 liquidalpha = 0;
2036                                 liquidcolor = '0 0 0';
2037                                 incontent = 0;
2038                                 break;
2039                 }
2040
2041                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
2042                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
2043                         contentfadetime = autocvar_hud_contents_fadeintime;
2044                         liquidalpha_prev = liquidalpha;
2045                         liquidcolor_prev = liquidcolor;
2046                 }
2047                 else
2048                         contentfadetime = autocvar_hud_contents_fadeouttime;
2049
2050                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
2051                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
2052
2053                 if(contentavgalpha)
2054                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
2055
2056                 if(autocvar_hud_postprocessing)
2057                 {
2058                         if(autocvar_hud_contents_blur && contentavgalpha)
2059                         {
2060                                 content_blurpostprocess.x = 1;
2061                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
2062                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
2063                         }
2064                         else
2065                         {
2066                                 content_blurpostprocess.x = 0;
2067                                 content_blurpostprocess.y = 0;
2068                                 content_blurpostprocess.z = 0;
2069                         }
2070                 }
2071         }
2072
2073         if(autocvar_hud_damage && !STAT(FROZEN))
2074         {
2075                 splash_size.x = max(vid_conwidth, vid_conheight);
2076                 splash_size.y = max(vid_conwidth, vid_conheight);
2077                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2078                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2079
2080                 float myhealth_flash_temp;
2081                 myhealth = STAT(HEALTH);
2082
2083                 // fade out
2084                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2085                 // add new damage
2086                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2087
2088                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2089                 pain_threshold = autocvar_hud_damage_pain_threshold;
2090                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2091                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2092
2093                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2094                 {
2095                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2096                 }
2097
2098                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2099
2100                 if(myhealth_prev < 1)
2101                 {
2102                         if(myhealth >= 1)
2103                         {
2104                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2105                                 myhealth_flash_temp = 0;
2106                         }
2107                         else
2108                         {
2109                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2110                         }
2111                 }
2112
2113                 if(spectatee_status == -1 || intermission)
2114                 {
2115                         myhealth_flash = 0; // observing, or match ended
2116                         myhealth_flash_temp = 0;
2117                 }
2118
2119                 myhealth_prev = myhealth;
2120
2121                 // IDEA: change damage color/picture based on player model for robot/alien species?
2122                 // pro: matches model better
2123                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2124                 // maybe different reddish pics?
2125                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2126                 {
2127                         if(autocvar_cl_gentle_damage == 2)
2128                         {
2129                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2130                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
2131                         }
2132                         else
2133                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2134
2135                         if(myhealth_flash_temp > 0)
2136                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2137                 }
2138                 else if(myhealth_flash_temp > 0)
2139                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2140
2141                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2142                 {
2143                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2144                         {
2145                                 damage_blurpostprocess.x = 1;
2146                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2147                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2148                         }
2149                         else
2150                         {
2151                                 damage_blurpostprocess.x = 0;
2152                                 damage_blurpostprocess.y = 0;
2153                                 damage_blurpostprocess.z = 0;
2154                         }
2155                 }
2156         }
2157
2158         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2159         float e2 = (autocvar_hud_powerup != 0);
2160         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2161         {
2162                 // enable or disable rendering types if they are used or not
2163                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2164                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2165
2166                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2167                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2168                 {
2169                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2170                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2171                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2172                         {
2173                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2174                                 old_blurradius = blurradius;
2175                                 old_bluralpha = bluralpha;
2176                         }
2177                 }
2178                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2179                 {
2180                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2181                         old_blurradius = 0;
2182                         old_bluralpha = 0;
2183                 }
2184
2185                 // edge detection postprocess handling done second (used by hud_powerup)
2186                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2187                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2188                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2189
2190                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2191
2192                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2193                 {
2194                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2195                         {
2196                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2197                                 old_sharpen_intensity = sharpen_intensity;
2198                         }
2199                 }
2200                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2201                 {
2202                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2203                         old_sharpen_intensity = 0;
2204                 }
2205
2206                 if(cvar("r_glsl_postprocess") == 0)
2207                         cvar_set("r_glsl_postprocess", "2");
2208         }
2209         else if(cvar("r_glsl_postprocess") == 2)
2210                 cvar_set("r_glsl_postprocess", "0");
2211
2212         /*if(gametype == MAPINFO_TYPE_CTF)
2213           {
2214           ctf_view();
2215           } else */
2216
2217         // draw 2D entities
2218         IL_EACH(g_drawables_2d, it.draw2d, it.draw2d(it));
2219         Draw_ShowNames_All();
2220         Debug_Draw();
2221
2222         scoreboard_active = Scoreboard_WouldDraw();
2223
2224         HUD_Draw(this); // this parameter for deep vehicle function
2225
2226         if(NextFrameCommand)
2227         {
2228                 localcmd("\n", NextFrameCommand, "\n");
2229                 NextFrameCommand = string_null;
2230         }
2231
2232         // we must do this check AFTER a frame was rendered, or it won't work
2233         if(cs_project_is_b0rked == 0)
2234         {
2235                 string w0, h0;
2236                 w0 = ftos(autocvar_vid_conwidth);
2237                 h0 = ftos(autocvar_vid_conheight);
2238                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2239                 //setproperty(VF_FOV, '90 90 0');
2240                 setproperty(VF_ORIGIN, '0 0 0');
2241                 setproperty(VF_ANGLES, '0 0 0');
2242                 setproperty(VF_PERSPECTIVE, 1);
2243                 makevectors('0 0 0');
2244                 vector v1, v2;
2245                 cvar_set("vid_conwidth", "800");
2246                 cvar_set("vid_conheight", "600");
2247                 v1 = cs_project(v_forward);
2248                 cvar_set("vid_conwidth", "640");
2249                 cvar_set("vid_conheight", "480");
2250                 v2 = cs_project(v_forward);
2251                 if(v1 == v2)
2252                         cs_project_is_b0rked = 1;
2253                 else
2254                         cs_project_is_b0rked = -1;
2255                 cvar_set("vid_conwidth", w0);
2256                 cvar_set("vid_conheight", h0);
2257         }
2258
2259         if(autocvar__hud_configure)
2260                 HUD_Panel_Mouse();
2261         else if (HUD_MinigameMenu_IsOpened() || active_minigame)
2262                 HUD_Minigame_Mouse();
2263         else if(QuickMenu_IsOpened())
2264                 QuickMenu_Mouse();
2265         else
2266                 HUD_Radar_Mouse();
2267
2268         cl_notice_run();
2269         unpause_update();
2270         Net_Flush();
2271
2272         // let's reset the view back to normal for the end
2273         setproperty(VF_MIN, '0 0 0');
2274         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2275
2276         IL_ENDFRAME();
2277 }
2278
2279
2280 // following vectors must be global to allow seamless switching between camera modes
2281 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2282 void CSQC_Demo_Camera()
2283 {
2284         float speed, attenuation, dimensions;
2285         vector tmp, delta;
2286
2287         if( autocvar_camera_reset || !camera_mode )
2288         {
2289                 camera_offset = '0 0 0';
2290                 current_angles = '0 0 0';
2291                 camera_direction = '0 0 0';
2292                 camera_offset.z += 30;
2293                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2294                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2295                 current_origin = view_origin;
2296                 current_camera_offset  = camera_offset;
2297                 cvar_set("camera_reset", "0");
2298                 camera_mode = CAMERA_CHASE;
2299         }
2300
2301         // Camera angles
2302         if( camera_roll )
2303                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2304
2305         if(autocvar_camera_look_player)
2306         {
2307                 vector dir;
2308                 float n;
2309
2310                 dir = normalize(view_origin - current_position);
2311                 n = mouse_angles.z;
2312                 mouse_angles = vectoangles(dir);
2313                 mouse_angles.x = mouse_angles.x * -1;
2314                 mouse_angles.z = n;
2315         }
2316         else
2317         {
2318                 tmp = getmousepos() * 0.1;
2319                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2320                 {
2321                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2322                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2323                 }
2324         }
2325
2326         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2327         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2328         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2329         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2330
2331         // Fix difference when angles don't have the same sign
2332         delta = '0 0 0';
2333         if(mouse_angles.y < -60 && current_angles.y > 60)
2334                 delta = '0 360 0';
2335         if(mouse_angles.y > 60 && current_angles.y < -60)
2336                 delta = '0 -360 0';
2337
2338         if(autocvar_camera_look_player)
2339                 attenuation = autocvar_camera_look_attenuation;
2340         else
2341                 attenuation = autocvar_camera_speed_attenuation;
2342
2343         attenuation = 1 / max(1, attenuation);
2344         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2345
2346         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2347         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2348         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2349         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2350
2351         // Camera position
2352         tmp = '0 0 0';
2353         dimensions = 0;
2354
2355         if( camera_direction.x )
2356         {
2357                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2358                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2359                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2360                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2361                 ++dimensions;
2362         }
2363
2364         if( camera_direction.y )
2365         {
2366                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2367                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2368                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2369                 ++dimensions;
2370         }
2371
2372         if( camera_direction.z )
2373         {
2374                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2375                 ++dimensions;
2376         }
2377
2378         if(autocvar_camera_free)
2379                 speed = autocvar_camera_speed_free;
2380         else
2381                 speed = autocvar_camera_speed_chase;
2382
2383         if(dimensions)
2384         {
2385                 speed = speed * sqrt(1 / dimensions);
2386                 camera_offset += tmp * speed;
2387         }
2388
2389         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2390
2391         // Camera modes
2392         if( autocvar_camera_free )
2393         {
2394                 if ( camera_mode == CAMERA_CHASE )
2395                 {
2396                         current_camera_offset = current_origin + current_camera_offset;
2397                         camera_offset = current_origin + camera_offset;
2398                 }
2399
2400                 camera_mode = CAMERA_FREE;
2401                 current_position = current_camera_offset;
2402         }
2403         else
2404         {
2405                 if ( camera_mode == CAMERA_FREE )
2406                 {
2407                         current_origin = view_origin;
2408                         camera_offset = camera_offset - current_origin;
2409                         current_camera_offset = current_camera_offset - current_origin;
2410                 }
2411
2412                 camera_mode = CAMERA_CHASE;
2413
2414                 if(autocvar_camera_chase_smoothly)
2415                         current_origin += (view_origin - current_origin) * attenuation;
2416                 else
2417                         current_origin = view_origin;
2418
2419                 current_position = current_origin + current_camera_offset;
2420         }
2421
2422         setproperty(VF_ANGLES, current_angles);
2423         setproperty(VF_ORIGIN, current_position);
2424 }