qcsrc/common/monsters/sv_monsters.qc

   1 // =========================
   2 //  SVQC Monster Properties
   3 // =========================
   4
   5
   6 void M_Item_Touch ()
   7 {
   8         if(self && IS_PLAYER(other) && other.deadflag == DEAD_NO)
   9         {
  10                 Item_Touch();
  11                 self.think = SUB_Remove;
  12                 self.nextthink = time + 0.1;
  13         }
  14 }
  15
  16 void monster_item_spawn()
  17 {
  18         if(self.monster_loot)
  19                 self.monster_loot();
  20
  21         self.gravity = 1;
  22         self.velocity = randomvec() * 175 + '0 0 325';
  23         self.touch = M_Item_Touch;
  24
  25         SUB_SetFade(self, time + autocvar_g_monsters_drop_time, 1);
  26 }
  27
  28 void monster_dropitem()
  29 {
  30         if(!self.candrop || !self.monster_loot)
  31                 return;
  32
  33         vector org = self.origin + ((self.mins + self.maxs) * 0.5);
  34         entity e = spawn();
  35
  36         setorigin(e, org);
  37
  38         e.monster_loot = self.monster_loot;
  39
  40         other = e;
  41         MUTATOR_CALLHOOK(MonsterDropItem);
  42         e = other;
  43
  44         e.think = monster_item_spawn;
  45         e.nextthink = time + 0.3;
  46 }
  47
  48 void monsters_setframe(float _frame)
  49 {
  50         if(self.frame == _frame)
  51                 return;
  52
  53         self.anim_start_time = time;
  54         self.frame = _frame;
  55         self.SendFlags |= MSF_ANIM;
  56 }
  57
  58 float monster_isvalidtarget (entity targ, entity ent)
  59 {
  60         if(!targ || !ent)
  61                 return FALSE; // someone doesn't exist
  62
  63         if(targ == ent)
  64                 return FALSE; // don't attack ourselves
  65
  66         traceline(ent.origin, targ.origin, MOVE_NORMAL, ent);
  67
  68         if(trace_ent != targ)
  69                 return FALSE;
  70
  71         if(targ.vehicle_flags & VHF_ISVEHICLE)
  72         if not((get_monsterinfo(ent.monsterid)).spawnflags & MON_FLAG_RANGED)
  73                 return FALSE; // melee attacks are useless against vehicles
  74
  75         if(time < game_starttime)
  76                 return FALSE; // monsters do nothing before the match has started
  77
  78         if(vlen(targ.origin - ent.origin) >= ent.target_range)
  79                 return FALSE; // enemy is too far away
  80
  81         if(targ.takedamage == DAMAGE_NO)
  82                 return FALSE; // enemy can't be damaged
  83
  84         if(targ.items & IT_INVISIBILITY)
  85                 return FALSE; // enemy is invisible
  86
  87         if(substring(targ.classname, 0, 10) == "onslaught_")
  88                 return FALSE; // don't attack onslaught targets
  89
  90         if(IS_SPEC(targ) || IS_OBSERVER(targ))
  91                 return FALSE; // enemy is a spectator
  92
  93         if not(targ.vehicle_flags & VHF_ISVEHICLE)
  94         if(targ.deadflag != DEAD_NO || ent.deadflag != DEAD_NO || targ.health <= 0 || ent.health <= 0)
  95                 return FALSE; // enemy/self is dead
  96
  97         if(ent.monster_owner == targ)
  98                 return FALSE; // don't attack our master
  99
 100         if(targ.monster_owner == ent)
 101                 return FALSE; // don't attack our pet
 102
 103         if not(targ.vehicle_flags & VHF_ISVEHICLE)
 104         if(targ.flags & FL_NOTARGET)
 105                 return FALSE; // enemy can't be targeted
 106
 107         if not(autocvar_g_monsters_typefrag)
 108         if(targ.BUTTON_CHAT)
 109                 return FALSE; // no typefragging!
 110
 111         if not(IsDifferentTeam(targ, ent))
 112                 return FALSE; // enemy is on our team
 113
 114         if(autocvar_g_monsters_target_infront || ent.spawnflags & MONSTERFLAG_INFRONT)
 115         if(ent.enemy != targ)
 116         {
 117                 float dot;
 118
 119                 makevectors (ent.angles);
 120                 dot = normalize (targ.origin - ent.origin) * v_forward;
 121
 122                 if(dot <= 0.3)
 123                         return FALSE;
 124         }
 125
 126         return TRUE;
 127 }
 128
 129 entity FindTarget (entity ent)
 130 {
 131         if(MUTATOR_CALLHOOK(MonsterFindTarget)) { return ent.enemy; } // Handled by a mutator
 132
 133         entity head, closest_target = world;
 134         head = findradius(ent.origin, ent.target_range);
 135
 136         while(head) // find the closest acceptable target to pass to
 137         {
 138                 if(head.monster_attack)
 139                 if(monster_isvalidtarget(head, ent))
 140                 {
 141                         // if it's a player, use the view origin as reference (stolen from RadiusDamage functions in g_damage.qc)
 142                         vector head_center = CENTER_OR_VIEWOFS(head);
 143                         vector ent_center = CENTER_OR_VIEWOFS(ent);
 144
 145                         //if(ctf_CheckPassDirection(head_center, ent_center, ent.v_angle, head.WarpZone_findradius_nearest))
 146                         if(closest_target)
 147                         {
 148                                 vector closest_target_center = CENTER_OR_VIEWOFS(closest_target);
 149                                 if(vlen(ent_center - head_center) < vlen(ent_center - closest_target_center))
 150                                         { closest_target = head; }
 151                         }
 152                         else { closest_target = head; }
 153                 }
 154
 155                 head = head.chain;
 156         }
 157
 158         return closest_target;
 159 }
 160
 161 void MonsterTouch ()
 162 {
 163         if(other == world)
 164                 return;
 165
 166         if(self.enemy != other)
 167         if not(other.flags & FL_MONSTER)
 168         if(monster_isvalidtarget(other, self))
 169                 self.enemy = other;
 170 }
 171
 172 string get_monster_model_datafilename(string m, float sk, string fil)
 173 {
 174         if(m)
 175                 m = strcat(m, "_");
 176         else
 177                 m = "models/monsters/*_";
 178         if(sk >= 0)
 179                 m = strcat(m, ftos(sk));
 180         else
 181                 m = strcat(m, "*");
 182         return strcat(m, ".", fil);
 183 }
 184
 185 void PrecacheMonsterSounds(string f)
 186 {
 187         float fh;
 188         string s;
 189         fh = fopen(f, FILE_READ);
 190         if(fh < 0)
 191                 return;
 192         while((s = fgets(fh)))
 193         {
 194                 if(tokenize_console(s) != 3)
 195                 {
 196                         dprint("Invalid sound info line: ", s, "\n");
 197                         continue;
 198                 }
 199                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
 200         }
 201         fclose(fh);
 202 }
 203
 204 void precache_monstersounds()
 205 {
 206         string m = (get_monsterinfo(self.monsterid)).model;
 207         float globhandle, n, i;
 208         string f;
 209
 210         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
 211         if (globhandle < 0)
 212                 return;
 213         n = search_getsize(globhandle);
 214         for (i = 0; i < n; ++i)
 215         {
 216                 //print(search_getfilename(globhandle, i), "\n");
 217                 f = search_getfilename(globhandle, i);
 218                 PrecacheMonsterSounds(f);
 219         }
 220         search_end(globhandle);
 221 }
 222
 223 void ClearMonsterSounds()
 224 {
 225 #define _MSOUND(m) if(self.monstersound_##m) { strunzone(self.monstersound_##m); self.monstersound_##m = string_null; }
 226         ALLMONSTERSOUNDS
 227 #undef _MSOUND
 228 }
 229
 230 .string GetMonsterSoundSampleField(string type)
 231 {
 232         GetMonsterSoundSampleField_notFound = 0;
 233         switch(type)
 234         {
 235 #define _MSOUND(m) case #m: return monstersound_##m;
 236                 ALLMONSTERSOUNDS
 237 #undef _MSOUND
 238         }
 239         GetMonsterSoundSampleField_notFound = 1;
 240         return string_null;
 241 }
 242
 243 float LoadMonsterSounds(string f, float first)
 244 {
 245         float fh;
 246         string s;
 247         var .string field;
 248         fh = fopen(f, FILE_READ);
 249         if(fh < 0)
 250         {
 251                 dprint("Monster sound file not found: ", f, "\n");
 252                 return 0;
 253         }
 254         while((s = fgets(fh)))
 255         {
 256                 if(tokenize_console(s) != 3)
 257                         continue;
 258                 field = GetMonsterSoundSampleField(argv(0));
 259                 if(GetMonsterSoundSampleField_notFound)
 260                         continue;
 261                 if(self.field)
 262                         strunzone(self.field);
 263                 self.field = strzone(strcat(argv(1), " ", argv(2)));
 264         }
 265         fclose(fh);
 266         return 1;
 267 }
 268
 269 .float skin_for_monstersound;
 270 void UpdateMonsterSounds()
 271 {
 272         entity mon = get_monsterinfo(self.monsterid);
 273
 274         if(self.skin == self.skin_for_monstersound)
 275                 return;
 276         self.skin_for_monstersound = self.skin;
 277         ClearMonsterSounds();
 278         //LoadMonsterSounds("sound/monsters/default.sounds", 1);
 279         if(!autocvar_g_debug_defaultsounds)
 280         if(!LoadMonsterSounds(get_monster_model_datafilename(mon.model, self.skin, "sounds"), 0))
 281                 LoadMonsterSounds(get_monster_model_datafilename(mon.model, 0, "sounds"), 0);
 282 }
 283
 284 void MonsterSound(.string samplefield, float sound_delay, float delaytoo, float chan)
 285 {
 286         if(delaytoo && time < self.msound_delay)
 287                 return; // too early
 288         GlobalSound(self.samplefield, chan, VOICETYPE_PLAYERSOUND);
 289
 290         self.msound_delay = time + sound_delay;
 291 }
 292
 293 void monster_makevectors(entity e)
 294 {
 295         vector v;
 296
 297         v = CENTER_OR_VIEWOFS(e);
 298         self.v_angle = vectoangles(v - (self.origin + self.view_ofs));
 299         self.v_angle_x = -self.v_angle_x;
 300
 301         makevectors(self.v_angle);
 302 }
 303
 304 float monster_melee(entity targ, float damg, float anim, float er, float anim_finished, float deathtype, float dostop)
 305 {
 306         float rdmg = damg * random();
 307
 308         if (self.health <= 0)
 309                 return FALSE; // attacking while dead?!
 310
 311         if(dostop)
 312         {
 313                 self.velocity_x = 0;
 314                 self.velocity_y = 0;
 315                 self.state = MONSTER_STATE_ATTACK_MELEE;
 316                 self.SendFlags |= MSF_MOVE;
 317         }
 318
 319         monsters_setframe(anim);
 320
 321         if(anim_finished != 0)
 322                 self.attack_finished_single = time + anim_finished;
 323
 324         monster_makevectors(targ);
 325
 326         traceline(self.origin + self.view_ofs, self.origin + v_forward * er, 0, self);
 327
 328         if(trace_ent.takedamage)
 329                 Damage(trace_ent, self, self, rdmg * monster_skill, deathtype, trace_ent.origin, normalize(trace_ent.origin - self.origin));
 330
 331         return TRUE;
 332 }
 333
 334 void Monster_CheckMinibossFlag ()
 335 {
 336         if(MUTATOR_CALLHOOK(MonsterCheckBossFlag))
 337                 return;
 338
 339         float chance = random() * 100;
 340
 341         // g_monsters_miniboss_chance cvar or spawnflags 64 causes a monster to be a miniboss
 342         if ((self.spawnflags & MONSTERFLAG_MINIBOSS) || (chance < autocvar_g_monsters_miniboss_chance))
 343         {
 344                 self.health += autocvar_g_monsters_miniboss_healthboost;
 345                 if not(self.weapon)
 346                         self.weapon = WEP_NEX;
 347         }
 348 }
 349
 350 float Monster_CanRespawn(entity ent)
 351 {
 352         other = ent;
 353         if(MUTATOR_CALLHOOK(MonsterRespawn))
 354                 return TRUE; // enabled by a mutator
 355
 356         if(ent.spawnflags & MONSTERFLAG_NORESPAWN)
 357                 return FALSE;
 358
 359         if not(autocvar_g_monsters_respawn)
 360                 return FALSE;
 361
 362         return TRUE;
 363 }
 364
 365 void Monster_Fade ()
 366 {
 367         if(Monster_CanRespawn(self))
 368         {
 369                 self.monster_respawned = TRUE;
 370                 self.think = self.monster_spawnfunc;
 371                 self.nextthink = time + self.respawntime;
 372                 self.deadflag = DEAD_RESPAWNING;
 373                 if(self.spawnflags & MONSTER_RESPAWN_DEATHPOINT)
 374                 {
 375                         self.pos1 = self.origin;
 376                         self.pos2 = self.angles;
 377                 }
 378                 self.event_damage = func_null;
 379                 self.takedamage = DAMAGE_NO;
 380                 setorigin(self, self.pos1);
 381                 self.angles = self.pos2;
 382                 self.health = self.max_health;
 383
 384                 self.SendFlags |= MSF_MOVE;
 385                 self.SendFlags |= MSF_STATUS;
 386         }
 387         else
 388                 SUB_SetFade(self, time + 3, 1);
 389 }
 390
 391 float Monster_CanJump (vector vel)
 392 {
 393         if(self.state)
 394                 return FALSE; // already attacking
 395         if not(self.flags & FL_ONGROUND)
 396                 return FALSE; // not on the ground
 397         if(self.health <= 0)
 398                 return FALSE; // called when dead?
 399         if(time < self.attack_finished_single)
 400                 return FALSE; // still attacking
 401
 402         vector old = self.velocity;
 403
 404         self.velocity = vel;
 405         tracetoss(self, self);
 406         self.velocity = old;
 407         if (trace_ent != self.enemy)
 408                 return FALSE;
 409
 410         return TRUE;
 411 }
 412
 413 float monster_leap (float anm, void() touchfunc, vector vel, float anim_finished)
 414 {
 415         if(!Monster_CanJump(vel))
 416                 return FALSE;
 417
 418         monsters_setframe(anm);
 419         self.state = MONSTER_STATE_ATTACK_LEAP;
 420         self.touch = touchfunc;
 421         self.origin_z += 1;
 422         self.velocity = vel;
 423         self.flags &= ~FL_ONGROUND;
 424
 425         self.attack_finished_single = time + anim_finished;
 426
 427         return TRUE;
 428 }
 429
 430 void monster_checkattack(entity e, entity targ)
 431 {
 432         if(e == world)
 433                 return;
 434         if(targ == world)
 435                 return;
 436
 437         if not(e.monster_attackfunc)
 438                 return;
 439
 440         if(time < e.attack_finished_single)
 441                 return;
 442
 443         if(vlen(targ.origin - e.origin) <= e.attack_range)
 444         if(e.monster_attackfunc(MONSTER_ATTACK_MELEE))
 445         {
 446                 MonsterSound(monstersound_melee, 0, FALSE, CH_VOICE);
 447                 return;
 448         }
 449
 450         if(vlen(targ.origin - e.origin) > e.attack_range)
 451         if(e.monster_attackfunc(MONSTER_ATTACK_RANGED))
 452         {
 453                 MonsterSound(monstersound_ranged, 0, FALSE, CH_VOICE);
 454                 return;
 455         }
 456 }
 457
 458 void monster_use ()
 459 {
 460         if not(self.enemy)
 461         if(self.health > 0)
 462         if(monster_isvalidtarget(activator, self))
 463                 self.enemy = activator;
 464 }
 465
 466 .float last_trace;
 467 .float last_enemycheck; // for checking enemy
 468 vector monster_pickmovetarget(entity targ)
 469 {
 470         // enemy is always preferred target
 471         if(self.enemy)
 472         {
 473                 makevectors(self.angles);
 474                 self.monster_movestate = MONSTER_MOVE_ENEMY;
 475                 self.last_trace = time + 1.2;
 476                 return self.enemy.origin;
 477         }
 478
 479         switch(self.monster_moveflags)
 480         {
 481                 case MONSTER_MOVE_OWNER:
 482                 {
 483                         self.monster_movestate = MONSTER_MOVE_OWNER;
 484                         self.last_trace = time + 0.3;
 485                         return (self.monster_owner) ? self.monster_owner.origin : self.origin;
 486                 }
 487                 case MONSTER_MOVE_SPAWNLOC:
 488                 {
 489                         self.monster_movestate = MONSTER_MOVE_SPAWNLOC;
 490                         self.last_trace = time + 2;
 491                         return self.pos1;
 492                 }
 493                 case MONSTER_MOVE_NOMOVE:
 494                 {
 495                         self.monster_movestate = MONSTER_MOVE_NOMOVE;
 496                         self.last_trace = time + 2;
 497                         return self.origin;
 498                 }
 499                 default:
 500                 case MONSTER_MOVE_WANDER:
 501                 {
 502                         vector pos;
 503                         self.monster_movestate = MONSTER_MOVE_WANDER;
 504                         self.last_trace = time + 2;
 505
 506                         self.angles_y = rint(random() * 500);
 507                         makevectors(self.angles);
 508                         pos = self.origin + v_forward * 600;
 509
 510                         if(self.flags & FL_FLY || self.flags & FL_SWIM)
 511                         if(self.spawnflags & MONSTERFLAG_FLY_VERTICAL)
 512                         {
 513                                 pos_z = random() * 200;
 514                                 if(random() >= 0.5)
 515                                         pos_z *= -1;
 516                         }
 517
 518                         if(targ)
 519                         {
 520                                 self.last_trace = time + 0.5;
 521                                 pos = targ.origin;
 522                         }
 523
 524                         return pos;
 525                 }
 526         }
 527 }
 528
 529 void monster_move(float runspeed, float walkspeed, float stopspeed, float manim_run, float manim_walk, float manim_idle)
 530 {
 531         fixedmakevectors(self.angles);
 532
 533         if(self.target2)
 534                 self.goalentity = find(world, targetname, self.target2);
 535
 536         entity targ;
 537
 538         if(self.frozen)
 539         {
 540                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
 541                 self.health = max(1, self.max_health * self.revive_progress);
 542
 543                 self.SendFlags |= MSF_STATUS;
 544
 545                 movelib_beak_simple(stopspeed);
 546
 547                 self.velocity = '0 0 0';
 548                 self.enemy = world;
 549                 self.nextthink = time + 0.1;
 550
 551                 if(self.revive_progress >= 1)
 552                         Unfreeze(self); // wait for next think before attacking
 553
 554                 // don't bother updating angles here?
 555                 if(self.origin != self.oldorigin)
 556                 {
 557                         self.oldorigin = self.origin;
 558                         self.SendFlags |= MSF_MOVE;
 559                 }
 560
 561                 return; // no moving while frozen
 562         }
 563
 564         if(self.flags & FL_SWIM)
 565         {
 566                 if(self.waterlevel < WATERLEVEL_WETFEET)
 567                 {
 568                         if(time >= self.last_trace)
 569                         {
 570                                 self.fish_wasdrowning = TRUE;
 571                                 self.last_trace = time + 0.4;
 572
 573                                 Damage (self, world, world, 2, DEATH_DROWN, self.origin, '0 0 0');
 574                                 self.angles = '90 90 0';
 575                                 if(random() < 0.5)
 576                                 {
 577                                         self.velocity_y += random() * 50;
 578                                         self.velocity_x -= random() * 50;
 579                                 }
 580                                 else
 581                                 {
 582                                         self.velocity_y -= random() * 50;
 583                                         self.velocity_x += random() * 50;
 584                                 }
 585                                 self.velocity_z += random() * 150;
 586                         }
 587
 588
 589                         self.movetype = MOVETYPE_BOUNCE;
 590                         //self.velocity_z = -200;
 591
 592                         self.SendFlags |= MSF_MOVE | MSF_ANG;
 593
 594                         return;
 595                 }
 596                 else if(self.fish_wasdrowning)
 597                 {
 598                         self.fish_wasdrowning = FALSE;
 599                         self.angles_x = 0;
 600                         self.movetype = MOVETYPE_WALK;
 601                 }
 602         }
 603
 604         targ = self.goalentity;
 605
 606         monster_target = targ;
 607         monster_speed_run = runspeed;
 608         monster_speed_walk = walkspeed;
 609
 610         if(MUTATOR_CALLHOOK(MonsterMove) || gameover || (round_handler_IsActive() && !round_handler_IsRoundStarted()) || time < game_starttime || (autocvar_g_campaign && !campaign_bots_may_start) || time < self.spawn_time)
 611         {
 612                 runspeed = walkspeed = 0;
 613                 if(time >= self.spawn_time)
 614                         monsters_setframe(manim_idle);
 615                 movelib_beak_simple(stopspeed);
 616                 if(self.oldorigin != self.origin)
 617                 {
 618                         self.oldorigin = self.origin;
 619                         self.SendFlags |= MSF_MOVE;
 620                 }
 621                 return;
 622         }
 623
 624         targ = monster_target;
 625         runspeed = monster_speed_run;
 626         walkspeed = monster_speed_walk;
 627
 628         if(teamplay)
 629         if(autocvar_g_monsters_teams)
 630         if(IsDifferentTeam(self.monster_owner, self))
 631                 self.monster_owner = world;
 632
 633         if(self.enemy && self.enemy.health < 1)
 634                 self.enemy = world; // enough!
 635
 636         if(time >= self.last_enemycheck)
 637         {
 638                 if not(monster_isvalidtarget(self.enemy, self))
 639                         self.enemy = world;
 640
 641                 if not(self.enemy)
 642                 {
 643                         self.enemy = FindTarget(self);
 644                         if(self.enemy)
 645                                 MonsterSound(monstersound_sight, 0, FALSE, CH_VOICE);
 646                 }
 647
 648                 self.last_enemycheck = time + 0.5;
 649         }
 650
 651         if(self.state == MONSTER_STATE_ATTACK_MELEE && time >= self.attack_finished_single)
 652                 self.state = 0;
 653
 654         if(self.state != MONSTER_STATE_ATTACK_MELEE) // don't move if set
 655         if(time >= self.last_trace || self.enemy) // update enemy instantly
 656                 self.moveto = monster_pickmovetarget(targ);
 657
 658         if not(self.enemy)
 659                 MonsterSound(monstersound_idle, 5, TRUE, CH_VOICE);
 660
 661         if(self.state != MONSTER_STATE_ATTACK_LEAP && self.state != MONSTER_STATE_ATTACK_MELEE)
 662                 self.steerto = steerlib_attract2(self.moveto, 0.5, 500, 0.95);
 663
 664         if(self.state == MONSTER_STATE_ATTACK_LEAP && (self.flags & FL_ONGROUND))
 665         {
 666                 self.state = 0;
 667                 self.touch = MonsterTouch;
 668         }
 669
 670         //self.steerto = steerlib_attract2(self.moveto, 0.5, 500, 0.95);
 671
 672         float turny = 0;
 673         vector real_angle = vectoangles(self.steerto) - self.angles;
 674
 675         if(self.state != MONSTER_STATE_ATTACK_LEAP && self.state != MONSTER_STATE_ATTACK_MELEE)
 676                 turny = 20;
 677
 678         if(self.flags & FL_SWIM)
 679                 turny = vlen(self.angles - self.moveto);
 680
 681         if(turny)
 682         {
 683                 turny = bound(turny * -1, shortangle_f(real_angle_y, self.angles_y), turny);
 684                 self.angles_y += turny;
 685         }
 686
 687         if(self.state == MONSTER_STATE_ATTACK_MELEE)
 688                 self.moveto = self.origin;
 689
 690         if(self.enemy && self.enemy.vehicle)
 691                 runspeed = 0;
 692
 693         if(((self.flags & FL_FLY) || (self.flags & FL_SWIM)) && self.spawnflags & MONSTERFLAG_FLY_VERTICAL)
 694                 v_forward = normalize(self.moveto - self.origin);
 695         else
 696                 self.moveto_z = self.origin_z;
 697
 698         if(vlen(self.origin - self.moveto) > 64)
 699         {
 700                 if(self.flags & FL_FLY || self.flags & FL_SWIM)
 701                         movelib_move_simple(v_forward, ((self.enemy) ? runspeed : walkspeed), 0.6);
 702                 else
 703                         movelib_move_simple_gravity(v_forward, ((self.enemy) ? runspeed : walkspeed), 0.6);
 704
 705                 if(time > self.pain_finished)
 706                 if(time > self.attack_finished_single)
 707                 if(vlen(self.velocity) > 10)
 708                         monsters_setframe((self.enemy) ? manim_run : manim_walk);
 709                 else
 710                         monsters_setframe(manim_idle);
 711         }
 712         else
 713         {
 714                 entity e = find(world, targetname, self.target2);
 715                 if(e.target2)
 716                         self.target2 = e.target2;
 717                 else if(e.target)
 718                         self.target2 = e.target;
 719
 720                 movelib_beak_simple(stopspeed);
 721                 if(time > self.attack_finished_single)
 722                 if(time > self.pain_finished)
 723                 if (vlen(self.velocity) <= 30)
 724                         monsters_setframe(manim_idle);
 725         }
 726
 727         monster_checkattack(self, self.enemy);
 728
 729         if(self.angles != self.oldangles)
 730         {
 731                 self.oldangles = self.angles;
 732                 self.SendFlags |= MSF_ANG;
 733         }
 734
 735         if(self.origin != self.oldorigin)
 736         {
 737                 self.oldorigin = self.origin;
 738                 self.SendFlags |= MSF_MOVE;
 739         }
 740 }
 741
 742 void monster_dead_think()
 743 {
 744         self.think = monster_dead_think;
 745         self.nextthink = time + self.ticrate;
 746
 747         self.deadflag = DEAD_DEAD;
 748
 749         if(self.ltime != 0)
 750         if(time >= self.ltime)
 751         {
 752                 Monster_Fade();
 753                 return;
 754         }
 755
 756         if(self.oldorigin != self.origin)
 757         {
 758                 self.oldorigin = self.origin;
 759                 self.SendFlags |= MSF_MOVE;
 760         }
 761 }
 762
 763 void monsters_setstatus()
 764 {
 765         self.stat_monsters_total = monsters_total;
 766         self.stat_monsters_killed = monsters_killed;
 767 }
 768
 769 void Monster_Appear()
 770 {
 771         self.enemy = activator;
 772         self.spawnflags &= ~MONSTERFLAG_APPEAR;
 773         self.monster_spawnfunc();
 774 }
 775
 776 float Monster_CheckAppearFlags(entity ent)
 777 {
 778         if not(ent.spawnflags & MONSTERFLAG_APPEAR)
 779                 return FALSE;
 780
 781         ent.think = func_null;
 782         ent.nextthink = 0;
 783         ent.use = Monster_Appear;
 784         ent.flags = FL_MONSTER; // set so this monster can get butchered
 785
 786         return TRUE;
 787 }
 788
 789 void monsters_reset()
 790 {
 791         setorigin(self, self.pos1);
 792         self.angles = self.pos2;
 793
 794         self.health = self.max_health;
 795         self.velocity = '0 0 0';
 796         self.enemy = world;
 797         self.goalentity = world;
 798         self.attack_finished_single = 0;
 799         self.moveto = self.origin;
 800
 801         self.SendFlags |= MSF_STATUS;
 802 }
 803
 804 float monster_send(entity to, float sf)
 805 {
 806         WriteByte(MSG_ENTITY, ENT_CLIENT_MONSTER);
 807         WriteByte(MSG_ENTITY, sf);
 808         if(sf & MSF_SETUP)
 809         {
 810                 WriteByte(MSG_ENTITY, self.monsterid);
 811
 812                 WriteCoord(MSG_ENTITY, self.origin_x);
 813                 WriteCoord(MSG_ENTITY, self.origin_y);
 814                 WriteCoord(MSG_ENTITY, self.origin_z);
 815
 816                 WriteAngle(MSG_ENTITY, self.angles_x);
 817                 WriteAngle(MSG_ENTITY, self.angles_y);
 818
 819                 WriteByte(MSG_ENTITY, self.skin);
 820                 WriteByte(MSG_ENTITY, self.team);
 821         }
 822
 823         if(sf & MSF_ANG)
 824         {
 825                 WriteShort(MSG_ENTITY, rint(self.angles_x));
 826                 WriteShort(MSG_ENTITY, rint(self.angles_y));
 827         }
 828
 829         if(sf & MSF_MOVE)
 830         {
 831                 WriteShort(MSG_ENTITY, rint(self.origin_x));
 832                 WriteShort(MSG_ENTITY, rint(self.origin_y));
 833                 WriteShort(MSG_ENTITY, rint(self.origin_z));
 834
 835                 WriteShort(MSG_ENTITY, rint(self.velocity_x));
 836                 WriteShort(MSG_ENTITY, rint(self.velocity_y));
 837                 WriteShort(MSG_ENTITY, rint(self.velocity_z));
 838
 839                 WriteShort(MSG_ENTITY, rint(self.angles_y));
 840         }
 841
 842         if(sf & MSF_ANIM)
 843         {
 844                 WriteCoord(MSG_ENTITY, self.anim_start_time);
 845                 WriteByte(MSG_ENTITY, self.frame);
 846         }
 847
 848         if(sf & MSF_STATUS)
 849         {
 850                 WriteByte(MSG_ENTITY, self.skin);
 851
 852                 WriteByte(MSG_ENTITY, self.team);
 853
 854                 WriteByte(MSG_ENTITY, self.deadflag);
 855
 856                 if(self.health <= 0)
 857                         WriteByte(MSG_ENTITY, 0);
 858                 else
 859                         WriteByte(MSG_ENTITY, ceil((self.health / self.max_health) * 255));
 860         }
 861
 862         return TRUE;
 863 }
 864
 865 void monster_link(void() spawnproc)
 866 {
 867         Net_LinkEntity(self, TRUE, 0, monster_send);
 868         self.think        = spawnproc;
 869         self.nextthink  = time;
 870 }
 871
 872 void monsters_corpse_damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 873 {
 874         self.health -= damage;
 875
 876         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 877
 878         if(self.health <= -100) // 100 health until gone?
 879         {
 880                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 881
 882                 self.think = SUB_Remove;
 883                 self.nextthink = time + 0.1;
 884         }
 885 }
 886
 887 void monster_die()
 888 {
 889         self.think = monster_dead_think;
 890         self.nextthink = self.ticrate;
 891         self.ltime = time + 5;
 892
 893         monster_dropitem();
 894
 895         MonsterSound(monstersound_death, 0, FALSE, CH_VOICE);
 896
 897         if(!(self.spawnflags & MONSTERFLAG_SPAWNED) && !self.monster_respawned)
 898                 monsters_killed += 1;
 899
 900         if(self.candrop && self.weapon)
 901                 W_ThrowNewWeapon(self, self.weapon, 0, self.origin, randomvec() * 150 + '0 0 325');
 902
 903         if(IS_CLIENT(self.realowner))
 904                 self.realowner.monstercount -= 1;
 905
 906         self.event_damage       = monsters_corpse_damage;
 907         self.solid                      = SOLID_CORPSE;
 908         self.takedamage         = DAMAGE_AIM;
 909         self.enemy                      = world;
 910         self.movetype           = MOVETYPE_TOSS;
 911         self.moveto                     = self.origin;
 912         self.touch                      = MonsterTouch; // reset incase monster was pouncing
 913         self.reset                      = func_null;
 914         self.state                      = 0;
 915         self.attack_finished_single = 0;
 916
 917         if not(self.flags & FL_FLY)
 918                 self.velocity = '0 0 0';
 919
 920         self.SendFlags |= MSF_MOVE;
 921
 922         // number of monsters spawned with mobspawn command
 923         totalspawned -= 1;
 924
 925         MON_ACTION(self.monsterid, MR_DEATH);
 926 }
 927
 928 void monsters_damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 929 {
 930         if(self.frozen && deathtype != DEATH_KILL)
 931                 return;
 932
 933         if(time < self.pain_finished && deathtype != DEATH_KILL)
 934                 return;
 935
 936         if(time < self.spawnshieldtime)
 937                 return;
 938
 939         vector v;
 940         float take, save;
 941
 942         v = healtharmor_applydamage(self.armorvalue, self.m_armor_blockpercent, damage);
 943         take = v_x;
 944         save = v_y;
 945
 946         self.health -= take;
 947
 948         self.dmg_time = time;
 949
 950         if(sound_allowed(MSG_BROADCAST, attacker) && deathtype != DEATH_DROWN)
 951                 spamsound (self, CH_PAIN, "misc/bodyimpact1.wav", VOL_BASE, ATTEN_NORM);  // FIXME: PLACEHOLDER
 952
 953         self.velocity += force * self.damageforcescale;
 954
 955         if(deathtype != DEATH_DROWN)
 956         {
 957                 Violence_GibSplash_At(hitloc, force, 2, bound(0, take, 200) / 16, self, attacker);
 958                 if (take > 50)
 959                         Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 960                 if (take > 100)
 961                         Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 962         }
 963
 964         if(self.health <= 0)
 965         {
 966                 if(deathtype == DEATH_KILL)
 967                         self.candrop = FALSE; // killed by mobkill command
 968
 969                 // TODO: fix this?
 970                 activator = attacker;
 971                 other = self.enemy;
 972                 SUB_UseTargets();
 973                 self.target2 = self.oldtarget2; // reset to original target on death, incase we respawn
 974
 975                 monster_die();
 976
 977                 frag_attacker = attacker;
 978                 frag_target = self;
 979                 MUTATOR_CALLHOOK(MonsterDies);
 980
 981                 if(self.health <= -100) // check if we're already gibbed
 982                 {
 983                         Violence_GibSplash(self, 1, 0.5, attacker);
 984
 985                         self.think = SUB_Remove;
 986                         self.nextthink = time + 0.1;
 987                 }
 988         }
 989
 990         self.SendFlags |= MSF_STATUS;
 991 }
 992
 993 void monster_think()
 994 {
 995         self.think = monster_think;
 996         self.nextthink = self.ticrate;
 997
 998         MON_ACTION(self.monsterid, MR_THINK);
 999 }
