qcsrc/common/command/generic.qc

   1 // =========================================================
   2 //  Generic program common command code, written by Samual
   3 //  Last updated: February 19th, 2012
   4 // =========================================================
   5
   6 // used by generic commands for better help/usage information
   7 string GetProgramCommandPrefix(void)
   8 {
   9         #ifdef SVQC
  10         return "sv_cmd";
  11         #endif
  12         #ifdef CSQC
  13         return "cl_cmd";
  14         #endif
  15         #ifdef MENUQC
  16         return "menu_cmd";
  17         #endif
  18 }
  19
  20 // used by curl command
  21 void Curl_URI_Get_Callback(float id, float status, string data)
  22 {
  23         float i;
  24         float do_exec;
  25         string do_cvar;
  26         i = id - URI_GET_CURL;
  27         do_exec = curl_uri_get_exec[i];
  28         do_cvar = curl_uri_get_cvar[i];
  29         if(status != 0)
  30         {
  31                 print(sprintf(_("error: status is %d\n"), status));
  32                 if(do_cvar)
  33                         strunzone(do_cvar);
  34                 return;
  35         }
  36         if(do_exec)
  37                 localcmd(data);
  38         if(do_cvar)
  39         {
  40                 cvar_set(do_cvar, data);
  41                 strunzone(do_cvar);
  42         }
  43         if(!do_exec)
  44                 if not(do_cvar)
  45                         print(data);
  46 }
  47
  48
  49 // =======================
  50 //  Command Sub-Functions
  51 // =======================
  52
  53 void GenericCommand_addtolist(float request, float argc)
  54 {
  55         switch(request)
  56         {
  57                 case CMD_REQUEST_COMMAND:
  58                 {
  59                         float i;
  60
  61                         if(argc >= 2)
  62                         {
  63                                 string original_cvar = argv(1);
  64                                 string tmp_string = argv(2);
  65
  66                                 if(cvar_string(original_cvar) == "") // cvar was empty
  67                                 {
  68                                         cvar_set(original_cvar, tmp_string);
  69                                 }
  70                                 else // add it to the end of the list if the list doesn't already have it
  71                                 {
  72                                         argc = tokenizebyseparator(cvar_string(original_cvar), " ");
  73
  74                                         for(i = 0; i < argc; ++i)
  75                                                 if(argv(i) == tmp_string)
  76                                                         return; // already in list
  77
  78                                         cvar_set(original_cvar, strcat(tmp_string, " ", cvar_string(original_cvar)));
  79                                 }
  80                                 return;
  81                         }
  82                 }
  83
  84                 default:
  85                         print("Incorrect parameters for ^2addtolist^7\n");
  86                 case CMD_REQUEST_USAGE:
  87                 {
  88                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " addtolist variable value\n"));
  89                         print("  Where 'variable' is what to add 'value' to.\n");
  90                         print("See also: ^2removefromlist^7\n");
  91                         return;
  92                 }
  93         }
  94 }
  95
  96 void GenericCommand_curl(float request, float argc)
  97 {
  98         switch(request)
  99         {
 100                 case CMD_REQUEST_COMMAND:
 101                 {
 102                         float do_exec;
 103                         string do_cvar;
 104                         float key;
 105                         float i, j;
 106                         string url;
 107                         float buf;
 108                         float r;
 109
 110                         do_exec = FALSE;
 111                         do_cvar = string_null;
 112                         key = -1;
 113
 114                         for(i = 1; i+1 < argc; ++i)
 115                         {
 116                                 if(argv(i) == "--cvar" && i+2 < argc)
 117                                 {
 118                                         ++i;
 119                                         do_cvar = strzone(argv(i));
 120                                         continue;
 121                                 }
 122                                 if(argv(i) == "--exec")
 123                                 {
 124                                         do_exec = TRUE;
 125                                         continue;
 126                                 }
 127                                 if(argv(i) == "--key" && i+2 < argc)
 128                                 {
 129                                         ++i;
 130                                         key = stof(argv(i));
 131                                         continue;
 132                                 }
 133                                 break;
 134                         }
 135
 136                         // now, argv(i) is the URL
 137                         // following args may be POST parameters
 138                         url = argv(i);
 139                         ++i;
 140                         buf = buf_create();
 141                         j = 0;
 142                         for(; i+1 < argc; i += 2)
 143                                 bufstr_set(buf, ++j, sprintf("%s=%s", uri_escape(argv(i)), uri_escape(argv(i+1))));
 144                         if(i < argc)
 145                                 bufstr_set(buf, ++j, sprintf("submit=%s", uri_escape(argv(i))));
 146
 147                         if(j == 0) // no args: GET
 148                                 r = crypto_uri_postbuf(url, URI_GET_CURL + curl_uri_get_pos, string_null, string_null, -1, key);
 149                         else // with args: POST
 150                                 r = crypto_uri_postbuf(url, URI_GET_CURL + curl_uri_get_pos, "application/x-www-form-urlencoded", "&", buf, key);
 151
 152                         if(r)
 153                         {
 154                                 curl_uri_get_exec[curl_uri_get_pos] = do_exec;
 155                                 curl_uri_get_cvar[curl_uri_get_pos] = do_cvar;
 156                                 curl_uri_get_pos = mod(curl_uri_get_pos + 1, URI_GET_CURL_END - URI_GET_CURL + 1);
 157                         }
 158                         else
 159                                 print(_("error creating curl handle\n"));
 160
 161                         buf_del(buf);
 162
 163                         return;
 164                 }
 165
 166                 default:
 167                 case CMD_REQUEST_USAGE:
 168                 {
 169                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " curl [--key N] [--cvar] [--exec] URL [postargs...]"));
 170                         return;
 171                 }
 172         }
 173 }
 174
 175 void GenericCommand_dumpcommands(float request)
 176 {
 177         switch(request)
 178         {
 179                 case CMD_REQUEST_COMMAND:
 180                 {
 181                         float fh;
 182                         string filename = strcat(GetProgramCommandPrefix(), "_dump.txt");
 183                         fh = fopen(filename, FILE_WRITE);
 184
 185                         if(fh >= 0)
 186                         {
 187                                 #ifdef SVQC
 188                                         CMD_Write("dump of server console commands:\n");
 189                                         GameCommand_macro_write_aliases(fh);
 190
 191                                         CMD_Write("\ndump of networked client only commands:\n");
 192                                         ClientCommand_macro_write_aliases(fh);
 193
 194                                         CMD_Write("\ndump of common commands:\n");
 195                                         CommonCommand_macro_write_aliases(fh);
 196
 197                                         CMD_Write("\ndump of ban commands:\n");
 198                                         BanCommand_macro_write_aliases(fh);
 199                                 #endif
 200
 201                                 #ifdef CSQC
 202                                         CMD_Write("dump of client commands:\n");
 203                                         LocalCommand_macro_write_aliases(fh);
 204                                 #endif
 205
 206                                 CMD_Write("\ndump of generic commands:\n");
 207                                 GenericCommand_macro_write_aliases(fh);
 208
 209                                 print("Completed dump of aliases in ^2data/data/", GetProgramCommandPrefix(), "_dump.txt^7.\n");
 210
 211                                 fclose(fh);
 212                         }
 213                         else
 214                         {
 215                                 print("^1Error: ^7Could not dump to file!\n");
 216                         }
 217                         return;
 218                 }
 219
 220                 default:
 221                 case CMD_REQUEST_USAGE:
 222                 {
 223                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " dumpcommands"));
 224                         print("  No arguments required.\n");
 225                         return;
 226                 }
 227         }
 228 }
 229
 230 void GenericCommand_maplist(float request, float argc)
 231 {
 232         switch(request)
 233         {
 234                 case CMD_REQUEST_COMMAND:
 235                 {
 236                         string tmp_string;
 237                         float i;
 238
 239                         switch(argv(1))
 240                         {
 241                                 case "add": // appends new maps to the maplist
 242                                 {
 243                                         if(argc == 3)
 244                                         {
 245                                                 if (!fexists(strcat("maps/", argv(2), ".bsp")))
 246                                                 {
 247                                                         print("maplist: ERROR: ", argv(2), " does not exist!\n");
 248                                                         break;
 249                                                 }
 250
 251                                                 if(cvar_string("g_maplist") == "")
 252                                                         cvar_set("g_maplist", argv(2));
 253                                                 else
 254                                                         cvar_set("g_maplist", strcat(argv(2), " ", cvar_string("g_maplist")));
 255
 256                                                 return;
 257                                         }
 258                                         break; // go to usage
 259                                 }
 260
 261                                 case "cleanup": // scans maplist and only adds back the ones which are really usable
 262                                 {
 263                                         MapInfo_Enumerate();
 264                                         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 265                                         argc = tokenizebyseparator(cvar_string("g_maplist"), " ");
 266
 267                                         tmp_string = "";
 268                                         for(i = 0; i < argc; ++i)
 269                                                 if(MapInfo_CheckMap(argv(i)))
 270                                                         tmp_string = strcat(tmp_string, " ", argv(i));
 271
 272                                         tmp_string = substring(tmp_string, 1, strlen(tmp_string) - 1);
 273                                         cvar_set("g_maplist", tmp_string);
 274
 275                                         return;
 276                                 }
 277
 278                                 case "remove": // scans maplist and only adds back whatever maps were not provided in argv(2)
 279                                 {
 280                                         if(argc == 3)
 281                                         {
 282                                                 argc = tokenizebyseparator(cvar_string("g_maplist"), " ");
 283
 284                                                 tmp_string = "";
 285                                                 for(i = 0; i < argc; ++i)
 286                                                         if(argv(i) != argv(2))
 287                                                                 tmp_string = strcat(tmp_string, " ", argv(i));
 288
 289                                                 tmp_string = substring(tmp_string, 1, strlen(tmp_string) - 1);
 290                                                 cvar_set("g_maplist", tmp_string);
 291
 292                                                 return;
 293                                         }
 294                                         break; // go to usage
 295                                 }
 296
 297                                 case "shuffle": // randomly shuffle the maplist
 298                                 {
 299                                         cvar_set("g_maplist", shufflewords(cvar_string("g_maplist")));
 300                                         return;
 301                                 }
 302
 303                                 default: break;
 304                         }
 305                 }
 306
 307                 default:
 308                         print("Incorrect parameters for ^2maplist^7\n");
 309                 case CMD_REQUEST_USAGE:
 310                 {
 311                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " maplist action [map]\n"));
 312                         print("  Where 'action' is the command to complete,\n");
 313                         print("  and 'map' is what it acts upon (if required).\n");
 314                         print("  Full list of commands here: \"add, cleanup, remove, shuffle.\"\n");
 315                         return;
 316                 }
 317         }
 318 }
 319
 320 void GenericCommand_nextframe(float request, float arguments, string command)
 321 {
 322         switch(request)
 323         {
 324                 case CMD_REQUEST_COMMAND:
 325                 {
 326                         queue_to_execute_next_frame(substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 327                         return;
 328                 }
 329
 330                 default:
 331                 case CMD_REQUEST_USAGE:
 332                 {
 333                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " nextframe command...\n"));
 334                         print("  Where command will be executed next frame of this VM\n");
 335                         return;
 336                 }
 337         }
 338 }
 339
 340 void GenericCommand_removefromlist(float request, float argc)
 341 {
 342         switch(request)
 343         {
 344                 case CMD_REQUEST_COMMAND:
 345                 {
 346                         if(argc == 3)
 347                         {
 348                                 float i;
 349                                 string original_cvar = argv(1);
 350                                 string removal = argv(2);
 351                                 string tmp_string;
 352
 353                                 argc = tokenizebyseparator(cvar_string(original_cvar), " ");
 354
 355                                 tmp_string = "";
 356                                 for(i = 0; i < argc; ++i)
 357                                         if(argv(i) != removal)
 358                                                 tmp_string = strcat(tmp_string, " ", argv(i));
 359
 360                                 tmp_string = substring(tmp_string, 1, strlen(tmp_string) - 1);
 361                                 cvar_set(original_cvar, tmp_string);
 362
 363                                 return;
 364                         }
 365                 }
 366
 367                 default:
 368                         print("Incorrect parameters for ^2removefromlist^7\n");
 369                 case CMD_REQUEST_USAGE:
 370                 {
 371                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " removefromlist variable value\n"));
 372                         print("  Where 'variable' is what cvar to remove 'value' from.\n");
 373                         print("See also: ^2addtolist^7\n");
 374                         return;
 375                 }
 376         }
 377 }
 378
 379 void GenericCommand_settemp(float request, float argc)
 380 {
 381         switch(request)
 382         {
 383                 case CMD_REQUEST_COMMAND:
 384                 {
 385                         if(argc >= 3)
 386                         {
 387                                 float f = cvar_settemp(argv(1), argv(2));
 388                                 if(f == 1)
 389                                         dprint("Creating new settemp tracker for ", argv(1), " and setting it to \"", argv(2), "\" temporarily.\n");
 390                                 else if(f == -1)
 391                                         dprint("Already had a tracker for ", argv(1), ", updating it to \"", argv(2), "\".\n");
 392                                 // else cvar_settemp itself errors out
 393
 394                                 return;
 395                         }
 396                 }
 397
 398                 default:
 399                         print("Incorrect parameters for ^2settemp^7\n");
 400                 case CMD_REQUEST_USAGE:
 401                 {
 402                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " settemp \"cvar\" \"arguments\"\n"));
 403                         print("  Where 'cvar' is the cvar you want to temporarily set with 'arguments'.\n");
 404                         print("See also: ^2settemp_restore^7\n");
 405                         return;
 406                 }
 407         }
 408 }
 409
 410 void GenericCommand_settemp_restore(float request, float argc)
 411 {
 412         switch(request)
 413         {
 414                 case CMD_REQUEST_COMMAND:
 415                 {
 416                         float i = cvar_settemp_restore();
 417
 418                         if(i)
 419                                 dprint("Restored ", ftos(i), " temporary cvar settings to their original values.\n");
 420                         else
 421                                 dprint("Nothing to restore.\n");
 422
 423                         return;
 424                 }
 425
 426                 default:
 427                 case CMD_REQUEST_USAGE:
 428                 {
 429                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " settemp_restore\n"));
 430                         print("  No arguments required.\n");
 431                         print("See also: ^2settemp^7\n");
 432                         return;
 433                 }
 434         }
 435 }
 436
 437 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 438 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 439 void GenericCommand_(float request)
 440 {
 441         switch(request)
 442         {
 443                 case CMD_REQUEST_COMMAND:
 444                 {
 445
 446                         return;
 447                 }
 448
 449                 default:
 450                 case CMD_REQUEST_USAGE:
 451                 {
 452                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " "));
 453                         print("  No arguments required.\n");
 454                         return;
 455                 }
 456         }
 457 }
 458 */
 459
 460 // ==================================
 461 //  Macro system for server commands
 462 // ==================================
 463
 464 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 465 #define GENERIC_COMMANDS(request,arguments,command) \
 466         GENERIC_COMMAND("addtolist", GenericCommand_addtolist(request, arguments), "Add a string to a cvar") \
 467         GENERIC_COMMAND("curl", GenericCommand_curl(request, arguments), "Queries an URL") \
 468         GENERIC_COMMAND("dumpcommands", GenericCommand_dumpcommands(request), "Dump all commands on the program to *_cmd_dump.txt") \
 469         GENERIC_COMMAND("maplist", GenericCommand_maplist(request, arguments), "Automatic control of maplist") \
 470         GENERIC_COMMAND("nextframe", GenericCommand_nextframe(request, arguments, command), "Execute the given command next frame of this VM") \
 471         GENERIC_COMMAND("removefromlist", GenericCommand_removefromlist(request, arguments), "Remove a string from a cvar") \
 472         GENERIC_COMMAND("rpn", GenericCommand_rpn(request, arguments, command), "RPN calculator") \
 473         GENERIC_COMMAND("settemp", GenericCommand_settemp(request, arguments), "Temporarily set a value to a cvar which is restored later") \
 474         GENERIC_COMMAND("settemp_restore", GenericCommand_settemp_restore(request, arguments), "Restore all cvars set by settemp command") \
 475         /* nothing */
 476
 477 void GenericCommand_macro_help()
 478 {
 479         #define GENERIC_COMMAND(name,function,description) \
 480                 { print("  ^2", name, "^7: ", description, "\n"); }
 481
 482         GENERIC_COMMANDS(0, 0, "")
 483         #undef GENERIC_COMMAND
 484
 485         return;
 486 }
 487
 488 float GenericCommand_macro_command(float argc, string command)
 489 {
 490         #define GENERIC_COMMAND(name,function,description) \
 491                 { if(name == strtolower(argv(0))) { function; return TRUE; } }
 492
 493         GENERIC_COMMANDS(CMD_REQUEST_COMMAND, argc, command)
 494         #undef GENERIC_COMMAND
 495
 496         return FALSE;
 497 }
 498
 499 float GenericCommand_macro_usage(float argc)
 500 {
 501         #define GENERIC_COMMAND(name,function,description) \
 502                 { if(name == strtolower(argv(1))) { function; return TRUE; } }
 503
 504         GENERIC_COMMANDS(CMD_REQUEST_USAGE, argc, "")
 505         #undef GENERIC_COMMAND
 506
 507         return FALSE;
 508 }
 509
 510 void GenericCommand_macro_write_aliases(float fh)
 511 {
 512         #define GENERIC_COMMAND(name,function,description) \
 513                 { CMD_Write_Alias("qc_cmd_svmenu", name, description); }
 514
 515         GENERIC_COMMANDS(0, 0, "")
 516         #undef GENERIC_COMMAND
 517
 518         return;
 519 }
 520
 521
 522 // ===========================================
 523 //  Main Common Function For Generic Commands
 524 // ===========================================
 525 // Commands spread out among all programs (menu, client, and server)
 526
 527 float GenericCommand(string command)
 528 {
 529         float argc = tokenize_console(command);
 530         float n, j, f, i;
 531         string s, s2, c;
 532         vector rgb;
 533
 534         // Guide for working with argc arguments by example:
 535         // argc:   1    - 2      - 3     - 4
 536         // argv:   0    - 1      - 2     - 3
 537         // cmd     vote - master - login - password
 538
 539         if(GenericCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
 540         {
 541                 return TRUE; // handled by one of the above GenericCommand_* functions
 542         }
 543         else if(argc >= 3 && argv(0) == "red")
 544         {
 545                 s = substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2));
 546                 localcmd(strcat(argv(1), " ", GenericCommand_markup(s)));
 547                 return TRUE;
 548         }
 549         else if(argc >= 3 && crc16(0, argv(0)) == 38566 && crc16(0, strcat(argv(0), argv(0), argv(0))) == 59830)
 550         {
 551                 // other test case
 552                 s = strconv(2, 0, 0, substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
 553
 554                 n = floor(random() * 6 + 2);
 555
 556                 s2 = "";
 557                 for(i = 0; i < n; ++i)
 558                 {
 559                         s2 = strcat(s2, "AH");
 560                 }
 561
 562                 if(random() < 0.1)
 563                         s2 = strcat(substring(s2, 1, strlen(s2) - 1), "A");
 564
 565                 if(s == "")
 566                         s = s2;
 567                 else
 568                         if(random() < 0.8)
 569                                 s = strcat(s, " ", s2);
 570                         else
 571                                 s = strcat(s2, " ", s);
 572
 573                 s2 = substring(s, strlen(s) - 2, 2);
 574                 if(s2 == "AH" || s2 == "AY")
 575                         s = strcat(s, "))");
 576                 else
 577                         s = strcat(s, " ))");
 578
 579                 if(random() < 0.1)
 580                         s = substring(s, 0, strlen(s) - 1);
 581
 582                 if(random() < 0.1)
 583                         s = strconv(1, 0, 0, s);
 584
 585                 localcmd(strcat(argv(1), " ", s));
 586
 587                 return TRUE;
 588         }
 589         else if(argc >= 3 && crc16(0, argv(0)) == 3826 && crc16(0, strcat(argv(0), argv(0), argv(0))) == 55790)
 590         {
 591                 // test case for terencehill's color codes
 592                 s = strdecolorize(substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
 593                 s2 = "";
 594
 595                 n = strlen(s);
 596                 j = ((6 * max(1, floor(strlen(s)/32 + random() * 2 - 1))) / n) * (1 - 2 * (random() > 0.5));
 597                 f = random() * 6;
 598
 599                 for(i = 0; i < n; ++i)
 600                 {
 601                         c = substring(s, i, 1);
 602
 603                         if(c == ";")
 604                                 c = ":";
 605                         else if(c == "^")
 606                         {
 607                                 c = "^^";
 608                                 if(substring(s, i+1, 1) == "^")
 609                                         ++i;
 610                         }
 611
 612                         if(c != " ")
 613                         {
 614                                 rgb = hsl_to_rgb('1 0 0' * (j * i + f) + '0 1 .5');
 615                                 c = strcat(rgb_to_hexcolor(rgb), c);
 616                         }
 617                         s2 = strcat(s2, c);
 618                 }
 619
 620                 localcmd(strcat(argv(1), " ", s2));
 621
 622                 return TRUE;
 623         }
 624
 625         return FALSE;
 626 }