qcsrc/common/mutators/mutator/buffs/buffs.qc

   1 #ifndef MUTATOR_BUFFS_H
   2 #define MUTATOR_BUFFS_H
   3
   4 #include "../instagib/module.inc"
   5
   6 bool  autocvar_g_buffs_effects;
   7 float autocvar_g_buffs_waypoint_distance;
   8 bool autocvar_g_buffs_randomize;
   9 float autocvar_g_buffs_random_lifetime;
  10 bool autocvar_g_buffs_random_location;
  11 int autocvar_g_buffs_random_location_attempts;
  12 int autocvar_g_buffs_spawn_count;
  13 bool autocvar_g_buffs_replace_powerups;
  14 float autocvar_g_buffs_cooldown_activate;
  15 float autocvar_g_buffs_cooldown_respawn;
  16 float autocvar_g_buffs_resistance_blockpercent;
  17 float autocvar_g_buffs_medic_survive_chance;
  18 float autocvar_g_buffs_medic_survive_health;
  19 float autocvar_g_buffs_medic_rot;
  20 float autocvar_g_buffs_medic_max;
  21 float autocvar_g_buffs_medic_regen;
  22 float autocvar_g_buffs_medic_heal_amount = 15;
  23 float autocvar_g_buffs_medic_heal_delay = 1;
  24 float autocvar_g_buffs_medic_heal_range = 400;
  25 float autocvar_g_buffs_vengeance_damage_multiplier;
  26 float autocvar_g_buffs_bash_force;
  27 float autocvar_g_buffs_bash_force_self;
  28 float autocvar_g_buffs_disability_slowtime;
  29 float autocvar_g_buffs_disability_speed;
  30 float autocvar_g_buffs_disability_rate;
  31 float autocvar_g_buffs_disability_weaponspeed;
  32 float autocvar_g_buffs_speed_speed;
  33 float autocvar_g_buffs_speed_rate;
  34 float autocvar_g_buffs_speed_weaponspeed;
  35 float autocvar_g_buffs_speed_damage_take;
  36 float autocvar_g_buffs_speed_regen;
  37 float autocvar_g_buffs_vampire_damage_steal;
  38 float autocvar_g_buffs_invisible_alpha;
  39 float autocvar_g_buffs_flight_gravity;
  40 float autocvar_g_buffs_jump_height;
  41 float autocvar_g_buffs_inferno_burntime_factor;
  42 float autocvar_g_buffs_inferno_burntime_min_time;
  43 float autocvar_g_buffs_inferno_burntime_target_damage;
  44 float autocvar_g_buffs_inferno_burntime_target_time;
  45 float autocvar_g_buffs_inferno_damagemultiplier;
  46 float autocvar_g_buffs_swapper_range;
  47 float autocvar_g_buffs_magnet_range_item;
  48 float autocvar_g_buffs_magnet_range_buff = 200;
  49 float autocvar_g_buffs_luck_chance = 0.15;
  50 float autocvar_g_buffs_luck_damagemultiplier = 3;
  51
  52 // ammo
  53 .float buff_ammo_prev_infitems;
  54 .int buff_ammo_prev_clipload;
  55 // invisible
  56 .float buff_invisible_prev_alpha;
  57 // flight
  58 .float buff_flight_prev_gravity;
  59 // medic
  60 .float buff_medic_healtime;
  61 // disability
  62 .float buff_disability_time;
  63 .float buff_disability_effect_time;
  64 // common buff variables
  65 .float buff_effect_delay;
  66
  67 // buff definitions
  68 .float buff_active;
  69 .float buff_activetime;
  70 .float buff_activetime_updated;
  71 .entity buff_waypoint;
  72 .int oldbuffs; // for updating effects
  73 .entity buff_model; // controls effects (TODO: make csqc)
  74
  75 const vector BUFF_MIN = ('-16 -16 -20');
  76 const vector BUFF_MAX = ('16 16 20');
  77
  78 // client side options
  79 .float cvar_cl_buffs_autoreplace;
  80 #endif
  81
  82 #ifdef IMPLEMENTATION
  83
  84 #include <common/triggers/target/music.qh>
  85 #include <common/gamemodes/all.qh>
  86
  87 .float buff_time = _STAT(BUFF_TIME);
  88 void buffs_DelayedInit();
  89
  90 REGISTER_MUTATOR(buffs, cvar("g_buffs"))
  91 {
  92         MUTATOR_ONADD
  93         {
  94                 InitializeEntity(world, buffs_DelayedInit, INITPRIO_FINDTARGET);
  95         }
  96 }
  97
  98 entity buff_FirstFromFlags(int _buffs)
  99 {
 100         if (flags)
 101         {
 102                 FOREACH(Buffs, it.m_itemid & _buffs, LAMBDA(return it));
 103         }
 104         return BUFF_Null;
 105 }
 106
 107 bool buffs_BuffModel_Customize()
 108 {SELFPARAM();
 109         entity player, myowner;
 110         bool same_team;
 111
 112         player = WaypointSprite_getviewentity(other);
 113         myowner = self.owner;
 114         same_team = (SAME_TEAM(player, myowner) || SAME_TEAM(player, myowner));
 115
 116         if(myowner.alpha <= 0.5 && !same_team && myowner.alpha != 0)
 117                 return false;
 118
 119         if(MUTATOR_CALLHOOK(BuffModel_Customize, self, player))
 120                 return false;
 121
 122         if(player == myowner || (IS_SPEC(other) && other.enemy == myowner))
 123         {
 124                 // somewhat hide the model, but keep the glow
 125                 self.effects = 0;
 126                 self.alpha = -1;
 127         }
 128         else
 129         {
 130                 self.effects = EF_FULLBRIGHT | EF_LOWPRECISION;
 131                 self.alpha = 1;
 132         }
 133         return true;
 134 }
 135
 136 void buffs_BuffModel_Spawn(entity player)
 137 {
 138         player.buff_model = spawn();
 139         setmodel(player.buff_model, MDL_BUFF);
 140         setsize(player.buff_model, '0 0 -40', '0 0 40');
 141         setattachment(player.buff_model, player, "");
 142         setorigin(player.buff_model, '0 0 1' * (player.buff_model.maxs.z * 1));
 143         player.buff_model.owner = player;
 144         player.buff_model.scale = 0.7;
 145         player.buff_model.pflags = PFLAGS_FULLDYNAMIC;
 146         player.buff_model.light_lev = 200;
 147         player.buff_model.customizeentityforclient = buffs_BuffModel_Customize;
 148 }
 149
 150 vector buff_GlowColor(entity buff)
 151 {
 152         //if(buff.team) { return Team_ColorRGB(buff.team); }
 153         return buff.m_color;
 154 }
 155
 156 void buff_Effect(entity player, string eff)
 157 {SELFPARAM();
 158         if(!autocvar_g_buffs_effects) { return; }
 159
 160         if(time >= self.buff_effect_delay)
 161         {
 162                 Send_Effect_(eff, player.origin + ((player.mins + player.maxs) * 0.5), '0 0 0', 1);
 163                 self.buff_effect_delay = time + 0.05; // prevent spam
 164         }
 165 }
 166
 167 // buff item
 168 float buff_Waypoint_visible_for_player(entity plr)
 169 {SELFPARAM();
 170         if(!self.owner.buff_active && !self.owner.buff_activetime)
 171                 return false;
 172
 173         if (plr.buffs)
 174         {
 175                 return plr.cvar_cl_buffs_autoreplace == false || plr.buffs != self.owner.buffs;
 176         }
 177
 178         return WaypointSprite_visible_for_player(plr);
 179 }
 180
 181 void buff_Waypoint_Spawn(entity e)
 182 {
 183         entity buff = buff_FirstFromFlags(e.buffs);
 184         entity wp = WaypointSprite_Spawn(WP_Buff, 0, autocvar_g_buffs_waypoint_distance, e, '0 0 1' * e.maxs.z, world, e.team, e, buff_waypoint, true, RADARICON_Buff);
 185         wp.wp_extra = buff.m_id;
 186         WaypointSprite_UpdateTeamRadar(e.buff_waypoint, RADARICON_Buff, e.glowmod);
 187         e.buff_waypoint.waypointsprite_visible_for_player = buff_Waypoint_visible_for_player;
 188 }
 189
 190 void buff_SetCooldown(float cd)
 191 {SELFPARAM();
 192         cd = max(0, cd);
 193
 194         if(!self.buff_waypoint)
 195                 buff_Waypoint_Spawn(self);
 196
 197         WaypointSprite_UpdateBuildFinished(self.buff_waypoint, time + cd);
 198         self.buff_activetime = cd;
 199         self.buff_active = !cd;
 200 }
 201
 202 void buff_Respawn(entity this)
 203 {
 204         if(gameover) { return; }
 205
 206         vector oldbufforigin = this.origin;
 207         this.velocity = '0 0 200';
 208
 209         if(!MoveToRandomMapLocation(this, DPCONTENTS_SOLID | DPCONTENTS_CORPSE | DPCONTENTS_PLAYERCLIP, DPCONTENTS_SLIME | DPCONTENTS_LAVA | DPCONTENTS_SKY | DPCONTENTS_BODY | DPCONTENTS_DONOTENTER, Q3SURFACEFLAG_SKY,
 210                 ((autocvar_g_buffs_random_location_attempts > 0) ? autocvar_g_buffs_random_location_attempts : 10), 1024, 256))
 211         {
 212                 entity spot = SelectSpawnPoint(true);
 213                 setorigin(this, spot.origin);
 214                 this.velocity = ((randomvec() * 100) + '0 0 200');
 215                 this.angles = spot.angles;
 216         }
 217
 218         tracebox(this.origin, this.mins * 1.5, this.maxs * 1.5, this.origin, MOVE_NOMONSTERS, this);
 219
 220         setorigin(this, trace_endpos); // attempt to unstick
 221
 222         this.movetype = MOVETYPE_TOSS;
 223
 224         makevectors(this.angles);
 225         this.angles = '0 0 0';
 226         if(autocvar_g_buffs_random_lifetime > 0)
 227                 this.lifetime = time + autocvar_g_buffs_random_lifetime;
 228
 229         Send_Effect(EFFECT_ELECTRO_COMBO, oldbufforigin + ((this.mins + this.maxs) * 0.5), '0 0 0', 1);
 230         Send_Effect(EFFECT_ELECTRO_COMBO, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 231
 232         WaypointSprite_Ping(this.buff_waypoint);
 233
 234         sound(this, CH_TRIGGER, SND_KA_RESPAWN, VOL_BASE, ATTEN_NONE); // ATTEN_NONE (it's a sound intended to be heard anywhere)
 235 }
 236
 237 void buff_Touch()
 238 {SELFPARAM();
 239         if(gameover) { return; }
 240
 241         if(ITEM_TOUCH_NEEDKILL())
 242         {
 243                 buff_Respawn(self);
 244                 return;
 245         }
 246
 247         if((self.team && DIFF_TEAM(other, self))
 248         || (STAT(FROZEN, other))
 249         || (other.vehicle)
 250         || (!self.buff_active)
 251         )
 252         {
 253                 // can't touch this
 254                 return;
 255         }
 256
 257         if(MUTATOR_CALLHOOK(BuffTouch, self, other))
 258                 return;
 259
 260         if(!IS_PLAYER(other))
 261                 return; // incase mutator changed other
 262
 263         if (other.buffs)
 264         {
 265                 if (other.cvar_cl_buffs_autoreplace && other.buffs != self.buffs)
 266                 {
 267                         int buffid = buff_FirstFromFlags(other.buffs).m_id;
 268                         //Send_Notification(NOTIF_ONE, other, MSG_MULTI, ITEM_BUFF_DROP, other.buffs);
 269                         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_ITEM_BUFF_LOST, other.netname, buffid);
 270
 271                         other.buffs = 0;
 272                         //sound(other, CH_TRIGGER, SND_BUFF_LOST, VOL_BASE, ATTN_NORM);
 273                 }
 274                 else { return; } // do nothing
 275         }
 276
 277         self.owner = other;
 278         self.buff_active = false;
 279         self.lifetime = 0;
 280         int buffid = buff_FirstFromFlags(self.buffs).m_id;
 281         Send_Notification(NOTIF_ONE, other, MSG_MULTI, ITEM_BUFF_GOT, buffid);
 282         Send_Notification(NOTIF_ALL_EXCEPT, other, MSG_INFO, INFO_ITEM_BUFF, other.netname, buffid);
 283
 284         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(self), '0 0 0', 1);
 285         sound(other, CH_TRIGGER, SND_SHIELD_RESPAWN, VOL_BASE, ATTN_NORM);
 286         other.buffs |= (self.buffs);
 287 }
 288
 289 float buff_Available(entity buff)
 290 {
 291         if (buff == BUFF_Null)
 292                 return false;
 293         if (buff == BUFF_AMMO && ((start_items & IT_UNLIMITED_WEAPON_AMMO) || (start_items & IT_UNLIMITED_AMMO) || (cvar("g_melee_only"))))
 294                 return false;
 295         if (buff == BUFF_VAMPIRE && cvar("g_vampire"))
 296                 return false;
 297         return cvar(strcat("g_buffs_", buff.m_name));
 298 }
 299
 300 .int buff_seencount;
 301
 302 void buff_NewType(entity ent, float cb)
 303 {
 304         RandomSelection_Init();
 305         FOREACH(Buffs, buff_Available(it), LAMBDA(
 306                 it.buff_seencount += 1;
 307                 // if it's already been chosen, give it a lower priority
 308                 RandomSelection_Add(world, it.m_itemid, string_null, 1, max(0.2, 1 / it.buff_seencount));
 309         ));
 310         ent.buffs = RandomSelection_chosen_float;
 311 }
 312
 313 void buff_Think()
 314 {SELFPARAM();
 315         if(self.buffs != self.oldbuffs)
 316         {
 317                 entity buff = buff_FirstFromFlags(self.buffs);
 318                 self.color = buff.m_color;
 319                 self.glowmod = buff_GlowColor(buff);
 320                 self.skin = buff.m_skin;
 321
 322                 setmodel(self, MDL_BUFF);
 323
 324                 if(self.buff_waypoint)
 325                 {
 326                         //WaypointSprite_Disown(self.buff_waypoint, 1);
 327                         WaypointSprite_Kill(self.buff_waypoint);
 328                         buff_Waypoint_Spawn(self);
 329                         if(self.buff_activetime)
 330                                 WaypointSprite_UpdateBuildFinished(self.buff_waypoint, time + self.buff_activetime - frametime);
 331                 }
 332
 333                 self.oldbuffs = self.buffs;
 334         }
 335
 336         if(!gameover)
 337         if((round_handler_IsActive() && !round_handler_IsRoundStarted()) || time >= game_starttime)
 338         if(!self.buff_activetime_updated)
 339         {
 340                 buff_SetCooldown(self.buff_activetime);
 341                 self.buff_activetime_updated = true;
 342         }
 343
 344         if(!self.buff_active && !self.buff_activetime)
 345         if(!self.owner || STAT(FROZEN, self.owner) || IS_DEAD(self.owner) || !self.owner.iscreature || !(self.owner.buffs & self.buffs))
 346         {
 347                 buff_SetCooldown(autocvar_g_buffs_cooldown_respawn + frametime);
 348                 self.owner = world;
 349                 if(autocvar_g_buffs_randomize)
 350                         buff_NewType(self, self.buffs);
 351
 352                 if(autocvar_g_buffs_random_location || (self.spawnflags & 64))
 353                         buff_Respawn(self);
 354         }
 355
 356         if(self.buff_activetime)
 357         if(!gameover)
 358         if((round_handler_IsActive() && !round_handler_IsRoundStarted()) || time >= game_starttime)
 359         {
 360                 self.buff_activetime = max(0, self.buff_activetime - frametime);
 361
 362                 if(!self.buff_activetime)
 363                 {
 364                         self.buff_active = true;
 365                         sound(self, CH_TRIGGER, SND_STRENGTH_RESPAWN, VOL_BASE, ATTN_NORM);
 366                         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(self), '0 0 0', 1);
 367                 }
 368         }
 369
 370         if(self.buff_active)
 371         {
 372                 if(self.team && !self.buff_waypoint)
 373                         buff_Waypoint_Spawn(self);
 374
 375                 if(self.lifetime)
 376                 if(time >= self.lifetime)
 377                         buff_Respawn(self);
 378         }
 379
 380         self.nextthink = time;
 381         //self.angles_y = time * 110.1;
 382 }
 383
 384 void buff_Waypoint_Reset()
 385 {SELFPARAM();
 386         WaypointSprite_Kill(self.buff_waypoint);
 387
 388         if(self.buff_activetime) { buff_Waypoint_Spawn(self); }
 389 }
 390
 391 void buff_Reset(entity this)
 392 {
 393         if(autocvar_g_buffs_randomize)
 394                 buff_NewType(this, this.buffs);
 395         this.owner = world;
 396         buff_SetCooldown(autocvar_g_buffs_cooldown_activate);
 397         buff_Waypoint_Reset();
 398         this.buff_activetime_updated = false;
 399
 400         if(autocvar_g_buffs_random_location || (this.spawnflags & 64))
 401                 buff_Respawn(this);
 402 }
 403
 404 float buff_Customize()
 405 {SELFPARAM();
 406         entity player = WaypointSprite_getviewentity(other);
 407         if(!self.buff_active || (self.team && DIFF_TEAM(player, self)))
 408         {
 409                 self.alpha = 0.3;
 410                 if(self.effects & EF_FULLBRIGHT) { self.effects &= ~(EF_FULLBRIGHT); }
 411                 self.pflags = 0;
 412         }
 413         else
 414         {
 415                 self.alpha = 1;
 416                 if(!(self.effects & EF_FULLBRIGHT)) { self.effects |= EF_FULLBRIGHT; }
 417                 self.light_lev = 220 + 36 * sin(time);
 418                 self.pflags = PFLAGS_FULLDYNAMIC;
 419         }
 420         return true;
 421 }
 422
 423 void buff_Init(entity ent)
 424 {SELFPARAM();
 425         if(!cvar("g_buffs")) { remove(ent); return; }
 426
 427         if(!teamplay && ent.team) { ent.team = 0; }
 428
 429         entity buff = buff_FirstFromFlags(self.buffs);
 430
 431         setself(ent);
 432         if(!self.buffs || buff_Available(buff))
 433                 buff_NewType(self, 0);
 434
 435         self.classname = "item_buff";
 436         self.solid = SOLID_TRIGGER;
 437         self.flags = FL_ITEM;
 438         self.think = buff_Think;
 439         self.touch = buff_Touch;
 440         self.reset = buff_Reset;
 441         self.nextthink = time + 0.1;
 442         self.gravity = 1;
 443         self.movetype = MOVETYPE_TOSS;
 444         self.scale = 1;
 445         self.skin = buff.m_skin;
 446         self.effects = EF_FULLBRIGHT | EF_STARDUST | EF_NOSHADOW;
 447         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY;
 448         self.customizeentityforclient = buff_Customize;
 449         //self.gravity = 100;
 450         self.color = buff.m_color;
 451         self.glowmod = buff_GlowColor(self);
 452         buff_SetCooldown(autocvar_g_buffs_cooldown_activate + game_starttime);
 453         self.buff_active = !self.buff_activetime;
 454         self.pflags = PFLAGS_FULLDYNAMIC;
 455
 456         if(self.spawnflags & 1)
 457                 self.noalign = true;
 458
 459         if(self.noalign)
 460                 self.movetype = MOVETYPE_NONE; // reset by random location
 461
 462         setmodel(self, MDL_BUFF);
 463         setsize(self, BUFF_MIN, BUFF_MAX);
 464
 465         if(cvar("g_buffs_random_location") || (self.spawnflags & 64))
 466                 buff_Respawn(self);
 467
 468         setself(this);
 469 }
 470
 471 void buff_Init_Compat(entity ent, entity replacement)
 472 {
 473         if (ent.spawnflags & 2)
 474                 ent.team = NUM_TEAM_1;
 475         else if (ent.spawnflags & 4)
 476                 ent.team = NUM_TEAM_2;
 477
 478         ent.buffs = replacement.m_itemid;
 479
 480         buff_Init(ent);
 481 }
 482
 483 void buff_SpawnReplacement(entity ent, entity old)
 484 {
 485         setorigin(ent, old.origin);
 486         ent.angles = old.angles;
 487         ent.noalign = (old.noalign || (old.spawnflags & 1));
 488
 489         buff_Init(ent);
 490 }
 491
 492 void buff_Vengeance_DelayedDamage()
 493 {SELFPARAM();
 494         if(self.enemy)
 495                 Damage(self.enemy, self.owner, self.owner, self.dmg, DEATH_BUFF.m_id, self.enemy.origin, '0 0 0');
 496
 497         remove(self);
 498         return;
 499 }
 500
 501 // note: only really useful in teamplay
 502 void buff_Medic_Heal(entity this)
 503 {
 504         FOREACH_CLIENT(IS_PLAYER(it) && it != this && vdist(it.origin - this.origin, <=, autocvar_g_buffs_medic_heal_range),
 505         {
 506                 if(SAME_TEAM(it, this))
 507                 if(it.health < autocvar_g_balance_health_regenstable)
 508                 {
 509                         Send_Effect(EFFECT_HEALING, it.origin, '0 0 0', 1);
 510                         it.health = bound(0, it.health + autocvar_g_buffs_medic_heal_amount, autocvar_g_balance_health_regenstable);
 511                 }
 512         });
 513 }
 514
 515 float buff_Inferno_CalculateTime(float x, float offset_x, float offset_y, float intersect_x, float intersect_y, float base)
 516 {
 517         return offset_y + (intersect_y - offset_y) * logn(((x - offset_x) * ((base - 1) / intersect_x)) + 1, base);
 518 }
 519
 520 // mutator hooks
 521 MUTATOR_HOOKFUNCTION(buffs, PlayerDamage_SplitHealthArmor)
 522 {
 523         if(frag_deathtype == DEATH_BUFF.m_id) { return false; }
 524
 525         if(frag_target.buffs & BUFF_RESISTANCE.m_itemid)
 526         {
 527                 vector v = healtharmor_applydamage(50, autocvar_g_buffs_resistance_blockpercent, frag_deathtype, frag_damage);
 528                 damage_take = v.x;
 529                 damage_save = v.y;
 530         }
 531
 532         return false;
 533 }
 534
 535 MUTATOR_HOOKFUNCTION(buffs, PlayerDamage_Calculate)
 536 {
 537         if(frag_deathtype == DEATH_BUFF.m_id) { return false; }
 538
 539         if(frag_target.buffs & BUFF_SPEED.m_itemid)
 540         if(frag_target != frag_attacker)
 541                 frag_damage *= autocvar_g_buffs_speed_damage_take;
 542
 543         if(frag_target.buffs & BUFF_MEDIC.m_itemid)
 544         if((frag_target.health - frag_damage) <= 0)
 545         if(!ITEM_DAMAGE_NEEDKILL(frag_deathtype))
 546         if(frag_attacker)
 547         if(random() <= autocvar_g_buffs_medic_survive_chance)
 548                 frag_damage = max(5, frag_target.health - autocvar_g_buffs_medic_survive_health);
 549
 550         if(frag_target.buffs & BUFF_JUMP.m_itemid)
 551         if(frag_deathtype == DEATH_FALL.m_id)
 552                 frag_damage = 0;
 553
 554         if(frag_target.buffs & BUFF_VENGEANCE.m_itemid)
 555         if(frag_attacker)
 556         if(frag_attacker != frag_target)
 557         if(!ITEM_DAMAGE_NEEDKILL(frag_deathtype))
 558         {
 559                 entity dmgent = spawn();
 560
 561                 dmgent.dmg = frag_damage * autocvar_g_buffs_vengeance_damage_multiplier;
 562                 dmgent.enemy = frag_attacker;
 563                 dmgent.owner = frag_target;
 564                 dmgent.think = buff_Vengeance_DelayedDamage;
 565                 dmgent.nextthink = time + 0.1;
 566         }
 567
 568         if(frag_target.buffs & BUFF_BASH.m_itemid)
 569         if(frag_attacker != frag_target)
 570                 frag_force = '0 0 0';
 571
 572         if(frag_attacker.buffs & BUFF_BASH.m_itemid)
 573         if(frag_force)
 574         if(frag_attacker == frag_target)
 575                 frag_force *= autocvar_g_buffs_bash_force_self;
 576         else
 577                 frag_force *= autocvar_g_buffs_bash_force;
 578
 579         if(frag_attacker.buffs & BUFF_DISABILITY.m_itemid)
 580         if(frag_target != frag_attacker)
 581                 frag_target.buff_disability_time = time + autocvar_g_buffs_disability_slowtime;
 582
 583         if(frag_target.buffs & BUFF_INFERNO.m_itemid)
 584         {
 585                 if(frag_deathtype == DEATH_FIRE.m_id)
 586                         frag_damage = 0;
 587                 if(frag_deathtype == DEATH_LAVA.m_id)
 588                         frag_damage *= 0.5; // TODO: cvarize?
 589         }
 590
 591         if(frag_attacker.buffs & BUFF_LUCK.m_itemid)
 592         if(frag_attacker != frag_target)
 593         if(autocvar_g_buffs_luck_damagemultiplier > 0)
 594         if(random() <= autocvar_g_buffs_luck_chance)
 595                 frag_damage *= autocvar_g_buffs_luck_damagemultiplier;
 596
 597         if(frag_attacker.buffs & BUFF_INFERNO.m_itemid)
 598         if(frag_target != frag_attacker) {
 599                 float btime = buff_Inferno_CalculateTime(
 600                         frag_damage,
 601                         0,
 602                         autocvar_g_buffs_inferno_burntime_min_time,
 603                         autocvar_g_buffs_inferno_burntime_target_damage,
 604                         autocvar_g_buffs_inferno_burntime_target_time,
 605                         autocvar_g_buffs_inferno_burntime_factor
 606                 );
 607                 Fire_AddDamage(frag_target, frag_attacker, (frag_damage * autocvar_g_buffs_inferno_damagemultiplier), btime, DEATH_BUFF.m_id);
 608         }
 609
 610         // this... is ridiculous (TODO: fix!)
 611         if(frag_attacker.buffs & BUFF_VAMPIRE.m_itemid)
 612         if(!frag_target.vehicle)
 613         if(DEATH_WEAPONOF(frag_deathtype) != WEP_ARC)
 614         if(!ITEM_DAMAGE_NEEDKILL(frag_deathtype))
 615         if(!IS_DEAD(frag_target))
 616         if(IS_PLAYER(frag_target) || IS_MONSTER(frag_target))
 617         if(frag_attacker != frag_target)
 618         if(!STAT(FROZEN, frag_target))
 619         if(frag_target.takedamage)
 620         if(DIFF_TEAM(frag_attacker, frag_target))
 621         {
 622                 frag_attacker.health = bound(0, frag_attacker.health + bound(0, frag_damage * autocvar_g_buffs_vampire_damage_steal, frag_target.health), g_pickup_healthsmall_max);
 623                 if(frag_target.armorvalue)
 624                         frag_attacker.armorvalue = bound(0, frag_attacker.armorvalue + bound(0, frag_damage * autocvar_g_buffs_vampire_damage_steal, frag_target.armorvalue), g_pickup_armorsmall_max);
 625         }
 626
 627         return false;
 628 }
 629
 630 MUTATOR_HOOKFUNCTION(buffs,PlayerSpawn)
 631 {SELFPARAM();
 632         self.buffs = 0;
 633         // reset timers here to prevent them continuing after re-spawn
 634         self.buff_disability_time = 0;
 635         self.buff_disability_effect_time = 0;
 636         return false;
 637 }
 638
 639 .float stat_sv_maxspeed;
 640 .float stat_sv_airspeedlimit_nonqw;
 641 .float stat_sv_jumpvelocity;
 642
 643 MUTATOR_HOOKFUNCTION(buffs, PlayerPhysics)
 644 {SELFPARAM();
 645         if(self.buffs & BUFF_SPEED.m_itemid)
 646         {
 647                 self.stat_sv_maxspeed *= autocvar_g_buffs_speed_speed;
 648                 self.stat_sv_airspeedlimit_nonqw *= autocvar_g_buffs_speed_speed;
 649         }
 650
 651         if(time < self.buff_disability_time)
 652         {
 653                 self.stat_sv_maxspeed *= autocvar_g_buffs_disability_speed;
 654                 self.stat_sv_airspeedlimit_nonqw *= autocvar_g_buffs_disability_speed;
 655         }
 656
 657         if(self.buffs & BUFF_JUMP.m_itemid)
 658         {
 659                 // automatically reset, no need to worry
 660                 self.stat_sv_jumpvelocity = autocvar_g_buffs_jump_height;
 661         }
 662
 663         return false;
 664 }
 665
 666 MUTATOR_HOOKFUNCTION(buffs, PlayerJump)
 667 {SELFPARAM();
 668         if(self.buffs & BUFF_JUMP.m_itemid)
 669                 player_jumpheight = autocvar_g_buffs_jump_height;
 670
 671         return false;
 672 }
 673
 674 MUTATOR_HOOKFUNCTION(buffs, MonsterMove)
 675 {SELFPARAM();
 676         if(time < self.buff_disability_time)
 677         {
 678                 monster_speed_walk *= autocvar_g_buffs_disability_speed;
 679                 monster_speed_run *= autocvar_g_buffs_disability_speed;
 680         }
 681
 682         return false;
 683 }
 684
 685 MUTATOR_HOOKFUNCTION(buffs, PlayerDies)
 686 {
 687         if(frag_target.buffs)
 688         {
 689                 int buffid = buff_FirstFromFlags(frag_target.buffs).m_id;
 690                 Send_Notification(NOTIF_ALL_EXCEPT, frag_target, MSG_INFO, INFO_ITEM_BUFF_LOST, frag_target.netname, buffid);
 691                 frag_target.buffs = 0;
 692
 693                 if(frag_target.buff_model)
 694                 {
 695                         remove(frag_target.buff_model);
 696                         frag_target.buff_model = world;
 697                 }
 698         }
 699         return false;
 700 }
 701
 702 MUTATOR_HOOKFUNCTION(buffs, PlayerUseKey, CBC_ORDER_FIRST)
 703 {SELFPARAM();
 704         if(MUTATOR_RETURNVALUE || gameover) { return false; }
 705         if(self.buffs)
 706         {
 707                 int buffid = buff_FirstFromFlags(self.buffs).m_id;
 708                 Send_Notification(NOTIF_ONE, self, MSG_MULTI, ITEM_BUFF_DROP, buffid);
 709                 Send_Notification(NOTIF_ALL_EXCEPT, self, MSG_INFO, INFO_ITEM_BUFF_LOST, self.netname, buffid);
 710
 711                 self.buffs = 0;
 712                 sound(self, CH_TRIGGER, SND_BUFF_LOST, VOL_BASE, ATTN_NORM);
 713                 return true;
 714         }
 715         return false;
 716 }
 717
 718 MUTATOR_HOOKFUNCTION(buffs, ForbidThrowCurrentWeapon)
 719 {SELFPARAM();
 720         if(MUTATOR_RETURNVALUE || gameover) { return false; }
 721
 722         if(self.buffs & BUFF_SWAPPER.m_itemid)
 723         {
 724                 float best_distance = autocvar_g_buffs_swapper_range;
 725                 entity closest = world;
 726                 FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
 727                         if(!IS_DEAD(it) && !STAT(FROZEN, it) && !it.vehicle)
 728                         if(DIFF_TEAM(it, self))
 729                         {
 730                                 float test = vlen2(self.origin - it.origin);
 731                                 if(test <= best_distance * best_distance)
 732                                 {
 733                                         best_distance = sqrt(test);
 734                                         closest = it;
 735                                 }
 736                         }
 737                 ));
 738
 739                 if(closest)
 740                 {
 741                         vector my_org, my_vel, my_ang, their_org, their_vel, their_ang;
 742
 743                         my_org = self.origin;
 744                         my_vel = self.velocity;
 745                         my_ang = self.angles;
 746                         their_org = closest.origin;
 747                         their_vel = closest.velocity;
 748                         their_ang = closest.angles;
 749
 750                         Drop_Special_Items(closest);
 751
 752                         MUTATOR_CALLHOOK(PortalTeleport, self); // initiate flag dropper
 753
 754                         setorigin(self, their_org);
 755                         setorigin(closest, my_org);
 756
 757                         closest.velocity = my_vel;
 758                         closest.angles = my_ang;
 759                         closest.fixangle = true;
 760                         closest.oldorigin = my_org;
 761                         closest.oldvelocity = my_vel;
 762                         self.velocity = their_vel;
 763                         self.angles = their_ang;
 764                         self.fixangle = true;
 765                         self.oldorigin = their_org;
 766                         self.oldvelocity = their_vel;
 767
 768                         // set pusher so self gets the kill if they fall into void
 769                         closest.pusher = self;
 770                         closest.pushltime = time + autocvar_g_maxpushtime;
 771                         closest.istypefrag = closest.BUTTON_CHAT;
 772
 773                         Send_Effect(EFFECT_ELECTRO_COMBO, their_org, '0 0 0', 1);
 774                         Send_Effect(EFFECT_ELECTRO_COMBO, my_org, '0 0 0', 1);
 775
 776                         sound(self, CH_TRIGGER, SND_KA_RESPAWN, VOL_BASE, ATTEN_NORM);
 777                         sound(closest, CH_TRIGGER, SND_KA_RESPAWN, VOL_BASE, ATTEN_NORM);
 778
 779                         // TODO: add a counter to handle how many times one can teleport, and a delay to prevent spam
 780                         self.buffs = 0;
 781                         return true;
 782                 }
 783         }
 784         return false;
 785 }
 786
 787 bool buffs_RemovePlayer(entity player)
 788 {
 789         if(player.buff_model)
 790         {
 791                 remove(player.buff_model);
 792                 player.buff_model = world;
 793         }
 794
 795         // also reset timers here to prevent them continuing after spectating
 796         player.buff_disability_time = 0;
 797         player.buff_disability_effect_time = 0;
 798
 799         return false;
 800 }
 801 MUTATOR_HOOKFUNCTION(buffs, MakePlayerObserver) { return buffs_RemovePlayer(self); }
 802 MUTATOR_HOOKFUNCTION(buffs, ClientDisconnect) { return buffs_RemovePlayer(self); }
 803
 804 MUTATOR_HOOKFUNCTION(buffs, CustomizeWaypoint)
 805 {SELFPARAM();
 806         entity e = WaypointSprite_getviewentity(other);
 807
 808         // if you have the invisibility powerup, sprites ALWAYS are restricted to your team
 809         // but only apply this to real players, not to spectators
 810         if((self.owner.flags & FL_CLIENT) && (self.owner.buffs & BUFF_INVISIBLE.m_itemid) && (e == other))
 811         if(DIFF_TEAM(self.owner, e))
 812                 return true;
 813
 814         return false;
 815 }
 816
 817 MUTATOR_HOOKFUNCTION(buffs, OnEntityPreSpawn, CBC_ORDER_LAST)
 818 {SELFPARAM();
 819         if (self.classname == "item_flight" && cvar("g_buffs") && cvar("g_buffs_flight"))
 820         {
 821                 buff_Init_Compat(self, BUFF_FLIGHT);
 822                 return true;
 823         }
 824         if(autocvar_g_buffs_replace_powerups)
 825         switch(self.classname)
 826         {
 827                 case "item_strength":
 828                 case "item_invincible":
 829                 {
 830                         entity e = spawn();
 831                         buff_SpawnReplacement(e, self);
 832                         return true;
 833                 }
 834         }
 835         return false;
 836 }
 837
 838 MUTATOR_HOOKFUNCTION(buffs, WeaponRateFactor)
 839 {SELFPARAM();
 840         if(self.buffs & BUFF_SPEED.m_itemid)
 841                 weapon_rate *= autocvar_g_buffs_speed_rate;
 842
 843         if(time < self.buff_disability_time)
 844                 weapon_rate *= autocvar_g_buffs_disability_rate;
 845
 846         return false;
 847 }
 848
 849 MUTATOR_HOOKFUNCTION(buffs, WeaponSpeedFactor)
 850 {SELFPARAM();
 851         if(self.buffs & BUFF_SPEED.m_itemid)
 852                 ret_float *= autocvar_g_buffs_speed_weaponspeed;
 853
 854         if(time < self.buff_disability_time)
 855                 ret_float *= autocvar_g_buffs_disability_weaponspeed;
 856
 857         return false;
 858 }
 859
 860 MUTATOR_HOOKFUNCTION(buffs, PlayerPreThink)
 861 {SELFPARAM();
 862         if(gameover || IS_DEAD(self)) { return false; }
 863
 864         if(time < self.buff_disability_time)
 865         if(time >= self.buff_disability_effect_time)
 866         {
 867                 Send_Effect(EFFECT_SMOKING, self.origin + ((self.mins + self.maxs) * 0.5), '0 0 0', 1);
 868                 self.buff_disability_effect_time = time + 0.5;
 869         }
 870
 871         // handle buff lost status
 872         // 1: notify everyone else
 873         // 2: notify carrier as well
 874         int buff_lost = 0;
 875
 876         if(self.buff_time)
 877         if(time >= self.buff_time)
 878                 buff_lost = 2;
 879
 880         if(STAT(FROZEN, self)) { buff_lost = 1; }
 881
 882         if(buff_lost)
 883         {
 884                 if(self.buffs)
 885                 {
 886                         int buffid = buff_FirstFromFlags(self.buffs).m_id;
 887                         Send_Notification(NOTIF_ALL_EXCEPT, self, MSG_INFO, INFO_ITEM_BUFF_LOST, self.netname, buffid);
 888                         if(buff_lost >= 2)
 889                         {
 890                                 Send_Notification(NOTIF_ONE, self, MSG_MULTI, ITEM_BUFF_DROP, buffid); // TODO: special timeout message?
 891                                 sound(self, CH_TRIGGER, SND_BUFF_LOST, VOL_BASE, ATTN_NORM);
 892                         }
 893                         self.buffs = 0;
 894                 }
 895         }
 896
 897         if(self.buffs & BUFF_MAGNET.m_itemid)
 898         {
 899                 vector pickup_size;
 900                 FOREACH_ENTITY_FLAGS(flags, FL_ITEM,
 901                 {
 902                         if(it.buffs)
 903                                 pickup_size = '1 1 1' * autocvar_g_buffs_magnet_range_buff;
 904                         else
 905                                 pickup_size = '1 1 1' * autocvar_g_buffs_magnet_range_item;
 906
 907                         if(boxesoverlap(self.absmin - pickup_size, self.absmax + pickup_size, it.absmin, it.absmax))
 908                         {
 909                                 if(it.touch)
 910                                 {
 911                                         entity oldother = other;
 912                                         other = self;
 913                                         WITH(entity, self, it, it.touch());
 914
 915                                         other = oldother;
 916                                 }
 917                         }
 918                 });
 919         }
 920
 921         if(self.buffs & BUFF_AMMO.m_itemid)
 922         if(self.clip_size)
 923                 self.clip_load = self.(weapon_load[PS(self).m_switchweapon.m_id]) = self.clip_size;
 924
 925         if((self.buffs & BUFF_INVISIBLE.m_itemid) && (self.oldbuffs & BUFF_INVISIBLE.m_itemid))
 926         if(self.alpha != autocvar_g_buffs_invisible_alpha)
 927                 self.alpha = autocvar_g_buffs_invisible_alpha; // powerups reset alpha, so we must enforce this (TODO)
 928
 929         if(self.buffs & BUFF_MEDIC.m_itemid)
 930         if(time >= self.buff_medic_healtime)
 931         {
 932                 buff_Medic_Heal(self);
 933                 self.buff_medic_healtime = time + autocvar_g_buffs_medic_heal_delay;
 934         }
 935
 936 #define BUFF_ONADD(b) if ( (self.buffs & (b).m_itemid) && !(self.oldbuffs & (b).m_itemid))
 937 #define BUFF_ONREM(b) if (!(self.buffs & (b).m_itemid) &&  (self.oldbuffs & (b).m_itemid))
 938
 939         if(self.buffs != self.oldbuffs)
 940         {
 941                 entity buff = buff_FirstFromFlags(self.buffs);
 942                 float bufftime = buff != BUFF_Null ? buff.m_time(buff) : 0;
 943                 self.buff_time = (bufftime) ? time + bufftime : 0;
 944
 945                 BUFF_ONADD(BUFF_AMMO)
 946                 {
 947                         self.buff_ammo_prev_infitems = (self.items & IT_UNLIMITED_WEAPON_AMMO);
 948                         self.items |= IT_UNLIMITED_WEAPON_AMMO;
 949
 950                         if(self.clip_load)
 951                                 self.buff_ammo_prev_clipload = self.clip_load;
 952                         self.clip_load = self.(weapon_load[PS(self).m_switchweapon.m_id]) = self.clip_size;
 953                 }
 954
 955                 BUFF_ONREM(BUFF_AMMO)
 956                 {
 957                         if(self.buff_ammo_prev_infitems)
 958                                 self.items |= IT_UNLIMITED_WEAPON_AMMO;
 959                         else
 960                                 self.items &= ~IT_UNLIMITED_WEAPON_AMMO;
 961
 962                         if(self.buff_ammo_prev_clipload)
 963                                 self.clip_load = self.buff_ammo_prev_clipload;
 964                 }
 965
 966                 BUFF_ONADD(BUFF_INVISIBLE)
 967                 {
 968                         if(time < self.strength_finished && g_instagib)
 969                                 self.alpha = autocvar_g_instagib_invis_alpha;
 970                         else
 971                                 self.alpha = self.buff_invisible_prev_alpha;
 972                         self.alpha = autocvar_g_buffs_invisible_alpha;
 973                 }
 974
 975                 BUFF_ONREM(BUFF_INVISIBLE)
 976                         self.alpha = self.buff_invisible_prev_alpha;
 977
 978                 BUFF_ONADD(BUFF_FLIGHT)
 979                 {
 980                         self.buff_flight_prev_gravity = self.gravity;
 981                         self.gravity = autocvar_g_buffs_flight_gravity;
 982                 }
 983
 984                 BUFF_ONREM(BUFF_FLIGHT)
 985                         self.gravity = self.buff_flight_prev_gravity;
 986
 987                 self.oldbuffs = self.buffs;
 988                 if(self.buffs)
 989                 {
 990                         if(!self.buff_model)
 991                                 buffs_BuffModel_Spawn(self);
 992
 993                         self.buff_model.color = buff.m_color;
 994                         self.buff_model.glowmod = buff_GlowColor(self.buff_model);
 995                         self.buff_model.skin = buff.m_skin;
 996
 997                         self.effects |= EF_NOSHADOW;
 998                 }
 999                 else
1000                 {
1001                         remove(self.buff_model);
1002                         self.buff_model = world;
1003
1004                         self.effects &= ~(EF_NOSHADOW);
1005                 }
1006         }
1007
1008         if(self.buff_model)
1009         {
1010                 self.buff_model.effects = self.effects;
1011                 self.buff_model.effects |= EF_LOWPRECISION;
1012                 self.buff_model.effects = self.buff_model.effects & EFMASK_CHEAP; // eat performance
1013
1014                 self.buff_model.alpha = self.alpha;
1015         }
1016
1017 #undef BUFF_ONADD
1018 #undef BUFF_ONREM
1019         return false;
1020 }
1021
1022 MUTATOR_HOOKFUNCTION(buffs, SpectateCopy)
1023 {SELFPARAM();
1024         self.buffs = other.buffs;
1025         return false;
1026 }
1027
1028 MUTATOR_HOOKFUNCTION(buffs, VehicleEnter)
1029 {
1030         vh_vehicle.buffs = vh_player.buffs;
1031         vh_player.buffs = 0;
1032         vh_vehicle.buff_time = max(0, vh_player.buff_time - time);
1033         vh_player.buff_time = 0;
1034         return false;
1035 }
1036
1037 MUTATOR_HOOKFUNCTION(buffs, VehicleExit)
1038 {
1039         vh_player.buffs = vh_player.oldbuffs = vh_vehicle.buffs;
1040         vh_vehicle.buffs = 0;
1041         vh_player.buff_time = time + vh_vehicle.buff_time;
1042         vh_vehicle.buff_time = 0;
1043         return false;
1044 }
1045
1046 MUTATOR_HOOKFUNCTION(buffs, PlayerRegen)
1047 {SELFPARAM();
1048         if(self.buffs & BUFF_MEDIC.m_itemid)
1049         {
1050                 regen_mod_rot = autocvar_g_buffs_medic_rot;
1051                 regen_mod_limit = regen_mod_max = autocvar_g_buffs_medic_max;
1052                 regen_mod_regen = autocvar_g_buffs_medic_regen;
1053         }
1054
1055         if(self.buffs & BUFF_SPEED.m_itemid)
1056                 regen_mod_regen = autocvar_g_buffs_speed_regen;
1057
1058         return false;
1059 }
1060
1061 MUTATOR_HOOKFUNCTION(buffs, GetCvars)
1062 {
1063         GetCvars_handleFloat(get_cvars_s, get_cvars_f, cvar_cl_buffs_autoreplace, "cl_buffs_autoreplace");
1064         return false;
1065 }
1066
1067 MUTATOR_HOOKFUNCTION(buffs, BuildMutatorsString)
1068 {
1069         ret_string = strcat(ret_string, ":Buffs");
1070         return false;
1071 }
1072
1073 MUTATOR_HOOKFUNCTION(buffs, BuildMutatorsPrettyString)
1074 {
1075         ret_string = strcat(ret_string, ", Buffs");
1076         return false;
1077 }
1078
1079 void buffs_DelayedInit()
1080 {
1081         if(autocvar_g_buffs_spawn_count > 0)
1082         if(find(world, classname, "item_buff") == world)
1083         {
1084                 float i;
1085                 for(i = 0; i < autocvar_g_buffs_spawn_count; ++i)
1086                 {
1087                         entity e = spawn();
1088                         e.spawnflags |= 64; // always randomize
1089                         e.velocity = randomvec() * 250; // this gets reset anyway if random location works
1090                         buff_Init(e);
1091                 }
1092         }
1093 }
1094 #endif