qcsrc/client/view.qc

   1 #include "_all.qh"
   2
   3 #include "announcer.qh"
   4 #include "hook.qh"
   5 #include "hud.qh"
   6 #include "hud_config.qh"
   7 #include "mapvoting.qh"
   8 #include "scoreboard.qh"
   9 #include "shownames.qh"
  10
  11 #include "mutators/events.qh"
  12
  13 #include "../common/constants.qh"
  14 #include "../common/mapinfo.qh"
  15 #include "../common/nades.qh"
  16 #include "../common/stats.qh"
  17 #include "../common/triggers/target/music.qh"
  18 #include "../common/teams.qh"
  19 #include "../common/util.qh"
  20
  21 #include "../common/weapons/all.qh"
  22
  23 #include "../csqcmodellib/cl_player.qh"
  24
  25 #include "../warpzonelib/client.qh"
  26 #include "../warpzonelib/common.qh"
  27
  28 entity porto;
  29 vector polyline[16];
  30 void Porto_Draw()
  31 {
  32         vector p, dir, ang, q, nextdir;
  33         float portal_number, portal1_idx;
  34
  35         if(activeweapon != WEP_PORTO.m_id || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
  36                 return;
  37         if(g_balance_porto_secondary)
  38                 return;
  39         if(intermission == 1)
  40                 return;
  41         if(intermission == 2)
  42                 return;
  43         if (getstati(STAT_HEALTH) <= 0)
  44                 return;
  45
  46         dir = view_forward;
  47
  48         if(angles_held_status)
  49         {
  50                 makevectors(angles_held);
  51                 dir = v_forward;
  52         }
  53
  54         p = view_origin;
  55
  56         polyline[0] = p;
  57         int idx = 1;
  58         portal_number = 0;
  59         nextdir = dir;
  60
  61         for (;;)
  62         {
  63                 dir = nextdir;
  64                 traceline(p, p + 65536 * dir, true, porto);
  65                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  66                         return;
  67                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  68                 p = trace_endpos;
  69                 polyline[idx] = p;
  70                 ++idx;
  71                 if(idx >= 16)
  72                         return;
  73                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  74                         continue;
  75                 ++portal_number;
  76                 ang = vectoangles2(trace_plane_normal, dir);
  77                 ang.x = -ang.x;
  78                 makevectors(ang);
  79                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  80                         return;
  81                 if(portal_number == 1)
  82                 {
  83                         portal1_idx = idx;
  84                         if(portal_number >= 2)
  85                                 break;
  86                 }
  87         }
  88
  89         while(idx >= 2)
  90         {
  91                 p = polyline[idx-2];
  92                 q = polyline[idx-1];
  93                 if(idx == 2)
  94                         p = p - view_up * 16;
  95                 if(idx-1 >= portal1_idx)
  96                 {
  97                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  98                 }
  99                 else
 100                 {
 101                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
 102                 }
 103                 --idx;
 104         }
 105 }
 106
 107 void Porto_Init()
 108 {
 109         porto = spawn();
 110         porto.classname = "porto";
 111         porto.draw = Porto_Draw;
 112         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 113 }
 114
 115 float drawtime;
 116 float avgspeed;
 117 vector GetCurrentFov(float fov)
 118 {
 119         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 120         float velocityzoom, curspeed;
 121         vector v;
 122
 123         zoomsensitivity = autocvar_cl_zoomsensitivity;
 124         zoomfactor = autocvar_cl_zoomfactor;
 125         if(zoomfactor < 1 || zoomfactor > 30)
 126                 zoomfactor = 2.5;
 127         zoomspeed = autocvar_cl_zoomspeed;
 128         if(zoomspeed >= 0)
 129         if(zoomspeed < 0.5 || zoomspeed > 16)
 130                         zoomspeed = 3.5;
 131
 132         zoomdir = button_zoom;
 133         if(hud == HUD_NORMAL)
 134         if((activeweapon == WEP_VORTEX.m_id && vortex_scope) || (activeweapon == WEP_RIFLE.m_id && rifle_scope)) // do NOT use switchweapon here
 135                 zoomdir += button_attack2;
 136         if(spectatee_status > 0 || isdemo())
 137         {
 138                 if(spectatorbutton_zoom)
 139                 {
 140                         if(zoomdir)
 141                                 zoomdir = 0;
 142                         else
 143                                 zoomdir = 1;
 144                 }
 145                 // fteqcc failed twice here already, don't optimize this
 146         }
 147
 148         if(zoomdir) { zoomin_effect = 0; }
 149
 150         if(camera_active)
 151         {
 152                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 153         }
 154         else if(autocvar_cl_spawnzoom && zoomin_effect)
 155         {
 156                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 157
 158                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 159                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 160                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 161         }
 162         else
 163         {
 164                 if(zoomspeed < 0) // instant zoom
 165                 {
 166                         if(zoomdir)
 167                                 current_viewzoom = 1 / zoomfactor;
 168                         else
 169                                 current_viewzoom = 1;
 170                 }
 171                 else
 172                 {
 173                         if(zoomdir)
 174                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 175                         else
 176                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 177                 }
 178         }
 179
 180         if(almost_equals(current_viewzoom, 1))
 181                 current_zoomfraction = 0;
 182         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 183                 current_zoomfraction = 1;
 184         else
 185                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 186
 187         if(zoomsensitivity < 1)
 188                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 189         else
 190                 setsensitivityscale(1);
 191
 192         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 193         {
 194                 if(intermission) { curspeed = 0; }
 195                 else
 196                 {
 197
 198                         makevectors(view_angles);
 199                         v = pmove_vel;
 200                         if(csqcplayer)
 201                                 v = csqcplayer.velocity;
 202
 203                         switch(autocvar_cl_velocityzoom_type)
 204                         {
 205                                 case 3: curspeed = max(0, v_forward * v); break;
 206                                 case 2: curspeed = (v_forward * v); break;
 207                                 case 1: default: curspeed = vlen(v); break;
 208                         }
 209                 }
 210
 211                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 212                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 213                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 214
 215                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 216         }
 217         else
 218                 velocityzoom = 1;
 219
 220         float frustumx, frustumy, fovx, fovy;
 221         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 222         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 223         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 224         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 225
 226         return '1 0 0' * fovx + '0 1 0' * fovy;
 227 }
 228
 229 vector GetViewLocationFOV(float fov)
 230 {
 231         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 232         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 233         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 234         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 235         return '1 0 0' * fovx + '0 1 0' * fovy;
 236 }
 237
 238 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 239 {
 240         float fovx, fovy;
 241         float width = (ov_worldmax.x - ov_worldmin.x);
 242         float height = (ov_worldmax.y - ov_worldmin.y);
 243         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 244         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 245         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 246         return '1 0 0' * fovx + '0 1 0' * fovy;
 247 }
 248
 249 // this function must match W_SetupShot!
 250 float zoomscript_caught;
 251
 252 vector wcross_origin;
 253 float wcross_scale_prev, wcross_alpha_prev;
 254 vector wcross_color_prev;
 255 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 256 vector wcross_color_goal_prev;
 257 float wcross_changedonetime;
 258
 259 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 260 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 261 float wcross_name_changestarttime, wcross_name_changedonetime;
 262 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 263
 264 float wcross_ring_prev;
 265
 266 entity trueaim;
 267 entity trueaim_rifle;
 268
 269 const float SHOTTYPE_HITTEAM = 1;
 270 const float SHOTTYPE_HITOBSTRUCTION = 2;
 271 const float SHOTTYPE_HITWORLD = 3;
 272 const float SHOTTYPE_HITENEMY = 4;
 273
 274 void TrueAim_Init()
 275 {
 276         trueaim = spawn();
 277         trueaim.classname = "trueaim";
 278         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 279         trueaim_rifle = spawn();
 280         trueaim_rifle.classname = "trueaim_rifle";
 281         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 282 }
 283
 284 float EnemyHitCheck()
 285 {
 286         float t, n;
 287         wcross_origin = project_3d_to_2d(trace_endpos);
 288         wcross_origin.z = 0;
 289         if(trace_ent)
 290                 n = trace_ent.entnum;
 291         else
 292                 n = trace_networkentity;
 293         if(n < 1)
 294                 return SHOTTYPE_HITWORLD;
 295         if(n > maxclients)
 296                 return SHOTTYPE_HITWORLD;
 297         t = GetPlayerColor(n - 1);
 298         if(teamplay)
 299                 if(t == myteam)
 300                         return SHOTTYPE_HITTEAM;
 301         if(t == NUM_SPECTATOR)
 302                 return SHOTTYPE_HITWORLD;
 303         return SHOTTYPE_HITENEMY;
 304 }
 305
 306 float TrueAimCheck()
 307 {
 308         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 309         vector vecs, trueaimpoint, w_shotorg;
 310         vector mi, ma, dv;
 311         float shottype;
 312         entity ta;
 313         float mv;
 314
 315         mi = ma = '0 0 0';
 316         ta = trueaim;
 317         mv = MOVE_NOMONSTERS;
 318
 319         switch(activeweapon) // WEAPONTODO
 320         {
 321                 case WEP_TUBA.m_id: // no aim
 322                 case WEP_PORTO.m_id: // shoots from eye
 323                 case WEP_HOOK.m_id: // no trueaim
 324                 case WEP_MORTAR.m_id: // toss curve
 325                         return SHOTTYPE_HITWORLD;
 326                 case WEP_VORTEX.m_id:
 327                 case WEP_VAPORIZER.m_id:
 328                         mv = MOVE_NORMAL;
 329                         break;
 330                 case WEP_RIFLE.m_id:
 331                         ta = trueaim_rifle;
 332                         mv = MOVE_NORMAL;
 333                         if(zoomscript_caught)
 334                         {
 335                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 336                                 return EnemyHitCheck();
 337                         }
 338                         break;
 339                 case WEP_DEVASTATOR.m_id: // projectile has a size!
 340                         mi = '-3 -3 -3';
 341                         ma = '3 3 3';
 342                         break;
 343                 case WEP_FIREBALL.m_id: // projectile has a size!
 344                         mi = '-16 -16 -16';
 345                         ma = '16 16 16';
 346                         break;
 347                 case WEP_SEEKER.m_id: // projectile has a size!
 348                         mi = '-2 -2 -2';
 349                         ma = '2 2 2';
 350                         break;
 351                 case WEP_ELECTRO.m_id: // projectile has a size!
 352                         mi = '0 0 -3';
 353                         ma = '0 0 -3';
 354                         break;
 355         }
 356
 357         vector traceorigin = getplayerorigin(player_localentnum-1) + (eZ * getstati(STAT_VIEWHEIGHT));
 358
 359         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 360
 361         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 362         trueaimpoint = trace_endpos;
 363
 364         if(vlen(trueaimpoint - traceorigin) < g_trueaim_minrange)
 365                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 366
 367         if(vecs.x > 0)
 368                 vecs.y = -vecs.y;
 369         else
 370                 vecs = '0 0 0';
 371
 372         dv = view_right * vecs.y + view_up * vecs.z;
 373         w_shotorg = traceorigin + dv;
 374
 375         // now move the vecs forward as much as requested if possible
 376         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 377         w_shotorg = trace_endpos - view_forward * nudge;
 378
 379         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 380         shottype = EnemyHitCheck();
 381         if(shottype != SHOTTYPE_HITWORLD)
 382                 return shottype;
 383
 384 #if 0
 385         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 386         // or rather, I know why, but see no fix
 387         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 388                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 389                 return SHOTTYPE_HITOBSTRUCTION;
 390 #endif
 391
 392         return SHOTTYPE_HITWORLD;
 393 }
 394
 395 void CSQC_common_hud(void);
 396
 397 void PostInit(void);
 398 void CSQC_Demo_Camera();
 399 float HUD_WouldDrawScoreboard();
 400 float camera_mode;
 401 const float CAMERA_FREE = 1;
 402 const float CAMERA_CHASE = 2;
 403 float reticle_type;
 404 string reticle_image;
 405 string NextFrameCommand;
 406
 407 vector freeze_org, freeze_ang;
 408 entity nightvision_noise, nightvision_noise2;
 409
 410 const float MAX_TIME_DIFF = 5;
 411 float pickup_crosshair_time, pickup_crosshair_size;
 412 float hitindication_crosshair_size;
 413 float use_vortex_chargepool;
 414
 415 float myhealth, myhealth_prev;
 416 float myhealth_flash;
 417
 418 float old_blurradius, old_bluralpha;
 419 float old_sharpen_intensity;
 420
 421 vector myhealth_gentlergb;
 422
 423 float contentavgalpha, liquidalpha_prev;
 424 vector liquidcolor_prev;
 425
 426 float eventchase_current_distance;
 427 float eventchase_running;
 428 bool WantEventchase()
 429 {
 430         if(autocvar_cl_orthoview)
 431                 return false;
 432         if(intermission)
 433                 return true;
 434         if(self.viewloc)
 435                 return true;
 436         if(spectatee_status >= 0)
 437         {
 438                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 439                         return true;
 440                 if(MUTATOR_CALLHOOK(WantEventchase, self))
 441                         return true;
 442                 if(autocvar_cl_eventchase_nexball && gametype == MAPINFO_TYPE_NEXBALL && !(WepSet_GetFromStat() & WepSet_FromWeapon(WEP_PORTO.m_id)))
 443                         return true;
 444                 if(autocvar_cl_eventchase_death && (getstati(STAT_HEALTH) <= 0))
 445                 {
 446                         if(autocvar_cl_eventchase_death == 2)
 447                         {
 448                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 449                                 if(self.velocity == '0 0 0' || eventchase_running)
 450                                         return true;
 451                         }
 452                         else return true;
 453                 }
 454         }
 455         return false;
 456 }
 457
 458 vector damage_blurpostprocess, content_blurpostprocess;
 459
 460 float checkfail[16];
 461
 462 float unaccounted_damage = 0;
 463 void UpdateDamage()
 464 {
 465         // accumulate damage with each stat update
 466         static float damage_total_prev = 0;
 467         float damage_total = getstati(STAT_DAMAGE_DEALT_TOTAL);
 468         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 469         damage_total_prev = damage_total;
 470
 471         static float damage_dealt_time_prev = 0;
 472         float damage_dealt_time = getstatf(STAT_HIT_TIME);
 473         if (damage_dealt_time != damage_dealt_time_prev)
 474         {
 475                 unaccounted_damage += unaccounted_damage_new;
 476                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")", "\n");
 477         }
 478         damage_dealt_time_prev = damage_dealt_time;
 479
 480         // prevent hitsound when switching spectatee
 481         static float spectatee_status_prev = 0;
 482         if (spectatee_status != spectatee_status_prev)
 483                 unaccounted_damage = 0;
 484         spectatee_status_prev = spectatee_status;
 485 }
 486
 487 void UpdateHitsound()
 488 {
 489         // varying sound pitch
 490
 491         static float hitsound_time_prev = 0;
 492         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 493         float arc_hack = activeweapon == WEP_ARC.m_id && autocvar_cl_hitsound >= 2;
 494         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 495         {
 496                 if (autocvar_cl_hitsound && unaccounted_damage)
 497                 {
 498                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 499                         float a = autocvar_cl_hitsound_max_pitch;
 500                         float b = autocvar_cl_hitsound_min_pitch;
 501                         float c = autocvar_cl_hitsound_nom_damage;
 502                         float x = unaccounted_damage;
 503                         float pitch_shift = (b*x*(a-1) + a*c*(1-b)) / (x*(a-1) + c*(1-b));
 504
 505                         // if sound variation is disabled, set pitch_shift to 1
 506                         if (autocvar_cl_hitsound == 1)
 507                                 pitch_shift = 1;
 508
 509                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 510                         if (autocvar_cl_hitsound == 3)
 511                         {
 512                                 float mirror_value = (a-b)/2 + b;
 513                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 514                         }
 515
 516                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift), "\n");
 517
 518                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 519                         // todo: normalize sound pressure levels? seems unnecessary
 520
 521                         sound7(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 522                 }
 523                 unaccounted_damage = 0;
 524                 hitsound_time_prev = time;
 525         }
 526
 527         static float typehit_time_prev = 0;
 528         float typehit_time = getstatf(STAT_TYPEHIT_TIME);
 529         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 530         {
 531                 sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
 532                 typehit_time_prev = typehit_time;
 533         }
 534 }
 535
 536 void UpdateCrosshair()
 537 {
 538         static float rainbow_last_flicker;
 539     static vector rainbow_prev_color;
 540         entity e = self;
 541         float f, i, j;
 542         vector v;
 543         if(getstati(STAT_FROZEN))
 544                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, ((getstatf(STAT_REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * getstatf(STAT_REVIVE_PROGRESS)) + ('0 1 1' * getstatf(STAT_REVIVE_PROGRESS) * -1)) : '0.25 0.90 1'), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 545         else if (getstatf(STAT_HEALING_ORB)>time)
 546                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, NADE_TYPE_HEAL.m_color, autocvar_hud_colorflash_alpha*getstatf(STAT_HEALING_ORB_ALPHA), DRAWFLAG_ADDITIVE);
 547         if(!intermission)
 548         if(getstatf(STAT_NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
 549         {
 550                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * getstatf(STAT_NADE_TIMER)) - ('0 1 1' * getstatf(STAT_NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 551                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
 552         }
 553         else if(getstatf(STAT_REVIVE_PROGRESS))
 554         {
 555                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 556                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
 557         }
 558
 559         if(autocvar_r_letterbox == 0)
 560                 if(autocvar_viewsize < 120)
 561                         CSQC_common_hud();
 562
 563         // crosshair goes VERY LAST
 564         if(!scoreboard_active && !camera_active && intermission != 2 &&
 565                 spectatee_status != -1 && hud == HUD_NORMAL && !csqcplayer.viewloc &&
 566                 !HUD_MinigameMenu_IsOpened() )
 567         {
 568                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 569                         return;
 570
 571                 string wcross_style;
 572                 float wcross_alpha, wcross_resolution;
 573                 wcross_style = autocvar_crosshair;
 574                 if (wcross_style == "0")
 575                         return;
 576                 wcross_resolution = autocvar_crosshair_size;
 577                 if (wcross_resolution == 0)
 578                         return;
 579                 wcross_alpha = autocvar_crosshair_alpha;
 580                 if (wcross_alpha == 0)
 581                         return;
 582
 583                 // TrueAim check
 584                 float shottype;
 585
 586                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 587                 wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 588                 wcross_origin.z = 0;
 589                 if(autocvar_crosshair_hittest)
 590                 {
 591                         vector wcross_oldorigin;
 592                         wcross_oldorigin = wcross_origin;
 593                         shottype = TrueAimCheck();
 594                         if(shottype == SHOTTYPE_HITWORLD)
 595                         {
 596                                 v = wcross_origin - wcross_oldorigin;
 597                                 v.x /= vid_conwidth;
 598                                 v.y /= vid_conheight;
 599                                 if(vlen(v) > 0.01)
 600                                         shottype = SHOTTYPE_HITOBSTRUCTION;
 601                         }
 602                         if(!autocvar_crosshair_hittest_showimpact)
 603                                 wcross_origin = wcross_oldorigin;
 604                 }
 605                 else
 606                         shottype = SHOTTYPE_HITWORLD;
 607
 608                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
 609                 string wcross_name = "";
 610                 float wcross_scale, wcross_blur;
 611
 612                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
 613                 {
 614                         e = get_weaponinfo(switchingweapon);
 615                         if(e)
 616                         {
 617                                 if(autocvar_crosshair_per_weapon)
 618                                 {
 619                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
 620                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 621                                         //if (wcross_resolution == 0)
 622                                                 //return;
 623
 624                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 625                                         wcross_resolution *= e.w_crosshair_size;
 626                                         wcross_name = e.w_crosshair;
 627                                 }
 628                         }
 629                 }
 630
 631                 if(wcross_name == "")
 632                         wcross_name = strcat("gfx/crosshair", wcross_style);
 633
 634                 // MAIN CROSSHAIR COLOR DECISION
 635                 switch(autocvar_crosshair_color_special)
 636                 {
 637                         case 1: // crosshair_color_per_weapon
 638                         {
 639                                 if(e)
 640                                 {
 641                                         wcross_color = e.wpcolor;
 642                                         break;
 643                                 }
 644                                 else { goto normalcolor; }
 645                         }
 646
 647                         case 2: // crosshair_color_by_health
 648                         {
 649                                 float x = getstati(STAT_HEALTH);
 650
 651                                 //x = red
 652                                 //y = green
 653                                 //z = blue
 654
 655                                 wcross_color.z = 0;
 656
 657                                 if(x > 200)
 658                                 {
 659                                         wcross_color.x = 0;
 660                                         wcross_color.y = 1;
 661                                 }
 662                                 else if(x > 150)
 663                                 {
 664                                         wcross_color.x = 0.4 - (x-150)*0.02 * 0.4;
 665                                         wcross_color.y = 0.9 + (x-150)*0.02 * 0.1;
 666                                 }
 667                                 else if(x > 100)
 668                                 {
 669                                         wcross_color.x = 1 - (x-100)*0.02 * 0.6;
 670                                         wcross_color.y = 1 - (x-100)*0.02 * 0.1;
 671                                         wcross_color.z = 1 - (x-100)*0.02;
 672                                 }
 673                                 else if(x > 50)
 674                                 {
 675                                         wcross_color.x = 1;
 676                                         wcross_color.y = 1;
 677                                         wcross_color.z = 0.2 + (x-50)*0.02 * 0.8;
 678                                 }
 679                                 else if(x > 20)
 680                                 {
 681                                         wcross_color.x = 1;
 682                                         wcross_color.y = (x-20)*90/27/100;
 683                                         wcross_color.z = (x-20)*90/27/100 * 0.2;
 684                                 }
 685                                 else
 686                                 {
 687                                         wcross_color.x = 1;
 688                                         wcross_color.y = 0;
 689                                 }
 690                                 break;
 691                         }
 692
 693                         case 3: // crosshair_color_rainbow
 694                         {
 695                                 if(time >= rainbow_last_flicker)
 696                                 {
 697                                         rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
 698                                         rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
 699                                 }
 700                                 wcross_color = rainbow_prev_color;
 701                                 break;
 702                         }
 703                         :normalcolor
 704                         default: { wcross_color = stov(autocvar_crosshair_color); break; }
 705                 }
 706
 707                 if(autocvar_crosshair_effect_scalefade)
 708                 {
 709                         wcross_scale = wcross_resolution;
 710                         wcross_resolution = 1;
 711                 }
 712                 else
 713                 {
 714                         wcross_scale = 1;
 715                 }
 716
 717                 if(autocvar_crosshair_pickup)
 718                 {
 719                         float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
 720
 721                         if(pickup_crosshair_time < stat_pickup_time)
 722                         {
 723                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
 724                                         pickup_crosshair_size = 1;
 725
 726                                 pickup_crosshair_time = stat_pickup_time;
 727                         }
 728
 729                         if(pickup_crosshair_size > 0)
 730                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
 731                         else
 732                                 pickup_crosshair_size = 0;
 733
 734                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
 735                 }
 736
 737                 // todo: make crosshair hit indication dependent on damage dealt
 738                 if(autocvar_crosshair_hitindication)
 739                 {
 740                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
 741
 742                         if(unaccounted_damage)
 743                         {
 744                                 hitindication_crosshair_size = 1;
 745                         }
 746
 747                         if(hitindication_crosshair_size > 0)
 748                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
 749                         else
 750                                 hitindication_crosshair_size = 0;
 751
 752                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
 753                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
 754                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
 755                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
 756                 }
 757
 758                 if(shottype == SHOTTYPE_HITENEMY)
 759                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
 760                 if(shottype == SHOTTYPE_HITTEAM)
 761                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
 762
 763                 f = fabs(autocvar_crosshair_effect_time);
 764                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
 765                 {
 766                         wcross_changedonetime = time + f;
 767                 }
 768                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
 769                 {
 770                         wcross_name_changestarttime = time;
 771                         wcross_name_changedonetime = time + f;
 772                         if(wcross_name_goal_prev_prev)
 773                                 strunzone(wcross_name_goal_prev_prev);
 774                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
 775                         wcross_name_goal_prev = strzone(wcross_name);
 776                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
 777                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
 778                         wcross_resolution_goal_prev = wcross_resolution;
 779                 }
 780
 781                 wcross_scale_goal_prev = wcross_scale;
 782                 wcross_alpha_goal_prev = wcross_alpha;
 783                 wcross_color_goal_prev = wcross_color;
 784
 785                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
 786                 {
 787                         wcross_blur = 1;
 788                         wcross_alpha *= 0.75;
 789                 }
 790                 else
 791                         wcross_blur = 0;
 792                 // *_prev is at time-frametime
 793                 // * is at wcross_changedonetime+f
 794                 // what do we have at time?
 795                 if(time < wcross_changedonetime)
 796                 {
 797                         f = frametime / (wcross_changedonetime - time + frametime);
 798                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
 799                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
 800                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
 801                 }
 802
 803                 wcross_scale_prev = wcross_scale;
 804                 wcross_alpha_prev = wcross_alpha;
 805                 wcross_color_prev = wcross_color;
 806
 807                 MUTATOR_CALLHOOK(UpdateCrosshair);
 808
 809                 wcross_scale *= 1 - autocvar__menu_alpha;
 810                 wcross_alpha *= 1 - autocvar__menu_alpha;
 811                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
 812
 813                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
 814                 {
 815                         // crosshair rings for weapon stats
 816                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
 817                         {
 818                                 // declarations and stats
 819                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
 820                                 string ring_image = string_null, ring_inner_image = string_null;
 821                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
 822
 823                                 ring_scale = autocvar_crosshair_ring_size;
 824
 825                                 float weapon_clipload, weapon_clipsize;
 826                                 weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
 827                                 weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
 828
 829                                 float ok_ammo_charge, ok_ammo_chargepool;
 830                                 ok_ammo_charge = getstatf(STAT_OK_AMMO_CHARGE);
 831                                 ok_ammo_chargepool = getstatf(STAT_OK_AMMO_CHARGEPOOL);
 832
 833                                 float vortex_charge, vortex_chargepool;
 834                                 vortex_charge = getstatf(STAT_VORTEX_CHARGE);
 835                                 vortex_chargepool = getstatf(STAT_VORTEX_CHARGEPOOL);
 836
 837                                 float arc_heat = getstatf(STAT_ARC_HEAT);
 838
 839                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
 840                                         vortex_charge_movingavg = vortex_charge;
 841
 842
 843                                 // handle the values
 844                                 if (autocvar_crosshair_ring && activeweapon == WEP_VORTEX.m_id && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
 845                                 {
 846                                         if (vortex_chargepool || use_vortex_chargepool) {
 847                                                 use_vortex_chargepool = 1;
 848                                                 ring_inner_value = vortex_chargepool;
 849                                         } else {
 850                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
 851                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
 852                                         }
 853
 854                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
 855                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
 856                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
 857
 858                                         // draw the outer ring to show the current charge of the weapon
 859                                         ring_value = vortex_charge;
 860                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
 861                                         ring_rgb = wcross_color;
 862                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
 863                                 }
 864                                 else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER.m_id && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
 865                                 {
 866                                         ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
 867                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
 868                                         ring_rgb = wcross_color;
 869                                         ring_image = "gfx/crosshair_ring.tga";
 870                                 }
 871                                 else if (activeweapon == WEP_HAGAR.m_id && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
 872                                 {
 873                                         ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
 874                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
 875                                         ring_rgb = wcross_color;
 876                                         ring_image = "gfx/crosshair_ring.tga";
 877                                 }
 878                                 else if (ok_ammo_charge)
 879                                 {
 880                                         ring_value = ok_ammo_chargepool;
 881                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
 882                                         ring_rgb = wcross_color;
 883                                         ring_image = "gfx/crosshair_ring.tga";
 884                                 }
 885                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
 886                                 {
 887                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
 888                                         ring_scale = autocvar_crosshair_ring_reload_size;
 889                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
 890                                         ring_rgb = wcross_color;
 891
 892                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
 893                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
 894                                         if ((activeweapon == WEP_RIFLE.m_id) && (weapon_clipsize == 80))
 895                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
 896                                         else
 897                                                 ring_image = "gfx/crosshair_ring.tga";
 898                                 }
 899                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && activeweapon == WEP_ARC.m_id )
 900                                 {
 901                                         ring_value = arc_heat;
 902                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
 903                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
 904                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
 905                                         ring_image = "gfx/crosshair_ring.tga";
 906                                 }
 907
 908                                 // if in weapon switch animation, fade ring out/in
 909                                 if(autocvar_crosshair_effect_time > 0)
 910                                 {
 911                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
 912                                         if (f >= 1)
 913                                         {
 914                                                 wcross_ring_prev = ((ring_image) ? true : false);
 915                                         }
 916
 917                                         if(wcross_ring_prev)
 918                                         {
 919                                                 if(f < 1)
 920                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
 921                                         }
 922                                         else
 923                                         {
 924                                                 if(f < 1)
 925                                                         ring_alpha *= bound(0, f, 1);
 926                                         }
 927                                 }
 928
 929                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
 930                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
 931
 932                                 if (ring_value)
 933                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
 934                         }
 935
 936 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
 937                         do \
 938                         { \
 939                                 if(wcross_blur > 0) \
 940                                 { \
 941                                         for(i = -2; i <= 2; ++i) \
 942                                         for(j = -2; j <= 2; ++j) \
 943                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
 944                                 } \
 945                                 else \
 946                                 { \
 947                                         M(0,0,sz,wcross_name,wcross_alpha); \
 948                                 } \
 949                         } \
 950                         while(0)
 951
 952 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
 953                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
 954
 955 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
 956                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
 957
 958                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
 959                         {
 960                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
 961                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
 962                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
 963                                 f = 1 - f;
 964                         }
 965                         else
 966                         {
 967                                 f = 1;
 968                         }
 969                         wcross_name_alpha_goal_prev = f;
 970
 971                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
 972                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
 973
 974                         if(autocvar_crosshair_dot)
 975                         {
 976                                 vector wcross_color_old;
 977                                 wcross_color_old = wcross_color;
 978
 979                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
 980                                         wcross_color = stov(autocvar_crosshair_dot_color);
 981
 982                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
 983                                 // FIXME why don't we use wcross_alpha here?cl_notice_run();
 984                                 wcross_color = wcross_color_old;
 985                         }
 986                 }
 987         }
 988         else
 989         {
 990                 wcross_scale_prev = 0;
 991                 wcross_alpha_prev = 0;
 992                 wcross_scale_goal_prev = 0;
 993                 wcross_alpha_goal_prev = 0;
 994                 wcross_changedonetime = 0;
 995                 if(wcross_name_goal_prev)
 996                         strunzone(wcross_name_goal_prev);
 997                 wcross_name_goal_prev = string_null;
 998                 if(wcross_name_goal_prev_prev)
 999                         strunzone(wcross_name_goal_prev_prev);
1000                 wcross_name_goal_prev_prev = string_null;
1001                 wcross_name_changestarttime = 0;
1002                 wcross_name_changedonetime = 0;
1003                 wcross_name_alpha_goal_prev = 0;
1004                 wcross_name_alpha_goal_prev_prev = 0;
1005                 wcross_resolution_goal_prev = 0;
1006                 wcross_resolution_goal_prev_prev = 0;
1007         }
1008 }
1009
1010 const int BUTTON_3 = 4;
1011 const int BUTTON_4 = 8;
1012 float cl_notice_run();
1013 float prev_myteam;
1014 int lasthud;
1015 float vh_notice_time;
1016 void WaypointSprite_Load();
1017 void CSQC_UpdateView(float w, float h)
1018 {
1019         entity e;
1020         float fov;
1021         float f;
1022         int i;
1023         vector vf_size, vf_min;
1024         float a;
1025
1026         execute_next_frame();
1027
1028         ++framecount;
1029
1030         hud = getstati(STAT_HUD);
1031
1032         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1033                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1034
1035         lasthud = hud;
1036
1037         if(autocvar__hud_showbinds_reload) // menu can set this one
1038         {
1039                 db_close(binddb);
1040                 binddb = db_create();
1041                 cvar_set("_hud_showbinds_reload", "0");
1042         }
1043
1044         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1045                 view_quality = getproperty(VF_MINFPS_QUALITY);
1046         else
1047                 view_quality = 1;
1048
1049         button_attack2 = (input_buttons & BUTTON_3);
1050         button_zoom = (input_buttons & BUTTON_4);
1051
1052 #define CHECKFAIL_ASSERT(flag,func,parm,val) do {                                                                   \
1053         float checkfailv = (func)(parm);                                                                                \
1054         if (checkfailv != (val)) {                                                                                      \
1055                 if (!checkfail[(flag)])                                                                                     \
1056                 localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv));                           \
1057                 checkfail[(flag)] = 1;                                                                                      \
1058         }                                                                                                               \
1059 } while(0)
1060         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
1061         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
1062         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
1063         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
1064         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
1065         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
1066         CHECKFAIL_ASSERT(6, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
1067
1068         vf_size = getpropertyvec(VF_SIZE);
1069         vf_min = getpropertyvec(VF_MIN);
1070         vid_width = vf_size.x;
1071         vid_height = vf_size.y;
1072
1073         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1074         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1075
1076         WaypointSprite_Load();
1077
1078         CSQCPlayer_SetCamera();
1079
1080         if(player_localentnum <= maxclients) // is it a client?
1081                 current_player = player_localentnum - 1;
1082         else // then player_localentnum is the vehicle I'm driving
1083                 current_player = player_localnum;
1084         myteam = GetPlayerColor(current_player);
1085
1086         if(myteam != prev_myteam)
1087         {
1088                 myteamcolors = colormapPaletteColor(myteam, 1);
1089                 for(i = 0; i < HUD_PANEL_NUM; ++i)
1090                         hud_panel[i].update_time = time;
1091                 prev_myteam = myteam;
1092         }
1093
1094         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
1095
1096         float is_dead = (getstati(STAT_HEALTH) <= 0);
1097
1098         // FIXME do we need this hack?
1099         if(isdemo())
1100         {
1101                 // in demos, input_buttons do not work
1102                 button_zoom = (autocvar__togglezoom == "-");
1103         }
1104         else if(button_zoom
1105                 && autocvar_cl_unpress_zoom_on_death
1106                 && (spectatee_status >= 0)
1107                 && (is_dead || intermission))
1108         {
1109                 // no zoom while dead or in intermission please
1110                 localcmd("-zoom\n");
1111                 button_zoom = false;
1112         }
1113
1114         // event chase camera
1115         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1116         {
1117                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1118                 float ons_roundlost = (gametype == MAPINFO_TYPE_ONSLAUGHT && getstati(STAT_ROUNDLOST));
1119                 entity gen = world;
1120
1121                 if(ons_roundlost)
1122                 {
1123                         entity e;
1124                         for(e = world; (e = find(e, classname, "onslaught_generator")); )
1125                         {
1126                                 if(e.health <= 0)
1127                                 {
1128                                         gen = e;
1129                                         break;
1130                                 }
1131                         }
1132                         if(!gen)
1133                                 ons_roundlost = FALSE; // don't enforce the 3rd person camera if there is no dead generator to show
1134                 }
1135                 if(WantEventchase() || (!autocvar_cl_orthoview && ons_roundlost))
1136                 {
1137                         eventchase_running = true;
1138
1139                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1140                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1141                         if(ons_roundlost) { current_view_origin = gen.origin; }
1142
1143                         // detect maximum viewoffset and use it
1144                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1145                         if(vehicle_chase && autocvar_cl_eventchase_vehicle_viewoffset) { view_offset = autocvar_cl_eventchase_vehicle_viewoffset; }
1146                         if(ons_roundlost) { view_offset = autocvar_cl_eventchase_generator_viewoffset; }
1147
1148                         if(view_offset)
1149                         {
1150                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, self);
1151                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1152                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1153                         }
1154
1155                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1156                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1157                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1158                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1159
1160                         // make the camera smooth back
1161                         float chase_distance = autocvar_cl_eventchase_distance;
1162                         if(vehicle_chase && autocvar_cl_eventchase_vehicle_distance) { chase_distance = autocvar_cl_eventchase_vehicle_distance; }
1163                         if(ons_roundlost) { chase_distance = autocvar_cl_eventchase_generator_distance; }
1164
1165                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1166                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1167                         else if(eventchase_current_distance != chase_distance)
1168                                 eventchase_current_distance = chase_distance;
1169
1170                         makevectors(view_angles);
1171
1172                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1173                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
1174
1175                         // If the boxtrace fails, revert back to line tracing.
1176                         if(!self.viewloc)
1177                         if(trace_startsolid)
1178                         {
1179                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1180                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
1181                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1182                         }
1183                         else { setproperty(VF_ORIGIN, trace_endpos); }
1184
1185                         if(!self.viewloc)
1186                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1187                 }
1188                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1189                 {
1190                         eventchase_running = false;
1191                         cvar_set("chase_active", "0");
1192                         eventchase_current_distance = 0; // start from 0 next time
1193                 }
1194         }
1195         // workaround for camera stuck between player's legs when using chase_active 1
1196         // because the engine stops updating the chase_active camera when the game ends
1197         else if(intermission)
1198         {
1199                 cvar_settemp("chase_active", "-1");
1200                 eventchase_current_distance = 0;
1201         }
1202
1203         // do lockview after event chase camera so that it still applies whenever necessary.
1204         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1)))
1205         {
1206                 setproperty(VF_ORIGIN, freeze_org);
1207                 setproperty(VF_ANGLES, freeze_ang);
1208         }
1209         else
1210         {
1211                 freeze_org = getpropertyvec(VF_ORIGIN);
1212                 freeze_ang = getpropertyvec(VF_ANGLES);
1213         }
1214
1215         WarpZone_FixView();
1216         //WarpZone_FixPMove();
1217
1218         vector ov_org = '0 0 0';
1219         vector ov_mid = '0 0 0';
1220         vector ov_worldmin = '0 0 0';
1221         vector ov_worldmax = '0 0 0';
1222         if(autocvar_cl_orthoview)
1223         {
1224                 ov_worldmin = mi_picmin;
1225                 ov_worldmax = mi_picmax;
1226
1227                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1228                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1229                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1230
1231                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1232                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1233
1234                 float ov_nearest = vlen(ov_org - vec3(
1235                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1236                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1237                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1238                 ));
1239
1240                 float ov_furthest = 0;
1241                 float dist = 0;
1242
1243                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1244                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1245                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1246                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1247                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1248                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1249                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1250                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1251
1252                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1253                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1254                 cvar_settemp("r_farclip_world", "0");
1255                 cvar_settemp("r_novis", "1");
1256                 cvar_settemp("r_useportalculling", "0");
1257                 cvar_settemp("r_useinfinitefarclip", "0");
1258
1259                 setproperty(VF_ORIGIN, ov_org);
1260                 setproperty(VF_ANGLES, '90 0 0');
1261
1262                 #if 0
1263                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1264                         vtos(ov_org),
1265                         vtos(getpropertyvec(VF_ANGLES)),
1266                         ov_distance,
1267                         ov_nearest,
1268                         ov_furthest);
1269                 #endif
1270         }
1271
1272         // Render the Scene
1273         view_origin = getpropertyvec(VF_ORIGIN);
1274         view_angles = getpropertyvec(VF_ANGLES);
1275         makevectors(view_angles);
1276         view_forward = v_forward;
1277         view_right = v_right;
1278         view_up = v_up;
1279
1280 #ifdef BLURTEST
1281         if(time > blurtest_time0 && time < blurtest_time1)
1282         {
1283                 float r, t;
1284
1285                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1286                 r = t * blurtest_radius;
1287                 f = 1 / pow(t, blurtest_power) - 1;
1288
1289                 cvar_set("r_glsl_postprocess", "1");
1290                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1291         }
1292         else
1293         {
1294                 cvar_set("r_glsl_postprocess", "0");
1295                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1296         }
1297 #endif
1298
1299         TargetMusic_Advance();
1300         Fog_Force();
1301
1302         if(drawtime == 0)
1303                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1304         else
1305                 drawframetime = bound(0.000001, time - drawtime, 1);
1306         drawtime = time;
1307
1308         // watch for gametype changes here...
1309         // in ParseStuffCMD the cmd isn't executed yet :/
1310         // might even be better to add the gametype to TE_CSQC_INIT...?
1311         if(!postinit)
1312                 PostInit();
1313
1314         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1315         {
1316                 if(calledhooks & HOOK_START)
1317                 {
1318                         localcmd("\ncl_hook_gameend\n");
1319                         calledhooks |= HOOK_END;
1320                 }
1321         }
1322
1323         Announcer();
1324
1325         fov = autocvar_fov;
1326         if(fov <= 59.5)
1327         {
1328                 if(!zoomscript_caught)
1329                 {
1330                         localcmd("+button9\n");
1331                         zoomscript_caught = 1;
1332                 }
1333         }
1334         else
1335         {
1336                 if(zoomscript_caught)
1337                 {
1338                         localcmd("-button9\n");
1339                         zoomscript_caught = 0;
1340                 }
1341         }
1342
1343         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1344
1345         // next WANTED weapon (for HUD)
1346         switchweapon = getstati(STAT_SWITCHWEAPON);
1347
1348         // currently switching-to weapon (for crosshair)
1349         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
1350
1351         // actually active weapon (for zoom)
1352         activeweapon = getstati(STAT_ACTIVEWEAPON);
1353
1354         f = (serverflags & SERVERFLAG_TEAMPLAY);
1355         if(f != teamplay)
1356         {
1357                 teamplay = f;
1358                 HUD_InitScores();
1359         }
1360
1361         if(last_switchweapon != switchweapon)
1362         {
1363                 weapontime = time;
1364                 last_switchweapon = switchweapon;
1365                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1366                 {
1367                         localcmd("-zoom\n");
1368                         button_zoom = false;
1369                 }
1370                 if(autocvar_cl_unpress_attack_on_weapon_switch)
1371                 {
1372                         localcmd("-fire\n");
1373                         localcmd("-fire2\n");
1374                         button_attack2 = false;
1375                 }
1376         }
1377         if(last_activeweapon != activeweapon)
1378         {
1379                 last_activeweapon = activeweapon;
1380
1381                 e = get_weaponinfo(activeweapon);
1382                 if(e.netname != "")
1383                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1384                 else
1385                         localcmd("\ncl_hook_activeweapon none\n");
1386         }
1387
1388         // ALWAYS Clear Current Scene First
1389         clearscene();
1390
1391         setproperty(VF_ORIGIN, view_origin);
1392         setproperty(VF_ANGLES, view_angles);
1393
1394         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1395         setproperty(VF_SIZE, vf_size);
1396         setproperty(VF_MIN, vf_min);
1397
1398         // Assign Standard Viewflags
1399         // Draw the World (and sky)
1400         setproperty(VF_DRAWWORLD, 1);
1401
1402         // Set the console size vars
1403         vid_conwidth = autocvar_vid_conwidth;
1404         vid_conheight = autocvar_vid_conheight;
1405         vid_pixelheight = autocvar_vid_pixelheight;
1406
1407         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1408         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1409         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1410
1411         // Camera for demo playback
1412         if(camera_active)
1413         {
1414                 if(autocvar_camera_enable)
1415                         CSQC_Demo_Camera();
1416                 else
1417                 {
1418                         cvar_set("chase_active", ftos(chase_active_backup));
1419                         cvar_set("cl_demo_mousegrab", "0");
1420                         camera_active = false;
1421                 }
1422         }
1423         else
1424         {
1425 #ifdef CAMERATEST
1426                 if(autocvar_camera_enable)
1427 #else
1428                 if(autocvar_camera_enable && isdemo())
1429 #endif
1430                 {
1431                         // Enable required Darkplaces cvars
1432                         chase_active_backup = autocvar_chase_active;
1433                         cvar_set("chase_active", "2");
1434                         cvar_set("cl_demo_mousegrab", "1");
1435                         camera_active = true;
1436                         camera_mode = false;
1437                 }
1438         }
1439
1440         // Draw the Crosshair
1441         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1442
1443         // Draw the Engine Status Bar (the default Quake HUD)
1444         setproperty(VF_DRAWENGINESBAR, 0);
1445
1446         // Update the mouse position
1447         /*
1448            mousepos_x = vid_conwidth;
1449            mousepos_y = vid_conheight;
1450            mousepos = mousepos*0.5 + getmousepos();
1451          */
1452
1453         e = self;
1454         for(self = world; (self = nextent(self)); )
1455                 if(self.draw)
1456                         self.draw();
1457         self = e;
1458
1459         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1460         renderscene();
1461
1462         // now switch to 2D drawing mode by calling a 2D drawing function
1463         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1464         // next R_RenderScene call
1465         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1466
1467         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1468         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1469         {
1470                 // apply night vision effect
1471                 vector tc_00, tc_01, tc_10, tc_11;
1472                 vector rgb = '0 0 0';
1473
1474                 if(!nightvision_noise)
1475                 {
1476                         nightvision_noise = spawn();
1477                         nightvision_noise.classname = "nightvision_noise";
1478                 }
1479                 if(!nightvision_noise2)
1480                 {
1481                         nightvision_noise2 = spawn();
1482                         nightvision_noise2.classname = "nightvision_noise2";
1483                 }
1484
1485                 // color tint in yellow
1486                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1487
1488                 // draw BG
1489                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1490                 rgb = '1 1 1';
1491                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1492                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1493                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1494                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1495                 tc_11 = tc_01 + tc_10 - tc_00;
1496                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1497                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1498                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1499                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1500                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1501                 R_EndPolygon();
1502
1503                 // draw FG
1504                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1505                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1506                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1507                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1508                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1509                 tc_11 = tc_01 + tc_10 - tc_00;
1510                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1511                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1512                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1513                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1514                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1515                 R_EndPolygon();
1516         }
1517
1518         if(autocvar_cl_reticle)
1519         {
1520                 // Draw the aiming reticle for weapons that use it
1521                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
1522                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
1523                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
1524                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
1525                 {
1526                         // no zoom reticle while dead
1527                         reticle_type = 0;
1528                 }
1529                 else if(WEP_ACTION(activeweapon, WR_ZOOMRETICLE) && autocvar_cl_reticle_weapon)
1530                 {
1531                         if(reticle_image != "") { reticle_type = 2; }
1532                         else { reticle_type = 0; }
1533                 }
1534                 else if(button_zoom || zoomscript_caught)
1535                 {
1536                         // normal zoom
1537                         reticle_type = 1;
1538                 }
1539
1540                 if(reticle_type)
1541                 {
1542                         if(autocvar_cl_reticle_stretch)
1543                         {
1544                                 reticle_size.x = vid_conwidth;
1545                                 reticle_size.y = vid_conheight;
1546                                 reticle_pos.x = 0;
1547                                 reticle_pos.y = 0;
1548                         }
1549                         else
1550                         {
1551                                 reticle_size.x = max(vid_conwidth, vid_conheight);
1552                                 reticle_size.y = max(vid_conwidth, vid_conheight);
1553                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
1554                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
1555                         }
1556
1557                         if(zoomscript_caught)
1558                                 f = 1;
1559                         else
1560                                 f = current_zoomfraction;
1561
1562                         if(f)
1563                         {
1564                                 switch(reticle_type)
1565                                 {
1566                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
1567                                         case 2: drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
1568                                 }
1569                         }
1570                 }
1571         }
1572         else
1573         {
1574                 if(reticle_type != 0) { reticle_type = 0; }
1575         }
1576
1577
1578         // improved polyblend
1579         if(autocvar_hud_contents)
1580         {
1581                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
1582                 vector liquidcolor;
1583
1584                 switch(pointcontents(view_origin))
1585                 {
1586                         case CONTENT_WATER:
1587                                 liquidalpha = autocvar_hud_contents_water_alpha;
1588                                 liquidcolor = stov(autocvar_hud_contents_water_color);
1589                                 incontent = 1;
1590                                 break;
1591
1592                         case CONTENT_LAVA:
1593                                 liquidalpha = autocvar_hud_contents_lava_alpha;
1594                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
1595                                 incontent = 1;
1596                                 break;
1597
1598                         case CONTENT_SLIME:
1599                                 liquidalpha = autocvar_hud_contents_slime_alpha;
1600                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
1601                                 incontent = 1;
1602                                 break;
1603
1604                         default:
1605                                 liquidalpha = 0;
1606                                 liquidcolor = '0 0 0';
1607                                 incontent = 0;
1608                                 break;
1609                 }
1610
1611                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
1612                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
1613                         contentfadetime = autocvar_hud_contents_fadeintime;
1614                         liquidalpha_prev = liquidalpha;
1615                         liquidcolor_prev = liquidcolor;
1616                 }
1617                 else
1618                         contentfadetime = autocvar_hud_contents_fadeouttime;
1619
1620                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
1621                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
1622
1623                 if(contentavgalpha)
1624                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
1625
1626                 if(autocvar_hud_postprocessing)
1627                 {
1628                         if(autocvar_hud_contents_blur && contentavgalpha)
1629                         {
1630                                 content_blurpostprocess.x = 1;
1631                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
1632                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
1633                         }
1634                         else
1635                         {
1636                                 content_blurpostprocess.x = 0;
1637                                 content_blurpostprocess.y = 0;
1638                                 content_blurpostprocess.z = 0;
1639                         }
1640                 }
1641         }
1642
1643         if(autocvar_hud_damage && !getstati(STAT_FROZEN))
1644         {
1645                 splash_size.x = max(vid_conwidth, vid_conheight);
1646                 splash_size.y = max(vid_conwidth, vid_conheight);
1647                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
1648                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
1649
1650                 float myhealth_flash_temp;
1651                 myhealth = getstati(STAT_HEALTH);
1652
1653                 // fade out
1654                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
1655                 // add new damage
1656                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
1657
1658                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
1659                 pain_threshold = autocvar_hud_damage_pain_threshold;
1660                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
1661                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
1662
1663                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
1664                 {
1665                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
1666                 }
1667
1668                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
1669
1670                 if(myhealth_prev < 1)
1671                 {
1672                         if(myhealth >= 1)
1673                         {
1674                                 myhealth_flash = 0; // just spawned, clear the flash immediately
1675                                 myhealth_flash_temp = 0;
1676                         }
1677                         else
1678                         {
1679                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
1680                         }
1681                 }
1682
1683                 if(spectatee_status == -1 || intermission)
1684                 {
1685                         myhealth_flash = 0; // observing, or match ended
1686                         myhealth_flash_temp = 0;
1687                 }
1688
1689                 myhealth_prev = myhealth;
1690
1691                 // IDEA: change damage color/picture based on player model for robot/alien species?
1692                 // pro: matches model better
1693                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
1694                 // maybe different reddish pics?
1695                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
1696                 {
1697                         if(autocvar_cl_gentle_damage == 2)
1698                         {
1699                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
1700                                 {
1701                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
1702                                 }
1703                         }
1704                         else
1705                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
1706
1707                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1708                 }
1709                 else
1710                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1711
1712                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
1713                 {
1714                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
1715                         {
1716                                 damage_blurpostprocess.x = 1;
1717                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
1718                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
1719                         }
1720                         else
1721                         {
1722                                 damage_blurpostprocess.x = 0;
1723                                 damage_blurpostprocess.y = 0;
1724                                 damage_blurpostprocess.z = 0;
1725                         }
1726                 }
1727         }
1728
1729         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
1730         float e2 = (autocvar_hud_powerup != 0);
1731         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
1732         {
1733                 // enable or disable rendering types if they are used or not
1734                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
1735                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
1736
1737                 // blur postprocess handling done first (used by hud_damage and hud_contents)
1738                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
1739                 {
1740                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
1741                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
1742                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
1743                         {
1744                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
1745                                 old_blurradius = blurradius;
1746                                 old_bluralpha = bluralpha;
1747                         }
1748                 }
1749                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
1750                 {
1751                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1752                         old_blurradius = 0;
1753                         old_bluralpha = 0;
1754                 }
1755
1756                 // edge detection postprocess handling done second (used by hud_powerup)
1757                 float sharpen_intensity = 0, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
1758                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
1759                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
1760
1761                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
1762
1763                 if(autocvar_hud_powerup && sharpen_intensity > 0)
1764                 {
1765                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
1766                         {
1767                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
1768                                 old_sharpen_intensity = sharpen_intensity;
1769                         }
1770                 }
1771                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
1772                 {
1773                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
1774                         old_sharpen_intensity = 0;
1775                 }
1776
1777                 if(cvar("r_glsl_postprocess") == 0)
1778                         cvar_set("r_glsl_postprocess", "2");
1779         }
1780         else if(cvar("r_glsl_postprocess") == 2)
1781                 cvar_set("r_glsl_postprocess", "0");
1782
1783         if(menu_visible)
1784                 menu_show();
1785
1786         /*if(gametype == MAPINFO_TYPE_CTF)
1787           {
1788           ctf_view();
1789           } else */
1790
1791         // draw 2D entities
1792         e = self;
1793         for(self = world; (self = nextent(self)); )
1794                 if(self.draw2d)
1795                         self.draw2d();
1796         self = e;
1797         Draw_ShowNames_All();
1798
1799         scoreboard_active = HUD_WouldDrawScoreboard();
1800
1801         UpdateDamage();
1802         UpdateCrosshair();
1803         UpdateHitsound();
1804
1805         if(NextFrameCommand)
1806         {
1807                 localcmd("\n", NextFrameCommand, "\n");
1808                 NextFrameCommand = string_null;
1809         }
1810
1811         // we must do this check AFTER a frame was rendered, or it won't work
1812         if(cs_project_is_b0rked == 0)
1813         {
1814                 string w0, h0;
1815                 w0 = ftos(autocvar_vid_conwidth);
1816                 h0 = ftos(autocvar_vid_conheight);
1817                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1818                 //setproperty(VF_FOV, '90 90 0');
1819                 setproperty(VF_ORIGIN, '0 0 0');
1820                 setproperty(VF_ANGLES, '0 0 0');
1821                 setproperty(VF_PERSPECTIVE, 1);
1822                 makevectors('0 0 0');
1823                 vector v1, v2;
1824                 cvar_set("vid_conwidth", "800");
1825                 cvar_set("vid_conheight", "600");
1826                 v1 = cs_project(v_forward);
1827                 cvar_set("vid_conwidth", "640");
1828                 cvar_set("vid_conheight", "480");
1829                 v2 = cs_project(v_forward);
1830                 if(v1 == v2)
1831                         cs_project_is_b0rked = 1;
1832                 else
1833                         cs_project_is_b0rked = -1;
1834                 cvar_set("vid_conwidth", w0);
1835                 cvar_set("vid_conheight", h0);
1836         }
1837
1838         if(autocvar__hud_configure)
1839                 HUD_Panel_Mouse();
1840         else if ( HUD_MinigameMenu_IsOpened() || minigame_isactive() )
1841                 HUD_Minigame_Mouse();
1842         else
1843                 HUD_Radar_Mouse();
1844
1845     if(hud && !intermission)
1846     if(hud == HUD_BUMBLEBEE_GUN)
1847         CSQC_BUMBLE_GUN_HUD();
1848     else
1849                 VEH_ACTION(hud, VR_HUD);
1850
1851         cl_notice_run();
1852
1853         // let's reset the view back to normal for the end
1854         setproperty(VF_MIN, '0 0 0');
1855         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1856 }
1857
1858
1859 void CSQC_common_hud(void)
1860 {
1861         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1862                 Accuracy_LoadLevels();
1863
1864         HUD_Main(); // always run these functions for alpha checks
1865         HUD_DrawScoreboard();
1866
1867         // scoreboard/accuracy, map/gametype voting screen
1868         if (scoreboard_active || intermission == 2)
1869                 HUD_Reset();
1870 }
1871
1872
1873 // following vectors must be global to allow seamless switching between camera modes
1874 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1875 void CSQC_Demo_Camera()
1876 {
1877         float speed, attenuation, dimensions;
1878         vector tmp, delta;
1879
1880         if( autocvar_camera_reset || !camera_mode )
1881         {
1882                 camera_offset = '0 0 0';
1883                 current_angles = '0 0 0';
1884                 camera_direction = '0 0 0';
1885                 camera_offset.z += 30;
1886                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
1887                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
1888                 current_origin = view_origin;
1889                 current_camera_offset  = camera_offset;
1890                 cvar_set("camera_reset", "0");
1891                 camera_mode = CAMERA_CHASE;
1892         }
1893
1894         // Camera angles
1895         if( camera_roll )
1896                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
1897
1898         if(autocvar_camera_look_player)
1899         {
1900                 vector dir;
1901                 float n;
1902
1903                 dir = normalize(view_origin - current_position);
1904                 n = mouse_angles.z;
1905                 mouse_angles = vectoangles(dir);
1906                 mouse_angles.x = mouse_angles.x * -1;
1907                 mouse_angles.z = n;
1908         }
1909         else
1910         {
1911                 tmp = getmousepos() * 0.1;
1912                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1913                 {
1914                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
1915                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
1916                 }
1917         }
1918
1919         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
1920         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
1921         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
1922         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
1923
1924         // Fix difference when angles don't have the same sign
1925         delta = '0 0 0';
1926         if(mouse_angles.y < -60 && current_angles.y > 60)
1927                 delta = '0 360 0';
1928         if(mouse_angles.y > 60 && current_angles.y < -60)
1929                 delta = '0 -360 0';
1930
1931         if(autocvar_camera_look_player)
1932                 attenuation = autocvar_camera_look_attenuation;
1933         else
1934                 attenuation = autocvar_camera_speed_attenuation;
1935
1936         attenuation = 1 / max(1, attenuation);
1937         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1938
1939         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
1940         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
1941         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
1942         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
1943
1944         // Camera position
1945         tmp = '0 0 0';
1946         dimensions = 0;
1947
1948         if( camera_direction.x )
1949         {
1950                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
1951                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
1952                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1953                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
1954                 ++dimensions;
1955         }
1956
1957         if( camera_direction.y )
1958         {
1959                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
1960                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
1961                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
1962                 ++dimensions;
1963         }
1964
1965         if( camera_direction.z )
1966         {
1967                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
1968                 ++dimensions;
1969         }
1970
1971         if(autocvar_camera_free)
1972                 speed = autocvar_camera_speed_free;
1973         else
1974                 speed = autocvar_camera_speed_chase;
1975
1976         if(dimensions)
1977         {
1978                 speed = speed * sqrt(1 / dimensions);
1979                 camera_offset += tmp * speed;
1980         }
1981
1982         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1983
1984         // Camera modes
1985         if( autocvar_camera_free )
1986         {
1987                 if ( camera_mode == CAMERA_CHASE )
1988                 {
1989                         current_camera_offset = current_origin + current_camera_offset;
1990                         camera_offset = current_origin + camera_offset;
1991                 }
1992
1993                 camera_mode = CAMERA_FREE;
1994                 current_position = current_camera_offset;
1995         }
1996         else
1997         {
1998                 if ( camera_mode == CAMERA_FREE )
1999                 {
2000                         current_origin = view_origin;
2001                         camera_offset = camera_offset - current_origin;
2002                         current_camera_offset = current_camera_offset - current_origin;
2003                 }
2004
2005                 camera_mode = CAMERA_CHASE;
2006
2007                 if(autocvar_camera_chase_smoothly)
2008                         current_origin += (view_origin - current_origin) * attenuation;
2009                 else
2010                         current_origin = view_origin;
2011
2012                 current_position = current_origin + current_camera_offset;
2013         }
2014
2015         setproperty(VF_ANGLES, current_angles);
2016         setproperty(VF_ORIGIN, current_position);
2017 }