qcsrc/common/items.qc

   1 // WEAPON PLUGIN SYSTEM
   2 entity weapon_info[24];
   3 entity dummy_weapon_info;
   4
   5 void register_weapon(float id, float(float) func, float ammotype, float i, float weapontype, float pickupbasevalue, string modelname, string shortname, string wname)
   6 {
   7         entity e;
   8         weapon_info[id - 1] = e = spawn();
   9         e.classname = "weapon_info";
  10         e.weapon = id;
  11         e.weapons = power2of(id - WEP_FIRST);
  12         e.netname = shortname;
  13         e.message = wname;
  14         e.items = ammotype;
  15         e.weapon_func = func;
  16         e.mdl = modelname;
  17         e.model = strzone(strcat("models/weapons/g_", modelname, ".md3"));
  18         e.spawnflags = weapontype;
  19         e.model2 = strzone(strcat("wpn-", e.mdl));
  20         e.impulse = i;
  21         e.bot_pickupbasevalue = pickupbasevalue;
  22 }
  23 float w_null(float dummy)
  24 {
  25         return 0;
  26 }
  27 void register_weapons_done()
  28 {
  29         entity wi;
  30
  31         dummy_weapon_info = spawn();
  32         dummy_weapon_info.classname = "weapon_info";
  33         dummy_weapon_info.weapon = 0; // you can recognize dummies by this
  34         dummy_weapon_info.weapons = 0; // you can recognize dummies by this too
  35         dummy_weapon_info.netname = "";
  36         dummy_weapon_info.message = "@!#%'n Tuba";
  37         dummy_weapon_info.items = 0;
  38         dummy_weapon_info.weapon_func = w_null;
  39         dummy_weapon_info.mdl = "";
  40         dummy_weapon_info.model = "";
  41         dummy_weapon_info.spawnflags = 0;
  42         dummy_weapon_info.model2 = "";
  43         dummy_weapon_info.impulse = -1;
  44         dummy_weapon_info.bot_pickupbasevalue = 0;
  45
  46         float i;
  47         weaponorder_byid = "";
  48         for(i = 24; i >= 1; --i)
  49                 if(weapon_info[i-1])
  50                         weaponorder_byid = strcat(weaponorder_byid, " ", ftos(i));
  51
  52         float imp;
  53         weaponorder_byimpulse = "";
  54         for(i = 1; i <= 24; ++i)
  55         {
  56                 wi = weapon_info[i-1];
  57                 if(wi && wi.impulse == 0)
  58                         weaponorder_byimpulse = strcat(weaponorder_byimpulse, " ", ftos(i));
  59         }
  60         for(imp = 9; imp > 0; --imp)
  61                 for(i = 1; i <= 24; ++i)
  62                 {
  63                         wi = weapon_info[i-1];
  64                         if(wi && wi.impulse == imp)
  65                                 weaponorder_byimpulse = strcat(weaponorder_byimpulse, " ", ftos(i));
  66                 }
  67
  68         weaponorder_byid = strzone(substring(weaponorder_byid, 1, strlen(weaponorder_byid) - 1));
  69         weaponorder_byimpulse = strzone(substring(weaponorder_byimpulse, 1, strlen(weaponorder_byimpulse) - 1));
  70 }
  71 entity get_weaponinfo(float id)
  72 {
  73         entity w;
  74         if(id < WEP_FIRST || id > WEP_LAST)
  75                 return dummy_weapon_info;
  76         w = weapon_info[id - 1];
  77         if(w)
  78                 return w;
  79         return dummy_weapon_info;
  80 }
  81 string W_FixWeaponOrder(string order, float complete)
  82 {
  83         return fixPriorityList(order, WEP_FIRST, WEP_LAST, 230 - WEP_FIRST, complete);
  84 }
  85 string W_NameWeaponOrder_MapFunc(string s)
  86 {
  87         entity wi;
  88         if(s == "0" || stof(s))
  89         {
  90                 wi = get_weaponinfo(stof(s));
  91                 if(wi != dummy_weapon_info)
  92                         return wi.netname;
  93         }
  94         return s;
  95 }
  96 string W_NameWeaponOrder(string order)
  97 {
  98         return mapPriorityList(order, W_NameWeaponOrder_MapFunc);
  99 }
 100 string W_NumberWeaponOrder_MapFunc(string s)
 101 {
 102         float i;
 103         if(s == "0" || stof(s))
 104                 return s;
 105         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 106                 if(s == get_weaponinfo(i).netname)
 107                         return ftos(i);
 108         return s;
 109 }
 110 string W_NumberWeaponOrder(string order)
 111 {
 112         return mapPriorityList(order, W_NumberWeaponOrder_MapFunc);
 113 }