qcsrc/common/animdecide.qc

   1 // implicit anim state
   2 .float anim_implicit_state;
   3 .float anim_implicit_time;
   4
   5 // actions
   6 .float anim_lower_implicit_action;
   7 .float anim_lower_implicit_time;
   8 .float anim_upper_implicit_action;
   9 .float anim_upper_implicit_time;
  10
  11 // player animation data for this model
  12 // each vector is as follows:
  13 // _x = startframe
  14 // _y = numframes
  15 // _z = framerate
  16 .vector anim_die1; // player dies
  17 .vector anim_die2; // player dies differently
  18 .vector anim_draw; // player pulls out a weapon
  19 .vector anim_duckwalk; // player walking while crouching
  20 .vector anim_duckjump; // player jumping from a crouch
  21 .vector anim_duckidle; // player idling while crouching
  22 .vector anim_idle; // player standing
  23 .vector anim_jump; // player jump
  24 .vector anim_pain1; // player flinches from pain
  25 .vector anim_pain2; // player flinches from pain, differently
  26 .vector anim_shoot; // player shoots
  27 .vector anim_taunt; // player taunts others (FIXME: no code references this)
  28 .vector anim_run; // player running forward
  29 .vector anim_runbackwards; // player running backward
  30 .vector anim_strafeleft; // player shuffling left quickly
  31 .vector anim_straferight; // player shuffling right quickly
  32 .vector anim_forwardright; // player running forward and right
  33 .vector anim_forwardleft; // player running forward and left
  34 .vector anim_backright; // player running backward and right
  35 .vector anim_backleft; // player running back and left
  36 .vector anim_melee; // player doing the melee action
  37 .vector anim_duck; // player doing the melee action
  38 .vector anim_duckwalkbackwards;
  39 .vector anim_duckwalkstrafeleft;
  40 .vector anim_duckwalkstraferight;
  41 .vector anim_duckwalkforwardright;
  42 .vector anim_duckwalkforwardleft;
  43 .vector anim_duckwalkbackright;
  44 .vector anim_duckwalkbackleft;
  45
  46 void animdecide_init(entity e)
  47 {
  48         vector none = '0 0 0';
  49         e.anim_die1 = animfixfps(e, '0 1 0.5', none); // 2 seconds
  50         e.anim_die2 = animfixfps(e, '1 1 0.5', none); // 2 seconds
  51         e.anim_draw = animfixfps(e, '2 1 3', none);
  52         e.anim_duckwalk = animfixfps(e, '4 1 1', none);
  53         e.anim_duckjump = animfixfps(e, '5 1 10', none);
  54         e.anim_duckidle = animfixfps(e, '6 1 1', none);
  55         e.anim_idle = animfixfps(e, '7 1 1', none);
  56         e.anim_jump = animfixfps(e, '8 1 10', none);
  57         e.anim_pain1 = animfixfps(e, '9 1 2', none); // 0.5 seconds
  58         e.anim_pain2 = animfixfps(e, '10 1 2', none); // 0.5 seconds
  59         e.anim_shoot = animfixfps(e, '11 1 5', none); // analyze models and set framerate
  60         e.anim_taunt = animfixfps(e, '12 1 0.33', none);
  61         e.anim_run = animfixfps(e, '13 1 1', none);
  62         e.anim_runbackwards = animfixfps(e, '14 1 1', none);
  63         e.anim_strafeleft = animfixfps(e, '15 1 1', none);
  64         e.anim_straferight = animfixfps(e, '16 1 1', none);
  65         e.anim_forwardright = animfixfps(e, '19 1 1', '16 1 1');
  66         e.anim_forwardleft = animfixfps(e, '20 1 1', '15 1 1');
  67         e.anim_backright = animfixfps(e, '21 1 1', '16 1 1');
  68         e.anim_backleft  = animfixfps(e, '22 1 1', '15 1 1');
  69         e.anim_melee = animfixfps(e, '23 1 1', '11 1 1');
  70         e.anim_duckwalkbackwards = animfixfps(e, '24 1 1', '4 1 1');
  71         e.anim_duckwalkstrafeleft = animfixfps(e, '25 1 1', '4 1 1');
  72         e.anim_duckwalkstraferight = animfixfps(e, '26 1 1', '4 1 1');
  73         e.anim_duckwalkforwardright = animfixfps(e, '27 1 1', '4 1 1');
  74         e.anim_duckwalkforwardleft = animfixfps(e, '28 1 1', '4 1 1');
  75         e.anim_duckwalkbackright = animfixfps(e, '29 1 1', '4 1 1');
  76         e.anim_duckwalkbackleft  = animfixfps(e, '30 1 1', '4 1 1');
  77 }
  78
  79 #define ANIMPRIO_IDLE 0
  80 #define ANIMPRIO_STATIC 1
  81 #define ANIMPRIO_ACTIVE 2
  82 #define ANIMPRIO_DEAD 3
  83
  84 vector animdecide_getupperanim(entity e)
  85 {
  86         // is there an action?
  87         vector outframe = '-1 0 0';
  88         float t, a;
  89         if(e.anim_upper_time >= e.anim_upper_implicit_time)
  90         {
  91                 a = e.anim_upper_action;
  92                 t = e.anim_upper_time;
  93         }
  94         else
  95         {
  96                 a = e.anim_upper_implicit_action;
  97                 t = e.anim_upper_implicit_time;
  98         }
  99         switch(a)
 100         {
 101                 case ANIMACTION_DRAW: outframe = e.anim_draw; break;
 102                 case ANIMACTION_PAIN1: outframe = e.anim_pain1; break;
 103                 case ANIMACTION_PAIN2: outframe = e.anim_pain2; break;
 104                 case ANIMACTION_SHOOT: outframe = e.anim_shoot; break;
 105                 case ANIMACTION_TAUNT: outframe = e.anim_taunt; break;
 106                 case ANIMACTION_MELEE: outframe = e.anim_melee; break;
 107         }
 108         if(outframe_x >= 0)
 109         {
 110                 if(time <= t + outframe_y / outframe_z)
 111                 {
 112                         // animation is running!
 113                         return vec3(outframe_x, t, ANIMPRIO_ACTIVE);
 114                 }
 115         }
 116         // or, decide the anim by state
 117         t = max(e.anim_time, e.anim_implicit_time);
 118         // but all states are for lower body!
 119         return vec3(e.anim_idle_x, t, ANIMPRIO_IDLE);
 120 }
 121
 122 vector animdecide_getloweranim(entity e)
 123 {
 124         // death etc.
 125         if(e.anim_state & ANIMSTATE_FROZEN)
 126                 return vec3(e.anim_idle_x, e.anim_time, ANIMPRIO_DEAD);
 127         if(e.anim_state & ANIMSTATE_DEAD1)
 128                 return vec3(e.anim_die1_x, e.anim_time, ANIMPRIO_DEAD);
 129         if(e.anim_state & ANIMSTATE_DEAD2)
 130                 return vec3(e.anim_die2_x, e.anim_time, ANIMPRIO_DEAD);
 131
 132         // is there an action?
 133         vector outframe = '-1 0 0';
 134         float t, a;
 135         if(e.anim_lower_time >= e.anim_lower_implicit_time)
 136         {
 137                 a = e.anim_lower_action;
 138                 t = e.anim_lower_time;
 139         }
 140         else
 141         {
 142                 a = e.anim_lower_implicit_action;
 143                 t = e.anim_lower_implicit_time;
 144         }
 145         switch(a)
 146         {
 147                 case ANIMACTION_JUMP: if(e.anim_implicit_state & ANIMIMPLICITSTATE_INAIR) { if(e.anim_state & ANIMSTATE_DUCK) outframe = e.anim_duckjump; else outframe = e.anim_jump; } break;
 148         }
 149         if(outframe_x >= 0)
 150         {
 151                 if(time <= t + outframe_y / outframe_z)
 152                 {
 153                         // animation is running!
 154                         return vec3(outframe_x, e.anim_lower_time, ANIMPRIO_ACTIVE);
 155                 }
 156         }
 157         // or, decide the anim by state
 158         t = max(e.anim_time, e.anim_implicit_time);
 159         if(e.anim_state & ANIMSTATE_DUCK)
 160         {
 161                 if(e.anim_implicit_state & ANIMIMPLICITSTATE_INAIR)
 162                         return vec3(e.anim_duckjump_x, 0, ANIMPRIO_ACTIVE); // play the END of the jump anim
 163                 else switch(e.anim_implicit_state & (ANIMIMPLICITSTATE_FORWARD | ANIMIMPLICITSTATE_BACKWARDS | ANIMIMPLICITSTATE_LEFT | ANIMIMPLICITSTATE_RIGHT))
 164                 {
 165                         case ANIMIMPLICITSTATE_FORWARD:
 166                                 return vec3(e.anim_duckwalk_x, t, ANIMPRIO_ACTIVE);
 167                         case ANIMIMPLICITSTATE_BACKWARDS:
 168                                 return vec3(e.anim_duckwalkbackwards_x, t, ANIMPRIO_ACTIVE);
 169                         case ANIMIMPLICITSTATE_RIGHT:
 170                                 return vec3(e.anim_duckwalkstraferight_x, t, ANIMPRIO_ACTIVE);
 171                         case ANIMIMPLICITSTATE_LEFT:
 172                                 return vec3(e.anim_duckwalkstrafeleft_x, t, ANIMPRIO_ACTIVE);
 173                         case ANIMIMPLICITSTATE_FORWARD | ANIMIMPLICITSTATE_RIGHT:
 174                                 return vec3(e.anim_duckwalkforwardright_x, t, ANIMPRIO_ACTIVE);
 175                         case ANIMIMPLICITSTATE_FORWARD | ANIMIMPLICITSTATE_LEFT:
 176                                 return vec3(e.anim_duckwalkforwardleft_x, t, ANIMPRIO_ACTIVE);
 177                         case ANIMIMPLICITSTATE_BACKWARDS | ANIMIMPLICITSTATE_RIGHT:
 178                                 return vec3(e.anim_duckwalkbackright_x, t, ANIMPRIO_ACTIVE);
 179                         case ANIMIMPLICITSTATE_BACKWARDS | ANIMIMPLICITSTATE_LEFT:
 180                                 return vec3(e.anim_duckwalkbackleft_x, t, ANIMPRIO_ACTIVE);
 181                         default:
 182                                 return vec3(e.anim_duckidle_x, t, ANIMPRIO_STATIC);
 183                 }
 184         }
 185         else
 186         {
 187                 if(e.anim_implicit_state & ANIMIMPLICITSTATE_INAIR)
 188                         return vec3(e.anim_jump_x, 0, ANIMPRIO_ACTIVE); // play the END of the jump anim
 189                 else switch(e.anim_implicit_state & (ANIMIMPLICITSTATE_FORWARD | ANIMIMPLICITSTATE_BACKWARDS | ANIMIMPLICITSTATE_LEFT | ANIMIMPLICITSTATE_RIGHT))
 190                 {
 191                         case ANIMIMPLICITSTATE_FORWARD:
 192                                 return vec3(e.anim_run_x, t, ANIMPRIO_ACTIVE);
 193                         case ANIMIMPLICITSTATE_BACKWARDS:
 194                                 return vec3(e.anim_runbackwards_x, t, ANIMPRIO_ACTIVE);
 195                         case ANIMIMPLICITSTATE_RIGHT:
 196                                 return vec3(e.anim_straferight_x, t, ANIMPRIO_ACTIVE);
 197                         case ANIMIMPLICITSTATE_LEFT:
 198                                 return vec3(e.anim_strafeleft_x, t, ANIMPRIO_ACTIVE);
 199                         case ANIMIMPLICITSTATE_FORWARD | ANIMIMPLICITSTATE_RIGHT:
 200                                 return vec3(e.anim_forwardright_x, t, ANIMPRIO_ACTIVE);
 201                         case ANIMIMPLICITSTATE_FORWARD | ANIMIMPLICITSTATE_LEFT:
 202                                 return vec3(e.anim_forwardleft_x, t, ANIMPRIO_ACTIVE);
 203                         case ANIMIMPLICITSTATE_BACKWARDS | ANIMIMPLICITSTATE_RIGHT:
 204                                 return vec3(e.anim_backright_x, t, ANIMPRIO_ACTIVE);
 205                         case ANIMIMPLICITSTATE_BACKWARDS | ANIMIMPLICITSTATE_LEFT:
 206                                 return vec3(e.anim_backleft_x, t, ANIMPRIO_ACTIVE);
 207                         default:
 208                                 return vec3(e.anim_idle_x, t, ANIMPRIO_IDLE);
 209                 }
 210         }
 211         // can't get here
 212 }
 213
 214 void animdecide_setimplicitstate(entity e, float flg)
 215 {
 216         float s;
 217         s = 0;
 218
 219         makevectors(e.angles);
 220         vector v;
 221         v_x = e.velocity * v_forward;
 222         v_y = e.velocity * v_right;
 223
 224         // we want to match like this:
 225         // the 8 directions shall be "evenly spaced"
 226         // that means, the forward key includes anything from -67.5 to +67.5 degrees
 227         // which then means x > |y| * cot(3pi/8)
 228         //
 229         // BUT, the engine's clip-movement-to-keyboard function uses 0.5 here,
 230         // which would be an angle range from -63.43 to +63.43 degrees, making
 231         // it slightly less likely to "hit two keys at once", so let's do this
 232         // here too
 233
 234         if(vlen(v) > 10)
 235         {
 236                 if(v_x >  fabs(v_y) * 0.5)
 237                         s |= ANIMIMPLICITSTATE_FORWARD;
 238                 if(v_x < -fabs(v_y) * 0.5)
 239                         s |= ANIMIMPLICITSTATE_BACKWARDS;
 240                 if(v_y >  fabs(v_x) * 0.5)
 241                         s |= ANIMIMPLICITSTATE_RIGHT;
 242                 if(v_y < -fabs(v_x) * 0.5)
 243                         s |= ANIMIMPLICITSTATE_LEFT;
 244         }
 245         if(!(flg & FL_ONGROUND))
 246                 s |= ANIMIMPLICITSTATE_INAIR;
 247
 248         // detect some kinds of otherwise misdetected jumps
 249         if(!(e.anim_implicit_state & ANIMIMPLICITSTATE_INAIR) && (s & ANIMIMPLICITSTATE_INAIR))
 250         {
 251                 // ground to air transition - do we want to reset jump anim?
 252 #if 0
 253                 if(e.anim_lower_action != ANIMACTION_JUMP || time > e.anim_lower_time + 0.2)
 254                 if(e.anim_lower_implicit_action != ANIMACTION_JUMP || time > e.anim_lower_implicit_time + 0.2)
 255                 {
 256                         traceline(e.origin + '0 0 1' * e.maxs_z, e.origin + '0 0 1' * (e.mins_z - autocvar_sv_player_jumpanim_minfall), MOVE_NOMONSTERS, e);
 257                         if(!trace_startsolid && trace_fraction == 1)
 258                         {
 259 #endif
 260                                 e.anim_lower_implicit_action = ANIMACTION_JUMP;
 261                                 e.anim_lower_implicit_time = time;
 262 #if 0
 263                         }
 264                 }
 265 #endif
 266         }
 267
 268         if(s != e.anim_implicit_state)
 269         {
 270                 e.anim_implicit_state = s;
 271                 e.anim_implicit_time = time;
 272         }
 273 }
 274 void animdecide_setframes(entity e, float flg, float support_blending, .float fld_frame, .float fld_frame1time, .float fld_frame2, .float fld_frame2time)
 275 {
 276         animdecide_setimplicitstate(e, flg);
 277         // _x: frame
 278         // _y: start time
 279         // _z: priority
 280         vector upper = animdecide_getupperanim(e);
 281         vector lower = animdecide_getloweranim(e);
 282         //print("UPPER: ", vtos(upper), ", LOWER: ", vtos(lower), "\n");
 283         if(upper_z > lower_z)
 284                 lower = upper;
 285         else if(lower_z > upper_z)
 286                 upper = lower;
 287         if(support_blending)
 288         {
 289                 if(e.frame1time != upper_y || e.frame2time != lower_y)
 290                         BITXOR_ASSIGN(e.effects, EF_RESTARTANIM_BIT);
 291                 e.fld_frame = upper_x;
 292                 e.fld_frame1time = upper_y;
 293                 e.fld_frame2 = lower_x;
 294                 e.fld_frame2time = lower_y;
 295         }
 296         else
 297         {
 298                 if(e.frame1time != upper_y)
 299                         BITXOR_ASSIGN(e.effects, EF_RESTARTANIM_BIT);
 300                 e.fld_frame = upper_x;
 301                 e.fld_frame1time = upper_y;
 302         }
 303 }
 304
 305 void animdecide_setstate(entity e, float newstate, float restart)
 306 {
 307         if(!restart)
 308                 if(newstate == e.anim_state)
 309                         return;
 310         e.anim_state = newstate;
 311         e.anim_time = time;
 312 }
 313 void animdecide_setaction(entity e, float action, float restart)
 314 {
 315         if(action < 0)
 316         {
 317                 if(!restart)
 318                         if(action == e.anim_lower_action)
 319                                 return;
 320                 e.anim_lower_action = action;
 321                 e.anim_lower_time = time;
 322         }
 323         else
 324         {
 325                 if(!restart)
 326                         if(action == e.anim_upper_action)
 327                                 return;
 328                 e.anim_upper_action = action;
 329                 e.anim_upper_time = time;
 330         }
 331 }