qcsrc/common/monsters/monster/brute.qc

   1 #ifdef REGISTER_MONSTER
   2 REGISTER_MONSTER(
   3 /* MON_##id   */ BRUTE,
   4 /* function   */ m_brute,
   5 /* spawnflags */ 0,
   6 /* mins,maxs  */ '-36 -36 -20', '36 36 50',
   7 /* model      */ "ogre.dpm",
   8 /* netname    */ "brute",
   9 /* fullname   */ _("Brute")
  10 );
  11
  12 #else
  13 #ifdef SVQC
  14 float autocvar_g_monster_brute;
  15 float autocvar_g_monster_brute_health;
  16 float autocvar_g_monster_brute_chainsaw_damage;
  17 float autocvar_g_monster_brute_speed_walk;
  18 float autocvar_g_monster_brute_speed_run;
  19 float autocvar_g_monster_brute_attack_uzi_bullets;
  20 float autocvar_g_monster_brute_attack_uzi_damage;
  21 float autocvar_g_monster_brute_attack_uzi_force;
  22 float autocvar_g_monster_brute_attack_uzi_chance;
  23 float autocvar_g_monster_brute_attack_grenade_damage;
  24 float autocvar_g_monster_brute_attack_grenade_edgedamage;
  25 float autocvar_g_monster_brute_attack_grenade_force;
  26 float autocvar_g_monster_brute_attack_grenade_radius;
  27
  28 const float brute_anim_idle             = 0;
  29 const float brute_anim_walk             = 1;
  30 const float brute_anim_run                      = 2;
  31 const float brute_anim_pain             = 3;
  32 const float brute_anim_swing            = 4;
  33 const float brute_anim_die                      = 5;
  34
  35 .float brute_cycles;
  36
  37 void brute_blade()
  38 {
  39         self.brute_cycles += 1;
  40         self.angles_y = self.angles_y + random()* 25;
  41
  42         monster_melee(self.enemy, autocvar_g_monster_brute_chainsaw_damage, 0.3, DEATH_MONSTER_BRUTE_BLADE, TRUE);
  43
  44         if(self.brute_cycles <= 4)
  45                 defer(0.2, brute_blade);
  46 }
  47
  48 void brute_uzi()
  49 {
  50         self.brute_cycles += 1;
  51
  52         monster_makevectors(self.enemy);
  53
  54         W_SetupShot (self, autocvar_g_antilag_bullets && 18000 >= autocvar_g_antilag_bullets, 0, "weapons/uzi_fire.wav", CH_WEAPON_A, autocvar_g_monster_brute_attack_uzi_damage);
  55         fireBallisticBullet(w_shotorg, w_shotdir, 0.02, 18000, 5, autocvar_g_monster_brute_attack_uzi_damage, autocvar_g_monster_brute_attack_uzi_force, DEATH_MONSTER_BRUTE_UZI, 0, 1, 115);
  56         endFireBallisticBullet();
  57
  58         if(self.brute_cycles <= autocvar_g_monster_brute_attack_uzi_bullets)
  59                 defer(0.1, brute_uzi);
  60 }
  61
  62 void brute_grenade_explode()
  63 {
  64         pointparticles(particleeffectnum("grenade_explode"), self.origin, '0 0 0', 1);
  65         sound(self, CH_SHOTS, "weapons/grenade_impact.wav", VOL_BASE, ATTN_NORM);
  66
  67         self.event_damage = func_null;
  68         self.takedamage = DAMAGE_NO;
  69
  70         if(self.movetype == MOVETYPE_NONE)
  71                 self.velocity = self.oldvelocity;
  72
  73         RadiusDamage (self, self.realowner, autocvar_g_monster_brute_attack_grenade_damage, autocvar_g_monster_brute_attack_grenade_edgedamage, autocvar_g_monster_brute_attack_grenade_radius, world, autocvar_g_monster_brute_attack_grenade_force, self.projectiledeathtype, other);
  74
  75         remove (self);
  76 }
  77
  78 void brute_grenade_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
  79 {
  80         if (self.health <= 0)
  81                 return;
  82
  83         if (!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, -1)) // no exceptions
  84                 return; // g_projectiles_damage says to halt
  85
  86         self.health = self.health - damage;
  87
  88         if (self.health <= 0)
  89                 W_PrepareExplosionByDamage(attacker, self.use);
  90 }
  91
  92 void brute_grenade_touch()
  93 {
  94         PROJECTILE_TOUCH;
  95
  96         self.use ();
  97 }
  98
  99 void brute_grenade_think()
 100 {
 101         self.nextthink = time;
 102         if (time > self.cnt)
 103         {
 104                 other = world;
 105                 brute_grenade_explode();
 106                 return;
 107         }
 108 }
 109
 110 void brute_grenade()
 111 {
 112         entity gren;
 113
 114         W_SetupShot_ProjectileSize (self, '-3 -3 -3', '3 3 3', FALSE, 4, "weapons/grenade_fire.wav", CH_WEAPON_A, autocvar_g_monster_brute_attack_grenade_damage);
 115         w_shotdir = v_forward; // no TrueAim for grenades please
 116
 117         gren = spawn ();
 118         gren.owner = gren.realowner = self;
 119         gren.classname = "grenade";
 120         gren.bot_dodge = TRUE;
 121         gren.bot_dodgerating = autocvar_g_monster_brute_attack_grenade_damage;
 122         gren.movetype = MOVETYPE_BOUNCE;
 123         PROJECTILE_MAKETRIGGER(gren);
 124         gren.projectiledeathtype = DEATH_MONSTER_BRUTE_GRENADE;
 125         setorigin(gren, w_shotorg);
 126         setsize(gren, '-3 -3 -3', '3 3 3');
 127
 128         gren.cnt = time + 5;
 129         gren.nextthink = time;
 130         gren.think = brute_grenade_think;
 131         gren.use = brute_grenade_explode;
 132         gren.touch = brute_grenade_touch;
 133
 134         gren.takedamage = DAMAGE_YES;
 135         gren.health = autocvar_g_balance_grenadelauncher_primary_health;
 136         gren.damageforcescale = autocvar_g_balance_grenadelauncher_primary_damageforcescale;
 137         gren.event_damage = brute_grenade_damage;
 138         gren.damagedbycontents = TRUE;
 139         gren.missile_flags = MIF_SPLASH | MIF_ARC;
 140         W_SETUPPROJECTILEVELOCITY_UP(gren, g_balance_grenadelauncher_primary);
 141
 142         gren.angles = vectoangles (gren.velocity);
 143         gren.flags = FL_PROJECTILE;
 144
 145         CSQCProjectile(gren, TRUE, PROJECTILE_GRENADE, TRUE);
 146 }
 147
 148 float brute_attack(float attack_type)
 149 {
 150         switch(attack_type)
 151         {
 152                 case MONSTER_ATTACK_MELEE:
 153                 {
 154                         self.brute_cycles = 0;
 155                         monsters_setframe(brute_anim_swing);
 156                         self.attack_finished_single = time + 1.3;
 157                         brute_blade();
 158
 159                         return TRUE;
 160                 }
 161                 case MONSTER_ATTACK_RANGED:
 162                 {
 163                         self.brute_cycles = 0;
 164                         if(random() <= autocvar_g_monster_brute_attack_uzi_chance)
 165                         {
 166                                 monsters_setframe(brute_anim_pain);
 167                                 self.attack_finished_single = time + 0.8;
 168                                 defer(0.1, brute_uzi);
 169                         }
 170                         else
 171                         {
 172                                 monster_makevectors(self.enemy);
 173                                 brute_grenade();
 174                                 monsters_setframe(brute_anim_pain);
 175                                 self.attack_finished_single = time + 1.2;
 176                         }
 177
 178                         return TRUE;
 179                 }
 180         }
 181
 182         return FALSE;
 183 }
 184
 185 void spawnfunc_monster_brute()
 186 {
 187         if not(autocvar_g_monster_brute) { remove(self); return; }
 188
 189         self.classname = "monster_brute";
 190
 191         self.monster_spawnfunc = spawnfunc_monster_brute;
 192
 193         if(Monster_CheckAppearFlags(self))
 194                 return;
 195
 196         if not(monster_initialize(MON_BRUTE, FALSE)) { remove(self); return; }
 197 }
 198
 199 float m_brute(float req)
 200 {
 201         switch(req)
 202         {
 203                 case MR_THINK:
 204                 {
 205                         monster_move(autocvar_g_monster_brute_speed_run, autocvar_g_monster_brute_speed_walk, 300, brute_anim_run, brute_anim_walk, brute_anim_idle);
 206                         return TRUE;
 207                 }
 208                 case MR_DEATH:
 209                 {
 210                         monsters_setframe(brute_anim_die);
 211                         return TRUE;
 212                 }
 213                 case MR_SETUP:
 214                 {
 215                         if not(self.health) self.health = autocvar_g_monster_brute_health;
 216
 217                         self.monster_attackfunc = brute_attack;
 218                         monsters_setframe(brute_anim_idle);
 219                         self.weapon = WEP_GRENADE_LAUNCHER;
 220
 221                         return TRUE;
 222                 }
 223                 case MR_INIT:
 224                 {
 225                         // nothing
 226                         return TRUE;
 227                 }
 228         }
 229
 230         return TRUE;
 231 }
 232
 233 #endif // SVQC
 234 #ifdef CSQC
 235 float m_brute(float req)
 236 {
 237         switch(req)
 238         {
 239                 case MR_DEATH:
 240                 {
 241                         // nothing
 242                         return TRUE;
 243                 }
 244                 case MR_INIT:
 245                 {
 246                         precache_model ("models/monsters/ogre.dpm");
 247                         return TRUE;
 248                 }
 249         }
 250
 251         return TRUE;
 252 }
 253
 254 #endif // CSQC
 255 #endif // REGISTER_MONSTER