qcsrc/common/gamemodes/gamemode/freezetag/sv_freezetag.qc

   1 #include "sv_freezetag.qh"
   2
   3 #include <common/resources/sv_resources.qh>
   4 #include <server/elimination.qh>
   5
   6 float autocvar_g_freezetag_frozen_maxtime;
   7 float autocvar_g_freezetag_revive_clearspeed;
   8 float autocvar_g_freezetag_round_timelimit;
   9 //int autocvar_g_freezetag_teams;
  10 int autocvar_g_freezetag_teams_override;
  11 float autocvar_g_freezetag_warmup;
  12
  13 float autocvar_g_ft_start_health = 100;
  14 float autocvar_g_ft_start_armor = 100;
  15 float autocvar_g_ft_start_ammo_shells = 60;
  16 float autocvar_g_ft_start_ammo_nails = 320;
  17 float autocvar_g_ft_start_ammo_rockets = 160;
  18 float autocvar_g_ft_start_ammo_cells = 180;
  19 float autocvar_g_ft_start_ammo_plasma = 180;
  20 float autocvar_g_ft_start_ammo_fuel = 0;
  21
  22 void freezetag_count_alive_players()
  23 {
  24         total_players = 0;
  25         for (int i = 1; i <= NUM_TEAMS; ++i)
  26         {
  27                 Team_SetNumberOfAlivePlayers(Team_GetTeamFromIndex(i), 0);
  28         }
  29         FOREACH_CLIENT(IS_PLAYER(it) && Entity_HasValidTeam(it),
  30         {
  31                 ++total_players;
  32                 if (GetResource(it, RES_HEALTH) < 1 || STAT(FROZEN, it) == FROZEN_NORMAL)
  33                 {
  34                         continue;
  35                 }
  36                 entity team_ = Entity_GetTeam(it);
  37                 int num_alive = Team_GetNumberOfAlivePlayers(team_);
  38                 ++num_alive;
  39                 Team_SetNumberOfAlivePlayers(team_, num_alive);
  40         });
  41         FOREACH_CLIENT(IS_REAL_CLIENT(it),
  42         {
  43                 STAT(REDALIVE, it) = Team_GetNumberOfAlivePlayers(Team_GetTeamFromIndex(1));
  44                 STAT(BLUEALIVE, it) = Team_GetNumberOfAlivePlayers(Team_GetTeamFromIndex(2));
  45                 STAT(YELLOWALIVE, it) = Team_GetNumberOfAlivePlayers(Team_GetTeamFromIndex(3));
  46                 STAT(PINKALIVE, it) = Team_GetNumberOfAlivePlayers(Team_GetTeamFromIndex(4));
  47         });
  48
  49         eliminatedPlayers.SendFlags |= 1;
  50 }
  51
  52 bool freezetag_CheckTeams()
  53 {
  54         static float prev_missing_teams_mask;
  55         if (Team_GetNumberOfAliveTeams() == NumTeams(freezetag_teams))
  56         {
  57                 if(prev_missing_teams_mask > 0)
  58                         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_MISSING_TEAMS);
  59                 prev_missing_teams_mask = -1;
  60                 return true;
  61         }
  62         if(total_players == 0)
  63         {
  64                 if(prev_missing_teams_mask > 0)
  65                         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_MISSING_TEAMS);
  66                 prev_missing_teams_mask = -1;
  67                 return false;
  68         }
  69         int missing_teams_mask = 0;
  70         for (int i = 1; i <= NUM_TEAMS; ++i)
  71         {
  72                 if ((freezetag_teams & Team_IndexToBit(i)) &&
  73                         (Team_GetNumberOfAlivePlayers(Team_GetTeamFromIndex(i)) == 0))
  74                 {
  75                         missing_teams_mask |= Team_IndexToBit(i);
  76                 }
  77         }
  78         if(prev_missing_teams_mask != missing_teams_mask)
  79         {
  80                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_MISSING_TEAMS, missing_teams_mask);
  81                 prev_missing_teams_mask = missing_teams_mask;
  82         }
  83         return false;
  84 }
  85
  86 void nades_Clear(entity);
  87 void nades_GiveBonus(entity player, float score);
  88
  89 bool freezetag_CheckWinner()
  90 {
  91         if(round_handler_GetEndTime() > 0 && round_handler_GetEndTime() - time <= 0)
  92         {
  93                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_ROUND_OVER);
  94                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_ROUND_OVER);
  95                 FOREACH_CLIENT(IS_PLAYER(it), {
  96                         it.freezetag_frozen_timeout = 0;
  97                         it.freezetag_revive_time = 0;
  98                         nades_Clear(it);
  99                 });
 100                 game_stopped = true;
 101                 round_handler_Init(5, autocvar_g_freezetag_warmup, autocvar_g_freezetag_round_timelimit);
 102                 return true;
 103         }
 104
 105         int winner_team = Team_GetWinnerAliveTeam();
 106         if (!winner_team)
 107                 return false;
 108
 109         if(winner_team > 0)
 110         {
 111                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, APP_TEAM_NUM(winner_team, CENTER_ROUND_TEAM_WIN));
 112                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(winner_team, INFO_ROUND_TEAM_WIN));
 113                 TeamScore_AddToTeam(winner_team, ST_FT_ROUNDS, +1);
 114         }
 115         else if(winner_team == -1)
 116         {
 117                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_ROUND_TIED);
 118                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_ROUND_TIED);
 119         }
 120
 121         FOREACH_CLIENT(IS_PLAYER(it), {
 122                 it.freezetag_frozen_timeout = 0;
 123                 it.freezetag_revive_time = 0;
 124                 nades_Clear(it);
 125         });
 126
 127         game_stopped = true;
 128         round_handler_Init(5, autocvar_g_freezetag_warmup, autocvar_g_freezetag_round_timelimit);
 129         return true;
 130 }
 131
 132 entity freezetag_LastPlayerForTeam(entity this)
 133 {
 134         entity last_pl = NULL;
 135         FOREACH_CLIENT(IS_PLAYER(it) && it != this && SAME_TEAM(it, this), {
 136                 if (STAT(FROZEN, it) != FROZEN_NORMAL && GetResource(it, RES_HEALTH) >= 1)
 137                 {
 138                         if (!last_pl)
 139                                 last_pl = it;
 140                         else
 141                                 return NULL;
 142                 }
 143         });
 144         return last_pl;
 145 }
 146
 147 void freezetag_LastPlayerForTeam_Notify(entity this)
 148 {
 149         if(round_handler_IsActive())
 150         if(round_handler_IsRoundStarted())
 151         {
 152                 entity pl = freezetag_LastPlayerForTeam(this);
 153                 if(pl)
 154                         Send_Notification(NOTIF_ONE, pl, MSG_CENTER, CENTER_ALONE);
 155         }
 156 }
 157
 158 void freezetag_Add_Score(entity targ, entity attacker)
 159 {
 160         if(attacker == targ)
 161         {
 162                 // you froze your own dumb self
 163                 // counted as "suicide" already
 164                 GameRules_scoring_add(targ, SCORE, -1);
 165         }
 166         else if(IS_PLAYER(attacker))
 167         {
 168                 // got frozen by an enemy
 169                 // counted as "kill" and "death" already
 170                 if(SAME_TEAM(attacker, targ))
 171                         GameRules_scoring_add(attacker, SCORE, -1);
 172                 else
 173                         GameRules_scoring_add(attacker, SCORE, +1);
 174                 GameRules_scoring_add(targ, SCORE, -1);
 175         }
 176         // else nothing - got frozen by the game type rules themselves
 177 }
 178
 179 // to be called when the player is frozen by freezetag (on death, spectator join etc), gives the score
 180 void freezetag_Freeze(entity targ, entity attacker)
 181 {
 182         if(STAT(FROZEN, targ))
 183                 return;
 184
 185         targ.freezetag_frozen_time = time;
 186         if (autocvar_g_freezetag_revive_auto && autocvar_g_freezetag_frozen_maxtime > 0)
 187                 targ.freezetag_frozen_timeout = time + autocvar_g_freezetag_frozen_maxtime;
 188
 189         Freeze(targ, 0, FROZEN_NORMAL, true);
 190
 191         freezetag_count_alive_players();
 192
 193         freezetag_Add_Score(targ, attacker);
 194 }
 195
 196 bool freezetag_isEliminated(entity e)
 197 {
 198         if(IS_PLAYER(e) && (STAT(FROZEN, e) == FROZEN_NORMAL || IS_DEAD(e)))
 199                 return true;
 200         return false;
 201 }
 202
 203
 204 // ================
 205 // Bot player logic
 206 // ================
 207
 208 void(entity this) havocbot_role_ft_freeing;
 209 void(entity this) havocbot_role_ft_offense;
 210
 211 void havocbot_goalrating_ft_freeplayers(entity this, float ratingscale, vector org, float sradius)
 212 {
 213         entity best_pl = NULL;
 214         float best_dist2 = FLOAT_MAX;
 215         FOREACH_CLIENT(IS_PLAYER(it) && it != this && SAME_TEAM(it, this), {
 216                 if (STAT(FROZEN, it) == FROZEN_NORMAL)
 217                 {
 218                         if(vdist(it.origin - org, >, sradius))
 219                                 continue;
 220                         navigation_routerating(this, it, ratingscale, 2000);
 221                 }
 222                 else if (best_dist2
 223                         && GetResource(it, RES_HEALTH) < GetResource(this, RES_HEALTH) + 30
 224                         && vlen2(it.origin - org) < best_dist2)
 225                 {
 226                         // If teamate is not frozen still seek them out as fight better
 227                         // in a group.
 228                         best_dist2 = vlen2(it.origin - org);
 229                         if (best_dist2 < 700 ** 2)
 230                         {
 231                                 best_pl = NULL;
 232                                 best_dist2 = 0; // already close to a teammate
 233                         }
 234                         else
 235                                 best_pl = it;
 236                 }
 237         });
 238         if (best_pl)
 239                 navigation_routerating(this, best_pl, ratingscale / 2, 2000);
 240 }
 241
 242 void havocbot_role_ft_offense(entity this)
 243 {
 244         if(IS_DEAD(this))
 245                 return;
 246
 247         if (!this.havocbot_role_timeout)
 248                 this.havocbot_role_timeout = time + random() * 10 + 20;
 249
 250         // Count how many players on team are unfrozen.
 251         int unfrozen = 0;
 252         FOREACH_CLIENT(IS_PLAYER(it) && SAME_TEAM(it, this) && STAT(FROZEN, it) != FROZEN_NORMAL, {
 253                 unfrozen++;
 254         });
 255
 256         // If only one left on team or if role has timed out then start trying to free players.
 257         if ((!unfrozen && STAT(FROZEN, this) != FROZEN_NORMAL) || time > this.havocbot_role_timeout)
 258         {
 259                 LOG_TRACE("changing role to freeing");
 260                 this.havocbot_role = havocbot_role_ft_freeing;
 261                 this.havocbot_role_timeout = 0;
 262                 return;
 263         }
 264
 265         if (navigation_goalrating_timeout(this))
 266         {
 267                 navigation_goalrating_start(this);
 268                 havocbot_goalrating_items(this, 12000, this.origin, 10000);
 269                 havocbot_goalrating_enemyplayers(this, 10000, this.origin, 10000);
 270                 havocbot_goalrating_ft_freeplayers(this, 9000, this.origin, 10000);
 271                 havocbot_goalrating_waypoints(this, 1, this.origin, 3000);
 272                 navigation_goalrating_end(this);
 273
 274                 navigation_goalrating_timeout_set(this);
 275         }
 276 }
 277
 278 void havocbot_role_ft_freeing(entity this)
 279 {
 280         if(IS_DEAD(this))
 281                 return;
 282
 283         if (!this.havocbot_role_timeout)
 284                 this.havocbot_role_timeout = time + random() * 10 + 20;
 285
 286         if (time > this.havocbot_role_timeout)
 287         {
 288                 LOG_TRACE("changing role to offense");
 289                 this.havocbot_role = havocbot_role_ft_offense;
 290                 this.havocbot_role_timeout = 0;
 291                 return;
 292         }
 293
 294         if (navigation_goalrating_timeout(this))
 295         {
 296                 navigation_goalrating_start(this);
 297                 havocbot_goalrating_items(this, 10000, this.origin, 10000);
 298                 havocbot_goalrating_enemyplayers(this, 5000, this.origin, 10000);
 299                 havocbot_goalrating_ft_freeplayers(this, 20000, this.origin, 10000);
 300                 havocbot_goalrating_waypoints(this, 1, this.origin, 3000);
 301                 navigation_goalrating_end(this);
 302
 303                 navigation_goalrating_timeout_set(this);
 304         }
 305 }
 306
 307
 308 // ==============
 309 // Hook Functions
 310 // ==============
 311
 312 void ft_RemovePlayer(entity this)
 313 {
 314         if (STAT(FROZEN, this) != FROZEN_NORMAL)
 315                 freezetag_LastPlayerForTeam_Notify(this);
 316         Unfreeze(this, false);
 317
 318         SetResourceExplicit(this, RES_HEALTH, 0); // neccessary to correctly count alive players
 319         freezetag_count_alive_players();
 320 }
 321
 322 MUTATOR_HOOKFUNCTION(ft, ClientDisconnect)
 323 {
 324         entity player = M_ARGV(0, entity);
 325
 326         ft_RemovePlayer(player);
 327         return true;
 328 }
 329
 330 MUTATOR_HOOKFUNCTION(ft, MakePlayerObserver)
 331 {
 332         entity player = M_ARGV(0, entity);
 333
 334         ft_RemovePlayer(player);
 335 }
 336
 337 MUTATOR_HOOKFUNCTION(ft, PlayerDies)
 338 {
 339         entity frag_attacker = M_ARGV(1, entity);
 340         entity frag_target = M_ARGV(2, entity);
 341         float frag_deathtype = M_ARGV(3, float);
 342
 343         if(round_handler_IsActive())
 344         if(round_handler_CountdownRunning())
 345         {
 346                 if (STAT(FROZEN, frag_target) == FROZEN_NORMAL)
 347                         Unfreeze(frag_target, true);
 348                 freezetag_count_alive_players();
 349                 frag_target.respawn_time = time;
 350                 frag_target.respawn_flags |= RESPAWN_FORCE;
 351                 return true;
 352         }
 353
 354         frag_target.respawn_time = time + 1;
 355         frag_target.respawn_flags |= RESPAWN_FORCE;
 356
 357         // let the player die, they will be automatically frozen when they respawn
 358         // it fixes a bug where you both really die (gibbing) and get frozen
 359         // if you succeed changing team through the menu
 360         if (frag_deathtype == DEATH_TEAMCHANGE.m_id || frag_deathtype == DEATH_AUTOTEAMCHANGE.m_id)
 361         {
 362                 freezetag_Add_Score(frag_target, frag_attacker);
 363                 freezetag_count_alive_players();
 364                 freezetag_LastPlayerForTeam_Notify(frag_target);
 365                 frag_target.freezetag_frozen_timeout = -2; // freeze on respawn
 366                 return true;
 367         }
 368
 369         if(ITEM_DAMAGE_NEEDKILL(frag_deathtype))
 370         {
 371                 // can't use freezetag_Add_Score here since it doesn't assign any points
 372                 // if the attacker is not a player (e.g. triggerhurt) by design
 373                 if ((STAT(FROZEN, frag_target) != FROZEN_NORMAL) && !IS_PLAYER(frag_attacker))
 374                         GameRules_scoring_add(frag_target, SCORE, -1);
 375
 376                 // by restoring some health right after player death (soft-kill)
 377                 // weapons and ammo won't be reset
 378                 SetResourceExplicit(frag_target, RES_HEALTH, 1);
 379                 // restore armor as it was removed in PlayerDamage
 380                 SetResourceExplicit(frag_target, RES_ARMOR, frag_target.freezetag_frozen_armor);
 381
 382                 // relocate
 383                 entity spot = SelectSpawnPoint(frag_target, true);
 384                 setorigin(frag_target, spot.origin);
 385                 frag_target.oldorigin = frag_target.origin;
 386                 frag_target.fixangle = true; // turn this way immediately
 387                 frag_target.angles = vec2(spot.angles);
 388                 frag_target.velocity = '0 0 0';
 389                 frag_target.oldvelocity = frag_target.velocity; // prevents fall damage, see CreatureFrame_FallDamage
 390                 frag_target.avelocity = '0 0 0';
 391                 frag_target.punchangle = '0 0 0';
 392                 frag_target.punchvector = '0 0 0';
 393         }
 394
 395         if (STAT(FROZEN, frag_target) == FROZEN_NORMAL)
 396                 return true;
 397
 398         freezetag_Freeze(frag_target, frag_attacker);
 399         freezetag_LastPlayerForTeam_Notify(frag_target);
 400
 401         if(frag_attacker == frag_target || frag_attacker == NULL)
 402         {
 403                 if(IS_PLAYER(frag_target))
 404                         Send_Notification(NOTIF_ONE, frag_target, MSG_CENTER, CENTER_FREEZETAG_SELF);
 405                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_FREEZETAG_SELF, frag_target.netname);
 406         }
 407         else
 408         {
 409                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_FREEZETAG_FREEZE, frag_target.netname, frag_attacker.netname);
 410         }
 411
 412         return true;
 413 }
 414
 415 MUTATOR_HOOKFUNCTION(ft, PlayerSpawn)
 416 {
 417         entity player = M_ARGV(0, entity);
 418
 419         if(player.freezetag_frozen_timeout == -1) // if PlayerSpawn is called by reset_map_players
 420                 return true; // do nothing, round is starting right now
 421
 422         if(player.freezetag_frozen_timeout <= -2) // player was dead
 423         {
 424                 freezetag_Freeze(player, NULL);
 425                 return true;
 426         }
 427
 428         freezetag_count_alive_players();
 429
 430         if(round_handler_IsActive())
 431         if(round_handler_IsRoundStarted())
 432         {
 433                 Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_FREEZETAG_SPAWN_LATE);
 434                 freezetag_Freeze(player, NULL);
 435         }
 436
 437         return true;
 438 }
 439
 440 MUTATOR_HOOKFUNCTION(ft, PutClientInServer)
 441 {
 442         eliminatedPlayers.SendFlags |= 1;
 443 }
 444
 445 MUTATOR_HOOKFUNCTION(ft, reset_map_players)
 446 {
 447         FOREACH_CLIENT(IS_PLAYER(it), {
 448                 CS(it).killcount = 0;
 449                 it.freezetag_revive_time = 0;
 450                 it.freezetag_frozen_timeout = -1;
 451                 PutClientInServer(it);
 452                 it.freezetag_frozen_timeout = 0;
 453         });
 454         freezetag_count_alive_players();
 455         return true;
 456 }
 457
 458 MUTATOR_HOOKFUNCTION(ft, GiveFragsForKill, CBC_ORDER_FIRST)
 459 {
 460         M_ARGV(2, float) = 0; // no frags counted in Freeze Tag
 461         return true;
 462 }
 463
 464 MUTATOR_HOOKFUNCTION(ft, Unfreeze)
 465 {
 466         entity targ = M_ARGV(0, entity);
 467         targ.freezetag_frozen_time = 0;
 468         targ.freezetag_frozen_timeout = 0;
 469 }
 470
 471 MUTATOR_HOOKFUNCTION(ft, Damage_Calculate)
 472 {
 473         entity frag_attacker = M_ARGV(1, entity);
 474         entity frag_target = M_ARGV(2, entity);
 475         //float frag_deathtype = M_ARGV(3, float);
 476         //float frag_damage = M_ARGV(4, float);
 477         vector frag_force = M_ARGV(6, vector);
 478
 479         frag_target.freezetag_frozen_armor = GetResource(frag_target, RES_ARMOR);
 480
 481         if (STAT(FROZEN, frag_target) == FROZEN_NORMAL && autocvar_g_freezetag_revive_auto_reducible
 482                 && autocvar_g_freezetag_frozen_maxtime > 0 && autocvar_g_freezetag_revive_auto)
 483         {
 484                 float t = 0;
 485                 if ((autocvar_g_freezetag_revive_auto_reducible < 0 || DIFF_TEAM(frag_attacker, frag_target))
 486                         && frag_target.freezetag_frozen_timeout > time)
 487                 {
 488                         if (fabs(autocvar_g_freezetag_revive_auto_reducible) == 1)
 489                         {
 490                                 float maxforce = autocvar_g_freezetag_revive_auto_reducible_maxforce;
 491                                 t = vlen(frag_force);
 492                                 // limit hit force considered at once, e.g when you have the Strength
 493                                 // powerup but also with weapons that fire multiple projectiles at once (crylink)
 494                                 if (frag_target.freezetag_frozen_force + t > maxforce)
 495                                 {
 496                                         t = max(0, maxforce - frag_target.freezetag_frozen_force);
 497                                         frag_target.freezetag_frozen_force = maxforce;
 498                                 }
 499                                 else
 500                                         frag_target.freezetag_frozen_force += t;
 501                                 t *= autocvar_g_freezetag_revive_auto_reducible_forcefactor;
 502                         }
 503                         frag_target.freezetag_frozen_timeout -= t;
 504                         if (frag_target.freezetag_frozen_timeout < time)
 505                                 frag_target.freezetag_frozen_timeout = time;
 506                 }
 507         }
 508 }
 509
 510 #ifdef IN_REVIVING_RANGE
 511         #undef IN_REVIVING_RANGE
 512 #endif
 513
 514 #define IN_REVIVING_RANGE(player, it, revive_extra_size) \
 515         (it != player && !IS_DEAD(it) && SAME_TEAM(it, player) \
 516         && boxesoverlap(player.absmin - revive_extra_size, player.absmax + revive_extra_size, it.absmin, it.absmax))
 517
 518 MUTATOR_HOOKFUNCTION(ft, PlayerPreThink, CBC_ORDER_FIRST)
 519 {
 520         if(game_stopped)
 521                 return true;
 522
 523         if(round_handler_IsActive())
 524         if(!round_handler_IsRoundStarted())
 525                 return true;
 526
 527         entity player = M_ARGV(0, entity);
 528         //if (STAT(FROZEN, player) == FROZEN_NORMAL)
 529         //if(player.freezetag_frozen_timeout > 0 && time < player.freezetag_frozen_timeout)
 530                 //player.iceblock.alpha = ICE_MIN_ALPHA + (ICE_MAX_ALPHA - ICE_MIN_ALPHA) * (player.freezetag_frozen_timeout - time) / (player.freezetag_frozen_timeout - player.freezetag_frozen_time);
 531
 532         player.freezetag_frozen_force = 0;
 533
 534         if (!(frametime && IS_PLAYER(player)))
 535                 return true;
 536
 537         entity revivers_last = NULL;
 538         entity revivers_first = NULL;
 539
 540         bool player_is_reviving = false;
 541         int n = 0;
 542         vector revive_extra_size = '1 1 1' * autocvar_g_freezetag_revive_extra_size;
 543         FOREACH_CLIENT(IS_PLAYER(it), {
 544                 // check if player is reviving anyone
 545                 if (STAT(FROZEN, it) == FROZEN_NORMAL)
 546                 {
 547                         if ((STAT(FROZEN, player) == FROZEN_NORMAL))
 548                                 continue;
 549                         if (!IN_REVIVING_RANGE(player, it, revive_extra_size))
 550                                 continue;
 551                         player_is_reviving = true;
 552                         break;
 553                 }
 554
 555                 if (!(STAT(FROZEN, player) == FROZEN_NORMAL))
 556                         continue; // both player and it are NOT frozen
 557                 if (!IN_REVIVING_RANGE(player, it, revive_extra_size))
 558                         continue;
 559
 560                 // found a teammate that is reviving player
 561                 if (autocvar_g_freezetag_revive_time_to_score > 0 && STAT(FROZEN, player) == FROZEN_NORMAL)
 562                 {
 563                         it.freezetag_revive_time += frametime / autocvar_g_freezetag_revive_time_to_score;
 564                         while (it.freezetag_revive_time > 1)
 565                         {
 566                                 GameRules_scoring_add(it, SCORE, +1);
 567                                 it.freezetag_revive_time -= 1;
 568                         }
 569                 }
 570                 if (revivers_last)
 571                         revivers_last.chain = it;
 572                 revivers_last = it;
 573                 if (!revivers_first)
 574                         revivers_first = it;
 575                 ++n;
 576         });
 577         if (revivers_last)
 578                 revivers_last.chain = NULL;
 579
 580         // allow normal revival during automatic revival
 581         // (if we wouldn't allow it then freezetag_frozen_timeout should be checked too in the previous loop)
 582         //if (STAT(FROZEN, player) == FROZEN_NORMAL) // redundant check
 583         if (!n && player.freezetag_frozen_timeout > 0 && time >= player.freezetag_frozen_timeout)
 584                 n = -1;
 585
 586         float base_progress = 0;
 587         if  (STAT(FROZEN, player) == FROZEN_NORMAL && autocvar_g_freezetag_revive_auto
 588                 && autocvar_g_freezetag_frozen_maxtime > 0 && autocvar_g_freezetag_revive_auto_progress)
 589         {
 590                 // NOTE if auto-revival is in progress, manual revive speed is reduced so that it always takes the same amount of time
 591                 base_progress = bound(0, (1 - (player.freezetag_frozen_timeout - time) / autocvar_g_freezetag_frozen_maxtime), 1);
 592         }
 593
 594         if (!n) // no teammate nearby
 595         {
 596                 float clearspeed = autocvar_g_freezetag_revive_clearspeed;
 597                 if (STAT(FROZEN, player) == FROZEN_NORMAL)
 598                 {
 599                         if (autocvar_g_freezetag_revive_time_to_score > 0)
 600                         {
 601                                 if (STAT(REVIVE_PROGRESS, player) > base_progress)
 602                                 {
 603                                         // reduce auto-revival time based on manual revival progress
 604                                         base_progress = STAT(REVIVE_PROGRESS, player);
 605                                         player.freezetag_frozen_timeout = time + autocvar_g_freezetag_frozen_maxtime * (1 - STAT(REVIVE_PROGRESS, player));
 606                                 }
 607                                 // don't clear revive progress, it would allow stacking points
 608                                 // by entering and exiting the revival zone many times
 609                                 STAT(REVIVE_PROGRESS, player) = base_progress;
 610                         }
 611                         else
 612                                 STAT(REVIVE_PROGRESS, player) = bound(base_progress, STAT(REVIVE_PROGRESS, player) - frametime * clearspeed * (1 - base_progress), 1);
 613                 }
 614                 else if (!STAT(FROZEN, player) && !player_is_reviving)
 615                         STAT(REVIVE_PROGRESS, player) = base_progress; // thawing nobody
 616         }
 617         else if (STAT(FROZEN, player) == FROZEN_NORMAL) // OK, there is at least one teammate reviving us
 618         {
 619                 float spd = autocvar_g_freezetag_revive_speed_t2s;
 620                 if (autocvar_g_freezetag_revive_time_to_score <= 0)
 621                         spd = autocvar_g_freezetag_revive_speed * (1 - base_progress);
 622                 STAT(REVIVE_PROGRESS, player) = bound(base_progress, STAT(REVIVE_PROGRESS, player) + frametime * max(1/60, spd), 1);
 623
 624                 if(STAT(REVIVE_PROGRESS, player) >= 1)
 625                 {
 626                         float frozen_time = time - player.freezetag_frozen_time;
 627                         Unfreeze(player, false);
 628                         SetResourceExplicit(player, RES_HEALTH, ((warmup_stage) ? warmup_start_health : start_health));
 629                         player.spawnshieldtime = time + autocvar_g_freezetag_revive_spawnshield;
 630                         freezetag_count_alive_players();
 631
 632                         if(n == -1)
 633                         {
 634                                 if(autocvar_sv_eventlog)
 635                                         GameLogEcho(strcat(":ft:autorevival:", ftos(player.playerid)));
 636                                 Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_FREEZETAG_AUTO_REVIVED, frozen_time);
 637                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_FREEZETAG_AUTO_REVIVED, player.netname, frozen_time);
 638                                 return true;
 639                         }
 640
 641                         // EVERY team mate nearby gets a point (even if multiple!)
 642                         for(entity it = revivers_first; it; it = it.chain)
 643                         {
 644                                 GameRules_scoring_add(it, FREEZETAG_REVIVALS, +1);
 645                                 if (autocvar_g_freezetag_revive_time_to_score <= 0)
 646                                         GameRules_scoring_add(it, SCORE, +1);
 647                                 nades_GiveBonus(it, autocvar_g_nades_bonus_score_low);
 648                         }
 649
 650                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_FREEZETAG_REVIVED, revivers_first.netname);
 651                         Send_Notification(NOTIF_ONE, revivers_first, MSG_CENTER, CENTER_FREEZETAG_REVIVE, player.netname);
 652                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_FREEZETAG_REVIVED, player.netname, revivers_first.netname);
 653                         if(autocvar_sv_eventlog)
 654                         {
 655                                 string revivers = "";
 656                                 for(entity it = revivers_first; it; it = it.chain)
 657                                         revivers = strcat(revivers, ftos(it.playerid), ",");
 658                                 revivers = substring(revivers, 0, strlen(revivers) - 1);
 659                                 GameLogEcho(strcat(":ft:revival:", ftos(player.playerid), ":", revivers));
 660                         }
 661                 }
 662
 663                 for(entity it = revivers_first; it; it = it.chain)
 664                         STAT(REVIVE_PROGRESS, it) = STAT(REVIVE_PROGRESS, player);
 665         }
 666
 667         if (STAT(FROZEN, player) == FROZEN_NORMAL)
 668         {
 669                 entity player_wp = player.waypointsprite_attached;
 670                 if (n > 0 || (n == 0 && STAT(REVIVE_PROGRESS, player) > 0.95))
 671                 {
 672                         WaypointSprite_UpdateSprites(player_wp, WP_Reviving, WP_Null, WP_Null);
 673                         WaypointSprite_UpdateTeamRadar(player_wp, RADARICON_WAYPOINT, WP_REVIVING_COLOR);
 674                 }
 675                 else
 676                 {
 677                         WaypointSprite_UpdateSprites(player_wp, WP_Frozen, WP_Null, WP_Null);
 678                         WaypointSprite_UpdateTeamRadar(player_wp, RADARICON_WAYPOINT, WP_FROZEN_COLOR);
 679                 }
 680
 681                 WaypointSprite_UpdateMaxHealth(player_wp, 1);
 682                 WaypointSprite_UpdateHealth(player_wp, STAT(REVIVE_PROGRESS, player));
 683         }
 684
 685         return true;
 686 }
 687
 688 MUTATOR_HOOKFUNCTION(ft, SetStartItems)
 689 {
 690         start_items &= ~(IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS);
 691         if(!cvar("g_use_ammunition"))
 692                 start_items |= IT_UNLIMITED_AMMO;
 693
 694         start_health       = warmup_start_health       = autocvar_g_ft_start_health;
 695         start_armorvalue   = warmup_start_armorvalue   = autocvar_g_ft_start_armor;
 696         start_ammo_shells  = warmup_start_ammo_shells  = autocvar_g_ft_start_ammo_shells;
 697         start_ammo_nails   = warmup_start_ammo_nails   = autocvar_g_ft_start_ammo_nails;
 698         start_ammo_rockets = warmup_start_ammo_rockets = autocvar_g_ft_start_ammo_rockets;
 699         start_ammo_cells   = warmup_start_ammo_cells   = autocvar_g_ft_start_ammo_cells;
 700         start_ammo_plasma  = warmup_start_ammo_plasma  = autocvar_g_ft_start_ammo_plasma;
 701         start_ammo_fuel    = warmup_start_ammo_fuel    = autocvar_g_ft_start_ammo_fuel;
 702 }
 703
 704 MUTATOR_HOOKFUNCTION(ft, HavocBot_ChooseRole)
 705 {
 706         entity bot = M_ARGV(0, entity);
 707
 708         if (!IS_DEAD(bot))
 709         {
 710                 if (random() < 0.5)
 711                         bot.havocbot_role = havocbot_role_ft_freeing;
 712                 else
 713                         bot.havocbot_role = havocbot_role_ft_offense;
 714         }
 715
 716         // if bots spawn all at once assign them a more appropriated role after a while
 717         if (time < CS(bot).jointime + 1)
 718                 bot.havocbot_role_timeout = time + 10 + random() * 10;
 719
 720         return true;
 721 }
 722
 723 MUTATOR_HOOKFUNCTION(ft, TeamBalance_CheckAllowedTeams, CBC_ORDER_EXCLUSIVE)
 724 {
 725         M_ARGV(0, float) = freezetag_teams;
 726         return true;
 727 }
 728
 729 MUTATOR_HOOKFUNCTION(ft, SetWeaponArena)
 730 {
 731         if(M_ARGV(0, string) == "0" || M_ARGV(0, string) == "")
 732                 M_ARGV(0, string) = autocvar_g_freezetag_weaponarena;
 733 }
 734
 735 MUTATOR_HOOKFUNCTION(ft, FragCenterMessage)
 736 {
 737         entity frag_attacker = M_ARGV(0, entity);
 738         entity frag_target = M_ARGV(1, entity);
 739         //float frag_deathtype = M_ARGV(2, float);
 740         int kill_count_to_attacker = M_ARGV(3, int);
 741         int kill_count_to_target = M_ARGV(4, int);
 742
 743         if(STAT(FROZEN, frag_target) == FROZEN_NORMAL)
 744                 return; // target was already frozen, so this is just pushing them off the cliff
 745
 746         Send_Notification(NOTIF_ONE, frag_attacker, MSG_CHOICE, CHOICE_FRAG_FREEZE, frag_target.netname, kill_count_to_attacker, (IS_BOT_CLIENT(frag_target) ? -1 : CS(frag_target).ping));
 747         Send_Notification(NOTIF_ONE, frag_target, MSG_CHOICE, CHOICE_FRAGGED_FREEZE, frag_attacker.netname, kill_count_to_target,
 748                 GetResource(frag_attacker, RES_HEALTH), GetResource(frag_attacker, RES_ARMOR), (IS_BOT_CLIENT(frag_attacker) ? -1 : CS(frag_attacker).ping));
 749
 750         return true;
 751 }
 752
 753 MUTATOR_HOOKFUNCTION(ft, SV_ParseServerCommand)
 754 {
 755         string cmd_name = M_ARGV(0, string);
 756         if (cmd_name == "shuffleteams")
 757                 shuffleteams_on_reset_map = !(round_handler_IsActive() && !round_handler_IsRoundStarted());
 758         return false;
 759 }
 760
 761 MUTATOR_HOOKFUNCTION(ft, Scores_CountFragsRemaining)
 762 {
 763         // announce remaining frags
 764         return true;
 765 }
 766
 767 void freezetag_Initialize()
 768 {
 769         freezetag_teams = autocvar_g_freezetag_teams_override;
 770         if(freezetag_teams < 2)
 771                 freezetag_teams = cvar("g_freezetag_teams"); // read the cvar directly as it gets written earlier in the same frame
 772
 773         freezetag_teams = BITS(bound(2, freezetag_teams, 4));
 774         GameRules_scoring(freezetag_teams, SFL_SORT_PRIO_PRIMARY, 0, {
 775                 field_team(ST_FT_ROUNDS, "rounds", SFL_SORT_PRIO_PRIMARY);
 776                 field(SP_FREEZETAG_REVIVALS, "revivals", 0);
 777         });
 778
 779         round_handler_Spawn(freezetag_CheckTeams, freezetag_CheckWinner, func_null);
 780         round_handler_Init(5, autocvar_g_freezetag_warmup, autocvar_g_freezetag_round_timelimit);
 781
 782         EliminatedPlayers_Init(freezetag_isEliminated);
 783 }