qcsrc/common/gamemodes/gamemode/onslaught/sv_onslaught.qc

   1 #include "sv_onslaught.qh"
   2 #include "sv_controlpoint.qh"
   3 #include "sv_generator.qh"
   4
   5 bool g_onslaught;
   6
   7 float autocvar_g_onslaught_teleport_wait;
   8 bool autocvar_g_onslaught_spawn_at_controlpoints;
   9 bool autocvar_g_onslaught_spawn_at_generator;
  10 float autocvar_g_onslaught_cp_proxydecap;
  11 float autocvar_g_onslaught_cp_proxydecap_distance = 512;
  12 float autocvar_g_onslaught_cp_proxydecap_dps = 100;
  13 float autocvar_g_onslaught_spawn_at_controlpoints_chance = 0.5;
  14 float autocvar_g_onslaught_spawn_at_controlpoints_random;
  15 float autocvar_g_onslaught_spawn_at_generator_chance;
  16 float autocvar_g_onslaught_spawn_at_generator_random;
  17 float autocvar_g_onslaught_cp_buildhealth;
  18 float autocvar_g_onslaught_cp_buildtime;
  19 float autocvar_g_onslaught_cp_health;
  20 float autocvar_g_onslaught_cp_regen;
  21 float autocvar_g_onslaught_gen_health;
  22 float autocvar_g_onslaught_shield_force = 100;
  23 float autocvar_g_onslaught_allow_vehicle_touch;
  24 float autocvar_g_onslaught_round_timelimit;
  25 float autocvar_g_onslaught_warmup;
  26 float autocvar_g_onslaught_teleport_radius;
  27 float autocvar_g_onslaught_spawn_choose;
  28 float autocvar_g_onslaught_click_radius;
  29
  30 void FixSize(entity e);
  31 entity cam;
  32
  33 // =======================
  34 // CaptureShield Functions
  35 // =======================
  36
  37 bool clientcamera_send(entity this, entity to, int sf)
  38 {
  39         WriteHeader(MSG_ENTITY, ENT_ONSCAMERA);
  40
  41         WriteCoord(MSG_ENTITY, this.origin_x);
  42         WriteCoord(MSG_ENTITY, this.origin_y);
  43         WriteCoord(MSG_ENTITY, this.origin_z);
  44
  45         WriteAngle(MSG_ENTITY, this.angles_x);
  46         WriteAngle(MSG_ENTITY, this.angles_y);
  47         WriteAngle(MSG_ENTITY, this.angles_z);
  48
  49         return true;
  50 }
  51
  52 bool ons_CaptureShield_Customize(entity this, entity client)
  53 {
  54         entity e = WaypointSprite_getviewentity(client);
  55
  56         if(!this.enemy.isshielded && (ons_ControlPoint_Attackable(this.enemy, e.team) > 0 || this.enemy.classname != "onslaught_controlpoint")) { return false; }
  57         if(SAME_TEAM(this, e)) { return false; }
  58
  59         return true;
  60 }
  61
  62 void ons_CaptureShield_Touch(entity this, entity toucher)
  63 {
  64         if(!this.enemy.isshielded && (ons_ControlPoint_Attackable(this.enemy, toucher.team) > 0 || this.enemy.classname != "onslaught_controlpoint")) { return; }
  65         if(!IS_PLAYER(toucher)) { return; }
  66         if(SAME_TEAM(toucher, this)) { return; }
  67
  68         vector mymid = (this.absmin + this.absmax) * 0.5;
  69         vector theirmid = (toucher.absmin + toucher.absmax) * 0.5;
  70
  71         Damage(toucher, this, this, 0, DEATH_HURTTRIGGER.m_id, mymid, normalize(theirmid - mymid) * ons_captureshield_force);
  72
  73         if(IS_REAL_CLIENT(toucher))
  74         {
  75                 play2(toucher, SND(ONS_DAMAGEBLOCKEDBYSHIELD));
  76
  77                 if(this.enemy.classname == "onslaught_generator")
  78                         Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_ONS_GENERATOR_SHIELDED);
  79                 else
  80                         Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_ONS_CONTROLPOINT_SHIELDED);
  81         }
  82 }
  83
  84 void ons_CaptureShield_Reset(entity this)
  85 {
  86         this.colormap = this.enemy.colormap;
  87         this.team = this.enemy.team;
  88 }
  89
  90 void ons_CaptureShield_Spawn(entity generator, bool is_generator)
  91 {
  92         entity shield = new(ons_captureshield);
  93         IL_PUSH(g_onsshields, shield);
  94
  95         shield.enemy = generator;
  96         shield.team = generator.team;
  97         shield.colormap = generator.colormap;
  98         shield.reset = ons_CaptureShield_Reset;
  99         settouch(shield, ons_CaptureShield_Touch);
 100         setcefc(shield, ons_CaptureShield_Customize);
 101         shield.effects = EF_ADDITIVE;
 102         set_movetype(shield, MOVETYPE_NOCLIP);
 103         shield.solid = SOLID_TRIGGER;
 104         shield.avelocity = '7 0 11';
 105         shield.scale = 1;
 106         shield.model = ((is_generator) ? "models/onslaught/generator_shield.md3" : "models/onslaught/controlpoint_shield.md3");
 107
 108         precache_model(shield.model);
 109         setorigin(shield, generator.origin);
 110         _setmodel(shield, shield.model);
 111         setsize(shield, shield.scale * shield.mins, shield.scale * shield.maxs);
 112 }
 113
 114
 115 // ==========
 116 // Junk Pile
 117 // ==========
 118
 119 void setmodel_fixsize(entity e, Model m)
 120 {
 121         setmodel(e, m);
 122         FixSize(e);
 123 }
 124
 125 void onslaught_updatelinks()
 126 {
 127         entity l;
 128         // first check if the game has ended
 129         LOG_DEBUG("--- updatelinks ---");
 130         // mark generators as being shielded and networked
 131         for(l = ons_worldgeneratorlist; l; l = l.ons_worldgeneratornext)
 132         {
 133                 if (l.iscaptured)
 134                         LOG_DEBUG(etos(l), " (generator) belongs to team ", ftos(l.team));
 135                 else
 136                         LOG_DEBUG(etos(l), " (generator) is destroyed");
 137                 l.islinked = l.iscaptured;
 138                 l.isshielded = l.iscaptured;
 139                 l.sprite.SendFlags |= 16;
 140         }
 141         // mark points as shielded and not networked
 142         for(l = ons_worldcplist; l; l = l.ons_worldcpnext)
 143         {
 144                 l.islinked = false;
 145                 l.isshielded = true;
 146                 int i;
 147                 for(i = 0; i < 17; ++i) { l.isgenneighbor[i] = false; l.iscpneighbor[i] = false; }
 148                 LOG_DEBUG(etos(l), " (point) belongs to team ", ftos(l.team));
 149                 l.sprite.SendFlags |= 16;
 150         }
 151         // flow power outward from the generators through the network
 152         bool stop = false;
 153         while (!stop)
 154         {
 155                 stop = true;
 156                 for(l = ons_worldlinklist; l; l = l.ons_worldlinknext)
 157                 {
 158                         // if both points are captured by the same team, and only one of
 159                         // them is powered, mark the other one as powered as well
 160                         if (l.enemy.iscaptured && l.goalentity.iscaptured)
 161                                 if (l.enemy.islinked != l.goalentity.islinked)
 162                                         if(SAME_TEAM(l.enemy, l.goalentity))
 163                                         {
 164                                                 if (!l.goalentity.islinked)
 165                                                 {
 166                                                         stop = false;
 167                                                         l.goalentity.islinked = true;
 168                                                         LOG_DEBUG(etos(l), " (link) is marking ", etos(l.goalentity), " (point) because its team matches ", etos(l.enemy), " (point)");
 169                                                 }
 170                                                 else if (!l.enemy.islinked)
 171                                                 {
 172                                                         stop = false;
 173                                                         l.enemy.islinked = true;
 174                                                         LOG_DEBUG(etos(l), " (link) is marking ", etos(l.enemy), " (point) because its team matches ", etos(l.goalentity), " (point)");
 175                                                 }
 176                                         }
 177                 }
 178         }
 179         // now that we know which points are powered we can mark their neighbors
 180         // as unshielded if team differs
 181         for(l = ons_worldlinklist; l; l = l.ons_worldlinknext)
 182         {
 183                 if (l.goalentity.islinked)
 184                 {
 185                         if(DIFF_TEAM(l.goalentity, l.enemy))
 186                         {
 187                                 LOG_DEBUG(etos(l), " (link) is unshielding ", etos(l.enemy), " (point) because its team does not match ", etos(l.goalentity), " (point)");
 188                                 l.enemy.isshielded = false;
 189                         }
 190                         if(l.goalentity.classname == "onslaught_generator")
 191                                 l.enemy.isgenneighbor[l.goalentity.team] = true;
 192                         else
 193                                 l.enemy.iscpneighbor[l.goalentity.team] = true;
 194                 }
 195                 if (l.enemy.islinked)
 196                 {
 197                         if(DIFF_TEAM(l.goalentity, l.enemy))
 198                         {
 199                                 LOG_DEBUG(etos(l), " (link) is unshielding ", etos(l.goalentity), " (point) because its team does not match ", etos(l.enemy), " (point)");
 200                                 l.goalentity.isshielded = false;
 201                         }
 202                         if(l.enemy.classname == "onslaught_generator")
 203                                 l.goalentity.isgenneighbor[l.enemy.team] = true;
 204                         else
 205                                 l.goalentity.iscpneighbor[l.enemy.team] = true;
 206                 }
 207         }
 208         // now update the generators
 209         for(l = ons_worldgeneratorlist; l; l = l.ons_worldgeneratornext)
 210         {
 211                 if (l.isshielded)
 212                 {
 213                         LOG_DEBUG(etos(l), " (generator) is shielded");
 214                         l.takedamage = DAMAGE_NO;
 215                         if(l.bot_attack)
 216                                 IL_REMOVE(g_bot_targets, l);
 217                         l.bot_attack = false;
 218                 }
 219                 else
 220                 {
 221                         LOG_DEBUG(etos(l), " (generator) is not shielded");
 222                         l.takedamage = DAMAGE_AIM;
 223                         if(!l.bot_attack)
 224                                 IL_PUSH(g_bot_targets, l);
 225                         l.bot_attack = true;
 226                 }
 227
 228                 ons_Generator_UpdateSprite(l);
 229         }
 230         // now update the takedamage and alpha variables on control point icons
 231         for(l = ons_worldcplist; l; l = l.ons_worldcpnext)
 232         {
 233                 if (l.isshielded)
 234                 {
 235                         LOG_DEBUG(etos(l), " (point) is shielded");
 236                         if (l.goalentity)
 237                         {
 238                                 l.goalentity.takedamage = DAMAGE_NO;
 239                                 if(l.goalentity.bot_attack)
 240                                         IL_REMOVE(g_bot_targets, l.goalentity);
 241                                 l.goalentity.bot_attack = false;
 242                         }
 243                 }
 244                 else
 245                 {
 246                         LOG_DEBUG(etos(l), " (point) is not shielded");
 247                         if (l.goalentity)
 248                         {
 249                                 l.goalentity.takedamage = DAMAGE_AIM;
 250                                 if(!l.goalentity.bot_attack)
 251                                         IL_PUSH(g_bot_targets, l.goalentity);
 252                                 l.goalentity.bot_attack = true;
 253                         }
 254                 }
 255                 ons_ControlPoint_UpdateSprite(l);
 256         }
 257         IL_EACH(g_onsshields, true,
 258         {
 259                 it.team = it.enemy.team;
 260                 it.colormap = it.enemy.colormap;
 261         });
 262 }
 263
 264
 265 // ===================
 266 // Main Link Functions
 267 // ===================
 268
 269 bool ons_Link_Send(entity this, entity to, int sendflags)
 270 {
 271         WriteHeader(MSG_ENTITY, ENT_CLIENT_RADARLINK);
 272         WriteByte(MSG_ENTITY, sendflags);
 273         if(sendflags & 1)
 274         {
 275                 WriteCoord(MSG_ENTITY, this.goalentity.origin_x);
 276                 WriteCoord(MSG_ENTITY, this.goalentity.origin_y);
 277                 WriteCoord(MSG_ENTITY, this.goalentity.origin_z);
 278         }
 279         if(sendflags & 2)
 280         {
 281                 WriteCoord(MSG_ENTITY, this.enemy.origin_x);
 282                 WriteCoord(MSG_ENTITY, this.enemy.origin_y);
 283                 WriteCoord(MSG_ENTITY, this.enemy.origin_z);
 284         }
 285         if(sendflags & 4)
 286         {
 287                 WriteByte(MSG_ENTITY, this.clientcolors); // which is goalentity's color + enemy's color * 16
 288         }
 289         return true;
 290 }
 291
 292 void ons_Link_CheckUpdate(entity this)
 293 {
 294         // TODO check if the two sides have moved (currently they won't move anyway)
 295         float cc = 0, cc1 = 0, cc2 = 0;
 296
 297         if(this.goalentity.islinked || this.goalentity.iscaptured) { cc1 = (this.goalentity.team - 1) * 0x01; }
 298         if(this.enemy.islinked || this.enemy.iscaptured) { cc2 = (this.enemy.team - 1) * 0x10; }
 299
 300         cc = cc1 + cc2;
 301
 302         if(cc != this.clientcolors)
 303         {
 304                 this.clientcolors = cc;
 305                 this.SendFlags |= 4;
 306         }
 307
 308         this.nextthink = time;
 309 }
 310
 311 void ons_DelayedLinkSetup(entity this)
 312 {
 313         this.goalentity = find(NULL, targetname, this.target);
 314         this.enemy = find(NULL, targetname, this.target2);
 315         if(!this.goalentity) { objerror(this, "can not find target\n"); }
 316         if(!this.enemy) { objerror(this, "can not find target2\n"); }
 317
 318         LOG_DEBUG(etos(this.goalentity), " linked with ", etos(this.enemy));
 319         this.SendFlags |= 3;
 320         setthink(this, ons_Link_CheckUpdate);
 321         this.nextthink = time;
 322 }
 323
 324
 325 // =============================
 326 // Main Control Point Functions
 327 // =============================
 328
 329 int ons_ControlPoint_CanBeLinked(entity cp, int teamnumber)
 330 {
 331         if(cp.isgenneighbor[teamnumber]) { return 2; }
 332         if(cp.iscpneighbor[teamnumber]) { return 1; }
 333
 334         return 0;
 335 }
 336
 337 int ons_ControlPoint_Attackable(entity cp, int teamnumber)
 338         // -2: SAME TEAM, attackable by enemy!
 339         // -1: SAME TEAM!
 340         // 0: off limits
 341         // 1: attack it
 342         // 2: touch it
 343         // 3: attack it (HIGH PRIO)
 344         // 4: touch it (HIGH PRIO)
 345 {
 346         int a;
 347
 348         if(cp.isshielded)
 349         {
 350                 return 0;
 351         }
 352         else if(cp.goalentity)
 353         {
 354                 // if there's already an icon built, nothing happens
 355                 if(cp.team == teamnumber)
 356                 {
 357                         a = ons_ControlPoint_CanBeLinked(cp, teamnumber);
 358                         if(a) // attackable by enemy?
 359                                 return -2; // EMERGENCY!
 360                         return -1;
 361                 }
 362                 // we know it can be linked, so no need to check
 363                 // but...
 364                 a = ons_ControlPoint_CanBeLinked(cp, teamnumber);
 365                 if(a == 2) // near our generator?
 366                         return 3; // EMERGENCY!
 367                 return 1;
 368         }
 369         else
 370         {
 371                 // free point
 372                 if(ons_ControlPoint_CanBeLinked(cp, teamnumber))
 373                 {
 374                         a = ons_ControlPoint_CanBeLinked(cp, teamnumber); // why was this here NUM_TEAM_1 + NUM_TEAM_2 - t
 375                         if(a == 2)
 376                                 return 4; // GET THIS ONE NOW!
 377                         else
 378                                 return 2; // TOUCH ME
 379                 }
 380         }
 381         return 0;
 382 }
 383
 384 void ons_ControlPoint_Icon_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 385 {
 386         if(damage <= 0) { return; }
 387
 388         if (this.owner.isshielded)
 389         {
 390                 // this is protected by a shield, so ignore the damage
 391                 if (time > this.pain_finished)
 392                         if (IS_PLAYER(attacker))
 393                         {
 394                                 play2(attacker, SND(ONS_DAMAGEBLOCKEDBYSHIELD));
 395                                 this.pain_finished = time + 1;
 396                                 attacker.typehitsound += 1; // play both sounds (shield is way too quiet)
 397                         }
 398
 399                 return;
 400         }
 401
 402         if(IS_PLAYER(attacker))
 403         if(time - ons_notification_time[this.team] > 10)
 404         {
 405                 play2team(this.team, SND(ONS_CONTROLPOINT_UNDERATTACK));
 406                 ons_notification_time[this.team] = time;
 407         }
 408
 409         this.health = this.health - damage;
 410         if(this.owner.iscaptured)
 411                 WaypointSprite_UpdateHealth(this.owner.sprite, this.health);
 412         else
 413                 WaypointSprite_UpdateBuildFinished(this.owner.sprite, time + (this.max_health - this.health) / (this.count / ONS_CP_THINKRATE));
 414         this.pain_finished = time + 1;
 415         // particles on every hit
 416         pointparticles(EFFECT_SPARKS, hitloc, force*-1, 1);
 417         //sound on every hit
 418         if (random() < 0.5)
 419                 sound(this, CH_TRIGGER, SND_ONS_HIT1, VOL_BASE+0.3, ATTEN_NORM);
 420         else
 421                 sound(this, CH_TRIGGER, SND_ONS_HIT2, VOL_BASE+0.3, ATTEN_NORM);
 422
 423         if (this.health < 0)
 424         {
 425                 sound(this, CH_TRIGGER, SND_GRENADE_IMPACT, VOL_BASE, ATTEN_NORM);
 426                 pointparticles(EFFECT_ROCKET_EXPLODE, this.origin, '0 0 0', 1);
 427                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_ONSLAUGHT_CPDESTROYED), this.owner.message, attacker.netname);
 428
 429                 PlayerScore_Add(attacker, SP_ONS_TAKES, 1);
 430                 PlayerScore_Add(attacker, SP_SCORE, 10);
 431
 432                 this.owner.goalentity = NULL;
 433                 this.owner.islinked = false;
 434                 this.owner.iscaptured = false;
 435                 this.owner.team = 0;
 436                 this.owner.colormap = 1024;
 437
 438                 WaypointSprite_UpdateMaxHealth(this.owner.sprite, 0);
 439
 440                 onslaught_updatelinks();
 441
 442                 // Use targets now (somebody make sure this is in the right place..)
 443                 SUB_UseTargets(this.owner, this, NULL);
 444
 445                 this.owner.waslinked = this.owner.islinked;
 446                 if(this.owner.model != "models/onslaught/controlpoint_pad.md3")
 447                         setmodel_fixsize(this.owner, MDL_ONS_CP_PAD1);
 448                 //setsize(this, '-32 -32 0', '32 32 8');
 449
 450                 delete(this);
 451         }
 452
 453         this.SendFlags |= CPSF_STATUS;
 454 }
 455
 456 void ons_ControlPoint_Icon_Think(entity this)
 457 {
 458         this.nextthink = time + ONS_CP_THINKRATE;
 459
 460         if(autocvar_g_onslaught_cp_proxydecap)
 461         {
 462                 int _enemy_count = 0;
 463                 int _friendly_count = 0;
 464
 465                 FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it), {
 466                         if(vdist(it.origin - this.origin, <, autocvar_g_onslaught_cp_proxydecap_distance))
 467                         {
 468                                 if(SAME_TEAM(it, this))
 469                                         ++_friendly_count;
 470                                 else
 471                                         ++_enemy_count;
 472                         }
 473                 });
 474
 475                 _friendly_count = _friendly_count * (autocvar_g_onslaught_cp_proxydecap_dps * ONS_CP_THINKRATE);
 476                 _enemy_count = _enemy_count * (autocvar_g_onslaught_cp_proxydecap_dps * ONS_CP_THINKRATE);
 477
 478                 this.health = bound(0, this.health + (_friendly_count - _enemy_count), this.max_health);
 479                 this.SendFlags |= CPSF_STATUS;
 480                 if(this.health <= 0)
 481                 {
 482                         ons_ControlPoint_Icon_Damage(this, this, this, 1, 0, this.origin, '0 0 0');
 483                         return;
 484                 }
 485         }
 486
 487         if (time > this.pain_finished + 5)
 488         {
 489                 if(this.health < this.max_health)
 490                 {
 491                         this.health = this.health + this.count;
 492                         if (this.health >= this.max_health)
 493                                 this.health = this.max_health;
 494                         WaypointSprite_UpdateHealth(this.owner.sprite, this.health);
 495                 }
 496         }
 497
 498         if(this.owner.islinked != this.owner.waslinked)
 499         {
 500                 // unteam the spawnpoint if needed
 501                 int t = this.owner.team;
 502                 if(!this.owner.islinked)
 503                         this.owner.team = 0;
 504
 505                 SUB_UseTargets(this.owner, this, NULL);
 506
 507                 this.owner.team = t;
 508
 509                 this.owner.waslinked = this.owner.islinked;
 510         }
 511
 512         // damaged fx
 513         if(random() < 0.6 - this.health / this.max_health)
 514         {
 515                 Send_Effect(EFFECT_ELECTRIC_SPARKS, this.origin + randompos('-10 -10 -20', '10 10 20'), '0 0 0', 1);
 516
 517                 if(random() > 0.8)
 518                         sound(this, CH_PAIN, SND_ONS_SPARK1, VOL_BASE, ATTEN_NORM);
 519                 else if (random() > 0.5)
 520                         sound(this, CH_PAIN, SND_ONS_SPARK2, VOL_BASE, ATTEN_NORM);
 521         }
 522 }
 523
 524 void ons_ControlPoint_Icon_BuildThink(entity this)
 525 {
 526         int a;
 527
 528         this.nextthink = time + ONS_CP_THINKRATE;
 529
 530         // only do this if there is power
 531         a = ons_ControlPoint_CanBeLinked(this.owner, this.owner.team);
 532         if(!a)
 533                 return;
 534
 535         this.health = this.health + this.count;
 536
 537         this.SendFlags |= CPSF_STATUS;
 538
 539         if (this.health >= this.max_health)
 540         {
 541                 this.health = this.max_health;
 542                 this.count = autocvar_g_onslaught_cp_regen * ONS_CP_THINKRATE; // slow repair rate from now on
 543                 setthink(this, ons_ControlPoint_Icon_Think);
 544                 sound(this, CH_TRIGGER, SND_ONS_CONTROLPOINT_BUILT, VOL_BASE, ATTEN_NORM);
 545                 this.owner.iscaptured = true;
 546                 this.solid = SOLID_BBOX;
 547
 548                 Send_Effect(EFFECT_CAP(this.owner.team), this.owner.origin, '0 0 0', 1);
 549
 550                 WaypointSprite_UpdateMaxHealth(this.owner.sprite, this.max_health);
 551                 WaypointSprite_UpdateHealth(this.owner.sprite, this.health);
 552
 553                 if(IS_PLAYER(this.owner.ons_toucher))
 554                 {
 555                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_ONSLAUGHT_CAPTURE, this.owner.ons_toucher.netname, this.owner.message);
 556                         Send_Notification(NOTIF_ALL_EXCEPT, this.owner.ons_toucher, MSG_CENTER, APP_TEAM_NUM(this.owner.ons_toucher.team, CENTER_ONS_CAPTURE), this.owner.message);
 557                         Send_Notification(NOTIF_ONE, this.owner.ons_toucher, MSG_CENTER, CENTER_ONS_CAPTURE, this.owner.message);
 558                         PlayerScore_Add(this.owner.ons_toucher, SP_ONS_CAPS, 1);
 559                         PlayerTeamScore_AddScore(this.owner.ons_toucher, 10);
 560                 }
 561
 562                 this.owner.ons_toucher = NULL;
 563
 564                 onslaught_updatelinks();
 565
 566                 // Use targets now (somebody make sure this is in the right place..)
 567                 SUB_UseTargets(this.owner, this, NULL);
 568
 569                 this.SendFlags |= CPSF_SETUP;
 570         }
 571         if(this.owner.model != MDL_ONS_CP_PAD2.model_str())
 572                 setmodel_fixsize(this.owner, MDL_ONS_CP_PAD2);
 573
 574         if(random() < 0.9 - this.health / this.max_health)
 575                 Send_Effect(EFFECT_RAGE, this.origin + 10 * randomvec(), '0 0 -1', 1);
 576 }
 577
 578 void onslaught_controlpoint_icon_link(entity e, void(entity this) spawnproc);
 579
 580 void ons_ControlPoint_Icon_Spawn(entity cp, entity player)
 581 {
 582         entity e = new(onslaught_controlpoint_icon);
 583
 584         setsize(e, CPICON_MIN, CPICON_MAX);
 585         setorigin(e, cp.origin + CPICON_OFFSET);
 586
 587         e.owner = cp;
 588         e.max_health = autocvar_g_onslaught_cp_health;
 589         e.health = autocvar_g_onslaught_cp_buildhealth;
 590         e.solid = SOLID_NOT;
 591         e.takedamage = DAMAGE_AIM;
 592         e.bot_attack = true;
 593         IL_PUSH(g_bot_targets, e);
 594         e.event_damage = ons_ControlPoint_Icon_Damage;
 595         e.team = player.team;
 596         e.colormap = 1024 + (e.team - 1) * 17;
 597         e.count = (e.max_health - e.health) * ONS_CP_THINKRATE / autocvar_g_onslaught_cp_buildtime; // how long it takes to build
 598
 599         sound(e, CH_TRIGGER, SND_ONS_CONTROLPOINT_BUILD, VOL_BASE, ATTEN_NORM);
 600
 601         cp.goalentity = e;
 602         cp.team = e.team;
 603         cp.colormap = e.colormap;
 604
 605         Send_Effect(EFFECT_FLAG_TOUCH(player.team), e.origin, '0 0 0', 1);
 606
 607         WaypointSprite_UpdateBuildFinished(cp.sprite, time + (e.max_health - e.health) / (e.count / ONS_CP_THINKRATE));
 608         WaypointSprite_UpdateRule(cp.sprite,cp.team,SPRITERULE_TEAMPLAY);
 609         cp.sprite.SendFlags |= 16;
 610
 611         onslaught_controlpoint_icon_link(e, ons_ControlPoint_Icon_BuildThink);
 612 }
 613
 614 entity ons_ControlPoint_Waypoint(entity e)
 615 {
 616         if(e.team)
 617         {
 618                 int a = ons_ControlPoint_Attackable(e, e.team);
 619
 620                 if(a == -2) { return WP_OnsCPDefend; } // defend now
 621                 if(a == -1 || a == 1 || a == 2) { return WP_OnsCP; } // touch
 622                 if(a == 3 || a == 4) { return WP_OnsCPAttack; } // attack
 623         }
 624         else
 625                 return WP_OnsCP;
 626
 627         return WP_Null;
 628 }
 629
 630 void ons_ControlPoint_UpdateSprite(entity e)
 631 {
 632         entity s1 = ons_ControlPoint_Waypoint(e);
 633         WaypointSprite_UpdateSprites(e.sprite, s1, s1, s1);
 634
 635         bool sh;
 636         sh = !(ons_ControlPoint_CanBeLinked(e, NUM_TEAM_1) || ons_ControlPoint_CanBeLinked(e, NUM_TEAM_2) || ons_ControlPoint_CanBeLinked(e, NUM_TEAM_3) || ons_ControlPoint_CanBeLinked(e, NUM_TEAM_4));
 637
 638         if(e.lastteam != e.team + 2 || e.lastshielded != sh || e.iscaptured != e.lastcaptured)
 639         {
 640                 if(e.iscaptured) // don't mess up build bars!
 641                 {
 642                         if(sh)
 643                         {
 644                                 WaypointSprite_UpdateMaxHealth(e.sprite, 0);
 645                         }
 646                         else
 647                         {
 648                                 WaypointSprite_UpdateMaxHealth(e.sprite, e.goalentity.max_health);
 649                                 WaypointSprite_UpdateHealth(e.sprite, e.goalentity.health);
 650                         }
 651                 }
 652                 if(e.lastshielded)
 653                 {
 654                         if(e.team)
 655                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_CONTROLPOINT, 0.5 * colormapPaletteColor(e.team - 1, false));
 656                         else
 657                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_CONTROLPOINT, '0.5 0.5 0.5');
 658                 }
 659                 else
 660                 {
 661                         if(e.team)
 662                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_CONTROLPOINT, colormapPaletteColor(e.team - 1, false));
 663                         else
 664                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_CONTROLPOINT, '0.75 0.75 0.75');
 665                 }
 666                 WaypointSprite_Ping(e.sprite);
 667
 668                 e.lastteam = e.team + 2;
 669                 e.lastshielded = sh;
 670                 e.lastcaptured = e.iscaptured;
 671         }
 672 }
 673
 674 void ons_ControlPoint_Touch(entity this, entity toucher)
 675 {
 676         int attackable;
 677
 678         if(IS_VEHICLE(toucher) && toucher.owner)
 679         if(autocvar_g_onslaught_allow_vehicle_touch)
 680                 toucher = toucher.owner;
 681         else
 682                 return;
 683
 684         if(!IS_PLAYER(toucher)) { return; }
 685         if(STAT(FROZEN, toucher)) { return; }
 686         if(IS_DEAD(toucher)) { return; }
 687
 688         if ( SAME_TEAM(this,toucher) )
 689         if ( this.iscaptured )
 690         {
 691                 if(time <= toucher.teleport_antispam)
 692                         Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_ONS_TELEPORT_ANTISPAM, rint(toucher.teleport_antispam - time));
 693                 else
 694                         Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_ONS_TELEPORT);
 695         }
 696
 697         attackable = ons_ControlPoint_Attackable(this, toucher.team);
 698         if(attackable != 2 && attackable != 4)
 699                 return;
 700         // we've verified that this player has a legitimate claim to this point,
 701         // so start building the captured point icon (which only captures this
 702         // point if it successfully builds without being destroyed first)
 703         ons_ControlPoint_Icon_Spawn(this, toucher);
 704
 705         this.ons_toucher = toucher;
 706
 707         onslaught_updatelinks();
 708 }
 709
 710 void ons_ControlPoint_Think(entity this)
 711 {
 712         this.nextthink = time + ONS_CP_THINKRATE;
 713         CSQCMODEL_AUTOUPDATE(this);
 714 }
 715
 716 void ons_ControlPoint_Reset(entity this)
 717 {
 718         if(this.goalentity)
 719                 delete(this.goalentity);
 720
 721         this.goalentity = NULL;
 722         this.team = 0;
 723         this.colormap = 1024;
 724         this.iscaptured = false;
 725         this.islinked = false;
 726         this.isshielded = true;
 727         setthink(this, ons_ControlPoint_Think);
 728         this.ons_toucher = NULL;
 729         this.nextthink = time + ONS_CP_THINKRATE;
 730         setmodel_fixsize(this, MDL_ONS_CP_PAD1);
 731
 732         WaypointSprite_UpdateMaxHealth(this.sprite, 0);
 733         WaypointSprite_UpdateRule(this.sprite,this.team,SPRITERULE_TEAMPLAY);
 734
 735         onslaught_updatelinks();
 736
 737         SUB_UseTargets(this, this, NULL); // to reset the structures, playerspawns etc.
 738
 739         CSQCMODEL_AUTOUPDATE(this);
 740 }
 741
 742 void ons_DelayedControlPoint_Setup(entity this)
 743 {
 744         onslaught_updatelinks();
 745
 746         // captureshield setup
 747         ons_CaptureShield_Spawn(this, false);
 748
 749         CSQCMODEL_AUTOINIT(this);
 750 }
 751
 752 void ons_ControlPoint_Setup(entity cp)
 753 {
 754         // main setup
 755         cp.ons_worldcpnext = ons_worldcplist; // link control point into ons_worldcplist
 756         ons_worldcplist = cp;
 757
 758         cp.netname = "Control point";
 759         cp.team = 0;
 760         cp.solid = SOLID_BBOX;
 761         set_movetype(cp, MOVETYPE_NONE);
 762         settouch(cp, ons_ControlPoint_Touch);
 763         setthink(cp, ons_ControlPoint_Think);
 764         cp.nextthink = time + ONS_CP_THINKRATE;
 765         cp.reset = ons_ControlPoint_Reset;
 766         cp.colormap = 1024;
 767         cp.iscaptured = false;
 768         cp.islinked = false;
 769         cp.isshielded = true;
 770
 771         if(cp.message == "") { cp.message = "a"; }
 772
 773         // appearence
 774         setmodel_fixsize(cp, MDL_ONS_CP_PAD1);
 775
 776         // control point placement
 777         if((cp.spawnflags & 1) || cp.noalign) // don't drop to floor, just stay at fixed location
 778         {
 779                 cp.noalign = true;
 780                 set_movetype(cp, MOVETYPE_NONE);
 781         }
 782         else // drop to floor, automatically find a platform and set that as spawn origin
 783         {
 784                 setorigin(cp, cp.origin + '0 0 20');
 785                 cp.noalign = false;
 786                 droptofloor(cp);
 787                 set_movetype(cp, MOVETYPE_TOSS);
 788         }
 789
 790         // waypointsprites
 791         WaypointSprite_SpawnFixed(WP_Null, cp.origin + CPGEN_WAYPOINT_OFFSET, cp, sprite, RADARICON_NONE);
 792         WaypointSprite_UpdateRule(cp.sprite, cp.team, SPRITERULE_TEAMPLAY);
 793
 794         InitializeEntity(cp, ons_DelayedControlPoint_Setup, INITPRIO_SETLOCATION);
 795 }
 796
 797
 798 // =========================
 799 // Main Generator Functions
 800 // =========================
 801
 802 entity ons_Generator_Waypoint(entity e)
 803 {
 804         if (e.isshielded)
 805                 return WP_OnsGenShielded;
 806         return WP_OnsGen;
 807 }
 808
 809 void ons_Generator_UpdateSprite(entity e)
 810 {
 811         entity s1 = ons_Generator_Waypoint(e);
 812         WaypointSprite_UpdateSprites(e.sprite, s1, s1, s1);
 813
 814         if(e.lastteam != e.team + 2 || e.lastshielded != e.isshielded)
 815         {
 816                 e.lastteam = e.team + 2;
 817                 e.lastshielded = e.isshielded;
 818                 if(e.lastshielded)
 819                 {
 820                         if(e.team)
 821                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_GENERATOR, 0.5 * colormapPaletteColor(e.team - 1, false));
 822                         else
 823                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_GENERATOR, '0.5 0.5 0.5');
 824                 }
 825                 else
 826                 {
 827                         if(e.team)
 828                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_GENERATOR, colormapPaletteColor(e.team - 1, false));
 829                         else
 830                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_GENERATOR, '0.75 0.75 0.75');
 831                 }
 832                 WaypointSprite_Ping(e.sprite);
 833         }
 834 }
 835
 836 void ons_camSetup(entity this)
 837 {
 838         if(cam) return;
 839
 840         cam = new(objective_camera);
 841         cam.origin = this.origin;
 842         setorigin(cam, cam.origin);
 843         cam.angles = this.angles;
 844         Net_LinkEntity(cam, false, 0, clientcamera_send);
 845
 846         FOREACH_CLIENT(true, it.clientcamera = cam;);
 847
 848         WriteByte(MSG_ALL, SVC_SETVIEWANGLES);
 849         WriteAngle(MSG_ALL, cam.angles_x);
 850         WriteAngle(MSG_ALL, cam.angles_y);
 851         WriteAngle(MSG_ALL, cam.angles_z);
 852 }
 853
 854 void ons_GeneratorDamage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 855 {
 856         if(damage <= 0) { return; }
 857         if(warmup_stage || gameover) { return; }
 858         if(!round_handler_IsRoundStarted()) { return; }
 859
 860         if (attacker != this)
 861         {
 862                 if (this.isshielded)
 863                 {
 864                         // generator is protected by a shield, so ignore the damage
 865                         if (time > this.pain_finished)
 866                                 if (IS_PLAYER(attacker))
 867                                 {
 868                                         play2(attacker, SND(ONS_DAMAGEBLOCKEDBYSHIELD));
 869                                         attacker.typehitsound += 1;
 870                                         this.pain_finished = time + 1;
 871                                 }
 872                         return;
 873                 }
 874                 if (time > this.pain_finished)
 875                 {
 876                         this.pain_finished = time + 10;
 877                         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && SAME_TEAM(it, this), Send_Notification(NOTIF_ONE, it, MSG_CENTER, CENTER_GENERATOR_UNDERATTACK));
 878                         play2team(this.team, SND(ONS_GENERATOR_UNDERATTACK));
 879                 }
 880         }
 881         this.health = this.health - damage;
 882         WaypointSprite_UpdateHealth(this.sprite, this.health);
 883         // choose an animation frame based on health
 884         this.frame = 10 * bound(0, (1 - this.health / this.max_health), 1);
 885         // see if the generator is still functional, or dying
 886         if (this.health > 0)
 887         {
 888                 this.lasthealth = this.health;
 889         }
 890         else
 891         {
 892                 if (attacker == this)
 893                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_ONSLAUGHT_GENDESTROYED_OVERTIME));
 894                 else
 895                 {
 896                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_ONSLAUGHT_GENDESTROYED));
 897                         PlayerScore_Add(attacker, SP_SCORE, 100);
 898                 }
 899                 this.iscaptured = false;
 900                 this.islinked = false;
 901                 this.isshielded = false;
 902                 this.takedamage = DAMAGE_NO; // can't be hurt anymore
 903                 this.event_damage = func_null; // won't do anything if hurt
 904                 this.count = 0; // reset counter
 905                 setthink(this, func_null);
 906                 this.nextthink = 0;
 907                 //this.think(); // do the first explosion now
 908
 909                 WaypointSprite_UpdateMaxHealth(this.sprite, 0);
 910                 WaypointSprite_Ping(this.sprite);
 911                 //WaypointSprite_Kill(this.sprite); // can't do this yet, code too poor
 912
 913                 onslaught_updatelinks();
 914
 915                 ons_camSetup(this);
 916         }
 917
 918         // Throw some flaming gibs on damage, more damage = more chance for gib
 919         if(random() < damage/220)
 920         {
 921                 sound(this, CH_TRIGGER, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 922         }
 923         else
 924         {
 925                 // particles on every hit
 926                 Send_Effect(EFFECT_SPARKS, hitloc, force * -1, 1);
 927
 928                 //sound on every hit
 929                 if (random() < 0.5)
 930                         sound(this, CH_TRIGGER, SND_ONS_HIT1, VOL_BASE, ATTEN_NORM);
 931                 else
 932                         sound(this, CH_TRIGGER, SND_ONS_HIT2, VOL_BASE, ATTEN_NORM);
 933         }
 934
 935         this.SendFlags |= GSF_STATUS;
 936 }
 937
 938 void ons_GeneratorThink(entity this)
 939 {
 940         this.nextthink = time + GEN_THINKRATE;
 941         if (!gameover)
 942         {
 943                 if(!this.isshielded && this.wait < time)
 944                 {
 945                         this.wait = time + 5;
 946                         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), {
 947                                 if(SAME_TEAM(it, this))
 948                                 {
 949                                         Send_Notification(NOTIF_ONE, it, MSG_CENTER, CENTER_ONS_NOTSHIELDED_TEAM);
 950                                         soundto(MSG_ONE, it, CHAN_AUTO, SND(KH_ALARM), VOL_BASE, ATTEN_NONE);    // FIXME: unique sound?
 951                                 }
 952                                 else
 953                                         Send_Notification(NOTIF_ONE, it, MSG_CENTER, APP_TEAM_NUM(this.team, CENTER_ONS_NOTSHIELDED));
 954                         });
 955                 }
 956         }
 957 }
 958
 959 void ons_GeneratorReset(entity this)
 960 {
 961         this.team = this.team_saved;
 962         this.lasthealth = this.max_health = this.health = autocvar_g_onslaught_gen_health;
 963         this.takedamage = DAMAGE_AIM;
 964         this.bot_attack = true;
 965         IL_PUSH(g_bot_targets, this);
 966         this.iscaptured = true;
 967         this.islinked = true;
 968         this.isshielded = true;
 969         this.event_damage = ons_GeneratorDamage;
 970         setthink(this, ons_GeneratorThink);
 971         this.nextthink = time + GEN_THINKRATE;
 972
 973         Net_LinkEntity(this, false, 0, generator_send);
 974
 975         this.SendFlags = GSF_SETUP; // just incase
 976         this.SendFlags |= GSF_STATUS;
 977
 978         WaypointSprite_UpdateMaxHealth(this.sprite, this.max_health);
 979         WaypointSprite_UpdateHealth(this.sprite, this.health);
 980         WaypointSprite_UpdateRule(this.sprite,this.team,SPRITERULE_TEAMPLAY);
 981
 982         onslaught_updatelinks();
 983 }
 984
 985 void ons_DelayedGeneratorSetup(entity this)
 986 {
 987         // bot waypoints
 988         waypoint_spawnforitem_force(this, this.origin);
 989         this.nearestwaypointtimeout = 0; // activate waypointing again
 990         this.bot_basewaypoint = this.nearestwaypoint;
 991
 992         // captureshield setup
 993         ons_CaptureShield_Spawn(this, true);
 994
 995         onslaught_updatelinks();
 996
 997         Net_LinkEntity(this, false, 0, generator_send);
 998 }
 999
