qcsrc/common/mapinfo.qc

   1 #include "mapinfo.qh"
   2 #if defined(CSQC)
   3     #include "../client/defs.qh"
   4     #include "util.qh"
   5     #include <common/weapons/_all.qh>
   6 #elif defined(MENUQC)
   7 #elif defined(SVQC)
   8     #include "util.qh"
   9     #include <common/monsters/_mod.qh>
  10 #endif
  11
  12 bool autocvar_g_mapinfo_ignore_warnings;
  13
  14 // generic string stuff
  15
  16 int _MapInfo_Cache_Active;
  17 int _MapInfo_Cache_DB_NameToIndex;
  18 int _MapInfo_Cache_Buf_IndexToMapData;
  19
  20 void MapInfo_Cache_Destroy()
  21 {
  22         if(!_MapInfo_Cache_Active)
  23                 return;
  24
  25         db_close(_MapInfo_Cache_DB_NameToIndex);
  26         buf_del(_MapInfo_Cache_Buf_IndexToMapData);
  27         _MapInfo_Cache_Active = 0;
  28 }
  29
  30 void MapInfo_Cache_Create()
  31 {
  32         MapInfo_Cache_Destroy();
  33         _MapInfo_Cache_DB_NameToIndex = db_create();
  34         _MapInfo_Cache_Buf_IndexToMapData = buf_create();
  35         _MapInfo_Cache_Active = 1;
  36 }
  37
  38 void MapInfo_Cache_Invalidate()
  39 {
  40         if(!_MapInfo_Cache_Active)
  41                 return;
  42
  43         MapInfo_Cache_Create();
  44 }
  45
  46 void MapInfo_Cache_Store()
  47 {
  48         float i;
  49         string s;
  50         if(!_MapInfo_Cache_Active)
  51                 return;
  52
  53         s = db_get(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname);
  54         if(s == "")
  55         {
  56                 i = buf_getsize(_MapInfo_Cache_Buf_IndexToMapData);
  57                 db_put(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname, ftos(i));
  58         }
  59         else
  60                 i = stof(s);
  61
  62         // now store all the stuff
  63         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData,   i, MapInfo_Map_bspname);
  64         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_title);
  65         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_titlestring);
  66         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_description);
  67         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_author);
  68         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedGametypes));
  69         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedFeatures));
  70         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_flags));
  71 }
  72
  73 float MapInfo_Cache_Retrieve(string map)
  74 {
  75         float i;
  76         string s;
  77         if(!_MapInfo_Cache_Active)
  78                 return 0;
  79
  80         s = db_get(_MapInfo_Cache_DB_NameToIndex, map);
  81         if(s == "")
  82                 return 0;
  83         i = stof(s);
  84
  85         // now retrieve all the stuff
  86         MapInfo_Map_bspname = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, i);
  87         MapInfo_Map_title = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  88         MapInfo_Map_titlestring = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  89         MapInfo_Map_description = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  90         MapInfo_Map_author = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  91         MapInfo_Map_supportedGametypes = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  92         MapInfo_Map_supportedFeatures = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  93         MapInfo_Map_flags = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  94
  95         return 1;
  96 }
  97
  98 // GLOB HANDLING (for all BSP files)
  99 float _MapInfo_globopen;
 100 float _MapInfo_globcount;
 101 float _MapInfo_globhandle;
 102 string _MapInfo_GlobItem(float i)
 103 {
 104         string s;
 105         if(!_MapInfo_globopen)
 106                 return string_null;
 107         s = search_getfilename(_MapInfo_globhandle, i);
 108         return substring(s, 5, strlen(s) - 9); // without maps/ and .bsp
 109 }
 110
 111 void MapInfo_Enumerate()
 112 {
 113         if(_MapInfo_globopen)
 114         {
 115                 search_end(_MapInfo_globhandle);
 116                 _MapInfo_globopen = 0;
 117         }
 118         MapInfo_Cache_Invalidate();
 119         _MapInfo_globhandle = search_begin("maps/*.bsp", true, true);
 120         if(_MapInfo_globhandle >= 0)
 121         {
 122                 _MapInfo_globcount = search_getsize(_MapInfo_globhandle);
 123                 _MapInfo_globopen = 1;
 124         }
 125         else
 126                 _MapInfo_globcount = 0;
 127 }
 128
 129 // filter the info by game type mask (updates MapInfo_count)
 130 //
 131 float _MapInfo_filtered;
 132 float _MapInfo_filtered_allocated;
 133 float MapInfo_FilterList_Lookup(float i)
 134 {
 135         return stof(bufstr_get(_MapInfo_filtered, i));
 136 }
 137
 138 void _MapInfo_FilterList_swap(float i, float j, entity pass)
 139 {
 140         string h;
 141         h = bufstr_get(_MapInfo_filtered, i);
 142         bufstr_set(_MapInfo_filtered, i, bufstr_get(_MapInfo_filtered, j));
 143         bufstr_set(_MapInfo_filtered, j, h);
 144 }
 145
 146 float _MapInfo_FilterList_cmp(float i, float j, entity pass)
 147 {
 148         string a, b;
 149         a = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, i)));
 150         b = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, j)));
 151         return strcasecmp(a, b);
 152 }
 153
 154 float MapInfo_FilterGametype(Gametype pGametype, int pFeatures, int pFlagsRequired, int pFlagsForbidden, bool pAbortOnGenerate)
 155 {
 156         return _MapInfo_FilterGametype(pGametype.m_flags, pFeatures, pFlagsRequired, pFlagsForbidden, pAbortOnGenerate);
 157 }
 158 float _MapInfo_FilterGametype(int pGametype, int pFeatures, int pFlagsRequired, int pFlagsForbidden, bool pAbortOnGenerate)
 159 {
 160         float i, j;
 161         if (!_MapInfo_filtered_allocated)
 162         {
 163                 _MapInfo_filtered_allocated = 1;
 164                 _MapInfo_filtered = buf_create();
 165         }
 166         MapInfo_count = 0;
 167         for(i = 0, j = -1; i < _MapInfo_globcount; ++i)
 168         {
 169                 if(MapInfo_Get_ByName(_MapInfo_GlobItem(i), 1, NULL) == 2) // if we generated one... BAIL OUT and let the caller continue in the next frame.
 170                         if(pAbortOnGenerate)
 171                         {
 172                                 LOG_TRACE("Autogenerated a .mapinfo, doing the rest later.");
 173                                 MapInfo_progress = i / _MapInfo_globcount;
 174                                 return 0;
 175                         }
 176                 if((MapInfo_Map_supportedGametypes & pGametype) != 0)
 177                 if((MapInfo_Map_supportedFeatures & pFeatures) == pFeatures)
 178                 if((MapInfo_Map_flags & pFlagsForbidden) == 0)
 179                 if((MapInfo_Map_flags & pFlagsRequired) == pFlagsRequired)
 180                         bufstr_set(_MapInfo_filtered, ++j, ftos(i));
 181         }
 182         MapInfo_count = j + 1;
 183         MapInfo_ClearTemps();
 184
 185         // sometimes the glob isn't sorted nicely, so fix it here...
 186         heapsort(MapInfo_count, _MapInfo_FilterList_swap, _MapInfo_FilterList_cmp, NULL);
 187
 188         return 1;
 189 }
 190 void MapInfo_FilterString(string sf)
 191 {
 192         // this function further filters _MapInfo_filtered, which is prepared by MapInfo_FilterGametype by string
 193         float i, j;
 194         string title;
 195
 196         for(i = 0, j = -1; i < MapInfo_count; ++i)
 197         {
 198                 if (MapInfo_Get_ByID(i))
 199                 {
 200                         // prepare for keyword filter
 201                         if (MapInfo_Map_title && strstrofs(MapInfo_Map_title, "<TITLE>", 0) == -1)
 202                                 title = MapInfo_Map_title;
 203                         else
 204                                 title = MapInfo_Map_bspname;
 205                         // keyword filter
 206                         if((strstrofs(strtolower(title), strtolower(sf), 0)) >= 0)
 207                                 bufstr_set(_MapInfo_filtered, ++j, bufstr_get(_MapInfo_filtered, i));
 208                 }
 209         }
 210         MapInfo_count = j + 1;
 211         MapInfo_ClearTemps();
 212
 213         // sometimes the glob isn't sorted nicely, so fix it here...
 214         heapsort(MapInfo_count, _MapInfo_FilterList_swap, _MapInfo_FilterList_cmp, NULL);
 215 }
 216
 217 void MapInfo_Filter_Free()
 218 {
 219         if(_MapInfo_filtered_allocated)
 220         {
 221                 buf_del(_MapInfo_filtered);
 222                 _MapInfo_filtered_allocated = 0;
 223         }
 224 }
 225
 226 // load info about the i-th map into the MapInfo_Map_* globals
 227 string MapInfo_BSPName_ByID(float i)
 228 {
 229         return _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i));
 230 }
 231
 232 string unquote(string s)
 233 {
 234         float l = strlen(s);
 235         for(float i = 0; i < l; ++i)
 236         {
 237                 string ch = substring(s, i, 1);
 238                 if((ch != " ") && (ch != "\""))
 239                 {
 240                         for(float j = l - i - 1; j > 0; --j)
 241                         {
 242                                 ch = substring(s, i+j, 1);
 243                                 if(ch != " ") if(ch != "\"")
 244                                         return substring(s, i, j+1);
 245                         }
 246                         return substring(s, i, 1);
 247                 }
 248         }
 249         return "";
 250 }
 251
 252 float MapInfo_Get_ByID(float i)
 253 {
 254         if(MapInfo_Get_ByName(MapInfo_BSPName_ByID(i), 0, NULL))
 255                 return 1;
 256         return 0;
 257 }
 258
 259 string _MapInfo_Map_worldspawn_music;
 260
 261 float _MapInfo_Generate(string pFilename) // 0: failure, 1: ok ent, 2: ok bsp
 262 {
 263         string fn;
 264         float fh;
 265         string s, k, v;
 266         vector o;
 267         float i;
 268         float inWorldspawn;
 269         float r;
 270         float diameter, spawnpoints;
 271         float spawnplaces;
 272
 273         vector mapMins, mapMaxs;
 274
 275         r = 1;
 276         fn = strcat("maps/", pFilename, ".ent");
 277         fh = fopen(fn, FILE_READ);
 278         if(fh < 0)
 279         {
 280                 r = 2;
 281                 fn = strcat("maps/", pFilename, ".bsp");
 282                 fh = fopen(fn, FILE_READ);
 283         }
 284         if(fh < 0)
 285                 return 0;
 286         LOG_INFO("Analyzing ", fn, " to generate initial mapinfo");
 287
 288         inWorldspawn = 2;
 289         MapInfo_Map_flags = 0;
 290         MapInfo_Map_supportedGametypes = 0;
 291         spawnpoints = 0;
 292         spawnplaces = 0;
 293         _MapInfo_Map_worldspawn_music = "";
 294         mapMins = '0 0 0';
 295         mapMaxs = '0 0 0';
 296
 297         for (;;)
 298         {
 299                 if (!((s = fgets(fh))))
 300                         break;
 301                 if(inWorldspawn == 1)
 302                         if(startsWith(s, "}"))
 303                                 inWorldspawn = 0;
 304                 k = unquote(car(s));
 305                 v = unquote(cdr(s));
 306                 if(inWorldspawn)
 307                 {
 308                         if(k == "classname" && v == "worldspawn")
 309                                 inWorldspawn = 1;
 310                         else if(k == "author")
 311                                 MapInfo_Map_author = v;
 312                         else if(k == "_description")
 313                                 MapInfo_Map_description = v;
 314                         else if(k == "music")
 315                                 _MapInfo_Map_worldspawn_music = v;
 316                         else if(k == "noise")
 317                                 _MapInfo_Map_worldspawn_music = v;
 318                         else if(k == "message")
 319                         {
 320                                 i = strstrofs(v, " by ", 0);
 321                                 if(MapInfo_Map_author == "<AUTHOR>" && i >= 0)
 322                                 {
 323                                         MapInfo_Map_title = substring(v, 0, i);
 324                                         MapInfo_Map_author = substring(v, i + 4, strlen(v) - (i + 4));
 325                                 }
 326                                 else
 327                                         MapInfo_Map_title = v;
 328                         }
 329                 }
 330                 else
 331                 {
 332                         if(k == "origin")
 333                         {
 334                                 o = stov(strcat("'", v, "'"));
 335                                 mapMins.x = min(mapMins.x, o.x);
 336                                 mapMins.y = min(mapMins.y, o.y);
 337                                 mapMins.z = min(mapMins.z, o.z);
 338                                 mapMaxs.x = max(mapMaxs.x, o.x);
 339                                 mapMaxs.y = max(mapMaxs.y, o.y);
 340                                 mapMaxs.z = max(mapMaxs.z, o.z);
 341                         }
 342                         else if(k == "race_place")
 343                         {
 344                                 if(stof(v) > 0)
 345                                         spawnplaces = 1;
 346                         }
 347                         else if(k == "classname")
 348                         {
 349                                 if(v == "info_player_team1")
 350                                         ++spawnpoints;
 351                                 else if(v == "info_player_team2")
 352                                         ++spawnpoints;
 353                                 else if(v == "info_player_start")
 354                                         ++spawnpoints;
 355                                 else if(v == "info_player_deathmatch")
 356                                         ++spawnpoints;
 357                                 else if(v == "weapon_nex")
 358                                         { }
 359                                 else if(v == "weapon_railgun")
 360                                         { }
 361                                 else if(startsWith(v, "weapon_"))
 362                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 363                                 else if(startsWith(v, "turret_"))
 364                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_TURRETS;
 365                                 else if(startsWith(v, "vehicle_"))
 366                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_VEHICLES;
 367                                 else if(startsWith(v, "monster_"))
 368                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_MONSTERS;
 369                                 else if(v == "target_music" || v == "trigger_music")
 370                                         _MapInfo_Map_worldspawn_music = string_null; // don't use regular BGM
 371                                 else
 372                                         FOREACH(Gametypes, true, it.m_generate_mapinfo(it, v));
 373                         }
 374                 }
 375         }
 376         if(inWorldspawn)
 377         {
 378                 LOG_WARN(fn, " ended still in worldspawn, BUG");
 379                 return 0;
 380         }
 381         diameter = vlen(mapMaxs - mapMins);
 382
 383         int twoBaseModes = 0;
 384         FOREACH(Gametypes, it.m_isTwoBaseMode(), twoBaseModes |= it.m_flags);
 385         if(twoBaseModes && (twoBaseModes &= MapInfo_Map_supportedGametypes))
 386         {
 387                 // we have a symmetrical map, don't add the modes without bases
 388         }
 389         else
 390         {
 391                 FOREACH(Gametypes, it.m_isAlwaysSupported(it, spawnpoints, diameter), MapInfo_Map_supportedGametypes |= it.m_flags);
 392         }
 393
 394         if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_RACE.m_flags)
 395         if(!spawnplaces)
 396         {
 397                 MapInfo_Map_supportedGametypes &= ~MAPINFO_TYPE_RACE.m_flags;
 398                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTS.m_flags;
 399         }
 400
 401         LOG_TRACE("-> diameter ",    ftos(diameter));
 402         LOG_TRACE(";  spawnpoints ", ftos(spawnpoints));
 403         LOG_TRACE(";  modes ",       ftos(MapInfo_Map_supportedGametypes));
 404
 405         fclose(fh);
 406
 407         return r;
 408 }
 409
 410 void _MapInfo_Map_Reset()
 411 {
 412         MapInfo_Map_title = "<TITLE>";
 413         MapInfo_Map_titlestring = "<TITLE>";
 414         MapInfo_Map_description = "<DESCRIPTION>";
 415         MapInfo_Map_author = "<AUTHOR>";
 416         MapInfo_Map_supportedGametypes = 0;
 417         MapInfo_Map_supportedFeatures = 0;
 418         MapInfo_Map_flags = 0;
 419         MapInfo_Map_clientstuff = "";
 420         MapInfo_Map_fog = "";
 421         MapInfo_Map_mins = '0 0 0';
 422         MapInfo_Map_maxs = '0 0 0';
 423 }
 424
 425 string _MapInfo_GetDefault(Gametype t)
 426 {
 427         switch(t)
 428         {
 429                 case MAPINFO_TYPE_DEATHMATCH:      return "30 20 0";
 430                 case MAPINFO_TYPE_TEAM_DEATHMATCH: return "50 20 2 0";
 431                 case MAPINFO_TYPE_DOMINATION:      return "200 20 0";
 432                 case MAPINFO_TYPE_CTF:             return "300 20 10 0";
 433                 case MAPINFO_TYPE_LMS:             return "9 20 0";
 434                 case MAPINFO_TYPE_CA:              return "10 20 0";
 435                 case MAPINFO_TYPE_KEYHUNT:         return "1000 20 3 0";
 436                 case MAPINFO_TYPE_ASSAULT:         return "20 0";
 437                 case MAPINFO_TYPE_RACE:            return "20 5 7 15 0";
 438                 case MAPINFO_TYPE_ONSLAUGHT:       return "20 0";
 439                 case MAPINFO_TYPE_NEXBALL:         return "5 20 0";
 440                 case MAPINFO_TYPE_CTS:             return "20 0 0";
 441                 case MAPINFO_TYPE_FREEZETAG:       return "10 20 0";
 442                 // NOTE: DO NOT ADD ANY MORE GAME TYPES HERE
 443                 // THIS IS JUST LEGACY SUPPORT FOR NEXUIZ MAPS
 444                 // ONLY ADD NEW STUFF TO _MapInfo_GetDefaultEx
 445                 // THIS FUNCTION WILL EVENTUALLY BE REMOVED
 446                 default:                           return "";
 447         }
 448 }
 449
 450 void _MapInfo_Map_ApplyGametype(string s, Gametype pWantedType, Gametype pThisType, int load_default)
 451 {
 452         string sa;
 453         MapInfo_Map_supportedGametypes |= pThisType.m_flags;
 454         if(!(pThisType.m_flags & pWantedType.m_flags))
 455                 return;
 456
 457         if(load_default)
 458                 _MapInfo_Map_ApplyGametype(_MapInfo_GetDefault(pThisType), pWantedType, pThisType, false);
 459
 460         if(!pWantedType.frags) // these modes don't use fraglimit
 461         {
 462                 cvar_set("fraglimit", "0");
 463         }
 464         else
 465         {
 466                 sa = car(s);
 467                 if(sa != "")
 468                         cvar_set("fraglimit", sa);
 469                 s = cdr(s);
 470         }
 471
 472         sa = car(s);
 473         if(sa != "")
 474                 cvar_set("timelimit", sa);
 475         s = cdr(s);
 476
 477         if(pWantedType.m_setTeams)
 478         {
 479                 sa = car(s);
 480                 if(sa != "")
 481                         pWantedType.m_setTeams(sa);
 482                 s = cdr(s);
 483         }
 484
 485         // rc = timelimit timelimit_qualification laps laps_teamplay
 486         if(pWantedType == MAPINFO_TYPE_RACE)
 487         {
 488                 cvar_set("fraglimit", "0"); // special case!
 489
 490                 sa = car(s); if(sa == "") sa = cvar_string("timelimit");
 491                 cvar_set("g_race_qualifying_timelimit", sa);
 492                 s = cdr(s);
 493
 494                 sa = car(s);
 495                 if(sa != "")
 496                         if(cvar("g_race_teams") < 2)
 497                                 cvar_set("fraglimit", sa);
 498                 s = cdr(s);
 499
 500                 sa = car(s);
 501                 if(sa != "")
 502                         if(cvar("g_race_teams") >= 2)
 503                                 cvar_set("fraglimit", sa);
 504                 s = cdr(s);
 505         }
 506
 507         if(!pWantedType.frags) // these modes don't use fraglimit
 508         {
 509                 cvar_set("leadlimit", "0");
 510         }
 511         else
 512         {
 513                 sa = car(s);
 514                 if(sa != "")
 515                         cvar_set("leadlimit", sa);
 516                 s = cdr(s);
 517         }
 518 }
 519
 520 string _MapInfo_GetDefaultEx(Gametype t)
 521 {
 522         return t ? t.model2 : "";
 523 }
 524
 525 float _MapInfo_GetTeamPlayBool(Gametype t)
 526 {
 527         return t ? t.team : false;
 528 }
 529
 530 void _MapInfo_Map_ApplyGametypeEx(string s, Gametype pWantedType, Gametype pThisType)
 531 {
 532         MapInfo_Map_supportedGametypes |= pThisType.m_flags;
 533         if (!(pThisType.m_flags & pWantedType.m_flags))
 534                 return;
 535
 536         // reset all the cvars to their defaults
 537
 538         cvar_set("timelimit", cvar_defstring("timelimit"));
 539         cvar_set("leadlimit", cvar_defstring("leadlimit"));
 540         cvar_set("fraglimit", cvar_defstring("fraglimit"));
 541         FOREACH(Gametypes, true, it.m_parse_mapinfo(string_null, string_null));
 542
 543         string fraglimit_normal = string_null;
 544         string fraglimit_teams = string_null;
 545
 546         for (s = strcat(_MapInfo_GetDefaultEx(pWantedType), " ", s); s != ""; s = cdr(s)) {
 547                 string sa = car(s);
 548                 if (sa == "") continue;
 549                 int p = strstrofs(sa, "=", 0);
 550                 if (p < 0) {
 551                         if(!autocvar_g_mapinfo_ignore_warnings)
 552                                 LOG_WARNF("Invalid gametype setting in mapinfo for gametype %s: %s", MapInfo_Type_ToString(pWantedType), sa);
 553                         continue;
 554                 }
 555                 string k = substring(sa, 0, p);
 556                 string v = substring(sa, p + 1, -1);
 557                 bool handled = true;
 558                 switch (k) {
 559                         case "timelimit":
 560                         {
 561                                 cvar_set("timelimit", v);
 562                                 break;
 563                         }
 564                         case "leadlimit":
 565                         {
 566                                 cvar_set("leadlimit", v);
 567                                 break;
 568                         }
 569                         case "pointlimit":
 570                         case "fraglimit":
 571                         case "lives":
 572                         case "laplimit":
 573                         case "caplimit":
 574                         {
 575                                 fraglimit_normal = v;
 576                                 break;
 577                         }
 578                         case "teampointlimit":
 579                         case "teamlaplimit":
 580                         {
 581                                 fraglimit_teams = v;
 582                                 break;
 583                         }
 584                         default:
 585                         {
 586                             handled = false;
 587                             break;
 588                         }
 589                 }
 590                 FOREACH(Gametypes, true, handled |= it.m_parse_mapinfo(k, v));
 591                 if (!handled && !autocvar_g_mapinfo_ignore_warnings)
 592             LOG_WARNF("Invalid gametype setting in mapinfo for gametype %s: %s", MapInfo_Type_ToString(pWantedType), sa);
 593         }
 594
 595         if (pWantedType == MAPINFO_TYPE_RACE && cvar("g_race_teams") >= 2)
 596         {
 597                 if(fraglimit_teams)
 598                         cvar_set("fraglimit", fraglimit_teams);
 599         }
 600         else
 601         {
 602                 if(fraglimit_normal)
 603                         cvar_set("fraglimit", fraglimit_normal);
 604         }
 605 }
 606
 607 Gametype MapInfo_Type_FromString(string t)
 608 {
 609 #define deprecate(from, to) MACRO_BEGIN { \
 610         if (t == #from) { \
 611                 string replacement = #to; \
 612                 if(!autocvar_g_mapinfo_ignore_warnings) \
 613                         LOG_WARNF("MapInfo_Type_FromString (probably %s): using deprecated name '%s'. Should use '%s'.", MapInfo_Map_bspname, t, replacement); \
 614                 t = replacement; \
 615         } \
 616 } MACRO_END
 617         deprecate(nexball, nb);
 618         deprecate(freezetag, ft);
 619         deprecate(keepaway, ka);
 620         deprecate(invasion, inv);
 621         deprecate(assault, as);
 622         deprecate(race, rc);
 623         FOREACH(Gametypes, it.mdl == t, return it);
 624         return NULL;
 625 #undef deprecate
 626 }
 627
 628 string MapInfo_Type_Description(Gametype t)
 629 {
 630         return t ? t.gametype_description : "";
 631 }
 632
 633 string MapInfo_Type_ToString(Gametype t)
 634 {
 635         return t ? t.mdl : "";
 636 }
 637
 638 string MapInfo_Type_ToText(Gametype t)
 639 {
 640         /* xgettext:no-c-format */
 641         return t ? t.message : _("@!#%'n Tuba Throwing");
 642 }
 643
 644 void _MapInfo_Parse_Settemp(string pFilename, string acl, float type, string s, float recurse)
 645 {
 646         string t;
 647         float fh, o;
 648         t = car(s); s = cdr(s);
 649
 650         // limited support of "" and comments
 651         //   remove trailing and leading " of t
 652         if(substring(t, 0, 1) == "\"")
 653         {
 654                 if(substring(t, -1, 1) == "\"")
 655                         t = substring(t, 1, -2);
 656         }
 657
 658         //   remove leading " of s
 659         if(substring(s, 0, 1) == "\"")
 660         {
 661                 s = substring(s, 1, -1);
 662         }
 663         //   remove trailing " of s, and all that follows (cvar description)
 664         o = strstrofs(s, "\"", 0);
 665         if(o >= 0)
 666                 s = substring(s, 0, o);
 667
 668         //   remove // comments
 669         o = strstrofs(s, "//", 0);
 670         if(o >= 0)
 671                 s = substring(s, 0, o);
 672
 673         //   remove trailing spaces
 674         while(substring(s, -1, 1) == " ")
 675                 s = substring(s, 0, -2);
 676
 677         if(t == "#include")
 678         {
 679                 if(recurse > 0)
 680                 {
 681                         fh = fopen(s, FILE_READ);
 682                         if(fh < 0)
 683                                 LOG_WARN("Map ", pFilename, " references not existing config file ", s);
 684                         else
 685                         {
 686                                 for (;;)
 687                                 {
 688                                         if (!((s = fgets(fh))))
 689                                                 break;
 690
 691                                         // catch different sorts of comments
 692                                         if(s == "")                    // empty lines
 693                                                 continue;
 694                                         if(substring(s, 0, 1) == "#")  // UNIX style
 695                                                 continue;
 696                                         if(substring(s, 0, 2) == "//") // C++ style
 697                                                 continue;
 698                                         if(substring(s, 0, 1) == "_")  // q3map style
 699                                                 continue;
 700
 701                                         if(substring(s, 0, 4) == "set ")
 702                                                 s = substring(s, 4, -1);
 703                                         if(substring(s, 0, 5) == "seta ")
 704                                                 s = substring(s, 5, -1);
 705
 706                                         _MapInfo_Parse_Settemp(pFilename, acl, type, s, recurse - 1);
 707                                 }
 708                                 fclose(fh);
 709                         }
 710                 }
 711                 else
 712                         LOG_WARN("Map ", pFilename, " uses too many levels of inclusion");
 713         }
 714         else if(t == "")
 715                 LOG_WARN("Map ", pFilename, " contains a potentially harmful setting, ignored");
 716         else if (!cvar_value_issafe(t))
 717                 LOG_WARN("Map ", pFilename, " contains a potentially harmful setting, ignored");
 718         else if (!cvar_value_issafe(s))
 719                 LOG_WARN("Map ", pFilename, " contains a potentially harmful setting, ignored");
 720         else if(matchacl(MAPINFO_SETTEMP_ACL_SYSTEM, t) <= 0)
 721                 LOG_WARN("Map ", pFilename, " contains a potentially harmful setting, ignored");
 722         else if(matchacl(acl, t) <= 0)
 723                 LOG_WARN("Map ", pFilename, " contains a denied setting, ignored");
 724         else
 725         {
 726                 if(type == 0) // server set
 727                 {
 728                         LOG_TRACE("Applying temporary setting ", t, " := ", s);
 729                         if(cvar("g_campaign"))
 730                                 cvar_set(t, s); // this is a wrapper and is always temporary anyway; no need to backup old values then
 731                         else
 732                                 cvar_settemp(t, s);
 733                 }
 734                 else
 735                 {
 736                         LOG_TRACE("Applying temporary client setting ", t, " := ", s);
 737                         MapInfo_Map_clientstuff = strcat(
 738                                         MapInfo_Map_clientstuff, "cl_cmd settemp \"", t, "\" \"", s, "\"\n"
 739                                         );
 740                 }
 741         }
 742 }
 743
 744 float MapInfo_isRedundant(string fn, string t)
 745 {
 746         // normalize file name
 747         fn = strreplace("_", "-", fn);
 748
 749         // normalize visible title
 750         t = strreplace(": ", "-", t);
 751         t = strreplace(":", "-", t);
 752         t = strreplace(" ", "-", t);
 753         t = strreplace("_", "-", t);
 754         t = strreplace("'", "-", t);
 755
 756         if(!strcasecmp(fn, t))
 757                 return true;
 758
 759         // we allow the visible title to have punctuation the file name does
 760         // not, but not vice versa
 761         t = strreplace("-", "", t);
 762
 763         if(!strcasecmp(fn, t))
 764                 return true;
 765
 766         return false;
 767 }
 768
 769 // load info about a map by name into the MapInfo_Map_* globals
 770 float MapInfo_Get_ByName_NoFallbacks(string pFilename, int pAllowGenerate, Gametype pGametypeToSet)
 771 {
 772         string fn;
 773         string s, t;
 774         float fh;
 775         int f, i;
 776         float r, n, p;
 777         string acl;
 778
 779         acl = MAPINFO_SETTEMP_ACL_USER;
 780
 781         if(strstrofs(pFilename, "/", 0) >= 0)
 782         {
 783                 LOG_WARN("Invalid character in map name, ignored");
 784                 return 0;
 785         }
 786
 787         if(pGametypeToSet == NULL)
 788                 if(MapInfo_Cache_Retrieve(pFilename))
 789                         return 1;
 790
 791         r = 1;
 792
 793         MapInfo_Map_bspname = pFilename;
 794
 795         // default all generic fields so they have "good" values in case something fails
 796         fn = strcat("maps/", pFilename, ".mapinfo");
 797         fh = fopen(fn, FILE_READ);
 798         if(fh < 0)
 799         {
 800                 fn = strcat("maps/autogenerated/", pFilename, ".mapinfo");
 801                 fh = fopen(fn, FILE_READ);
 802                 if(fh < 0)
 803                 {
 804                         if(!pAllowGenerate)
 805                                 return 0;
 806                         _MapInfo_Map_Reset();
 807                         r = _MapInfo_Generate(pFilename);
 808                         if(!r)
 809                                 return 0;
 810                         fh = fopen(fn, FILE_WRITE);
 811                         fputs(fh, strcat("title ", MapInfo_Map_title, "\n"));
 812                         fputs(fh, strcat("description ", MapInfo_Map_description, "\n"));
 813                         fputs(fh, strcat("author ", MapInfo_Map_author, "\n"));
 814                         if(_MapInfo_Map_worldspawn_music != "")
 815                         {
 816                                 if(
 817                                         substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".wav"
 818                                         ||
 819                                         substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".ogg"
 820                                 )
 821                                         fputs(fh, strcat("cdtrack ", substring(_MapInfo_Map_worldspawn_music, 0, strlen(_MapInfo_Map_worldspawn_music) - 4), "\n"));
 822                                 else
 823                                         fputs(fh, strcat("cdtrack ", _MapInfo_Map_worldspawn_music, "\n"));
 824                         }
 825                         else
 826                         {
 827                                 n = tokenize_console(cvar_string("g_cdtracks_remaplist"));
 828                                 s = strcat(" ", cvar_string("g_cdtracks_dontusebydefault"), " ");
 829                                 for (;;)
 830                                 {
 831                                         i = floor(random() * n);
 832                                         if(strstrofs(s, strcat(" ", argv(i), " "), 0) < 0)
 833                                                 break;
 834                                 }
 835                                 fputs(fh, strcat("cdtrack ", ftos(i + 1), "\n"));
 836                         }
 837                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_WEAPONS)
 838                                 fputs(fh, "has weapons\n");
 839                         else
 840                                 fputs(fh, "// uncomment this if you added weapon pickups: has weapons\n");
 841                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_TURRETS)
 842                                 fputs(fh, "has turrets\n");
 843                         else
 844                                 fputs(fh, "// uncomment this if you added turrets: has turrets\n");
 845                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_VEHICLES)
 846                                 fputs(fh, "has vehicles\n");
 847                         else
 848                                 fputs(fh, "// uncomment this if you added vehicles: has vehicles\n");
 849                         if(MapInfo_Map_flags & MAPINFO_FLAG_FRUSTRATING)
 850                                 fputs(fh, "frustrating\n");
 851
 852                         FOREACH(Gametypes, MapInfo_Map_supportedGametypes & it.m_flags, {
 853                                 fputs(fh, sprintf("gametype %s // defaults: %s\n", MapInfo_Type_ToString(it), _MapInfo_GetDefaultEx(it)));
 854                         });
 855
 856                         if(fexists(strcat("scripts/", pFilename, ".arena")))
 857                                 fputs(fh, "settemp_for_type all sv_q3acompat_machineshotgunswap 1\n");
 858
 859                         if(fexists(strcat("scripts/", pFilename, ".defi")))
 860                                 fputs(fh, "settemp_for_type all sv_vq3compat 1\n");
 861
 862                         fputs(fh, "// optional: fog density red green blue alpha mindist maxdist\n");
 863                         fputs(fh, "// optional: settemp_for_type (all|gametypename) cvarname value\n");
 864                         fputs(fh, "// optional: clientsettemp_for_type (all|gametypename) cvarname value\n");
 865                         fputs(fh, "// optional: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
 866                         fputs(fh, "// optional: hidden\n");
 867
 868                         fclose(fh);
 869                         r = 2;
 870                         // return r;
 871                         fh = fopen(fn, FILE_READ);
 872                         if(fh < 0)
 873                                 error("... but I just wrote it!");
 874                 }
 875
 876                 if(!autocvar_g_mapinfo_ignore_warnings)
 877                         LOG_WARN("autogenerated mapinfo file ", fn, " has been loaded; please edit that file and move it to maps/", pFilename, ".mapinfo");
 878         }
 879
 880         _MapInfo_Map_Reset();
 881         for (;;)
 882         {
 883                 if (!((s = fgets(fh))))
 884                         break;
 885
 886                 // catch different sorts of comments
 887                 if(s == "")                    // empty lines
 888                         continue;
 889                 if(substring(s, 0, 1) == "#")  // UNIX style
 890                         continue;
 891                 if(substring(s, 0, 2) == "//") // C++ style
 892                         continue;
 893                 if(substring(s, 0, 1) == "_")  // q3map style
 894                         continue;
 895
 896                 p = strstrofs(s, "//", 0);
 897                 if(p >= 0)
 898                         s = substring(s, 0, p);
 899
 900                 t = car(s); s = cdr(s);
 901                 if(t == "title")
 902                         MapInfo_Map_title = s;
 903                 else if(t == "description")
 904                         MapInfo_Map_description = s;
 905                 else if(t == "author")
 906                         MapInfo_Map_author = s;
 907                 else if(t == "has")
 908                 {
 909                         t = car(s); // s = cdr(s);
 910                         if     (t == "weapons") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 911                         else if(t == "turrets") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_TURRETS;
 912                         else if(t == "vehicles") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_VEHICLES;
 913                         else if(t == "monsters") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_MONSTERS;
 914                         else if(t == "new_toys") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 915                         else
 916                                 LOG_WARN("Map ", pFilename, " supports unknown feature ", t, ", ignored");
 917                 }
 918                 else if(t == "hidden")
 919                 {
 920                         MapInfo_Map_flags |= MAPINFO_FLAG_HIDDEN;
 921                 }
 922                 else if(t == "forbidden")
 923                 {
 924                         MapInfo_Map_flags |= MAPINFO_FLAG_FORBIDDEN;
 925                 }
 926                 else if(t == "frustrating")
 927                 {
 928                         MapInfo_Map_flags |= MAPINFO_FLAG_FRUSTRATING;
 929                 }
 930                 else if(t == "noautomaplist")
 931                 {
 932                         MapInfo_Map_flags |= MAPINFO_FLAG_NOAUTOMAPLIST;
 933                 }
 934                 else if(t == "gameversion_min")
 935                 {
 936                         if (cvar("gameversion") < stof(s))
 937                                 MapInfo_Map_flags |= MAPINFO_FLAG_NOAUTOMAPLIST;
 938                 }
 939                 else if(t == "type")
 940                 {
 941                         t = car(s); s = cdr(s);
 942                         Gametype f = MapInfo_Type_FromString(t);
 943                         //if(!autocvar_g_mapinfo_ignore_warnings)
 944                                 //LOG_WARN("Map ", pFilename, " contains the legacy 'type' keyword which is deprecated and will be removed in the future. Please migrate the mapinfo file to 'gametype'.");
 945                         if(f)
 946                                 _MapInfo_Map_ApplyGametype (s, pGametypeToSet, f, true);
 947                         else if(!autocvar_g_mapinfo_ignore_warnings)
 948                                 LOG_DEBUG("Map ", pFilename, " supports unknown game type ", t, ", ignored");
 949                 }
 950                 else if(t == "gametype")
 951                 {
 952                         t = car(s); s = cdr(s);
 953                         Gametype f = MapInfo_Type_FromString(t);
 954                         if(f)
 955                                 _MapInfo_Map_ApplyGametypeEx (s, pGametypeToSet, f);
 956                         else if(!autocvar_g_mapinfo_ignore_warnings)
 957                                 LOG_DEBUG("Map ", pFilename, " supports unknown game type ", t, ", ignored");
 958                 }
 959                 else if(t == "size")
 960                 {
 961                         float a, b, c, d, e;
 962                         t = car(s); s = cdr(s); a = stof(t);
 963                         t = car(s); s = cdr(s); b = stof(t);
 964                         t = car(s); s = cdr(s); c = stof(t);
 965                         t = car(s); s = cdr(s); d = stof(t);
 966                         t = car(s); s = cdr(s); e = stof(t);
 967                         if(s == "")
 968                                 LOG_WARN("Map ", pFilename, " contains an incorrect size line (not enough params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z");
 969                         else
 970                         {
 971                                 t = car(s); s = cdr(s); f = stof(t);
 972                                 if(s != "")
 973                                         LOG_WARN("Map ", pFilename, " contains an incorrect size line (too many params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z");
 974                                 else
 975                                 {
 976                                         if(a >= d || b >= e || c >= f)
 977                                                 LOG_WARN("Map ", pFilename, " contains an incorrect size line, mins have to be < maxs");
 978                                         else
 979                                         {
 980                                                 MapInfo_Map_mins.x = a;
 981                                                 MapInfo_Map_mins.y = b;
 982                                                 MapInfo_Map_mins.z = c;
 983                                                 MapInfo_Map_maxs.x = d;
 984                                                 MapInfo_Map_maxs.y = e;
 985                                                 MapInfo_Map_maxs.z = f;
 986                                         }
 987                                 }
 988                         }
 989                 }
 990                 else if(t == "settemp_for_type")
 991                 {
 992                         t = car(s); s = cdr(s);
 993                         bool all = t == "all";
 994                         Gametype f = NULL;
 995                         if(all || (f = MapInfo_Type_FromString(t)))
 996                         {
 997                                 if((all ? MAPINFO_TYPE_ALL : f.m_flags) & pGametypeToSet.m_flags)
 998                                 {
 999                                         _MapInfo_Parse_Settemp(pFilename, acl, 0, s, 1);
1000                                 }
1001                         }
1002                         else
1003                         {
1004                                 LOG_DEBUG("Map ", pFilename, " has a setting for unknown game type ", t, ", ignored");
1005                         }
1006                 }
1007                 else if(t == "clientsettemp_for_type")
1008                 {
1009                         t = car(s); s = cdr(s);
1010                         bool all = t == "all";
1011                         Gametype f = NULL;
1012                         if(all || (f = MapInfo_Type_FromString(t)))
1013                         {
1014                                 if((all ? MAPINFO_TYPE_ALL : f.m_flags) & pGametypeToSet.m_flags)
1015                                 {
1016                                         _MapInfo_Parse_Settemp(pFilename, acl, 1, s, 1);
1017                                 }
1018                         }
1019                         else
1020                         {
1021                                 LOG_DEBUG("Map ", pFilename, " has a client setting for unknown game type ", t, ", ignored");
1022                         }
1023                 }
1024                 else if(t == "fog")
1025                 {
1026                         if (!cvar_value_issafe(s))
1027                                 LOG_WARN("Map ", pFilename, " contains a potentially harmful fog setting, ignored");
1028                         else
1029                                 MapInfo_Map_fog = s;
1030                 }
1031                 else if(t == "cdtrack")
1032                 {
1033                         t = car(s); s = cdr(s);
1034                         // We do this only if pGametypeToSet even though this
1035                         // content is theoretically game type independent,
1036                         // because MapInfo_Map_clientstuff contains otherwise
1037                         // game type dependent stuff. That way this value stays
1038                         // empty when not setting a game type to not set any
1039                         // false expectations.
1040                         if(pGametypeToSet)
1041                         {
1042                                 if (!cvar_value_issafe(t))
1043                                         LOG_WARN("Map ", pFilename, " contains a potentially harmful cdtrack, ignored");
1044                                 else
1045                                         MapInfo_Map_clientstuff = strcat(
1046                                                 MapInfo_Map_clientstuff, "cd loop \"", t, "\"\n"
1047                                         );
1048                         }
1049                 }
1050                 else if(!autocvar_g_mapinfo_ignore_warnings)
1051                         LOG_WARN("Map ", pFilename, " provides unknown info item ", t, ", ignored");
1052         }
1053         fclose(fh);
1054
1055         if(MapInfo_Map_title == "<TITLE>")
1056                 MapInfo_Map_titlestring = MapInfo_Map_bspname;
1057         else if(MapInfo_isRedundant(MapInfo_Map_bspname, MapInfo_Map_title))
1058                 MapInfo_Map_titlestring = MapInfo_Map_title;
1059         else
1060                 MapInfo_Map_titlestring = sprintf("%s: %s", MapInfo_Map_bspname, MapInfo_Map_title);
1061
1062         MapInfo_Cache_Store();
1063         if(MapInfo_Map_supportedGametypes != 0)
1064                 return r;
1065         LOG_WARN("Map ", pFilename, " supports no game types, ignored");
1066         return 0;
1067 }
1068 int MapInfo_Get_ByName(string pFilename, float pAllowGenerate, Gametype pGametypeToSet)
1069 {
1070         int r = MapInfo_Get_ByName_NoFallbacks(pFilename, pAllowGenerate, pGametypeToSet);
1071
1072         FOREACH(Gametypes, it.m_isForcedSupported(it), _MapInfo_Map_ApplyGametypeEx("", pGametypeToSet, it));
1073
1074         if(pGametypeToSet)
1075         {
1076                 if(!(MapInfo_Map_supportedGametypes & pGametypeToSet.m_flags))
1077                 {
1078                         error("Can't select the requested game type. This should never happen as the caller should prevent it!\n");
1079                         //_MapInfo_Map_ApplyGametypeEx("", pGametypeToSet, MAPINFO_TYPE_DEATHMATCH);
1080                         //return;
1081                 }
1082         }
1083
1084         return r;
1085 }
1086
1087 float MapInfo_FindName(string s)
1088 {
1089         // if there is exactly one map of prefix s, return it
1090         // if not, return the null string
1091         // note that DP sorts glob results... so I can use a binary search
1092         float l, r, m, cmp;
1093         l = 0;
1094         r = MapInfo_count;
1095         // invariants: r is behind s, l-1 is equal or before
1096         while(l != r)
1097         {
1098                 m = floor((l + r) / 2);
1099                 MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(m));
1100                 cmp = strcasecmp(MapInfo_FindName_match, s);
1101                 if(cmp == 0)
1102                         return m; // found and good
1103                 if(cmp < 0)
1104                         l = m + 1; // l-1 is before s
1105                 else
1106                         r = m; // behind s
1107         }
1108         MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(l));
1109         MapInfo_FindName_firstResult = l;
1110         // r == l, so: l is behind s, l-1 is before
1111         // SO: if there is any, l is the one with the right prefix
1112         //     and l+1 may be one too
1113         if(l == MapInfo_count)
1114         {
1115                 MapInfo_FindName_match = string_null;
1116                 MapInfo_FindName_firstResult = -1;
1117                 return -1; // no MapInfo_FindName_match, behind last item
1118         }
1119         if(!startsWithNocase(MapInfo_FindName_match, s))
1120         {
1121                 MapInfo_FindName_match = string_null;
1122                 MapInfo_FindName_firstResult = -1;
1123                 return -1; // wrong prefix
1124         }
1125         if(l == MapInfo_count - 1)
1126                 return l; // last one, nothing can follow => unique
1127         if(startsWithNocase(_MapInfo_GlobItem(MapInfo_FilterList_Lookup(l + 1)), s))
1128         {
1129                 MapInfo_FindName_match = string_null;
1130                 return -1; // ambigous MapInfo_FindName_match
1131         }
1132         return l;
1133 }
1134
1135 string MapInfo_FixName(string s)
1136 {
1137         MapInfo_FindName(s);
1138         return MapInfo_FindName_match;
1139 }
1140
1141 int MapInfo_CurrentFeatures()
1142 {
1143         int req = 0;
1144         if(!(cvar("g_lms") || cvar("g_instagib") || cvar("g_overkill") || cvar("g_nix") || cvar("g_weaponarena") || !cvar("g_pickup_items") || cvar("g_race") || cvar("g_cts") || cvar("g_nexball")))
1145                 req |= MAPINFO_FEATURE_WEAPONS;
1146         return req;
1147 }
1148
1149 Gametype MapInfo_CurrentGametype()
1150 {
1151         Gametype prev = Gametypes_from(cvar("gamecfg"));
1152         FOREACH(Gametypes, cvar(it.netname) && it != prev, return it);
1153         return prev ? prev : MAPINFO_TYPE_DEATHMATCH;
1154 }
1155
1156 float _MapInfo_CheckMap(string s, bool gametype_only) // returns 0 if the map can't be played with the current settings, 1 otherwise
1157 {
1158         if(!MapInfo_Get_ByName(s, 1, NULL))
1159                 return 0;
1160         if((MapInfo_Map_supportedGametypes & MapInfo_CurrentGametype().m_flags) == 0)
1161                 return 0;
1162         if (gametype_only)
1163                 return 1;
1164         if((MapInfo_Map_supportedFeatures & MapInfo_CurrentFeatures()) != MapInfo_CurrentFeatures())
1165                 return 0;
1166         return 1;
1167 }
1168
1169 float MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
1170 {
1171         float r;
1172         r = _MapInfo_CheckMap(s, false);
1173         MapInfo_ClearTemps();
1174         return r;
1175 }
1176
1177 void MapInfo_SwitchGameType(Gametype t)
1178 {
1179         FOREACH(Gametypes, true, cvar_set(it.netname, (it == t) ? "1" : "0"));
1180 }
1181
1182 void MapInfo_LoadMap(string s, float reinit)
1183 {
1184         MapInfo_Map_supportedGametypes = 0;
1185         // we shouldn't need this, as LoadMapSettings already fixes the gametype
1186         //if(!MapInfo_CheckMap(s))
1187         //{
1188         //      print("EMERGENCY: can't play the selected map in the given game mode. Falling back to DM.\n");
1189         //      MapInfo_SwitchGameType(MAPINFO_TYPE_DEATHMATCH.m_flags);
1190         //}
1191
1192         LOG_INFO("Switching to map ", s);
1193
1194         cvar_settemp_restore();
1195         if(reinit)
1196                 localcmd(strcat("\nmap ", s, "\n"));
1197         else
1198                 localcmd(strcat("\nchangelevel ", s, "\n"));
1199 }
1200
1201 string MapInfo_ListAllowedMaps(Gametype type, float pRequiredFlags, float pForbiddenFlags)
1202 {
1203         string out;
1204
1205         // to make absolutely sure:
1206         MapInfo_Enumerate();
1207         MapInfo_FilterGametype(type, MapInfo_CurrentFeatures(), pRequiredFlags, pForbiddenFlags, 0);
1208
1209         out = "";
1210         for(float i = 0; i < MapInfo_count; ++i)
1211                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
1212         return substring(out, 1, strlen(out) - 1);
1213 }
1214
1215 string MapInfo_ListAllAllowedMaps(float pRequiredFlags, float pForbiddenFlags)
1216 {
1217         string out;
1218
1219         // to make absolutely sure:
1220         MapInfo_Enumerate();
1221         _MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, pRequiredFlags, pForbiddenFlags, 0);
1222
1223         out = "";
1224         for(float i = 0; i < MapInfo_count; ++i)
1225                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
1226
1227         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), pRequiredFlags, pForbiddenFlags, 0);
1228
1229         return substring(out, 1, strlen(out) - 1);
1230 }
1231
1232 void MapInfo_LoadMapSettings_SaveGameType(Gametype t)
1233 {
1234         MapInfo_SwitchGameType(t);
1235         cvar_set("gamecfg", ftos(t.m_id));
1236         MapInfo_LoadedGametype = t;
1237 }
1238
1239 void MapInfo_LoadMapSettings(string s) // to be called from worldspawn
1240 {
1241         Gametype t = MapInfo_CurrentGametype();
1242         MapInfo_LoadMapSettings_SaveGameType(t);
1243
1244         if(!_MapInfo_CheckMap(s, true)) // with underscore, it keeps temps
1245         {
1246                 if(cvar("g_mapinfo_allow_unsupported_modes_and_let_stuff_break"))
1247                 {
1248                         LOG_SEVERE("can't play the selected map in the given game mode. Working with only the override settings.");
1249                         _MapInfo_Map_ApplyGametypeEx("", t, t);
1250                         return; // do not call Get_ByName!
1251                 }
1252
1253                 if(MapInfo_Map_supportedGametypes == 0)
1254                 {
1255                         LOG_SEVERE("Mapinfo system is not functional at all. Assuming deathmatch.");
1256                         MapInfo_Map_supportedGametypes = MAPINFO_TYPE_DEATHMATCH.m_flags;
1257                         MapInfo_LoadMapSettings_SaveGameType(MAPINFO_TYPE_DEATHMATCH);
1258                         _MapInfo_Map_ApplyGametypeEx("", MAPINFO_TYPE_DEATHMATCH, MAPINFO_TYPE_DEATHMATCH);
1259                         return; // do not call Get_ByName!
1260                 }
1261
1262                 int _t = 1;
1263                 while(!(MapInfo_Map_supportedGametypes & 1))
1264                 {
1265                         _t <<= 1;
1266                         MapInfo_Map_supportedGametypes = floor(MapInfo_Map_supportedGametypes >> 1);
1267                 }
1268                 Gametype t_prev = t;
1269                 FOREACH(Gametypes, it.m_flags == _t, { t = it; break; });
1270
1271                 // t is now a supported mode!
1272                 LOG_WARNF("can't play the selected map in the given game mode (%s). Falling back to a supported mode (%s).", t_prev.mdl, t.mdl);
1273                 MapInfo_LoadMapSettings_SaveGameType(t);
1274         }
1275         if(!_MapInfo_CheckMap(s, false)) { // with underscore, it keeps temps
1276                 LOG_WARNF("the selected map lacks features required by current settings; playing anyway.");
1277         }
1278         MapInfo_Get_ByName(s, 1, t);
1279 }
1280
1281 void MapInfo_ClearTemps()
1282 {
1283         MapInfo_Map_bspname = string_null;
1284         MapInfo_Map_title = string_null;
1285         MapInfo_Map_titlestring = string_null;
1286         MapInfo_Map_description = string_null;
1287         MapInfo_Map_author = string_null;
1288         MapInfo_Map_clientstuff = string_null;
1289         MapInfo_Map_supportedGametypes = 0;
1290         MapInfo_Map_supportedFeatures = 0;
1291 }
1292
1293 void MapInfo_Shutdown()
1294 {
1295         MapInfo_ClearTemps();
1296         MapInfo_Filter_Free();
1297         MapInfo_Cache_Destroy();
1298         if(_MapInfo_globopen)
1299         {
1300                 search_end(_MapInfo_globhandle);
1301                 _MapInfo_globhandle = -1;
1302                 _MapInfo_globopen = false;
1303         }
1304 }
1305
1306 int MapInfo_ForbiddenFlags()
1307 {
1308         int f = MAPINFO_FLAG_FORBIDDEN;
1309
1310 #ifdef GAMEQC
1311         if (!cvar("g_maplist_allow_hidden"))
1312 #endif
1313                 f |= MAPINFO_FLAG_HIDDEN;
1314
1315         if (!cvar("g_maplist_allow_frustrating"))
1316                 f |= MAPINFO_FLAG_FRUSTRATING;
1317
1318         return f;
1319 }
1320
1321 int MapInfo_RequiredFlags()
1322 {
1323         int f = 0;
1324
1325         if(cvar("g_maplist_allow_frustrating") > 1)
1326                 f |= MAPINFO_FLAG_FRUSTRATING;
1327
1328         return f;
1329 }