qcsrc/common/monsters/monster/brute.qc

   1 #ifdef REGISTER_MONSTER
   2 REGISTER_MONSTER(
   3 /* MON_##id   */ BRUTE,
   4 /* function   */ m_brute,
   5 /* mins,maxs  */ '-36 -36 -20', '36 36 50',
   6 /* model      */ "ogre.dpm",
   7 /* netname    */ "brute",
   8 /* fullname   */ _("Brute")
   9 );
  10
  11 #else
  12 #ifdef SVQC
  13 float autocvar_g_monster_brute;
  14 float autocvar_g_monster_brute_health;
  15 float autocvar_g_monster_brute_chainsaw_damage;
  16 float autocvar_g_monster_brute_speed_walk;
  17 float autocvar_g_monster_brute_speed_run;
  18 float autocvar_g_monster_brute_attack_uzi_bullets;
  19 float autocvar_g_monster_brute_attack_uzi_damage;
  20 float autocvar_g_monster_brute_attack_uzi_force;
  21 float autocvar_g_monster_brute_attack_uzi_chance;
  22 float autocvar_g_monster_brute_attack_grenade_damage;
  23 float autocvar_g_monster_brute_attack_grenade_edgedamage;
  24 float autocvar_g_monster_brute_attack_grenade_force;
  25 float autocvar_g_monster_brute_attack_grenade_radius;
  26
  27 const float brute_anim_idle             = 0;
  28 const float brute_anim_walk             = 1;
  29 const float brute_anim_run                      = 2;
  30 const float brute_anim_pain             = 3;
  31 const float brute_anim_swing            = 4;
  32 const float brute_anim_die                      = 5;
  33
  34 .float brute_cycles;
  35
  36 void brute_blade()
  37 {
  38         self.brute_cycles += 1;
  39         self.angles_y = self.angles_y + random()* 25;
  40
  41         monster_melee(self.enemy, autocvar_g_monster_brute_chainsaw_damage, 0.3, DEATH_MONSTER_BRUTE_BLADE, TRUE);
  42
  43         if(self.brute_cycles <= 4)
  44                 defer(0.2, brute_blade);
  45 }
  46
  47 void brute_uzi()
  48 {
  49         self.brute_cycles += 1;
  50
  51         monster_makevectors(self.enemy);
  52
  53         W_SetupShot (self, autocvar_g_antilag_bullets && 18000 >= autocvar_g_antilag_bullets, 0, "weapons/uzi_fire.wav", CH_WEAPON_A, autocvar_g_monster_brute_attack_uzi_damage);
  54         fireBallisticBullet(w_shotorg, w_shotdir, 0.02, 18000, 5, autocvar_g_monster_brute_attack_uzi_damage, autocvar_g_monster_brute_attack_uzi_force, DEATH_MONSTER_BRUTE_UZI, 0, 1, 115);
  55         endFireBallisticBullet();
  56
  57         if(self.brute_cycles <= autocvar_g_monster_brute_attack_uzi_bullets)
  58                 defer(0.1, brute_uzi);
  59 }
  60
  61 void brute_grenade_explode()
  62 {
  63         pointparticles(particleeffectnum("grenade_explode"), self.origin, '0 0 0', 1);
  64         sound(self, CH_SHOTS, "weapons/grenade_impact.wav", VOL_BASE, ATTN_NORM);
  65
  66         self.event_damage = func_null;
  67         self.takedamage = DAMAGE_NO;
  68
  69         if(self.movetype == MOVETYPE_NONE)
  70                 self.velocity = self.oldvelocity;
  71
  72         RadiusDamage (self, self.realowner, autocvar_g_monster_brute_attack_grenade_damage, autocvar_g_monster_brute_attack_grenade_edgedamage, autocvar_g_monster_brute_attack_grenade_radius, world, autocvar_g_monster_brute_attack_grenade_force, self.projectiledeathtype, other);
  73
  74         remove (self);
  75 }
  76
  77 void brute_grenade_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
  78 {
  79         if (self.health <= 0)
  80                 return;
  81
  82         if (!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, -1)) // no exceptions
  83                 return; // g_projectiles_damage says to halt
  84
  85         self.health = self.health - damage;
  86
  87         if (self.health <= 0)
  88                 W_PrepareExplosionByDamage(attacker, self.use);
  89 }
  90
  91 void brute_grenade_touch()
  92 {
  93         PROJECTILE_TOUCH;
  94
  95         self.use ();
  96 }
  97
  98 void brute_grenade_think()
  99 {
 100         self.nextthink = time;
 101         if (time > self.cnt)
 102         {
 103                 other = world;
 104                 brute_grenade_explode();
 105                 return;
 106         }
 107 }
 108
 109 void brute_grenade()
 110 {
 111         entity gren;
 112
 113         W_SetupShot_ProjectileSize (self, '-3 -3 -3', '3 3 3', FALSE, 4, "weapons/grenade_fire.wav", CH_WEAPON_A, autocvar_g_monster_brute_attack_grenade_damage);
 114         w_shotdir = v_forward; // no TrueAim for grenades please
 115
 116         gren = spawn ();
 117         gren.owner = gren.realowner = self;
 118         gren.classname = "grenade";
 119         gren.bot_dodge = TRUE;
 120         gren.bot_dodgerating = autocvar_g_monster_brute_attack_grenade_damage;
 121         gren.movetype = MOVETYPE_BOUNCE;
 122         PROJECTILE_MAKETRIGGER(gren);
 123         gren.projectiledeathtype = DEATH_MONSTER_BRUTE_GRENADE;
 124         setorigin(gren, w_shotorg);
 125         setsize(gren, '-3 -3 -3', '3 3 3');
 126
 127         gren.cnt = time + 5;
 128         gren.nextthink = time;
 129         gren.think = brute_grenade_think;
 130         gren.use = brute_grenade_explode;
 131         gren.touch = brute_grenade_touch;
 132
 133         gren.takedamage = DAMAGE_YES;
 134         gren.health = autocvar_g_balance_grenadelauncher_primary_health;
 135         gren.damageforcescale = autocvar_g_balance_grenadelauncher_primary_damageforcescale;
 136         gren.event_damage = brute_grenade_damage;
 137         gren.damagedbycontents = TRUE;
 138         gren.missile_flags = MIF_SPLASH | MIF_ARC;
 139         W_SETUPPROJECTILEVELOCITY_UP(gren, g_balance_grenadelauncher_primary);
 140
 141         gren.angles = vectoangles (gren.velocity);
 142         gren.flags = FL_PROJECTILE;
 143
 144         CSQCProjectile(gren, TRUE, PROJECTILE_GRENADE, TRUE);
 145 }
 146
 147 float brute_attack(float attack_type)
 148 {
 149         switch(attack_type)
 150         {
 151                 case MONSTER_ATTACK_MELEE:
 152                 {
 153                         self.brute_cycles = 0;
 154                         monsters_setframe(brute_anim_swing);
 155                         self.attack_finished_single = time + 1.3;
 156                         brute_blade();
 157
 158                         return TRUE;
 159                 }
 160                 case MONSTER_ATTACK_RANGED:
 161                 {
 162                         self.brute_cycles = 0;
 163                         if(random() <= autocvar_g_monster_brute_attack_uzi_chance)
 164                         {
 165                                 monsters_setframe(brute_anim_pain);
 166                                 self.attack_finished_single = time + 0.8;
 167                                 defer(0.1, brute_uzi);
 168                         }
 169                         else
 170                         {
 171                                 monster_makevectors(self.enemy);
 172                                 brute_grenade();
 173                                 monsters_setframe(brute_anim_pain);
 174                                 self.attack_finished_single = time + 1.2;
 175                         }
 176
 177                         return TRUE;
 178                 }
 179         }
 180
 181         return FALSE;
 182 }
 183
 184 void spawnfunc_monster_brute()
 185 {
 186         if not(autocvar_g_monster_brute) { remove(self); return; }
 187
 188         self.classname = "monster_brute";
 189
 190         self.monster_spawnfunc = spawnfunc_monster_brute;
 191
 192         if(Monster_CheckAppearFlags(self))
 193                 return;
 194
 195         if not(monster_initialize(MON_BRUTE, FALSE, 0)) { remove(self); return; }
 196 }
 197
 198 float m_brute(float req)
 199 {
 200         switch(req)
 201         {
 202                 case MR_THINK:
 203                 {
 204                         monster_move(autocvar_g_monster_brute_speed_run, autocvar_g_monster_brute_speed_walk, 300, brute_anim_run, brute_anim_walk, brute_anim_idle);
 205                         return TRUE;
 206                 }
 207                 case MR_DEATH:
 208                 {
 209                         monsters_setframe(brute_anim_die);
 210                         return TRUE;
 211                 }
 212                 case MR_SETUP:
 213                 {
 214                         if not(self.health) self.health = autocvar_g_monster_brute_health;
 215
 216                         self.monster_attackfunc = brute_attack;
 217                         monsters_setframe(brute_anim_idle);
 218                         self.weapon = WEP_GRENADE_LAUNCHER;
 219
 220                         return TRUE;
 221                 }
 222                 case MR_INIT:
 223                 {
 224                         // nothing
 225                         return TRUE;
 226                 }
 227         }
 228
 229         return TRUE;
 230 }
 231
 232 #endif // SVQC
 233 #ifdef CSQC
 234 float m_brute(float req)
 235 {
 236         switch(req)
 237         {
 238                 case MR_DEATH:
 239                 {
 240                         // nothing
 241                         return TRUE;
 242                 }
 243                 case MR_INIT:
 244                 {
 245                         precache_model ("models/monsters/ogre.dpm");
 246                         return TRUE;
 247                 }
 248         }
 249
 250         return TRUE;
 251 }
 252
 253 #endif // CSQC
 254 #endif // REGISTER_MONSTER