1000
1001 void onslaught_generator_touch(entity this, entity toucher)
1002 {
1003         if ( IS_PLAYER(toucher) )
1004         if ( SAME_TEAM(this,toucher) )
1005         if ( this.iscaptured )
1006         {
1007                 Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_ONS_TELEPORT);
1008         }
1009 }
1010
1011 void ons_GeneratorSetup(entity gen) // called when spawning a generator entity on the map as a spawnfunc
1012 {
1013         // declarations
1014         int teamnumber = gen.team;
1015
1016         // main setup
1017         gen.ons_worldgeneratornext = ons_worldgeneratorlist; // link generator into ons_worldgeneratorlist
1018         ons_worldgeneratorlist = gen;
1019
1020         gen.netname = sprintf("%s generator", Team_ColoredFullName(teamnumber));
1021         gen.classname = "onslaught_generator";
1022         gen.solid = SOLID_BBOX;
1023         gen.team_saved = teamnumber;
1024         set_movetype(gen, MOVETYPE_NONE);
1025         gen.lasthealth = gen.max_health = gen.health = autocvar_g_onslaught_gen_health;
1026         gen.takedamage = DAMAGE_AIM;
1027         gen.bot_attack = true;
1028         IL_PUSH(g_bot_targets, gen);
1029         gen.event_damage = ons_GeneratorDamage;
1030         gen.reset = ons_GeneratorReset;
1031         setthink(gen, ons_GeneratorThink);
1032         gen.nextthink = time + GEN_THINKRATE;
1033         gen.iscaptured = true;
1034         gen.islinked = true;
1035         gen.isshielded = true;
1036         settouch(gen, onslaught_generator_touch);
1037
1038         // appearence
1039         // model handled by CSQC
1040         setsize(gen, GENERATOR_MIN, GENERATOR_MAX);
1041         setorigin(gen, (gen.origin + CPGEN_SPAWN_OFFSET));
1042         gen.colormap = 1024 + (teamnumber - 1) * 17;
1043
1044         // generator placement
1045         droptofloor(gen);
1046
1047         // waypointsprites
1048         WaypointSprite_SpawnFixed(WP_Null, gen.origin + CPGEN_WAYPOINT_OFFSET, gen, sprite, RADARICON_NONE);
1049         WaypointSprite_UpdateRule(gen.sprite, gen.team, SPRITERULE_TEAMPLAY);
1050         WaypointSprite_UpdateMaxHealth(gen.sprite, gen.max_health);
1051         WaypointSprite_UpdateHealth(gen.sprite, gen.health);
1052
1053         InitializeEntity(gen, ons_DelayedGeneratorSetup, INITPRIO_SETLOCATION);
1054 }
1055
1056
1057 // ===============
1058 //  Round Handler
1059 // ===============
1060
1061 int total_generators;
1062 void Onslaught_count_generators()
1063 {
1064         entity e;
1065         total_generators = redowned = blueowned = yellowowned = pinkowned = 0;
1066         for(e = ons_worldgeneratorlist; e; e = e.ons_worldgeneratornext)
1067         {
1068                 ++total_generators;
1069                 redowned += (e.team == NUM_TEAM_1 && e.health > 0);
1070                 blueowned += (e.team == NUM_TEAM_2 && e.health > 0);
1071                 yellowowned += (e.team == NUM_TEAM_3 && e.health > 0);
1072                 pinkowned += (e.team == NUM_TEAM_4 && e.health > 0);
1073         }
1074 }
1075
1076 int Onslaught_GetWinnerTeam()
1077 {
1078         int winner_team = 0;
1079         if(redowned > 0)
1080                 winner_team = NUM_TEAM_1;
1081         if(blueowned > 0)
1082         {
1083                 if(winner_team) return 0;
1084                 winner_team = NUM_TEAM_2;
1085         }
1086         if(yellowowned > 0)
1087         {
1088                 if(winner_team) return 0;
1089                 winner_team = NUM_TEAM_3;
1090         }
1091         if(pinkowned > 0)
1092         {
1093                 if(winner_team) return 0;
1094                 winner_team = NUM_TEAM_4;
1095         }
1096         if(winner_team)
1097                 return winner_team;
1098         return -1; // no generators left?
1099 }
1100
1101 void nades_Clear(entity e);
1102
1103 #define ONS_OWNED_GENERATORS() ((redowned > 0) + (blueowned > 0) + (yellowowned > 0) + (pinkowned > 0))
1104 #define ONS_OWNED_GENERATORS_OK() (ONS_OWNED_GENERATORS() > 1)
1105 bool Onslaught_CheckWinner()
1106 {
1107         if ((autocvar_timelimit && time > game_starttime + autocvar_timelimit * 60) || (round_handler_GetEndTime() > 0 && round_handler_GetEndTime() - time <= 0))
1108         {
1109                 ons_stalemate = true;
1110
1111                 if (!wpforenemy_announced)
1112                 {
1113                         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_CONTROLPOINT);
1114                         sound(NULL, CH_INFO, SND_ONS_GENERATOR_DECAY, VOL_BASE, ATTEN_NONE);
1115
1116                         wpforenemy_announced = true;
1117                 }
1118
1119                 entity tmp_entity; // temporary entity
1120                 float d;
1121                 for(tmp_entity = ons_worldgeneratorlist; tmp_entity; tmp_entity = tmp_entity.ons_worldgeneratornext) if(time >= tmp_entity.ons_overtime_damagedelay)
1122                 {
1123                         // tmp_entity.max_health / 300 gives 5 minutes of overtime.
1124                         // control points reduce the overtime duration.
1125                         d = 1;
1126                         entity e;
1127                         for(e = ons_worldcplist; e; e = e.ons_worldcpnext)
1128                         {
1129                                 if(DIFF_TEAM(e, tmp_entity))
1130                                 if(e.islinked)
1131                                         d = d + 1;
1132                         }
1133
1134                         if(autocvar_g_campaign && autocvar__campaign_testrun)
1135                                 d = d * tmp_entity.max_health;
1136                         else
1137                                 d = d * tmp_entity.max_health / max(30, 60 * autocvar_timelimit_suddendeath);
1138
1139                         Damage(tmp_entity, tmp_entity, tmp_entity, d, DEATH_HURTTRIGGER.m_id, tmp_entity.origin, '0 0 0');
1140
1141                         tmp_entity.sprite.SendFlags |= 16;
1142
1143                         tmp_entity.ons_overtime_damagedelay = time + 1;
1144                 }
1145         }
1146         else { wpforenemy_announced = false; ons_stalemate = false; }
1147
1148         Onslaught_count_generators();
1149
1150         if(ONS_OWNED_GENERATORS_OK())
1151                 return 0;
1152
1153         int winner_team = Onslaught_GetWinnerTeam();
1154
1155         if(winner_team > 0)
1156         {
1157                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, APP_TEAM_NUM(winner_team, CENTER_ROUND_TEAM_WIN));
1158                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(winner_team, INFO_ROUND_TEAM_WIN));
1159                 TeamScore_AddToTeam(winner_team, ST_ONS_CAPS, +1);
1160         }
1161         else if(winner_team == -1)
1162         {
1163                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_ROUND_TIED);
1164                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_ROUND_TIED);
1165         }
1166
1167         ons_stalemate = false;
1168
1169         play2all(SND(CTF_CAPTURE(winner_team)));
1170
1171         round_handler_Init(7, autocvar_g_onslaught_warmup, autocvar_g_onslaught_round_timelimit);
1172
1173         FOREACH_CLIENT(IS_PLAYER(it), {
1174                 STAT(ROUNDLOST, it) = true;
1175                 it.player_blocked = true;
1176
1177                 nades_Clear(it);
1178         });
1179
1180         return 1;
1181 }
1182
1183 bool Onslaught_CheckPlayers()
1184 {
1185         return 1;
1186 }
1187
1188 void Onslaught_RoundStart()
1189 {
1190         entity tmp_entity;
1191         FOREACH_CLIENT(IS_PLAYER(it), it.player_blocked = false);
1192
1193         for(tmp_entity = ons_worldcplist; tmp_entity; tmp_entity = tmp_entity.ons_worldcpnext)
1194                 tmp_entity.sprite.SendFlags |= 16;
1195
1196         for(tmp_entity = ons_worldgeneratorlist; tmp_entity; tmp_entity = tmp_entity.ons_worldgeneratornext)
1197                 tmp_entity.sprite.SendFlags |= 16;
1198 }
1199
1200
1201 // ================
1202 // Bot player logic
1203 // ================
1204
1205 // NOTE: LEGACY CODE, needs to be re-written!
1206
1207 void havocbot_goalrating_ons_offenseitems(entity this, float ratingscale, vector org, float sradius)
1208 {
1209         bool needarmor = false, needweapons = false;
1210
1211         // Needs armor/health?
1212         if(this.health<100)
1213                 needarmor = true;
1214
1215         // Needs weapons?
1216         int c = 0;
1217         FOREACH(Weapons, it != WEP_Null, {
1218                 if(this.weapons & (it.m_wepset))
1219                 if(++c >= 4)
1220                         break;
1221         });
1222
1223         if(c<4)
1224                 needweapons = true;
1225
1226         if(!needweapons && !needarmor)
1227                 return;
1228
1229         LOG_DEBUG(this.netname, " needs weapons ", ftos(needweapons));
1230         LOG_DEBUG(this.netname, " needs armor ", ftos(needarmor));
1231
1232         // See what is around
1233         IL_EACH(g_items, it.bot_pickup,
1234         {
1235                 // gather health and armor only
1236                 if (it.solid)
1237                 if ( ((it.health || it.armorvalue) && needarmor) || (it.weapons && needweapons ) )
1238                 if (vdist(it.origin - org, <, sradius))
1239                 {
1240                         int t = it.bot_pickupevalfunc(this, it);
1241                         if (t > 0)
1242                                 navigation_routerating(this, it, t * ratingscale, 500);
1243                 }
1244         });
1245 }
1246
1247 void havocbot_role_ons_setrole(entity this, int role)
1248 {
1249         LOG_DEBUG(this.netname," switched to ");
1250         switch(role)
1251         {
1252                 case HAVOCBOT_ONS_ROLE_DEFENSE:
1253                         LOG_DEBUG("defense");
1254                         this.havocbot_role = havocbot_role_ons_defense;
1255                         this.havocbot_role_flags = HAVOCBOT_ONS_ROLE_DEFENSE;
1256                         this.havocbot_role_timeout = 0;
1257                         break;
1258                 case HAVOCBOT_ONS_ROLE_ASSISTANT:
1259                         LOG_DEBUG("assistant");
1260                         this.havocbot_role = havocbot_role_ons_assistant;
1261                         this.havocbot_role_flags = HAVOCBOT_ONS_ROLE_ASSISTANT;
1262                         this.havocbot_role_timeout = 0;
1263                         break;
1264                 case HAVOCBOT_ONS_ROLE_OFFENSE:
1265                         LOG_DEBUG("offense");
1266                         this.havocbot_role = havocbot_role_ons_offense;
1267                         this.havocbot_role_flags = HAVOCBOT_ONS_ROLE_OFFENSE;
1268                         this.havocbot_role_timeout = 0;
1269                         break;
1270         }
1271         LOG_DEBUG("");
1272 }
1273
1274 void havocbot_goalrating_ons_controlpoints_attack(entity this, float ratingscale)
1275 {
1276         entity cp, cp1, cp2, best, wp;
1277         float radius, bestvalue;
1278         int c;
1279         bool found;
1280
1281         // Filter control points
1282         for(cp2 = ons_worldcplist; cp2; cp2 = cp2.ons_worldcpnext)
1283         {
1284                 cp2.wpcost = c = 0;
1285                 cp2.wpconsidered = false;
1286
1287                 if(cp2.isshielded)
1288                         continue;
1289
1290                 // Ignore owned controlpoints
1291                 if(!(cp2.isgenneighbor[this.team] || cp2.iscpneighbor[this.team]))
1292                         continue;
1293
1294                 // Count team mates interested in this control point
1295                 // (easier and cleaner than keeping counters per cp and teams)
1296                 FOREACH_CLIENT(IS_PLAYER(it), {
1297                         if(SAME_TEAM(it, this))
1298                         if(it.havocbot_role_flags & HAVOCBOT_ONS_ROLE_OFFENSE)
1299                         if(it.havocbot_ons_target == cp2)
1300                                 ++c;
1301                 });
1302
1303                 // NOTE: probably decrease the cost of attackable control points
1304                 cp2.wpcost = c;
1305                 cp2.wpconsidered = true;
1306         }
1307
1308         // We'll consider only the best case
1309         bestvalue = 99999999999;
1310         cp = NULL;
1311         for(cp1 = ons_worldcplist; cp1; cp1 = cp1.ons_worldcpnext)
1312         {
1313                 if (!cp1.wpconsidered)
1314                         continue;
1315
1316                 if(cp1.wpcost<bestvalue)
1317                 {
1318                         bestvalue = cp1.wpcost;
1319                         cp = cp1;
1320                         this.havocbot_ons_target = cp1;
1321                 }
1322         }
1323
1324         if (!cp)
1325                 return;
1326
1327         LOG_DEBUG(this.netname, " chose cp ranked ", ftos(bestvalue));
1328
1329         if(cp.goalentity)
1330         {
1331                 // Should be attacked
1332                 // Rate waypoints near it
1333                 found = false;
1334                 best = NULL;
1335                 bestvalue = 99999999999;
1336                 for(radius=0; radius<1000 && !found; radius+=500)
1337                 {
1338                         for(wp=findradius(cp.origin,radius); wp; wp=wp.chain)
1339                         {
1340                                 if(!(wp.wpflags & WAYPOINTFLAG_GENERATED))
1341                                 if(wp.classname=="waypoint")
1342                                 if(checkpvs(wp.origin,cp))
1343                                 {
1344                                         found = true;
1345                                         if(wp.cnt<bestvalue)
1346                                         {
1347                                                 best = wp;
1348                                                 bestvalue = wp.cnt;
1349                                         }
1350                                 }
1351                         }
1352                 }
1353
1354                 if(best)
1355                 {
1356                         navigation_routerating(this, best, ratingscale, 10000);
1357                         best.cnt += 1;
1358
1359                         this.havocbot_attack_time = 0;
1360                         if(checkpvs(this.view_ofs,cp))
1361                         if(checkpvs(this.view_ofs,best))
1362                                 this.havocbot_attack_time = time + 2;
1363                 }
1364                 else
1365                 {
1366                         navigation_routerating(this, cp, ratingscale, 10000);
1367                 }
1368                 LOG_DEBUG(this.netname, " found an attackable controlpoint at ", vtos(cp.origin));
1369         }
1370         else
1371         {
1372                 // Should be touched
1373                 LOG_DEBUG(this.netname, " found a touchable controlpoint at ", vtos(cp.origin));
1374                 found = false;
1375
1376                 // Look for auto generated waypoint
1377                 if (!bot_waypoints_for_items)
1378                 for (wp = findradius(cp.origin,100); wp; wp = wp.chain)
1379                 {
1380                         if(wp.classname=="waypoint")
1381                         {
1382                                 navigation_routerating(this, wp, ratingscale, 10000);
1383                                 found = true;
1384                         }
1385                 }
1386
1387                 // Nothing found, rate the controlpoint itself
1388                 if (!found)
1389                         navigation_routerating(this, cp, ratingscale, 10000);
1390         }
1391 }
1392
1393 bool havocbot_goalrating_ons_generator_attack(entity this, float ratingscale)
1394 {
1395         entity g, wp, bestwp;
1396         bool found;
1397         int best;
1398
1399         for(g = ons_worldgeneratorlist; g; g = g.ons_worldgeneratornext)
1400         {
1401                 if(SAME_TEAM(g, this) || g.isshielded)
1402                         continue;
1403
1404                 // Should be attacked
1405                 // Rate waypoints near it
1406                 found = false;
1407                 bestwp = NULL;
1408                 best = 99999999999;
1409
1410                 for(wp=findradius(g.origin,400); wp; wp=wp.chain)
1411                 {
1412                         if(wp.classname=="waypoint")
1413                         if(checkpvs(wp.origin,g))
1414                         {
1415                                 found = true;
1416                                 if(wp.cnt<best)
1417                                 {
1418                                         bestwp = wp;
1419                                         best = wp.cnt;
1420                                 }
1421                         }
1422                 }
1423
1424                 if(bestwp)
1425                 {
1426                         LOG_DEBUG("waypoints found around generator");
1427                         navigation_routerating(this, bestwp, ratingscale, 10000);
1428                         bestwp.cnt += 1;
1429
1430                         this.havocbot_attack_time = 0;
1431                         if(checkpvs(this.view_ofs,g))
1432                         if(checkpvs(this.view_ofs,bestwp))
1433                                 this.havocbot_attack_time = time + 5;
1434
1435                         return true;
1436                 }
1437                 else
1438                 {
1439                         LOG_DEBUG("generator found without waypoints around");
1440                         // if there aren't waypoints near the generator go straight to it
1441                         navigation_routerating(this, g, ratingscale, 10000);
1442                         this.havocbot_attack_time = 0;
1443                         return true;
1444                 }
1445         }
1446         return false;
1447 }
1448
1449 void havocbot_role_ons_offense(entity this)
1450 {
1451         if(IS_DEAD(this))
1452         {
1453                 this.havocbot_attack_time = 0;
1454                 havocbot_ons_reset_role(this);
1455                 return;
1456         }
1457
1458         // Set the role timeout if necessary
1459         if (!this.havocbot_role_timeout)
1460                 this.havocbot_role_timeout = time + 120;
1461
1462         if (time > this.havocbot_role_timeout)
1463         {
1464                 havocbot_ons_reset_role(this);
1465                 return;
1466         }
1467
1468         if(this.havocbot_attack_time>time)
1469                 return;
1470
1471         if (this.bot_strategytime < time)
1472         {
1473                 navigation_goalrating_start(this);
1474                 havocbot_goalrating_enemyplayers(this, 20000, this.origin, 650);
1475                 if(!havocbot_goalrating_ons_generator_attack(this, 20000))
1476                         havocbot_goalrating_ons_controlpoints_attack(this, 20000);
1477                 havocbot_goalrating_ons_offenseitems(this, 10000, this.origin, 10000);
1478                 navigation_goalrating_end(this);
1479
1480                 this.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
1481         }
1482 }
1483
1484 void havocbot_role_ons_assistant(entity this)
1485 {
1486         havocbot_ons_reset_role(this);
1487 }
1488
1489 void havocbot_role_ons_defense(entity this)
1490 {
1491         havocbot_ons_reset_role(this);
1492 }
1493
1494 void havocbot_ons_reset_role(entity this)
1495 {
1496         if(IS_DEAD(this))
1497                 return;
1498
1499         this.havocbot_ons_target = NULL;
1500
1501         // TODO: Defend control points or generator if necessary
1502
1503         havocbot_role_ons_setrole(this, HAVOCBOT_ONS_ROLE_OFFENSE);
1504 }
1505
1506
1507 /*
1508  * Find control point or generator owned by the same team self which is nearest to pos
1509  * if max_dist is positive, only control points within this range will be considered
1510  */
1511 entity ons_Nearest_ControlPoint(entity this, vector pos, float max_dist)
1512 {
1513         entity closest_target = NULL;
1514         for(entity cp = ons_worldcplist; cp; cp = cp.ons_worldcpnext)
1515         {
1516                 if(SAME_TEAM(cp, this))
1517                 if(cp.iscaptured)
1518                 if(max_dist <= 0 || vdist(cp.origin - pos, <=, max_dist))
1519                 if(vlen2(cp.origin - pos) <= vlen2(closest_target.origin - pos) || closest_target == NULL)
1520                         closest_target = cp;
1521         }
1522         for(entity gen = ons_worldgeneratorlist; gen; gen = gen.ons_worldgeneratornext)
1523         {
1524                 if(SAME_TEAM(gen, this))
1525                 if(max_dist <= 0 || vdist(gen.origin - pos, <, max_dist))
1526                 if(vlen2(gen.origin - pos) <= vlen2(closest_target.origin - pos) || closest_target == NULL)
1527                         closest_target = gen;
1528         }
1529
1530         return closest_target;
1531 }
1532
1533 /*
1534  * Find control point or generator owned by the same team self which is nearest to pos
1535  * if max_dist is positive, only control points within this range will be considered
1536  * This function only check distances on the XY plane, disregarding Z
1537  */
1538 entity ons_Nearest_ControlPoint_2D(entity this, vector pos, float max_dist)
1539 {
1540         entity closest_target = NULL;
1541         vector delta;
1542         float smallest_distance = 0, distance;
1543
1544         for(entity cp = ons_worldcplist; cp; cp = cp.ons_worldcpnext)
1545         {
1546                 delta = cp.origin - pos;
1547                 delta_z = 0;
1548                 distance = vlen(delta);
1549
1550                 if(SAME_TEAM(cp, this))
1551                 if(cp.iscaptured)
1552                 if(max_dist <= 0 || distance <= max_dist)
1553                 if(closest_target == NULL || distance <= smallest_distance )
1554                 {
1555                         closest_target = cp;
1556                         smallest_distance = distance;
1557                 }
1558         }
1559         for(entity gen = ons_worldgeneratorlist; gen; gen = gen.ons_worldgeneratornext)
1560         {
1561                 delta = gen.origin - pos;
1562                 delta_z = 0;
1563                 distance = vlen(delta);
1564
1565                 if(SAME_TEAM(gen, this))
1566                 if(max_dist <= 0 || distance <= max_dist)
1567                 if(closest_target == NULL || distance <= smallest_distance )
1568                 {
1569                         closest_target = gen;
1570                         smallest_distance = distance;
1571                 }
1572         }
1573
1574         return closest_target;
1575 }
1576 /**
1577  * find the number of control points and generators in the same team as this
1578  */
1579 int ons_Count_SelfControlPoints(entity this)
1580 {
1581         int n = 0;
1582         for(entity cp = ons_worldcplist; cp; cp = cp.ons_worldcpnext)
1583         {
1584                 if(SAME_TEAM(cp, this))
1585                 if(cp.iscaptured)
1586                         n++;
1587         }
1588         for(entity gen = ons_worldgeneratorlist; gen; gen = gen.ons_worldgeneratornext)
1589         {
1590                 if(SAME_TEAM(gen, this))
1591                         n++;
1592         }
1593         return n;
1594 }
1595
1596 /**
1597  * Teleport player to a random position near tele_target
1598  * if tele_effects is true, teleport sound+particles are created
1599  * return false on failure
1600  */
1601 bool ons_Teleport(entity player, entity tele_target, float range, bool tele_effects)
1602 {
1603         if ( !tele_target )
1604                 return false;
1605
1606         int i;
1607         vector loc;
1608         float theta;
1609         // narrow the range for each iteration to increase chances that a spawnpoint
1610         // can be found even if there's little room around the control point
1611         float iteration_scale = 1;
1612         for(i = 0; i < 16; ++i)
1613         {
1614                 iteration_scale -= i / 16;
1615                 theta = random() * 2 * M_PI;
1616                 loc_y = sin(theta);
1617                 loc_x = cos(theta);
1618                 loc_z = 0;
1619                 loc *= random() * range * iteration_scale;
1620
1621                 loc += tele_target.origin + '0 0 128' * iteration_scale;
1622
1623                 tracebox(loc, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), loc, MOVE_NORMAL, player);
1624                 if(trace_fraction == 1.0 && !trace_startsolid)
1625                 {
1626                         traceline(tele_target.origin, loc, MOVE_NOMONSTERS, tele_target); // double check to make sure we're not spawning outside the NULL
1627                         if(trace_fraction == 1.0 && !trace_startsolid)
1628                         {
1629                                 if ( tele_effects )
1630                                 {
1631                                         Send_Effect(EFFECT_TELEPORT, player.origin, '0 0 0', 1);
1632                                         sound (player, CH_TRIGGER, SND_TELEPORT, VOL_BASE, ATTEN_NORM);
1633                                 }
1634                                 setorigin(player, loc);
1635                                 player.angles = '0 1 0' * ( theta * RAD2DEG + 180 );
1636                                 makevectors(player.angles);
1637                                 player.fixangle = true;
1638                                 player.teleport_antispam = time + autocvar_g_onslaught_teleport_wait;
1639
1640                                 if ( tele_effects )
1641                                         Send_Effect(EFFECT_TELEPORT, player.origin + v_forward * 32, '0 0 0', 1);
1642                                 return true;
1643                         }
1644                 }
1645         }
1646
1647         return false;
1648 }
1649
1650 // ==============
1651 // Hook Functions
1652 // ==============
1653
1654 MUTATOR_HOOKFUNCTION(ons, reset_map_global)
1655 {
1656         FOREACH_CLIENT(IS_PLAYER(it), {
1657                 STAT(ROUNDLOST, it) = false;
1658                 it.ons_deathloc = '0 0 0';
1659                 PutClientInServer(it);
1660         });
1661         return false;
1662 }
1663
1664 MUTATOR_HOOKFUNCTION(ons, ClientDisconnect)
1665 {
1666         entity player = M_ARGV(0, entity);
1667
1668         player.ons_deathloc = '0 0 0';
1669 }
1670
1671 MUTATOR_HOOKFUNCTION(ons, MakePlayerObserver)
1672 {
1673         entity player = M_ARGV(0, entity);
1674
1675         player.ons_deathloc = '0 0 0';
1676 }
1677
1678 MUTATOR_HOOKFUNCTION(ons, PlayerSpawn)
1679 {
1680         entity player = M_ARGV(0, entity);
1681
1682         if(!round_handler_IsRoundStarted())
1683         {
1684                 player.player_blocked = true;
1685                 return false;
1686         }
1687
1688         entity l;
1689         for(l = ons_worldgeneratorlist; l; l = l.ons_worldgeneratornext)
1690         {
1691                 l.sprite.SendFlags |= 16;
1692         }
1693         for(l = ons_worldcplist; l; l = l.ons_worldcpnext)
1694         {
1695                 l.sprite.SendFlags |= 16;
1696         }
1697
1698         if(ons_stalemate) { Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_OVERTIME_CONTROLPOINT); }
1699
1700         if ( autocvar_g_onslaught_spawn_choose )
1701         if ( player.ons_spawn_by )
1702         if ( ons_Teleport(player,player.ons_spawn_by,autocvar_g_onslaught_teleport_radius,false) )
1703         {
1704                 player.ons_spawn_by = NULL;
1705                 return false;
1706         }
1707
1708         if(autocvar_g_onslaught_spawn_at_controlpoints)
1709         if(random() <= autocvar_g_onslaught_spawn_at_controlpoints_chance)
1710         {
1711                 float random_target = autocvar_g_onslaught_spawn_at_controlpoints_random;
1712                 entity tmp_entity, closest_target = NULL;
1713                 vector spawn_loc = player.ons_deathloc;
1714
1715                 // new joining player or round reset, don't bother checking
1716                 if(spawn_loc == '0 0 0') { return false; }
1717
1718                 if(random_target) { RandomSelection_Init(); }
1719
1720                 for(tmp_entity = ons_worldcplist; tmp_entity; tmp_entity = tmp_entity.ons_worldcpnext)
1721                 {
1722                         if(SAME_TEAM(tmp_entity, player))
1723                         if(random_target)
1724                                 RandomSelection_Add(tmp_entity, 0, string_null, 1, 1);
1725                         else if(vlen2(tmp_entity.origin - spawn_loc) <= vlen2(closest_target.origin - spawn_loc) || closest_target == NULL)
1726                                 closest_target = tmp_entity;
1727                 }
1728
1729                 if(random_target) { closest_target = RandomSelection_chosen_ent; }
1730
1731                 if(closest_target)
1732                 {
1733                         float i;
1734                         vector loc;
1735                         float iteration_scale = 1;
1736                         for(i = 0; i < 10; ++i)
1737                         {
1738                                 iteration_scale -= i / 10;
1739                                 loc = closest_target.origin + '0 0 96' * iteration_scale;
1740                                 loc += ('0 1 0' * random()) * 128 * iteration_scale;
1741                                 tracebox(loc, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), loc, MOVE_NORMAL, player);
1742                                 if(trace_fraction == 1.0 && !trace_startsolid)
1743                                 {
1744                                         traceline(closest_target.origin, loc, MOVE_NOMONSTERS, closest_target); // double check to make sure we're not spawning outside the NULL
1745                                         if(trace_fraction == 1.0 && !trace_startsolid)
1746                                         {
1747                                                 setorigin(player, loc);
1748                                                 player.angles = normalize(loc - closest_target.origin) * RAD2DEG;
1749                                                 return false;
1750                                         }
1751                                 }
1752                         }
1753                 }
1754         }
1755
1756         if(autocvar_g_onslaught_spawn_at_generator)
1757         if(random() <= autocvar_g_onslaught_spawn_at_generator_chance)
1758         {
1759                 float random_target = autocvar_g_onslaught_spawn_at_generator_random;
1760                 entity tmp_entity, closest_target = NULL;
1761                 vector spawn_loc = player.ons_deathloc;
1762
1763                 // new joining player or round reset, don't bother checking
1764                 if(spawn_loc == '0 0 0') { return false; }
1765
1766                 if(random_target) { RandomSelection_Init(); }
1767
1768                 for(tmp_entity = ons_worldgeneratorlist; tmp_entity; tmp_entity = tmp_entity.ons_worldgeneratornext)
1769                 {
1770                         if(random_target)
1771                                 RandomSelection_Add(tmp_entity, 0, string_null, 1, 1);
1772                         else
1773                         {
1774                                 if(SAME_TEAM(tmp_entity, player))
1775                                 if(vlen2(tmp_entity.origin - spawn_loc) <= vlen2(closest_target.origin - spawn_loc) || closest_target == NULL)
1776                                         closest_target = tmp_entity;
1777                         }
1778                 }
1779
1780                 if(random_target) { closest_target = RandomSelection_chosen_ent; }
1781
1782                 if(closest_target)
1783                 {
1784                         float i;
1785                         vector loc;
1786                         float iteration_scale = 1;
1787                         for(i = 0; i < 10; ++i)
1788                         {
1789                                 iteration_scale -= i / 10;
1790                                 loc = closest_target.origin + '0 0 128' * iteration_scale;
1791                                 loc += ('0 1 0' * random()) * 256 * iteration_scale;
1792                                 tracebox(loc, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), loc, MOVE_NORMAL, player);
1793                                 if(trace_fraction == 1.0 && !trace_startsolid)
1794                                 {
1795                                         traceline(closest_target.origin, loc, MOVE_NOMONSTERS, closest_target); // double check to make sure we're not spawning outside the NULL
1796                                         if(trace_fraction == 1.0 && !trace_startsolid)
1797                                         {
1798                                                 setorigin(player, loc);
1799                                                 player.angles = normalize(loc - closest_target.origin) * RAD2DEG;
1800                                                 return false;
1801                                         }
1802                                 }
1803                         }
1804                 }
1805         }
1806
1807         return false;
1808 }
1809
1810 MUTATOR_HOOKFUNCTION(ons, PlayerDies)
1811 {
1812         entity frag_target = M_ARGV(2, entity);
1813
1814         frag_target.ons_deathloc = frag_target.origin;
1815         entity l;
1816         for(l = ons_worldgeneratorlist; l; l = l.ons_worldgeneratornext)
1817         {
1818                 l.sprite.SendFlags |= 16;
1819         }
1820         for(l = ons_worldcplist; l; l = l.ons_worldcpnext)
1821         {
1822                 l.sprite.SendFlags |= 16;
1823         }
1824
1825         if ( autocvar_g_onslaught_spawn_choose )
1826         if ( ons_Count_SelfControlPoints(frag_target) > 1 )
1827                 stuffcmd(frag_target, "qc_cmd_cl hud clickradar\n");
1828
1829         return false;
1830 }
1831
1832 MUTATOR_HOOKFUNCTION(ons, MonsterMove)
1833 {
1834         entity mon = M_ARGV(0, entity);
1835
1836         entity e = find(NULL, targetname, mon.target);
1837         if (e != NULL)
1838                 mon.team = e.team;
1839 }
1840
1841 void ons_MonsterSpawn_Delayed(entity this)
1842 {
1843         entity own = this.owner;
1844
1845         if(!own) { delete(this); return; }
1846
1847         if(own.targetname)
1848         {
1849                 entity e = find(NULL, target, own.targetname);
1850                 if(e != NULL)
1851                 {
1852                         own.team = e.team;
1853
1854                         own.use(own, e, NULL);
1855                 }
1856         }
1857
1858         delete(this);
1859 }
1860
1861 MUTATOR_HOOKFUNCTION(ons, MonsterSpawn)
1862 {
1863         entity mon = M_ARGV(0, entity);
1864
1865         entity e = spawn();
1866         e.owner = mon;
1867         InitializeEntity(e, ons_MonsterSpawn_Delayed, INITPRIO_FINDTARGET);
1868 }
1869
1870 void ons_TurretSpawn_Delayed(entity this)
1871 {
1872         entity own = this.owner;
1873
1874         if(!own) { delete(this); return; }
1875
1876         if(own.targetname)
1877         {
1878                 entity e = find(NULL, target, own.targetname);
1879                 if(e != NULL)
1880                 {
1881                         own.team = e.team;
1882                         own.active = ACTIVE_NOT;
1883
1884                         own.use(own, e, NULL);
1885                 }
1886         }
1887
1888         delete(this);
1889 }
1890
1891 MUTATOR_HOOKFUNCTION(ons, TurretSpawn)
1892 {
1893         entity turret = M_ARGV(0, entity);
1894
1895         entity e = spawn();
1896         e.owner = turret;
1897         InitializeEntity(e, ons_TurretSpawn_Delayed, INITPRIO_FINDTARGET);
1898
1899         return false;
1900 }
1901
1902 MUTATOR_HOOKFUNCTION(ons, HavocBot_ChooseRole)
1903 {
1904         entity bot = M_ARGV(0, entity);
1905
1906         havocbot_ons_reset_role(bot);
1907         return true;
1908 }
1909
1910 MUTATOR_HOOKFUNCTION(ons, CheckAllowedTeams)
1911 {
1912         // onslaught is special
1913         for(entity tmp_entity = ons_worldgeneratorlist; tmp_entity; tmp_entity = tmp_entity.ons_worldgeneratornext)
1914         {
1915                 switch(tmp_entity.team)
1916                 {
1917                         case NUM_TEAM_1: c1 = 0; break;
1918                         case NUM_TEAM_2: c2 = 0; break;
1919                         case NUM_TEAM_3: c3 = 0; break;
1920                         case NUM_TEAM_4: c4 = 0; break;
1921                 }
1922         }
1923
1924         return true;
1925 }
1926
1927 MUTATOR_HOOKFUNCTION(ons, SpectateCopy)
1928 {
1929         entity spectatee = M_ARGV(0, entity);
1930         entity client = M_ARGV(1, entity);
1931
1932         STAT(ROUNDLOST, client) = STAT(ROUNDLOST, spectatee); // make spectators see it too
1933 }
1934
1935 MUTATOR_HOOKFUNCTION(ons, SV_ParseClientCommand)
1936 {
1937         if(MUTATOR_RETURNVALUE) // command was already handled?
1938                 return false;
1939
1940         entity player = M_ARGV(0, entity);
1941         string cmd_name = M_ARGV(1, string);
1942         int cmd_argc = M_ARGV(2, int);
1943
1944         if ( cmd_name == "ons_spawn" )
1945         {
1946                 vector pos = player.origin;
1947                 if(cmd_argc > 1)
1948                         pos_x = stof(argv(1));
1949                 if(cmd_argc > 2)
1950                         pos_y = stof(argv(2));
1951                 if(cmd_argc > 3)
1952                         pos_z = stof(argv(3));
1953
1954                 if ( IS_PLAYER(player) )
1955                 {
1956                         if ( !STAT(FROZEN, player) )
1957                         {
1958                                 entity source_point = ons_Nearest_ControlPoint(player, player.origin, autocvar_g_onslaught_teleport_radius);
1959
1960                                 if ( !source_point && player.health > 0 )
1961                                 {
1962                                         sprint(player, "\nYou need to be next to a control point\n");
1963                                         return true;
1964                                 }
1965
1966
1967                                 entity closest_target = ons_Nearest_ControlPoint_2D(player, pos, autocvar_g_onslaught_click_radius);
1968
1969                                 if ( closest_target == NULL )
1970                                 {
1971                                         sprint(player, "\nNo control point found\n");
1972                                         return true;
1973                                 }
1974
1975                                 if ( player.health <= 0 )
1976                                 {
1977                                         player.ons_spawn_by = closest_target;
1978                                         player.respawn_flags = player.respawn_flags | RESPAWN_FORCE;
1979                                 }
1980                                 else
1981                                 {
1982                                         if ( source_point == closest_target )
1983                                         {
1984                                                 sprint(player, "\nTeleporting to the same point\n");
1985                                                 return true;
1986                                         }
1987
1988                                         if ( !ons_Teleport(player,closest_target,autocvar_g_onslaught_teleport_radius,true) )
1989                                                 sprint(player, "\nUnable to teleport there\n");
1990                                 }
1991
1992                                 return true;
1993                         }
1994
1995                         sprint(player, "\nNo teleportation for you\n");
1996                 }
1997
1998                 return true;
1999         }
2000         return false;
2001 }
2002
2003 MUTATOR_HOOKFUNCTION(ons, PlayerUseKey)
2004 {
2005         if(MUTATOR_RETURNVALUE || gameover) { return false; }
2006
2007         entity player = M_ARGV(0, entity);
2008
2009         if((time > player.teleport_antispam) && (!IS_DEAD(player)) && !player.vehicle)
2010         {
2011                 entity source_point = ons_Nearest_ControlPoint(player, player.origin, autocvar_g_onslaught_teleport_radius);
2012                 if ( source_point )
2013                 {
2014                         stuffcmd(player, "qc_cmd_cl hud clickradar\n");
2015                         return true;
2016                 }
2017         }
2018 }
2019
2020 MUTATOR_HOOKFUNCTION(ons, PlayHitsound)
2021 {
2022         entity frag_victim = M_ARGV(0, entity);
2023
2024         return (frag_victim.classname == "onslaught_generator" && !frag_victim.isshielded)
2025                 || (frag_victim.classname == "onslaught_controlpoint_icon" && !frag_victim.owner.isshielded);
2026 }
2027
2028 MUTATOR_HOOKFUNCTION(ons, SendWaypoint)
2029 {
2030     entity wp = M_ARGV(0, entity);
2031     entity to = M_ARGV(1, entity);
2032     int sf = M_ARGV(2, int);
2033     int wp_flag = M_ARGV(3, int);
2034
2035         if(sf & 16)
2036         {
2037                 if(wp.owner.classname == "onslaught_controlpoint")
2038                 {
2039                         entity wp_owner = wp.owner;
2040                         entity e = WaypointSprite_getviewentity(to);
2041                         if(SAME_TEAM(e, wp_owner) && wp_owner.goalentity.health >= wp_owner.goalentity.max_health) { wp_flag |= 2; }
2042                         if(!ons_ControlPoint_Attackable(wp_owner, e.team)) { wp_flag |= 2; }
2043                 }
2044                 if(wp.owner.classname == "onslaught_generator")
2045                 {
2046                         entity wp_owner = wp.owner;
2047                         if(wp_owner.isshielded && wp_owner.health >= wp_owner.max_health) { wp_flag |= 2; }
2048                         if(wp_owner.health <= 0) { wp_flag |= 2; }
2049                 }
2050         }
2051
2052         M_ARGV(3, int) = wp_flag;
2053 }
2054
2055 MUTATOR_HOOKFUNCTION(ons, TurretValidateTarget)
2056 {
2057         entity turret_target = M_ARGV(1, entity);
2058
2059         if(substring(turret_target.classname, 0, 10) == "onslaught_") // don't attack onslaught targets, that's the player's job!
2060         {
2061                 M_ARGV(3, float) = -3;
2062                 return true;
2063         }
2064
2065         return false;
2066 }
2067
2068 MUTATOR_HOOKFUNCTION(ons, TurretThink)
2069 {
2070     entity turret = M_ARGV(0, entity);
2071
2072         // ONS uses somewhat backwards linking.
2073         if(turret.target)
2074         {
2075                 entity e = find(NULL, targetname, turret.target);
2076                 if (e != NULL)
2077                         turret.team = e.team;
2078         }
2079
2080         if(turret.team != turret.tur_head.team)
2081                 turret_respawn(turret);
2082 }
2083
2084
2085 // ==========
2086 // Spawnfuncs
2087 // ==========
2088
2089 /*QUAKED spawnfunc_onslaught_link (0 .5 .8) (-16 -16 -16) (16 16 16)
2090   Link between control points.
2091
2092   This entity targets two different spawnfunc_onslaught_controlpoint or spawnfunc_onslaught_generator entities, and suppresses shielding on both if they are owned by different teams.
2093
2094 keys:
2095 "target" - first control point.
2096 "target2" - second control point.
2097  */
2098 spawnfunc(onslaught_link)
2099 {
2100         if(!g_onslaught) { delete(this); return; }
2101
2102         if (this.target == "" || this.target2 == "")
2103                 objerror(this, "target and target2 must be set\n");
2104
2105         this.ons_worldlinknext = ons_worldlinklist; // link into ons_worldlinklist
2106         ons_worldlinklist = this;
2107
2108         InitializeEntity(this, ons_DelayedLinkSetup, INITPRIO_FINDTARGET);
2109         Net_LinkEntity(this, false, 0, ons_Link_Send);
2110 }
2111
2112 /*QUAKED spawnfunc_onslaught_controlpoint (0 .5 .8) (-32 -32 0) (32 32 128)
2113   Control point. Be sure to give this enough clearance so that the shootable part has room to exist
2114
2115   This should link to an spawnfunc_onslaught_controlpoint entity or spawnfunc_onslaught_generator entity.
2116
2117 keys:
2118 "targetname" - name that spawnfunc_onslaught_link entities will use to target this.
2119 "target" - target any entities that are tied to this control point, such as vehicles and buildable structure entities.
2120 "message" - name of this control point (should reflect the location in the map, such as "center bridge", "north tower", etc)
2121  */
2122
2123 spawnfunc(onslaught_controlpoint)
2124 {
2125         if(!g_onslaught) { delete(this); return; }
2126
2127         ons_ControlPoint_Setup(this);
2128 }
2129
2130 /*QUAKED spawnfunc_onslaught_generator (0 .5 .8) (-32 -32 -24) (32 32 64)
2131   Base generator.
2132
2133   spawnfunc_onslaught_link entities can target this.
2134
2135 keys:
2136 "team" - team that owns this generator (5 = red, 14 = blue, etc), MUST BE SET.
2137 "targetname" - name that spawnfunc_onslaught_link entities will use to target this.
2138  */
2139 spawnfunc(onslaught_generator)
2140 {
2141         if(!g_onslaught) { delete(this); return; }
2142         if(!this.team) { objerror(this, "team must be set"); }
2143
2144         ons_GeneratorSetup(this);
2145 }
2146
2147 // scoreboard setup
2148 void ons_ScoreRules()
2149 {
2150         CheckAllowedTeams(NULL);
2151         int teams = 0;
2152         if(c1 >= 0) teams |= BIT(0);
2153         if(c2 >= 0) teams |= BIT(1);
2154         if(c3 >= 0) teams |= BIT(2);
2155         if(c4 >= 0) teams |= BIT(3);
2156         ScoreRules_basics(teams, SFL_SORT_PRIO_PRIMARY, 0, true);
2157         ScoreInfo_SetLabel_TeamScore  (ST_ONS_CAPS,     "destroyed", SFL_SORT_PRIO_PRIMARY);
2158         ScoreInfo_SetLabel_PlayerScore(SP_ONS_CAPS,    "caps",      SFL_SORT_PRIO_SECONDARY);
2159         ScoreInfo_SetLabel_PlayerScore(SP_ONS_TAKES,    "takes",     0);
2160         ScoreRules_basics_end();
2161 }
2162
2163 void ons_DelayedInit(entity this) // Do this check with a delay so we can wait for teams to be set up
2164 {
2165         ons_ScoreRules();
2166
2167         round_handler_Spawn(Onslaught_CheckPlayers, Onslaught_CheckWinner, Onslaught_RoundStart);
2168         round_handler_Init(5, autocvar_g_onslaught_warmup, autocvar_g_onslaught_round_timelimit);
2169 }
2170
2171 void ons_Initialize()
2172 {
2173         g_onslaught = true;
2174         ons_captureshield_force = autocvar_g_onslaught_shield_force;
2175
2176         InitializeEntity(NULL, ons_DelayedInit, INITPRIO_GAMETYPE);
2177 }