qcsrc/common/minigames/minigame/snake.qc

   1 const float SNAKE_TURN_MOVE  = 0x0100; // the snake is moving, player must control it
   2 const float SNAKE_TURN_LOSS  = 0x0200; // they did it?!
   3 const float SNAKE_TURN_WAIT  = 0x0400; // the snake is waiting for the player to make their first move and begin the game
   4 const float SNAKE_TURN_TYPE  = 0x0f00; // turn type mask
   5
   6 const int SNAKE_SF_PLAYERSCORE = MINIG_SF_CUSTOM;
   7
   8 const int SNAKE_LET_CNT = 15;
   9 const int SNAKE_NUM_CNT = 15;
  10
  11 const int SNAKE_TILE_SIZE = 15;
  12
  13 bool autocvar_sv_minigames_snake_wrap = false;
  14 float autocvar_sv_minigames_snake_delay_initial = 0.7;
  15 float autocvar_sv_minigames_snake_delay_multiplier = 50;
  16 float autocvar_sv_minigames_snake_delay_min = 0.1;
  17
  18 .int snake_score;
  19 .entity snake_head;
  20
  21 .float snake_delay;
  22 .float snake_nextmove;
  23 .vector snake_dir;
  24
  25 // find same game piece given its tile name
  26 entity snake_find_piece(entity minig, string tile)
  27 {
  28         entity e = world;
  29         while ( ( e = findentity(e,owner,minig) ) )
  30                 if ( e.classname == "minigame_board_piece" && e.netname == tile )
  31                         return e;
  32         return world;
  33 }
  34
  35 // find same game piece given its cnt
  36 entity snake_find_cnt(entity minig, int tile)
  37 {
  38         entity e = world;
  39         while ( ( e = findentity(e,owner,minig) ) )
  40                 if ( e.classname == "minigame_board_piece" && e.cnt == tile )
  41                         return e;
  42         return world;
  43 }
  44
  45 // check if the tile name is valid (15x15 grid)
  46 bool snake_valid_tile(string tile)
  47 {
  48         if ( !tile )
  49                 return false;
  50         int number = minigame_tile_number(tile);
  51         int letter = minigame_tile_letter(tile);
  52         return 0 <= number && number < SNAKE_NUM_CNT && 0 <= letter && letter < SNAKE_LET_CNT;
  53 }
  54
  55 void snake_new_mouse(entity minigame)
  56 {
  57         RandomSelection_Init();
  58         int i, j;
  59         for(i = 0; i < SNAKE_LET_CNT; ++i)
  60         for(j = 0; j < SNAKE_NUM_CNT; ++j)
  61         {
  62                 string pos = minigame_tile_buildname(i, j);
  63                 if(!snake_find_piece(minigame, pos))
  64                         RandomSelection_Add(world, 0, pos, 1, 1);
  65         }
  66
  67         entity piece = msle_spawn(minigame,"minigame_board_piece");
  68         piece.team = 1;
  69         piece.netname = strzone(RandomSelection_chosen_string);
  70         minigame_server_sendflags(piece,MINIG_SF_ALL);
  71
  72         minigame_server_sendflags(minigame,MINIG_SF_UPDATE);
  73 }
  74
  75 void snake_setup_pieces(entity minigame)
  76 {
  77         int targnum = bound(1, floor(random() * SNAKE_NUM_CNT), SNAKE_NUM_CNT - 1);
  78         int targlet = bound(1, floor(random() * SNAKE_LET_CNT), SNAKE_LET_CNT - 1);
  79
  80         entity piece = msle_spawn(minigame,"minigame_board_piece");
  81         piece.team = 1; // init default team?
  82         piece.netname = strzone(minigame_tile_buildname(targlet,targnum));
  83         piece.cnt = 1;
  84         minigame_server_sendflags(piece,MINIG_SF_ALL);
  85
  86         minigame.snake_head = piece;
  87
  88         snake_new_mouse(minigame);
  89
  90         minigame_server_sendflags(minigame,MINIG_SF_UPDATE);
  91 }
  92
  93 void snake_add_score(entity minigame, int thescore)
  94 {
  95 #ifdef SVQC
  96         if(!minigame)
  97                 return;
  98         if(minigame.minigame_players)
  99         {
 100                 minigame.minigame_players.snake_score += thescore;
 101                 minigame.minigame_players.SendFlags |= SNAKE_SF_PLAYERSCORE;
 102         }
 103 #endif
 104 }
 105
 106 void snake_move_body(entity minigame, bool ate_mouse)
 107 {
 108         entity tail = world;
 109         string tailpos = string_null;
 110         vector taildir = '0 0 0';
 111
 112         int i, pieces = 0;
 113         for(i = (SNAKE_NUM_CNT * SNAKE_LET_CNT); i >= 2; --i)
 114         {
 115                 entity piece = snake_find_cnt(minigame, i);
 116                 entity nextpiece = snake_find_cnt(minigame, i - 1);
 117                 if(!piece)
 118                         continue;
 119
 120                 pieces++;
 121
 122                 if(!tail)
 123                 {
 124                         tail = piece;
 125                         tailpos = piece.netname;
 126                         taildir = piece.snake_dir;
 127                 }
 128
 129                 if(piece.netname) { strunzone(piece.netname); }
 130                 piece.netname = strzone(nextpiece.netname);
 131                 piece.snake_dir = nextpiece.snake_dir;
 132                 minigame_server_sendflags(piece, MINIG_SF_ALL);
 133         }
 134
 135         // just a head
 136         if(!pieces)
 137         {
 138                 tail = minigame.snake_head;
 139                 tailpos = minigame.snake_head.netname;
 140                 taildir = minigame.snake_head.snake_dir;
 141         }
 142
 143         if(tail && ate_mouse)
 144         {
 145                 int newcnt = tail.cnt + 1;
 146                 minigame.snake_delay = max(autocvar_sv_minigames_snake_delay_min, autocvar_sv_minigames_snake_delay_initial - (newcnt / autocvar_sv_minigames_snake_delay_multiplier));
 147                 snake_add_score(minigame, 1);
 148
 149                 entity piece = msle_spawn(minigame,"minigame_board_piece");
 150                 piece.cnt = newcnt;
 151                 piece.team = 1;
 152                 piece.snake_dir = taildir;
 153                 piece.netname = strzone(tailpos);
 154                 minigame_server_sendflags(piece,MINIG_SF_ALL);
 155
 156                 minigame_server_sendflags(minigame,MINIG_SF_UPDATE);
 157         }
 158 }
 159
 160 void snake_move_head(entity minigame)
 161 {
 162         entity head = minigame.snake_head;
 163
 164         int myx = minigame_tile_letter(head.netname);
 165         int myy = minigame_tile_number(head.netname);
 166
 167         string newpos;
 168
 169         if(autocvar_sv_minigames_snake_wrap)
 170                 newpos = minigame_relative_tile(head.netname, minigame.snake_dir_x, minigame.snake_dir_y, SNAKE_NUM_CNT, SNAKE_LET_CNT);
 171         else
 172         {
 173                 myx += minigame.snake_dir_x;
 174                 myy += minigame.snake_dir_y;
 175
 176                 newpos = minigame_tile_buildname(myx, myy);
 177         }
 178
 179         if(!snake_valid_tile(newpos) || (snake_find_piece(minigame, newpos)).cnt)
 180         {
 181                 minigame.minigame_flags = SNAKE_TURN_LOSS;
 182                 minigame_server_sendflags(minigame,MINIG_SF_UPDATE);
 183                 return;
 184         }
 185
 186         bool ate_mouse = false;
 187         entity piece = snake_find_piece(minigame, newpos);
 188         if(piece && !piece.cnt)
 189                 ate_mouse = true;
 190
 191         // move the body first, then set the new head position?
 192         snake_move_body(minigame, ate_mouse);
 193
 194         if(ate_mouse)
 195         {
 196                 if(piece.netname) { strunzone(piece.netname); }
 197                 remove(piece);
 198
 199                 snake_new_mouse(minigame);
 200         }
 201
 202         if(head.netname) { strunzone(head.netname); }
 203         head.netname = strzone(newpos);
 204         minigame_server_sendflags(head,MINIG_SF_ALL);
 205 }
 206
 207 // make a move
 208 void snake_move(entity minigame, entity player, string dxs, string dys )
 209 {
 210         if ( (minigame.minigame_flags & SNAKE_TURN_MOVE) || (minigame.minigame_flags & SNAKE_TURN_WAIT) )
 211         if ( dxs || dys )
 212         {
 213                 //if ( snake_valid_tile(pos) )
 214                 //if ( snake_find_piece(minigame, pos) )
 215                 {
 216                         int dx = ((dxs) ? bound(-1, stof(dxs), 1) : 0);
 217                         int dy = ((dys) ? bound(-1, stof(dys), 1) : 0);
 218
 219                         int myl = minigame_tile_letter(minigame.snake_head.netname);
 220                         int myn = minigame_tile_number(minigame.snake_head.netname);
 221
 222                         entity head = snake_find_piece(minigame, minigame_tile_buildname(myl + dx, myn + dy));
 223                         if(head && head.cnt == 2)
 224                                 return; // nope!
 225
 226                         if(minigame.minigame_flags & SNAKE_TURN_WAIT)
 227                                 minigame.snake_nextmove = time;
 228                         minigame.minigame_flags = SNAKE_TURN_MOVE;
 229                         minigame.snake_dir_x = dx;
 230                         minigame.snake_dir_y = dy;
 231                         minigame.snake_dir_z = 0;
 232                         minigame.snake_head.snake_dir = minigame.snake_dir;
 233                         minigame_server_sendflags(minigame.snake_head,MINIG_SF_UPDATE);
 234                         minigame_server_sendflags(minigame,MINIG_SF_UPDATE);
 235                 }
 236         }
 237 }
 238
 239 #ifdef SVQC
 240
 241
 242 // required function, handle server side events
 243 int snake_server_event(entity minigame, string event, ...)
 244 {
 245         switch(event)
 246         {
 247                 case "start":
 248                 {
 249                         snake_setup_pieces(minigame);
 250                         minigame.snake_delay = autocvar_sv_minigames_snake_delay_initial;
 251                         minigame.minigame_flags = SNAKE_TURN_WAIT;
 252                         return true;
 253                 }
 254                 case "end":
 255                 {
 256                         entity e = world;
 257                         while( (e = findentity(e, owner, minigame)) )
 258                         if(e.classname == "minigame_board_piece")
 259                         {
 260                                 if(e.netname) { strunzone(e.netname); }
 261                                 remove(e);
 262                         }
 263                         minigame.snake_head = world;
 264                         return false;
 265                 }
 266                 case "join":
 267                 {
 268                         int pl_num = minigame_count_players(minigame);
 269
 270                         // Don't allow more than 1 player
 271                         // not sure if this should be a multiplayer game (might get crazy)
 272                         if(pl_num >= 1) { return false; }
 273
 274                         // Team 1 by default
 275                         return 1;
 276                 }
 277                 case "frame":
 278                 {
 279                         if(minigame.minigame_flags & SNAKE_TURN_MOVE)
 280                         if(time >= minigame.snake_nextmove)
 281                         {
 282                                 snake_move_head(minigame);
 283                                 minigame.snake_nextmove = time + minigame.snake_delay;
 284                         }
 285                         return false;
 286                 }
 287                 case "cmd":
 288                 {
 289                         switch(argv(0))
 290                         {
 291                                 case "move":
 292                                         snake_move(minigame, ...(0,entity), ((...(1,int)) >= 2 ? argv(1) : string_null), ((...(1,int)) == 3 ? argv(2) : string_null));
 293                                         return true;
 294                         }
 295
 296                         return false;
 297                 }
 298                 case "network_send":
 299                 {
 300                         entity sent = ...(0,entity);
 301                         int sf = ...(1,int);
 302                         if ( sent.classname == "minigame_board_piece" && (sf & MINIG_SF_UPDATE) )
 303                         {
 304                                 WriteByte(MSG_ENTITY,sent.cnt);
 305                                 WriteCoord(MSG_ENTITY,sent.snake_dir_x);
 306                                 WriteCoord(MSG_ENTITY,sent.snake_dir_y);
 307                         }
 308                         else if ( sent.classname == "minigame_player" && (sf & SNAKE_SF_PLAYERSCORE ) )
 309                         {
 310                                 WriteLong(MSG_ENTITY,sent.snake_score);
 311                         }
 312                         return false;
 313                 }
 314         }
 315
 316         return false;
 317 }
 318
 319
 320 #elif defined(CSQC)
 321
 322 vector snake_boardpos; // HUD board position
 323 vector snake_boardsize;// HUD board size
 324
 325 // Required function, draw the game board
 326 void snake_hud_board(vector pos, vector mySize)
 327 {
 328         minigame_hud_fitsqare(pos, mySize);
 329         snake_boardpos = pos;
 330         snake_boardsize = mySize;
 331
 332         minigame_hud_simpleboard(pos,mySize,minigame_texture("snake/board"));
 333
 334         vector tile_size = minigame_hud_denormalize_size('1 1 0' / SNAKE_TILE_SIZE,pos,mySize);
 335         vector tile_pos;
 336
 337         entity tail = world;
 338         int i;
 339         for(i = (SNAKE_NUM_CNT * SNAKE_LET_CNT); i >= 2; --i)
 340         {
 341                 entity piece = snake_find_cnt(active_minigame, i);
 342                 if(piece)
 343                 {
 344                         tail = piece;
 345                         break;
 346                 }
 347         }
 348
 349         entity e;
 350         FOREACH_MINIGAME_ENTITY(e)
 351         {
 352                 if ( e.classname == "minigame_board_piece" )
 353                 {
 354                         tile_pos = minigame_tile_pos(e.netname,SNAKE_NUM_CNT,SNAKE_LET_CNT);
 355                         tile_pos = minigame_hud_denormalize(tile_pos,pos,mySize);
 356                         string thepiece = "snake/mouse";
 357                         if(e.cnt)
 358                                 thepiece = "snake/body";
 359                         if(tail && e.cnt == tail.cnt)
 360                                 thepiece = "snake/tail";
 361                         if(e.cnt == 1)
 362                         {
 363                                 int dx = minigame_tile_letter(e.netname) + e.snake_dir_x * 2;
 364                                 int dy = minigame_tile_number(e.netname) + e.snake_dir_y * 2;
 365                                 entity mouse = snake_find_piece(active_minigame, minigame_tile_buildname(dx, dy));
 366                                 thepiece = "snake/head";
 367                                 if(mouse && !mouse.cnt)
 368                                 {
 369                                         float myang = 0;
 370                                         int myx = minigame_tile_letter(e.netname);
 371                                         int myy = minigame_tile_number(e.netname);
 372                                         if(myx - 2 == dx)
 373                                                 myang = M_PI*3/2;
 374                                         if(myx + 2 == dx)
 375                                                 myang = M_PI/2;
 376                                         if(myy - 2 == dy)
 377                                                 myang = M_PI;
 378
 379                                         int newx = minigame_tile_letter(e.netname) + e.snake_dir_x;
 380                                         int newy = minigame_tile_number(e.netname) + e.snake_dir_y;
 381                                         string newpos = minigame_tile_buildname(newx, newy);
 382
 383                                         vector my_pos = minigame_tile_pos(newpos,SNAKE_NUM_CNT,SNAKE_LET_CNT);
 384                                         my_pos = minigame_hud_denormalize(my_pos,pos,mySize);
 385
 386                                         drawrotpic(my_pos, myang, minigame_texture("snake/tongue"),
 387                                                         tile_size, tile_size/2, '1 1 1',
 388                                                         panel_fg_alpha, DRAWFLAG_NORMAL );
 389                                 }
 390                         }
 391
 392                         if(e.cnt == 1 || e.cnt == tail.cnt)
 393                         {
 394                                 vector thedir = e.snake_dir;
 395                                 float theang = 0;
 396                                 if(e.cnt == tail.cnt)
 397                                 {
 398                                         int thex = minigame_tile_letter(e.netname);
 399                                         int they = minigame_tile_number(e.netname);
 400                                         entity t = snake_find_cnt(active_minigame, e.cnt - 1);
 401                                         int tx = minigame_tile_letter(t.netname);
 402                                         int ty = minigame_tile_number(t.netname);
 403
 404                                         if(thex - 1 == tx)
 405                                         {
 406                                                 thedir_y = 0;
 407                                                 thedir_x = -1;
 408                                         }
 409                                         if(they + 1 == ty)
 410                                         {
 411                                                 thedir_x = 0;
 412                                                 thedir_y = 1;
 413                                         }
 414                                         if(they - 1 == ty)
 415                                         {
 416                                                 thedir_x = 0;
 417                                                 thedir_y = -1;
 418                                         }
 419                                 }
 420
 421                                 if(thedir_y == -1)
 422                                         theang = M_PI;
 423                                 if(thedir_x == 1)
 424                                         theang = M_PI/2;
 425                                 if(thedir_x == -1)
 426                                         theang = M_PI*3/2;
 427
 428                                 drawrotpic(tile_pos, theang, minigame_texture(thepiece),
 429                                                         tile_size, tile_size/2, '1 1 1',
 430                                                         panel_fg_alpha, DRAWFLAG_NORMAL );
 431                         }
 432                         else
 433                         {
 434                                 minigame_drawpic_centered( tile_pos,
 435                                                 minigame_texture(thepiece),
 436                                                 tile_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL );
 437                         }
 438                 }
 439         }
 440
 441         if ( active_minigame.minigame_flags & SNAKE_TURN_LOSS )
 442         {
 443                 int scores = 0;
 444                 FOREACH_MINIGAME_ENTITY(e)
 445                         if(e.classname == "minigame_player")
 446                                 scores = e.snake_score;
 447
 448                 vector winfs = hud_fontsize*2;
 449                 string scores_text;
 450                 scores_text = strcat("Score: ", ftos(scores));
 451
 452                 vector win_pos = pos+eY*(mySize_y-winfs_y)/2;
 453                 vector win_sz;
 454                 win_sz = minigame_drawcolorcodedstring_wrapped(mySize_x,win_pos,
 455                         sprintf("Game over! %s", scores_text),
 456                         winfs, 0, DRAWFLAG_NORMAL, 0.5);
 457
 458                 drawfill(win_pos-eY*hud_fontsize_y,win_sz+2*eY*hud_fontsize_y,'0.3 0.3 1',0.8,DRAWFLAG_ADDITIVE);
 459
 460                 minigame_drawcolorcodedstring_wrapped(mySize_x,win_pos,
 461                         sprintf("Game over! %s", scores_text),
 462                         winfs, panel_fg_alpha, DRAWFLAG_NORMAL, 0.5);
 463         }
 464 }
 465
 466
 467 // Required function, draw the game status panel
 468 void snake_hud_status(vector pos, vector mySize)
 469 {
 470         HUD_Panel_DrawBg(1);
 471         vector ts;
 472         ts = minigame_drawstring_wrapped(mySize_x,pos,active_minigame.descriptor.message,
 473                 hud_fontsize * 2, '0.25 0.47 0.72', panel_fg_alpha, DRAWFLAG_NORMAL,0.5);
 474
 475         pos_y += ts_y;
 476         mySize_y -= ts_y;
 477
 478         vector player_fontsize = hud_fontsize * 1.75;
 479         ts_y = ( mySize_y - 2*player_fontsize_y ) / 2;
 480         ts_x = mySize_x;
 481         vector mypos;
 482         vector tile_size = '48 48 0';
 483
 484         mypos = pos;
 485         drawfill(mypos,eX*mySize_x+eY*player_fontsize_y,'1 1 1',0.5,DRAWFLAG_ADDITIVE);
 486         mypos_y += player_fontsize_y;
 487         drawfill(mypos,eX*mySize_x+eY*tile_size_y,'1 1 1',0.25,DRAWFLAG_ADDITIVE);
 488
 489         entity e;
 490         FOREACH_MINIGAME_ENTITY(e)
 491         {
 492                 if ( e.classname == "minigame_player" )
 493                 {
 494                         mypos = pos;
 495                         minigame_drawcolorcodedstring_trunc(mySize_x,mypos,
 496                                 GetPlayerName(e.minigame_playerslot-1),
 497                                 player_fontsize, panel_fg_alpha, DRAWFLAG_NORMAL);
 498
 499                         mypos_y += player_fontsize_y;
 500                         //drawpic( mypos,
 501                         //              minigame_texture("snake/piece"),
 502                         //              tile_size, '1 0 0', panel_fg_alpha, DRAWFLAG_NORMAL );
 503
 504                         //mypos_x += tile_size_x;
 505
 506                         drawstring(mypos,ftos(e.snake_score),tile_size,
 507                                            '0.7 0.84 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 508                 }
 509         }
 510 }
 511
 512 // Turn a set of flags into a help message
 513 string snake_turn_to_string(int turnflags)
 514 {
 515         if ( turnflags & SNAKE_TURN_LOSS )
 516                 return _("Game over!");
 517
 518         if ( turnflags & SNAKE_TURN_WAIT )
 519                 return _("Press an arrow key to begin the game");
 520
 521         if ( turnflags & SNAKE_TURN_MOVE )
 522                 return _("Avoid the walls and the snake's body, collect the mice!");
 523
 524         return "";
 525 }
 526
 527 // Make the correct move
 528 void snake_set_direction(entity minigame, int dx, int dy)
 529 {
 530         //if ( minigame.minigame_flags == SNAKE_TURN_MOVE )
 531         //{
 532                 minigame_cmd("move ",ftos(dx), " ", ftos(dy));
 533         //}
 534 }
 535
 536 // Required function, handle client events
 537 int snake_client_event(entity minigame, string event, ...)
 538 {
 539         switch(event)
 540         {
 541                 case "activate":
 542                 {
 543                         minigame.message = snake_turn_to_string(minigame.minigame_flags);
 544                         return false;
 545                 }
 546                 case "key_pressed":
 547                 {
 548                         //if((minigame.minigame_flags & SNAKE_TURN_TEAM) == minigame_self.team)
 549                         {
 550                                 switch ( ...(0,int) )
 551                                 {
 552                                         case K_RIGHTARROW:
 553                                         case K_KP_RIGHTARROW:
 554                                                 snake_set_direction(minigame, 1, 0);
 555                                                 return true;
 556                                         case K_LEFTARROW:
 557                                         case K_KP_LEFTARROW:
 558                                                 snake_set_direction(minigame, -1, 0);
 559                                                 return true;
 560                                         case K_UPARROW:
 561                                         case K_KP_UPARROW:
 562                                                 snake_set_direction(minigame, 0, 1);
 563                                                 return true;
 564                                         case K_DOWNARROW:
 565                                         case K_KP_DOWNARROW:
 566                                                 snake_set_direction(minigame, 0, -1);
 567                                                 return true;
 568                                 }
 569                         }
 570
 571                         return false;
 572                 }
 573                 case "network_receive":
 574                 {
 575                         entity sent = ...(0,entity);
 576                         int sf = ...(1,int);
 577                         if ( sent.classname == "minigame" )
 578                         {
 579                                 if ( sf & MINIG_SF_UPDATE )
 580                                 {
 581                                         sent.message = snake_turn_to_string(sent.minigame_flags);
 582                                         //if ( sent.minigame_flags & minigame_self.team )
 583                                                 minigame_prompt();
 584                                 }
 585                         }
 586                         else if(sent.classname == "minigame_board_piece")
 587                         {
 588                                 if(sf & MINIG_SF_UPDATE)
 589                                 {
 590                                         sent.cnt = ReadByte();
 591                                         sent.snake_dir_x = ReadCoord();
 592                                         sent.snake_dir_y = ReadCoord();
 593                                         sent.snake_dir_z = 0;
 594                                         if(sent.cnt == 1)
 595                                                 minigame.snake_head = sent; // hax
 596                                 }
 597                         }
 598                         else if ( sent.classname == "minigame_player" && (sf & SNAKE_SF_PLAYERSCORE ) )
 599                         {
 600                                 sent.snake_score = ReadLong();
 601                         }
 602
 603                         return false;
 604                 }
 605         }
 606
 607         return false;
 608 }
 609
 610 #endif