qcsrc/client/view.qc

   1 #include "view.qh"
   2
   3 #include "announcer.qh"
   4 #include "hud/_mod.qh"
   5 #include "mapvoting.qh"
   6 #include "shownames.qh"
   7 #include "hud/panel/scoreboard.qh"
   8 #include "hud/panel/quickmenu.qh"
   9
  10 #include "mutators/events.qh"
  11
  12 #include <common/animdecide.qh>
  13 #include <common/ent_cs.qh>
  14 #include <common/anim.qh>
  15 #include <common/constants.qh>
  16 #include <common/debug.qh>
  17 #include <common/mapinfo.qh>
  18 #include <common/gamemodes/_mod.qh>
  19 #include <common/physics/player.qh>
  20 #include <common/stats.qh>
  21 #include <common/triggers/target/music.qh>
  22 #include <common/teams.qh>
  23
  24 #include <common/vehicles/all.qh>
  25 #include <common/weapons/_all.qh>
  26 #include <common/viewloc.qh>
  27 #include <common/minigames/cl_minigames.qh>
  28 #include <common/minigames/cl_minigames_hud.qh>
  29
  30 #include <lib/csqcmodel/cl_player.qh>
  31 #include <lib/csqcmodel/cl_model.qh>
  32 #include "csqcmodel_hooks.qh"
  33
  34 #include <lib/warpzone/client.qh>
  35 #include <lib/warpzone/common.qh>
  36
  37 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
  38
  39 float autocvar_cl_viewmodel_scale;
  40
  41 bool autocvar_cl_bobmodel;
  42 float autocvar_cl_bobmodel_speed;
  43 float autocvar_cl_bobmodel_side;
  44 float autocvar_cl_bobmodel_up;
  45
  46 float autocvar_cl_followmodel;
  47 float autocvar_cl_followmodel_speed = 0.3;
  48 float autocvar_cl_followmodel_limit = 135;
  49 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
  50 float autocvar_cl_followmodel_highpass = 0.05;
  51 float autocvar_cl_followmodel_lowpass = 0.03;
  52 bool autocvar_cl_followmodel_velocity_absolute;
  53
  54 float autocvar_cl_leanmodel;
  55 float autocvar_cl_leanmodel_speed = 0.3;
  56 float autocvar_cl_leanmodel_limit = 30;
  57 float autocvar_cl_leanmodel_highpass1 = 0.2;
  58 float autocvar_cl_leanmodel_highpass = 0.2;
  59 float autocvar_cl_leanmodel_lowpass = 0.05;
  60
  61 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
  62 #define lowpass(value, frac, ref_store, ret) MACRO_BEGIN \
  63 { \
  64         ret = ref_store = ref_store * (1 - frac) + (value) * frac; \
  65 } MACRO_END
  66
  67 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  68 { \
  69         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  70         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  71 } MACRO_END
  72
  73 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
  74 { \
  75         float __f = 0; lowpass(value, frac, ref_store, __f); \
  76         ret = (value) - __f; \
  77 } MACRO_END
  78
  79 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  80 { \
  81         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
  82         ret = (value) - __f; \
  83 } MACRO_END
  84
  85 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  86 { \
  87         lowpass(value.x, frac, ref_store.x, ref_out.x); \
  88         lowpass(value.y, frac, ref_store.y, ref_out.y); \
  89 } MACRO_END
  90
  91 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  92 { \
  93         highpass(value.x, frac, ref_store.x, ref_out.x); \
  94         highpass(value.y, frac, ref_store.y, ref_out.y); \
  95 } MACRO_END
  96
  97 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
  98 { \
  99         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
 100         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
 101 } MACRO_END
 102
 103 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 104 { \
 105         lowpass(value.x, frac, ref_store.x, ref_out.x); \
 106         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 107         lowpass(value.z, frac, ref_store.z, ref_out.z); \
 108 } MACRO_END
 109
 110 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 111 { \
 112         highpass(value.x, frac, ref_store.x, ref_out.x); \
 113         highpass(value.y, frac, ref_store.y, ref_out.y); \
 114         highpass(value.z, frac, ref_store.z, ref_out.z); \
 115 } MACRO_END
 116
 117 void calc_followmodel_ofs(entity view)
 118 {
 119         if(cl_followmodel_time == time)
 120                 return; // cl_followmodel_ofs already calculated for this frame
 121
 122         float frac;
 123         vector gunorg = '0 0 0';
 124         static vector vel_average;
 125         static vector gunorg_prev = '0 0 0';
 126         static vector gunorg_adjustment_highpass;
 127         static vector gunorg_adjustment_lowpass;
 128
 129         vector vel;
 130         if (autocvar_cl_followmodel_velocity_absolute)
 131                 vel = view.velocity;
 132         else
 133         {
 134                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 135                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 136                 vel.x = view.velocity * forward;
 137                 vel.y = view.velocity * right * -1;
 138                 vel.z = view.velocity * up;
 139         }
 140
 141         vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
 142         vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
 143         vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
 144
 145         frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
 146         lowpass3(vel, frac, vel_average, gunorg);
 147
 148         gunorg *= -autocvar_cl_followmodel_speed * 0.042;
 149
 150         // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 151         // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 152         frac = avg_factor(autocvar_cl_followmodel_highpass);
 153         highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
 154         frac = avg_factor(autocvar_cl_followmodel_lowpass);
 155         lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
 156
 157         if (autocvar_cl_followmodel_velocity_absolute)
 158         {
 159                 vector fixed_gunorg;
 160                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 161                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 162                 fixed_gunorg.x = gunorg * forward;
 163                 fixed_gunorg.y = gunorg * right * -1;
 164                 fixed_gunorg.z = gunorg * up;
 165                 gunorg = fixed_gunorg;
 166         }
 167
 168         cl_followmodel_ofs = gunorg;
 169         cl_followmodel_time = time;
 170 }
 171
 172 vector leanmodel_ofs(entity view)
 173 {
 174         float frac;
 175         vector gunangles = '0 0 0';
 176         static vector gunangles_prev = '0 0 0';
 177         static vector gunangles_highpass = '0 0 0';
 178         static vector gunangles_adjustment_highpass;
 179         static vector gunangles_adjustment_lowpass;
 180
 181         if (view.csqcmodel_teleported)
 182                 gunangles_prev = view_angles;
 183
 184         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 185         gunangles_highpass += gunangles_prev;
 186         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 187         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 188         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 189         frac = avg_factor(autocvar_cl_leanmodel_highpass1);
 190         highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
 191         gunangles_prev = view_angles;
 192         gunangles_highpass -= gunangles_prev;
 193
 194         PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
 195         YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
 196
 197         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 198         frac = avg_factor(autocvar_cl_leanmodel_highpass);
 199         highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
 200         frac = avg_factor(autocvar_cl_leanmodel_lowpass);
 201         lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
 202
 203         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 204
 205         return gunangles;
 206 }
 207
 208 vector bobmodel_ofs(entity view)
 209 {
 210         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 211         static bool oldonground;
 212         static float hitgroundtime;
 213         if (clonground)
 214         {
 215                 float f = time; // cl.movecmd[0].time
 216                 if (!oldonground)
 217                         hitgroundtime = f;
 218         }
 219         oldonground = clonground;
 220
 221         // calculate for swinging gun model
 222         // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 223         vector gunorg = '0 0 0';
 224         static float bobmodel_scale = 0;
 225         static float time_ofs = 0; // makes the effect always restart in the same way
 226         if (clonground)
 227         {
 228                 if (time - hitgroundtime > 0.05)
 229                         bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
 230         }
 231         else
 232                 bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
 233
 234         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 235         if (bobmodel_scale && xyspeed)
 236         {
 237                 float bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
 238                 float s = (time - time_ofs) * autocvar_cl_bobmodel_speed;
 239                 gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
 240                 gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
 241         }
 242         else
 243                 time_ofs = time;
 244
 245         return gunorg;
 246 }
 247
 248 void viewmodel_animate(entity this)
 249 {
 250         if (autocvar_chase_active) return;
 251         if (STAT(HEALTH) <= 0) return;
 252
 253         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 254
 255         if (autocvar_cl_followmodel)
 256         {
 257                 calc_followmodel_ofs(view);
 258                 this.origin += cl_followmodel_ofs;
 259         }
 260
 261         if (autocvar_cl_leanmodel)
 262                 this.angles += leanmodel_ofs(view);
 263
 264         // vertical view bobbing code
 265         // TODO: cl_bob
 266
 267         // horizontal view bobbing code
 268         // TODO: cl_bob2
 269
 270         // fall bobbing code
 271         // causes the view to swing down and back up when touching the ground
 272         // TODO: cl_bobfall
 273
 274         // gun model bobbing code
 275         if (autocvar_cl_bobmodel)
 276                 this.origin += bobmodel_ofs(view);
 277 }
 278
 279 .vector viewmodel_origin, viewmodel_angles;
 280 .float weapon_nextthink;
 281 .float weapon_eta_last;
 282 .float weapon_switchdelay;
 283
 284 .string name_last;
 285
 286 void viewmodel_draw(entity this)
 287 {
 288         if(!this.activeweapon || !autocvar_r_drawviewmodel)
 289                 return;
 290         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 291         float a = this.alpha;
 292         static bool wasinvehicle;
 293         bool invehicle = player_localentnum > maxclients;
 294         if (invehicle) a = -1;
 295         else if (wasinvehicle) a = 1;
 296         wasinvehicle = invehicle;
 297         Weapon wep = this.activeweapon;
 298         int c = entcs_GetClientColors(current_player);
 299         vector g = weaponentity_glowmod(wep, NULL, c, this);
 300         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 301         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 302                 | EF_NODEPTHTEST)
 303                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 304         for (entity e = this; e; e = e.weaponchild)
 305         {
 306                 e.drawmask = mask;
 307                 e.alpha = a;
 308                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 309                 e.glowmod = g;
 310                 e.csqcmodel_effects = fx;
 311                 CSQCModel_Effects_Apply(e);
 312         }
 313         {
 314                 string name = wep.mdl;
 315                 bool swap = name != this.name_last;
 316                 // if (swap)
 317                 {
 318                         this.name_last = name;
 319                         CL_WeaponEntity_SetModel(this, name, swap);
 320                         this.viewmodel_origin = this.origin;
 321                         this.viewmodel_angles = this.angles;
 322                 }
 323                 anim_update(this);
 324                 if (!this.animstate_override && !this.animstate_looping)
 325                         anim_set(this, this.anim_idle, true, false, false);
 326         }
 327         float f = 0; // 0..1; 0: fully active
 328         float rate = STAT(WEAPONRATEFACTOR);
 329         float eta = rate ? ((this.weapon_nextthink - time) / rate) : 0;
 330         if (eta <= 0) f = this.weapon_eta_last;
 331         else switch (this.state)
 332         {
 333                 case WS_RAISE:
 334                 {
 335                         f = eta / max(eta, this.weapon_switchdelay);
 336                         break;
 337                 }
 338                 case WS_DROP:
 339                 {
 340                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 341                         break;
 342                 }
 343                 case WS_CLEAR:
 344                 {
 345                         f = 1;
 346                         break;
 347                 }
 348         }
 349         this.weapon_eta_last = f;
 350         this.origin = this.viewmodel_origin;
 351         this.angles = this.viewmodel_angles;
 352         this.angles_x = (-90 * f * f);
 353         viewmodel_animate(this);
 354         setorigin(this, this.origin);
 355 }
 356
 357 entity viewmodels[MAX_WEAPONSLOTS];
 358 STATIC_INIT(viewmodel) {
 359     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 360         viewmodels[slot] = new(viewmodel);
 361 }
 362
 363 void Porto_Draw(entity this);
 364 STATIC_INIT(Porto)
 365 {
 366         entity e = new_pure(porto);
 367         e.draw = Porto_Draw;
 368         IL_PUSH(g_drawables, e);
 369         e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 370 }
 371
 372 const int polyline_length = 16;
 373 vector polyline[polyline_length];
 374 void Porto_Draw(entity this)
 375 {
 376         entity wepent = viewmodels[0]; // TODO: unhardcode
 377         if (wepent.activeweapon != WEP_PORTO) return;
 378         if (spectatee_status) return;
 379         if (WEP_CVAR(porto, secondary)) return;
 380         if (intermission == 1) return;
 381         if (intermission == 2) return;
 382         if (STAT(HEALTH) <= 0) return;
 383
 384         vector pos = view_origin;
 385         vector dir = view_forward;
 386         if (angles_held_status)
 387         {
 388                 makevectors(angles_held);
 389                 dir = v_forward;
 390         }
 391
 392         polyline[0] = pos;
 393
 394         int portal_number = 0, portal1_idx = 1, portal_max = 2;
 395         int n = 1 + 2;  // 2 lines == 3 points
 396         for (int idx = 0; idx < n && idx < polyline_length - 1; )
 397         {
 398                 traceline(pos, pos + 65536 * dir, true, this);
 399                 dir = reflect(dir, trace_plane_normal);
 400                 pos = trace_endpos;
 401                 polyline[++idx] = pos;
 402                 if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 403                 {
 404                         n += 1;
 405                         continue;
 406                 }
 407                 if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 408                 {
 409                         n = max(2, idx);
 410                         break;
 411                 }
 412                 // check size
 413                 {
 414                         vector ang = vectoangles2(trace_plane_normal, dir);
 415                         ang.x = -ang.x;
 416                         makevectors(ang);
 417                         if (!CheckWireframeBox(this, pos - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 418                         {
 419                                 n = max(2, idx);
 420                                 break;
 421                         }
 422                 }
 423                 portal_number += 1;
 424                 if (portal_number >= portal_max) break;
 425                 if (portal_number == 1) portal1_idx = idx;
 426         }
 427         for (int idx = 0; idx < n - 1; ++idx)
 428         {
 429                 vector p = polyline[idx], q = polyline[idx + 1];
 430                 if (idx == 0) p -= view_up * 16;  // line from player
 431                 vector rgb = (idx < portal1_idx) ? '1 0 0' : '0 0 1';
 432                 Draw_CylindricLine(p, q, 4, "", 1, 0, rgb, 0.5, DRAWFLAG_NORMAL, view_origin);
 433         }
 434 }
 435
 436 float drawtime;
 437 float avgspeed;
 438 vector GetCurrentFov(float fov)
 439 {
 440         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 441         float velocityzoom, curspeed;
 442         vector v;
 443
 444         zoomsensitivity = autocvar_cl_zoomsensitivity;
 445         zoomfactor = autocvar_cl_zoomfactor;
 446         if(zoomfactor < 1 || zoomfactor > 30)
 447                 zoomfactor = 2.5;
 448         zoomspeed = autocvar_cl_zoomspeed;
 449         if(zoomspeed >= 0)
 450         if(zoomspeed < 0.5 || zoomspeed > 16)
 451                         zoomspeed = 3.5;
 452
 453         zoomdir = button_zoom;
 454
 455         if(hud == HUD_NORMAL && !spectatee_status)
 456         {
 457                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 458                 {
 459                         entity wepent = viewmodels[slot];
 460                         if(wepent.switchweapon == wepent.activeweapon)
 461                         if((wepent.activeweapon == WEP_VORTEX && !WEP_CVAR(vortex, secondary)) || (wepent.activeweapon == WEP_RIFLE && !WEP_CVAR(rifle, secondary))) // do NOT use switchweapon here
 462                                 zoomdir += button_attack2;
 463                 }
 464         }
 465         if(spectatee_status > 0 || isdemo())
 466         {
 467                 if(spectatorbutton_zoom)
 468                 {
 469                         if(zoomdir)
 470                                 zoomdir = 0;
 471                         else
 472                                 zoomdir = 1;
 473                 }
 474                 // fteqcc failed twice here already, don't optimize this
 475         }
 476
 477         if(zoomdir) { zoomin_effect = 0; }
 478
 479         if(camera_active)
 480         {
 481                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 482         }
 483         else if(autocvar_cl_spawnzoom && zoomin_effect)
 484         {
 485                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 486
 487                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 488                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 489                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 490         }
 491         else
 492         {
 493                 if(zoomspeed < 0) // instant zoom
 494                 {
 495                         if(zoomdir)
 496                                 current_viewzoom = 1 / zoomfactor;
 497                         else
 498                                 current_viewzoom = 1;
 499                 }
 500                 else
 501                 {
 502                         if(zoomdir)
 503                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 504                         else
 505                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 506                 }
 507         }
 508
 509         if(almost_equals(current_viewzoom, 1))
 510                 current_zoomfraction = 0;
 511         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 512                 current_zoomfraction = 1;
 513         else
 514                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 515
 516         if(zoomsensitivity < 1)
 517                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 518         else
 519                 setsensitivityscale(1);
 520
 521         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 522         {
 523                 if(intermission) { curspeed = 0; }
 524                 else
 525                 {
 526
 527                         makevectors(view_angles);
 528                         v = pmove_vel;
 529                         if(csqcplayer)
 530                                 v = csqcplayer.velocity;
 531
 532                         switch(autocvar_cl_velocityzoom_type)
 533                         {
 534                                 case 3: curspeed = max(0, v_forward * v); break;
 535                                 case 2: curspeed = (v_forward * v); break;
 536                                 case 1: default: curspeed = vlen(v); break;
 537                         }
 538                 }
 539
 540                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 541                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 542                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 543
 544                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 545         }
 546         else
 547                 velocityzoom = 1;
 548
 549         float frustumx, frustumy, fovx, fovy;
 550         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 551         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 552         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 553         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 554
 555         return '1 0 0' * fovx + '0 1 0' * fovy;
 556 }
 557
 558 vector GetViewLocationFOV(float fov)
 559 {
 560         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 561         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 562         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 563         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 564         return '1 0 0' * fovx + '0 1 0' * fovy;
 565 }
 566
 567 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 568 {
 569         float fovx, fovy;
 570         float width = (ov_worldmax.x - ov_worldmin.x);
 571         float height = (ov_worldmax.y - ov_worldmin.y);
 572         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 573         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 574         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 575         return '1 0 0' * fovx + '0 1 0' * fovy;
 576 }
 577
 578 // this function must match W_SetupShot!
 579 float zoomscript_caught;
 580
 581 vector wcross_origin;
 582 float wcross_scale_prev, wcross_alpha_prev;
 583 vector wcross_color_prev;
 584 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 585 vector wcross_color_goal_prev;
 586 float wcross_changedonetime;
 587
 588 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 589 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 590 float wcross_name_changestarttime, wcross_name_changedonetime;
 591 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 592
 593 float wcross_ring_prev;
 594
 595 entity trueaim;
 596 entity trueaim_rifle;
 597
 598 const float SHOTTYPE_HITTEAM = 1;
 599 const float SHOTTYPE_HITOBSTRUCTION = 2;
 600 const float SHOTTYPE_HITWORLD = 3;
 601 const float SHOTTYPE_HITENEMY = 4;
 602
 603 void TrueAim_Init()
 604 {
 605         (trueaim = new_pure(trueaim)).dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 606         (trueaim_rifle = new_pure(trueaim_rifle)).dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 607 }
 608
 609 float EnemyHitCheck()
 610 {
 611         float t, n;
 612         wcross_origin = project_3d_to_2d(trace_endpos);
 613         wcross_origin.z = 0;
 614         if(trace_ent)
 615                 n = trace_ent.entnum;
 616         else
 617                 n = trace_networkentity;
 618         if(n < 1)
 619                 return SHOTTYPE_HITWORLD;
 620         if(n > maxclients)
 621                 return SHOTTYPE_HITWORLD;
 622         t = entcs_GetTeam(n - 1);
 623         if(teamplay)
 624                 if(t == myteam)
 625                         return SHOTTYPE_HITTEAM;
 626         if(t == NUM_SPECTATOR)
 627                 return SHOTTYPE_HITWORLD;
 628         return SHOTTYPE_HITENEMY;
 629 }
 630
 631 float TrueAimCheck()
 632 {
 633         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 634         vector vecs, trueaimpoint, w_shotorg;
 635         vector mi, ma, dv;
 636         float shottype;
 637         entity ta;
 638         float mv;
 639
 640         mi = ma = '0 0 0';
 641         ta = trueaim;
 642         mv = MOVE_NOMONSTERS;
 643
 644         entity wepent = viewmodels[0]; // TODO: unhardcode
 645
 646         switch(wepent.activeweapon) // WEAPONTODO
 647         {
 648                 case WEP_TUBA: // no aim
 649                 case WEP_PORTO: // shoots from eye
 650                 case WEP_NEXBALL: // shoots from eye
 651                 case WEP_HOOK: // no trueaim
 652                 case WEP_MORTAR: // toss curve
 653                         return SHOTTYPE_HITWORLD;
 654                 case WEP_VORTEX:
 655                 case WEP_VAPORIZER:
 656                         mv = MOVE_NORMAL;
 657                         break;
 658                 case WEP_RIFLE:
 659                         ta = trueaim_rifle;
 660                         mv = MOVE_NORMAL;
 661                         if(zoomscript_caught)
 662                         {
 663                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 664                                 return EnemyHitCheck();
 665                         }
 666                         break;
 667                 case WEP_DEVASTATOR: // projectile has a size!
 668                         mi = '-3 -3 -3';
 669                         ma = '3 3 3';
 670                         break;
 671                 case WEP_FIREBALL: // projectile has a size!
 672                         mi = '-16 -16 -16';
 673                         ma = '16 16 16';
 674                         break;
 675                 case WEP_SEEKER: // projectile has a size!
 676                         mi = '-2 -2 -2';
 677                         ma = '2 2 2';
 678                         break;
 679                 case WEP_ELECTRO: // projectile has a size!
 680                         mi = '0 0 -3';
 681                         ma = '0 0 -3';
 682                         break;
 683         }
 684
 685         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
 686
 687         vecs = decompressShotOrigin(STAT(SHOTORG));
 688
 689         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 690         trueaimpoint = trace_endpos;
 691
 692         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
 693                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 694
 695         if(vecs.x > 0)
 696                 vecs.y = -vecs.y;
 697         else
 698                 vecs = '0 0 0';
 699
 700         dv = view_right * vecs.y + view_up * vecs.z;
 701         w_shotorg = traceorigin + dv;
 702
 703         // now move the vecs forward as much as requested if possible
 704         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 705         w_shotorg = trace_endpos - view_forward * nudge;
 706
 707         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 708         shottype = EnemyHitCheck();
 709         if(shottype != SHOTTYPE_HITWORLD)
 710                 return shottype;
 711
 712 #if 0
 713         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 714         // or rather, I know why, but see no fix
 715         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 716                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 717                 return SHOTTYPE_HITOBSTRUCTION;
 718 #endif
 719
 720         return SHOTTYPE_HITWORLD;
 721 }
 722
 723 void PostInit();
 724 void CSQC_Demo_Camera();
 725 float camera_mode;
 726 const float CAMERA_FREE = 1;
 727 const float CAMERA_CHASE = 2;
 728 float reticle_type;
 729 string reticle_image;
 730 string NextFrameCommand;
 731
 732 vector freeze_org, freeze_ang;
 733 entity nightvision_noise, nightvision_noise2;
 734
 735 const float MAX_TIME_DIFF = 5;
 736 float pickup_crosshair_time, pickup_crosshair_size;
 737 float hitindication_crosshair_size;
 738 float use_vortex_chargepool;
 739
 740 float myhealth, myhealth_prev;
 741 float myhealth_flash;
 742
 743 float old_blurradius, old_bluralpha;
 744 float old_sharpen_intensity;
 745
 746 vector myhealth_gentlergb;
 747
 748 float contentavgalpha, liquidalpha_prev;
 749 vector liquidcolor_prev;
 750
 751 float eventchase_current_distance;
 752 float eventchase_running;
 753 bool WantEventchase(entity this)
 754 {
 755         if(autocvar_cl_orthoview)
 756                 return false;
 757         if(intermission)
 758                 return true;
 759         if(this.viewloc)
 760                 return true;
 761         if(spectatee_status >= 0)
 762         {
 763                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 764                         return true;
 765                 if(MUTATOR_CALLHOOK(WantEventchase, this))
 766                         return true;
 767                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
 768                 {
 769                         if(autocvar_cl_eventchase_death == 2)
 770                         {
 771                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 772                                 if(this.velocity == '0 0 0' || eventchase_running)
 773                                         return true;
 774                         }
 775                         else return true;
 776                 }
 777         }
 778         return false;
 779 }
 780
 781 void HUD_Crosshair_Vehicle(entity this)
 782 {
 783         if(hud != HUD_BUMBLEBEE_GUN)
 784         {
 785                 Vehicle info = Vehicles_from(hud);
 786                 info.vr_crosshair(info, this);
 787         }
 788 }
 789
 790 vector damage_blurpostprocess, content_blurpostprocess;
 791
 792 float unaccounted_damage = 0;
 793 void UpdateDamage()
 794 {
 795         // accumulate damage with each stat update
 796         static float damage_total_prev = 0;
 797         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 798         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 799         damage_total_prev = damage_total;
 800
 801         static float damage_dealt_time_prev = 0;
 802         float damage_dealt_time = STAT(HIT_TIME);
 803         if (damage_dealt_time != damage_dealt_time_prev)
 804         {
 805                 unaccounted_damage += unaccounted_damage_new;
 806                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")");
 807         }
 808         damage_dealt_time_prev = damage_dealt_time;
 809
 810         // prevent hitsound when switching spectatee
 811         static float spectatee_status_prev = 0;
 812         if (spectatee_status != spectatee_status_prev)
 813                 unaccounted_damage = 0;
 814         spectatee_status_prev = spectatee_status;
 815 }
 816
 817 void HitSound()
 818 {
 819         // varying sound pitch
 820
 821         entity wepent = viewmodels[0]; // TODO: unhardcode
 822
 823         static float hitsound_time_prev = 0;
 824         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 825         float arc_hack = wepent.activeweapon == WEP_ARC && autocvar_cl_hitsound >= 2;
 826         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 827         {
 828                 if (autocvar_cl_hitsound && unaccounted_damage)
 829                 {
 830                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 831                         float a = autocvar_cl_hitsound_max_pitch;
 832                         float b = autocvar_cl_hitsound_min_pitch;
 833                         float c = autocvar_cl_hitsound_nom_damage;
 834                         float x = unaccounted_damage;
 835                         float pitch_shift = (b*x*(a-1) + a*c*(1-b)) / (x*(a-1) + c*(1-b));
 836
 837                         // if sound variation is disabled, set pitch_shift to 1
 838                         if (autocvar_cl_hitsound == 1)
 839                                 pitch_shift = 1;
 840
 841                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 842                         if (autocvar_cl_hitsound == 3)
 843                         {
 844                                 float mirror_value = (a-b)/2 + b;
 845                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 846                         }
 847
 848                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift));
 849
 850                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 851                         // todo: normalize sound pressure levels? seems unnecessary
 852
 853                         sound7(NULL, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 854                 }
 855                 unaccounted_damage = 0;
 856                 hitsound_time_prev = time;
 857         }
 858
 859         static float typehit_time_prev = 0;
 860         float typehit_time = STAT(TYPEHIT_TIME);
 861         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 862         {
 863                 sound(NULL, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 864                 typehit_time_prev = typehit_time;
 865         }
 866 }
 867
 868 vector crosshair_getcolor(entity this, float health_stat)
 869 {
 870         static float rainbow_last_flicker;
 871         static vector rainbow_prev_color;
 872         vector wcross_color = '0 0 0';
 873         switch(autocvar_crosshair_color_special)
 874         {
 875                 case 1: // crosshair_color_per_weapon
 876                 {
 877                         if(this != WEP_Null && hud == HUD_NORMAL)
 878                         {
 879                                 wcross_color = this.wpcolor;
 880                                 break;
 881                         }
 882                         else { goto normalcolor; }
 883                 }
 884
 885                 case 2: // crosshair_color_by_health
 886                 {
 887                         float x = health_stat;
 888
 889                         //x = red
 890                         //y = green
 891                         //z = blue
 892
 893                         wcross_color.z = 0;
 894
 895                         if(x > 200)
 896                         {
 897                                 wcross_color.x = 0;
 898                                 wcross_color.y = 1;
 899                         }
 900                         else if(x > 150)
 901                         {
 902                                 wcross_color.x = 0.4 - (x-150)*0.02 * 0.4;
 903                                 wcross_color.y = 0.9 + (x-150)*0.02 * 0.1;
 904                         }
 905                         else if(x > 100)
 906                         {
 907                                 wcross_color.x = 1 - (x-100)*0.02 * 0.6;
 908                                 wcross_color.y = 1 - (x-100)*0.02 * 0.1;
 909                                 wcross_color.z = 1 - (x-100)*0.02;
 910                         }
 911                         else if(x > 50)
 912                         {
 913                                 wcross_color.x = 1;
 914                                 wcross_color.y = 1;
 915                                 wcross_color.z = 0.2 + (x-50)*0.02 * 0.8;
 916                         }
 917                         else if(x > 20)
 918                         {
 919                                 wcross_color.x = 1;
 920                                 wcross_color.y = (x-20)*90/27/100;
 921                                 wcross_color.z = (x-20)*90/27/100 * 0.2;
 922                         }
 923                         else
 924                         {
 925                                 wcross_color.x = 1;
 926                                 wcross_color.y = 0;
 927                         }
 928                         break;
 929                 }
 930
 931                 case 3: // crosshair_color_rainbow
 932                 {
 933                         if(time >= rainbow_last_flicker)
 934                         {
 935                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
 936                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
 937                         }
 938                         wcross_color = rainbow_prev_color;
 939                         break;
 940                 }
 941 LABEL(normalcolor)
 942                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
 943         }
 944
 945         return wcross_color;
 946 }
 947
 948 void HUD_Crosshair(entity this)
 949 {
 950         float f, i, j;
 951         vector v;
 952         if(!scoreboard_active && !camera_active && intermission != 2 &&
 953                 spectatee_status != -1 && !csqcplayer.viewloc && !MUTATOR_CALLHOOK(DrawCrosshair) &&
 954                 !HUD_MinigameMenu_IsOpened() )
 955         {
 956                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 957                         return;
 958
 959                 if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
 960                         return;
 961
 962                 if (hud != HUD_NORMAL)
 963                 {
 964                         HUD_Crosshair_Vehicle(this);
 965                         return;
 966                 }
 967
 968                 string wcross_style;
 969                 float wcross_alpha, wcross_resolution;
 970                 wcross_style = autocvar_crosshair;
 971                 if (wcross_style == "0")
 972                         return;
 973                 wcross_resolution = autocvar_crosshair_size;
 974                 if (wcross_resolution == 0)
 975                         return;
 976                 wcross_alpha = autocvar_crosshair_alpha;
 977                 if (wcross_alpha == 0)
 978                         return;
 979
 980                 // TrueAim check
 981                 float shottype;
 982
 983                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 984                 wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 985                 wcross_origin.z = 0;
 986                 if(autocvar_crosshair_hittest)
 987                 {
 988                         vector wcross_oldorigin;
 989                         wcross_oldorigin = wcross_origin;
 990                         shottype = TrueAimCheck();
 991                         if(shottype == SHOTTYPE_HITWORLD)
 992                         {
 993                                 v = wcross_origin - wcross_oldorigin;
 994                                 v.x /= vid_conwidth;
 995                                 v.y /= vid_conheight;
 996                                 if(vdist(v, >, 0.01))
 997                                         shottype = SHOTTYPE_HITOBSTRUCTION;
 998                         }
 999                         if(!autocvar_crosshair_hittest_showimpact)
1000                                 wcross_origin = wcross_oldorigin;
1001                 }
1002                 else
1003                         shottype = SHOTTYPE_HITWORLD;
1004
1005                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1006                 string wcross_name = "";
1007                 float wcross_scale, wcross_blur;
1008
1009         entity e = WEP_Null;
1010                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1011                 {
1012                         entity wepent = viewmodels[0]; // TODO: unhardcode
1013                         e = wepent.switchingweapon;
1014                         if(e)
1015                         {
1016                                 if(autocvar_crosshair_per_weapon)
1017                                 {
1018                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
1019                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1020                                         //if (wcross_resolution == 0)
1021                                                 //return;
1022
1023                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1024                                         wcross_resolution *= e.w_crosshair_size;
1025                                         wcross_name = e.w_crosshair;
1026                                 }
1027                         }
1028                 }
1029
1030                 if(wcross_name == "")
1031                         wcross_name = strcat("gfx/crosshair", wcross_style);
1032
1033                 // MAIN CROSSHAIR COLOR DECISION
1034                 wcross_color = crosshair_getcolor(e, STAT(HEALTH));
1035
1036                 if(autocvar_crosshair_effect_scalefade)
1037                 {
1038                         wcross_scale = wcross_resolution;
1039                         wcross_resolution = 1;
1040                 }
1041                 else
1042                 {
1043                         wcross_scale = 1;
1044                 }
1045
1046                 if(autocvar_crosshair_pickup)
1047                 {
1048                         float stat_pickup_time = STAT(LAST_PICKUP);
1049
1050                         if(pickup_crosshair_time < stat_pickup_time)
1051                         {
1052                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1053                                         pickup_crosshair_size = 1;
1054
1055                                 pickup_crosshair_time = stat_pickup_time;
1056                         }
1057
1058                         if(pickup_crosshair_size > 0)
1059                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1060                         else
1061                                 pickup_crosshair_size = 0;
1062
1063                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1064                 }
1065
1066                 // todo: make crosshair hit indication dependent on damage dealt
1067                 if(autocvar_crosshair_hitindication)
1068                 {
1069                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1070
1071                         if(unaccounted_damage)
1072                         {
1073                                 hitindication_crosshair_size = 1;
1074                         }
1075
1076                         if(hitindication_crosshair_size > 0)
1077                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1078                         else
1079                                 hitindication_crosshair_size = 0;
1080
1081                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1082                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1083                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1084                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1085                 }
1086
1087                 if(shottype == SHOTTYPE_HITENEMY)
1088                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1089                 if(shottype == SHOTTYPE_HITTEAM)
1090                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1091
1092                 f = fabs(autocvar_crosshair_effect_time);
1093                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1094                 {
1095                         wcross_changedonetime = time + f;
1096                 }
1097                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1098                 {
1099                         wcross_name_changestarttime = time;
1100                         wcross_name_changedonetime = time + f;
1101                         if(wcross_name_goal_prev_prev)
1102                                 strunzone(wcross_name_goal_prev_prev);
1103                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1104                         wcross_name_goal_prev = strzone(wcross_name);
1105                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1106                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1107                         wcross_resolution_goal_prev = wcross_resolution;
1108                 }
1109
1110                 wcross_scale_goal_prev = wcross_scale;
1111                 wcross_alpha_goal_prev = wcross_alpha;
1112                 wcross_color_goal_prev = wcross_color;
1113
1114                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1115                 {
1116                         wcross_blur = 1;
1117                         wcross_alpha *= 0.75;
1118                 }
1119                 else
1120                         wcross_blur = 0;
1121                 // *_prev is at time-frametime
1122                 // * is at wcross_changedonetime+f
1123                 // what do we have at time?
1124                 if(time < wcross_changedonetime)
1125                 {
1126                         f = frametime / (wcross_changedonetime - time + frametime);
1127                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1128                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1129                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1130                 }
1131
1132                 wcross_scale_prev = wcross_scale;
1133                 wcross_alpha_prev = wcross_alpha;
1134                 wcross_color_prev = wcross_color;
1135
1136                 MUTATOR_CALLHOOK(UpdateCrosshair);
1137
1138                 wcross_scale *= 1 - autocvar__menu_alpha;
1139                 wcross_alpha *= 1 - autocvar__menu_alpha;
1140                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1141
1142                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1143                 {
1144                         // crosshair rings for weapon stats
1145                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1146                         {
1147                                 // declarations and stats
1148                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1149                                 string ring_image = string_null, ring_inner_image = string_null;
1150                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1151
1152                                 ring_scale = autocvar_crosshair_ring_size;
1153
1154                                 float weapon_clipload, weapon_clipsize;
1155                                 weapon_clipload = STAT(WEAPON_CLIPLOAD);
1156                                 weapon_clipsize = STAT(WEAPON_CLIPSIZE);
1157
1158                                 float ok_ammo_charge, ok_ammo_chargepool;
1159                                 ok_ammo_charge = STAT(OK_AMMO_CHARGE);
1160                                 ok_ammo_chargepool = STAT(OK_AMMO_CHARGEPOOL);
1161
1162                                 float vortex_charge, vortex_chargepool;
1163                                 vortex_charge = STAT(VORTEX_CHARGE);
1164                                 vortex_chargepool = STAT(VORTEX_CHARGEPOOL);
1165
1166                                 float arc_heat = STAT(ARC_HEAT);
1167
1168                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1169                                         vortex_charge_movingavg = vortex_charge;
1170
1171                                 entity wepent = viewmodels[0]; // TODO: unhardcode
1172
1173                                 // handle the values
1174                                 if (autocvar_crosshair_ring && wepent.activeweapon == WEP_VORTEX && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1175                                 {
1176                                         if (vortex_chargepool || use_vortex_chargepool) {
1177                                                 use_vortex_chargepool = 1;
1178                                                 ring_inner_value = vortex_chargepool;
1179                                         } else {
1180                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
1181                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
1182                                         }
1183
1184                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1185                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1186                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1187
1188                                         // draw the outer ring to show the current charge of the weapon
1189                                         ring_value = vortex_charge;
1190                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1191                                         ring_rgb = wcross_color;
1192                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1193                                 }
1194                                 else if (autocvar_crosshair_ring && wepent.activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1195                                 {
1196                                         ring_value = bound(0, STAT(LAYED_MINES) / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1197                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1198                                         ring_rgb = wcross_color;
1199                                         ring_image = "gfx/crosshair_ring.tga";
1200                                 }
1201                                 else if (wepent.activeweapon == WEP_HAGAR && STAT(HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1202                                 {
1203                                         ring_value = bound(0, STAT(HAGAR_LOAD) / WEP_CVAR_SEC(hagar, load_max), 1);
1204                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1205                                         ring_rgb = wcross_color;
1206                                         ring_image = "gfx/crosshair_ring.tga";
1207                                 }
1208                                 else if (ok_ammo_charge)
1209                                 {
1210                                         ring_value = ok_ammo_chargepool;
1211                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1212                                         ring_rgb = wcross_color;
1213                                         ring_image = "gfx/crosshair_ring.tga";
1214                                 }
1215                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1216                                 {
1217                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1218                                         ring_scale = autocvar_crosshair_ring_reload_size;
1219                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1220                                         ring_rgb = wcross_color;
1221
1222                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1223                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1224                                         if ((wepent.activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1225                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1226                                         else
1227                                                 ring_image = "gfx/crosshair_ring.tga";
1228                                 }
1229                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && wepent.activeweapon == WEP_ARC )
1230                                 {
1231                                         ring_value = arc_heat;
1232                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1233                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1234                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1235                                         ring_image = "gfx/crosshair_ring.tga";
1236                                 }
1237
1238                                 // if in weapon switch animation, fade ring out/in
1239                                 if(autocvar_crosshair_effect_time > 0)
1240                                 {
1241                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1242                                         if (f >= 1)
1243                                         {
1244                                                 wcross_ring_prev = ((ring_image) ? true : false);
1245                                         }
1246
1247                                         if(wcross_ring_prev)
1248                                         {
1249                                                 if(f < 1)
1250                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1251                                         }
1252                                         else
1253                                         {
1254                                                 if(f < 1)
1255                                                         ring_alpha *= bound(0, f, 1);
1256                                         }
1257                                 }
1258
1259                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1260                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1261
1262                                 if (ring_value)
1263                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1264                         }
1265
1266 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1267                         MACRO_BEGIN { \
1268                                 if(wcross_blur > 0) \
1269                                 { \
1270                                         for(i = -2; i <= 2; ++i) \
1271                                         for(j = -2; j <= 2; ++j) \
1272                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1273                                 } \
1274                                 else \
1275                                 { \
1276                                         M(0,0,sz,wcross_name,wcross_alpha); \
1277                                 } \
1278                         } MACRO_END
1279
1280 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1281                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1282
1283 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1284                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1285
1286                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1287                         {
1288                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1289                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1290                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1291                                 f = 1 - f;
1292                         }
1293                         else
1294                         {
1295                                 f = 1;
1296                         }
1297                         wcross_name_alpha_goal_prev = f;
1298
1299                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1300                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1301
1302                         if(autocvar_crosshair_dot)
1303                         {
1304                                 vector wcross_color_old;
1305                                 wcross_color_old = wcross_color;
1306
1307                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1308                                         wcross_color = stov(autocvar_crosshair_dot_color);
1309
1310                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1311                                 // FIXME why don't we use wcross_alpha here?
1312                                 wcross_color = wcross_color_old;
1313                         }
1314                 }
1315         }
1316         else
1317         {
1318                 wcross_scale_prev = 0;
1319                 wcross_alpha_prev = 0;
1320                 wcross_scale_goal_prev = 0;
1321                 wcross_alpha_goal_prev = 0;
1322                 wcross_changedonetime = 0;
1323                 if(wcross_name_goal_prev)
1324                         strunzone(wcross_name_goal_prev);
1325                 wcross_name_goal_prev = string_null;
1326                 if(wcross_name_goal_prev_prev)
1327                         strunzone(wcross_name_goal_prev_prev);
1328                 wcross_name_goal_prev_prev = string_null;
1329                 wcross_name_changestarttime = 0;
1330                 wcross_name_changedonetime = 0;
1331                 wcross_name_alpha_goal_prev = 0;
1332                 wcross_name_alpha_goal_prev_prev = 0;
1333                 wcross_resolution_goal_prev = 0;
1334                 wcross_resolution_goal_prev_prev = 0;
1335         }
1336 }
1337
1338 void HUD_Draw(entity this)
1339 {
1340         // if we don't know gametype and scores yet avoid drawing the scoreboard
1341         // also in the very first frames, player state may be inconsistent so avoid drawing the hud at all
1342         // e.g. since initial player's health is 0 hud would display the hud_damage effect,
1343         // cl_deathscoreboard would show the scoreboard and so on
1344         if(!gametype)
1345                 return;
1346
1347         if(!intermission)
1348         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1349         {
1350                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, M_ARGV(0, vector), autocvar_hud_colorflash_alpha * M_ARGV(1, float), DRAWFLAG_ADDITIVE);
1351         }
1352         else if(STAT(FROZEN))
1353         {
1354                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, ((STAT(REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * STAT(REVIVE_PROGRESS)) + ('0 1 1' * STAT(REVIVE_PROGRESS) * -1)) : '0.25 0.90 1'), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1355         }
1356         if(!intermission)
1357         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1358         {
1359                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * STAT(NADE_TIMER)) - ('0 1 1' * STAT(NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1360                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1361         }
1362         else if(STAT(CAPTURE_PROGRESS))
1363         {
1364                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(CAPTURE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1365                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Capture progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1366         }
1367         else if(STAT(REVIVE_PROGRESS))
1368         {
1369                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1370                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1371         }
1372
1373         if(autocvar_r_letterbox == 0)
1374                 if(autocvar_viewsize < 120)
1375                 {
1376                         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1377                                 Accuracy_LoadLevels();
1378
1379                         HUD_Main();
1380                         HUD_Scale_Disable();
1381                 }
1382
1383         // crosshair goes VERY LAST
1384         UpdateDamage();
1385         HUD_Crosshair(this);
1386         HitSound();
1387 }
1388
1389 bool ov_enabled;
1390 float oldr_nearclip;
1391 float oldr_farclip_base;
1392 float oldr_farclip_world;
1393 float oldr_novis;
1394 float oldr_useportalculling;
1395 float oldr_useinfinitefarclip;
1396
1397 void cl_notice_run();
1398
1399 float prev_myteam;
1400 int lasthud;
1401 float vh_notice_time;
1402 void WaypointSprite_Load();
1403 void CSQC_UpdateView(entity this, float w, float h)
1404 {
1405     TC(int, w); TC(int, h);
1406         entity e;
1407         float fov;
1408         float f;
1409         vector vf_size, vf_min;
1410         float a;
1411
1412         execute_next_frame();
1413
1414         ++framecount;
1415
1416         stats_get();
1417         hud = STAT(HUD);
1418
1419         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1420                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1421
1422         lasthud = hud;
1423
1424         HUD_Scale_Disable();
1425
1426         if(autocvar__hud_showbinds_reload) // menu can set this one
1427         {
1428                 db_close(binddb);
1429                 binddb = db_create();
1430                 cvar_set("_hud_showbinds_reload", "0");
1431         }
1432
1433         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1434                 view_quality = getproperty(VF_MINFPS_QUALITY);
1435         else
1436                 view_quality = 1;
1437
1438         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1439         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1440
1441         vf_size = getpropertyvec(VF_SIZE);
1442         vf_min = getpropertyvec(VF_MIN);
1443         vid_width = vf_size.x;
1444         vid_height = vf_size.y;
1445
1446         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1447         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1448
1449         WaypointSprite_Load();
1450
1451         CSQCPlayer_SetCamera();
1452
1453         if(player_localentnum <= maxclients) // is it a client?
1454                 current_player = player_localentnum - 1;
1455         else // then player_localentnum is the vehicle I'm driving
1456                 current_player = player_localnum;
1457         myteam = entcs_GetTeam(current_player);
1458
1459         if(myteam != prev_myteam)
1460         {
1461                 myteamcolors = colormapPaletteColor(myteam, 1);
1462                 FOREACH(hud_panels, true, it.update_time = time);
1463                 prev_myteam = myteam;
1464         }
1465
1466         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1467
1468         float is_dead = (STAT(HEALTH) <= 0);
1469
1470         // FIXME do we need this hack?
1471         if(isdemo())
1472         {
1473                 // in demos, input_buttons do not work
1474                 button_zoom = (autocvar__togglezoom == "-");
1475         }
1476         else if(button_zoom
1477                 && autocvar_cl_unpress_zoom_on_death
1478                 && (spectatee_status >= 0)
1479                 && (is_dead || intermission))
1480         {
1481                 // no zoom while dead or in intermission please
1482                 localcmd("-zoom\n");
1483                 button_zoom = false;
1484         }
1485
1486         // event chase camera
1487         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1488         {
1489                 if(STAT(CAMERA_SPECTATOR))
1490                 {
1491                         if(spectatee_status > 0)
1492                         {
1493                                 if(!autocvar_chase_active)
1494                                 {
1495                                         cvar_set("chase_active", "-2");
1496                                         goto skip_eventchase_death;
1497                                 }
1498                         }
1499                         else if(autocvar_chase_active == -2)
1500                                 cvar_set("chase_active", "0");
1501
1502                         if(autocvar_chase_active == -2)
1503                                 goto skip_eventchase_death;
1504                 }
1505                 else if(autocvar_chase_active == -2)
1506                         cvar_set("chase_active", "0");
1507
1508                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1509
1510                 float vehicle_viewdist = 0;
1511                 vector vehicle_viewofs = '0 0 0';
1512
1513                 if(vehicle_chase)
1514                 {
1515                         if(hud != HUD_BUMBLEBEE_GUN)
1516                         {
1517                                 Vehicle info = Vehicles_from(hud);
1518                                 vehicle_viewdist = info.height;
1519                                 vehicle_viewofs = info.view_ofs;
1520                         }
1521                 }
1522
1523                 if(WantEventchase(this))
1524                 {
1525                         vector current_view_origin_override = '0 0 0';
1526                         vector view_offset_override = '0 0 0';
1527                         float chase_distance_override = 0;
1528                         bool custom_eventchase = MUTATOR_CALLHOOK(CustomizeEventchase, this);
1529                         if(custom_eventchase)
1530                         {
1531                                 current_view_origin_override = M_ARGV(0, vector);
1532                                 view_offset_override = M_ARGV(1, vector);
1533                                 chase_distance_override = M_ARGV(0, float);
1534                         }
1535                         eventchase_running = true;
1536
1537                         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1538                         if(!local_player)
1539                                 local_player = this; // fall back!
1540
1541                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1542                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1543                         if (custom_eventchase)
1544                                 current_view_origin = current_view_origin_override;
1545
1546                         // detect maximum viewoffset and use it
1547                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1548                         if(vehicle_chase)
1549                         {
1550                                 if(vehicle_viewofs)
1551                                         view_offset = vehicle_viewofs;
1552                                 else
1553                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
1554                         }
1555                         if (custom_eventchase)
1556                                 view_offset = view_offset_override;
1557
1558                         if(view_offset)
1559                         {
1560                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, this);
1561                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1562                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1563                         }
1564
1565                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1566                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1567                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1568                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1569
1570                         // make the camera smooth back
1571                         float chase_distance = autocvar_cl_eventchase_distance;
1572                         if(vehicle_chase)
1573                         {
1574                                 if(vehicle_viewofs)
1575                                         chase_distance = vehicle_viewdist;
1576                                 else
1577                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
1578                         }
1579                         if (custom_eventchase)
1580                                 chase_distance = chase_distance_override;
1581
1582                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1583                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1584                         else if(eventchase_current_distance != chase_distance)
1585                                 eventchase_current_distance = chase_distance;
1586
1587                         makevectors(view_angles);
1588
1589                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1590                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, this);
1591
1592                         // If the boxtrace fails, revert back to line tracing.
1593                         if(!local_player.viewloc)
1594                         if(trace_startsolid)
1595                         {
1596                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1597                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, this);
1598                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1599                         }
1600                         else { setproperty(VF_ORIGIN, trace_endpos); }
1601
1602                         if(!local_player.viewloc)
1603                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1604                 }
1605                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1606                 {
1607                         eventchase_running = false;
1608                         cvar_set("chase_active", "0");
1609                         eventchase_current_distance = 0; // start from 0 next time
1610                 }
1611         }
1612         // workaround for camera stuck between player's legs when using chase_active 1
1613         // because the engine stops updating the chase_active camera when the game ends
1614         else if(intermission)
1615         {
1616                 cvar_settemp("chase_active", "-1");
1617                 eventchase_current_distance = 0;
1618         }
1619
1620         LABEL(skip_eventchase_death);
1621
1622         // do lockview after event chase camera so that it still applies whenever necessary.
1623         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1624         {
1625                 setproperty(VF_ORIGIN, freeze_org);
1626                 setproperty(VF_ANGLES, freeze_ang);
1627         }
1628         else
1629         {
1630                 freeze_org = getpropertyvec(VF_ORIGIN);
1631                 freeze_ang = getpropertyvec(VF_ANGLES);
1632         }
1633
1634         WarpZone_FixView();
1635         //WarpZone_FixPMove();
1636
1637         vector ov_org = '0 0 0';
1638         vector ov_mid = '0 0 0';
1639         vector ov_worldmin = '0 0 0';
1640         vector ov_worldmax = '0 0 0';
1641         if(autocvar_cl_orthoview)
1642         {
1643                 ov_worldmin = mi_picmin;
1644                 ov_worldmax = mi_picmax;
1645
1646                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1647                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1648                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1649
1650                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1651                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1652
1653                 float ov_nearest = vlen(ov_org - vec3(
1654                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1655                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1656                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1657                 ));
1658
1659                 float ov_furthest = 0;
1660                 float dist = 0;
1661
1662                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1663                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1664                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1665                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1666                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1667                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1668                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1669                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1670
1671                 if(!ov_enabled)
1672                 {
1673                         oldr_nearclip = cvar("r_nearclip");
1674                         oldr_farclip_base = cvar("r_farclip_base");
1675                         oldr_farclip_world = cvar("r_farclip_world");
1676                         oldr_novis = cvar("r_novis");
1677                         oldr_useportalculling = cvar("r_useportalculling");
1678                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1679                 }
1680
1681                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1682                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1683                 cvar_settemp("r_farclip_world", "0");
1684                 cvar_settemp("r_novis", "1");
1685                 cvar_settemp("r_useportalculling", "0");
1686                 cvar_settemp("r_useinfinitefarclip", "0");
1687
1688                 setproperty(VF_ORIGIN, ov_org);
1689                 setproperty(VF_ANGLES, '90 0 0');
1690
1691                 ov_enabled = true;
1692
1693                 #if 0
1694                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1695                         vtos(ov_org),
1696                         vtos(getpropertyvec(VF_ANGLES)),
1697                         ov_distance,
1698                         ov_nearest,
1699                         ov_furthest);
1700                 #endif
1701         }
1702         else
1703         {
1704                 if(ov_enabled)
1705                 {
1706                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1707                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1708                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1709                         cvar_set("r_novis", ftos(oldr_novis));
1710                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1711                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1712                 }
1713                 ov_enabled = false;
1714         }
1715
1716         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
1717         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
1718         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1719                 viewmodel_draw(viewmodels[slot]);
1720
1721         // Render the Scene
1722         view_origin = getpropertyvec(VF_ORIGIN);
1723         view_angles = getpropertyvec(VF_ANGLES);
1724         makevectors(view_angles);
1725         view_forward = v_forward;
1726         view_right = v_right;
1727         view_up = v_up;
1728
1729 #ifdef BLURTEST
1730         if(time > blurtest_time0 && time < blurtest_time1)
1731         {
1732                 float r, t;
1733
1734                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1735                 r = t * blurtest_radius;
1736                 f = 1 / pow(t, blurtest_power) - 1;
1737
1738                 cvar_set("r_glsl_postprocess", "1");
1739                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1740         }
1741         else
1742         {
1743                 cvar_set("r_glsl_postprocess", "0");
1744                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1745         }
1746 #endif
1747
1748         TargetMusic_Advance();
1749         Fog_Force();
1750
1751         if(drawtime == 0)
1752                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1753         else
1754                 drawframetime = bound(0.000001, time - drawtime, 1);
1755         drawtime = time;
1756
1757         // watch for gametype changes here...
1758         // in ParseStuffCMD the cmd isn't executed yet :/
1759         // might even be better to add the gametype to TE_CSQC_INIT...?
1760         if(!postinit)
1761                 PostInit();
1762
1763         if(intermission && !gameover_time)
1764                 gameover_time = time;
1765
1766         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1767         {
1768                 if(calledhooks & HOOK_START)
1769                 {
1770                         localcmd("\ncl_hook_gameend\n");
1771                         calledhooks |= HOOK_END;
1772                 }
1773         }
1774
1775         Announcer();
1776
1777         fov = autocvar_fov;
1778         if(fov <= 59.5)
1779         {
1780                 if(!zoomscript_caught)
1781                 {
1782                         localcmd("+button9\n");
1783                         zoomscript_caught = 1;
1784                 }
1785         }
1786         else
1787         {
1788                 if(zoomscript_caught)
1789                 {
1790                         localcmd("-button9\n");
1791                         zoomscript_caught = 0;
1792                 }
1793         }
1794
1795         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1796
1797         entity wepent = viewmodels[0]; // TODO: unhardcode
1798
1799         if(last_switchweapon != wepent.switchweapon)
1800         {
1801                 weapontime = time;
1802                 last_switchweapon = wepent.switchweapon;
1803                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1804                 {
1805                         localcmd("-zoom\n");
1806                         button_zoom = false;
1807                 }
1808                 if(autocvar_cl_unpress_attack_on_weapon_switch)
1809                 {
1810                         localcmd("-fire\n");
1811                         localcmd("-fire2\n");
1812                         button_attack2 = false;
1813                 }
1814         }
1815         if(last_activeweapon != wepent.activeweapon)
1816         {
1817                 last_activeweapon = wepent.activeweapon;
1818
1819                 e = wepent.activeweapon;
1820                 if(e.netname != "")
1821                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1822                 else
1823                         localcmd("\ncl_hook_activeweapon none\n");
1824         }
1825
1826         // ALWAYS Clear Current Scene First
1827         clearscene();
1828
1829         setproperty(VF_ORIGIN, view_origin);
1830         setproperty(VF_ANGLES, view_angles);
1831
1832         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1833         setproperty(VF_SIZE, vf_size);
1834         setproperty(VF_MIN, vf_min);
1835
1836         // Assign Standard Viewflags
1837         // Draw the World (and sky)
1838         setproperty(VF_DRAWWORLD, 1);
1839
1840         // Set the console size vars
1841         vid_conwidth = autocvar_vid_conwidth;
1842         vid_conheight = autocvar_vid_conheight;
1843         vid_pixelheight = autocvar_vid_pixelheight;
1844
1845         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1846         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1847         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1848
1849         if(camera_active) // Camera for demo playback
1850         {
1851                 if(autocvar_camera_enable)
1852                         CSQC_Demo_Camera();
1853                 else
1854                 {
1855                         cvar_set("chase_active", ftos(chase_active_backup));
1856                         cvar_set("cl_demo_mousegrab", "0");
1857                         camera_active = false;
1858                 }
1859         }
1860         else
1861         {
1862 #ifdef CAMERATEST
1863                 if(autocvar_camera_enable)
1864 #else
1865                 if(autocvar_camera_enable && isdemo())
1866 #endif
1867                 {
1868                         // Enable required Darkplaces cvars
1869                         chase_active_backup = autocvar_chase_active;
1870                         cvar_set("chase_active", "2");
1871                         cvar_set("cl_demo_mousegrab", "1");
1872                         camera_active = true;
1873                         camera_mode = false;
1874                 }
1875         }
1876
1877         // Draw the Crosshair
1878         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1879
1880         // Draw the Engine Status Bar (the default Quake HUD)
1881         setproperty(VF_DRAWENGINESBAR, 0);
1882
1883         // Update the mouse position
1884         /*
1885            mousepos_x = vid_conwidth;
1886            mousepos_y = vid_conheight;
1887            mousepos = mousepos*0.5 + getmousepos();
1888          */
1889
1890         IL_EACH(g_drawables, it.draw, it.draw(it));
1891
1892         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1893         renderscene();
1894
1895         // now switch to 2D drawing mode by calling a 2D drawing function
1896         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1897         // next R_RenderScene call
1898         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1899
1900         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1901         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1902         {
1903                 // apply night vision effect
1904                 vector tc_00, tc_01, tc_10, tc_11;
1905                 vector rgb = '0 0 0';
1906
1907                 if(!nightvision_noise)
1908                 {
1909                         nightvision_noise = new(nightvision_noise);
1910                 }
1911                 if(!nightvision_noise2)
1912                 {
1913                         nightvision_noise2 = new(nightvision_noise2);
1914                 }
1915
1916                 // color tint in yellow
1917                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1918
1919                 // draw BG
1920                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1921                 rgb = '1 1 1';
1922                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1923                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1924                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1925                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1926                 tc_11 = tc_01 + tc_10 - tc_00;
1927                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1928                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1929                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1930                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1931                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1932                 R_EndPolygon();
1933
1934                 // draw FG
1935                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1936                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1937                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1938                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1939                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1940                 tc_11 = tc_01 + tc_10 - tc_00;
1941                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1942                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1943                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1944                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1945                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1946                 R_EndPolygon();
1947         }
1948
1949         if(autocvar_cl_reticle)
1950         {
1951                 bool wep_zoomed = false;
1952                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1953                 {
1954                         entity wepe = viewmodels[slot];
1955                         Weapon wep = wepe.activeweapon;
1956                         if(wep != WEP_Null && wep.wr_zoom)
1957                                 wep_zoomed += wep.wr_zoom(wep, NULL);
1958                 }
1959                 // Draw the aiming reticle for weapons that use it
1960                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
1961                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
1962                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
1963                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
1964                 {
1965                         // no zoom reticle while dead
1966                         reticle_type = 0;
1967                 }
1968                 else if(wep_zoomed && autocvar_cl_reticle_weapon)
1969                 {
1970                         if(reticle_image != "") { reticle_type = 2; }
1971                         else { reticle_type = 0; }
1972                 }
1973                 else if(button_zoom || zoomscript_caught)
1974                 {
1975                         // normal zoom
1976                         reticle_type = 1;
1977                 }
1978
1979                 if(reticle_type)
1980                 {
1981                         if(autocvar_cl_reticle_stretch)
1982                         {
1983                                 reticle_size.x = vid_conwidth;
1984                                 reticle_size.y = vid_conheight;
1985                                 reticle_pos.x = 0;
1986                                 reticle_pos.y = 0;
1987                         }
1988                         else
1989                         {
1990                                 reticle_size.x = max(vid_conwidth, vid_conheight);
1991                                 reticle_size.y = max(vid_conwidth, vid_conheight);
1992                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
1993                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
1994                         }
1995
1996                         if(zoomscript_caught)
1997                                 f = 1;
1998                         else
1999                                 f = current_zoomfraction;
2000
2001                         if(f)
2002                         {
2003                                 switch(reticle_type)
2004                                 {
2005                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
2006                                         case 2: drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
2007                                 }
2008                         }
2009                 }
2010         }
2011         else
2012         {
2013                 if(reticle_type != 0) { reticle_type = 0; }
2014         }
2015
2016
2017         // improved polyblend
2018         if(autocvar_hud_contents)
2019         {
2020                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
2021                 vector liquidcolor;
2022
2023                 switch(pointcontents(view_origin))
2024                 {
2025                         case CONTENT_WATER:
2026                                 liquidalpha = autocvar_hud_contents_water_alpha;
2027                                 liquidcolor = stov(autocvar_hud_contents_water_color);
2028                                 incontent = 1;
2029                                 break;
2030
2031                         case CONTENT_LAVA:
2032                                 liquidalpha = autocvar_hud_contents_lava_alpha;
2033                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
2034                                 incontent = 1;
2035                                 break;
2036
2037                         case CONTENT_SLIME:
2038                                 liquidalpha = autocvar_hud_contents_slime_alpha;
2039                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
2040                                 incontent = 1;
2041                                 break;
2042
2043                         default:
2044                                 liquidalpha = 0;
2045                                 liquidcolor = '0 0 0';
2046                                 incontent = 0;
2047                                 break;
2048                 }
2049
2050                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
2051                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
2052                         contentfadetime = autocvar_hud_contents_fadeintime;
2053                         liquidalpha_prev = liquidalpha;
2054                         liquidcolor_prev = liquidcolor;
2055                 }
2056                 else
2057                         contentfadetime = autocvar_hud_contents_fadeouttime;
2058
2059                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
2060                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
2061
2062                 if(contentavgalpha)
2063                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
2064
2065                 if(autocvar_hud_postprocessing)
2066                 {
2067                         if(autocvar_hud_contents_blur && contentavgalpha)
2068                         {
2069                                 content_blurpostprocess.x = 1;
2070                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
2071                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
2072                         }
2073                         else
2074                         {
2075                                 content_blurpostprocess.x = 0;
2076                                 content_blurpostprocess.y = 0;
2077                                 content_blurpostprocess.z = 0;
2078                         }
2079                 }
2080         }
2081
2082         if(autocvar_hud_damage && !STAT(FROZEN))
2083         {
2084                 splash_size.x = max(vid_conwidth, vid_conheight);
2085                 splash_size.y = max(vid_conwidth, vid_conheight);
2086                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2087                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2088
2089                 float myhealth_flash_temp;
2090                 myhealth = STAT(HEALTH);
2091
2092                 // fade out
2093                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2094                 // add new damage
2095                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2096
2097                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2098                 pain_threshold = autocvar_hud_damage_pain_threshold;
2099                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2100                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2101
2102                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2103                 {
2104                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2105                 }
2106
2107                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2108
2109                 if(myhealth_prev < 1)
2110                 {
2111                         if(myhealth >= 1)
2112                         {
2113                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2114                                 myhealth_flash_temp = 0;
2115                         }
2116                         else
2117                         {
2118                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2119                         }
2120                 }
2121
2122                 if(spectatee_status == -1 || intermission)
2123                 {
2124                         myhealth_flash = 0; // observing, or match ended
2125                         myhealth_flash_temp = 0;
2126                 }
2127
2128                 myhealth_prev = myhealth;
2129
2130                 // IDEA: change damage color/picture based on player model for robot/alien species?
2131                 // pro: matches model better
2132                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2133                 // maybe different reddish pics?
2134                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2135                 {
2136                         if(autocvar_cl_gentle_damage == 2)
2137                         {
2138                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2139                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
2140                         }
2141                         else
2142                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2143
2144                         if(myhealth_flash_temp > 0)
2145                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2146                 }
2147                 else if(myhealth_flash_temp > 0)
2148                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2149
2150                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2151                 {
2152                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2153                         {
2154                                 damage_blurpostprocess.x = 1;
2155                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2156                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2157                         }
2158                         else
2159                         {
2160                                 damage_blurpostprocess.x = 0;
2161                                 damage_blurpostprocess.y = 0;
2162                                 damage_blurpostprocess.z = 0;
2163                         }
2164                 }
2165         }
2166
2167         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2168         float e2 = (autocvar_hud_powerup != 0);
2169         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2170         {
2171                 // enable or disable rendering types if they are used or not
2172                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2173                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2174
2175                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2176                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2177                 {
2178                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2179                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2180                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2181                         {
2182                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2183                                 old_blurradius = blurradius;
2184                                 old_bluralpha = bluralpha;
2185                         }
2186                 }
2187                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2188                 {
2189                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2190                         old_blurradius = 0;
2191                         old_bluralpha = 0;
2192                 }
2193
2194                 // edge detection postprocess handling done second (used by hud_powerup)
2195                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2196                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2197                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2198
2199                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2200
2201                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2202                 {
2203                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2204                         {
2205                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2206                                 old_sharpen_intensity = sharpen_intensity;
2207                         }
2208                 }
2209                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2210                 {
2211                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2212                         old_sharpen_intensity = 0;
2213                 }
2214
2215                 if(cvar("r_glsl_postprocess") == 0)
2216                         cvar_set("r_glsl_postprocess", "2");
2217         }
2218         else if(cvar("r_glsl_postprocess") == 2)
2219                 cvar_set("r_glsl_postprocess", "0");
2220
2221         /*if(gametype == MAPINFO_TYPE_CTF)
2222           {
2223           ctf_view();
2224           } else */
2225
2226         // draw 2D entities
2227         IL_EACH(g_drawables_2d, it.draw2d, it.draw2d(it));
2228         Draw_ShowNames_All();
2229         Debug_Draw();
2230
2231         scoreboard_active = Scoreboard_WouldDraw();
2232
2233         HUD_Draw(this); // this parameter for deep vehicle function
2234
2235         if(NextFrameCommand)
2236         {
2237                 localcmd("\n", NextFrameCommand, "\n");
2238                 NextFrameCommand = string_null;
2239         }
2240
2241         // we must do this check AFTER a frame was rendered, or it won't work
2242         if(cs_project_is_b0rked == 0)
2243         {
2244                 string w0, h0;
2245                 w0 = ftos(autocvar_vid_conwidth);
2246                 h0 = ftos(autocvar_vid_conheight);
2247                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2248                 //setproperty(VF_FOV, '90 90 0');
2249                 setproperty(VF_ORIGIN, '0 0 0');
2250                 setproperty(VF_ANGLES, '0 0 0');
2251                 setproperty(VF_PERSPECTIVE, 1);
2252                 makevectors('0 0 0');
2253                 vector v1, v2;
2254                 cvar_set("vid_conwidth", "800");
2255                 cvar_set("vid_conheight", "600");
2256                 v1 = cs_project(v_forward);
2257                 cvar_set("vid_conwidth", "640");
2258                 cvar_set("vid_conheight", "480");
2259                 v2 = cs_project(v_forward);
2260                 if(v1 == v2)
2261                         cs_project_is_b0rked = 1;
2262                 else
2263                         cs_project_is_b0rked = -1;
2264                 cvar_set("vid_conwidth", w0);
2265                 cvar_set("vid_conheight", h0);
2266         }
2267
2268         if(autocvar__hud_configure)
2269                 HUD_Panel_Mouse();
2270         else if (HUD_MinigameMenu_IsOpened() || active_minigame)
2271                 HUD_Minigame_Mouse();
2272         else if(QuickMenu_IsOpened())
2273                 QuickMenu_Mouse();
2274         else
2275                 HUD_Radar_Mouse();
2276
2277         cl_notice_run();
2278         unpause_update();
2279         Net_Flush();
2280
2281         // let's reset the view back to normal for the end
2282         setproperty(VF_MIN, '0 0 0');
2283         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2284
2285         IL_ENDFRAME();
2286 }
2287
2288
2289 // following vectors must be global to allow seamless switching between camera modes
2290 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2291 void CSQC_Demo_Camera()
2292 {
2293         float speed, attenuation, dimensions;
2294         vector tmp, delta;
2295
2296         if( autocvar_camera_reset || !camera_mode )
2297         {
2298                 camera_offset = '0 0 0';
2299                 current_angles = '0 0 0';
2300                 camera_direction = '0 0 0';
2301                 camera_offset.z += 30;
2302                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2303                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2304                 current_origin = view_origin;
2305                 current_camera_offset  = camera_offset;
2306                 cvar_set("camera_reset", "0");
2307                 camera_mode = CAMERA_CHASE;
2308         }
2309
2310         // Camera angles
2311         if( camera_roll )
2312                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2313
2314         if(autocvar_camera_look_player)
2315         {
2316                 vector dir;
2317                 float n;
2318
2319                 dir = normalize(view_origin - current_position);
2320                 n = mouse_angles.z;
2321                 mouse_angles = vectoangles(dir);
2322                 mouse_angles.x = mouse_angles.x * -1;
2323                 mouse_angles.z = n;
2324         }
2325         else
2326         {
2327                 tmp = getmousepos() * 0.1;
2328                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2329                 {
2330                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2331                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2332                 }
2333         }
2334
2335         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2336         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2337         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2338         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2339
2340         // Fix difference when angles don't have the same sign
2341         delta = '0 0 0';
2342         if(mouse_angles.y < -60 && current_angles.y > 60)
2343                 delta = '0 360 0';
2344         if(mouse_angles.y > 60 && current_angles.y < -60)
2345                 delta = '0 -360 0';
2346
2347         if(autocvar_camera_look_player)
2348                 attenuation = autocvar_camera_look_attenuation;
2349         else
2350                 attenuation = autocvar_camera_speed_attenuation;
2351
2352         attenuation = 1 / max(1, attenuation);
2353         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2354
2355         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2356         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2357         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2358         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2359
2360         // Camera position
2361         tmp = '0 0 0';
2362         dimensions = 0;
2363
2364         if( camera_direction.x )
2365         {
2366                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2367                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2368                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2369                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2370                 ++dimensions;
2371         }
2372
2373         if( camera_direction.y )
2374         {
2375                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2376                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2377                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2378                 ++dimensions;
2379         }
2380
2381         if( camera_direction.z )
2382         {
2383                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2384                 ++dimensions;
2385         }
2386
2387         if(autocvar_camera_free)
2388                 speed = autocvar_camera_speed_free;
2389         else
2390                 speed = autocvar_camera_speed_chase;
2391
2392         if(dimensions)
2393         {
2394                 speed = speed * sqrt(1 / dimensions);
2395                 camera_offset += tmp * speed;
2396         }
2397
2398         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2399
2400         // Camera modes
2401         if( autocvar_camera_free )
2402         {
2403                 if ( camera_mode == CAMERA_CHASE )
2404                 {
2405                         current_camera_offset = current_origin + current_camera_offset;
2406                         camera_offset = current_origin + camera_offset;
2407                 }
2408
2409                 camera_mode = CAMERA_FREE;
2410                 current_position = current_camera_offset;
2411         }
2412         else
2413         {
2414                 if ( camera_mode == CAMERA_FREE )
2415                 {
2416                         current_origin = view_origin;
2417                         camera_offset = camera_offset - current_origin;
2418                         current_camera_offset = current_camera_offset - current_origin;
2419                 }
2420
2421                 camera_mode = CAMERA_CHASE;
2422
2423                 if(autocvar_camera_chase_smoothly)
2424                         current_origin += (view_origin - current_origin) * attenuation;
2425                 else
2426                         current_origin = view_origin;
2427
2428                 current_position = current_origin + current_camera_offset;
2429         }
2430
2431         setproperty(VF_ANGLES, current_angles);
2432         setproperty(VF_ORIGIN, current_position);
2433 }