qcsrc/client/view.qc

   1 #include "view.qh"
   2
   3 #include "announcer.qh"
   4 #include "hud/_mod.qh"
   5 #include "mapvoting.qh"
   6 #include "shownames.qh"
   7 #include "hud/panel/scoreboard.qh"
   8 #include "hud/panel/quickmenu.qh"
   9
  10 #include "mutators/events.qh"
  11
  12 #include <common/animdecide.qh>
  13 #include <common/ent_cs.qh>
  14 #include <common/anim.qh>
  15 #include <common/constants.qh>
  16 #include <common/net_linked.qh>
  17 #include <common/debug.qh>
  18 #include <common/mapinfo.qh>
  19 #include <common/gamemodes/_mod.qh>
  20 #include <common/physics/player.qh>
  21 #include <common/stats.qh>
  22 #include <common/triggers/target/music.qh>
  23 #include <common/teams.qh>
  24
  25 #include <common/weapons/weapon/tuba.qh>
  26
  27 #include <common/vehicles/all.qh>
  28 #include <common/weapons/_all.qh>
  29 #include <common/viewloc.qh>
  30 #include <common/minigames/cl_minigames.qh>
  31 #include <common/minigames/cl_minigames_hud.qh>
  32
  33 #include <lib/csqcmodel/cl_player.qh>
  34 #include <lib/csqcmodel/cl_model.qh>
  35 #include "csqcmodel_hooks.qh"
  36
  37 #include <lib/warpzone/client.qh>
  38 #include <lib/warpzone/common.qh>
  39
  40 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
  41
  42 float autocvar_cl_viewmodel_scale;
  43
  44 bool autocvar_cl_bobmodel;
  45 float autocvar_cl_bobmodel_speed;
  46 float autocvar_cl_bobmodel_side;
  47 float autocvar_cl_bobmodel_up;
  48
  49 float autocvar_cl_followmodel;
  50 float autocvar_cl_followmodel_speed = 0.3;
  51 float autocvar_cl_followmodel_limit = 135;
  52 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
  53 float autocvar_cl_followmodel_highpass = 0.05;
  54 float autocvar_cl_followmodel_lowpass = 0.03;
  55 bool autocvar_cl_followmodel_velocity_absolute;
  56
  57 float autocvar_cl_leanmodel;
  58 float autocvar_cl_leanmodel_speed = 0.3;
  59 float autocvar_cl_leanmodel_limit = 30;
  60 float autocvar_cl_leanmodel_highpass1 = 0.2;
  61 float autocvar_cl_leanmodel_highpass = 0.2;
  62 float autocvar_cl_leanmodel_lowpass = 0.05;
  63
  64 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
  65 #define lowpass(value, frac, ref_store, ret) MACRO_BEGIN \
  66 { \
  67         ret = ref_store = ref_store * (1 - frac) + (value) * frac; \
  68 } MACRO_END
  69
  70 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  71 { \
  72         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  73         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  74 } MACRO_END
  75
  76 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
  77 { \
  78         float __f = 0; lowpass(value, frac, ref_store, __f); \
  79         ret = (value) - __f; \
  80 } MACRO_END
  81
  82 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  83 { \
  84         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
  85         ret = (value) - __f; \
  86 } MACRO_END
  87
  88 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  89 { \
  90         lowpass(value.x, frac, ref_store.x, ref_out.x); \
  91         lowpass(value.y, frac, ref_store.y, ref_out.y); \
  92 } MACRO_END
  93
  94 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  95 { \
  96         highpass(value.x, frac, ref_store.x, ref_out.x); \
  97         highpass(value.y, frac, ref_store.y, ref_out.y); \
  98 } MACRO_END
  99
 100 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
 101 { \
 102         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
 103         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
 104 } MACRO_END
 105
 106 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 107 { \
 108         lowpass(value.x, frac, ref_store.x, ref_out.x); \
 109         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 110         lowpass(value.z, frac, ref_store.z, ref_out.z); \
 111 } MACRO_END
 112
 113 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 114 { \
 115         highpass(value.x, frac, ref_store.x, ref_out.x); \
 116         highpass(value.y, frac, ref_store.y, ref_out.y); \
 117         highpass(value.z, frac, ref_store.z, ref_out.z); \
 118 } MACRO_END
 119
 120 void calc_followmodel_ofs(entity view)
 121 {
 122         if(cl_followmodel_time == time)
 123                 return; // cl_followmodel_ofs already calculated for this frame
 124
 125         float frac;
 126         vector gunorg = '0 0 0';
 127         static vector vel_average;
 128         static vector gunorg_prev = '0 0 0';
 129         static vector gunorg_adjustment_highpass;
 130         static vector gunorg_adjustment_lowpass;
 131
 132         vector vel;
 133         if (autocvar_cl_followmodel_velocity_absolute)
 134                 vel = view.velocity;
 135         else
 136         {
 137                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 138                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 139                 vel.x = view.velocity * forward;
 140                 vel.y = view.velocity * right * -1;
 141                 vel.z = view.velocity * up;
 142         }
 143
 144         vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
 145         vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
 146         vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
 147
 148         frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
 149         lowpass3(vel, frac, vel_average, gunorg);
 150
 151         gunorg *= -autocvar_cl_followmodel_speed * 0.042;
 152
 153         // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 154         // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 155         frac = avg_factor(autocvar_cl_followmodel_highpass);
 156         highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
 157         frac = avg_factor(autocvar_cl_followmodel_lowpass);
 158         lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
 159
 160         if (autocvar_cl_followmodel_velocity_absolute)
 161         {
 162                 vector fixed_gunorg;
 163                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 164                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 165                 fixed_gunorg.x = gunorg * forward;
 166                 fixed_gunorg.y = gunorg * right * -1;
 167                 fixed_gunorg.z = gunorg * up;
 168                 gunorg = fixed_gunorg;
 169         }
 170
 171         cl_followmodel_ofs = gunorg;
 172         cl_followmodel_time = time;
 173 }
 174
 175 vector leanmodel_ofs(entity view)
 176 {
 177         float frac;
 178         vector gunangles = '0 0 0';
 179         static vector gunangles_prev = '0 0 0';
 180         static vector gunangles_highpass = '0 0 0';
 181         static vector gunangles_adjustment_highpass;
 182         static vector gunangles_adjustment_lowpass;
 183
 184         if (view.csqcmodel_teleported)
 185                 gunangles_prev = view_angles;
 186
 187         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 188         gunangles_highpass += gunangles_prev;
 189         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 190         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 191         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 192         frac = avg_factor(autocvar_cl_leanmodel_highpass1);
 193         highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
 194         gunangles_prev = view_angles;
 195         gunangles_highpass -= gunangles_prev;
 196
 197         PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
 198         YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
 199
 200         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 201         frac = avg_factor(autocvar_cl_leanmodel_highpass);
 202         highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
 203         frac = avg_factor(autocvar_cl_leanmodel_lowpass);
 204         lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
 205
 206         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 207
 208         return gunangles;
 209 }
 210
 211 vector bobmodel_ofs(entity view)
 212 {
 213         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 214         static bool oldonground;
 215         static float hitgroundtime;
 216         if (clonground)
 217         {
 218                 float f = time; // cl.movecmd[0].time
 219                 if (!oldonground)
 220                         hitgroundtime = f;
 221         }
 222         oldonground = clonground;
 223
 224         // calculate for swinging gun model
 225         // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 226         vector gunorg = '0 0 0';
 227         static float bobmodel_scale = 0;
 228         static float time_ofs = 0; // makes the effect always restart in the same way
 229         if (clonground)
 230         {
 231                 if (time - hitgroundtime > 0.05)
 232                         bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
 233         }
 234         else
 235                 bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
 236
 237         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 238         if (bobmodel_scale && xyspeed)
 239         {
 240                 float bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
 241                 float s = (time - time_ofs) * autocvar_cl_bobmodel_speed;
 242                 gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
 243                 gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
 244         }
 245         else
 246                 time_ofs = time;
 247
 248         return gunorg;
 249 }
 250
 251 void viewmodel_animate(entity this)
 252 {
 253         if (autocvar_chase_active) return;
 254         if (STAT(HEALTH) <= 0) return;
 255
 256         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 257
 258         if (autocvar_cl_followmodel)
 259         {
 260                 calc_followmodel_ofs(view);
 261                 this.origin += cl_followmodel_ofs;
 262         }
 263
 264         if (autocvar_cl_leanmodel)
 265                 this.angles += leanmodel_ofs(view);
 266
 267         // vertical view bobbing code
 268         // TODO: cl_bob
 269
 270         // horizontal view bobbing code
 271         // TODO: cl_bob2
 272
 273         // fall bobbing code
 274         // causes the view to swing down and back up when touching the ground
 275         // TODO: cl_bobfall
 276
 277         // gun model bobbing code
 278         if (autocvar_cl_bobmodel)
 279                 this.origin += bobmodel_ofs(view);
 280 }
 281
 282 .vector viewmodel_origin, viewmodel_angles;
 283 .float weapon_nextthink;
 284 .float weapon_eta_last;
 285 .float weapon_switchdelay;
 286
 287 void viewmodel_draw(entity this)
 288 {
 289         if(!activeweapon || !autocvar_r_drawviewmodel)
 290                 return;
 291         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 292         float a = this.alpha;
 293         static bool wasinvehicle;
 294         bool invehicle = player_localentnum > maxclients;
 295         if (invehicle) a = -1;
 296         else if (wasinvehicle) a = 1;
 297         wasinvehicle = invehicle;
 298         Weapon wep = activeweapon;
 299         int c = entcs_GetClientColors(current_player);
 300         vector g = weaponentity_glowmod(wep, NULL, c);
 301         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 302         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 303                 | EF_NODEPTHTEST)
 304                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 305         for (entity e = this; e; e = e.weaponchild)
 306         {
 307                 e.drawmask = mask;
 308                 e.alpha = a;
 309                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 310                 e.glowmod = g;
 311                 e.csqcmodel_effects = fx;
 312                 CSQCModel_Effects_Apply(e);
 313         }
 314         {
 315                 static string name_last;
 316                 string name = wep.mdl;
 317                 string newname = wep.wr_viewmodel(wep, this);
 318                 if(newname)
 319                         name = newname;
 320                 bool swap = name != name_last;
 321                 // if (swap)
 322                 {
 323                         name_last = name;
 324                         CL_WeaponEntity_SetModel(this, name, swap);
 325                         this.viewmodel_origin = this.origin;
 326                         this.viewmodel_angles = this.angles;
 327                 }
 328                 anim_update(this);
 329                 if (!this.animstate_override && !this.animstate_looping)
 330                         anim_set(this, this.anim_idle, true, false, false);
 331         }
 332         float f = 0; // 0..1; 0: fully active
 333         float rate = STAT(WEAPONRATEFACTOR);
 334         float eta = rate ? ((this.weapon_nextthink - time) / rate) : 0;
 335         if (eta <= 0) f = this.weapon_eta_last;
 336         else switch (this.state)
 337         {
 338                 case WS_RAISE:
 339                 {
 340                         f = eta / max(eta, this.weapon_switchdelay);
 341                         break;
 342                 }
 343                 case WS_DROP:
 344                 {
 345                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 346                         break;
 347                 }
 348                 case WS_CLEAR:
 349                 {
 350                         f = 1;
 351                         break;
 352                 }
 353         }
 354         this.weapon_eta_last = f;
 355         this.origin = this.viewmodel_origin;
 356         this.angles = this.viewmodel_angles;
 357         this.angles_x = (-90 * f * f);
 358         viewmodel_animate(this);
 359         setorigin(this, this.origin);
 360 }
 361
 362 entity viewmodel;
 363 STATIC_INIT(viewmodel) {
 364     viewmodel = new(viewmodel);
 365 }
 366
 367 void Porto_Draw(entity this);
 368 STATIC_INIT(Porto)
 369 {
 370         entity e = new_pure(porto);
 371         e.draw = Porto_Draw;
 372         IL_PUSH(g_drawables, e);
 373         e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 374 }
 375
 376 const int polyline_length = 16;
 377 vector polyline[polyline_length];
 378 void Porto_Draw(entity this)
 379 {
 380         if (activeweapon != WEP_PORTO) return;
 381         if (spectatee_status) return;
 382         if (WEP_CVAR(porto, secondary)) return;
 383         if (intermission == 1) return;
 384         if (intermission == 2) return;
 385         if (STAT(HEALTH) <= 0) return;
 386
 387         vector pos = view_origin;
 388         vector dir = view_forward;
 389         if (angles_held_status)
 390         {
 391                 makevectors(angles_held);
 392                 dir = v_forward;
 393         }
 394
 395         polyline[0] = pos;
 396
 397         int portal_number = 0, portal1_idx = 1, portal_max = 2;
 398         int n = 1 + 2;  // 2 lines == 3 points
 399         for (int idx = 0; idx < n && idx < polyline_length - 1; )
 400         {
 401                 traceline(pos, pos + 65536 * dir, true, this);
 402                 dir = reflect(dir, trace_plane_normal);
 403                 pos = trace_endpos;
 404                 polyline[++idx] = pos;
 405                 if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 406                 {
 407                         n += 1;
 408                         continue;
 409                 }
 410                 if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 411                 {
 412                         n = max(2, idx);
 413                         break;
 414                 }
 415                 // check size
 416                 {
 417                         vector ang = vectoangles2(trace_plane_normal, dir);
 418                         ang.x = -ang.x;
 419                         makevectors(ang);
 420                         if (!CheckWireframeBox(this, pos - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 421                         {
 422                                 n = max(2, idx);
 423                                 break;
 424                         }
 425                 }
 426                 portal_number += 1;
 427                 if (portal_number >= portal_max) break;
 428                 if (portal_number == 1) portal1_idx = idx;
 429         }
 430         for (int idx = 0; idx < n - 1; ++idx)
 431         {
 432                 vector p = polyline[idx], q = polyline[idx + 1];
 433                 if (idx == 0) p -= view_up * 16;  // line from player
 434                 vector rgb = (idx < portal1_idx) ? '1 0 0' : '0 0 1';
 435                 Draw_CylindricLine(p, q, 4, "", 1, 0, rgb, 0.5, DRAWFLAG_NORMAL, view_origin);
 436         }
 437 }
 438
 439 float drawtime;
 440 float avgspeed;
 441 vector GetCurrentFov(float fov)
 442 {
 443         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 444         float velocityzoom, curspeed;
 445         vector v;
 446
 447         zoomsensitivity = autocvar_cl_zoomsensitivity;
 448         zoomfactor = autocvar_cl_zoomfactor;
 449         if(zoomfactor < 1 || zoomfactor > 30)
 450                 zoomfactor = 2.5;
 451         zoomspeed = autocvar_cl_zoomspeed;
 452         if(zoomspeed >= 0)
 453         if(zoomspeed < 0.5 || zoomspeed > 16)
 454                         zoomspeed = 3.5;
 455
 456         zoomdir = button_zoom;
 457         if(hud == HUD_NORMAL && !spectatee_status)
 458         if(switchweapon == activeweapon)
 459         if((activeweapon == WEP_VORTEX && !WEP_CVAR(vortex, secondary)) || (activeweapon == WEP_RIFLE && !WEP_CVAR(rifle, secondary))) // do NOT use switchweapon here
 460                 zoomdir += button_attack2;
 461         if(spectatee_status > 0 || isdemo())
 462         {
 463                 if(spectatorbutton_zoom)
 464                 {
 465                         if(zoomdir)
 466                                 zoomdir = 0;
 467                         else
 468                                 zoomdir = 1;
 469                 }
 470                 // fteqcc failed twice here already, don't optimize this
 471         }
 472
 473         if(zoomdir) { zoomin_effect = 0; }
 474
 475         if(camera_active)
 476         {
 477                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 478         }
 479         else if(autocvar_cl_spawnzoom && zoomin_effect)
 480         {
 481                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 482
 483                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 484                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 485                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 486         }
 487         else
 488         {
 489                 if(zoomspeed < 0) // instant zoom
 490                 {
 491                         if(zoomdir)
 492                                 current_viewzoom = 1 / zoomfactor;
 493                         else
 494                                 current_viewzoom = 1;
 495                 }
 496                 else
 497                 {
 498                         if(zoomdir)
 499                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 500                         else
 501                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 502                 }
 503         }
 504
 505         if(almost_equals(current_viewzoom, 1))
 506                 current_zoomfraction = 0;
 507         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 508                 current_zoomfraction = 1;
 509         else
 510                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 511
 512         if(zoomsensitivity < 1)
 513                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 514         else
 515                 setsensitivityscale(1);
 516
 517         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 518         {
 519                 if(intermission) { curspeed = 0; }
 520                 else
 521                 {
 522
 523                         makevectors(view_angles);
 524                         v = pmove_vel;
 525                         if(csqcplayer)
 526                                 v = csqcplayer.velocity;
 527
 528                         switch(autocvar_cl_velocityzoom_type)
 529                         {
 530                                 case 3: curspeed = max(0, v_forward * v); break;
 531                                 case 2: curspeed = (v_forward * v); break;
 532                                 case 1: default: curspeed = vlen(v); break;
 533                         }
 534                 }
 535
 536                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 537                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 538                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 539
 540                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 541         }
 542         else
 543                 velocityzoom = 1;
 544
 545         float frustumx, frustumy, fovx, fovy;
 546         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 547         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 548         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 549         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 550
 551         return '1 0 0' * fovx + '0 1 0' * fovy;
 552 }
 553
 554 vector GetViewLocationFOV(float fov)
 555 {
 556         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 557         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 558         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 559         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 560         return '1 0 0' * fovx + '0 1 0' * fovy;
 561 }
 562
 563 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 564 {
 565         float fovx, fovy;
 566         float width = (ov_worldmax.x - ov_worldmin.x);
 567         float height = (ov_worldmax.y - ov_worldmin.y);
 568         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 569         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 570         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 571         return '1 0 0' * fovx + '0 1 0' * fovy;
 572 }
 573
 574 // this function must match W_SetupShot!
 575 float zoomscript_caught;
 576
 577 vector wcross_origin;
 578 float wcross_scale_prev, wcross_alpha_prev;
 579 vector wcross_color_prev;
 580 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 581 vector wcross_color_goal_prev;
 582 float wcross_changedonetime;
 583
 584 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 585 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 586 float wcross_name_changestarttime, wcross_name_changedonetime;
 587 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 588
 589 float wcross_ring_prev;
 590
 591 entity trueaim;
 592 entity trueaim_rifle;
 593
 594 const float SHOTTYPE_HITTEAM = 1;
 595 const float SHOTTYPE_HITOBSTRUCTION = 2;
 596 const float SHOTTYPE_HITWORLD = 3;
 597 const float SHOTTYPE_HITENEMY = 4;
 598
 599 void TrueAim_Init()
 600 {
 601         (trueaim = new_pure(trueaim)).dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 602         (trueaim_rifle = new_pure(trueaim_rifle)).dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 603 }
 604
 605 float EnemyHitCheck()
 606 {
 607         float t, n;
 608         wcross_origin = project_3d_to_2d(trace_endpos);
 609         wcross_origin.z = 0;
 610         if(trace_ent)
 611                 n = trace_ent.entnum;
 612         else
 613                 n = trace_networkentity;
 614         if(n < 1)
 615                 return SHOTTYPE_HITWORLD;
 616         if(n > maxclients)
 617                 return SHOTTYPE_HITWORLD;
 618         t = entcs_GetTeam(n - 1);
 619         if(teamplay)
 620                 if(t == myteam)
 621                         return SHOTTYPE_HITTEAM;
 622         if(t == NUM_SPECTATOR)
 623                 return SHOTTYPE_HITWORLD;
 624         return SHOTTYPE_HITENEMY;
 625 }
 626
 627 float TrueAimCheck()
 628 {
 629         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 630         vector vecs, trueaimpoint, w_shotorg;
 631         vector mi, ma, dv;
 632         float shottype;
 633         entity ta;
 634         float mv;
 635
 636         mi = ma = '0 0 0';
 637         ta = trueaim;
 638         mv = MOVE_NOMONSTERS;
 639
 640         switch(activeweapon) // WEAPONTODO
 641         {
 642                 case WEP_TUBA: // no aim
 643                 case WEP_PORTO: // shoots from eye
 644                 case WEP_NEXBALL: // shoots from eye
 645                 case WEP_HOOK: // no trueaim
 646                 case WEP_MORTAR: // toss curve
 647                         return SHOTTYPE_HITWORLD;
 648                 case WEP_VORTEX:
 649                 case WEP_VAPORIZER:
 650                         mv = MOVE_NORMAL;
 651                         break;
 652                 case WEP_RIFLE:
 653                         ta = trueaim_rifle;
 654                         mv = MOVE_NORMAL;
 655                         if(zoomscript_caught)
 656                         {
 657                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 658                                 return EnemyHitCheck();
 659                         }
 660                         break;
 661                 case WEP_DEVASTATOR: // projectile has a size!
 662                         mi = '-3 -3 -3';
 663                         ma = '3 3 3';
 664                         break;
 665                 case WEP_FIREBALL: // projectile has a size!
 666                         mi = '-16 -16 -16';
 667                         ma = '16 16 16';
 668                         break;
 669                 case WEP_SEEKER: // projectile has a size!
 670                         mi = '-2 -2 -2';
 671                         ma = '2 2 2';
 672                         break;
 673                 case WEP_ELECTRO: // projectile has a size!
 674                         mi = '0 0 -3';
 675                         ma = '0 0 -3';
 676                         break;
 677         }
 678
 679         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
 680
 681         vecs = decompressShotOrigin(STAT(SHOTORG));
 682
 683         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 684         trueaimpoint = trace_endpos;
 685
 686         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
 687                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 688
 689         if(vecs.x > 0)
 690                 vecs.y = -vecs.y;
 691         else
 692                 vecs = '0 0 0';
 693
 694         dv = view_right * vecs.y + view_up * vecs.z;
 695         w_shotorg = traceorigin + dv;
 696
 697         // now move the vecs forward as much as requested if possible
 698         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 699         w_shotorg = trace_endpos - view_forward * nudge;
 700
 701         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 702         shottype = EnemyHitCheck();
 703         if(shottype != SHOTTYPE_HITWORLD)
 704                 return shottype;
 705
 706 #if 0
 707         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 708         // or rather, I know why, but see no fix
 709         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 710                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 711                 return SHOTTYPE_HITOBSTRUCTION;
 712 #endif
 713
 714         return SHOTTYPE_HITWORLD;
 715 }
 716
 717 void PostInit();
 718 void CSQC_Demo_Camera();
 719 float camera_mode;
 720 const float CAMERA_FREE = 1;
 721 const float CAMERA_CHASE = 2;
 722 float reticle_type;
 723 string reticle_image;
 724 string NextFrameCommand;
 725
 726 vector freeze_org, freeze_ang;
 727 entity nightvision_noise, nightvision_noise2;
 728
 729 const float MAX_TIME_DIFF = 5;
 730 float pickup_crosshair_time, pickup_crosshair_size;
 731 float hitindication_crosshair_size;
 732 float use_vortex_chargepool;
 733
 734 float myhealth, myhealth_prev;
 735 float myhealth_flash;
 736
 737 float old_blurradius, old_bluralpha;
 738 float old_sharpen_intensity;
 739
 740 vector myhealth_gentlergb;
 741
 742 float contentavgalpha, liquidalpha_prev;
 743 vector liquidcolor_prev;
 744
 745 float eventchase_current_distance;
 746 float eventchase_running;
 747 bool WantEventchase(entity this)
 748 {
 749         if(autocvar_cl_orthoview)
 750                 return false;
 751         if(intermission)
 752                 return true;
 753         if(this.viewloc)
 754                 return true;
 755         if(spectatee_status >= 0)
 756         {
 757                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 758                         return true;
 759                 if(MUTATOR_CALLHOOK(WantEventchase, this))
 760                         return true;
 761                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
 762                 {
 763                         if(autocvar_cl_eventchase_death == 2)
 764                         {
 765                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 766                                 if(this.velocity == '0 0 0' || eventchase_running)
 767                                         return true;
 768                         }
 769                         else return true;
 770                 }
 771         }
 772         return false;
 773 }
 774
 775 void HUD_Crosshair_Vehicle(entity this)
 776 {
 777         if(hud != HUD_BUMBLEBEE_GUN)
 778         {
 779                 Vehicle info = Vehicles_from(hud);
 780                 info.vr_crosshair(info, this);
 781         }
 782 }
 783
 784 vector damage_blurpostprocess, content_blurpostprocess;
 785
 786 float unaccounted_damage = 0;
 787 void UpdateDamage()
 788 {
 789         // accumulate damage with each stat update
 790         static float damage_total_prev = 0;
 791         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 792         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 793         damage_total_prev = damage_total;
 794
 795         static float damage_dealt_time_prev = 0;
 796         float damage_dealt_time = STAT(HIT_TIME);
 797         if (damage_dealt_time != damage_dealt_time_prev)
 798         {
 799                 unaccounted_damage += unaccounted_damage_new;
 800                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")");
 801         }
 802         damage_dealt_time_prev = damage_dealt_time;
 803
 804         // prevent hitsound when switching spectatee
 805         static float spectatee_status_prev = 0;
 806         if (spectatee_status != spectatee_status_prev)
 807                 unaccounted_damage = 0;
 808         spectatee_status_prev = spectatee_status;
 809 }
 810
 811 void HitSound()
 812 {
 813         // varying sound pitch
 814
 815         static float hitsound_time_prev = 0;
 816         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 817         float arc_hack = activeweapon == WEP_ARC && autocvar_cl_hitsound >= 2;
 818         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 819         {
 820                 if (autocvar_cl_hitsound && unaccounted_damage)
 821                 {
 822                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 823                         float a = autocvar_cl_hitsound_max_pitch;
 824                         float b = autocvar_cl_hitsound_min_pitch;
 825                         float c = autocvar_cl_hitsound_nom_damage;
 826                         float d = unaccounted_damage;
 827                         float pitch_shift = (b*d*(a-1) + a*c*(1-b)) / (d*(a-1) + c*(1-b));
 828
 829                         // if sound variation is disabled, set pitch_shift to 1
 830                         if (autocvar_cl_hitsound == 1)
 831                                 pitch_shift = 1;
 832
 833                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 834                         if (autocvar_cl_hitsound == 3)
 835                         {
 836                                 float mirror_value = (a-b)/2 + b;
 837                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 838                         }
 839
 840                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift));
 841
 842                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 843                         // todo: normalize sound pressure levels? seems unnecessary
 844
 845                         sound7(NULL, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 846                 }
 847                 unaccounted_damage = 0;
 848                 hitsound_time_prev = time;
 849         }
 850
 851         static float typehit_time_prev = 0;
 852         float typehit_time = STAT(TYPEHIT_TIME);
 853         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 854         {
 855                 sound(NULL, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 856                 typehit_time_prev = typehit_time;
 857         }
 858 }
 859
 860 vector crosshair_getcolor(entity this, float health_stat)
 861 {
 862         static float rainbow_last_flicker;
 863         static vector rainbow_prev_color;
 864         vector wcross_color = '0 0 0';
 865         switch(autocvar_crosshair_color_special)
 866         {
 867                 case 1: // crosshair_color_per_weapon
 868                 {
 869                         if(this != WEP_Null && hud == HUD_NORMAL)
 870                         {
 871                                 wcross_color = this.wpcolor;
 872                                 break;
 873                         }
 874                         else { goto normalcolor; }
 875                 }
 876
 877                 case 2: // crosshair_color_by_health
 878                 {
 879                         float hp = health_stat;
 880
 881                         //x = red
 882                         //y = green
 883                         //z = blue
 884
 885                         wcross_color.z = 0;
 886
 887                         if(hp > 200)
 888                         {
 889                                 wcross_color.x = 0;
 890                                 wcross_color.y = 1;
 891                         }
 892                         else if(hp > 150)
 893                         {
 894                                 wcross_color.x = 0.4 - (hp-150)*0.02 * 0.4;
 895                                 wcross_color.y = 0.9 + (hp-150)*0.02 * 0.1;
 896                         }
 897                         else if(hp > 100)
 898                         {
 899                                 wcross_color.x = 1 - (hp-100)*0.02 * 0.6;
 900                                 wcross_color.y = 1 - (hp-100)*0.02 * 0.1;
 901                                 wcross_color.z = 1 - (hp-100)*0.02;
 902                         }
 903                         else if(hp > 50)
 904                         {
 905                                 wcross_color.x = 1;
 906                                 wcross_color.y = 1;
 907                                 wcross_color.z = 0.2 + (hp-50)*0.02 * 0.8;
 908                         }
 909                         else if(hp > 20)
 910                         {
 911                                 wcross_color.x = 1;
 912                                 wcross_color.y = (hp-20)*90/27/100;
 913                                 wcross_color.z = (hp-20)*90/27/100 * 0.2;
 914                         }
 915                         else
 916                         {
 917                                 wcross_color.x = 1;
 918                                 wcross_color.y = 0;
 919                         }
 920                         break;
 921                 }
 922
 923                 case 3: // crosshair_color_rainbow
 924                 {
 925                         if(time >= rainbow_last_flicker)
 926                         {
 927                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
 928                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
 929                         }
 930                         wcross_color = rainbow_prev_color;
 931                         break;
 932                 }
 933 LABEL(normalcolor)
 934                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
 935         }
 936
 937         return wcross_color;
 938 }
 939
 940 void HUD_Crosshair(entity this)
 941 {
 942         float f, i, j;
 943         vector v;
 944         if(!scoreboard_active && !camera_active && intermission != 2 &&
 945                 spectatee_status != -1 && !csqcplayer.viewloc && !MUTATOR_CALLHOOK(DrawCrosshair) &&
 946                 !HUD_MinigameMenu_IsOpened() )
 947         {
 948                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 949                         return;
 950
 951                 if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
 952                         return;
 953
 954                 if (hud != HUD_NORMAL)
 955                 {
 956                         HUD_Crosshair_Vehicle(this);
 957                         return;
 958                 }
 959
 960                 string wcross_style;
 961                 float wcross_alpha, wcross_resolution;
 962                 wcross_style = autocvar_crosshair;
 963                 if (wcross_style == "0")
 964                         return;
 965                 wcross_resolution = autocvar_crosshair_size;
 966                 if (wcross_resolution == 0)
 967                         return;
 968                 wcross_alpha = autocvar_crosshair_alpha;
 969                 if (wcross_alpha == 0)
 970                         return;
 971
 972                 // TrueAim check
 973                 float shottype;
 974
 975                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 976                 wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 977                 wcross_origin.z = 0;
 978                 if(autocvar_crosshair_hittest)
 979                 {
 980                         vector wcross_oldorigin;
 981                         wcross_oldorigin = wcross_origin;
 982                         shottype = TrueAimCheck();
 983                         if(shottype == SHOTTYPE_HITWORLD)
 984                         {
 985                                 v = wcross_origin - wcross_oldorigin;
 986                                 v.x /= vid_conwidth;
 987                                 v.y /= vid_conheight;
 988                                 if(vdist(v, >, 0.01))
 989                                         shottype = SHOTTYPE_HITOBSTRUCTION;
 990                         }
 991                         if(!autocvar_crosshair_hittest_showimpact)
 992                                 wcross_origin = wcross_oldorigin;
 993                 }
 994                 else
 995                         shottype = SHOTTYPE_HITWORLD;
 996
 997                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
 998                 string wcross_name = "";
 999                 float wcross_scale, wcross_blur;
1000
1001         entity e = WEP_Null;
1002                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1003                 {
1004                         e = switchingweapon;
1005                         if(e)
1006                         {
1007                                 if(autocvar_crosshair_per_weapon)
1008                                 {
1009                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
1010                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1011                                         //if (wcross_resolution == 0)
1012                                                 //return;
1013
1014                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1015                                         wcross_resolution *= e.w_crosshair_size;
1016                                         wcross_name = e.w_crosshair;
1017                                 }
1018                         }
1019                 }
1020
1021                 if(wcross_name == "")
1022                         wcross_name = strcat("gfx/crosshair", wcross_style);
1023
1024                 // MAIN CROSSHAIR COLOR DECISION
1025                 wcross_color = crosshair_getcolor(e, STAT(HEALTH));
1026
1027                 if(autocvar_crosshair_effect_scalefade)
1028                 {
1029                         wcross_scale = wcross_resolution;
1030                         wcross_resolution = 1;
1031                 }
1032                 else
1033                 {
1034                         wcross_scale = 1;
1035                 }
1036
1037                 if(autocvar_crosshair_pickup)
1038                 {
1039                         float stat_pickup_time = STAT(LAST_PICKUP);
1040
1041                         if(pickup_crosshair_time < stat_pickup_time)
1042                         {
1043                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1044                                         pickup_crosshair_size = 1;
1045
1046                                 pickup_crosshair_time = stat_pickup_time;
1047                         }
1048
1049                         if(pickup_crosshair_size > 0)
1050                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1051                         else
1052                                 pickup_crosshair_size = 0;
1053
1054                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1055                 }
1056
1057                 // todo: make crosshair hit indication dependent on damage dealt
1058                 if(autocvar_crosshair_hitindication)
1059                 {
1060                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1061
1062                         if(unaccounted_damage)
1063                         {
1064                                 hitindication_crosshair_size = 1;
1065                         }
1066
1067                         if(hitindication_crosshair_size > 0)
1068                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1069                         else
1070                                 hitindication_crosshair_size = 0;
1071
1072                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1073                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1074                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1075                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1076                 }
1077
1078                 if(shottype == SHOTTYPE_HITENEMY)
1079                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1080                 if(shottype == SHOTTYPE_HITTEAM)
1081                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1082
1083                 f = fabs(autocvar_crosshair_effect_time);
1084                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1085                 {
1086                         wcross_changedonetime = time + f;
1087                 }
1088                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1089                 {
1090                         wcross_name_changestarttime = time;
1091                         wcross_name_changedonetime = time + f;
1092                         if(wcross_name_goal_prev_prev)
1093                                 strunzone(wcross_name_goal_prev_prev);
1094                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1095                         wcross_name_goal_prev = strzone(wcross_name);
1096                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1097                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1098                         wcross_resolution_goal_prev = wcross_resolution;
1099                 }
1100
1101                 wcross_scale_goal_prev = wcross_scale;
1102                 wcross_alpha_goal_prev = wcross_alpha;
1103                 wcross_color_goal_prev = wcross_color;
1104
1105                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1106                 {
1107                         wcross_blur = 1;
1108                         wcross_alpha *= 0.75;
1109                 }
1110                 else
1111                         wcross_blur = 0;
1112                 // *_prev is at time-frametime
1113                 // * is at wcross_changedonetime+f
1114                 // what do we have at time?
1115                 if(time < wcross_changedonetime)
1116                 {
1117                         f = frametime / (wcross_changedonetime - time + frametime);
1118                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1119                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1120                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1121                 }
1122
1123                 wcross_scale_prev = wcross_scale;
1124                 wcross_alpha_prev = wcross_alpha;
1125                 wcross_color_prev = wcross_color;
1126
1127                 MUTATOR_CALLHOOK(UpdateCrosshair);
1128
1129                 wcross_scale *= 1 - autocvar__menu_alpha;
1130                 wcross_alpha *= 1 - autocvar__menu_alpha;
1131                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1132
1133                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1134                 {
1135                         // crosshair rings for weapon stats
1136                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1137                         {
1138                                 // declarations and stats
1139                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1140                                 string ring_image = string_null, ring_inner_image = string_null;
1141                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1142
1143                                 ring_scale = autocvar_crosshair_ring_size;
1144
1145                                 float weapon_clipload, weapon_clipsize;
1146                                 weapon_clipload = STAT(WEAPON_CLIPLOAD);
1147                                 weapon_clipsize = STAT(WEAPON_CLIPSIZE);
1148
1149                                 float ok_ammo_charge, ok_ammo_chargepool;
1150                                 ok_ammo_charge = STAT(OK_AMMO_CHARGE);
1151                                 ok_ammo_chargepool = STAT(OK_AMMO_CHARGEPOOL);
1152
1153                                 float vortex_charge, vortex_chargepool;
1154                                 vortex_charge = STAT(VORTEX_CHARGE);
1155                                 vortex_chargepool = STAT(VORTEX_CHARGEPOOL);
1156
1157                                 float arc_heat = STAT(ARC_HEAT);
1158
1159                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1160                                         vortex_charge_movingavg = vortex_charge;
1161
1162
1163                                 // handle the values
1164                                 if (autocvar_crosshair_ring && activeweapon == WEP_VORTEX && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1165                                 {
1166                                         if (vortex_chargepool || use_vortex_chargepool) {
1167                                                 use_vortex_chargepool = 1;
1168                                                 ring_inner_value = vortex_chargepool;
1169                                         } else {
1170                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
1171                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
1172                                         }
1173
1174                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1175                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1176                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1177
1178                                         // draw the outer ring to show the current charge of the weapon
1179                                         ring_value = vortex_charge;
1180                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1181                                         ring_rgb = wcross_color;
1182                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1183                                 }
1184                                 else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1185                                 {
1186                                         ring_value = bound(0, STAT(LAYED_MINES) / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1187                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1188                                         ring_rgb = wcross_color;
1189                                         ring_image = "gfx/crosshair_ring.tga";
1190                                 }
1191                                 else if (activeweapon == WEP_HAGAR && STAT(HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1192                                 {
1193                                         ring_value = bound(0, STAT(HAGAR_LOAD) / WEP_CVAR_SEC(hagar, load_max), 1);
1194                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1195                                         ring_rgb = wcross_color;
1196                                         ring_image = "gfx/crosshair_ring.tga";
1197                                 }
1198                                 else if (ok_ammo_charge)
1199                                 {
1200                                         ring_value = ok_ammo_chargepool;
1201                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1202                                         ring_rgb = wcross_color;
1203                                         ring_image = "gfx/crosshair_ring.tga";
1204                                 }
1205                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1206                                 {
1207                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1208                                         ring_scale = autocvar_crosshair_ring_reload_size;
1209                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1210                                         ring_rgb = wcross_color;
1211
1212                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1213                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1214                                         if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1215                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1216                                         else
1217                                                 ring_image = "gfx/crosshair_ring.tga";
1218                                 }
1219                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && activeweapon == WEP_ARC )
1220                                 {
1221                                         ring_value = arc_heat;
1222                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1223                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1224                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1225                                         ring_image = "gfx/crosshair_ring.tga";
1226                                 }
1227
1228                                 // if in weapon switch animation, fade ring out/in
1229                                 if(autocvar_crosshair_effect_time > 0)
1230                                 {
1231                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1232                                         if (f >= 1)
1233                                         {
1234                                                 wcross_ring_prev = ((ring_image) ? true : false);
1235                                         }
1236
1237                                         if(wcross_ring_prev)
1238                                         {
1239                                                 if(f < 1)
1240                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1241                                         }
1242                                         else
1243                                         {
1244                                                 if(f < 1)
1245                                                         ring_alpha *= bound(0, f, 1);
1246                                         }
1247                                 }
1248
1249                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1250                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1251
1252                                 if (ring_value)
1253                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1254                         }
1255
1256 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1257                         MACRO_BEGIN { \
1258                                 if(wcross_blur > 0) \
1259                                 { \
1260                                         for(i = -2; i <= 2; ++i) \
1261                                         for(j = -2; j <= 2; ++j) \
1262                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1263                                 } \
1264                                 else \
1265                                 { \
1266                                         M(0,0,sz,wcross_name,wcross_alpha); \
1267                                 } \
1268                         } MACRO_END
1269
1270 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1271                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1272
1273 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1274                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1275
1276                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1277                         {
1278                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1279                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1280                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1281                                 f = 1 - f;
1282                         }
1283                         else
1284                         {
1285                                 f = 1;
1286                         }
1287                         wcross_name_alpha_goal_prev = f;
1288
1289                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1290                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1291
1292                         if(autocvar_crosshair_dot)
1293                         {
1294                                 vector wcross_color_old;
1295                                 wcross_color_old = wcross_color;
1296
1297                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1298                                         wcross_color = stov(autocvar_crosshair_dot_color);
1299
1300                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1301                                 // FIXME why don't we use wcross_alpha here?
1302                                 wcross_color = wcross_color_old;
1303                         }
1304                 }
1305         }
1306         else
1307         {
1308                 wcross_scale_prev = 0;
1309                 wcross_alpha_prev = 0;
1310                 wcross_scale_goal_prev = 0;
1311                 wcross_alpha_goal_prev = 0;
1312                 wcross_changedonetime = 0;
1313                 if(wcross_name_goal_prev)
1314                         strunzone(wcross_name_goal_prev);
1315                 wcross_name_goal_prev = string_null;
1316                 if(wcross_name_goal_prev_prev)
1317                         strunzone(wcross_name_goal_prev_prev);
1318                 wcross_name_goal_prev_prev = string_null;
1319                 wcross_name_changestarttime = 0;
1320                 wcross_name_changedonetime = 0;
1321                 wcross_name_alpha_goal_prev = 0;
1322                 wcross_name_alpha_goal_prev_prev = 0;
1323                 wcross_resolution_goal_prev = 0;
1324                 wcross_resolution_goal_prev_prev = 0;
1325         }
1326 }
1327
1328 void HUD_Draw(entity this)
1329 {
1330         // if we don't know gametype and scores yet avoid drawing the scoreboard
1331         // also in the very first frames, player state may be inconsistent so avoid drawing the hud at all
1332         // e.g. since initial player's health is 0 hud would display the hud_damage effect,
1333         // cl_deathscoreboard would show the scoreboard and so on
1334         if(!gametype)
1335                 return;
1336
1337         if(!intermission)
1338         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1339         {
1340                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, M_ARGV(0, vector), autocvar_hud_colorflash_alpha * M_ARGV(1, float), DRAWFLAG_ADDITIVE);
1341         }
1342         else if(STAT(FROZEN))
1343         {
1344                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, ((STAT(REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * STAT(REVIVE_PROGRESS)) + ('0 1 1' * STAT(REVIVE_PROGRESS) * -1)) : '0.25 0.90 1'), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1345         }
1346         if(!intermission)
1347         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1348         {
1349                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * STAT(NADE_TIMER)) - ('0 1 1' * STAT(NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1350                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1351         }
1352         else if(STAT(CAPTURE_PROGRESS))
1353         {
1354                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(CAPTURE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1355                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Capture progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1356         }
1357         else if(STAT(REVIVE_PROGRESS))
1358         {
1359                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1360                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1361         }
1362
1363         if(autocvar_r_letterbox == 0)
1364                 if(autocvar_viewsize < 120)
1365                 {
1366                         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1367                                 Accuracy_LoadLevels();
1368
1369                         HUD_Main();
1370                         HUD_Scale_Disable();
1371                 }
1372
1373         // crosshair goes VERY LAST
1374         UpdateDamage();
1375         HUD_Crosshair(this);
1376         HitSound();
1377 }
1378
1379 bool ov_enabled;
1380 float oldr_nearclip;
1381 float oldr_farclip_base;
1382 float oldr_farclip_world;
1383 float oldr_novis;
1384 float oldr_useportalculling;
1385 float oldr_useinfinitefarclip;
1386
1387 void cl_notice_run();
1388
1389 float prev_myteam;
1390 int lasthud;
1391 float vh_notice_time;
1392 void WaypointSprite_Load();
1393 void CSQC_UpdateView(entity this, float w, float h)
1394 {
1395     TC(int, w); TC(int, h);
1396         entity e;
1397         float fov;
1398         float f;
1399         vector vf_size, vf_min;
1400         float a;
1401
1402         execute_next_frame();
1403
1404         ++framecount;
1405
1406         stats_get();
1407         hud = STAT(HUD);
1408
1409         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1410                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1411
1412         lasthud = hud;
1413
1414         HUD_Scale_Disable();
1415
1416         if(autocvar__hud_showbinds_reload) // menu can set this one
1417         {
1418                 db_close(binddb);
1419                 binddb = db_create();
1420                 cvar_set("_hud_showbinds_reload", "0");
1421         }
1422
1423         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1424                 view_quality = getproperty(VF_MINFPS_QUALITY);
1425         else
1426                 view_quality = 1;
1427
1428         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1429         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1430
1431         vf_size = getpropertyvec(VF_SIZE);
1432         vf_min = getpropertyvec(VF_MIN);
1433         vid_width = vf_size.x;
1434         vid_height = vf_size.y;
1435
1436         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1437         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1438
1439         WaypointSprite_Load();
1440
1441         CSQCPlayer_SetCamera();
1442
1443         if(player_localentnum <= maxclients) // is it a client?
1444                 current_player = player_localentnum - 1;
1445         else // then player_localentnum is the vehicle I'm driving
1446                 current_player = player_localnum;
1447         myteam = entcs_GetTeam(current_player);
1448
1449         if(myteam != prev_myteam)
1450         {
1451                 myteamcolors = colormapPaletteColor(myteam, 1);
1452                 FOREACH(hud_panels, true, it.update_time = time);
1453                 prev_myteam = myteam;
1454         }
1455
1456         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1457
1458         float is_dead = (STAT(HEALTH) <= 0);
1459
1460         // FIXME do we need this hack?
1461         if(isdemo())
1462         {
1463                 // in demos, input_buttons do not work
1464                 button_zoom = (autocvar__togglezoom == "-");
1465         }
1466         else if(button_zoom
1467                 && autocvar_cl_unpress_zoom_on_death
1468                 && (spectatee_status >= 0)
1469                 && (is_dead || intermission))
1470         {
1471                 // no zoom while dead or in intermission please
1472                 localcmd("-zoom\n");
1473                 button_zoom = false;
1474         }
1475
1476         // event chase camera
1477         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1478         {
1479                 if(STAT(CAMERA_SPECTATOR))
1480                 {
1481                         if(spectatee_status > 0)
1482                         {
1483                                 if(!autocvar_chase_active)
1484                                 {
1485                                         cvar_set("chase_active", "-2");
1486                                         goto skip_eventchase_death;
1487                                 }
1488                         }
1489                         else if(autocvar_chase_active == -2)
1490                                 cvar_set("chase_active", "0");
1491
1492                         if(autocvar_chase_active == -2)
1493                                 goto skip_eventchase_death;
1494                 }
1495                 else if(autocvar_chase_active == -2)
1496                         cvar_set("chase_active", "0");
1497
1498                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1499
1500                 float vehicle_viewdist = 0;
1501                 vector vehicle_viewofs = '0 0 0';
1502
1503                 if(vehicle_chase)
1504                 {
1505                         if(hud != HUD_BUMBLEBEE_GUN)
1506                         {
1507                                 Vehicle info = Vehicles_from(hud);
1508                                 vehicle_viewdist = info.height;
1509                                 vehicle_viewofs = info.view_ofs;
1510                         }
1511                 }
1512
1513                 if(WantEventchase(this))
1514                 {
1515                         vector current_view_origin_override = '0 0 0';
1516                         vector view_offset_override = '0 0 0';
1517                         float chase_distance_override = 0;
1518                         bool custom_eventchase = MUTATOR_CALLHOOK(CustomizeEventchase, this);
1519                         if(custom_eventchase)
1520                         {
1521                                 current_view_origin_override = M_ARGV(0, vector);
1522                                 view_offset_override = M_ARGV(1, vector);
1523                                 chase_distance_override = M_ARGV(0, float);
1524                         }
1525                         eventchase_running = true;
1526
1527                         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1528                         if(!local_player)
1529                                 local_player = this; // fall back!
1530
1531                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1532                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1533                         if (custom_eventchase)
1534                                 current_view_origin = current_view_origin_override;
1535
1536                         // detect maximum viewoffset and use it
1537                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1538                         if(vehicle_chase)
1539                         {
1540                                 if(vehicle_viewofs)
1541                                         view_offset = vehicle_viewofs;
1542                                 else
1543                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
1544                         }
1545                         if (custom_eventchase)
1546                                 view_offset = view_offset_override;
1547
1548                         if(view_offset)
1549                         {
1550                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, this);
1551                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1552                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1553                         }
1554
1555                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1556                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1557                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1558                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1559
1560                         // make the camera smooth back
1561                         float chase_distance = autocvar_cl_eventchase_distance;
1562                         if(vehicle_chase)
1563                         {
1564                                 if(vehicle_viewofs)
1565                                         chase_distance = vehicle_viewdist;
1566                                 else
1567                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
1568                         }
1569                         if (custom_eventchase)
1570                                 chase_distance = chase_distance_override;
1571
1572                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1573                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1574                         else if(eventchase_current_distance != chase_distance)
1575                                 eventchase_current_distance = chase_distance;
1576
1577                         makevectors(view_angles);
1578
1579                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1580                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, this);
1581
1582                         // If the boxtrace fails, revert back to line tracing.
1583                         if(!local_player.viewloc)
1584                         if(trace_startsolid)
1585                         {
1586                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1587                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, this);
1588                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1589                         }
1590                         else { setproperty(VF_ORIGIN, trace_endpos); }
1591
1592                         if(!local_player.viewloc)
1593                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1594                 }
1595                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1596                 {
1597                         eventchase_running = false;
1598                         cvar_set("chase_active", "0");
1599                         eventchase_current_distance = 0; // start from 0 next time
1600                 }
1601         }
1602         // workaround for camera stuck between player's legs when using chase_active 1
1603         // because the engine stops updating the chase_active camera when the game ends
1604         else if(intermission)
1605         {
1606                 cvar_settemp("chase_active", "-1");
1607                 eventchase_current_distance = 0;
1608         }
1609
1610         LABEL(skip_eventchase_death);
1611
1612         // do lockview after event chase camera so that it still applies whenever necessary.
1613         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1614         {
1615                 setproperty(VF_ORIGIN, freeze_org);
1616                 setproperty(VF_ANGLES, freeze_ang);
1617         }
1618         else
1619         {
1620                 freeze_org = getpropertyvec(VF_ORIGIN);
1621                 freeze_ang = getpropertyvec(VF_ANGLES);
1622         }
1623
1624         WarpZone_FixView();
1625         //WarpZone_FixPMove();
1626
1627         vector ov_org = '0 0 0';
1628         vector ov_mid = '0 0 0';
1629         vector ov_worldmin = '0 0 0';
1630         vector ov_worldmax = '0 0 0';
1631         if(autocvar_cl_orthoview)
1632         {
1633                 ov_worldmin = mi_picmin;
1634                 ov_worldmax = mi_picmax;
1635
1636                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1637                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1638                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1639
1640                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1641                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1642
1643                 float ov_nearest = vlen(ov_org - vec3(
1644                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1645                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1646                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1647                 ));
1648
1649                 float ov_furthest = 0;
1650                 float dist = 0;
1651
1652                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1653                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1654                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1655                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1656                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1657                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1658                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1659                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1660
1661                 if(!ov_enabled)
1662                 {
1663                         oldr_nearclip = cvar("r_nearclip");
1664                         oldr_farclip_base = cvar("r_farclip_base");
1665                         oldr_farclip_world = cvar("r_farclip_world");
1666                         oldr_novis = cvar("r_novis");
1667                         oldr_useportalculling = cvar("r_useportalculling");
1668                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1669                 }
1670
1671                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1672                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1673                 cvar_settemp("r_farclip_world", "0");
1674                 cvar_settemp("r_novis", "1");
1675                 cvar_settemp("r_useportalculling", "0");
1676                 cvar_settemp("r_useinfinitefarclip", "0");
1677
1678                 setproperty(VF_ORIGIN, ov_org);
1679                 setproperty(VF_ANGLES, '90 0 0');
1680
1681                 ov_enabled = true;
1682
1683                 #if 0
1684                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1685                         vtos(ov_org),
1686                         vtos(getpropertyvec(VF_ANGLES)),
1687                         ov_distance,
1688                         ov_nearest,
1689                         ov_furthest);
1690                 #endif
1691         }
1692         else
1693         {
1694                 if(ov_enabled)
1695                 {
1696                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1697                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1698                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1699                         cvar_set("r_novis", ftos(oldr_novis));
1700                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1701                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1702                 }
1703                 ov_enabled = false;
1704         }
1705
1706         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
1707         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
1708         viewmodel_draw(viewmodel);
1709
1710         // Render the Scene
1711         view_origin = getpropertyvec(VF_ORIGIN);
1712         view_angles = getpropertyvec(VF_ANGLES);
1713         makevectors(view_angles);
1714         view_forward = v_forward;
1715         view_right = v_right;
1716         view_up = v_up;
1717
1718 #ifdef BLURTEST
1719         if(time > blurtest_time0 && time < blurtest_time1)
1720         {
1721                 float r, t;
1722
1723                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1724                 r = t * blurtest_radius;
1725                 f = 1 / pow(t, blurtest_power) - 1;
1726
1727                 cvar_set("r_glsl_postprocess", "1");
1728                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1729         }
1730         else
1731         {
1732                 cvar_set("r_glsl_postprocess", "0");
1733                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1734         }
1735 #endif
1736
1737         TargetMusic_Advance();
1738         Fog_Force();
1739
1740         if(drawtime == 0)
1741                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1742         else
1743                 drawframetime = bound(0.000001, time - drawtime, 1);
1744         drawtime = time;
1745
1746         // watch for gametype changes here...
1747         // in ParseStuffCMD the cmd isn't executed yet :/
1748         // might even be better to add the gametype to TE_CSQC_INIT...?
1749         if(!postinit)
1750                 PostInit();
1751
1752         if(intermission && !gameover_time)
1753                 gameover_time = time;
1754
1755         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1756         {
1757                 if(calledhooks & HOOK_START)
1758                 {
1759                         localcmd("\ncl_hook_gameend\n");
1760                         calledhooks |= HOOK_END;
1761                 }
1762         }
1763
1764         Announcer();
1765
1766         fov = autocvar_fov;
1767         if(fov <= 59.5)
1768         {
1769                 if(!zoomscript_caught)
1770                 {
1771                         localcmd("+button9\n");
1772                         zoomscript_caught = 1;
1773                 }
1774         }
1775         else
1776         {
1777                 if(zoomscript_caught)
1778                 {
1779                         localcmd("-button9\n");
1780                         zoomscript_caught = 0;
1781                 }
1782         }
1783
1784         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1785
1786         // currently switching-to weapon (for crosshair)
1787         switchingweapon = Weapons_from(STAT(SWITCHINGWEAPON));
1788
1789         // actually active weapon (for zoom)
1790         activeweapon = Weapons_from(STAT(ACTIVEWEAPON));
1791
1792         switchweapon = Weapons_from(STAT(SWITCHWEAPON));
1793
1794         if(last_switchweapon != switchweapon)
1795         {
1796                 weapontime = time;
1797                 last_switchweapon = switchweapon;
1798                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1799                 {
1800                         localcmd("-zoom\n");
1801                         button_zoom = false;
1802                 }
1803                 if(autocvar_cl_unpress_attack_on_weapon_switch)
1804                 {
1805                         localcmd("-fire\n");
1806                         localcmd("-fire2\n");
1807                         button_attack2 = false;
1808                 }
1809         }
1810         if(last_activeweapon != activeweapon)
1811         {
1812                 last_activeweapon = activeweapon;
1813
1814                 e = activeweapon;
1815                 if(e.netname != "")
1816                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1817                 else
1818                         localcmd("\ncl_hook_activeweapon none\n");
1819         }
1820
1821         // ALWAYS Clear Current Scene First
1822         clearscene();
1823
1824         setproperty(VF_ORIGIN, view_origin);
1825         setproperty(VF_ANGLES, view_angles);
1826
1827         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1828         setproperty(VF_SIZE, vf_size);
1829         setproperty(VF_MIN, vf_min);
1830
1831         // Assign Standard Viewflags
1832         // Draw the World (and sky)
1833         setproperty(VF_DRAWWORLD, 1);
1834
1835         // Set the console size vars
1836         vid_conwidth = autocvar_vid_conwidth;
1837         vid_conheight = autocvar_vid_conheight;
1838         vid_pixelheight = autocvar_vid_pixelheight;
1839
1840         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1841         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1842         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1843
1844         if(camera_active) // Camera for demo playback
1845         {
1846                 if(autocvar_camera_enable)
1847                         CSQC_Demo_Camera();
1848                 else
1849                 {
1850                         cvar_set("chase_active", ftos(chase_active_backup));
1851                         cvar_set("cl_demo_mousegrab", "0");
1852                         camera_active = false;
1853                 }
1854         }
1855         else
1856         {
1857 #ifdef CAMERATEST
1858                 if(autocvar_camera_enable)
1859 #else
1860                 if(autocvar_camera_enable && isdemo())
1861 #endif
1862                 {
1863                         // Enable required Darkplaces cvars
1864                         chase_active_backup = autocvar_chase_active;
1865                         cvar_set("chase_active", "2");
1866                         cvar_set("cl_demo_mousegrab", "1");
1867                         camera_active = true;
1868                         camera_mode = false;
1869                 }
1870         }
1871
1872         // Draw the Crosshair
1873         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1874
1875         // Draw the Engine Status Bar (the default Quake HUD)
1876         setproperty(VF_DRAWENGINESBAR, 0);
1877
1878         // Update the mouse position
1879         /*
1880            mousepos_x = vid_conwidth;
1881            mousepos_y = vid_conheight;
1882            mousepos = mousepos*0.5 + getmousepos();
1883          */
1884
1885         IL_EACH(g_drawables, it.draw, it.draw(it));
1886
1887         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1888         renderscene();
1889
1890         // now switch to 2D drawing mode by calling a 2D drawing function
1891         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1892         // next R_RenderScene call
1893         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1894
1895         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1896         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1897         {
1898                 // apply night vision effect
1899                 vector tc_00, tc_01, tc_10, tc_11;
1900                 vector rgb = '0 0 0';
1901
1902                 if(!nightvision_noise)
1903                 {
1904                         nightvision_noise = new(nightvision_noise);
1905                 }
1906                 if(!nightvision_noise2)
1907                 {
1908                         nightvision_noise2 = new(nightvision_noise2);
1909                 }
1910
1911                 // color tint in yellow
1912                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1913
1914                 // draw BG
1915                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1916                 rgb = '1 1 1';
1917                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1918                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1919                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1920                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1921                 tc_11 = tc_01 + tc_10 - tc_00;
1922                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1923                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1924                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1925                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1926                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1927                 R_EndPolygon();
1928
1929                 // draw FG
1930                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1931                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1932                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1933                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1934                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1935                 tc_11 = tc_01 + tc_10 - tc_00;
1936                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1937                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1938                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1939                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1940                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1941                 R_EndPolygon();
1942         }
1943
1944         if(autocvar_cl_reticle)
1945         {
1946                 Weapon wep = activeweapon;
1947                 // Draw the aiming reticle for weapons that use it
1948                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
1949                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
1950                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
1951                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
1952                 {
1953                         // no zoom reticle while dead
1954                         reticle_type = 0;
1955                 }
1956                 else if(wep.wr_zoomreticle(wep) && autocvar_cl_reticle_weapon)
1957                 {
1958                         if(reticle_image != "") { reticle_type = 2; }
1959                         else { reticle_type = 0; }
1960                 }
1961                 else if(button_zoom || zoomscript_caught)
1962                 {
1963                         // normal zoom
1964                         reticle_type = 1;
1965                 }
1966
1967                 if(reticle_type)
1968                 {
1969                         if(autocvar_cl_reticle_stretch)
1970                         {
1971                                 reticle_size.x = vid_conwidth;
1972                                 reticle_size.y = vid_conheight;
1973                                 reticle_pos.x = 0;
1974                                 reticle_pos.y = 0;
1975                         }
1976                         else
1977                         {
1978                                 reticle_size.x = max(vid_conwidth, vid_conheight);
1979                                 reticle_size.y = max(vid_conwidth, vid_conheight);
1980                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
1981                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
1982                         }
1983
1984                         if(zoomscript_caught)
1985                                 f = 1;
1986                         else
1987                                 f = current_zoomfraction;
1988
1989                         if(f)
1990                         {
1991                                 switch(reticle_type)
1992                                 {
1993                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
1994                                         case 2: drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
1995                                 }
1996                         }
1997                 }
1998         }
1999         else
2000         {
2001                 if(reticle_type != 0) { reticle_type = 0; }
2002         }
2003
2004
2005         // improved polyblend
2006         if(autocvar_hud_contents)
2007         {
2008                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
2009                 vector liquidcolor;
2010
2011                 switch(pointcontents(view_origin))
2012                 {
2013                         case CONTENT_WATER:
2014                                 liquidalpha = autocvar_hud_contents_water_alpha;
2015                                 liquidcolor = stov(autocvar_hud_contents_water_color);
2016                                 incontent = 1;
2017                                 break;
2018
2019                         case CONTENT_LAVA:
2020                                 liquidalpha = autocvar_hud_contents_lava_alpha;
2021                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
2022                                 incontent = 1;
2023                                 break;
2024
2025                         case CONTENT_SLIME:
2026                                 liquidalpha = autocvar_hud_contents_slime_alpha;
2027                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
2028                                 incontent = 1;
2029                                 break;
2030
2031                         default:
2032                                 liquidalpha = 0;
2033                                 liquidcolor = '0 0 0';
2034                                 incontent = 0;
2035                                 break;
2036                 }
2037
2038                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
2039                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
2040                         contentfadetime = autocvar_hud_contents_fadeintime;
2041                         liquidalpha_prev = liquidalpha;
2042                         liquidcolor_prev = liquidcolor;
2043                 }
2044                 else
2045                         contentfadetime = autocvar_hud_contents_fadeouttime;
2046
2047                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
2048                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
2049
2050                 if(contentavgalpha)
2051                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
2052
2053                 if(autocvar_hud_postprocessing)
2054                 {
2055                         if(autocvar_hud_contents_blur && contentavgalpha)
2056                         {
2057                                 content_blurpostprocess.x = 1;
2058                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
2059                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
2060                         }
2061                         else
2062                         {
2063                                 content_blurpostprocess.x = 0;
2064                                 content_blurpostprocess.y = 0;
2065                                 content_blurpostprocess.z = 0;
2066                         }
2067                 }
2068         }
2069
2070         if(autocvar_hud_damage && !STAT(FROZEN))
2071         {
2072                 splash_size.x = max(vid_conwidth, vid_conheight);
2073                 splash_size.y = max(vid_conwidth, vid_conheight);
2074                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2075                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2076
2077                 float myhealth_flash_temp;
2078                 myhealth = STAT(HEALTH);
2079
2080                 // fade out
2081                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2082                 // add new damage
2083                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2084
2085                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2086                 pain_threshold = autocvar_hud_damage_pain_threshold;
2087                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2088                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2089
2090                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2091                 {
2092                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2093                 }
2094
2095                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2096
2097                 if(myhealth_prev < 1)
2098                 {
2099                         if(myhealth >= 1)
2100                         {
2101                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2102                                 myhealth_flash_temp = 0;
2103                         }
2104                         else
2105                         {
2106                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2107                         }
2108                 }
2109
2110                 if(spectatee_status == -1 || intermission)
2111                 {
2112                         myhealth_flash = 0; // observing, or match ended
2113                         myhealth_flash_temp = 0;
2114                 }
2115
2116                 myhealth_prev = myhealth;
2117
2118                 // IDEA: change damage color/picture based on player model for robot/alien species?
2119                 // pro: matches model better
2120                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2121                 // maybe different reddish pics?
2122                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2123                 {
2124                         if(autocvar_cl_gentle_damage == 2)
2125                         {
2126                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2127                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
2128                         }
2129                         else
2130                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2131
2132                         if(myhealth_flash_temp > 0)
2133                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2134                 }
2135                 else if(myhealth_flash_temp > 0)
2136                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2137
2138                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2139                 {
2140                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2141                         {
2142                                 damage_blurpostprocess.x = 1;
2143                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2144                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2145                         }
2146                         else
2147                         {
2148                                 damage_blurpostprocess.x = 0;
2149                                 damage_blurpostprocess.y = 0;
2150                                 damage_blurpostprocess.z = 0;
2151                         }
2152                 }
2153         }
2154
2155         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2156         float e2 = (autocvar_hud_powerup != 0);
2157         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2158         {
2159                 // enable or disable rendering types if they are used or not
2160                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2161                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2162
2163                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2164                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2165                 {
2166                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2167                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2168                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2169                         {
2170                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2171                                 old_blurradius = blurradius;
2172                                 old_bluralpha = bluralpha;
2173                         }
2174                 }
2175                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2176                 {
2177                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2178                         old_blurradius = 0;
2179                         old_bluralpha = 0;
2180                 }
2181
2182                 // edge detection postprocess handling done second (used by hud_powerup)
2183                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2184                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2185                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2186
2187                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2188
2189                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2190                 {
2191                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2192                         {
2193                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2194                                 old_sharpen_intensity = sharpen_intensity;
2195                         }
2196                 }
2197                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2198                 {
2199                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2200                         old_sharpen_intensity = 0;
2201                 }
2202
2203                 if(cvar("r_glsl_postprocess") == 0)
2204                         cvar_set("r_glsl_postprocess", "2");
2205         }
2206         else if(cvar("r_glsl_postprocess") == 2)
2207                 cvar_set("r_glsl_postprocess", "0");
2208
2209         /*if(gametype == MAPINFO_TYPE_CTF)
2210           {
2211           ctf_view();
2212           } else */
2213
2214         // draw 2D entities
2215         IL_EACH(g_drawables_2d, it.draw2d, it.draw2d(it));
2216         Draw_ShowNames_All();
2217         Debug_Draw();
2218
2219         scoreboard_active = Scoreboard_WouldDraw();
2220
2221         HUD_Draw(this); // this parameter for deep vehicle function
2222
2223         if(NextFrameCommand)
2224         {
2225                 localcmd("\n", NextFrameCommand, "\n");
2226                 NextFrameCommand = string_null;
2227         }
2228
2229         // we must do this check AFTER a frame was rendered, or it won't work
2230         if(cs_project_is_b0rked == 0)
2231         {
2232                 string w0, h0;
2233                 w0 = ftos(autocvar_vid_conwidth);
2234                 h0 = ftos(autocvar_vid_conheight);
2235                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2236                 //setproperty(VF_FOV, '90 90 0');
2237                 setproperty(VF_ORIGIN, '0 0 0');
2238                 setproperty(VF_ANGLES, '0 0 0');
2239                 setproperty(VF_PERSPECTIVE, 1);
2240                 makevectors('0 0 0');
2241                 vector v1, v2;
2242                 cvar_set("vid_conwidth", "800");
2243                 cvar_set("vid_conheight", "600");
2244                 v1 = cs_project(v_forward);
2245                 cvar_set("vid_conwidth", "640");
2246                 cvar_set("vid_conheight", "480");
2247                 v2 = cs_project(v_forward);
2248                 if(v1 == v2)
2249                         cs_project_is_b0rked = 1;
2250                 else
2251                         cs_project_is_b0rked = -1;
2252                 cvar_set("vid_conwidth", w0);
2253                 cvar_set("vid_conheight", h0);
2254         }
2255
2256         if(autocvar__hud_configure)
2257                 HUD_Panel_Mouse();
2258         else if (HUD_MinigameMenu_IsOpened() || active_minigame)
2259                 HUD_Minigame_Mouse();
2260         else if(QuickMenu_IsOpened())
2261                 QuickMenu_Mouse();
2262         else
2263                 HUD_Radar_Mouse();
2264
2265         cl_notice_run();
2266         unpause_update();
2267         Net_Flush();
2268
2269         // let's reset the view back to normal for the end
2270         setproperty(VF_MIN, '0 0 0');
2271         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2272
2273         IL_ENDFRAME();
2274 }
2275
2276
2277 // following vectors must be global to allow seamless switching between camera modes
2278 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2279 void CSQC_Demo_Camera()
2280 {
2281         float speed, attenuation, dimensions;
2282         vector tmp, delta;
2283
2284         if( autocvar_camera_reset || !camera_mode )
2285         {
2286                 camera_offset = '0 0 0';
2287                 current_angles = '0 0 0';
2288                 camera_direction = '0 0 0';
2289                 camera_offset.z += 30;
2290                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2291                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2292                 current_origin = view_origin;
2293                 current_camera_offset  = camera_offset;
2294                 cvar_set("camera_reset", "0");
2295                 camera_mode = CAMERA_CHASE;
2296         }
2297
2298         // Camera angles
2299         if( camera_roll )
2300                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2301
2302         if(autocvar_camera_look_player)
2303         {
2304                 vector dir;
2305                 float n;
2306
2307                 dir = normalize(view_origin - current_position);
2308                 n = mouse_angles.z;
2309                 mouse_angles = vectoangles(dir);
2310                 mouse_angles.x = mouse_angles.x * -1;
2311                 mouse_angles.z = n;
2312         }
2313         else
2314         {
2315                 tmp = getmousepos() * 0.1;
2316                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2317                 {
2318                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2319                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2320                 }
2321         }
2322
2323         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2324         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2325         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2326         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2327
2328         // Fix difference when angles don't have the same sign
2329         delta = '0 0 0';
2330         if(mouse_angles.y < -60 && current_angles.y > 60)
2331                 delta = '0 360 0';
2332         if(mouse_angles.y > 60 && current_angles.y < -60)
2333                 delta = '0 -360 0';
2334
2335         if(autocvar_camera_look_player)
2336                 attenuation = autocvar_camera_look_attenuation;
2337         else
2338                 attenuation = autocvar_camera_speed_attenuation;
2339
2340         attenuation = 1 / max(1, attenuation);
2341         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2342
2343         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2344         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2345         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2346         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2347
2348         // Camera position
2349         tmp = '0 0 0';
2350         dimensions = 0;
2351
2352         if( camera_direction.x )
2353         {
2354                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2355                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2356                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2357                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2358                 ++dimensions;
2359         }
2360
2361         if( camera_direction.y )
2362         {
2363                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2364                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2365                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2366                 ++dimensions;
2367         }
2368
2369         if( camera_direction.z )
2370         {
2371                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2372                 ++dimensions;
2373         }
2374
2375         if(autocvar_camera_free)
2376                 speed = autocvar_camera_speed_free;
2377         else
2378                 speed = autocvar_camera_speed_chase;
2379
2380         if(dimensions)
2381         {
2382                 speed = speed * sqrt(1 / dimensions);
2383                 camera_offset += tmp * speed;
2384         }
2385
2386         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2387
2388         // Camera modes
2389         if( autocvar_camera_free )
2390         {
2391                 if ( camera_mode == CAMERA_CHASE )
2392                 {
2393                         current_camera_offset = current_origin + current_camera_offset;
2394                         camera_offset = current_origin + camera_offset;
2395                 }
2396
2397                 camera_mode = CAMERA_FREE;
2398                 current_position = current_camera_offset;
2399         }
2400         else
2401         {
2402                 if ( camera_mode == CAMERA_FREE )
2403                 {
2404                         current_origin = view_origin;
2405                         camera_offset = camera_offset - current_origin;
2406                         current_camera_offset = current_camera_offset - current_origin;
2407                 }
2408
2409                 camera_mode = CAMERA_CHASE;
2410
2411                 if(autocvar_camera_chase_smoothly)
2412                         current_origin += (view_origin - current_origin) * attenuation;
2413                 else
2414                         current_origin = view_origin;
2415
2416                 current_position = current_origin + current_camera_offset;
2417         }
2418
2419         setproperty(VF_ANGLES, current_angles);
2420         setproperty(VF_ORIGIN, current_position);
2421 }