qcsrc/common/monsters/monster/cerberus.qc

   1 #ifdef REGISTER_MONSTER
   2 REGISTER_MONSTER(
   3 /* MON_##id   */ CERBERUS,
   4 /* function   */ m_cerberus,
   5 /* spawnflags */ MON_FLAG_MELEE | MON_FLAG_MUTATORBLOCKED,
   6 /* mins,maxs  */ '-16 -16 -24', '16 16 12',
   7 /* model      */ "dog.dpm",
   8 /* netname    */ "cerberus",
   9 /* fullname   */ _("Cerberus")
  10 );
  11
  12 #define CERBERUS_SETTINGS(monster) \
  13         MON_ADD_CVAR(monster, health) \
  14         MON_ADD_CVAR(monster, attack_bite_damage) \
  15         MON_ADD_CVAR(monster, attack_jump_damage) \
  16         MON_ADD_CVAR(monster, speed_stop) \
  17         MON_ADD_CVAR(monster, speed_run) \
  18         MON_ADD_CVAR(monster, speed_walk)
  19
  20 #ifdef SVQC
  21 CERBERUS_SETTINGS(cerberus)
  22 #endif // SVQC
  23 #else
  24 #ifdef SVQC
  25 const float cerberus_anim_idle          = 0;
  26 const float cerberus_anim_walk          = 1;
  27 const float cerberus_anim_run           = 2;
  28 const float cerberus_anim_attack        = 3;
  29 const float cerberus_anim_die           = 4;
  30 const float cerberus_anim_pain          = 5;
  31
  32 .float cerberus_last_trace;
  33
  34 void cerberus_findowner()
  35 {
  36         if(time < self.cerberus_last_trace || self.monster_owner)
  37                 return;
  38
  39         entity head;
  40
  41         FOR_EACH_MONSTER(head)
  42         if(head.health > 0)
  43         if(head.monsterid == MON_BRUISER)
  44         if(findentity(world, monster_owner, head) == world)
  45         if(vlen(head.origin - self.origin) < self.target_range)
  46         if(SAME_TEAM(head, self))
  47         if(head.enemy == world)
  48         {
  49                 self.monster_owner = head;
  50                 break;
  51         }
  52
  53         self.cerberus_last_trace = time + 3;
  54 }
  55
  56 void cerberus_checkowner()
  57 {
  58         if(time < self.cerberus_last_trace)
  59                 return;
  60         if(IS_PLAYER(self.monster_owner))
  61                 return; // don't check player masters
  62
  63         if(vlen(self.origin - self.monster_owner.origin) > self.target_range)
  64                 self.monster_owner = world;
  65         if(self.monster_owner.health < 1)
  66                 self.monster_owner = world;
  67         if(DIFF_TEAM(self.monster_owner, self))
  68                 self.monster_owner = world;
  69
  70         self.cerberus_last_trace = time + 3;
  71 }
  72
  73 void cerberus_touch_jump()
  74 {
  75         if (other.takedamage)
  76         if (vlen(self.velocity) > 300)
  77         {
  78                 Damage(self.enemy, self, self, MON_CVAR(cerberus, attack_jump_damage) * monster_skill, DEATH_MONSTER_CERBERUS_JUMP, self.enemy.origin, normalize(self.enemy.origin - self.origin));
  79                 self.touch = MonsterTouch;
  80         }
  81
  82         if(trace_dphitcontents)
  83                 self.touch = MonsterTouch;
  84 }
  85
  86 float cerberus_attack(float attack_type)
  87 {
  88         switch(attack_type)
  89         {
  90                 case MONSTER_ATTACK_MELEE:
  91                 {
  92                         return monster_melee(self.enemy, MON_CVAR(cerberus, attack_bite_damage), cerberus_anim_attack, self.attack_range, 0.7, DEATH_MONSTER_CERBERUS_BITE, TRUE);
  93                 }
  94                 case MONSTER_ATTACK_RANGED:
  95                 {
  96                         makevectors(self.angles);
  97                         return monster_leap(cerberus_anim_attack, cerberus_touch_jump, v_forward * 300 + '0 0 200', 0.8);
  98                 }
  99         }
 100
 101         return FALSE;
 102 }
 103
 104 void spawnfunc_monster_cerberus()
 105 {
 106         self.classname = "monster_cerberus";
 107
 108         self.monster_spawnfunc = spawnfunc_monster_cerberus;
 109
 110         if(Monster_CheckAppearFlags(self))
 111                 return;
 112
 113         if not(monster_initialize(MON_CERBERUS, FALSE)) { remove(self); return; }
 114 }
 115
 116 // compatibility with old spawns
 117 void spawnfunc_monster_dog() { spawnfunc_monster_cerberus(); }
 118
 119 float m_cerberus(float req)
 120 {
 121         switch(req)
 122         {
 123                 case MR_THINK:
 124                 {
 125                         if(self.monster_owner)
 126                                 cerberus_checkowner();
 127                         else
 128                                 cerberus_findowner();
 129                         monster_move(MON_CVAR(cerberus, speed_run), MON_CVAR(cerberus, speed_walk), MON_CVAR(cerberus, speed_stop), cerberus_anim_run, cerberus_anim_walk, cerberus_anim_idle);
 130                         return TRUE;
 131                 }
 132                 case MR_DEATH:
 133                 {
 134                         if(self.monster_owner.flags & FL_MONSTER)
 135                                 self.monster_owner = world;
 136                         self.frame = cerberus_anim_die;
 137                         return TRUE;
 138                 }
 139                 case MR_SETUP:
 140                 {
 141                         if not(self.health) self.health = MON_CVAR(cerberus, health);
 142
 143                         self.monster_loot = spawnfunc_item_health_small;
 144                         self.monster_attackfunc = cerberus_attack;
 145                         self.frame = cerberus_anim_idle;
 146
 147                         return TRUE;
 148                 }
 149                 case MR_PRECACHE:
 150                 {
 151                         precache_model ("models/monsters/dog.dpm");
 152                         return TRUE;
 153                 }
 154                 case MR_CONFIG:
 155                 {
 156                         MON_CONFIG_SETTINGS(CERBERUS_SETTINGS(cerberus))
 157                         return TRUE;
 158                 }
 159         }
 160
 161         return TRUE;
 162 }
 163
 164 #endif // SVQC
 165 #ifdef CSQC
 166 float m_cerberus(float req)
 167 {
 168         switch(req)
 169         {
 170                 case MR_PRECACHE:
 171                 {
 172                         precache_model ("models/monsters/dog.dpm");
 173                         return TRUE;
 174                 }
 175         }
 176
 177         return TRUE;
 178 }
 179
 180 #endif // CSQC
 181 #endif // REGISTER_MONSTER