qcsrc/common/monsters/monster/brute.qc

   1 #ifdef REGISTER_MONSTER
   2 REGISTER_MONSTER(
   3 /* MON_##id   */ BRUTE,
   4 /* function   */ m_brute,
   5 /* spawnflags */ 0,
   6 /* mins,maxs  */ '-36 -36 -20', '36 36 50',
   7 /* model      */ "ogre.dpm",
   8 /* netname    */ "brute",
   9 /* fullname   */ _("Brute")
  10 );
  11
  12 #define BRUTE_SETTINGS(monster) \
  13         MON_ADD_CVAR(monster, health) \
  14         MON_ADD_CVAR(monster, attack_chainsaw_damage) \
  15         MON_ADD_CVAR(monster, attack_uzi_bullets) \
  16         MON_ADD_CVAR(monster, attack_uzi_damage) \
  17         MON_ADD_CVAR(monster, attack_uzi_force) \
  18         MON_ADD_CVAR(monster, attack_uzi_chance) \
  19         MON_ADD_CVAR(monster, attack_grenade_damage) \
  20         MON_ADD_CVAR(monster, attack_grenade_edgedamage) \
  21         MON_ADD_CVAR(monster, attack_grenade_force) \
  22         MON_ADD_CVAR(monster, attack_grenade_radius) \
  23         MON_ADD_CVAR(monster, attack_grenade_speed) \
  24         MON_ADD_CVAR(monster, attack_grenade_speed_up) \
  25         MON_ADD_CVAR(monster, speed_run) \
  26         MON_ADD_CVAR(monster, speed_walk)
  27
  28 #ifdef SVQC
  29 BRUTE_SETTINGS(brute)
  30 #endif // SVQC
  31 #else
  32 #ifdef SVQC
  33 const float brute_anim_idle             = 0;
  34 const float brute_anim_walk             = 1;
  35 const float brute_anim_run                      = 2;
  36 const float brute_anim_pain             = 3;
  37 const float brute_anim_swing            = 4;
  38 const float brute_anim_die                      = 5;
  39
  40 .float brute_cycles;
  41
  42 void brute_blade()
  43 {
  44         self.brute_cycles += 1;
  45         self.angles_y = self.angles_y + random()* 25;
  46
  47         monster_melee(self.enemy, MON_CVAR(brute, attack_chainsaw_damage), 0.3, DEATH_MONSTER_BRUTE_BLADE, TRUE);
  48
  49         if(self.brute_cycles <= 4)
  50                 defer(0.2, brute_blade);
  51 }
  52
  53 void brute_uzi()
  54 {
  55         self.brute_cycles += 1;
  56
  57         monster_makevectors(self.enemy);
  58
  59         W_SetupShot (self, autocvar_g_antilag_bullets && 18000 >= autocvar_g_antilag_bullets, 0, "weapons/uzi_fire.wav", CH_WEAPON_A, MON_CVAR(brute, attack_uzi_damage));
  60         fireBallisticBullet(w_shotorg, w_shotdir, 0.02, 18000, 5, MON_CVAR(brute, attack_uzi_damage), MON_CVAR(brute, attack_uzi_force), DEATH_MONSTER_BRUTE_UZI, 0, 1, 115);
  61         endFireBallisticBullet();
  62
  63         if(self.brute_cycles <= MON_CVAR(brute, attack_uzi_bullets))
  64                 defer(0.1, brute_uzi);
  65 }
  66
  67 void brute_grenade_explode()
  68 {
  69         pointparticles(particleeffectnum("grenade_explode"), self.origin, '0 0 0', 1);
  70         sound(self, CH_SHOTS, "weapons/grenade_impact.wav", VOL_BASE, ATTN_NORM);
  71
  72         self.event_damage = func_null;
  73         self.takedamage = DAMAGE_NO;
  74
  75         if(self.movetype == MOVETYPE_NONE)
  76                 self.velocity = self.oldvelocity;
  77
  78         RadiusDamage (self, self.realowner, MON_CVAR(brute, attack_grenade_damage), MON_CVAR(brute, attack_grenade_edgedamage), MON_CVAR(brute, attack_grenade_radius), world, MON_CVAR(brute, attack_grenade_force), self.projectiledeathtype, other);
  79
  80         remove (self);
  81 }
  82
  83 void brute_grenade_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
  84 {
  85         if (self.health <= 0)
  86                 return;
  87
  88         if (!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, -1)) // no exceptions
  89                 return; // g_projectiles_damage says to halt
  90
  91         self.health = self.health - damage;
  92
  93         if (self.health <= 0)
  94                 W_PrepareExplosionByDamage(attacker, self.use);
  95 }
  96
  97 void brute_grenade_touch()
  98 {
  99         PROJECTILE_TOUCH;
 100
 101         self.use ();
 102 }
 103
 104 void brute_grenade_think()
 105 {
 106         self.nextthink = time;
 107         if (time > self.cnt)
 108         {
 109                 other = world;
 110                 brute_grenade_explode();
 111                 return;
 112         }
 113 }
 114
 115 void brute_grenade()
 116 {
 117         entity gren;
 118
 119         W_SetupShot_ProjectileSize (self, '-3 -3 -3', '3 3 3', FALSE, 4, "weapons/grenade_fire.wav", CH_WEAPON_A, MON_CVAR(brute, attack_grenade_damage));
 120         w_shotdir = v_forward; // no TrueAim for grenades please
 121
 122         gren = spawn ();
 123         gren.owner = gren.realowner = self;
 124         gren.classname = "grenade";
 125         gren.bot_dodge = TRUE;
 126         gren.bot_dodgerating = MON_CVAR(brute, attack_grenade_damage);
 127         gren.movetype = MOVETYPE_BOUNCE;
 128         PROJECTILE_MAKETRIGGER(gren);
 129         gren.projectiledeathtype = DEATH_MONSTER_BRUTE_GRENADE;
 130         setorigin(gren, w_shotorg);
 131         setsize(gren, '-3 -3 -3', '3 3 3');
 132
 133         gren.cnt = time + 5;
 134         gren.nextthink = time;
 135         gren.think = brute_grenade_think;
 136         gren.use = brute_grenade_explode;
 137         gren.touch = brute_grenade_touch;
 138
 139         gren.takedamage = DAMAGE_YES;
 140         gren.health = 50;
 141         gren.damageforcescale = 0;
 142         gren.event_damage = brute_grenade_damage;
 143         gren.damagedbycontents = TRUE;
 144         gren.missile_flags = MIF_SPLASH | MIF_ARC;
 145         W_SetupProjectileVelocityEx(gren, w_shotdir, v_up, MON_CVAR(brute, attack_grenade_speed), MON_CVAR(brute, attack_grenade_speed_up), 0, 0, FALSE);
 146
 147         gren.angles = vectoangles (gren.velocity);
 148         gren.flags = FL_PROJECTILE;
 149
 150         CSQCProjectile(gren, TRUE, PROJECTILE_GRENADE, TRUE);
 151 }
 152
 153 float brute_attack(float attack_type)
 154 {
 155         switch(attack_type)
 156         {
 157                 case MONSTER_ATTACK_MELEE:
 158                 {
 159                         self.brute_cycles = 0;
 160                         monsters_setframe(brute_anim_swing);
 161                         self.attack_finished_single = time + 1.3;
 162                         brute_blade();
 163
 164                         return TRUE;
 165                 }
 166                 case MONSTER_ATTACK_RANGED:
 167                 {
 168                         self.brute_cycles = 0;
 169                         if(random() <= MON_CVAR(brute, attack_uzi_chance))
 170                         {
 171                                 monsters_setframe(brute_anim_pain);
 172                                 self.attack_finished_single = time + 0.8;
 173                                 defer(0.1, brute_uzi);
 174                         }
 175                         else
 176                         {
 177                                 monster_makevectors(self.enemy);
 178                                 brute_grenade();
 179                                 monsters_setframe(brute_anim_pain);
 180                                 self.attack_finished_single = time + 1.2;
 181                         }
 182
 183                         return TRUE;
 184                 }
 185         }
 186
 187         return FALSE;
 188 }
 189
 190 void spawnfunc_monster_brute()
 191 {
 192         self.classname = "monster_brute";
 193
 194         self.monster_spawnfunc = spawnfunc_monster_brute;
 195
 196         if(Monster_CheckAppearFlags(self))
 197                 return;
 198
 199         if not(monster_initialize(MON_BRUTE, FALSE)) { remove(self); return; }
 200 }
 201
 202 float m_brute(float req)
 203 {
 204         switch(req)
 205         {
 206                 case MR_THINK:
 207                 {
 208                         monster_move(MON_CVAR(brute, speed_run), MON_CVAR(brute, speed_walk), 300, brute_anim_run, brute_anim_walk, brute_anim_idle);
 209                         return TRUE;
 210                 }
 211                 case MR_DEATH:
 212                 {
 213                         monsters_setframe(brute_anim_die);
 214                         return TRUE;
 215                 }
 216                 case MR_SETUP:
 217                 {
 218                         if not(self.health) self.health = MON_CVAR(brute, health);
 219
 220                         self.monster_attackfunc = brute_attack;
 221                         monsters_setframe(brute_anim_idle);
 222                         self.weapon = WEP_GRENADE_LAUNCHER;
 223
 224                         return TRUE;
 225                 }
 226                 case MR_INIT:
 227                 {
 228                         // nothing
 229                         return TRUE;
 230                 }
 231                 case MR_CONFIG:
 232                 {
 233                         MON_CONFIG_SETTINGS(BRUTE_SETTINGS(brute))
 234                         return TRUE;
 235                 }
 236         }
 237
 238         return TRUE;
 239 }
 240
 241 #endif // SVQC
 242 #ifdef CSQC
 243 float m_brute(float req)
 244 {
 245         switch(req)
 246         {
 247                 case MR_DEATH:
 248                 {
 249                         // nothing
 250                         return TRUE;
 251                 }
 252                 case MR_INIT:
 253                 {
 254                         precache_model ("models/monsters/ogre.dpm");
 255                         return TRUE;
 256                 }
 257         }
 258
 259         return TRUE;
 260 }
 261
 262 #endif // CSQC
 263 #endif // REGISTER_MONSTER