qcsrc/common/monsters/monster/brute.qc

   1 #ifdef REGISTER_MONSTER
   2 REGISTER_MONSTER(
   3 /* MON_##id   */ BRUTE,
   4 /* function   */ m_brute,
   5 /* spawnflags */ 0,
   6 /* mins,maxs  */ '-36 -36 -20', '36 36 50',
   7 /* model      */ "ogre.dpm",
   8 /* netname    */ "brute",
   9 /* fullname   */ _("Brute")
  10 );
  11
  12 #define BRUTE_SETTINGS(monster) \
  13         MON_ADD_CVAR(monster, health) \
  14         MON_ADD_CVAR(monster, attack_chainsaw_damage) \
  15         MON_ADD_CVAR(monster, attack_uzi_bullets) \
  16         MON_ADD_CVAR(monster, attack_uzi_damage) \
  17         MON_ADD_CVAR(monster, attack_uzi_force) \
  18         MON_ADD_CVAR(monster, attack_uzi_chance) \
  19         MON_ADD_CVAR(monster, attack_grenade_damage) \
  20         MON_ADD_CVAR(monster, attack_grenade_edgedamage) \
  21         MON_ADD_CVAR(monster, attack_grenade_force) \
  22         MON_ADD_CVAR(monster, attack_grenade_radius) \
  23         MON_ADD_CVAR(monster, attack_grenade_speed) \
  24         MON_ADD_CVAR(monster, attack_grenade_speed_up) \
  25         MON_ADD_CVAR(monster, speed_stop) \
  26         MON_ADD_CVAR(monster, speed_run) \
  27         MON_ADD_CVAR(monster, speed_walk)
  28
  29 #ifdef SVQC
  30 BRUTE_SETTINGS(brute)
  31 #endif // SVQC
  32 #else
  33 #ifdef SVQC
  34 const float brute_anim_idle             = 0;
  35 const float brute_anim_walk             = 1;
  36 const float brute_anim_run                      = 2;
  37 const float brute_anim_pain             = 3;
  38 const float brute_anim_swing            = 4;
  39 const float brute_anim_die                      = 5;
  40
  41 .float brute_cycles;
  42
  43 void brute_blade()
  44 {
  45         self.brute_cycles += 1;
  46         self.angles_y = self.angles_y + random()* 25;
  47
  48         monster_melee(self.enemy, MON_CVAR(brute, attack_chainsaw_damage), self.attack_range, DEATH_MONSTER_BRUTE_BLADE, TRUE);
  49
  50         if(self.brute_cycles <= 4)
  51                 defer(0.2, brute_blade);
  52 }
  53
  54 void brute_uzi()
  55 {
  56         self.brute_cycles += 1;
  57
  58         monster_makevectors(self.enemy);
  59
  60         sound(self, CH_WEAPON_A, "weapons/uzi_fire.wav", VOL_BASE, ATTN_NORM);
  61         fireBallisticBullet(CENTER_OR_VIEWOFS(self), v_forward, 0.02, 18000, 5, MON_CVAR(brute, attack_uzi_damage), MON_CVAR(brute, attack_uzi_force), DEATH_MONSTER_BRUTE_UZI, 0, 1, 115);
  62         endFireBallisticBullet();
  63
  64         if(self.brute_cycles <= MON_CVAR(brute, attack_uzi_bullets))
  65                 defer(0.1, brute_uzi);
  66 }
  67
  68 void brute_grenade_explode()
  69 {
  70         pointparticles(particleeffectnum("grenade_explode"), self.origin, '0 0 0', 1);
  71         sound(self, CH_SHOTS, "weapons/grenade_impact.wav", VOL_BASE, ATTN_NORM);
  72
  73         self.event_damage = func_null;
  74         self.takedamage = DAMAGE_NO;
  75
  76         if(self.movetype == MOVETYPE_NONE)
  77                 self.velocity = self.oldvelocity;
  78
  79         RadiusDamage (self, self.realowner, MON_CVAR(brute, attack_grenade_damage), MON_CVAR(brute, attack_grenade_edgedamage), MON_CVAR(brute, attack_grenade_radius), world, MON_CVAR(brute, attack_grenade_force), self.projectiledeathtype, other);
  80
  81         remove (self);
  82 }
  83
  84 void brute_grenade_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
  85 {
  86         if (self.health <= 0)
  87                 return;
  88
  89         if (!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, -1)) // no exceptions
  90                 return; // g_projectiles_damage says to halt
  91
  92         self.health = self.health - damage;
  93
  94         if (self.health <= 0)
  95                 W_PrepareExplosionByDamage(attacker, self.use);
  96 }
  97
  98 void brute_grenade_touch()
  99 {
 100         PROJECTILE_TOUCH;
 101
 102         self.use ();
 103 }
 104
 105 void brute_grenade_think()
 106 {
 107         self.nextthink = time;
 108         if (time > self.cnt)
 109         {
 110                 other = world;
 111                 brute_grenade_explode();
 112                 return;
 113         }
 114 }
 115
 116 void brute_grenade()
 117 {
 118         entity gren;
 119
 120         monster_makevectors(self.enemy);
 121
 122         sound(self, CH_WEAPON_A, "weapons/grenade_fire.wav", VOL_BASE, ATTN_NORM);
 123
 124         gren = spawn ();
 125         gren.owner = gren.realowner = self;
 126         gren.classname = "grenade";
 127         gren.bot_dodge = TRUE;
 128         gren.bot_dodgerating = MON_CVAR(brute, attack_grenade_damage);
 129         gren.movetype = MOVETYPE_BOUNCE;
 130         PROJECTILE_MAKETRIGGER(gren);
 131         gren.projectiledeathtype = DEATH_MONSTER_BRUTE_GRENADE;
 132         setorigin(gren, CENTER_OR_VIEWOFS(self));
 133         setsize(gren, '-3 -3 -3', '3 3 3');
 134
 135         gren.cnt = time + 5;
 136         gren.nextthink = time;
 137         gren.think = brute_grenade_think;
 138         gren.use = brute_grenade_explode;
 139         gren.touch = brute_grenade_touch;
 140
 141         gren.takedamage = DAMAGE_YES;
 142         gren.health = 50;
 143         gren.damageforcescale = 0;
 144         gren.event_damage = brute_grenade_damage;
 145         gren.damagedbycontents = TRUE;
 146         gren.missile_flags = MIF_SPLASH | MIF_ARC;
 147         W_SetupProjectileVelocityEx(gren, v_forward, v_up, MON_CVAR(brute, attack_grenade_speed), MON_CVAR(brute, attack_grenade_speed_up), 0, 0, FALSE);
 148
 149         gren.angles = vectoangles (gren.velocity);
 150         gren.flags = FL_PROJECTILE;
 151
 152         CSQCProjectile(gren, TRUE, PROJECTILE_GRENADE, TRUE);
 153 }
 154
 155 float brute_attack(float attack_type)
 156 {
 157         switch(attack_type)
 158         {
 159                 case MONSTER_ATTACK_MELEE:
 160                 {
 161                         self.brute_cycles = 0;
 162                         monsters_setframe(brute_anim_swing);
 163                         self.attack_finished_single = time + 1.3;
 164                         brute_blade();
 165
 166                         return TRUE;
 167                 }
 168                 case MONSTER_ATTACK_RANGED:
 169                 {
 170                         self.brute_cycles = 0;
 171                         if(random() <= MON_CVAR(brute, attack_uzi_chance))
 172                         {
 173                                 monsters_setframe(brute_anim_pain);
 174                                 self.attack_finished_single = time + 0.8;
 175                                 defer(0.1, brute_uzi);
 176                         }
 177                         else
 178                         {
 179                                 monster_makevectors(self.enemy);
 180                                 brute_grenade();
 181                                 monsters_setframe(brute_anim_pain);
 182                                 self.attack_finished_single = time + 1.2;
 183                         }
 184
 185                         return TRUE;
 186                 }
 187         }
 188
 189         return FALSE;
 190 }
 191
 192 void spawnfunc_monster_brute()
 193 {
 194         self.classname = "monster_brute";
 195
 196         self.monster_spawnfunc = spawnfunc_monster_brute;
 197
 198         if(Monster_CheckAppearFlags(self))
 199                 return;
 200
 201         if not(monster_initialize(MON_BRUTE, FALSE)) { remove(self); return; }
 202 }
 203
 204 // compatibility with old spawns
 205 void spawnfunc_monster_ogre() { spawnfunc_monster_brute(); }
 206
 207 float m_brute(float req)
 208 {
 209         switch(req)
 210         {
 211                 case MR_THINK:
 212                 {
 213                         monster_move(MON_CVAR(brute, speed_run), MON_CVAR(brute, speed_walk), MON_CVAR(brute, speed_stop), brute_anim_run, brute_anim_walk, brute_anim_idle);
 214                         return TRUE;
 215                 }
 216                 case MR_DEATH:
 217                 {
 218                         monsters_setframe(brute_anim_die);
 219                         return TRUE;
 220                 }
 221                 case MR_SETUP:
 222                 {
 223                         if not(self.health) self.health = MON_CVAR(brute, health);
 224
 225                         self.monster_loot = spawnfunc_item_bullets;
 226                         self.monster_attackfunc = brute_attack;
 227                         monsters_setframe(brute_anim_idle);
 228                         self.weapon = WEP_GRENADE_LAUNCHER;
 229
 230                         return TRUE;
 231                 }
 232                 case MR_INIT:
 233                 {
 234                         // nothing
 235                         return TRUE;
 236                 }
 237                 case MR_CONFIG:
 238                 {
 239                         MON_CONFIG_SETTINGS(BRUTE_SETTINGS(brute))
 240                         return TRUE;
 241                 }
 242         }
 243
 244         return TRUE;
 245 }
 246
 247 #endif // SVQC
 248 #ifdef CSQC
 249 float m_brute(float req)
 250 {
 251         switch(req)
 252         {
 253                 case MR_DEATH:
 254                 {
 255                         // nothing
 256                         return TRUE;
 257                 }
 258                 case MR_INIT:
 259                 {
 260                         precache_model ("models/monsters/ogre.dpm");
 261                         return TRUE;
 262                 }
 263         }
 264
 265         return TRUE;
 266 }
 267
 268 #endif // CSQC
 269 #endif // REGISTER_MONSTER