qcsrc/client/view.qc

   1 #include "view.qh"
   2
   3 #include "autocvars.qh"
   4 #include "miscfunctions.qh"
   5 #include "announcer.qh"
   6 #include "hud/_mod.qh"
   7 #include "mapvoting.qh"
   8 #include "shownames.qh"
   9 #include "hud/panel/scoreboard.qh"
  10 #include "hud/panel/quickmenu.qh"
  11
  12 #include <client/mutators/_mod.qh>
  13
  14 #include <common/animdecide.qh>
  15 #include <common/deathtypes/all.qh>
  16 #include <common/ent_cs.qh>
  17 #include <common/anim.qh>
  18 #include <common/constants.qh>
  19 #include <common/net_linked.qh>
  20 #include <common/net_notice.qh>
  21 #include <common/debug.qh>
  22 #include <common/mapinfo.qh>
  23 #include <common/gamemodes/_mod.qh>
  24 #include <common/physics/player.qh>
  25 #include <common/stats.qh>
  26 #include <common/mapobjects/target/music.qh>
  27 #include <common/teams.qh>
  28 #include <common/wepent.qh>
  29
  30 #include <common/weapons/weapon/tuba.qh>
  31
  32 #include <common/vehicles/all.qh>
  33 #include <common/weapons/_all.qh>
  34 #include <common/mutators/mutator/overkill/oknex.qh>
  35 #include <common/mutators/mutator/waypoints/all.qh>
  36 #include <common/viewloc.qh>
  37 #include <common/mapobjects/trigger/viewloc.qh>
  38 #include <common/minigames/cl_minigames.qh>
  39 #include <common/minigames/cl_minigames_hud.qh>
  40
  41 #include <lib/csqcmodel/cl_player.qh>
  42 #include <lib/csqcmodel/cl_model.qh>
  43 #include "csqcmodel_hooks.qh"
  44
  45 #include <lib/warpzone/client.qh>
  46 #include <lib/warpzone/common.qh>
  47
  48 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
  49
  50 float autocvar_cl_viewmodel_scale;
  51 float autocvar_cl_viewmodel_alpha = 1;
  52
  53 bool autocvar_cl_bobmodel;
  54 float autocvar_cl_bobmodel_speed;
  55 float autocvar_cl_bobmodel_side;
  56 float autocvar_cl_bobmodel_up;
  57
  58 float autocvar_cl_followmodel;
  59 float autocvar_cl_followmodel_speed = 0.3;
  60 float autocvar_cl_followmodel_limit = 135;
  61 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
  62 float autocvar_cl_followmodel_highpass = 0.05;
  63 float autocvar_cl_followmodel_lowpass = 0.03;
  64 bool autocvar_cl_followmodel_velocity_absolute;
  65
  66 float autocvar_cl_leanmodel;
  67 float autocvar_cl_leanmodel_speed = 0.3;
  68 float autocvar_cl_leanmodel_limit = 30;
  69 float autocvar_cl_leanmodel_highpass1 = 0.2;
  70 float autocvar_cl_leanmodel_highpass = 0.2;
  71 float autocvar_cl_leanmodel_lowpass = 0.05;
  72
  73 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
  74
  75 #define lowpass(value, frac, ref_store, ret) \
  76         ret = ref_store = ref_store * (1 - frac) + (value) * frac;
  77
  78 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  79         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  80         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  81 MACRO_END
  82
  83 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
  84         float __f = 0; lowpass(value, frac, ref_store, __f); \
  85         ret = (value) - __f; \
  86 MACRO_END
  87
  88 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  89         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
  90         ret = (value) - __f; \
  91 MACRO_END
  92
  93 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  94         lowpass(value.x, frac, ref_store.x, ref_out.x); \
  95         lowpass(value.y, frac, ref_store.y, ref_out.y); \
  96 MACRO_END
  97
  98 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  99         highpass(value.x, frac, ref_store.x, ref_out.x); \
 100         highpass(value.y, frac, ref_store.y, ref_out.y); \
 101 MACRO_END
 102
 103 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
 104         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
 105         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
 106 MACRO_END
 107
 108 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 109         lowpass(value.x, frac, ref_store.x, ref_out.x); \
 110         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 111         lowpass(value.z, frac, ref_store.z, ref_out.z); \
 112 MACRO_END
 113
 114 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 115         highpass(value.x, frac, ref_store.x, ref_out.x); \
 116         highpass(value.y, frac, ref_store.y, ref_out.y); \
 117         highpass(value.z, frac, ref_store.z, ref_out.z); \
 118 MACRO_END
 119
 120 void calc_followmodel_ofs(entity view)
 121 {
 122         if(cl_followmodel_time == time)
 123                 return; // cl_followmodel_ofs already calculated for this frame
 124
 125         float frac;
 126         vector gunorg = '0 0 0';
 127         static vector vel_average;
 128         static vector gunorg_adjustment_highpass;
 129         static vector gunorg_adjustment_lowpass;
 130
 131         vector vel;
 132         if (autocvar_cl_followmodel_velocity_absolute)
 133                 vel = view.velocity;
 134         else
 135         {
 136                 vector forward, right, up;
 137                 MAKE_VECTORS(view_angles, forward, right, up);
 138                 vel.x = view.velocity * forward;
 139                 vel.y = view.velocity * right * -1;
 140                 vel.z = view.velocity * up;
 141         }
 142
 143         vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
 144         vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
 145         vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
 146
 147         frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
 148         lowpass3(vel, frac, vel_average, gunorg);
 149
 150         gunorg *= -autocvar_cl_followmodel_speed * 0.042;
 151
 152         // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 153         // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 154         frac = avg_factor(autocvar_cl_followmodel_highpass);
 155         highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
 156         frac = avg_factor(autocvar_cl_followmodel_lowpass);
 157         lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
 158
 159         if (autocvar_cl_followmodel_velocity_absolute)
 160         {
 161                 vector fixed_gunorg;
 162                 vector forward, right, up;
 163                 MAKE_VECTORS(view_angles, forward, right, up);
 164                 fixed_gunorg.x = gunorg * forward;
 165                 fixed_gunorg.y = gunorg * right * -1;
 166                 fixed_gunorg.z = gunorg * up;
 167                 gunorg = fixed_gunorg;
 168         }
 169
 170         cl_followmodel_ofs = gunorg;
 171         cl_followmodel_time = time;
 172 }
 173
 174 vector leanmodel_ofs(entity view)
 175 {
 176         float frac;
 177         vector gunangles = '0 0 0';
 178         static vector gunangles_prev = '0 0 0';
 179         static vector gunangles_highpass = '0 0 0';
 180         static vector gunangles_adjustment_highpass;
 181         static vector gunangles_adjustment_lowpass;
 182
 183         if (view.csqcmodel_teleported)
 184                 gunangles_prev = view_angles;
 185
 186         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 187         gunangles_highpass += gunangles_prev;
 188         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 189         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 190         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 191         frac = avg_factor(autocvar_cl_leanmodel_highpass1);
 192         highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
 193         gunangles_prev = view_angles;
 194         gunangles_highpass -= gunangles_prev;
 195
 196         PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
 197         YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
 198
 199         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 200         frac = avg_factor(autocvar_cl_leanmodel_highpass);
 201         highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
 202         frac = avg_factor(autocvar_cl_leanmodel_lowpass);
 203         lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
 204
 205         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 206
 207         return gunangles;
 208 }
 209
 210 vector bobmodel_ofs(entity view)
 211 {
 212         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 213         static bool oldonground;
 214         static float hitgroundtime;
 215         if (clonground)
 216         {
 217                 float f = time; // cl.movecmd[0].time
 218                 if (!oldonground)
 219                         hitgroundtime = f;
 220         }
 221         oldonground = clonground;
 222
 223         // calculate for swinging gun model
 224         // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 225         vector gunorg = '0 0 0';
 226         static float bobmodel_scale = 0;
 227         static float time_ofs = 0; // makes the effect always restart in the same way
 228         if (clonground)
 229         {
 230                 if (time - hitgroundtime > 0.05)
 231                         bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
 232         }
 233         else
 234                 bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
 235
 236         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 237         if (bobmodel_scale && xyspeed)
 238         {
 239                 float bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
 240                 float s = (time - time_ofs) * autocvar_cl_bobmodel_speed;
 241                 gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
 242                 gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
 243         }
 244         else
 245                 time_ofs = time;
 246
 247         return gunorg;
 248 }
 249
 250 void viewmodel_animate(entity this)
 251 {
 252         if (autocvar_chase_active) return;
 253         if (STAT(HEALTH) <= 0) return;
 254
 255         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 256
 257         if (autocvar_cl_followmodel)
 258         {
 259                 calc_followmodel_ofs(view);
 260                 this.origin += cl_followmodel_ofs;
 261         }
 262
 263         if (autocvar_cl_leanmodel)
 264                 this.angles += leanmodel_ofs(view);
 265
 266         // vertical view bobbing code
 267         // TODO: cl_bob
 268
 269         // horizontal view bobbing code
 270         // TODO: cl_bob2
 271
 272         // fall bobbing code
 273         // causes the view to swing down and back up when touching the ground
 274         // TODO: cl_bobfall
 275
 276         // gun model bobbing code
 277         if (autocvar_cl_bobmodel)
 278                 this.origin += bobmodel_ofs(view);
 279 }
 280
 281 .vector viewmodel_origin, viewmodel_angles;
 282 .float weapon_nextthink;
 283 .float weapon_eta_last;
 284 .float weapon_switchdelay;
 285
 286 .string name_last;
 287
 288 void viewmodel_draw(entity this)
 289 {
 290         if(!this.activeweapon || !autocvar_r_drawviewmodel)
 291                 return;
 292         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 293         float a = ((autocvar_cl_viewmodel_alpha) ? bound(-1, autocvar_cl_viewmodel_alpha, this.m_alpha) : this.m_alpha);
 294         int wepskin = this.m_skin;
 295         bool invehicle = player_localentnum > maxclients;
 296         if (invehicle) a = -1;
 297         Weapon wep = this.activeweapon;
 298         int c = entcs_GetClientColors(current_player);
 299         vector g = weaponentity_glowmod(wep, NULL, c, this);
 300         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 301         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 302                 | EF_NODEPTHTEST)
 303                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 304         for (entity e = this; e; e = e.weaponchild)
 305         {
 306                 e.drawmask = mask;
 307                 e.alpha = a;
 308                 e.skin = wepskin;
 309                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 310                 e.glowmod = g;
 311                 e.csqcmodel_effects = fx;
 312                 CSQCModel_Effects_Apply(e);
 313         }
 314         if(a >= 0)
 315         {
 316                 string name = wep.mdl;
 317                 string newname = wep.wr_viewmodel(wep, this);
 318                 if(newname)
 319                         name = newname;
 320                 bool swap = name != this.name_last;
 321                 // if (swap)
 322                 {
 323                         this.name_last = name;
 324                         CL_WeaponEntity_SetModel(this, name, swap);
 325                         this.viewmodel_origin = this.origin;
 326                         this.viewmodel_angles = this.angles;
 327                 }
 328                 anim_update(this);
 329                 if ((!this.animstate_override && !this.animstate_looping) || time > this.animstate_endtime)
 330                         anim_set(this, this.anim_idle, true, false, false);
 331         }
 332         float f = 0; // 0..1; 0: fully active
 333         float rate = STAT(WEAPONRATEFACTOR);
 334         float eta = rate ? ((this.weapon_nextthink - time) / rate) : 0;
 335         if (eta <= 0) f = this.weapon_eta_last;
 336         else switch (this.state)
 337         {
 338                 case WS_RAISE:
 339                 {
 340                         f = eta / max(eta, this.weapon_switchdelay);
 341                         break;
 342                 }
 343                 case WS_DROP:
 344                 {
 345                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 346                         break;
 347                 }
 348                 case WS_CLEAR:
 349                 {
 350                         f = 1;
 351                         break;
 352                 }
 353         }
 354         this.weapon_eta_last = f;
 355         this.origin = this.viewmodel_origin;
 356         this.angles = this.viewmodel_angles;
 357         this.angles_x = (-90 * f * f);
 358         viewmodel_animate(this);
 359         MUTATOR_CALLHOOK(DrawViewModel, this);
 360         setorigin(this, this.origin);
 361 }
 362
 363 STATIC_INIT(viewmodel) {
 364     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 365         viewmodels[slot] = new(viewmodel);
 366 }
 367
 368 float showfps_prevfps;
 369 float showfps_prevfps_time;
 370 int showfps_framecounter;
 371
 372 void fpscounter_update()
 373 {
 374         if(!STAT(SHOWFPS))
 375                 return;
 376
 377         float currentTime = gettime(GETTIME_REALTIME);
 378         showfps_framecounter += 1;
 379         if(currentTime - showfps_prevfps_time > STAT(SHOWFPS))
 380         {
 381                 showfps_prevfps = showfps_framecounter/(currentTime - showfps_prevfps_time);
 382                 showfps_framecounter = 0;
 383                 showfps_prevfps_time = currentTime;
 384
 385                 int channel = MSG_C2S;
 386                 WriteHeader(channel, fpsreport);
 387                 WriteShort(channel, bound(0, rint(showfps_prevfps), 65535)); // prevent insane fps values
 388         }
 389 }
 390
 391 STATIC_INIT(fpscounter_init)
 392 {
 393         float currentTime = gettime(GETTIME_REALTIME);
 394         showfps_prevfps_time = currentTime; // we must initialize it to avoid an instant low frame sending
 395 }
 396
 397 float avgspeed;
 398 vector GetCurrentFov(float fov)
 399 {
 400         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 401         float velocityzoom, curspeed;
 402         vector v;
 403
 404         zoomsensitivity = autocvar_cl_zoomsensitivity;
 405         zoomfactor = autocvar_cl_zoomfactor;
 406         if(zoomfactor < 1 || zoomfactor > 30)
 407                 zoomfactor = 2.5;
 408         zoomspeed = autocvar_cl_zoomspeed;
 409         if (zoomspeed >= 0 && (zoomspeed < 0.5 || zoomspeed > 16))
 410                 zoomspeed = 3.5;
 411
 412         zoomdir = button_zoom;
 413
 414         if(hud == HUD_NORMAL && !spectatee_status)
 415         {
 416                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 417                 {
 418                         entity wepent = viewmodels[slot];
 419                         if(wepent.switchweapon != wepent.activeweapon)
 420                                 continue;
 421                         Weapon wep = wepent.activeweapon;
 422                         if(wep != WEP_Null && wep.wr_zoomdir)
 423                         {
 424                                 bool do_zoom = wep.wr_zoomdir(wep); // TODO: merge this with wr_zoom?
 425                                 zoomdir += do_zoom;
 426                         }
 427                 }
 428         }
 429         if(spectatee_status > 0 || isdemo())
 430         {
 431                 if(spectatorbutton_zoom)
 432                 {
 433                         if(zoomdir)
 434                                 zoomdir = 0;
 435                         else
 436                                 zoomdir = 1;
 437                 }
 438                 // fteqcc failed twice here already, don't optimize this
 439         }
 440
 441         if(zoomdir) { zoomin_effect = 0; }
 442
 443         if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
 444         {
 445                 current_viewzoom = 1;
 446         }
 447         else if (camera_active)
 448         {
 449                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 450         }
 451         else if(autocvar_cl_spawnzoom && zoomin_effect)
 452         {
 453                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 454
 455                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 456                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 457                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 458         }
 459         else
 460         {
 461                 if(zoomspeed < 0) // instant zoom
 462                 {
 463                         if(zoomdir)
 464                                 current_viewzoom = 1 / zoomfactor;
 465                         else
 466                                 current_viewzoom = 1;
 467                 }
 468                 else
 469                 {
 470                         if(zoomdir)
 471                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 472                         else
 473                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 474                 }
 475         }
 476
 477         if(almost_equals(current_viewzoom, 1))
 478                 current_zoomfraction = 0;
 479         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 480                 current_zoomfraction = 1;
 481         else
 482                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 483
 484         if(zoomsensitivity < 1)
 485                 setsensitivityscale(current_viewzoom ** (1 - zoomsensitivity));
 486         else
 487                 setsensitivityscale(1);
 488
 489         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type && !autocvar_cl_lockview) // _type = 0 disables velocity zoom too
 490         {
 491                 if (intermission || (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2))
 492                         curspeed = 0;
 493                 else
 494                 {
 495                         vector forward, right, up;
 496                         MAKE_VECTORS(view_angles, forward, right, up);
 497                         v = pmove_vel;
 498                         if(csqcplayer)
 499                                 v = csqcplayer.velocity;
 500
 501                         switch(autocvar_cl_velocityzoom_type)
 502                         {
 503                                 case 3: curspeed = max(0, forward * v); break;
 504                                 case 2: curspeed = (forward * v); break;
 505                                 case 1: default: curspeed = vlen(v); break;
 506                         }
 507                 }
 508
 509                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 510                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 511                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 512
 513                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 514         }
 515         else
 516                 velocityzoom = 1;
 517
 518         float frustumx, frustumy, fovx, fovy;
 519         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 520         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 521         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 522         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 523
 524         return '1 0 0' * fovx + '0 1 0' * fovy;
 525 }
 526
 527 vector GetViewLocationFOV(float fov)
 528 {
 529         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 530         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 531         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 532         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 533         return '1 0 0' * fovx + '0 1 0' * fovy;
 534 }
 535
 536 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 537 {
 538         float fovx, fovy;
 539         float width = (ov_worldmax.x - ov_worldmin.x);
 540         float height = (ov_worldmax.y - ov_worldmin.y);
 541         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 542         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 543         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 544         return '1 0 0' * fovx + '0 1 0' * fovy;
 545 }
 546
 547 // this function must match W_SetupShot!
 548 float zoomscript_caught;
 549
 550 bool minigame_wasactive;
 551
 552 vector wcross_origin;
 553 float wcross_scale_prev, wcross_alpha_prev;
 554 vector wcross_color_prev;
 555 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 556 vector wcross_color_goal_prev;
 557 float wcross_changedonetime;
 558
 559 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 560 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 561 float wcross_name_changestarttime, wcross_name_changedonetime;
 562 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 563
 564 float wcross_ring_prev;
 565
 566 entity trueaim;
 567 entity trueaim_rifle;
 568
 569 const float SHOTTYPE_HITTEAM = 1;
 570 const float SHOTTYPE_HITOBSTRUCTION = 2;
 571 const float SHOTTYPE_HITWORLD = 3;
 572 const float SHOTTYPE_HITENEMY = 4;
 573
 574 void TrueAim_Init()
 575 {
 576         (trueaim = new_pure(trueaim)).dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 577         (trueaim_rifle = new_pure(trueaim_rifle)).dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 578 }
 579
 580 float EnemyHitCheck()
 581 {
 582         float t, n;
 583         wcross_origin = project_3d_to_2d(trace_endpos);
 584         wcross_origin.z = 0;
 585         if(trace_ent)
 586                 n = trace_ent.entnum;
 587         else
 588                 n = trace_networkentity;
 589         if(n < 1)
 590                 return SHOTTYPE_HITWORLD;
 591         if(n > maxclients)
 592                 return SHOTTYPE_HITWORLD;
 593         t = entcs_GetTeam(n - 1);
 594         if(teamplay)
 595                 if(t == myteam)
 596                         return SHOTTYPE_HITTEAM;
 597         if(t == NUM_SPECTATOR)
 598                 return SHOTTYPE_HITWORLD;
 599         return SHOTTYPE_HITENEMY;
 600 }
 601
 602 float TrueAimCheck(entity wepent)
 603 {
 604         if(wepent.activeweapon.spawnflags & WEP_FLAG_NOTRUEAIM)
 605                 return SHOTTYPE_HITWORLD;
 606
 607         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 608         vector vecs, trueaimpoint, w_shotorg;
 609         vector mi, ma, dv;
 610         float shottype;
 611         entity ta;
 612         float mv;
 613
 614         mi = ma = '0 0 0';
 615         ta = trueaim;
 616         mv = MOVE_NOMONSTERS;
 617
 618         switch(wepent.activeweapon) // WEAPONTODO
 619         {
 620                 case WEP_VORTEX:
 621                 case WEP_OVERKILL_NEX:
 622                 case WEP_VAPORIZER:
 623                         mv = MOVE_NORMAL;
 624                         break;
 625                 case WEP_RIFLE:
 626                         ta = trueaim_rifle;
 627                         mv = MOVE_NORMAL;
 628                         if(zoomscript_caught)
 629                         {
 630                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * max_shot_distance, mv, ta);
 631                                 return EnemyHitCheck();
 632                         }
 633                         break;
 634                 case WEP_DEVASTATOR: // projectile has a size!
 635                         mi = '-3 -3 -3';
 636                         ma = '3 3 3';
 637                         break;
 638                 case WEP_FIREBALL: // projectile has a size!
 639                         mi = '-16 -16 -16';
 640                         ma = '16 16 16';
 641                         break;
 642                 case WEP_SEEKER: // projectile has a size!
 643                         mi = '-2 -2 -2';
 644                         ma = '2 2 2';
 645                         break;
 646                 case WEP_ELECTRO: // projectile has a size!
 647                         mi = '0 0 -3';
 648                         ma = '0 0 -3';
 649                         break;
 650         }
 651
 652         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
 653
 654         vecs = decompressShotOrigin(STAT(SHOTORG));
 655
 656         traceline(traceorigin, traceorigin + view_forward * max_shot_distance, mv, ta);
 657         trueaimpoint = trace_endpos;
 658         // move trueaimpoint a little bit forward to make the final tracebox reliable
 659         // since it sometimes doesn't reach a teammate by a hair
 660         trueaimpoint += view_forward;
 661
 662         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
 663                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 664
 665         if(vecs.x > 0)
 666                 vecs.y = -vecs.y;
 667         else
 668                 vecs = '0 0 0';
 669
 670         dv = view_right * vecs.y + view_up * vecs.z;
 671         w_shotorg = traceorigin + dv;
 672
 673         // now move the vecs forward as much as requested if possible
 674         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 675         w_shotorg = trace_endpos - view_forward * nudge;
 676
 677         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 678         shottype = EnemyHitCheck();
 679         if(shottype != SHOTTYPE_HITWORLD)
 680                 return shottype;
 681
 682 #if 0
 683         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 684         // or rather, I know why, but see no fix
 685         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 686                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 687                 return SHOTTYPE_HITOBSTRUCTION;
 688 #endif
 689
 690         return SHOTTYPE_HITWORLD;
 691 }
 692
 693 float camera_mode;
 694 const float CAMERA_FREE = 1;
 695 const float CAMERA_CHASE = 2;
 696 float reticle_type;
 697 string NextFrameCommand;
 698
 699 vector freeze_org, freeze_ang;
 700 entity nightvision_noise, nightvision_noise2;
 701
 702 const float MAX_TIME_DIFF = 5;
 703 float pickup_crosshair_time, pickup_crosshair_size;
 704 float hitindication_crosshair_size;
 705 float use_vortex_chargepool;
 706
 707 float myhealth, myhealth_prev;
 708 float myhealth_flash;
 709
 710 float old_blurradius, old_bluralpha;
 711 float old_sharpen_intensity;
 712
 713 vector myhealth_gentlergb;
 714
 715 float contentavgalpha, liquidalpha_prev;
 716 vector liquidcolor_prev;
 717
 718 float eventchase_current_distance;
 719 float eventchase_running;
 720 int WantEventchase(entity this, bool want_vehiclechase)
 721 {
 722         if(autocvar_cl_orthoview)
 723                 return 0;
 724         if(STAT(GAME_STOPPED) || intermission)
 725                 return 1;
 726         if(this.viewloc)
 727                 return 1;
 728         if(spectatee_status >= 0)
 729         {
 730                 if(want_vehiclechase)
 731                         return 1;
 732                 if(MUTATOR_CALLHOOK(WantEventchase, this))
 733                         return 1;
 734                 if(autocvar_cl_eventchase_frozen && STAT(FROZEN))
 735                         return 1;
 736                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
 737                 {
 738                         if(autocvar_cl_eventchase_death == 2)
 739                         {
 740                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 741                                 if(this.velocity == '0 0 0' || eventchase_running)
 742                                         return 1;
 743                         }
 744                         else return 1;
 745                 }
 746                 if (spectatee_status > 0 && autocvar_cl_eventchase_spectated_change)
 747                 {
 748                         if (time <= spectatee_status_changed_time + min(3, autocvar_cl_eventchase_spectated_change_time))
 749                                 return 1;
 750                         else if (eventchase_running)
 751                                 return -1; // disable chase_active while eventchase is still enabled so to avoid a glicth
 752                 }
 753         }
 754         return 0;
 755 }
 756
 757 void View_EventChase(entity this)
 758 {
 759         // event chase camera
 760         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 761         {
 762                 if(STAT(CAMERA_SPECTATOR))
 763                 {
 764                         if(spectatee_status > 0)
 765                         {
 766                                 if(!autocvar_chase_active)
 767                                 {
 768                                         cvar_set("chase_active", "-2");
 769                                         return;
 770                                 }
 771                         }
 772                         else if(autocvar_chase_active == -2)
 773                                 cvar_set("chase_active", "0");
 774
 775                         if(autocvar_chase_active == -2)
 776                                 return;
 777                 }
 778                 else if(autocvar_chase_active == -2)
 779                         cvar_set("chase_active", "0");
 780
 781                 bool vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
 782
 783                 float vehicle_viewdist = 0;
 784                 vector vehicle_viewofs = '0 0 0';
 785
 786                 if(vehicle_chase)
 787                 {
 788                         if(hud != HUD_BUMBLEBEE_GUN)
 789                         {
 790                                 Vehicle info = REGISTRY_GET(Vehicles, hud);
 791                                 vehicle_viewdist = info.height;
 792                                 vehicle_viewofs = info.view_ofs;
 793                                 if(vehicle_viewdist < 0) // when set below 0, this vehicle doesn't use third person view (gunner slots)
 794                                         vehicle_chase = false;
 795                         }
 796                         else
 797                                 vehicle_chase = false;
 798                 }
 799
 800                 int eventchase = WantEventchase(this, vehicle_chase);
 801                 if (eventchase)
 802                 {
 803                         vector current_view_origin_override = '0 0 0';
 804                         vector view_offset_override = '0 0 0';
 805                         float chase_distance_override = 0;
 806                         bool custom_eventchase = MUTATOR_CALLHOOK(CustomizeEventchase, this);
 807                         if(custom_eventchase)
 808                         {
 809                                 current_view_origin_override = M_ARGV(0, vector);
 810                                 view_offset_override = M_ARGV(1, vector);
 811                                 chase_distance_override = M_ARGV(0, float);
 812                         }
 813                         eventchase_running = true;
 814
 815                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
 816                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
 817                         if (custom_eventchase)
 818                                 current_view_origin = current_view_origin_override;
 819
 820                         // detect maximum viewoffset and use it
 821                         vector view_offset = autocvar_cl_eventchase_viewoffset;
 822                         if(vehicle_chase)
 823                         {
 824                                 if(vehicle_viewofs)
 825                                         view_offset = vehicle_viewofs;
 826                                 else
 827                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
 828                         }
 829                         if (custom_eventchase)
 830                                 view_offset = view_offset_override;
 831
 832                         if(view_offset)
 833                         {
 834                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, this);
 835                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
 836                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
 837                         }
 838
 839                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 840                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
 841                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 842                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
 843
 844                         // make the camera smooth back
 845                         float chase_distance = autocvar_cl_eventchase_distance;
 846                         if(vehicle_chase)
 847                         {
 848                                 if(vehicle_viewofs)
 849                                         chase_distance = vehicle_viewdist;
 850                                 else
 851                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
 852                         }
 853                         if (custom_eventchase)
 854                                 chase_distance = chase_distance_override;
 855
 856                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
 857                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 858                         else if(eventchase_current_distance != chase_distance)
 859                                 eventchase_current_distance = chase_distance;
 860
 861                         vector forward, right, up;
 862                         MAKE_VECTORS(view_angles, forward, right, up);
 863
 864                         vector eventchase_target_origin = (current_view_origin - (forward * eventchase_current_distance));
 865                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, this);
 866
 867                         // If the boxtrace fails, revert back to line tracing.
 868                         if(!this.viewloc)
 869                         if(trace_startsolid)
 870                         {
 871                                 eventchase_target_origin = (current_view_origin - (forward * eventchase_current_distance));
 872                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, this);
 873                                 setproperty(VF_ORIGIN, (trace_endpos - (forward * autocvar_cl_eventchase_mins.z)));
 874                         }
 875                         else { setproperty(VF_ORIGIN, trace_endpos); }
 876
 877                         if(!this.viewloc)
 878                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
 879                 }
 880
 881                 if (eventchase <= 0 && autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 882                 {
 883                         eventchase_running = false;
 884                         cvar_set("chase_active", "0");
 885                         eventchase_current_distance = 0; // start from 0 next time
 886                 }
 887         }
 888         // workaround for camera stuck between player's legs when using chase_active 1
 889         // because the engine stops updating the chase_active camera when the game ends
 890         else if(intermission)
 891         {
 892                 cvar_settemp("chase_active", "-1");
 893                 eventchase_current_distance = 0;
 894         }
 895 }
 896
 897 void HUD_Crosshair_Vehicle(entity this)
 898 {
 899         if(hud != HUD_BUMBLEBEE_GUN)
 900         {
 901                 Vehicle info = REGISTRY_GET(Vehicles, hud);
 902                 info.vr_crosshair(info, this);
 903         }
 904 }
 905
 906 vector damage_blurpostprocess, content_blurpostprocess;
 907
 908 float unaccounted_damage = 0;
 909 void UpdateDamage()
 910 {
 911         // accumulate damage with each stat update
 912         static float damage_total_prev = 0;
 913         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 914         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 915         damage_total_prev = damage_total;
 916
 917         static float damage_dealt_time_prev = 0;
 918         float damage_dealt_time = STAT(HIT_TIME);
 919         if (damage_dealt_time != damage_dealt_time_prev)
 920         {
 921                 unaccounted_damage += unaccounted_damage_new;
 922                 //LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")");
 923         }
 924         damage_dealt_time_prev = damage_dealt_time;
 925
 926         // prevent hitsound when switching spectatee
 927         static float spectatee_status_prev = 0;
 928         if (spectatee_status != spectatee_status_prev)
 929                 unaccounted_damage = 0;
 930         spectatee_status_prev = spectatee_status;
 931 }
 932
 933 void HitSound()
 934 {
 935         // varying sound pitch
 936
 937         bool have_arc = false;
 938         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 939         {
 940                 entity wepent = viewmodels[slot];
 941
 942                 if(wepent.activeweapon == WEP_ARC)
 943                         have_arc = true;
 944         }
 945
 946         static float hitsound_time_prev = 0;
 947         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 948         bool arc_hack = have_arc && autocvar_cl_hitsound >= 2;
 949         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 950         {
 951                 if (autocvar_cl_hitsound && unaccounted_damage)
 952                 {
 953                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 954                         float a = autocvar_cl_hitsound_max_pitch;
 955                         float b = autocvar_cl_hitsound_min_pitch;
 956                         float c = autocvar_cl_hitsound_nom_damage;
 957                         float d = unaccounted_damage;
 958                         float pitch_shift = (b*d*(a-1) + a*c*(1-b)) / (d*(a-1) + c*(1-b));
 959
 960                         // if sound variation is disabled, set pitch_shift to 1
 961                         if (autocvar_cl_hitsound == 1)
 962                                 pitch_shift = 1;
 963
 964                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 965                         if (autocvar_cl_hitsound == 3)
 966                         {
 967                                 float mirror_value = (a-b)/2 + b;
 968                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 969                         }
 970
 971                         //LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift));
 972
 973                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 974                         // todo: normalize sound pressure levels? seems unnecessary
 975
 976                         sound7(NULL, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 977                 }
 978                 unaccounted_damage = 0;
 979                 hitsound_time_prev = time;
 980         }
 981
 982         static float typehit_time_prev = 0;
 983         float typehit_time = STAT(TYPEHIT_TIME);
 984         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 985         {
 986                 sound(NULL, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 987                 typehit_time_prev = typehit_time;
 988         }
 989
 990         static float kill_time_prev = 0;
 991         float kill_time = STAT(KILL_TIME);
 992         if (COMPARE_INCREASING(kill_time, kill_time_prev) > autocvar_cl_hitsound_antispam_time)
 993         {
 994                 sound(NULL, CH_INFO, SND_KILL, VOL_BASE, ATTN_NONE);
 995                 kill_time_prev = kill_time;
 996         }
 997 }
 998
 999 vector crosshair_getcolor(entity this, float health_stat)
1000 {
1001         static float rainbow_last_flicker;
1002         static vector rainbow_prev_color;
1003         vector wcross_color = '0 0 0';
1004         switch(autocvar_crosshair_color_special)
1005         {
1006                 case 1: // weapon color
1007                 {
1008                         if(this != WEP_Null && hud == HUD_NORMAL)
1009                         {
1010                                 wcross_color = this.wpcolor;
1011                                 break;
1012                         }
1013                         else { goto normalcolor; }
1014                 }
1015
1016                 case 2: // color based on health and armor
1017                 {
1018                         vector v = healtharmor_maxdamage(health_stat, STAT(ARMOR), armorblockpercent, DEATH_WEAPON.m_id);
1019                         float hp = floor(v.x + 1);
1020
1021                         //x = red
1022                         //y = green
1023                         //z = blue
1024
1025                         wcross_color.z = 0;
1026
1027                         if(hp > 200)
1028                         {
1029                                 wcross_color.x = 0;
1030                                 wcross_color.y = 1;
1031                         }
1032                         else if(hp > 150)
1033                         {
1034                                 wcross_color.x = 0.4 - (hp-150)*0.02 * 0.4;
1035                                 wcross_color.y = 0.9 + (hp-150)*0.02 * 0.1;
1036                         }
1037                         else if(hp > 100)
1038                         {
1039                                 wcross_color.x = 1 - (hp-100)*0.02 * 0.6;
1040                                 wcross_color.y = 1 - (hp-100)*0.02 * 0.1;
1041                                 wcross_color.z = 1 - (hp-100)*0.02;
1042                         }
1043                         else if(hp > 50)
1044                         {
1045                                 wcross_color.x = 1;
1046                                 wcross_color.y = 1;
1047                                 wcross_color.z = 0.2 + (hp-50)*0.02 * 0.8;
1048                         }
1049                         else if(hp > 20)
1050                         {
1051                                 wcross_color.x = 1;
1052                                 wcross_color.y = (hp-20)*90/27/100;
1053                                 wcross_color.z = (hp-20)*90/27/100 * 0.2;
1054                         }
1055                         else
1056                         {
1057                                 wcross_color.x = 1;
1058                                 wcross_color.y = 0;
1059                         }
1060                         break;
1061                 }
1062
1063                 case 3: // rainbow/random color
1064                 {
1065                         if(time >= rainbow_last_flicker)
1066                         {
1067                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
1068                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
1069                         }
1070                         wcross_color = rainbow_prev_color;
1071                         break;
1072                 }
1073 LABEL(normalcolor)
1074                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
1075         }
1076
1077         return wcross_color;
1078 }
1079
1080 void HUD_Crosshair(entity this)
1081 {
1082         // reset player's alpha here upon death since forced scoreboard prevents running the crosshair_chase code
1083         if(autocvar_chase_active > 0 && autocvar_crosshair_chase && STAT(HEALTH) <= 0 && csqcplayer)
1084                 csqcplayer.alpha = csqcplayer.m_alpha;
1085
1086         float f, i, j;
1087         vector v;
1088         if(!scoreboard_active && !camera_active && intermission != 2 && !STAT(GAME_STOPPED) && !autocvar_cl_lockview
1089                 && spectatee_status != -1 && (!csqcplayer.viewloc || (!spectatee_status && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM))) && !MUTATOR_CALLHOOK(DrawCrosshair)
1090                 && !HUD_MinigameMenu_IsOpened())
1091         {
1092                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
1093                         return;
1094
1095                 if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
1096                         return;
1097
1098                 if (hud != HUD_NORMAL)
1099                 {
1100                         HUD_Crosshair_Vehicle(this);
1101                         return;
1102                 }
1103
1104                 string wcross_style;
1105                 float wcross_alpha, wcross_resolution;
1106                 wcross_style = autocvar_crosshair;
1107                 if (csqcplayer.viewloc && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM) && autocvar_crosshair_2d != "")
1108                         wcross_style = autocvar_crosshair_2d;
1109                 if (wcross_style == "0")
1110                         return;
1111                 wcross_resolution = autocvar_crosshair_size;
1112                 if (wcross_resolution == 0)
1113                         return;
1114                 wcross_alpha = autocvar_crosshair_alpha;
1115                 if (wcross_alpha == 0)
1116                         return;
1117
1118                 // TrueAim check
1119                 float shottype;
1120
1121                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1122                 if(csqcplayer.viewloc && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM))
1123                         wcross_origin = viewloc_mousepos;
1124                 else if(autocvar_chase_active > 0 && autocvar_crosshair_chase)
1125                 {
1126                         vector player_org = ((csqcplayer) ? csqcplayer.origin + csqcplayer.view_ofs : view_origin);
1127                         if(csqcplayer && autocvar_crosshair_chase_playeralpha && autocvar_crosshair_chase_playeralpha < 1)
1128                         {
1129                                 traceline(view_origin, view_origin + max_shot_distance * view_forward, MOVE_NORMAL, NULL);
1130                                 float myalpha = (!csqcplayer.m_alpha) ? 1 : csqcplayer.m_alpha;
1131                                 if(trace_ent == csqcplayer)
1132                                         csqcplayer.alpha = min(autocvar_crosshair_chase_playeralpha, myalpha);
1133                                 else
1134                                         csqcplayer.alpha = csqcplayer.m_alpha;
1135                         }
1136                         traceline(player_org, player_org + max_shot_distance * view_forward, MOVE_WORLDONLY, NULL);
1137                         wcross_origin = project_3d_to_2d(trace_endpos);
1138                 }
1139                 else
1140                         wcross_origin = project_3d_to_2d(view_origin + max_shot_distance * view_forward);
1141                 wcross_origin.z = 0;
1142                 if(autocvar_crosshair_hittest)
1143                 {
1144                         vector wcross_oldorigin;
1145                         entity thiswep = viewmodels[0]; // TODO: unhardcode
1146                         wcross_oldorigin = wcross_origin;
1147                         shottype = TrueAimCheck(thiswep);
1148                         if(shottype == SHOTTYPE_HITWORLD)
1149                         {
1150                                 v = wcross_origin - wcross_oldorigin;
1151                                 v.x /= vid_conwidth;
1152                                 v.y /= vid_conheight;
1153                                 if(vdist(v, >, 0.01))
1154                                         shottype = SHOTTYPE_HITOBSTRUCTION;
1155                         }
1156                         if(!autocvar_crosshair_hittest_showimpact)
1157                                 wcross_origin = wcross_oldorigin;
1158                 }
1159                 else
1160                         shottype = SHOTTYPE_HITWORLD;
1161
1162                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1163                 string wcross_name = "";
1164                 float wcross_scale, wcross_blur;
1165
1166                 entity e = WEP_Null;
1167                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1168                 {
1169                         entity wepent = viewmodels[0]; // TODO: unhardcode
1170                         e = wepent.switchingweapon;
1171                         if(e)
1172                         {
1173                                 if(autocvar_crosshair_per_weapon)
1174                                 {
1175                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
1176                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1177                                         //if (wcross_resolution == 0)
1178                                                 //return;
1179
1180                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1181                                         wcross_resolution *= e.w_crosshair_size;
1182                                         wcross_name = e.w_crosshair;
1183                                 }
1184                         }
1185                 }
1186
1187                 if(wcross_name == "")
1188                         wcross_name = strcat("gfx/crosshair", wcross_style);
1189
1190                 // MAIN CROSSHAIR COLOR DECISION
1191                 wcross_color = crosshair_getcolor(e, STAT(HEALTH));
1192
1193                 if(autocvar_crosshair_effect_scalefade)
1194                 {
1195                         wcross_scale = wcross_resolution;
1196                         wcross_resolution = 1;
1197                 }
1198                 else
1199                 {
1200                         wcross_scale = 1;
1201                 }
1202
1203                 if(autocvar_crosshair_pickup)
1204                 {
1205                         float stat_pickup_time = STAT(LAST_PICKUP);
1206
1207                         if(pickup_crosshair_time < stat_pickup_time)
1208                         {
1209                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1210                                         pickup_crosshair_size = 1;
1211
1212                                 pickup_crosshair_time = stat_pickup_time;
1213                         }
1214
1215                         if(pickup_crosshair_size > 0)
1216                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1217                         else
1218                                 pickup_crosshair_size = 0;
1219
1220                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1221                 }
1222
1223                 // todo: make crosshair hit indication dependent on damage dealt
1224                 if(autocvar_crosshair_hitindication)
1225                 {
1226                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1227
1228                         if(unaccounted_damage)
1229                         {
1230                                 hitindication_crosshair_size = 1;
1231                         }
1232
1233                         if(hitindication_crosshair_size > 0)
1234                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1235                         else
1236                                 hitindication_crosshair_size = 0;
1237
1238                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1239                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1240                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1241                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1242                 }
1243
1244                 // no effects needed for targeting enemies, this can't possibly span all valid targets!
1245                 // just show for teammates to give a sign that they're an invalid target
1246                 //if(shottype == SHOTTYPE_HITENEMY)
1247                         //wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1248                 if(shottype == SHOTTYPE_HITTEAM)
1249                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1250
1251                 f = fabs(autocvar_crosshair_effect_time);
1252                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1253                 {
1254                         wcross_changedonetime = time + f;
1255                 }
1256                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1257                 {
1258                         wcross_name_changestarttime = time;
1259                         wcross_name_changedonetime = time + f;
1260                         if(wcross_name_goal_prev_prev)
1261                                 strunzone(wcross_name_goal_prev_prev);
1262                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1263                         wcross_name_goal_prev = strzone(wcross_name);
1264                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1265                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1266                         wcross_resolution_goal_prev = wcross_resolution;
1267                 }
1268
1269                 wcross_scale_goal_prev = wcross_scale;
1270                 wcross_alpha_goal_prev = wcross_alpha;
1271                 wcross_color_goal_prev = wcross_color;
1272
1273                 if(spectatee_status == 0 && (shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active)))
1274                 {
1275                         wcross_blur = 1;
1276                         wcross_alpha *= 0.75;
1277                 }
1278                 else
1279                         wcross_blur = 0;
1280                 // *_prev is at time-frametime
1281                 // * is at wcross_changedonetime+f
1282                 // what do we have at time?
1283                 if(time < wcross_changedonetime)
1284                 {
1285                         f = frametime / (wcross_changedonetime - time + frametime);
1286                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1287                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1288                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1289                 }
1290
1291                 wcross_scale_prev = wcross_scale;
1292                 wcross_alpha_prev = wcross_alpha;
1293                 wcross_color_prev = wcross_color;
1294
1295                 MUTATOR_CALLHOOK(UpdateCrosshair);
1296
1297                 wcross_scale *= 1 - autocvar__menu_alpha;
1298                 wcross_alpha *= 1 - autocvar__menu_alpha;
1299                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1300
1301                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1302                 {
1303                         // crosshair rings for weapon stats
1304                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1305                         {
1306                                 // declarations and stats
1307                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1308                                 string ring_image = string_null, ring_inner_image = string_null;
1309                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1310
1311                                 ring_scale = autocvar_crosshair_ring_size;
1312
1313                                 entity wepent = viewmodels[0]; // TODO: unhardcode
1314
1315                                 int weapon_clipload = wepent.clip_load;
1316                                 int weapon_clipsize = wepent.clip_size;
1317
1318                                 float arc_heat = wepent.arc_heat_percent;
1319                                 float vcharge = wepent.vortex_charge;
1320                                 float vchargepool = wepent.vortex_chargepool_ammo;
1321                                 float oknex_charge_ = wepent.oknex_charge;
1322                                 float oknex_chargepool_ = wepent.oknex_chargepool_ammo;
1323
1324                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1325                                         vortex_charge_movingavg = vcharge;
1326
1327                                 // handle the values
1328                                 if (autocvar_crosshair_ring && wepent.activeweapon == WEP_VORTEX && vcharge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1329                                 {
1330                                         if (vchargepool || use_vortex_chargepool) {
1331                                                 use_vortex_chargepool = 1;
1332                                                 ring_inner_value = vchargepool;
1333                                         } else {
1334                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vcharge;
1335                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vcharge - vortex_charge_movingavg), 1);
1336                                         }
1337
1338                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1339                                         ring_inner_rgb = vec3(autocvar_crosshair_ring_vortex_inner_color_red, autocvar_crosshair_ring_vortex_inner_color_green, autocvar_crosshair_ring_vortex_inner_color_blue);
1340                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1341
1342                                         // draw the outer ring to show the current charge of the weapon
1343                                         ring_value = vcharge;
1344                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1345                                         ring_rgb = wcross_color;
1346                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1347                                 }
1348                                 else if (autocvar_crosshair_ring && (wepent.activeweapon == WEP_OVERKILL_NEX) && oknex_charge_ && autocvar_crosshair_ring_vortex)
1349                                 {
1350                                         if (oknex_chargepool_ || use_vortex_chargepool) {
1351                                                 use_vortex_chargepool = 1;
1352                                                 ring_inner_value = oknex_chargepool_;
1353                                         } else {
1354                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * oknex_charge_;
1355                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (oknex_charge_ - vortex_charge_movingavg), 1);
1356                                         }
1357
1358                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1359                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1360                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1361
1362                                         // draw the outer ring to show the current charge of the weapon
1363                                         ring_value = oknex_charge_;
1364                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1365                                         ring_rgb = wcross_color;
1366                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1367                                 }
1368                                 else if (autocvar_crosshair_ring && wepent.activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1369                                 {
1370                                         ring_value = bound(0, wepent.minelayer_mines / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1371                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1372                                         ring_rgb = wcross_color;
1373                                         ring_image = "gfx/crosshair_ring.tga";
1374                                 }
1375                                 else if (wepent.activeweapon == WEP_HAGAR && wepent.hagar_load && autocvar_crosshair_ring_hagar)
1376                                 {
1377                                         ring_value = bound(0, wepent.hagar_load / WEP_CVAR_SEC(hagar, load_max), 1);
1378                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1379                                         ring_rgb = wcross_color;
1380                                         ring_image = "gfx/crosshair_ring.tga";
1381                                 }
1382                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1383                                 {
1384                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1385                                         ring_scale = autocvar_crosshair_ring_reload_size;
1386                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1387                                         ring_rgb = wcross_color;
1388
1389                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1390                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1391                                         if ((wepent.activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1392                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1393                                         else
1394                                                 ring_image = "gfx/crosshair_ring.tga";
1395                                 }
1396                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && wepent.activeweapon == WEP_ARC )
1397                                 {
1398                                         ring_value = arc_heat;
1399                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1400                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1401                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1402                                         ring_image = "gfx/crosshair_ring.tga";
1403                                 }
1404
1405                                 // if in weapon switch animation, fade ring out/in
1406                                 if(autocvar_crosshair_effect_time > 0)
1407                                 {
1408                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1409                                         if (f >= 1)
1410                                         {
1411                                                 wcross_ring_prev = ((ring_image) ? true : false);
1412                                         }
1413
1414                                         if(wcross_ring_prev)
1415                                         {
1416                                                 if(f < 1)
1417                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1418                                         }
1419                                         else
1420                                         {
1421                                                 if(f < 1)
1422                                                         ring_alpha *= bound(0, f, 1);
1423                                         }
1424                                 }
1425
1426                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1427                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * wcross_resolution * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1428
1429                                 if (ring_value)
1430                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * wcross_resolution * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1431                         }
1432
1433 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1434                         MACRO_BEGIN \
1435                                 vector scaled_sz = sz * wcross_size; \
1436                                 if(wcross_blur > 0) \
1437                                 { \
1438                                         for(i = -2; i <= 2; ++i) \
1439                                         for(j = -2; j <= 2; ++j) \
1440                                         M(i,j,sz,scaled_sz,wcross_name,wcross_alpha*0.04); \
1441                                 } \
1442                                 else \
1443                                 { \
1444                                         M(0,0,sz,scaled_sz,wcross_name,wcross_alpha); \
1445                                 } \
1446                         MACRO_END
1447
1448 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,scaled_sz,wcross_name,wcross_alpha) \
1449                         drawpic(wcross_origin - ('0.5 0 0' * (scaled_sz.x + i * wcross_blur) + '0 0.5 0' * (scaled_sz.y + j * wcross_blur)), wcross_name, scaled_sz, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1450
1451 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1452                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1453
1454                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1455                         {
1456                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1457                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1458                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1459                                 f = 1 - f;
1460                         }
1461                         else
1462                         {
1463                                 f = 1;
1464                         }
1465                         wcross_name_alpha_goal_prev = f;
1466
1467                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1468                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1469
1470                         if(autocvar_crosshair_dot)
1471                         {
1472                                 vector wcross_color_old;
1473                                 wcross_color_old = wcross_color;
1474
1475                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1476                                         wcross_color = stov(autocvar_crosshair_dot_color);
1477
1478                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1479                                 // FIXME why don't we use wcross_alpha here?
1480                                 wcross_color = wcross_color_old;
1481                         }
1482                 }
1483         }
1484         else
1485         {
1486                 wcross_scale_prev = 0;
1487                 wcross_alpha_prev = 0;
1488                 wcross_scale_goal_prev = 0;
1489                 wcross_alpha_goal_prev = 0;
1490                 wcross_changedonetime = 0;
1491                 strfree(wcross_name_goal_prev);
1492                 strfree(wcross_name_goal_prev_prev);
1493                 wcross_name_changestarttime = 0;
1494                 wcross_name_changedonetime = 0;
1495                 wcross_name_alpha_goal_prev = 0;
1496                 wcross_name_alpha_goal_prev_prev = 0;
1497                 wcross_resolution_goal_prev = 0;
1498                 wcross_resolution_goal_prev_prev = 0;
1499         }
1500 }
1501
1502 const int MAX_SPECIALCOMMAND = 15;
1503 vector specialcommand_slots[MAX_SPECIALCOMMAND];
1504 vector specialcommand_colors[MAX_SPECIALCOMMAND];
1505 const float SPECIALCOMMAND_SPEED = 150;
1506 const float SPECIALCOMMAND_TURNSPEED = 2;
1507 const float SPECIALCOMMAND_SIZE = 0.025;
1508 const float SPECIALCOMMAND_CHANCE = 0.35;
1509 float sc_spawntime, sc_changetime;
1510 vector sc_color = '1 1 1';
1511 void SpecialCommand()
1512 {
1513         if(!STAT(MOVEVARS_SPECIALCOMMAND))
1514                 return;
1515
1516         if(time >= sc_changetime)
1517         {
1518                 sc_changetime = time + 1;
1519                 sc_color = randomvec() * 1.5;
1520                 sc_color.x = bound(0.2, sc_color.x, 0.75);
1521                 sc_color.y = bound(0.2, sc_color.y, 0.75);
1522                 sc_color.z = bound(0.2, sc_color.z, 0.75);
1523         }
1524         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), sc_color, autocvar_hud_colorflash_alpha * bound(0.1, sc_changetime - time, 0.3), DRAWFLAG_ADDITIVE);
1525
1526         if(!precache_pic("gfx/smile"))
1527                 return; // damn party poopers
1528
1529         for(int j = MAX_SPECIALCOMMAND - 1; j >= 0; --j)
1530         {
1531                 vector slot = specialcommand_slots[j];
1532                 if(slot.y)
1533                         slot.y += SPECIALCOMMAND_SPEED * frametime;
1534                 //if(slot.z)
1535                         //slot.z = sin(SPECIALCOMMAND_TURNSPEED * M_PI * time);
1536                 if(slot.y >= vid_conheight)
1537                         slot = '0 0 0';
1538
1539                 if(slot == '0 0 0')
1540                 {
1541                         if(random() <= SPECIALCOMMAND_CHANCE && time > sc_spawntime) // low chance to spawn!
1542                         {
1543                                 slot.x = bound(0, (random() * vid_conwidth + 1), vid_conwidth);
1544                                 slot.y = 1; // start it off 0 so we can use it
1545                                 slot.z = floor(random() * REGISTRY_MAX(Weapons));
1546                                 sc_spawntime = time + bound(0.4, random(), 0.75); // prevent spawning another one for this amount of time!
1547                                 vector newcolor = randomvec() * 2;
1548                                 newcolor.x = bound(0.4, newcolor.x, 1);
1549                                 newcolor.y = bound(0.4, newcolor.y, 1);
1550                                 newcolor.z = bound(0.4, newcolor.z, 1);
1551                                 specialcommand_colors[j] = newcolor;
1552                         }
1553                 }
1554                 else
1555                 {
1556                         vector splash_size = '0 0 0';
1557                         splash_size.x = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1558                         splash_size.y = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1559                         entity wep = REGISTRY_GET(Weapons, slot.z);
1560                         if(wep == WEP_Null)
1561                                 drawpic(vec2(slot), "gfx/smile", vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1562                         else
1563                                 drawpic_skin(vec2(slot), wep.model2, vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1564                         //drawrotpic(vec2(slot), slot.z, "gfx/smile", vec2(splash_size), vec2(splash_size) / 2, specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1565                 }
1566
1567                 specialcommand_slots[j] = slot;
1568         }
1569 }
1570
1571 void HUD_Draw(entity this)
1572 {
1573         // if we don't know gametype and scores yet avoid drawing the scoreboard
1574         // also in the very first frames, player state may be inconsistent so avoid drawing the hud at all
1575         // e.g. since initial player's health is 0 hud would display the hud_damage effect,
1576         // cl_deathscoreboard would show the scoreboard and so on
1577         if(!gametype)
1578                 return;
1579
1580         Hud_Dynamic_Frame();
1581
1582         if(!intermission)
1583         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1584         {
1585                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), M_ARGV(0, vector), autocvar_hud_colorflash_alpha * M_ARGV(1, float), DRAWFLAG_ADDITIVE);
1586         }
1587         else if(STAT(FROZEN))
1588         {
1589                 vector col = '0.25 0.90 1';
1590                 if(STAT(REVIVE_PROGRESS))
1591                         col += vec3(STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS));
1592                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1593         }
1594
1595         HUD_Scale_Enable();
1596         if(!intermission)
1597         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1598         {
1599                 vector col = '0.25 0.90 1' + vec3(STAT(NADE_TIMER), -STAT(NADE_TIMER), -STAT(NADE_TIMER));
1600                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1601                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1602         }
1603         else if(STAT(CAPTURE_PROGRESS))
1604         {
1605                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(CAPTURE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1606                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Capture progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1607         }
1608         else if(STAT(REVIVE_PROGRESS))
1609         {
1610                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1611                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1612         }
1613         HUD_Scale_Disable();
1614
1615         if(autocvar_r_letterbox == 0)
1616                 if(autocvar_viewsize < 120)
1617                 {
1618                         if(!(ISGAMETYPE(RACE) || ISGAMETYPE(CTS)))
1619                                 Accuracy_LoadLevels();
1620
1621                         HUD_Main();
1622                         HUD_Scale_Disable();
1623                 }
1624
1625         // crosshair goes VERY LAST
1626         SpecialCommand();
1627         UpdateDamage();
1628         HUD_Crosshair(this);
1629         HitSound();
1630 }
1631
1632 void ViewLocation_Mouse()
1633 {
1634         if(spectatee_status)
1635                 return; // don't draw it as spectator!
1636
1637         viewloc_mousepos += getmousepos() * autocvar_menu_mouse_speed;
1638         viewloc_mousepos.x = bound(0, viewloc_mousepos.x, vid_conwidth);
1639         viewloc_mousepos.y = bound(0, viewloc_mousepos.y, vid_conheight);
1640
1641         //float cursor_alpha = 1 - autocvar__menu_alpha;
1642         //cursor_type = CURSOR_NORMAL;
1643         //draw_cursor(viewloc_mousepos, '0.5 0.5 0', "/cursor_move", '1 1 1', cursor_alpha);
1644 }
1645
1646 void HUD_Cursor_Show()
1647 {
1648         float cursor_alpha = 1 - autocvar__menu_alpha;
1649         if(cursor_type == CURSOR_NORMAL)
1650                 draw_cursor_normal(mousepos, '1 1 1', cursor_alpha);
1651         else if(cursor_type == CURSOR_MOVE)
1652                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_move", '1 1 1', cursor_alpha);
1653         else if(cursor_type == CURSOR_RESIZE)
1654                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_resize", '1 1 1', cursor_alpha);
1655         else if(cursor_type == CURSOR_RESIZE2)
1656                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_resize2", '1 1 1', cursor_alpha);
1657 }
1658
1659 void HUD_Mouse(entity player)
1660 {
1661         if(autocvar__menu_alpha == 1)
1662                 return;
1663
1664         if(!cursor_active)
1665         {
1666                 if(player.viewloc && (player.viewloc.spawnflags & VIEWLOC_FREEAIM))
1667                         ViewLocation_Mouse(); // NOTE: doesn't use cursormode
1668                 return;
1669         }
1670
1671         if (cursor_active == -1) // starting to display the cursor
1672         {
1673                 // since HUD_Mouse is called by CSQC_UpdateView before CSQC_InputEvent,
1674                 // in the first frame mousepos is the mouse position of the last time
1675                 // the cursor was displayed, thus we ignore it to avoid a glictch
1676                 cursor_active = 1;
1677                 return;
1678         }
1679
1680         if(!autocvar_hud_cursormode)
1681                 update_mousepos();
1682
1683         cursor_type = CURSOR_NORMAL;
1684         if(autocvar__hud_configure)
1685                 HUD_Panel_Mouse();
1686         else
1687         {
1688                 if (HUD_MinigameMenu_IsOpened())
1689                         HUD_Minigame_Mouse();
1690                 if (QuickMenu_IsOpened())
1691                         QuickMenu_Mouse();
1692                 if (HUD_Radar_Clickable())
1693                         HUD_Radar_Mouse();
1694         }
1695
1696         prevMouseClicked = mouseClicked;
1697
1698         HUD_Cursor_Show();
1699 }
1700
1701 void View_NightVision()
1702 {
1703         if(!(autocvar_r_fakelight >= 2 || autocvar_r_fullbright) || (serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1704                 return;
1705
1706         // apply night vision effect
1707         vector tc_00, tc_01, tc_10, tc_11;
1708         vector rgb = '0 0 0';
1709         float a;
1710
1711         if(!nightvision_noise)
1712         {
1713                 nightvision_noise = new(nightvision_noise);
1714         }
1715         if(!nightvision_noise2)
1716         {
1717                 nightvision_noise2 = new(nightvision_noise2);
1718         }
1719
1720         // color tint in yellow
1721         drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1722
1723         // draw BG
1724         a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1725         rgb = '1 1 1';
1726         tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1727         tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1728         tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1729         //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1730         tc_11 = tc_01 + tc_10 - tc_00;
1731         R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE, true);
1732         R_PolygonVertex('0 0 0', tc_00, rgb, a);
1733         R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1734         R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1735         R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1736         R_EndPolygon();
1737
1738         // draw FG
1739         a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1740         rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1741         tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1742         tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1743         tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1744         tc_11 = tc_01 + tc_10 - tc_00;
1745         R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE, true);
1746         R_PolygonVertex('0 0 0', tc_00, rgb, a);
1747         R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1748         R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1749         R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1750         R_EndPolygon();
1751 }
1752
1753 void DrawReticle(entity this)
1754 {
1755         if(!autocvar_cl_reticle || MUTATOR_CALLHOOK(DrawReticle))
1756         {
1757                 reticle_type = 0;
1758                 return;
1759         }
1760
1761         float is_dead = (STAT(HEALTH) <= 0);
1762         string reticle_image = string_null;
1763         bool wep_zoomed = false;
1764         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1765         {
1766                 entity wepe = viewmodels[slot];
1767                 Weapon wep = wepe.activeweapon;
1768                 if(wep != WEP_Null && wep.wr_zoom)
1769                 {
1770                         bool do_zoom = wep.wr_zoom(wep, NULL);
1771                         if(!reticle_image && wep.w_reticle && wep.w_reticle != "")
1772                                 reticle_image = wep.w_reticle;
1773                         wep_zoomed += do_zoom;
1774                 }
1775         }
1776         // Draw the aiming reticle for weapons that use it
1777         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
1778         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
1779         // the view to go back to normal, so reticle_type would become 0 as we fade out)
1780         if(spectatee_status || is_dead || hud != HUD_NORMAL || this.viewloc)
1781         {
1782                 // no zoom reticle while dead
1783                 reticle_type = 0;
1784         }
1785         else if(wep_zoomed && autocvar_cl_reticle_weapon)
1786         {
1787                 if(reticle_image) { reticle_type = 2; }
1788                 else { reticle_type = 0; }
1789         }
1790         else if(button_zoom || zoomscript_caught)
1791         {
1792                 // normal zoom
1793                 reticle_type = 1;
1794         }
1795
1796         if(reticle_type)
1797         {
1798                 vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1799                 if(autocvar_cl_reticle_stretch)
1800                 {
1801                         reticle_size.x = vid_conwidth;
1802                         reticle_size.y = vid_conheight;
1803                         reticle_pos.x = 0;
1804                         reticle_pos.y = 0;
1805                 }
1806                 else
1807                 {
1808                         reticle_size.x = max(vid_conwidth, vid_conheight);
1809                         reticle_size.y = max(vid_conwidth, vid_conheight);
1810                         reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
1811                         reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
1812                 }
1813
1814                 float f = (zoomscript_caught) ? 1 : current_zoomfraction;
1815
1816                 if(f)
1817                 {
1818                         switch(reticle_type)
1819                         {
1820                                 case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
1821                                 case 2: if(reticle_image) drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
1822                         }
1823                 }
1824         }
1825 }
1826
1827 // visual overlay while in liquids
1828 // provides some effects to the postprocessing function
1829 void HUD_Contents()
1830 {
1831         if(!autocvar_hud_contents || MUTATOR_CALLHOOK(HUD_Contents))
1832                 return;
1833
1834         // improved polyblend
1835         float contentalpha_temp, incontent, liquidalpha, contentfadetime;
1836         vector liquidcolor;
1837
1838         switch(pointcontents(view_origin))
1839         {
1840                 case CONTENT_WATER:
1841                         liquidalpha = autocvar_hud_contents_water_alpha;
1842                         liquidcolor = stov(autocvar_hud_contents_water_color);
1843                         incontent = 1;
1844                         break;
1845
1846                 case CONTENT_LAVA:
1847                         liquidalpha = autocvar_hud_contents_lava_alpha;
1848                         liquidcolor = stov(autocvar_hud_contents_lava_color);
1849                         incontent = 1;
1850                         break;
1851
1852                 case CONTENT_SLIME:
1853                         liquidalpha = autocvar_hud_contents_slime_alpha;
1854                         liquidcolor = stov(autocvar_hud_contents_slime_color);
1855                         incontent = 1;
1856                         break;
1857
1858                 default:
1859                         liquidalpha = 0;
1860                         liquidcolor = '0 0 0';
1861                         incontent = 0;
1862                         break;
1863         }
1864
1865         if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
1866         { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
1867                 contentfadetime = autocvar_hud_contents_fadeintime;
1868                 liquidalpha_prev = liquidalpha;
1869                 liquidcolor_prev = liquidcolor;
1870         }
1871         else
1872                 contentfadetime = autocvar_hud_contents_fadeouttime;
1873
1874         contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
1875         contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
1876
1877         if(contentavgalpha)
1878                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
1879
1880         if(autocvar_hud_postprocessing)
1881         {
1882                 if(autocvar_hud_contents_blur && contentavgalpha)
1883                 {
1884                         content_blurpostprocess.x = 1;
1885                         content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
1886                         content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
1887                 }
1888                 else
1889                 {
1890                         content_blurpostprocess.x = 0;
1891                         content_blurpostprocess.y = 0;
1892                         content_blurpostprocess.z = 0;
1893                 }
1894         }
1895 }
1896
1897 // visual pain effects on the screen
1898 // provides some effects to the postprocessing function
1899 void HUD_Damage()
1900 {
1901         if(!autocvar_hud_damage || STAT(FROZEN))
1902                 return;
1903
1904         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1905         splash_size.x = max(vid_conwidth, vid_conheight);
1906         splash_size.y = max(vid_conwidth, vid_conheight);
1907         splash_pos.x = (vid_conwidth - splash_size.x) / 2;
1908         splash_pos.y = (vid_conheight - splash_size.y) / 2;
1909
1910         float myhealth_flash_temp;
1911         myhealth = STAT(HEALTH);
1912
1913         // fade out
1914         myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
1915         // add new damage
1916         myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
1917
1918         float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
1919         pain_threshold = autocvar_hud_damage_pain_threshold;
1920         pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
1921         pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
1922
1923         if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
1924         {
1925                 pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
1926         }
1927
1928         myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
1929
1930         if(myhealth_prev < 1)
1931         {
1932                 if(myhealth >= 1)
1933                 {
1934                         myhealth_flash = 0; // just spawned, clear the flash immediately
1935                         myhealth_flash_temp = 0;
1936                 }
1937                 else
1938                 {
1939                         myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
1940                 }
1941         }
1942
1943         if(spectatee_status == -1 || intermission)
1944         {
1945                 myhealth_flash = 0; // observing, or match ended
1946                 myhealth_flash_temp = 0;
1947         }
1948
1949         myhealth_prev = myhealth;
1950
1951         // IDEA: change damage color/picture based on player model for robot/alien species?
1952         // pro: matches model better
1953         // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
1954         // maybe different reddish pics?
1955         if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
1956         {
1957                 if(autocvar_cl_gentle_damage == 2)
1958                 {
1959                         if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
1960                                 myhealth_gentlergb = randomvec();
1961                 }
1962                 else
1963                         myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
1964
1965                 if(myhealth_flash_temp > 0)
1966                         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1967         }
1968         else if(myhealth_flash_temp > 0)
1969                 drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1970
1971         if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
1972         {
1973                 if(autocvar_hud_damage_blur && myhealth_flash_temp)
1974                 {
1975                         damage_blurpostprocess.x = 1;
1976                         damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
1977                         damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
1978                 }
1979                 else
1980                 {
1981                         damage_blurpostprocess.x = 0;
1982                         damage_blurpostprocess.y = 0;
1983                         damage_blurpostprocess.z = 0;
1984                 }
1985         }
1986 }
1987
1988 void View_PostProcessing()
1989 {
1990         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
1991         float e2 = (autocvar_hud_powerup != 0);
1992         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
1993         {
1994                 // enable or disable rendering types if they are used or not
1995                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
1996                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
1997
1998                 // blur postprocess handling done first (used by hud_damage and hud_contents)
1999                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2000                 {
2001                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2002                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2003                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2004                         {
2005                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2006                                 old_blurradius = blurradius;
2007                                 old_bluralpha = bluralpha;
2008                         }
2009                 }
2010                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2011                 {
2012                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2013                         old_blurradius = 0;
2014                         old_bluralpha = 0;
2015                 }
2016
2017                 // edge detection postprocess handling done second (used by hud_powerup)
2018                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2019                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2020                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2021
2022                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2023
2024                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2025                 {
2026                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2027                         {
2028                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2029                                 old_sharpen_intensity = sharpen_intensity;
2030                         }
2031                 }
2032                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2033                 {
2034                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2035                         old_sharpen_intensity = 0;
2036                 }
2037
2038                 if(cvar("r_glsl_postprocess") == 0)
2039                         cvar_set("r_glsl_postprocess", "2");
2040         }
2041         else if(cvar("r_glsl_postprocess") == 2)
2042                 cvar_set("r_glsl_postprocess", "0");
2043 }
2044
2045 void View_Lock()
2046 {
2047         int lock_type = (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened()));
2048         if (lock_type == 0)
2049                 lock_type = autocvar_cl_lockview;
2050
2051         // lock_type 1: lock origin and angles
2052         // lock_type 2: lock only origin
2053         if(lock_type >= 1)
2054                 setproperty(VF_ORIGIN, freeze_org);
2055         else
2056                 freeze_org = getpropertyvec(VF_ORIGIN);
2057         if(lock_type == 1)
2058                 setproperty(VF_ANGLES, freeze_ang);
2059         else
2060                 freeze_ang = getpropertyvec(VF_ANGLES);
2061 }
2062
2063 void View_DemoCamera()
2064 {
2065         if(camera_active) // Camera for demo playback
2066         {
2067                 if(autocvar_camera_enable)
2068                         CSQC_Demo_Camera();
2069                 else
2070                 {
2071                         cvar_set("chase_active", ftos(chase_active_backup));
2072                         cvar_set("cl_demo_mousegrab", "0");
2073                         camera_active = false;
2074                 }
2075         }
2076         else
2077         {
2078 #ifdef CAMERATEST
2079                 if(autocvar_camera_enable)
2080 #else
2081                 if(autocvar_camera_enable && isdemo())
2082 #endif
2083                 {
2084                         // Enable required Darkplaces cvars
2085                         chase_active_backup = autocvar_chase_active;
2086                         cvar_set("chase_active", "2");
2087                         cvar_set("cl_demo_mousegrab", "1");
2088                         camera_active = true;
2089                         camera_mode = false;
2090                 }
2091         }
2092 }
2093
2094 #ifdef BLURTEST
2095 void View_BlurTest()
2096 {
2097         if(time > blurtest_time0 && time < blurtest_time1)
2098         {
2099                 float t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
2100                 float r = t * blurtest_radius;
2101                 float f = 1 / (t ** blurtest_power) - 1;
2102
2103                 cvar_set("r_glsl_postprocess", "1");
2104                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
2105         }
2106         else
2107         {
2108                 cvar_set("r_glsl_postprocess", "0");
2109                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2110         }
2111 }
2112 #endif
2113
2114 void View_CheckButtonStatus()
2115 {
2116         float is_dead = (STAT(HEALTH) <= 0);
2117
2118         // FIXME do we need this hack?
2119         if(isdemo())
2120         {
2121                 // in demos, input_buttons do not work
2122                 button_zoom = (autocvar__togglezoom == "-");
2123         }
2124         else if(button_zoom
2125                 && autocvar_cl_unpress_zoom_on_death
2126                 && (spectatee_status >= 0)
2127                 && (is_dead || intermission))
2128         {
2129                 // no zoom while dead or in intermission please
2130                 localcmd("-zoom\n");
2131                 button_zoom = false;
2132         }
2133
2134         if(autocvar_fov <= 59.5)
2135         {
2136                 if(!zoomscript_caught)
2137                 {
2138                         localcmd("+button9\n");
2139                         zoomscript_caught = 1;
2140                 }
2141         }
2142         else
2143         {
2144                 if(zoomscript_caught)
2145                 {
2146                         localcmd("-button9\n");
2147                         zoomscript_caught = 0;
2148                 }
2149         }
2150
2151         if(active_minigame && HUD_MinigameMenu_IsOpened())
2152         {
2153                 if(!minigame_wasactive)
2154                 {
2155                         localcmd("+button12\n");
2156                         minigame_wasactive = true;
2157                 }
2158         }
2159         else if(minigame_wasactive)
2160         {
2161                 localcmd("-button12\n");
2162                 minigame_wasactive = false;
2163         }
2164
2165         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2166         {
2167                 entity wepent = viewmodels[slot];
2168
2169                 if(wepent.last_switchweapon != wepent.switchweapon)
2170                 {
2171                         weapontime = time;
2172                         wepent.last_switchweapon = wepent.switchweapon;
2173                         if(slot == 0 && button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
2174                         {
2175                                 localcmd("-zoom\n");
2176                                 button_zoom = false;
2177                         }
2178                         if(slot == 0 && autocvar_cl_unpress_attack_on_weapon_switch)
2179                         {
2180                                 localcmd("-fire\n");
2181                                 localcmd("-fire2\n");
2182                                 button_attack2 = false;
2183                         }
2184                 }
2185                 if(wepent.last_activeweapon != wepent.activeweapon)
2186                 {
2187                         wepent.last_activeweapon = wepent.activeweapon;
2188
2189                         entity e = wepent.activeweapon;
2190                         if(e.netname != "")
2191                                 localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
2192                         else if(slot == 0)
2193                                 localcmd("\ncl_hook_activeweapon none\n");
2194                 }
2195         }
2196 }
2197
2198 bool ov_enabled;
2199 float oldr_nearclip;
2200 float oldr_farclip_base;
2201 float oldr_farclip_world;
2202 float oldr_novis;
2203 float oldr_useportalculling;
2204 float oldr_useinfinitefarclip;
2205 vector ov_org = '0 0 0';
2206 vector ov_mid = '0 0 0';
2207 vector ov_worldmin = '0 0 0';
2208 vector ov_worldmax = '0 0 0';
2209
2210 void View_Ortho()
2211 {
2212         ov_org = '0 0 0';
2213         ov_mid = '0 0 0';
2214         ov_worldmin = '0 0 0';
2215         ov_worldmax = '0 0 0';
2216         if(autocvar_cl_orthoview)
2217         {
2218                 ov_worldmin = mi_picmin;
2219                 ov_worldmax = mi_picmax;
2220
2221                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
2222                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
2223                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
2224
2225                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
2226                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
2227
2228                 float ov_nearest = vlen(ov_org - vec3(
2229                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
2230                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
2231                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
2232                 ));
2233
2234                 float ov_furthest = 0;
2235                 float dist = 0;
2236
2237                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
2238                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
2239                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
2240                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
2241                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
2242                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
2243                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
2244                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
2245
2246                 if(!ov_enabled)
2247                 {
2248                         oldr_nearclip = cvar("r_nearclip");
2249                         oldr_farclip_base = cvar("r_farclip_base");
2250                         oldr_farclip_world = cvar("r_farclip_world");
2251                         oldr_novis = cvar("r_novis");
2252                         oldr_useportalculling = cvar("r_useportalculling");
2253                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
2254                 }
2255
2256                 cvar_settemp("r_nearclip", ftos(ov_nearest));
2257                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
2258                 cvar_settemp("r_farclip_world", "0");
2259                 cvar_settemp("r_novis", "1");
2260                 cvar_settemp("r_useportalculling", "0");
2261                 cvar_settemp("r_useinfinitefarclip", "0");
2262
2263                 setproperty(VF_ORIGIN, ov_org);
2264                 setproperty(VF_ANGLES, '90 0 0');
2265
2266                 ov_enabled = true;
2267
2268                 #if 0
2269                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f",
2270                         vtos(ov_org),
2271                         vtos(getpropertyvec(VF_ANGLES)),
2272                         ov_distance,
2273                         ov_nearest,
2274                         ov_furthest);
2275                 #endif
2276         }
2277         else
2278         {
2279                 if(ov_enabled)
2280                 {
2281                         cvar_set("r_nearclip", ftos(oldr_nearclip));
2282                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
2283                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
2284                         cvar_set("r_novis", ftos(oldr_novis));
2285                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
2286                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
2287                 }
2288                 ov_enabled = false;
2289         }
2290 }
2291
2292 void View_UpdateFov()
2293 {
2294         vector fov;
2295         if(autocvar_cl_orthoview)
2296                 fov = GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org);
2297         else if(csqcplayer.viewloc)
2298                 fov = GetViewLocationFOV(110); // enforce 110 fov, so things don't look odd
2299         else
2300                 fov = GetCurrentFov(autocvar_fov);
2301
2302         setproperty(VF_FOV, fov);
2303 }
2304
2305 void CSQC_UpdateView(entity this, float w, float h)
2306 {
2307         TC(int, w); TC(int, h);
2308
2309         execute_next_frame();
2310
2311         ++framecount;
2312
2313         stats_get();
2314         hud = STAT(HUD);
2315
2316         ReplicateVars(false);
2317         if (ReplicateVars_NOT_SENDING())
2318                 ReplicateVars_DELAY(0.8 + random() * 0.4); // no need to check cvars every frame
2319
2320         HUD_Scale_Disable();
2321
2322         if(autocvar__hud_showbinds_reload) // menu can set this one
2323         {
2324                 db_close(binddb);
2325                 binddb = db_create();
2326                 cvar_set("_hud_showbinds_reload", "0");
2327         }
2328
2329         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
2330                 view_quality = getproperty(VF_MINFPS_QUALITY);
2331         else
2332                 view_quality = 1;
2333
2334         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
2335         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
2336
2337         vector vf_size = getpropertyvec(VF_SIZE);
2338         vector vf_min = getpropertyvec(VF_MIN);
2339         vid_width = vf_size.x;
2340         vid_height = vf_size.y;
2341
2342         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
2343
2344         WaypointSprite_Load();
2345
2346         CSQCPlayer_SetCamera();
2347
2348         if(player_localentnum <= maxclients) // is it a client?
2349                 current_player = player_localentnum - 1;
2350         else // then player_localentnum is the vehicle I'm driving
2351                 current_player = player_localnum;
2352         myteam = entcs_GetTeam(current_player);
2353
2354         // abused multiple places below
2355         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
2356         if(!local_player)
2357                 local_player = this; // fall back!
2358
2359         View_EventChase(local_player);
2360
2361         // do lockview after event chase camera so that it still applies whenever necessary.
2362         View_Lock();
2363
2364         WarpZone_FixView();
2365         //WarpZone_FixPMove();
2366
2367         View_Ortho();
2368
2369         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
2370         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
2371         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2372                 viewmodel_draw(viewmodels[slot]);
2373
2374         // Render the Scene
2375         view_origin = getpropertyvec(VF_ORIGIN);
2376         view_angles = getpropertyvec(VF_ANGLES);
2377         MAKE_VECTORS(view_angles, view_forward, view_right, view_up);
2378
2379 #ifdef BLURTEST
2380         View_BlurTest();
2381 #endif
2382
2383         TargetMusic_Advance();
2384         Fog_Force();
2385         fpscounter_update();
2386
2387         if(drawtime == 0)
2388                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
2389         else
2390                 drawframetime = bound(0.000001, time - drawtime, 1);
2391         drawtime = time;
2392
2393         // watch for gametype changes here...
2394         // in ParseStuffCMD the cmd isn't executed yet :/
2395         // might even be better to add the gametype to TE_CSQC_INIT...?
2396         if(!postinit)
2397                 PostInit();
2398
2399         if(intermission && !intermission_time)
2400                 intermission_time = time;
2401
2402         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
2403         {
2404                 if(calledhooks & HOOK_START)
2405                 {
2406                         localcmd("\ncl_hook_gameend\n");
2407                         calledhooks |= HOOK_END;
2408                 }
2409         }
2410
2411         Announcer();
2412
2413         View_CheckButtonStatus();
2414
2415         ColorTranslateMode = autocvar_cl_stripcolorcodes;
2416
2417         // ALWAYS Clear Current Scene First
2418         clearscene();
2419
2420         setproperty(VF_ORIGIN, view_origin);
2421         setproperty(VF_ANGLES, view_angles);
2422
2423         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
2424         setproperty(VF_SIZE, vf_size);
2425         setproperty(VF_MIN, vf_min);
2426
2427         // Assign Standard Viewflags
2428         // Draw the World (and sky)
2429         setproperty(VF_DRAWWORLD, 1);
2430
2431         // Set the console size vars
2432         vid_conwidth = autocvar_vid_conwidth;
2433         vid_conheight = autocvar_vid_conheight;
2434         vid_pixelheight = autocvar_vid_pixelheight;
2435
2436         View_UpdateFov();
2437
2438         View_DemoCamera();
2439
2440         // Draw the Crosshair
2441         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
2442
2443         // Draw the Engine Status Bar (the default Quake HUD)
2444         setproperty(VF_DRAWENGINESBAR, 0);
2445
2446         // Update the mouse position
2447         /*
2448            mousepos_x = vid_conwidth;
2449            mousepos_y = vid_conheight;
2450            mousepos = mousepos*0.5 + getmousepos();
2451          */
2452
2453         IL_EACH(g_drawables, it.draw, it.draw(it));
2454
2455         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS); // TODO: .health is used in cl_deathfade (a feature we have turned off currently)
2456         renderscene();
2457
2458         // Now the the scene has been rendered, begin with the 2D drawing functions
2459
2460         View_NightVision();
2461         DrawReticle(local_player);
2462         HUD_Contents();
2463         HUD_Damage();
2464         View_PostProcessing();
2465
2466         // draw 2D entities
2467         IL_EACH(g_drawables_2d, it.draw2d, it.draw2d(it));
2468         Draw_ShowNames_All();
2469 #if ENABLE_DEBUGDRAW
2470         Debug_Draw();
2471 #endif
2472
2473         scoreboard_active = Scoreboard_WouldDraw();
2474
2475         HUD_Draw(this); // this parameter for deep vehicle function
2476
2477         if(NextFrameCommand)
2478         {
2479                 localcmd("\n", NextFrameCommand, "\n");
2480                 NextFrameCommand = string_null;
2481         }
2482
2483         // we must do this check AFTER a frame was rendered, or it won't work
2484         if(cs_project_is_b0rked == 0)
2485         {
2486                 string w0, h0;
2487                 w0 = ftos(autocvar_vid_conwidth);
2488                 h0 = ftos(autocvar_vid_conheight);
2489                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2490                 //setproperty(VF_FOV, '90 90 0');
2491                 setproperty(VF_ORIGIN, '0 0 0');
2492                 setproperty(VF_ANGLES, '0 0 0');
2493                 setproperty(VF_PERSPECTIVE, 1);
2494                 vector forward, right, up;
2495                 MAKE_VECTORS('0 0 0', forward, right, up);
2496                 vector v1, v2;
2497                 cvar_set("vid_conwidth", "800");
2498                 cvar_set("vid_conheight", "600");
2499                 v1 = cs_project(forward);
2500                 cvar_set("vid_conwidth", "640");
2501                 cvar_set("vid_conheight", "480");
2502                 v2 = cs_project(forward);
2503                 if(v1 == v2)
2504                         cs_project_is_b0rked = 1;
2505                 else
2506                         cs_project_is_b0rked = -1;
2507                 cvar_set("vid_conwidth", w0);
2508                 cvar_set("vid_conheight", h0);
2509         }
2510
2511         HUD_Mouse(local_player);
2512
2513         cl_notice_run();
2514         unpause_update();
2515         Net_Flush();
2516
2517         // let's reset the view back to normal for the end
2518         setproperty(VF_MIN, '0 0 0');
2519         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2520
2521         IL_ENDFRAME();
2522 }
2523
2524
2525 // following vectors must be global to allow seamless switching between camera modes
2526 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2527 void CSQC_Demo_Camera()
2528 {
2529         float speed, attenuation, dimensions;
2530         vector tmp, delta;
2531
2532         if( autocvar_camera_reset || !camera_mode )
2533         {
2534                 camera_offset = '0 0 0';
2535                 current_angles = '0 0 0';
2536                 camera_direction = '0 0 0';
2537                 camera_offset.z += 30;
2538                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2539                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2540                 current_origin = view_origin;
2541                 current_camera_offset  = camera_offset;
2542                 cvar_set("camera_reset", "0");
2543                 camera_mode = CAMERA_CHASE;
2544         }
2545
2546         // Camera angles
2547         if( camera_roll )
2548                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2549
2550         if(autocvar_camera_look_player)
2551         {
2552                 vector dir;
2553                 float n;
2554
2555                 dir = normalize(view_origin - current_position);
2556                 n = mouse_angles.z;
2557                 mouse_angles = vectoangles(dir);
2558                 mouse_angles.x = mouse_angles.x * -1;
2559                 mouse_angles.z = n;
2560         }
2561         else
2562         {
2563                 tmp = getmousepos() * 0.1;
2564                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2565                 {
2566                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2567                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2568                 }
2569         }
2570
2571         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2572         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2573         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2574         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2575
2576         // Fix difference when angles don't have the same sign
2577         delta = '0 0 0';
2578         if(mouse_angles.y < -60 && current_angles.y > 60)
2579                 delta = '0 360 0';
2580         if(mouse_angles.y > 60 && current_angles.y < -60)
2581                 delta = '0 -360 0';
2582
2583         if(autocvar_camera_look_player)
2584                 attenuation = autocvar_camera_look_attenuation;
2585         else
2586                 attenuation = autocvar_camera_speed_attenuation;
2587
2588         attenuation = 1 / max(1, attenuation);
2589         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2590
2591         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2592         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2593         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2594         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2595
2596         // Camera position
2597         tmp = '0 0 0';
2598         dimensions = 0;
2599
2600         if( camera_direction.x )
2601         {
2602                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2603                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2604                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2605                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2606                 ++dimensions;
2607         }
2608
2609         if( camera_direction.y )
2610         {
2611                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2612                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2613                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2614                 ++dimensions;
2615         }
2616
2617         if( camera_direction.z )
2618         {
2619                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2620                 ++dimensions;
2621         }
2622
2623         if(autocvar_camera_free)
2624                 speed = autocvar_camera_speed_free;
2625         else
2626                 speed = autocvar_camera_speed_chase;
2627
2628         if(dimensions)
2629         {
2630                 speed = speed * sqrt(1 / dimensions);
2631                 camera_offset += tmp * speed;
2632         }
2633
2634         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2635
2636         // Camera modes
2637         if( autocvar_camera_free )
2638         {
2639                 if ( camera_mode == CAMERA_CHASE )
2640                 {
2641                         current_camera_offset = current_origin + current_camera_offset;
2642                         camera_offset = current_origin + camera_offset;
2643                 }
2644
2645                 camera_mode = CAMERA_FREE;
2646                 current_position = current_camera_offset;
2647         }
2648         else
2649         {
2650                 if ( camera_mode == CAMERA_FREE )
2651                 {
2652                         current_origin = view_origin;
2653                         camera_offset = camera_offset - current_origin;
2654                         current_camera_offset = current_camera_offset - current_origin;
2655                 }
2656
2657                 camera_mode = CAMERA_CHASE;
2658
2659                 if(autocvar_camera_chase_smoothly)
2660                         current_origin += (view_origin - current_origin) * attenuation;
2661                 else
2662                         current_origin = view_origin;
2663
2664                 current_position = current_origin + current_camera_offset;
2665         }
2666
2667         setproperty(VF_ANGLES, current_angles);
2668         setproperty(VF_ORIGIN, current_position);
2669 }