qcsrc/common/monsters/lib/monsters.qc

   1 // TODO: clean up this file?
   2
   3 void() spawnfunc_item_minst_cells;
   4
   5 void M_Item_Touch ()
   6 {
   7         if(self && IS_PLAYER(other) && other.deadflag == DEAD_NO)
   8         {
   9                 Item_Touch();
  10                 self.think = SUB_Remove;
  11                 self.nextthink = time + 0.1;
  12         }
  13 }
  14
  15 void monster_item_spawn()
  16 {
  17         if(self.monster_loot)
  18                 self.monster_loot();
  19
  20         self.gravity = 1;
  21         self.velocity = randomvec() * 175 + '0 0 325';
  22         self.touch = M_Item_Touch;
  23
  24         SUB_SetFade(self, time + autocvar_g_monsters_drop_time, 1);
  25 }
  26
  27 void Monster_DropItem (string itype, string itemsize)
  28 {
  29         vector org = self.origin + ((self.mins + self.maxs) * 0.5);
  30         entity e = spawn();
  31
  32         setorigin(e, org);
  33
  34         switch(itype)
  35         {
  36                 case "armor":
  37                 {
  38                         switch(itemsize)
  39                         {
  40                                 case "mega": e.monster_loot = spawnfunc_item_armor_large; break;
  41                                 case "large": e.monster_loot = spawnfunc_item_armor_big; break;
  42                                 case "medium": e.monster_loot = spawnfunc_item_armor_medium; break;
  43                                 case "small": e.monster_loot = spawnfunc_item_armor_small; break;
  44                         }
  45                         break;
  46                 }
  47                 case "health":
  48                 {
  49                         switch(itemsize)
  50                         {
  51                                 case "mega": e.monster_loot = spawnfunc_item_health_mega; break;
  52                                 case "large": e.monster_loot = spawnfunc_item_health_large; break;
  53                                 case "medium": e.monster_loot = spawnfunc_item_health_medium; break;
  54                                 case "small": e.monster_loot = spawnfunc_item_health_small; break;
  55                         }
  56                         break;
  57                 }
  58                 case "ammo":
  59                 {
  60                         switch(itemsize)
  61                         {
  62                                 case "shells": e.monster_loot = spawnfunc_item_shells; break;
  63                                 case "cells": e.monster_loot = spawnfunc_item_cells; break;
  64                                 case "rockets": e.monster_loot = spawnfunc_item_rockets; break;
  65                                 case "bullets":
  66                                 case "nails": e.monster_loot = spawnfunc_item_bullets; break;
  67                         }
  68                         break;
  69                 }
  70         }
  71
  72         other = e;
  73         MUTATOR_CALLHOOK(MonsterDropItem);
  74         e = other;
  75
  76         e.think = monster_item_spawn;
  77         e.nextthink = time + 0.1;
  78 }
  79
  80 void monsters_setframe(float _frame)
  81 {
  82         if(self.frame == _frame)
  83                 return;
  84
  85         self.anim_start_time = time;
  86         self.frame = _frame;
  87         self.SendFlags |= MSF_ANIM;
  88 }
  89
  90 float monster_isvalidtarget (entity targ, entity ent)
  91 {
  92         if(!targ || !ent)
  93                 return FALSE; // someone doesn't exist
  94
  95         if(time < game_starttime)
  96                 return FALSE; // monsters do nothing before the match has started
  97
  98         WarpZone_TraceLine(ent.origin, targ.origin, MOVE_NORMAL, ent);
  99
 100         if(vlen(targ.origin - ent.origin) >= ent.target_range)
 101                 return FALSE; // enemy is too far away
 102
 103         if not(targ.vehicle_flags & VHF_ISVEHICLE)
 104         if(trace_ent != targ)
 105                 return FALSE; // we can't see the enemy
 106
 107         if(targ.takedamage == DAMAGE_NO)
 108                 return FALSE; // enemy can't be damaged
 109
 110         if(targ.items & IT_INVISIBILITY)
 111                 return FALSE; // enemy is invisible
 112
 113         if(substring(targ.classname, 0, 10) == "onslaught_")
 114                 return FALSE; // don't attack onslaught targets
 115
 116         if(IS_SPEC(targ) || IS_OBSERVER(targ))
 117                 return FALSE; // enemy is a spectator
 118
 119         if not(targ.vehicle_flags & VHF_ISVEHICLE) // vehicles dont count as alive?
 120         if(targ.deadflag != DEAD_NO || ent.deadflag != DEAD_NO || targ.health <= 0 || ent.health <= 0)
 121                 return FALSE; // enemy/self is dead
 122
 123         if(targ.monster_owner == ent || ent.monster_owner == targ)
 124                 return FALSE; // enemy owns us, or we own them
 125
 126         if not(targ.vehicle_flags & VHF_ISVEHICLE)
 127         if(targ.flags & FL_NOTARGET)
 128                 return FALSE; // enemy can't be targeted
 129
 130         if not(autocvar_g_monsters_typefrag)
 131         if(targ.BUTTON_CHAT)
 132                 return FALSE; // no typefragging!
 133
 134         if not(IsDifferentTeam(targ, ent))
 135                 return FALSE; // enemy is on our team
 136
 137         if(autocvar_g_monsters_target_infront)
 138         if(ent.enemy != targ)
 139         {
 140                 float dot;
 141
 142                 makevectors (ent.angles);
 143                 dot = normalize (targ.origin - ent.origin) * v_forward;
 144
 145                 if(dot <= 0.3)
 146                         return FALSE;
 147         }
 148
 149         return TRUE;
 150 }
 151
 152 entity FindTarget (entity ent)
 153 {
 154         if(MUTATOR_CALLHOOK(MonsterFindTarget)) { return ent.enemy; } // Handled by a mutator
 155         entity e;
 156
 157         for(e = world; (e = findflags(e, monster_attack, TRUE)); )
 158         if(monster_isvalidtarget(e, ent))
 159                 return e;
 160
 161         return world;
 162 }
 163
 164 void MonsterTouch ()
 165 {
 166         if(other == world)
 167                 return;
 168
 169         if(self.enemy != other)
 170         if not(other.flags & FL_MONSTER)
 171         if(monster_isvalidtarget(other, self))
 172                 self.enemy = other;
 173 }
 174
 175 void monster_sound(string msound, float sound_delay, float delaytoo)
 176 {
 177         if(delaytoo && time < self.msound_delay)
 178                 return; // too early
 179
 180         if(msound == "")
 181                 return; // sound doesn't exist
 182
 183         sound(self, CHAN_AUTO, msound, VOL_BASE, ATTN_NORM);
 184
 185         self.msound_delay = time + sound_delay;
 186 }
 187
 188 void monster_precachesounds(entity e)
 189 {
 190         precache_sound(e.msound_idle);
 191         precache_sound(e.msound_death);
 192         precache_sound(e.msound_attack_melee);
 193         precache_sound(e.msound_attack_ranged);
 194         precache_sound(e.msound_sight);
 195         precache_sound(e.msound_pain);
 196 }
 197
 198 void monster_setupsounds(string mon)
 199 {
 200         if(self.msound_idle == "") self.msound_idle = strzone(strcat("monsters/", mon, "_idle.wav"));
 201         if(self.msound_death == "") self.msound_death = strzone(strcat("monsters/", mon, "_death.wav"));
 202         if(self.msound_pain == "") self.msound_pain = strzone(strcat("monsters/", mon, "_pain.wav"));
 203         if(self.msound_attack_melee == "") self.msound_attack_melee = strzone(strcat("monsters/", mon, "_melee.wav"));
 204         if(self.msound_attack_ranged == "") self.msound_attack_ranged = strzone(strcat("monsters/", mon, "_attack.wav"));
 205         if(self.msound_sight == "") self.msound_sight = strzone(strcat("monsters/", mon, "_sight.wav"));
 206 }
 207
 208 float monster_melee (entity targ, float damg, float er, float deathtype, float dostop)
 209 {
 210         float dot, rdmg = damg * random();
 211
 212         if (self.health <= 0)
 213                 return FALSE;
 214         if (targ == world)
 215                 return FALSE;
 216
 217         if(dostop)
 218         {
 219                 self.velocity_x = 0;
 220                 self.velocity_y = 0;
 221                 self.state = MONSTER_STATE_ATTACK_MELEE;
 222                 self.SendFlags |= MSF_MOVE;
 223         }
 224
 225         makevectors (self.angles);
 226         dot = normalize (targ.origin - self.origin) * v_forward;
 227
 228         if(dot > er)
 229                 Damage(targ, self, self, rdmg * monster_skill, deathtype, targ.origin, normalize(targ.origin - self.origin));
 230
 231         return TRUE;
 232 }
 233
 234 void Monster_CheckDropCvars (string mon)
 235 {
 236         if not(self.candrop)
 237                 return; // forced off
 238
 239         string dropitem;
 240         string dropsize;
 241
 242         dropitem = cvar_string(strcat("g_monster_", mon, "_drop"));
 243         dropsize = cvar_string(strcat("g_monster_", mon, "_drop_size"));
 244
 245         if(autocvar_g_monsters_forcedrop)
 246                 Monster_DropItem(autocvar_g_monsters_drop_type, autocvar_g_monsters_drop_size);
 247         else if(dropitem != "")
 248                 Monster_DropItem(dropitem, dropsize);
 249         else
 250                 Monster_DropItem("armor", "medium");
 251 }
 252
 253 void Monster_CheckMinibossFlag ()
 254 {
 255         if(MUTATOR_CALLHOOK(MonsterCheckBossFlag))
 256                 return;
 257
 258         float chance = random() * 100;
 259
 260         // g_monsters_miniboss_chance cvar or spawnflags 64 causes a monster to be a miniboss
 261         if ((self.spawnflags & MONSTERFLAG_MINIBOSS) || (chance < autocvar_g_monsters_miniboss_chance))
 262         {
 263                 self.health += autocvar_g_monsters_miniboss_healthboost;
 264                 self.flags |= MONSTERFLAG_MINIBOSS;
 265                 if not(self.weapon)
 266                         self.weapon = WEP_NEX;
 267         }
 268 }
 269
 270 float Monster_CanRespawn(entity ent)
 271 {
 272         other = ent;
 273         if(MUTATOR_CALLHOOK(MonsterRespawn))
 274                 return TRUE; // enabled by a mutator
 275
 276         if(ent.spawnflags & MONSTERFLAG_NORESPAWN)
 277                 return FALSE;
 278
 279         if not(autocvar_g_monsters_respawn)
 280                 return FALSE;
 281
 282         return TRUE;
 283 }
 284
 285 void Monster_Fade ()
 286 {
 287         if(Monster_CanRespawn(self))
 288         {
 289                 self.monster_respawned = TRUE;
 290                 self.think = self.monster_spawnfunc;
 291                 self.nextthink = time + self.respawntime;
 292                 self.deadflag = DEAD_RESPAWNING;
 293                 if(self.spawnflags & MONSTER_RESPAWN_DEATHPOINT)
 294                 {
 295                         self.pos1 = self.origin;
 296                         self.pos2 = self.angles;
 297                 }
 298                 self.event_damage = func_null;
 299                 self.takedamage = DAMAGE_NO;
 300                 setorigin(self, self.pos1);
 301                 self.angles = self.pos2;
 302                 self.health = self.max_health; // TODO: check if resetting to max_health is wise here
 303
 304                 self.SendFlags |= MSF_MOVE;
 305                 self.SendFlags |= MSF_STATUS;
 306
 307                 return;
 308         }
 309         SUB_SetFade(self, time + 3, 1);
 310 }
 311
 312 float Monster_CanJump (vector vel)
 313 {
 314         if(self.state)
 315                 return FALSE; // already attacking
 316         if not(self.flags & FL_ONGROUND)
 317                 return FALSE; // not on the ground
 318         if(self.health <= 0)
 319                 return FALSE; // called when dead?
 320         if(time < self.attack_finished_single)
 321                 return FALSE; // still attacking
 322
 323         vector old = self.velocity;
 324
 325         self.velocity = vel;
 326         tracetoss(self, self);
 327         self.velocity = old;
 328         if (trace_ent != self.enemy)
 329                 return FALSE;
 330
 331         return TRUE;
 332 }
 333
 334 float monster_leap (float anm, void() touchfunc, vector vel, float anim_finished)
 335 {
 336         if(!Monster_CanJump(vel))
 337                 return FALSE;
 338
 339         monsters_setframe(anm);
 340         self.state = MONSTER_STATE_ATTACK_LEAP;
 341         self.touch = touchfunc;
 342         self.origin_z += 1;
 343         self.velocity = vel;
 344         self.flags &~= FL_ONGROUND;
 345
 346         self.attack_finished_single = time + anim_finished;
 347
 348         return TRUE;
 349 }
 350
 351 void monster_checkattack(entity e, entity targ)
 352 {
 353         if(e == world)
 354                 return;
 355         if(targ == world)
 356                 return;
 357
 358         if not(e.monster_attackfunc)
 359                 return;
 360
 361         if(time < e.attack_finished_single)
 362                 return;
 363
 364         if(vlen(targ.origin - e.origin) <= e.attack_range)
 365         if(e.monster_attackfunc(MONSTER_ATTACK_MELEE))
 366         {
 367                 monster_sound(e.msound_attack_melee, 0, FALSE);
 368                 return;
 369         }
 370
 371         if(e.monster_attackfunc(MONSTER_ATTACK_RANGED))
 372         {
 373                 monster_sound(e.msound_attack_ranged, 0, FALSE);
 374                 return;
 375         }
 376 }
 377
 378 void monster_makevectors(entity e)
 379 {
 380         vector v;
 381
 382         v = CENTER_OR_VIEWOFS(e);
 383         self.v_angle = vectoangles(v - (self.origin + self.view_ofs));
 384         self.v_angle_x = -self.v_angle_x;
 385
 386         makevectors(self.v_angle);
 387 }
 388
 389 void monster_use ()
 390 {
 391         if (self.enemy)
 392                 return;
 393         if (self.health <= 0)
 394                 return;
 395
 396         if(!monster_isvalidtarget(activator, self))
 397                 return;
 398
 399         self.enemy = activator;
 400 }
 401
 402 float trace_path(vector from, vector to)
 403 {
 404         vector dir = normalize(to - from) * 15, offset = '0 0 0';
 405         float trace1 = trace_fraction;
 406
 407         offset_x = dir_y;
 408         offset_y = -dir_x;
 409         traceline (from+offset, to+offset, TRUE, self);
 410
 411         traceline(from-offset, to-offset, TRUE, self);
 412
 413         return ((trace1 < trace_fraction) ? trace1 : trace_fraction);
 414 }
 415
 416 .float last_trace;
 417 .float last_enemycheck; // for checking enemy
 418 vector monster_pickmovetarget(entity targ)
 419 {
 420         // enemy is always preferred target
 421         if(self.enemy)
 422         {
 423                 self.monster_movestate = MONSTER_MOVE_ENEMY;
 424                 self.last_trace = time + 1.2;
 425                 return self.enemy.origin;
 426         }
 427
 428         switch(self.monster_moveflags)
 429         {
 430                 case MONSTER_MOVE_OWNER:
 431                 {
 432                         self.monster_movestate = MONSTER_MOVE_OWNER;
 433                         self.last_trace = time + 0.3;
 434                         if(self.monster_owner && self.monster_owner.classname != "td_spawnpoint")
 435                                 return self.monster_owner.origin;
 436                 }
 437                 case MONSTER_MOVE_SPAWNLOC:
 438                 {
 439                         self.monster_movestate = MONSTER_MOVE_SPAWNLOC;
 440                         self.last_trace = time + 2;
 441                         return self.pos1;
 442                 }
 443                 case MONSTER_MOVE_NOMOVE:
 444                 {
 445                         self.monster_movestate = MONSTER_MOVE_NOMOVE;
 446                         self.last_trace = time + 2;
 447                         return self.origin;
 448                 }
 449                 default:
 450                 case MONSTER_MOVE_WANDER:
 451                 {
 452                         vector pos;
 453                         self.monster_movestate = MONSTER_MOVE_WANDER;
 454                         self.last_trace = time + 2;
 455
 456                         self.angles_y = random() * 500;
 457                         makevectors(self.angles);
 458                         pos = self.origin + v_forward * 600;
 459
 460                         if(self.flags & FL_FLY || self.flags & FL_SWIM)
 461                         {
 462                                 pos_z = random() * 200;
 463                                 if(random() >= 0.5)
 464                                         pos_z *= -1;
 465                         }
 466
 467                         if(targ)
 468                         {
 469                                 self.last_trace = time + 0.5;
 470                                 pos = targ.origin;
 471                         }
 472
 473                         return pos;
 474                 }
 475         }
 476 }
 477
 478 void monster_move(float runspeed, float walkspeed, float stopspeed, float manim_run, float manim_walk, float manim_idle)
 479 {
 480         fixedmakevectors(self.angles);
 481
 482         if(self.target2)
 483                 self.goalentity = find(world, targetname, self.target2);
 484
 485         entity targ;
 486
 487         if(self.frozen)
 488         {
 489                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
 490                 self.health = max(1, self.max_health * self.revive_progress);
 491
 492                 if(self.sprite) WaypointSprite_UpdateHealth(self.sprite, self.health);
 493
 494                 movelib_beak_simple(stopspeed);
 495
 496                 self.velocity = '0 0 0';
 497                 self.enemy = world;
 498                 self.nextthink = time + 0.1;
 499
 500                 if(self.revive_progress >= 1)
 501                         Unfreeze(self); // wait for next think before attacking
 502
 503                 // don't bother updating angles here?
 504                 if(self.origin != self.oldorigin)
 505                 {
 506                         self.oldorigin = self.origin;
 507                         self.SendFlags |= MSF_MOVE;
 508                 }
 509
 510                 return; // no moving while frozen
 511         }
 512
 513         if(self.flags & FL_SWIM)
 514         {
 515                 if(self.waterlevel < WATERLEVEL_WETFEET)
 516                 {
 517                         if(time >= self.last_trace)
 518                         {
 519                                 self.last_trace = time + 0.4;
 520
 521                                 Damage (self, world, world, 2, DEATH_DROWN, self.origin, '0 0 0');
 522                                 self.angles = '90 90 0';
 523                                 if(random() < 0.5)
 524                                 {
 525                                         self.velocity_y += random() * 50;
 526                                         self.velocity_x -= random() * 50;
 527                                 }
 528                                 else
 529                                 {
 530                                         self.velocity_y -= random() * 50;
 531                                         self.velocity_x += random() * 50;
 532                                 }
 533                                 self.velocity_z += random() * 150;
 534                         }
 535
 536
 537                         self.movetype = MOVETYPE_BOUNCE;
 538                         //self.velocity_z = -200;
 539
 540                         self.SendFlags |= MSF_MOVE | MSF_ANG;
 541
 542                         return;
 543                 }
 544                 else
 545                 {
 546                         self.angles = '0 0 0';
 547                         self.movetype = MOVETYPE_WALK;
 548                 }
 549         }
 550
 551         targ = self.goalentity;
 552
 553         monster_target = targ;
 554         monster_speed_run = runspeed;
 555         monster_speed_walk = walkspeed;
 556
 557         if(MUTATOR_CALLHOOK(MonsterMove) || gameover || (round_handler_IsActive() && !round_handler_IsRoundStarted()) || time < game_starttime || (autocvar_g_campaign && !campaign_bots_may_start) || time < self.spawn_time)
 558         {
 559                 runspeed = walkspeed = 0;
 560                 if(time >= self.spawn_time)
 561                         monsters_setframe(manim_idle);
 562                 movelib_beak_simple(stopspeed);
 563                 self.SendFlags |= MSF_MOVE;
 564                 return;
 565         }
 566
 567         targ = monster_target;
 568         runspeed = monster_speed_run;
 569         walkspeed = monster_speed_walk;
 570
 571         if(IsDifferentTeam(self.monster_owner, self))
 572                 self.monster_owner = world;
 573
 574         if(time >= self.last_enemycheck)
 575         {
 576                 if not(monster_isvalidtarget(self.enemy, self))
 577                         self.enemy = world;
 578                 self.last_enemycheck = time + 2;
 579         }
 580
 581         if(self.enemy && self.enemy.health < 1)
 582                 self.enemy = world; // enough!
 583
 584         if not(self.enemy)
 585         {
 586                 self.enemy = FindTarget(self);
 587                 if(self.enemy)
 588                         monster_sound(self.msound_sight, 0, FALSE);
 589         }
 590
 591         if(self.state == MONSTER_STATE_ATTACK_MELEE && time >= self.attack_finished_single)
 592                 self.state = 0;
 593
 594         if(self.state != MONSTER_STATE_ATTACK_MELEE) // don't move if set
 595         if(time >= self.last_trace || self.enemy) // update enemy instantly
 596                 self.moveto = monster_pickmovetarget(targ);
 597
 598         if not(self.enemy)
 599                 monster_sound(self.msound_idle, 5, TRUE);
 600
 601         if(self.state != MONSTER_STATE_ATTACK_LEAP && self.state != MONSTER_STATE_ATTACK_MELEE)
 602                 self.steerto = steerlib_attract2(self.moveto, 0.5, 500, 0.95);
 603
 604         if(self.state == MONSTER_STATE_ATTACK_LEAP && (self.flags & FL_ONGROUND))
 605         {
 606                 self.state = 0;
 607                 self.touch = MonsterTouch;
 608         }
 609
 610         //self.steerto = steerlib_attract2(self.moveto, 0.5, 500, 0.95);
 611
 612         float turny = 0;
 613         vector real_angle = vectoangles(self.steerto) - self.angles;
 614
 615         if(self.state != MONSTER_STATE_ATTACK_LEAP && self.state != MONSTER_STATE_ATTACK_MELEE)
 616                 turny = 20;
 617
 618         if(self.flags & FL_SWIM)
 619                 turny = vlen(self.angles - self.moveto);
 620
 621         if(turny)
 622         {
 623                 turny = bound(turny * -1, shortangle_f(real_angle_y, self.angles_y), turny);
 624                 self.angles_y += turny;
 625         }
 626
 627         if(self.state == MONSTER_STATE_ATTACK_MELEE)
 628                 self.moveto = self.origin;
 629         else if(self.enemy)
 630                 self.moveto = self.moveto * 0.9 + ((self.origin + v_forward * 500) + randomvec() * 400) * 0.1;
 631
 632         if not(self.flags & FL_FLY || self.flags & FL_SWIM)
 633                 self.moveto_z = self.origin_z;
 634
 635         float l = vlen(self.moveto - self.origin);
 636         float t1 = trace_path(self.origin+'0 0 10', self.moveto+'0 0 10');
 637         float t2 = trace_path(self.origin-'0 0 15', self.moveto-'0 0 15');
 638
 639         if(self.flags & FL_FLY || self.flags & FL_SWIM)
 640                 v_forward = normalize(self.moveto - self.origin);
 641
 642         if(t1*l-t2*l>50 && (t1*l > 100 || t1 > 0.8))
 643         if(self.flags & FL_ONGROUND)
 644                 movelib_jump_simple(100);
 645
 646         if(vlen(self.origin - self.moveto) > 64)
 647         {
 648                 if(self.flags & FL_FLY || self.flags & FL_SWIM)
 649                         movelib_move_simple(v_forward, ((self.enemy) ? runspeed : walkspeed), 0.6);
 650                 else
 651                         movelib_move_simple_gravity(v_forward, ((self.enemy) ? runspeed : walkspeed), 0.6);
 652                 if(time > self.pain_finished)
 653                 if(time > self.attack_finished_single)
 654                 if(vlen(self.velocity) > 0)
 655                         monsters_setframe((self.enemy) ? manim_run : manim_walk);
 656                 else
 657                         monsters_setframe(manim_idle);
 658         }
 659         else
 660         {
 661                 entity e = find(world, targetname, self.target2);
 662                 if(e.target2)
 663                         self.target2 = e.target2;
 664                 else if(e.target)
 665                         self.target2 = e.target;
 666
 667                 movelib_beak_simple(stopspeed);
 668                 if(time > self.attack_finished_single)
 669                 if(time > self.pain_finished)
 670                 if (vlen(self.velocity) <= 30)
 671                         monsters_setframe(manim_idle);
 672         }
 673
 674         monster_checkattack(self, self.enemy);
 675
 676         if(self.angles != self.oldangles)
 677         {
 678                 self.oldangles = self.angles;
 679                 self.SendFlags |= MSF_ANG;
 680         }
 681
 682         if(self.origin != self.oldorigin)
 683         {
 684                 self.oldorigin = self.origin;
 685                 self.SendFlags |= MSF_MOVE;
 686         }
 687 }
 688
 689 void monster_dead_think()
 690 {
 691         self.think = monster_dead_think;
 692         self.nextthink = time + 0.3; // don't need to update so often now
 693
 694         self.deadflag = DEAD_DEAD;
 695
 696         if(time >= self.ltime)
 697         {
 698                 Monster_Fade();
 699                 return;
 700         }
 701
 702         self.SendFlags |= MSF_MOVE; // keep up to date on the monster's location
 703 }
 704
 705 void monsters_setstatus()
 706 {
 707         self.stat_monsters_total = monsters_total;
 708         self.stat_monsters_killed = monsters_killed;
 709 }
 710
 711 void Monster_Appear()
 712 {
 713         self.enemy = activator;
 714         self.spawnflags &~= MONSTERFLAG_APPEAR;
 715         self.monster_spawnfunc();
 716 }
 717
 718 float Monster_CheckAppearFlags(entity ent)
 719 {
 720         if not(ent.spawnflags & MONSTERFLAG_APPEAR)
 721                 return FALSE;
 722
 723         ent.think = func_null;
 724         ent.nextthink = 0;
 725         ent.use = Monster_Appear;
 726         ent.flags = FL_MONSTER; // set so this monster can get butchered
 727
 728         return TRUE;
 729 }
 730
 731 void monsters_reset()
 732 {
 733         setorigin(self, self.pos1);
 734         self.angles = self.pos2;
 735
 736         self.health = self.max_health;
 737         self.velocity = '0 0 0';
 738         self.enemy = world;
 739         self.goalentity = world;
 740         self.attack_finished_single = 0;
 741         self.moveto = self.origin;
 742
 743         WaypointSprite_UpdateHealth(self.sprite, self.health);
 744 }
 745
 746 float monster_send(entity to, float sf)
 747 {
 748         WriteByte(MSG_ENTITY, ENT_CLIENT_MONSTER);
 749         WriteByte(MSG_ENTITY, sf);
 750         if(sf & MSF_SETUP)
 751         {
 752             WriteByte(MSG_ENTITY, self.monsterid);
 753
 754             WriteCoord(MSG_ENTITY, self.origin_x);
 755             WriteCoord(MSG_ENTITY, self.origin_y);
 756             WriteCoord(MSG_ENTITY, self.origin_z);
 757
 758             WriteAngle(MSG_ENTITY, self.angles_x);
 759             WriteAngle(MSG_ENTITY, self.angles_y);
 760
 761                 WriteByte(MSG_ENTITY, self.skin);
 762                 WriteByte(MSG_ENTITY, self.team);
 763     }
 764
 765     if(sf & MSF_ANG)
 766     {
 767         WriteShort(MSG_ENTITY, rint(self.angles_x));
 768         WriteShort(MSG_ENTITY, rint(self.angles_y));
 769     }
 770
 771     if(sf & MSF_MOVE)
 772     {
 773         WriteShort(MSG_ENTITY, rint(self.origin_x));
 774         WriteShort(MSG_ENTITY, rint(self.origin_y));
 775         WriteShort(MSG_ENTITY, rint(self.origin_z));
 776
 777         WriteShort(MSG_ENTITY, rint(self.velocity_x));
 778         WriteShort(MSG_ENTITY, rint(self.velocity_y));
 779         WriteShort(MSG_ENTITY, rint(self.velocity_z));
 780
 781         WriteShort(MSG_ENTITY, rint(self.angles_y));
 782     }
 783
 784     if(sf & MSF_ANIM)
 785     {
 786         WriteCoord(MSG_ENTITY, self.anim_start_time);
 787         WriteByte(MSG_ENTITY, self.frame);
 788     }
 789
 790     if(sf & MSF_STATUS)
 791     {
 792                 WriteByte(MSG_ENTITY, self.skin);
 793
 794         WriteByte(MSG_ENTITY, self.team);
 795
 796                 WriteByte(MSG_ENTITY, self.deadflag);
 797
 798         if(self.health <= 0)
 799             WriteByte(MSG_ENTITY, 0);
 800         else
 801             WriteByte(MSG_ENTITY, ceil((self.health / self.max_health) * 255));
 802     }
 803
 804         return TRUE;
 805 }
 806
 807 void monster_link(void() spawnproc)
 808 {
 809     Net_LinkEntity(self, TRUE, 0, monster_send);
 810     self.think      = spawnproc;
 811     self.nextthink  = time;
 812 }
 813
 814 void monsters_corpse_damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 815 {
 816         self.health -= damage;
 817
 818         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 819
 820         if(self.health <= -100) // 100 health until gone?
 821         {
 822                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 823
 824                 self.think = SUB_Remove;
 825                 self.nextthink = time + 0.1;
 826         }
 827 }
 828
 829 void monster_die()
 830 {
 831         self.think = monster_dead_think;
 832         self.nextthink = self.ticrate;
 833         self.ltime = time + 5;
 834
 835         Monster_CheckDropCvars(self.netname);
 836
 837         WaypointSprite_Kill(self.sprite);
 838
 839         if(self.weaponentity)
 840         {
 841                 remove(self.weaponentity);
 842                 self.weaponentity = world;
 843         }
 844
 845         monster_sound(self.msound_death, 0, FALSE);
 846
 847         if(!(self.spawnflags & MONSTERFLAG_SPAWNED) && !self.monster_respawned)
 848                 monsters_killed += 1;
 849
 850         if(self.candrop && self.weapon)
 851                 W_ThrowNewWeapon(self, self.weapon, 0, self.origin, randomvec() * 150 + '0 0 325');
 852
 853         if(IS_CLIENT(self.realowner))
 854                 self.realowner.monstercount -= 1;
 855
 856         self.event_damage       = monsters_corpse_damage;
 857         self.solid                      = SOLID_CORPSE;
 858         self.takedamage         = DAMAGE_AIM;
 859         self.enemy                      = world;
 860         self.movetype           = MOVETYPE_TOSS;
 861         self.moveto                     = self.origin;
 862         self.touch                      = MonsterTouch; // reset incase monster was pouncing
 863
 864         if not(self.flags & FL_FLY)
 865                 self.velocity = '0 0 0';
 866
 867         self.SendFlags |= MSF_MOVE;
 868
 869         totalspawned -= 1;
 870
 871         MON_ACTION(self.monsterid, MR_DEATH);
 872 }
 873
 874 void monsters_damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 875 {
 876         if(self.frozen && deathtype != DEATH_KILL)
 877                 return;
 878
 879         if(time < self.pain_finished && deathtype != DEATH_KILL)
 880                 return;
 881
 882         if(time < self.spawnshieldtime)
 883                 return;
 884
 885         if(deathtype != DEATH_KILL)
 886                 damage *= self.armorvalue;
 887
 888         if(self.weaponentity && self.weaponentity.classname == "shield")
 889                 self.weaponentity.health -= damage;
 890
 891         self.health -= damage;
 892
 893         if(self.sprite)
 894                 WaypointSprite_UpdateHealth(self.sprite, self.health);
 895
 896         self.dmg_time = time;
 897
 898         if(sound_allowed(MSG_BROADCAST, attacker) && deathtype != DEATH_DROWN)
 899                 spamsound (self, CH_PAIN, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);  // FIXME: PLACEHOLDER
 900
 901         self.velocity += force * self.damageforcescale;
 902
 903         if(deathtype != DEATH_DROWN)
 904         {
 905                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 906                 if (damage > 50)
 907                         Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 908                 if (damage > 100)
 909                         Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 910         }
 911
 912         if(self.health <= 0)
 913         {
 914                 if(self.sprite)
 915                 {
 916                         // Update one more time to avoid waypoint fading without emptying healthbar
 917                         WaypointSprite_UpdateHealth(self.sprite, 0);
 918                 }
 919
 920                 if(deathtype == DEATH_KILL)
 921                         self.candrop = FALSE; // killed by mobkill command
 922
 923                 // TODO: fix this?
 924                 activator = attacker;
 925                 other = self.enemy;
 926                 SUB_UseTargets();
 927                 self.target2 = self.oldtarget2; // reset to original target on death, incase we respawn
 928
 929                 monster_die();
 930
 931                 frag_attacker = attacker;
 932                 frag_target = self;
 933                 MUTATOR_CALLHOOK(MonsterDies);
 934
 935                 if(self.health <= -100) // check if we're already gibbed
 936                 {
 937                         Violence_GibSplash(self, 1, 0.5, attacker);
 938
 939                         self.think = SUB_Remove;
 940                         self.nextthink = time + 0.1;
 941                 }
 942         }
 943
 944         self.SendFlags |= MSF_STATUS;
 945 }
 946
 947 void monster_think()
 948 {
 949         self.think = monster_think;
 950         self.nextthink = self.ticrate;
 951
 952         MON_ACTION(self.monsterid, MR_THINK);
 953 }
 954
 955 void monster_spawn()
 956 {
 957         MON_ACTION(self.monsterid, MR_SETUP);
 958
 959         if not(self.monster_respawned)
 960                 Monster_CheckMinibossFlag();
 961
 962         self.max_health = self.health;
 963         self.pain_finished = self.nextthink;
 964         self.anim_start_time = time;
 965
 966         if not(self.noalign)
 967         {
 968                 setorigin(self, self.origin + '0 0 20');
 969                 tracebox(self.origin + '0 0 100', self.mins, self.maxs, self.origin - '0 0 10000', MOVE_WORLDONLY, self);
 970                 setorigin(self, trace_endpos);
 971         }
 972
 973         if not(self.monster_respawned)
 974         if not(self.skin)
 975                 self.skin = rint(random() * 4);
 976
 977         self.pos1 = self.origin;
 978
 979         monster_setupsounds(self.netname);
 980
 981         monster_precachesounds(self);
 982
 983         if(teamplay)
 984                 self.monster_attack = TRUE; // we can have monster enemies in team games
 985
 986         if(autocvar_g_monsters_healthbars)
 987         {
 988                 WaypointSprite_Spawn(strzone(strdecolorize(self.monster_name)), 0, 600, self, '0 0 1' * (self.maxs_z + 15), world, 0, self, sprite, FALSE, RADARICON_DANGER, ((self.team) ? Team_ColorRGB(self.team) : '1 0 0'));
 989                 WaypointSprite_UpdateMaxHealth(self.sprite, self.max_health);
 990                 WaypointSprite_UpdateHealth(self.sprite, self.health);
 991         }
 992
 993         monster_sound(self.msound_spawn, 0, FALSE);
 994
 995         MUTATOR_CALLHOOK(MonsterSpawn);
 996
 997         self.think = monster_think;
 998         self.nextthink = time + self.ticrate;
 999
1000         self.SendFlags = MSF_SETUP;
1001 }
1002
1003 float monster_initialize(float mon_id, float nodrop)
1004 {
1005         if not(autocvar_g_monsters)
1006                 return FALSE;
1007
1008         vector min_s, max_s;
1009         entity mon = get_monsterinfo(mon_id);
1010
1011         // support for quake style removing monsters based on skill
1012         if(monster_skill <= autocvar_g_monsters_skill_easy && (self.spawnflags & MONSTERSKILL_NOTEASY)) { return FALSE; }
1013         if(monster_skill == autocvar_g_monsters_skill_normal && (self.spawnflags & MONSTERSKILL_NOTMEDIUM)) { return FALSE; }
1014         if(monster_skill == autocvar_g_monsters_skill_hard && (self.spawnflags & MONSTERSKILL_NOTHARD)) { return FALSE; }
1015         if(monster_skill == autocvar_g_monsters_skill_insane && (self.spawnflags & MONSTERSKILL_NOTINSANE)) { return FALSE; }
1016         if(monster_skill >= autocvar_g_monsters_skill_nightmare && (self.spawnflags & MONSTERSKILL_NOTNIGHTMARE)) { return FALSE; }
1017
1018         if(self.monster_name == "")
1019                 self.monster_name = M_NAME(mon_id);
1020
1021         if(self.team && !teamplay)
1022                 self.team = 0;
1023
1024         self.flags = FL_MONSTER;
1025
1026         if not(self.spawnflags & MONSTERFLAG_SPAWNED) // naturally spawned monster
1027         if not(self.monster_respawned)
1028                 monsters_total += 1;
1029
1030         min_s = mon.mins;
1031         max_s = mon.maxs;
1032
1033         self.netname = mon.netname;
1034
1035         setsize(self, min_s, max_s);
1036         self.takedamage                 = DAMAGE_AIM;
1037         self.bot_attack                 = TRUE;
1038         self.iscreature                 = TRUE;
1039         self.teleportable               = TRUE;
1040         self.damagedbycontents  = TRUE;
1041         self.monsterid                  = mon_id;
1042         self.damageforcescale   = 0;
1043         self.event_damage               = monsters_damage;
1044         self.touch                              = MonsterTouch;
1045         self.use                                = monster_use;
1046         self.solid                              = SOLID_BBOX;
1047         self.movetype                   = MOVETYPE_WALK;
1048         self.spawnshieldtime    = time + autocvar_g_monsters_spawnshieldtime;
1049         monsters_spawned           += 1;
1050         self.enemy                              = world;
1051         self.velocity                   = '0 0 0';
1052         self.moveto                             = self.origin;
1053         self.pos2                               = self.angles;
1054         self.reset                              = monsters_reset;
1055         self.candrop                    = TRUE;
1056         self.view_ofs                   = '0 0 1' * (self.maxs_z * 0.5);
1057         self.oldtarget2                 = self.target2;
1058         self.deadflag                   = DEAD_NO;
1059         self.noalign                    = nodrop;
1060         self.spawn_time                 = time;
1061         self.gravity                    = 1;
1062         self.dphitcontentsmask  = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_BOTCLIP | DPCONTENTS_MONSTERCLIP;
1063
1064         if(mon.spawnflags & MONSTER_TYPE_SWIM)
1065                 self.flags |= FL_SWIM;
1066
1067         if(mon.spawnflags & MONSTER_TYPE_FLY)
1068         {
1069                 self.flags |= FL_FLY;
1070                 self.movetype = MOVETYPE_FLY;
1071         }
1072
1073         if not(self.scale)
1074                 self.scale = 1;
1075
1076         if(mon.spawnflags & MONSTER_SIZE_BROKEN)
1077                 self.scale = 1.3;
1078
1079         if not(self.attack_range)
1080                 self.attack_range = 120;
1081
1082         if not(self.ticrate)
1083                 self.ticrate = autocvar_g_monsters_think_delay;
1084
1085         self.ticrate = bound(sys_frametime, self.ticrate, 60);
1086
1087         if not(self.armorvalue)
1088                 self.armorvalue = 1; // multiplier
1089
1090         if not(self.target_range)
1091                 self.target_range = autocvar_g_monsters_target_range;
1092
1093         if not(self.respawntime)
1094                 self.respawntime = autocvar_g_monsters_respawn_delay;
1095
1096         if not(self.monster_moveflags)
1097                 self.monster_moveflags = MONSTER_MOVE_WANDER;
1098
1099         monster_link(monster_spawn);
1100
1101         return TRUE;
1102 }