qcsrc/common/monsters/sv_monsters.qc

   1 // =========================
   2 //  SVQC Monster Properties
   3 // =========================
   4
   5
   6 void M_Item_Touch ()
   7 {
   8         if(self && IS_PLAYER(other) && other.deadflag == DEAD_NO)
   9         {
  10                 Item_Touch();
  11                 self.think = SUB_Remove;
  12                 self.nextthink = time + 0.1;
  13         }
  14 }
  15
  16 void monster_item_spawn()
  17 {
  18         if(self.monster_loot)
  19                 self.monster_loot();
  20
  21         self.gravity = 1;
  22         self.velocity = randomvec() * 175 + '0 0 325';
  23         self.touch = M_Item_Touch;
  24
  25         SUB_SetFade(self, time + autocvar_g_monsters_drop_time, 1);
  26 }
  27
  28 void monster_dropitem()
  29 {
  30         if(!self.candrop || !self.monster_loot)
  31                 return;
  32
  33         vector org = self.origin + ((self.mins + self.maxs) * 0.5);
  34         entity e = spawn();
  35
  36         setorigin(e, org);
  37
  38         e.monster_loot = self.monster_loot;
  39
  40         other = e;
  41         MUTATOR_CALLHOOK(MonsterDropItem);
  42         e = other;
  43
  44         e.think = monster_item_spawn;
  45         e.nextthink = time + 0.3;
  46 }
  47
  48 void monsters_setframe(float _frame)
  49 {
  50         if(self.frame == _frame)
  51                 return;
  52
  53         self.anim_start_time = time;
  54         self.frame = _frame;
  55         self.SendFlags |= MSF_ANIM;
  56 }
  57
  58 float monster_isvalidtarget (entity targ, entity ent)
  59 {
  60         if(!targ || !ent)
  61                 return FALSE; // someone doesn't exist
  62
  63         if(time < game_starttime)
  64                 return FALSE; // monsters do nothing before the match has started
  65
  66         WarpZone_TraceLine(ent.origin, targ.origin, MOVE_NORMAL, ent);
  67
  68         if(vlen(targ.origin - ent.origin) >= ent.target_range)
  69                 return FALSE; // enemy is too far away
  70
  71         if not(targ.vehicle_flags & VHF_ISVEHICLE)
  72         if(trace_ent != targ)
  73                 return FALSE; // we can't see the enemy
  74
  75         if(targ.takedamage == DAMAGE_NO)
  76                 return FALSE; // enemy can't be damaged
  77
  78         if(targ.items & IT_INVISIBILITY)
  79                 return FALSE; // enemy is invisible
  80
  81         if(substring(targ.classname, 0, 10) == "onslaught_")
  82                 return FALSE; // don't attack onslaught targets
  83
  84         if(IS_SPEC(targ) || IS_OBSERVER(targ))
  85                 return FALSE; // enemy is a spectator
  86
  87         if not(targ.vehicle_flags & VHF_ISVEHICLE) // vehicles dont count as alive?
  88         if(targ.deadflag != DEAD_NO || ent.deadflag != DEAD_NO || targ.health <= 0 || ent.health <= 0)
  89                 return FALSE; // enemy/self is dead
  90
  91         if(ent.monster_owner == targ)
  92                 return FALSE; // don't attack our master
  93
  94         if(targ.monster_owner == ent)
  95                 return FALSE; // don't attack our pet
  96
  97         if not(targ.vehicle_flags & VHF_ISVEHICLE)
  98         if(targ.flags & FL_NOTARGET)
  99                 return FALSE; // enemy can't be targeted
 100
 101         if not(autocvar_g_monsters_typefrag)
 102         if(targ.BUTTON_CHAT)
 103                 return FALSE; // no typefragging!
 104
 105         if not(IsDifferentTeam(targ, ent))
 106                 return FALSE; // enemy is on our team
 107
 108         if(autocvar_g_monsters_target_infront)
 109         if(ent.enemy != targ)
 110         {
 111                 float dot;
 112
 113                 makevectors (ent.angles);
 114                 dot = normalize (targ.origin - ent.origin) * v_forward;
 115
 116                 if(dot <= 0.3)
 117                         return FALSE;
 118         }
 119
 120         return TRUE;
 121 }
 122
 123 entity FindTarget (entity ent)
 124 {
 125         if(MUTATOR_CALLHOOK(MonsterFindTarget)) { return ent.enemy; } // Handled by a mutator
 126         entity e;
 127
 128         for(e = world; (e = findflags(e, monster_attack, TRUE)); )
 129         if(monster_isvalidtarget(e, ent))
 130                 return e;
 131
 132         return world;
 133 }
 134
 135 void MonsterTouch ()
 136 {
 137         if(other == world)
 138                 return;
 139
 140         if(self.enemy != other)
 141         if not(other.flags & FL_MONSTER)
 142         if(monster_isvalidtarget(other, self))
 143                 self.enemy = other;
 144 }
 145
 146 void monster_sound(string msound, float sound_delay, float delaytoo)
 147 {
 148         if(delaytoo && time < self.msound_delay)
 149                 return; // too early
 150
 151         if(msound == "")
 152                 return; // sound doesn't exist
 153
 154         sound(self, CHAN_AUTO, msound, VOL_BASE, ATTN_NORM);
 155
 156         self.msound_delay = time + sound_delay;
 157 }
 158
 159 void monster_precachesounds(entity e)
 160 {
 161         precache_sound(e.msound_idle);
 162         precache_sound(e.msound_death);
 163         precache_sound(e.msound_attack_melee);
 164         precache_sound(e.msound_attack_ranged);
 165         precache_sound(e.msound_sight);
 166         precache_sound(e.msound_pain);
 167 }
 168
 169 void monster_setupsounds(string mon)
 170 {
 171         if(self.msound_idle == "") self.msound_idle = strzone(strcat("monsters/", mon, "_idle.wav"));
 172         if(self.msound_death == "") self.msound_death = strzone(strcat("monsters/", mon, "_death.wav"));
 173         if(self.msound_pain == "") self.msound_pain = strzone(strcat("monsters/", mon, "_pain.wav"));
 174         if(self.msound_attack_melee == "") self.msound_attack_melee = strzone(strcat("monsters/", mon, "_melee.wav"));
 175         if(self.msound_attack_ranged == "") self.msound_attack_ranged = strzone(strcat("monsters/", mon, "_attack.wav"));
 176         if(self.msound_sight == "") self.msound_sight = strzone(strcat("monsters/", mon, "_sight.wav"));
 177 }
 178
 179 float monster_melee(entity targ, float damg, float er, float deathtype, float dostop)
 180 {
 181         float rdmg = damg * random();
 182
 183         if (self.health <= 0)
 184                 return FALSE;
 185         if (targ == world)
 186                 return FALSE;
 187
 188         if(dostop)
 189         {
 190                 self.velocity_x = 0;
 191                 self.velocity_y = 0;
 192                 self.state = MONSTER_STATE_ATTACK_MELEE;
 193                 self.SendFlags |= MSF_MOVE;
 194         }
 195
 196         makevectors (self.angles);
 197
 198         traceline(self.origin + self.view_ofs, self.origin + v_forward * er, 0, self);
 199
 200         if(trace_ent.takedamage)
 201                 Damage(targ, self, self, rdmg * monster_skill, deathtype, targ.origin, normalize(targ.origin - self.origin));
 202
 203         return TRUE;
 204 }
 205
 206 void Monster_CheckMinibossFlag ()
 207 {
 208         if(MUTATOR_CALLHOOK(MonsterCheckBossFlag))
 209                 return;
 210
 211         float chance = random() * 100;
 212
 213         // g_monsters_miniboss_chance cvar or spawnflags 64 causes a monster to be a miniboss
 214         if ((self.spawnflags & MONSTERFLAG_MINIBOSS) || (chance < autocvar_g_monsters_miniboss_chance))
 215         {
 216                 self.health += autocvar_g_monsters_miniboss_healthboost;
 217                 if not(self.weapon)
 218                         self.weapon = WEP_NEX;
 219         }
 220 }
 221
 222 float Monster_CanRespawn(entity ent)
 223 {
 224         other = ent;
 225         if(MUTATOR_CALLHOOK(MonsterRespawn))
 226                 return TRUE; // enabled by a mutator
 227
 228         if(ent.spawnflags & MONSTERFLAG_NORESPAWN)
 229                 return FALSE;
 230
 231         if not(autocvar_g_monsters_respawn)
 232                 return FALSE;
 233
 234         return TRUE;
 235 }
 236
 237 void Monster_Fade ()
 238 {
 239         if(Monster_CanRespawn(self))
 240         {
 241                 self.monster_respawned = TRUE;
 242                 self.think = self.monster_spawnfunc;
 243                 self.nextthink = time + self.respawntime;
 244                 self.deadflag = DEAD_RESPAWNING;
 245                 if(self.spawnflags & MONSTER_RESPAWN_DEATHPOINT)
 246                 {
 247                         self.pos1 = self.origin;
 248                         self.pos2 = self.angles;
 249                 }
 250                 self.event_damage = func_null;
 251                 self.takedamage = DAMAGE_NO;
 252                 setorigin(self, self.pos1);
 253                 self.angles = self.pos2;
 254                 self.health = self.max_health; // TODO: check if resetting to max_health is wise here
 255
 256                 self.SendFlags |= MSF_MOVE;
 257                 self.SendFlags |= MSF_STATUS;
 258
 259                 return;
 260         }
 261         SUB_SetFade(self, time + 3, 1);
 262 }
 263
 264 float Monster_CanJump (vector vel)
 265 {
 266         if(self.state)
 267                 return FALSE; // already attacking
 268         if not(self.flags & FL_ONGROUND)
 269                 return FALSE; // not on the ground
 270         if(self.health <= 0)
 271                 return FALSE; // called when dead?
 272         if(time < self.attack_finished_single)
 273                 return FALSE; // still attacking
 274
 275         vector old = self.velocity;
 276
 277         self.velocity = vel;
 278         tracetoss(self, self);
 279         self.velocity = old;
 280         if (trace_ent != self.enemy)
 281                 return FALSE;
 282
 283         return TRUE;
 284 }
 285
 286 float monster_leap (float anm, void() touchfunc, vector vel, float anim_finished)
 287 {
 288         if(!Monster_CanJump(vel))
 289                 return FALSE;
 290
 291         monsters_setframe(anm);
 292         self.state = MONSTER_STATE_ATTACK_LEAP;
 293         self.touch = touchfunc;
 294         self.origin_z += 1;
 295         self.velocity = vel;
 296         self.flags &~= FL_ONGROUND;
 297
 298         self.attack_finished_single = time + anim_finished;
 299
 300         return TRUE;
 301 }
 302
 303 void monster_checkattack(entity e, entity targ)
 304 {
 305         if(e == world)
 306                 return;
 307         if(targ == world)
 308                 return;
 309
 310         if not(e.monster_attackfunc)
 311                 return;
 312
 313         if(time < e.attack_finished_single)
 314                 return;
 315
 316         if(vlen(targ.origin - e.origin) <= e.attack_range)
 317         if(e.monster_attackfunc(MONSTER_ATTACK_MELEE))
 318         {
 319                 monster_sound(e.msound_attack_melee, 0, FALSE);
 320                 return;
 321         }
 322
 323         if(vlen(targ.origin - e.origin) > e.attack_range)
 324         if(e.monster_attackfunc(MONSTER_ATTACK_RANGED))
 325         {
 326                 monster_sound(e.msound_attack_ranged, 0, FALSE);
 327                 return;
 328         }
 329 }
 330
 331 void monster_makevectors(entity e)
 332 {
 333         vector v;
 334
 335         v = CENTER_OR_VIEWOFS(e);
 336         self.v_angle = vectoangles(v - (self.origin + self.view_ofs));
 337         self.v_angle_x = -self.v_angle_x;
 338
 339         makevectors(self.v_angle);
 340 }
 341
 342 void monster_use ()
 343 {
 344         if (self.enemy)
 345                 return;
 346         if (self.health <= 0)
 347                 return;
 348
 349         if(!monster_isvalidtarget(activator, self))
 350                 return;
 351
 352         self.enemy = activator;
 353 }
 354
 355 float trace_path(vector from, vector to)
 356 {
 357         vector dir = normalize(to - from) * 15, offset = '0 0 0';
 358         float trace1 = trace_fraction;
 359
 360         offset_x = dir_y;
 361         offset_y = -dir_x;
 362         traceline (from+offset, to+offset, TRUE, self);
 363
 364         traceline(from-offset, to-offset, TRUE, self);
 365
 366         return ((trace1 < trace_fraction) ? trace1 : trace_fraction);
 367 }
 368
 369 .float last_trace;
 370 .float last_enemycheck; // for checking enemy
 371 vector monster_pickmovetarget(entity targ)
 372 {
 373         // enemy is always preferred target
 374         if(self.enemy)
 375         {
 376                 self.monster_movestate = MONSTER_MOVE_ENEMY;
 377                 self.last_trace = time + 1.2;
 378                 return self.enemy.origin;
 379         }
 380
 381         switch(self.monster_moveflags)
 382         {
 383                 case MONSTER_MOVE_OWNER:
 384                 {
 385                         self.monster_movestate = MONSTER_MOVE_OWNER;
 386                         self.last_trace = time + 0.3;
 387                         if(self.monster_owner && self.monster_owner.classname != "td_spawnpoint")
 388                                 return self.monster_owner.origin;
 389                 }
 390                 case MONSTER_MOVE_SPAWNLOC:
 391                 {
 392                         self.monster_movestate = MONSTER_MOVE_SPAWNLOC;
 393                         self.last_trace = time + 2;
 394                         return self.pos1;
 395                 }
 396                 case MONSTER_MOVE_NOMOVE:
 397                 {
 398                         self.monster_movestate = MONSTER_MOVE_NOMOVE;
 399                         self.last_trace = time + 2;
 400                         return self.origin;
 401                 }
 402                 default:
 403                 case MONSTER_MOVE_WANDER:
 404                 {
 405                         vector pos;
 406                         self.monster_movestate = MONSTER_MOVE_WANDER;
 407                         self.last_trace = time + 2;
 408
 409                         self.angles_y = random() * 500;
 410                         makevectors(self.angles);
 411                         pos = self.origin + v_forward * 600;
 412
 413                         if(self.flags & FL_FLY || self.flags & FL_SWIM)
 414                         {
 415                                 pos_z = random() * 200;
 416                                 if(random() >= 0.5)
 417                                         pos_z *= -1;
 418                         }
 419
 420                         if(targ)
 421                         {
 422                                 self.last_trace = time + 0.5;
 423                                 pos = targ.origin;
 424                         }
 425
 426                         return pos;
 427                 }
 428         }
 429 }
 430
 431 void monster_move(float runspeed, float walkspeed, float stopspeed, float manim_run, float manim_walk, float manim_idle)
 432 {
 433         fixedmakevectors(self.angles);
 434
 435         if(self.target2)
 436                 self.goalentity = find(world, targetname, self.target2);
 437
 438         entity targ;
 439
 440         if(self.frozen)
 441         {
 442                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
 443                 self.health = max(1, self.max_health * self.revive_progress);
 444
 445                 if(self.sprite) WaypointSprite_UpdateHealth(self.sprite, self.health);
 446
 447                 movelib_beak_simple(stopspeed);
 448
 449                 self.velocity = '0 0 0';
 450                 self.enemy = world;
 451                 self.nextthink = time + 0.1;
 452
 453                 if(self.revive_progress >= 1)
 454                         Unfreeze(self); // wait for next think before attacking
 455
 456                 // don't bother updating angles here?
 457                 if(self.origin != self.oldorigin)
 458                 {
 459                         self.oldorigin = self.origin;
 460                         self.SendFlags |= MSF_MOVE;
 461                 }
 462
 463                 return; // no moving while frozen
 464         }
 465
 466         if(self.flags & FL_SWIM)
 467         {
 468                 if(self.waterlevel < WATERLEVEL_WETFEET)
 469                 {
 470                         if(time >= self.last_trace)
 471                         {
 472                                 self.last_trace = time + 0.4;
 473
 474                                 Damage (self, world, world, 2, DEATH_DROWN, self.origin, '0 0 0');
 475                                 self.angles = '90 90 0';
 476                                 if(random() < 0.5)
 477                                 {
 478                                         self.velocity_y += random() * 50;
 479                                         self.velocity_x -= random() * 50;
 480                                 }
 481                                 else
 482                                 {
 483                                         self.velocity_y -= random() * 50;
 484                                         self.velocity_x += random() * 50;
 485                                 }
 486                                 self.velocity_z += random() * 150;
 487                         }
 488
 489
 490                         self.movetype = MOVETYPE_BOUNCE;
 491                         //self.velocity_z = -200;
 492
 493                         self.SendFlags |= MSF_MOVE | MSF_ANG;
 494
 495                         return;
 496                 }
 497                 else
 498                 {
 499                         self.angles = '0 0 0';
 500                         self.movetype = MOVETYPE_WALK;
 501                 }
 502         }
 503
 504         targ = self.goalentity;
 505
 506         monster_target = targ;
 507         monster_speed_run = runspeed;
 508         monster_speed_walk = walkspeed;
 509
 510         if(MUTATOR_CALLHOOK(MonsterMove) || gameover || (round_handler_IsActive() && !round_handler_IsRoundStarted()) || time < game_starttime || (autocvar_g_campaign && !campaign_bots_may_start) || time < self.spawn_time)
 511         {
 512                 runspeed = walkspeed = 0;
 513                 if(time >= self.spawn_time)
 514                         monsters_setframe(manim_idle);
 515                 movelib_beak_simple(stopspeed);
 516                 self.SendFlags |= MSF_MOVE;
 517                 return;
 518         }
 519
 520         targ = monster_target;
 521         runspeed = monster_speed_run;
 522         walkspeed = monster_speed_walk;
 523
 524         if(teamplay)
 525         if(autocvar_g_monsters_teams)
 526         if(IsDifferentTeam(self.monster_owner, self))
 527                 self.monster_owner = world;
 528
 529         if(time >= self.last_enemycheck)
 530         {
 531                 if not(monster_isvalidtarget(self.enemy, self))
 532                         self.enemy = world;
 533                 self.last_enemycheck = time + 2;
 534         }
 535
 536         if(self.enemy && self.enemy.health < 1)
 537                 self.enemy = world; // enough!
 538
 539         if not(self.enemy)
 540         {
 541                 self.enemy = FindTarget(self);
 542                 if(self.enemy)
 543                         monster_sound(self.msound_sight, 0, FALSE);
 544         }
 545
 546         if(self.state == MONSTER_STATE_ATTACK_MELEE && time >= self.attack_finished_single)
 547                 self.state = 0;
 548
 549         if(self.state != MONSTER_STATE_ATTACK_MELEE) // don't move if set
 550         if(time >= self.last_trace || self.enemy) // update enemy instantly
 551                 self.moveto = monster_pickmovetarget(targ);
 552
 553         if not(self.enemy)
 554                 monster_sound(self.msound_idle, 5, TRUE);
 555
 556         if(self.state != MONSTER_STATE_ATTACK_LEAP && self.state != MONSTER_STATE_ATTACK_MELEE)
 557                 self.steerto = steerlib_attract2(self.moveto, 0.5, 500, 0.95);
 558
 559         if(self.state == MONSTER_STATE_ATTACK_LEAP && (self.flags & FL_ONGROUND))
 560         {
 561                 self.state = 0;
 562                 self.touch = MonsterTouch;
 563         }
 564
 565         //self.steerto = steerlib_attract2(self.moveto, 0.5, 500, 0.95);
 566
 567         float turny = 0;
 568         vector real_angle = vectoangles(self.steerto) - self.angles;
 569
 570         if(self.state != MONSTER_STATE_ATTACK_LEAP && self.state != MONSTER_STATE_ATTACK_MELEE)
 571                 turny = 20;
 572
 573         if(self.flags & FL_SWIM)
 574                 turny = vlen(self.angles - self.moveto);
 575
 576         if(turny)
 577         {
 578                 turny = bound(turny * -1, shortangle_f(real_angle_y, self.angles_y), turny);
 579                 self.angles_y += turny;
 580         }
 581
 582         if(self.state == MONSTER_STATE_ATTACK_MELEE)
 583                 self.moveto = self.origin;
 584         else if(self.enemy)
 585                 self.moveto = self.moveto * 0.9 + ((self.origin + v_forward * 500) + randomvec() * 400) * 0.1;
 586
 587         if not(self.flags & FL_FLY || self.flags & FL_SWIM)
 588                 self.moveto_z = self.origin_z;
 589
 590         float l = vlen(self.moveto - self.origin);
 591         float t1 = trace_path(self.origin+'0 0 10', self.moveto+'0 0 10');
 592         float t2 = trace_path(self.origin-'0 0 15', self.moveto-'0 0 15');
 593
 594         if(self.flags & FL_FLY || self.flags & FL_SWIM)
 595                 v_forward = normalize(self.moveto - self.origin);
 596
 597         if(t1*l-t2*l>50 && (t1*l > 100 || t1 > 0.8))
 598         if(self.flags & FL_ONGROUND)
 599                 movelib_jump_simple(100);
 600
 601         if(vlen(self.origin - self.moveto) > 64)
 602         {
 603                 if(self.flags & FL_FLY || self.flags & FL_SWIM)
 604                         movelib_move_simple(v_forward, ((self.enemy) ? runspeed : walkspeed), 0.6);
 605                 else
 606                         movelib_move_simple_gravity(v_forward, ((self.enemy) ? runspeed : walkspeed), 0.6);
 607                 if(time > self.pain_finished)
 608                 if(time > self.attack_finished_single)
 609                 if(vlen(self.velocity) > 0)
 610                         monsters_setframe((self.enemy) ? manim_run : manim_walk);
 611                 else
 612                         monsters_setframe(manim_idle);
 613         }
 614         else
 615         {
 616                 entity e = find(world, targetname, self.target2);
 617                 if(e.target2)
 618                         self.target2 = e.target2;
 619                 else if(e.target)
 620                         self.target2 = e.target;
 621
 622                 movelib_beak_simple(stopspeed);
 623                 if(time > self.attack_finished_single)
 624                 if(time > self.pain_finished)
 625                 if (vlen(self.velocity) <= 30)
 626                         monsters_setframe(manim_idle);
 627         }
 628
 629         monster_checkattack(self, self.enemy);
 630
 631         if(self.angles != self.oldangles)
 632         {
 633                 self.oldangles = self.angles;
 634                 self.SendFlags |= MSF_ANG;
 635         }
 636
 637         if(self.origin != self.oldorigin)
 638         {
 639                 self.oldorigin = self.origin;
 640                 self.SendFlags |= MSF_MOVE;
 641         }
 642 }
 643
 644 void monster_dead_think()
 645 {
 646         self.think = monster_dead_think;
 647         self.nextthink = time + 0.3; // don't need to update so often now
 648
 649         self.deadflag = DEAD_DEAD;
 650
 651         if(time >= self.ltime)
 652         {
 653                 Monster_Fade();
 654                 return;
 655         }
 656
 657         self.SendFlags |= MSF_MOVE; // keep up to date on the monster's location
 658 }
 659
 660 void monsters_setstatus()
 661 {
 662         self.stat_monsters_total = monsters_total;
 663         self.stat_monsters_killed = monsters_killed;
 664 }
 665
 666 void Monster_Appear()
 667 {
 668         self.enemy = activator;
 669         self.spawnflags &~= MONSTERFLAG_APPEAR;
 670         self.monster_spawnfunc();
 671 }
 672
 673 float Monster_CheckAppearFlags(entity ent)
 674 {
 675         if not(ent.spawnflags & MONSTERFLAG_APPEAR)
 676                 return FALSE;
 677
 678         ent.think = func_null;
 679         ent.nextthink = 0;
 680         ent.use = Monster_Appear;
 681         ent.flags = FL_MONSTER; // set so this monster can get butchered
 682
 683         return TRUE;
 684 }
 685
 686 void monsters_reset()
 687 {
 688         setorigin(self, self.pos1);
 689         self.angles = self.pos2;
 690
 691         self.health = self.max_health;
 692         self.velocity = '0 0 0';
 693         self.enemy = world;
 694         self.goalentity = world;
 695         self.attack_finished_single = 0;
 696         self.moveto = self.origin;
 697
 698         WaypointSprite_UpdateHealth(self.sprite, self.health);
 699 }
 700
 701 float monster_send(entity to, float sf)
 702 {
 703         WriteByte(MSG_ENTITY, ENT_CLIENT_MONSTER);
 704         WriteByte(MSG_ENTITY, sf);
 705         if(sf & MSF_SETUP)
 706         {
 707             WriteByte(MSG_ENTITY, self.monsterid);
 708
 709             WriteCoord(MSG_ENTITY, self.origin_x);
 710             WriteCoord(MSG_ENTITY, self.origin_y);
 711             WriteCoord(MSG_ENTITY, self.origin_z);
 712
 713             WriteAngle(MSG_ENTITY, self.angles_x);
 714             WriteAngle(MSG_ENTITY, self.angles_y);
 715
 716                 WriteByte(MSG_ENTITY, self.skin);
 717                 WriteByte(MSG_ENTITY, self.team);
 718     }
 719
 720     if(sf & MSF_ANG)
 721     {
 722         WriteShort(MSG_ENTITY, rint(self.angles_x));
 723         WriteShort(MSG_ENTITY, rint(self.angles_y));
 724     }
 725
 726     if(sf & MSF_MOVE)
 727     {
 728         WriteShort(MSG_ENTITY, rint(self.origin_x));
 729         WriteShort(MSG_ENTITY, rint(self.origin_y));
 730         WriteShort(MSG_ENTITY, rint(self.origin_z));
 731
 732         WriteShort(MSG_ENTITY, rint(self.velocity_x));
 733         WriteShort(MSG_ENTITY, rint(self.velocity_y));
 734         WriteShort(MSG_ENTITY, rint(self.velocity_z));
 735
 736         WriteShort(MSG_ENTITY, rint(self.angles_y));
 737     }
 738
 739     if(sf & MSF_ANIM)
 740     {
 741         WriteCoord(MSG_ENTITY, self.anim_start_time);
 742         WriteByte(MSG_ENTITY, self.frame);
 743     }
 744
 745     if(sf & MSF_STATUS)
 746     {
 747                 WriteByte(MSG_ENTITY, self.skin);
 748
 749         WriteByte(MSG_ENTITY, self.team);
 750
 751                 WriteByte(MSG_ENTITY, self.deadflag);
 752
 753         if(self.health <= 0)
 754             WriteByte(MSG_ENTITY, 0);
 755         else
 756             WriteByte(MSG_ENTITY, ceil((self.health / self.max_health) * 255));
 757     }
 758
 759         return TRUE;
 760 }
 761
 762 void monster_link(void() spawnproc)
 763 {
 764     Net_LinkEntity(self, TRUE, 0, monster_send);
 765     self.think      = spawnproc;
 766     self.nextthink  = time;
 767 }
 768
 769 void monsters_corpse_damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 770 {
 771         self.health -= damage;
 772
 773         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 774
 775         if(self.health <= -100) // 100 health until gone?
 776         {
 777                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 778
 779                 self.think = SUB_Remove;
 780                 self.nextthink = time + 0.1;
 781         }
 782 }
 783
 784 void monster_die()
 785 {
 786         self.think = monster_dead_think;
 787         self.nextthink = self.ticrate;
 788         self.ltime = time + 5;
 789
 790         monster_dropitem();
 791
 792         WaypointSprite_Kill(self.sprite);
 793
 794         if(self.weaponentity)
 795         {
 796                 remove(self.weaponentity);
 797                 self.weaponentity = world;
 798         }
 799
 800         monster_sound(self.msound_death, 0, FALSE);
 801
 802         if(!(self.spawnflags & MONSTERFLAG_SPAWNED) && !self.monster_respawned)
 803                 monsters_killed += 1;
 804
 805         if(self.candrop && self.weapon)
 806                 W_ThrowNewWeapon(self, self.weapon, 0, self.origin, randomvec() * 150 + '0 0 325');
 807
 808         if(IS_CLIENT(self.realowner))
 809                 self.realowner.monstercount -= 1;
 810
 811         self.event_damage       = monsters_corpse_damage;
 812         self.solid                      = SOLID_CORPSE;
 813         self.takedamage         = DAMAGE_AIM;
 814         self.enemy                      = world;
 815         self.movetype           = MOVETYPE_TOSS;
 816         self.moveto                     = self.origin;
 817         self.touch                      = MonsterTouch; // reset incase monster was pouncing
 818
 819         if not(self.flags & FL_FLY)
 820                 self.velocity = '0 0 0';
 821
 822         self.SendFlags |= MSF_MOVE;
 823
 824         // number of monsters spawned with mobspawn command
 825         totalspawned -= 1;
 826
 827         MON_ACTION(self.monsterid, MR_DEATH);
 828 }
 829
 830 void monsters_damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 831 {
 832         if(self.frozen && deathtype != DEATH_KILL)
 833                 return;
 834
 835         if(time < self.pain_finished && deathtype != DEATH_KILL)
 836                 return;
 837
 838         if(time < self.spawnshieldtime)
 839                 return;
 840
 841         if(deathtype != DEATH_KILL)
 842                 damage *= self.armorvalue;
 843
 844         if(self.weaponentity && self.weaponentity.classname == "shield")
 845                 self.weaponentity.health -= damage;
 846
 847         self.health -= damage;
 848
 849         if(self.sprite)
 850                 WaypointSprite_UpdateHealth(self.sprite, self.health);
 851
 852         self.dmg_time = time;
 853
 854         if(sound_allowed(MSG_BROADCAST, attacker) && deathtype != DEATH_DROWN)
 855                 spamsound (self, CH_PAIN, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);  // FIXME: PLACEHOLDER
 856
 857         self.velocity += force * self.damageforcescale;
 858
 859         if(deathtype != DEATH_DROWN)
 860         {
 861                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 862                 if (damage > 50)
 863                         Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 864                 if (damage > 100)
 865                         Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 866         }
 867
 868         if(self.health <= 0)
 869         {
 870                 if(self.sprite)
 871                 {
 872                         // Update one more time to avoid waypoint fading without emptying healthbar
 873                         WaypointSprite_UpdateHealth(self.sprite, 0);
 874                 }
 875
 876                 if(deathtype == DEATH_KILL)
 877                         self.candrop = FALSE; // killed by mobkill command
 878
 879                 // TODO: fix this?
 880                 activator = attacker;
 881                 other = self.enemy;
 882                 SUB_UseTargets();
 883                 self.target2 = self.oldtarget2; // reset to original target on death, incase we respawn
 884
 885                 monster_die();
 886
 887                 frag_attacker = attacker;
 888                 frag_target = self;
 889                 MUTATOR_CALLHOOK(MonsterDies);
 890
 891                 if(self.health <= -100) // check if we're already gibbed
 892                 {
 893                         Violence_GibSplash(self, 1, 0.5, attacker);
 894
 895                         self.think = SUB_Remove;
 896                         self.nextthink = time + 0.1;
 897                 }
 898         }
 899
 900         self.SendFlags |= MSF_STATUS;
 901 }
 902
 903 void monster_think()
 904 {
 905         self.think = monster_think;
 906         self.nextthink = self.ticrate;
 907
 908         MON_ACTION(self.monsterid, MR_THINK);
 909 }
 910
 911 void monster_spawn()
 912 {
 913         MON_ACTION(self.monsterid, MR_SETUP);
 914
 915         if not(self.monster_respawned)
 916                 Monster_CheckMinibossFlag();
 917
 918         self.max_health = self.health;
 919         self.pain_finished = self.nextthink;
 920         self.anim_start_time = time;
 921
 922         if not(self.noalign)
 923         {
 924                 setorigin(self, self.origin + '0 0 20');
 925                 tracebox(self.origin + '0 0 100', self.mins, self.maxs, self.origin - '0 0 10000', MOVE_WORLDONLY, self);
 926                 setorigin(self, trace_endpos);
 927         }
 928
 929         if not(self.monster_respawned)
 930         if not(self.skin)
 931                 self.skin = rint(random() * 4);
 932
 933         if not(self.attack_range)
 934                 self.attack_range = autocvar_g_monsters_attack_range;
 935
 936         self.pos1 = self.origin;
 937
 938         monster_setupsounds(self.netname);
 939
 940         monster_precachesounds(self);
 941
 942         if(teamplay)
 943                 self.monster_attack = TRUE; // we can have monster enemies in team games
 944
 945         if(autocvar_g_monsters_healthbars)
 946         {
 947                 WaypointSprite_Spawn(strzone(strdecolorize(self.monster_name)), 0, 600, self, '0 0 1' * (self.maxs_z + 15), world, 0, self, sprite, FALSE, RADARICON_DANGER, ((self.team) ? Team_ColorRGB(self.team) : '1 0 0'));
 948                 WaypointSprite_UpdateMaxHealth(self.sprite, self.max_health);
 949                 WaypointSprite_UpdateHealth(self.sprite, self.health);
 950         }
 951
 952         monster_sound(self.msound_spawn, 0, FALSE);
 953
 954         MUTATOR_CALLHOOK(MonsterSpawn);
 955
 956         self.think = monster_think;
 957         self.nextthink = time + self.ticrate;
 958
 959         self.SendFlags = MSF_SETUP;
 960 }
 961
 962 float monster_initialize(float mon_id, float nodrop)
 963 {
 964         if not(autocvar_g_monsters)
 965                 return FALSE;
 966
 967         vector min_s, max_s;
 968         entity mon = get_monsterinfo(mon_id);
 969
 970         // support for quake style removing monsters based on skill
 971         if(monster_skill <= autocvar_g_monsters_skill_easy && (self.spawnflags & MONSTERSKILL_NOTEASY)) { return FALSE; }
 972         if(monster_skill == autocvar_g_monsters_skill_normal && (self.spawnflags & MONSTERSKILL_NOTMEDIUM)) { return FALSE; }
 973         if(monster_skill == autocvar_g_monsters_skill_hard && (self.spawnflags & MONSTERSKILL_NOTHARD)) { return FALSE; }
 974         if(monster_skill == autocvar_g_monsters_skill_insane && (self.spawnflags & MONSTERSKILL_NOTINSANE)) { return FALSE; }
 975         if(monster_skill >= autocvar_g_monsters_skill_nightmare && (self.spawnflags & MONSTERSKILL_NOTNIGHTMARE)) { return FALSE; }
 976
 977         if(self.monster_name == "")
 978                 self.monster_name = M_NAME(mon_id);
 979
 980         if(self.team && !teamplay)
 981                 self.team = 0;
 982
 983         self.flags = FL_MONSTER;
 984
 985         if not(self.spawnflags & MONSTERFLAG_SPAWNED) // naturally spawned monster
 986         if not(self.monster_respawned)
 987                 monsters_total += 1;
 988
 989         min_s = mon.mins;
 990         max_s = mon.maxs;
 991
 992         self.netname = mon.netname;
 993
 994         setsize(self, min_s, max_s);
 995         self.takedamage                 = DAMAGE_AIM;
 996         self.bot_attack                 = TRUE;
 997         self.iscreature                 = TRUE;
 998         self.teleportable               = TRUE;
 999         self.damagedbycontents  = TRUE;
1000         self.monsterid                  = mon_id;
1001         self.damageforcescale   = 0;
1002         self.event_damage               = monsters_damage;
1003         self.touch                              = MonsterTouch;
1004         self.use                                = monster_use;
1005         self.solid                              = SOLID_BBOX;
1006         self.movetype                   = MOVETYPE_WALK;
1007         self.spawnshieldtime    = time + autocvar_g_monsters_spawnshieldtime;
1008         monsters_spawned           += 1;
1009         self.enemy                              = world;
1010         self.velocity                   = '0 0 0';
1011         self.moveto                             = self.origin;
1012         self.pos2                               = self.angles;
1013         self.reset                              = monsters_reset;
1014         self.candrop                    = TRUE;
1015         self.view_ofs                   = '0 0 1' * (self.maxs_z * 0.5);
1016         self.oldtarget2                 = self.target2;
1017         self.deadflag                   = DEAD_NO;
1018         self.noalign                    = nodrop;
1019         self.spawn_time                 = time;
1020         self.gravity                    = 1;
1021         self.dphitcontentsmask  = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_BOTCLIP | DPCONTENTS_MONSTERCLIP;
1022
1023         if(mon.spawnflags & MONSTER_TYPE_SWIM)
1024                 self.flags |= FL_SWIM;
1025
1026         if(mon.spawnflags & MONSTER_TYPE_FLY)
1027         {
1028                 self.flags |= FL_FLY;
1029                 self.movetype = MOVETYPE_FLY;
1030         }
1031
1032         if not(self.scale)
1033                 self.scale = 1;
1034
1035         if(mon.spawnflags & MONSTER_SIZE_BROKEN)
1036                 self.scale = 1.3;
1037
1038         if not(self.ticrate)
1039                 self.ticrate = autocvar_g_monsters_think_delay;
1040
1041         self.ticrate = bound(sys_frametime, self.ticrate, 60);
1042
1043         if not(self.armorvalue)
1044                 self.armorvalue = 1; // multiplier
1045
1046         if not(self.target_range)
1047                 self.target_range = autocvar_g_monsters_target_range;
1048
1049         if not(self.respawntime)
1050                 self.respawntime = autocvar_g_monsters_respawn_delay;
1051
1052         if not(self.monster_moveflags)
1053                 self.monster_moveflags = MONSTER_MOVE_WANDER;
1054
1055         monster_link(monster_spawn);
1056
1057         return TRUE;
1058 }