1000
1001 void monster_spawn()
1002 {
1003         MON_ACTION(self.monsterid, MR_SETUP);
1004
1005         if not(self.monster_respawned)
1006                 Monster_CheckMinibossFlag();
1007
1008         self.max_health = self.health;
1009         self.pain_finished = self.nextthink;
1010         self.anim_start_time = time;
1011
1012         if not(self.noalign)
1013         {
1014                 setorigin(self, self.origin + '0 0 20');
1015                 tracebox(self.origin + '0 0 100', self.mins, self.maxs, self.origin - '0 0 10000', MOVE_WORLDONLY, self);
1016                 setorigin(self, trace_endpos);
1017         }
1018
1019         if not(self.monster_respawned)
1020         if not(self.skin)
1021                 self.skin = rint(random() * 4);
1022
1023         if not(self.attack_range)
1024                 self.attack_range = autocvar_g_monsters_attack_range;
1025
1026         self.pos1 = self.origin;
1027
1028         //monster_setupsounds(self.netname);
1029         precache_monstersounds();
1030         UpdateMonsterSounds();
1031         //monster_precachesounds(self);
1032
1033         if(teamplay)
1034                 self.monster_attack = TRUE; // we can have monster enemies in team games
1035
1036         MonsterSound(monstersound_spawn, 0, FALSE, CH_VOICE);
1037
1038         self.think = monster_think;
1039         self.nextthink = time + self.ticrate;
1040
1041         self.SendFlags |= MSF_SETUP;
1042
1043         MUTATOR_CALLHOOK(MonsterSpawn);
1044 }
1045
1046 float monster_initialize(float mon_id, float nodrop)
1047 {
1048         if not(autocvar_g_monsters)
1049                 return FALSE;
1050
1051         entity mon = get_monsterinfo(mon_id);
1052
1053         // support for quake style removing monsters based on skill
1054         switch(monster_skill)
1055         {
1056                 case 0:
1057                 case 1: if(self.spawnflags & MONSTERSKILL_NOTEASY)              return FALSE; break;
1058                 case 2: if(self.spawnflags & MONSTERSKILL_NOTMEDIUM)    return FALSE; break;
1059                 default:
1060                 case 3: if(self.spawnflags & MONSTERSKILL_NOTHARD)              return FALSE; break;
1061         }
1062
1063         if(self.team && !teamplay)
1064                 self.team = 0;
1065
1066         if not(self.spawnflags & MONSTERFLAG_SPAWNED) // naturally spawned monster
1067         if not(self.monster_respawned)
1068                 monsters_total += 1;
1069
1070         setsize(self, mon.mins, mon.maxs);
1071         self.flags                              = FL_MONSTER;
1072         self.takedamage                 = DAMAGE_AIM;
1073         self.bot_attack                 = TRUE;
1074         self.iscreature                 = TRUE;
1075         self.teleportable               = TRUE;
1076         self.damagedbycontents  = TRUE;
1077         self.monsterid                  = mon_id;
1078         self.damageforcescale   = 0;
1079         self.event_damage               = monsters_damage;
1080         self.touch                              = MonsterTouch;
1081         self.use                                = monster_use;
1082         self.solid                              = SOLID_BBOX;
1083         self.movetype                   = MOVETYPE_WALK;
1084         self.spawnshieldtime    = time + autocvar_g_monsters_spawnshieldtime;
1085         self.enemy                              = world;
1086         self.velocity                   = '0 0 0';
1087         self.moveto                             = self.origin;
1088         self.pos2                               = self.angles;
1089         self.reset                              = monsters_reset;
1090         self.netname                    = mon.netname;
1091         self.monster_name               = M_NAME(mon_id);
1092         self.candrop                    = TRUE;
1093         self.view_ofs                   = '0 0 1' * (self.maxs_z * 0.5);
1094         self.oldtarget2                 = self.target2;
1095         self.deadflag                   = DEAD_NO;
1096         self.scale                              = 1;
1097         self.noalign                    = nodrop;
1098         self.spawn_time                 = time;
1099         self.gravity                    = 1;
1100         self.dphitcontentsmask  = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_BOTCLIP | DPCONTENTS_MONSTERCLIP;
1101
1102         if(mon.spawnflags & MONSTER_TYPE_SWIM)
1103                 self.flags |= FL_SWIM;
1104
1105         if(mon.spawnflags & MONSTER_TYPE_FLY)
1106         {
1107                 self.flags |= FL_FLY;
1108                 self.movetype = MOVETYPE_FLY;
1109         }
1110
1111         if(mon.spawnflags & MONSTER_SIZE_BROKEN)
1112                 self.scale = 1.3;
1113
1114         if not(self.ticrate)
1115                 self.ticrate = autocvar_g_monsters_think_delay;
1116
1117         self.ticrate = bound(sys_frametime, self.ticrate, 60);
1118
1119         if not(self.m_armor_blockpercent)
1120                 self.m_armor_blockpercent = 0.5;
1121
1122         if not(self.target_range)
1123                 self.target_range = autocvar_g_monsters_target_range;
1124
1125         if not(self.respawntime)
1126                 self.respawntime = autocvar_g_monsters_respawn_delay;
1127
1128         if not(self.monster_moveflags)
1129                 self.monster_moveflags = MONSTER_MOVE_WANDER;
1130
1131         monster_link(monster_spawn);
1132
1133         return TRUE;
1134 }