qcsrc/common/mutators/mutator/buffs/buffs.qc

   1 #ifndef MUTATOR_BUFFS_H
   2 #define MUTATOR_BUFFS_H
   3
   4 #include "../instagib/module.inc"
   5
   6 bool  autocvar_g_buffs_effects;
   7 float autocvar_g_buffs_waypoint_distance;
   8 bool autocvar_g_buffs_randomize;
   9 float autocvar_g_buffs_random_lifetime;
  10 bool autocvar_g_buffs_random_location;
  11 int autocvar_g_buffs_random_location_attempts;
  12 int autocvar_g_buffs_spawn_count;
  13 bool autocvar_g_buffs_replace_powerups;
  14 float autocvar_g_buffs_cooldown_activate;
  15 float autocvar_g_buffs_cooldown_respawn;
  16 float autocvar_g_buffs_resistance_blockpercent;
  17 float autocvar_g_buffs_medic_survive_chance;
  18 float autocvar_g_buffs_medic_survive_health;
  19 float autocvar_g_buffs_medic_rot;
  20 float autocvar_g_buffs_medic_max;
  21 float autocvar_g_buffs_medic_regen;
  22 float autocvar_g_buffs_medic_heal_amount = 15;
  23 float autocvar_g_buffs_medic_heal_delay = 1;
  24 float autocvar_g_buffs_medic_heal_range = 400;
  25 float autocvar_g_buffs_vengeance_damage_multiplier;
  26 float autocvar_g_buffs_bash_force;
  27 float autocvar_g_buffs_bash_force_self;
  28 float autocvar_g_buffs_disability_slowtime;
  29 float autocvar_g_buffs_disability_speed;
  30 float autocvar_g_buffs_disability_rate;
  31 float autocvar_g_buffs_disability_weaponspeed;
  32 float autocvar_g_buffs_speed_speed;
  33 float autocvar_g_buffs_speed_rate;
  34 float autocvar_g_buffs_speed_weaponspeed;
  35 float autocvar_g_buffs_speed_damage_take;
  36 float autocvar_g_buffs_speed_regen;
  37 float autocvar_g_buffs_vampire_damage_steal;
  38 float autocvar_g_buffs_invisible_alpha;
  39 float autocvar_g_buffs_jump_height;
  40 float autocvar_g_buffs_inferno_burntime_factor;
  41 float autocvar_g_buffs_inferno_burntime_min_time;
  42 float autocvar_g_buffs_inferno_burntime_target_damage;
  43 float autocvar_g_buffs_inferno_burntime_target_time;
  44 float autocvar_g_buffs_inferno_damagemultiplier;
  45 float autocvar_g_buffs_swapper_range;
  46 float autocvar_g_buffs_magnet_range_item;
  47 float autocvar_g_buffs_magnet_range_buff = 200;
  48 float autocvar_g_buffs_luck_chance = 0.15;
  49 float autocvar_g_buffs_luck_damagemultiplier = 3;
  50
  51 // ammo
  52 .float buff_ammo_prev_infitems;
  53 .int buff_ammo_prev_clipload;
  54 // invisible
  55 .float buff_invisible_prev_alpha;
  56 // medic
  57 .float buff_medic_healtime;
  58 // disability
  59 .float buff_disability_time;
  60 .float buff_disability_effect_time;
  61 // common buff variables
  62 .float buff_effect_delay;
  63
  64 // buff definitions
  65 .float buff_active;
  66 .float buff_activetime;
  67 .float buff_activetime_updated;
  68 .entity buff_waypoint;
  69 .int oldbuffs; // for updating effects
  70 .entity buff_model; // controls effects (TODO: make csqc)
  71
  72 const vector BUFF_MIN = ('-16 -16 -20');
  73 const vector BUFF_MAX = ('16 16 20');
  74
  75 // client side options
  76 .float cvar_cl_buffs_autoreplace;
  77 #endif
  78
  79 #ifdef IMPLEMENTATION
  80
  81 #include <common/triggers/target/music.qh>
  82 #include <common/gamemodes/all.qh>
  83
  84 .float buff_time = _STAT(BUFF_TIME);
  85 void buffs_DelayedInit();
  86
  87 REGISTER_MUTATOR(buffs, cvar("g_buffs"))
  88 {
  89         MUTATOR_ONADD
  90         {
  91                 InitializeEntity(world, buffs_DelayedInit, INITPRIO_FINDTARGET);
  92         }
  93 }
  94
  95 bool buffs_BuffModel_Customize()
  96 {SELFPARAM();
  97         entity player, myowner;
  98         bool same_team;
  99
 100         player = WaypointSprite_getviewentity(other);
 101         myowner = self.owner;
 102         same_team = (SAME_TEAM(player, myowner) || SAME_TEAM(player, myowner));
 103
 104         if(myowner.alpha <= 0.5 && !same_team && myowner.alpha != 0)
 105                 return false;
 106
 107         if(MUTATOR_CALLHOOK(BuffModel_Customize, self, player))
 108                 return false;
 109
 110         if(player == myowner || (IS_SPEC(other) && other.enemy == myowner))
 111         {
 112                 // somewhat hide the model, but keep the glow
 113                 self.effects = 0;
 114                 self.alpha = -1;
 115         }
 116         else
 117         {
 118                 self.effects = EF_FULLBRIGHT | EF_LOWPRECISION;
 119                 self.alpha = 1;
 120         }
 121         return true;
 122 }
 123
 124 void buffs_BuffModel_Spawn(entity player)
 125 {
 126         player.buff_model = spawn();
 127         setmodel(player.buff_model, MDL_BUFF);
 128         setsize(player.buff_model, '0 0 -40', '0 0 40');
 129         setattachment(player.buff_model, player, "");
 130         setorigin(player.buff_model, '0 0 1' * (player.buff_model.maxs.z * 1));
 131         player.buff_model.owner = player;
 132         player.buff_model.scale = 0.7;
 133         player.buff_model.pflags = PFLAGS_FULLDYNAMIC;
 134         player.buff_model.light_lev = 200;
 135         player.buff_model.customizeentityforclient = buffs_BuffModel_Customize;
 136 }
 137
 138 vector buff_GlowColor(entity buff)
 139 {
 140         //if(buff.team) { return Team_ColorRGB(buff.team); }
 141         return buff.m_color;
 142 }
 143
 144 void buff_Effect(entity player, string eff)
 145 {SELFPARAM();
 146         if(!autocvar_g_buffs_effects) { return; }
 147
 148         if(time >= self.buff_effect_delay)
 149         {
 150                 Send_Effect_(eff, player.origin + ((player.mins + player.maxs) * 0.5), '0 0 0', 1);
 151                 self.buff_effect_delay = time + 0.05; // prevent spam
 152         }
 153 }
 154
 155 // buff item
 156 float buff_Waypoint_visible_for_player(entity plr)
 157 {SELFPARAM();
 158         if(!self.owner.buff_active && !self.owner.buff_activetime)
 159                 return false;
 160
 161         if (plr.buffs)
 162         {
 163                 return plr.cvar_cl_buffs_autoreplace == false || plr.buffs != self.owner.buffs;
 164         }
 165
 166         return WaypointSprite_visible_for_player(plr);
 167 }
 168
 169 void buff_Waypoint_Spawn(entity e)
 170 {
 171         entity buff = buff_FirstFromFlags(e.buffs);
 172         entity wp = WaypointSprite_Spawn(WP_Buff, 0, autocvar_g_buffs_waypoint_distance, e, '0 0 1' * e.maxs.z, world, e.team, e, buff_waypoint, true, RADARICON_Buff);
 173         wp.wp_extra = buff.m_id;
 174         WaypointSprite_UpdateTeamRadar(e.buff_waypoint, RADARICON_Buff, e.glowmod);
 175         e.buff_waypoint.waypointsprite_visible_for_player = buff_Waypoint_visible_for_player;
 176 }
 177
 178 void buff_SetCooldown(float cd)
 179 {SELFPARAM();
 180         cd = max(0, cd);
 181
 182         if(!self.buff_waypoint)
 183                 buff_Waypoint_Spawn(self);
 184
 185         WaypointSprite_UpdateBuildFinished(self.buff_waypoint, time + cd);
 186         self.buff_activetime = cd;
 187         self.buff_active = !cd;
 188 }
 189
 190 void buff_Respawn(entity this)
 191 {
 192         if(gameover) { return; }
 193
 194         vector oldbufforigin = this.origin;
 195         this.velocity = '0 0 200';
 196
 197         if(!MoveToRandomMapLocation(this, DPCONTENTS_SOLID | DPCONTENTS_CORPSE | DPCONTENTS_PLAYERCLIP, DPCONTENTS_SLIME | DPCONTENTS_LAVA | DPCONTENTS_SKY | DPCONTENTS_BODY | DPCONTENTS_DONOTENTER, Q3SURFACEFLAG_SKY,
 198                 ((autocvar_g_buffs_random_location_attempts > 0) ? autocvar_g_buffs_random_location_attempts : 10), 1024, 256))
 199         {
 200                 entity spot = SelectSpawnPoint(true);
 201                 setorigin(this, spot.origin);
 202                 this.velocity = ((randomvec() * 100) + '0 0 200');
 203                 this.angles = spot.angles;
 204         }
 205
 206         tracebox(this.origin, this.mins * 1.5, this.maxs * 1.5, this.origin, MOVE_NOMONSTERS, this);
 207
 208         setorigin(this, trace_endpos); // attempt to unstick
 209
 210         this.movetype = MOVETYPE_TOSS;
 211
 212         makevectors(this.angles);
 213         this.angles = '0 0 0';
 214         if(autocvar_g_buffs_random_lifetime > 0)
 215                 this.lifetime = time + autocvar_g_buffs_random_lifetime;
 216
 217         Send_Effect(EFFECT_ELECTRO_COMBO, oldbufforigin + ((this.mins + this.maxs) * 0.5), '0 0 0', 1);
 218         Send_Effect(EFFECT_ELECTRO_COMBO, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 219
 220         WaypointSprite_Ping(this.buff_waypoint);
 221
 222         sound(this, CH_TRIGGER, SND_KA_RESPAWN, VOL_BASE, ATTEN_NONE); // ATTEN_NONE (it's a sound intended to be heard anywhere)
 223 }
 224
 225 void buff_Touch()
 226 {SELFPARAM();
 227         if(gameover) { return; }
 228
 229         if(ITEM_TOUCH_NEEDKILL())
 230         {
 231                 buff_Respawn(self);
 232                 return;
 233         }
 234
 235         if((self.team && DIFF_TEAM(other, self))
 236         || (STAT(FROZEN, other))
 237         || (other.vehicle)
 238         || (!self.buff_active)
 239         )
 240         {
 241                 // can't touch this
 242                 return;
 243         }
 244
 245         if(MUTATOR_CALLHOOK(BuffTouch, self, other))
 246                 return;
 247
 248         if(!IS_PLAYER(other))
 249                 return; // incase mutator changed other
 250
 251         if (other.buffs)
 252         {
 253                 if (other.cvar_cl_buffs_autoreplace && other.buffs != self.buffs)
 254                 {
 255                         int buffid = buff_FirstFromFlags(other.buffs).m_id;
 256                         //Send_Notification(NOTIF_ONE, other, MSG_MULTI, ITEM_BUFF_DROP, other.buffs);
 257                         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_ITEM_BUFF_LOST, other.netname, buffid);
 258
 259                         other.buffs = 0;
 260                         //sound(other, CH_TRIGGER, SND_BUFF_LOST, VOL_BASE, ATTN_NORM);
 261                 }
 262                 else { return; } // do nothing
 263         }
 264
 265         self.owner = other;
 266         self.buff_active = false;
 267         self.lifetime = 0;
 268         int buffid = buff_FirstFromFlags(self.buffs).m_id;
 269         Send_Notification(NOTIF_ONE, other, MSG_MULTI, ITEM_BUFF_GOT, buffid);
 270         Send_Notification(NOTIF_ALL_EXCEPT, other, MSG_INFO, INFO_ITEM_BUFF, other.netname, buffid);
 271
 272         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(self), '0 0 0', 1);
 273         sound(other, CH_TRIGGER, SND_SHIELD_RESPAWN, VOL_BASE, ATTN_NORM);
 274         other.buffs |= (self.buffs);
 275 }
 276
 277 float buff_Available(entity buff)
 278 {
 279         if (buff == BUFF_Null)
 280                 return false;
 281         if (buff == BUFF_AMMO && ((start_items & IT_UNLIMITED_WEAPON_AMMO) || (start_items & IT_UNLIMITED_AMMO) || (cvar("g_melee_only"))))
 282                 return false;
 283         if (buff == BUFF_VAMPIRE && cvar("g_vampire"))
 284                 return false;
 285         return cvar(strcat("g_buffs_", buff.m_name));
 286 }
 287
 288 .int buff_seencount;
 289
 290 void buff_NewType(entity ent, float cb)
 291 {
 292         RandomSelection_Init();
 293         FOREACH(Buffs, buff_Available(it), LAMBDA(
 294                 it.buff_seencount += 1;
 295                 // if it's already been chosen, give it a lower priority
 296                 RandomSelection_Add(world, it.m_itemid, string_null, 1, max(0.2, 1 / it.buff_seencount));
 297         ));
 298         ent.buffs = RandomSelection_chosen_float;
 299 }
 300
 301 void buff_Think()
 302 {SELFPARAM();
 303         if(self.buffs != self.oldbuffs)
 304         {
 305                 entity buff = buff_FirstFromFlags(self.buffs);
 306                 self.color = buff.m_color;
 307                 self.glowmod = buff_GlowColor(buff);
 308                 self.skin = buff.m_skin;
 309
 310                 setmodel(self, MDL_BUFF);
 311
 312                 if(self.buff_waypoint)
 313                 {
 314                         //WaypointSprite_Disown(self.buff_waypoint, 1);
 315                         WaypointSprite_Kill(self.buff_waypoint);
 316                         buff_Waypoint_Spawn(self);
 317                         if(self.buff_activetime)
 318                                 WaypointSprite_UpdateBuildFinished(self.buff_waypoint, time + self.buff_activetime - frametime);
 319                 }
 320
 321                 self.oldbuffs = self.buffs;
 322         }
 323
 324         if(!gameover)
 325         if((round_handler_IsActive() && !round_handler_IsRoundStarted()) || time >= game_starttime)
 326         if(!self.buff_activetime_updated)
 327         {
 328                 buff_SetCooldown(self.buff_activetime);
 329                 self.buff_activetime_updated = true;
 330         }
 331
 332         if(!self.buff_active && !self.buff_activetime)
 333         if(!self.owner || STAT(FROZEN, self.owner) || IS_DEAD(self.owner) || !self.owner.iscreature || !(self.owner.buffs & self.buffs))
 334         {
 335                 buff_SetCooldown(autocvar_g_buffs_cooldown_respawn + frametime);
 336                 self.owner = world;
 337                 if(autocvar_g_buffs_randomize)
 338                         buff_NewType(self, self.buffs);
 339
 340                 if(autocvar_g_buffs_random_location || (self.spawnflags & 64))
 341                         buff_Respawn(self);
 342         }
 343
 344         if(self.buff_activetime)
 345         if(!gameover)
 346         if((round_handler_IsActive() && !round_handler_IsRoundStarted()) || time >= game_starttime)
 347         {
 348                 self.buff_activetime = max(0, self.buff_activetime - frametime);
 349
 350                 if(!self.buff_activetime)
 351                 {
 352                         self.buff_active = true;
 353                         sound(self, CH_TRIGGER, SND_STRENGTH_RESPAWN, VOL_BASE, ATTN_NORM);
 354                         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(self), '0 0 0', 1);
 355                 }
 356         }
 357
 358         if(self.buff_active)
 359         {
 360                 if(self.team && !self.buff_waypoint)
 361                         buff_Waypoint_Spawn(self);
 362
 363                 if(self.lifetime)
 364                 if(time >= self.lifetime)
 365                         buff_Respawn(self);
 366         }
 367
 368         self.nextthink = time;
 369         //self.angles_y = time * 110.1;
 370 }
 371
 372 void buff_Waypoint_Reset()
 373 {SELFPARAM();
 374         WaypointSprite_Kill(self.buff_waypoint);
 375
 376         if(self.buff_activetime) { buff_Waypoint_Spawn(self); }
 377 }
 378
 379 void buff_Reset(entity this)
 380 {
 381         if(autocvar_g_buffs_randomize)
 382                 buff_NewType(this, this.buffs);
 383         this.owner = world;
 384         buff_SetCooldown(autocvar_g_buffs_cooldown_activate);
 385         buff_Waypoint_Reset();
 386         this.buff_activetime_updated = false;
 387
 388         if(autocvar_g_buffs_random_location || (this.spawnflags & 64))
 389                 buff_Respawn(this);
 390 }
 391
 392 float buff_Customize()
 393 {SELFPARAM();
 394         entity player = WaypointSprite_getviewentity(other);
 395         if(!self.buff_active || (self.team && DIFF_TEAM(player, self)))
 396         {
 397                 self.alpha = 0.3;
 398                 if(self.effects & EF_FULLBRIGHT) { self.effects &= ~(EF_FULLBRIGHT); }
 399                 self.pflags = 0;
 400         }
 401         else
 402         {
 403                 self.alpha = 1;
 404                 if(!(self.effects & EF_FULLBRIGHT)) { self.effects |= EF_FULLBRIGHT; }
 405                 self.light_lev = 220 + 36 * sin(time);
 406                 self.pflags = PFLAGS_FULLDYNAMIC;
 407         }
 408         return true;
 409 }
 410
 411 void buff_Init(entity ent)
 412 {SELFPARAM();
 413         if(!cvar("g_buffs")) { remove(ent); return; }
 414
 415         if(!teamplay && ent.team) { ent.team = 0; }
 416
 417         entity buff = buff_FirstFromFlags(self.buffs);
 418
 419         setself(ent);
 420         if(!self.buffs || buff_Available(buff))
 421                 buff_NewType(self, 0);
 422
 423         self.classname = "item_buff";
 424         self.solid = SOLID_TRIGGER;
 425         self.flags = FL_ITEM;
 426         self.think = buff_Think;
 427         self.touch = buff_Touch;
 428         self.reset = buff_Reset;
 429         self.nextthink = time + 0.1;
 430         self.gravity = 1;
 431         self.movetype = MOVETYPE_TOSS;
 432         self.scale = 1;
 433         self.skin = buff.m_skin;
 434         self.effects = EF_FULLBRIGHT | EF_STARDUST | EF_NOSHADOW;
 435         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY;
 436         self.customizeentityforclient = buff_Customize;
 437         //self.gravity = 100;
 438         self.color = buff.m_color;
 439         self.glowmod = buff_GlowColor(self);
 440         buff_SetCooldown(autocvar_g_buffs_cooldown_activate + game_starttime);
 441         self.buff_active = !self.buff_activetime;
 442         self.pflags = PFLAGS_FULLDYNAMIC;
 443
 444         if(self.spawnflags & 1)
 445                 self.noalign = true;
 446
 447         if(self.noalign)
 448                 self.movetype = MOVETYPE_NONE; // reset by random location
 449
 450         setmodel(self, MDL_BUFF);
 451         setsize(self, BUFF_MIN, BUFF_MAX);
 452
 453         if(cvar("g_buffs_random_location") || (self.spawnflags & 64))
 454                 buff_Respawn(self);
 455
 456         setself(this);
 457 }
 458
 459 void buff_Init_Compat(entity ent, entity replacement)
 460 {
 461         if (ent.spawnflags & 2)
 462                 ent.team = NUM_TEAM_1;
 463         else if (ent.spawnflags & 4)
 464                 ent.team = NUM_TEAM_2;
 465
 466         ent.buffs = replacement.m_itemid;
 467
 468         buff_Init(ent);
 469 }
 470
 471 void buff_SpawnReplacement(entity ent, entity old)
 472 {
 473         setorigin(ent, old.origin);
 474         ent.angles = old.angles;
 475         ent.noalign = (old.noalign || (old.spawnflags & 1));
 476
 477         buff_Init(ent);
 478 }
 479
 480 void buff_Vengeance_DelayedDamage()
 481 {SELFPARAM();
 482         if(self.enemy)
 483                 Damage(self.enemy, self.owner, self.owner, self.dmg, DEATH_BUFF.m_id, self.enemy.origin, '0 0 0');
 484
 485         remove(self);
 486         return;
 487 }
 488
 489 // note: only really useful in teamplay
 490 void buff_Medic_Heal(entity this)
 491 {
 492         FOREACH_CLIENT(IS_PLAYER(it) && it != this && vdist(it.origin - this.origin, <=, autocvar_g_buffs_medic_heal_range),
 493         {
 494                 if(SAME_TEAM(it, this))
 495                 if(it.health < autocvar_g_balance_health_regenstable)
 496                 {
 497                         Send_Effect(EFFECT_HEALING, it.origin, '0 0 0', 1);
 498                         it.health = bound(0, it.health + autocvar_g_buffs_medic_heal_amount, autocvar_g_balance_health_regenstable);
 499                 }
 500         });
 501 }
 502
 503 float buff_Inferno_CalculateTime(float x, float offset_x, float offset_y, float intersect_x, float intersect_y, float base)
 504 {
 505         return offset_y + (intersect_y - offset_y) * logn(((x - offset_x) * ((base - 1) / intersect_x)) + 1, base);
 506 }
 507
 508 // mutator hooks
 509 MUTATOR_HOOKFUNCTION(buffs, PlayerDamage_SplitHealthArmor)
 510 {
 511         if(frag_deathtype == DEATH_BUFF.m_id) { return false; }
 512
 513         if(frag_target.buffs & BUFF_RESISTANCE.m_itemid)
 514         {
 515                 vector v = healtharmor_applydamage(50, autocvar_g_buffs_resistance_blockpercent, frag_deathtype, frag_damage);
 516                 damage_take = v.x;
 517                 damage_save = v.y;
 518         }
 519
 520         return false;
 521 }
 522
 523 MUTATOR_HOOKFUNCTION(buffs, PlayerDamage_Calculate)
 524 {
 525         if(frag_deathtype == DEATH_BUFF.m_id) { return false; }
 526
 527         if(frag_target.buffs & BUFF_SPEED.m_itemid)
 528         if(frag_target != frag_attacker)
 529                 frag_damage *= autocvar_g_buffs_speed_damage_take;
 530
 531         if(frag_target.buffs & BUFF_MEDIC.m_itemid)
 532         if((frag_target.health - frag_damage) <= 0)
 533         if(!ITEM_DAMAGE_NEEDKILL(frag_deathtype))
 534         if(frag_attacker)
 535         if(random() <= autocvar_g_buffs_medic_survive_chance)
 536                 frag_damage = max(5, frag_target.health - autocvar_g_buffs_medic_survive_health);
 537
 538         if(frag_target.buffs & BUFF_JUMP.m_itemid)
 539         if(frag_deathtype == DEATH_FALL.m_id)
 540                 frag_damage = 0;
 541
 542         if(frag_target.buffs & BUFF_VENGEANCE.m_itemid)
 543         if(frag_attacker)
 544         if(frag_attacker != frag_target)
 545         if(!ITEM_DAMAGE_NEEDKILL(frag_deathtype))
 546         {
 547                 entity dmgent = spawn();
 548
 549                 dmgent.dmg = frag_damage * autocvar_g_buffs_vengeance_damage_multiplier;
 550                 dmgent.enemy = frag_attacker;
 551                 dmgent.owner = frag_target;
 552                 dmgent.think = buff_Vengeance_DelayedDamage;
 553                 dmgent.nextthink = time + 0.1;
 554         }
 555
 556         if(frag_target.buffs & BUFF_BASH.m_itemid)
 557         if(frag_attacker != frag_target)
 558                 frag_force = '0 0 0';
 559
 560         if(frag_attacker.buffs & BUFF_BASH.m_itemid)
 561         if(frag_force)
 562         if(frag_attacker == frag_target)
 563                 frag_force *= autocvar_g_buffs_bash_force_self;
 564         else
 565                 frag_force *= autocvar_g_buffs_bash_force;
 566
 567         if(frag_attacker.buffs & BUFF_DISABILITY.m_itemid)
 568         if(frag_target != frag_attacker)
 569                 frag_target.buff_disability_time = time + autocvar_g_buffs_disability_slowtime;
 570
 571         if(frag_target.buffs & BUFF_INFERNO.m_itemid)
 572         {
 573                 if(frag_deathtype == DEATH_FIRE.m_id)
 574                         frag_damage = 0;
 575                 if(frag_deathtype == DEATH_LAVA.m_id)
 576                         frag_damage *= 0.5; // TODO: cvarize?
 577         }
 578
 579         if(frag_attacker.buffs & BUFF_LUCK.m_itemid)
 580         if(frag_attacker != frag_target)
 581         if(autocvar_g_buffs_luck_damagemultiplier > 0)
 582         if(random() <= autocvar_g_buffs_luck_chance)
 583                 frag_damage *= autocvar_g_buffs_luck_damagemultiplier;
 584
 585         if(frag_attacker.buffs & BUFF_INFERNO.m_itemid)
 586         if(frag_target != frag_attacker) {
 587                 float btime = buff_Inferno_CalculateTime(
 588                         frag_damage,
 589                         0,
 590                         autocvar_g_buffs_inferno_burntime_min_time,
 591                         autocvar_g_buffs_inferno_burntime_target_damage,
 592                         autocvar_g_buffs_inferno_burntime_target_time,
 593                         autocvar_g_buffs_inferno_burntime_factor
 594                 );
 595                 Fire_AddDamage(frag_target, frag_attacker, (frag_damage * autocvar_g_buffs_inferno_damagemultiplier), btime, DEATH_BUFF.m_id);
 596         }
 597
 598         // this... is ridiculous (TODO: fix!)
 599         if(frag_attacker.buffs & BUFF_VAMPIRE.m_itemid)
 600         if(!frag_target.vehicle)
 601         if(DEATH_WEAPONOF(frag_deathtype) != WEP_ARC)
 602         if(!ITEM_DAMAGE_NEEDKILL(frag_deathtype))
 603         if(!IS_DEAD(frag_target))
 604         if(IS_PLAYER(frag_target) || IS_MONSTER(frag_target))
 605         if(frag_attacker != frag_target)
 606         if(!STAT(FROZEN, frag_target))
 607         if(frag_target.takedamage)
 608         if(DIFF_TEAM(frag_attacker, frag_target))
 609         {
 610                 frag_attacker.health = bound(0, frag_attacker.health + bound(0, frag_damage * autocvar_g_buffs_vampire_damage_steal, frag_target.health), g_pickup_healthsmall_max);
 611                 if(frag_target.armorvalue)
 612                         frag_attacker.armorvalue = bound(0, frag_attacker.armorvalue + bound(0, frag_damage * autocvar_g_buffs_vampire_damage_steal, frag_target.armorvalue), g_pickup_armorsmall_max);
 613         }
 614
 615         return false;
 616 }
 617
 618 MUTATOR_HOOKFUNCTION(buffs,PlayerSpawn)
 619 {SELFPARAM();
 620         self.buffs = 0;
 621         // reset timers here to prevent them continuing after re-spawn
 622         self.buff_disability_time = 0;
 623         self.buff_disability_effect_time = 0;
 624         return false;
 625 }
 626
 627 .float stat_sv_maxspeed;
 628 .float stat_sv_airspeedlimit_nonqw;
 629 .float stat_sv_jumpvelocity;
 630
 631 MUTATOR_HOOKFUNCTION(buffs, PlayerPhysics)
 632 {SELFPARAM();
 633         if(self.buffs & BUFF_SPEED.m_itemid)
 634         {
 635                 self.stat_sv_maxspeed *= autocvar_g_buffs_speed_speed;
 636                 self.stat_sv_airspeedlimit_nonqw *= autocvar_g_buffs_speed_speed;
 637         }
 638
 639         if(time < self.buff_disability_time)
 640         {
 641                 self.stat_sv_maxspeed *= autocvar_g_buffs_disability_speed;
 642                 self.stat_sv_airspeedlimit_nonqw *= autocvar_g_buffs_disability_speed;
 643         }
 644
 645         if(self.buffs & BUFF_JUMP.m_itemid)
 646         {
 647                 // automatically reset, no need to worry
 648                 self.stat_sv_jumpvelocity = autocvar_g_buffs_jump_height;
 649         }
 650
 651         return false;
 652 }
 653
 654 MUTATOR_HOOKFUNCTION(buffs, PlayerJump)
 655 {SELFPARAM();
 656         if(self.buffs & BUFF_JUMP.m_itemid)
 657                 player_jumpheight = autocvar_g_buffs_jump_height;
 658
 659         return false;
 660 }
 661
 662 MUTATOR_HOOKFUNCTION(buffs, MonsterMove)
 663 {SELFPARAM();
 664         if(time < self.buff_disability_time)
 665         {
 666                 monster_speed_walk *= autocvar_g_buffs_disability_speed;
 667                 monster_speed_run *= autocvar_g_buffs_disability_speed;
 668         }
 669
 670         return false;
 671 }
 672
 673 MUTATOR_HOOKFUNCTION(buffs, PlayerDies)
 674 {
 675         if(frag_target.buffs)
 676         {
 677                 int buffid = buff_FirstFromFlags(frag_target.buffs).m_id;
 678                 Send_Notification(NOTIF_ALL_EXCEPT, frag_target, MSG_INFO, INFO_ITEM_BUFF_LOST, frag_target.netname, buffid);
 679                 frag_target.buffs = 0;
 680
 681                 if(frag_target.buff_model)
 682                 {
 683                         remove(frag_target.buff_model);
 684                         frag_target.buff_model = world;
 685                 }
 686         }
 687         return false;
 688 }
 689
 690 MUTATOR_HOOKFUNCTION(buffs, PlayerUseKey, CBC_ORDER_FIRST)
 691 {SELFPARAM();
 692         if(MUTATOR_RETURNVALUE || gameover) { return false; }
 693         if(self.buffs)
 694         {
 695                 int buffid = buff_FirstFromFlags(self.buffs).m_id;
 696                 Send_Notification(NOTIF_ONE, self, MSG_MULTI, ITEM_BUFF_DROP, buffid);
 697                 Send_Notification(NOTIF_ALL_EXCEPT, self, MSG_INFO, INFO_ITEM_BUFF_LOST, self.netname, buffid);
 698
 699                 self.buffs = 0;
 700                 sound(self, CH_TRIGGER, SND_BUFF_LOST, VOL_BASE, ATTN_NORM);
 701                 return true;
 702         }
 703         return false;
 704 }
 705
 706 MUTATOR_HOOKFUNCTION(buffs, ForbidThrowCurrentWeapon)
 707 {SELFPARAM();
 708         if(MUTATOR_RETURNVALUE || gameover) { return false; }
 709
 710         if(self.buffs & BUFF_SWAPPER.m_itemid)
 711         {
 712                 float best_distance = autocvar_g_buffs_swapper_range;
 713                 entity closest = world;
 714                 FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
 715                         if(!IS_DEAD(it) && !STAT(FROZEN, it) && !it.vehicle)
 716                         if(DIFF_TEAM(it, self))
 717                         {
 718                                 float test = vlen2(self.origin - it.origin);
 719                                 if(test <= best_distance * best_distance)
 720                                 {
 721                                         best_distance = sqrt(test);
 722                                         closest = it;
 723                                 }
 724                         }
 725                 ));
 726
 727                 if(closest)
 728                 {
 729                         vector my_org, my_vel, my_ang, their_org, their_vel, their_ang;
 730
 731                         my_org = self.origin;
 732                         my_vel = self.velocity;
 733                         my_ang = self.angles;
 734                         their_org = closest.origin;
 735                         their_vel = closest.velocity;
 736                         their_ang = closest.angles;
 737
 738                         Drop_Special_Items(closest);
 739
 740                         MUTATOR_CALLHOOK(PortalTeleport, self); // initiate flag dropper
 741
 742                         setorigin(self, their_org);
 743                         setorigin(closest, my_org);
 744
 745                         closest.velocity = my_vel;
 746                         closest.angles = my_ang;
 747                         closest.fixangle = true;
 748                         closest.oldorigin = my_org;
 749                         closest.oldvelocity = my_vel;
 750                         self.velocity = their_vel;
 751                         self.angles = their_ang;
 752                         self.fixangle = true;
 753                         self.oldorigin = their_org;
 754                         self.oldvelocity = their_vel;
 755
 756                         // set pusher so self gets the kill if they fall into void
 757                         closest.pusher = self;
 758                         closest.pushltime = time + autocvar_g_maxpushtime;
 759                         closest.istypefrag = closest.BUTTON_CHAT;
 760
 761                         Send_Effect(EFFECT_ELECTRO_COMBO, their_org, '0 0 0', 1);
 762                         Send_Effect(EFFECT_ELECTRO_COMBO, my_org, '0 0 0', 1);
 763
 764                         sound(self, CH_TRIGGER, SND_KA_RESPAWN, VOL_BASE, ATTEN_NORM);
 765                         sound(closest, CH_TRIGGER, SND_KA_RESPAWN, VOL_BASE, ATTEN_NORM);
 766
 767                         // TODO: add a counter to handle how many times one can teleport, and a delay to prevent spam
 768                         self.buffs = 0;
 769                         return true;
 770                 }
 771         }
 772         return false;
 773 }
 774
 775 bool buffs_RemovePlayer(entity player)
 776 {
 777         if(player.buff_model)
 778         {
 779                 remove(player.buff_model);
 780                 player.buff_model = world;
 781         }
 782
 783         // also reset timers here to prevent them continuing after spectating
 784         player.buff_disability_time = 0;
 785         player.buff_disability_effect_time = 0;
 786
 787         return false;
 788 }
 789 MUTATOR_HOOKFUNCTION(buffs, MakePlayerObserver) { return buffs_RemovePlayer(self); }
 790 MUTATOR_HOOKFUNCTION(buffs, ClientDisconnect) { return buffs_RemovePlayer(self); }
 791
 792 MUTATOR_HOOKFUNCTION(buffs, CustomizeWaypoint)
 793 {SELFPARAM();
 794         entity e = WaypointSprite_getviewentity(other);
 795
 796         // if you have the invisibility powerup, sprites ALWAYS are restricted to your team
 797         // but only apply this to real players, not to spectators
 798         if((self.owner.flags & FL_CLIENT) && (self.owner.buffs & BUFF_INVISIBLE.m_itemid) && (e == other))
 799         if(DIFF_TEAM(self.owner, e))
 800                 return true;
 801
 802         return false;
 803 }
 804
 805 MUTATOR_HOOKFUNCTION(buffs, OnEntityPreSpawn, CBC_ORDER_LAST)
 806 {SELFPARAM();
 807         if(autocvar_g_buffs_replace_powerups)
 808         switch(self.classname)
 809         {
 810                 case "item_strength":
 811                 case "item_invincible":
 812                 {
 813                         entity e = spawn();
 814                         buff_SpawnReplacement(e, self);
 815                         return true;
 816                 }
 817         }
 818         return false;
 819 }
 820
 821 MUTATOR_HOOKFUNCTION(buffs, WeaponRateFactor)
 822 {SELFPARAM();
 823         if(self.buffs & BUFF_SPEED.m_itemid)
 824                 weapon_rate *= autocvar_g_buffs_speed_rate;
 825
 826         if(time < self.buff_disability_time)
 827                 weapon_rate *= autocvar_g_buffs_disability_rate;
 828
 829         return false;
 830 }
 831
 832 MUTATOR_HOOKFUNCTION(buffs, WeaponSpeedFactor)
 833 {SELFPARAM();
 834         if(self.buffs & BUFF_SPEED.m_itemid)
 835                 ret_float *= autocvar_g_buffs_speed_weaponspeed;
 836
 837         if(time < self.buff_disability_time)
 838                 ret_float *= autocvar_g_buffs_disability_weaponspeed;
 839
 840         return false;
 841 }
 842
 843 MUTATOR_HOOKFUNCTION(buffs, PlayerPreThink)
 844 {SELFPARAM();
 845         if(gameover || IS_DEAD(self)) { return false; }
 846
 847         if(time < self.buff_disability_time)
 848         if(time >= self.buff_disability_effect_time)
 849         {
 850                 Send_Effect(EFFECT_SMOKING, self.origin + ((self.mins + self.maxs) * 0.5), '0 0 0', 1);
 851                 self.buff_disability_effect_time = time + 0.5;
 852         }
 853
 854         // handle buff lost status
 855         // 1: notify everyone else
 856         // 2: notify carrier as well
 857         int buff_lost = 0;
 858
 859         if(self.buff_time)
 860         if(time >= self.buff_time)
 861                 buff_lost = 2;
 862
 863         if(STAT(FROZEN, self)) { buff_lost = 1; }
 864
 865         if(buff_lost)
 866         {
 867                 if(self.buffs)
 868                 {
 869                         int buffid = buff_FirstFromFlags(self.buffs).m_id;
 870                         Send_Notification(NOTIF_ALL_EXCEPT, self, MSG_INFO, INFO_ITEM_BUFF_LOST, self.netname, buffid);
 871                         if(buff_lost >= 2)
 872                         {
 873                                 Send_Notification(NOTIF_ONE, self, MSG_MULTI, ITEM_BUFF_DROP, buffid); // TODO: special timeout message?
 874                                 sound(self, CH_TRIGGER, SND_BUFF_LOST, VOL_BASE, ATTN_NORM);
 875                         }
 876                         self.buffs = 0;
 877                 }
 878         }
 879
 880         if(self.buffs & BUFF_MAGNET.m_itemid)
 881         {
 882                 vector pickup_size;
 883                 FOREACH_ENTITY_FLAGS(flags, FL_ITEM,
 884                 {
 885                         if(it.buffs)
 886                                 pickup_size = '1 1 1' * autocvar_g_buffs_magnet_range_buff;
 887                         else
 888                                 pickup_size = '1 1 1' * autocvar_g_buffs_magnet_range_item;
 889
 890                         if(boxesoverlap(self.absmin - pickup_size, self.absmax + pickup_size, it.absmin, it.absmax))
 891                         {
 892                                 if(it.touch)
 893                                 {
 894                                         entity oldother = other;
 895                                         other = self;
 896                                         WITH(entity, self, it, it.touch());
 897
 898                                         other = oldother;
 899                                 }
 900                         }
 901                 });
 902         }
 903
 904         if(self.buffs & BUFF_AMMO.m_itemid)
 905         if(self.clip_size)
 906                 self.clip_load = self.(weapon_load[PS(self).m_switchweapon.m_id]) = self.clip_size;
 907
 908         if((self.buffs & BUFF_INVISIBLE.m_itemid) && (self.oldbuffs & BUFF_INVISIBLE.m_itemid))
 909         if(self.alpha != autocvar_g_buffs_invisible_alpha)
 910                 self.alpha = autocvar_g_buffs_invisible_alpha; // powerups reset alpha, so we must enforce this (TODO)
 911
 912         if(self.buffs & BUFF_MEDIC.m_itemid)
 913         if(time >= self.buff_medic_healtime)
 914         {
 915                 buff_Medic_Heal(self);
 916                 self.buff_medic_healtime = time + autocvar_g_buffs_medic_heal_delay;
 917         }
 918
 919 #define BUFF_ONADD(b) if ( (self.buffs & (b).m_itemid) && !(self.oldbuffs & (b).m_itemid))
 920 #define BUFF_ONREM(b) if (!(self.buffs & (b).m_itemid) &&  (self.oldbuffs & (b).m_itemid))
 921
 922         if(self.buffs != self.oldbuffs)
 923         {
 924                 entity buff = buff_FirstFromFlags(self.buffs);
 925                 float bufftime = buff != BUFF_Null ? buff.m_time(buff) : 0;
 926                 self.buff_time = (bufftime) ? time + bufftime : 0;
 927
 928                 BUFF_ONADD(BUFF_AMMO)
 929                 {
 930                         self.buff_ammo_prev_infitems = (self.items & IT_UNLIMITED_WEAPON_AMMO);
 931                         self.items |= IT_UNLIMITED_WEAPON_AMMO;
 932
 933                         if(self.clip_load)
 934                                 self.buff_ammo_prev_clipload = self.clip_load;
 935                         self.clip_load = self.(weapon_load[PS(self).m_switchweapon.m_id]) = self.clip_size;
 936                 }
 937
 938                 BUFF_ONREM(BUFF_AMMO)
 939                 {
 940                         if(self.buff_ammo_prev_infitems)
 941                                 self.items |= IT_UNLIMITED_WEAPON_AMMO;
 942                         else
 943                                 self.items &= ~IT_UNLIMITED_WEAPON_AMMO;
 944
 945                         if(self.buff_ammo_prev_clipload)
 946                                 self.clip_load = self.buff_ammo_prev_clipload;
 947                 }
 948
 949                 BUFF_ONADD(BUFF_INVISIBLE)
 950                 {
 951                         if(time < self.strength_finished && g_instagib)
 952                                 self.alpha = autocvar_g_instagib_invis_alpha;
 953                         else
 954                                 self.alpha = self.buff_invisible_prev_alpha;
 955                         self.alpha = autocvar_g_buffs_invisible_alpha;
 956                 }
 957
 958                 BUFF_ONREM(BUFF_INVISIBLE)
 959                         self.alpha = self.buff_invisible_prev_alpha;
 960
 961                 self.oldbuffs = self.buffs;
 962                 if(self.buffs)
 963                 {
 964                         if(!self.buff_model)
 965                                 buffs_BuffModel_Spawn(self);
 966
 967                         self.buff_model.color = buff.m_color;
 968                         self.buff_model.glowmod = buff_GlowColor(self.buff_model);
 969                         self.buff_model.skin = buff.m_skin;
 970
 971                         self.effects |= EF_NOSHADOW;
 972                 }
 973                 else
 974                 {
 975                         remove(self.buff_model);
 976                         self.buff_model = world;
 977
 978                         self.effects &= ~(EF_NOSHADOW);
 979                 }
 980         }
 981
 982         if(self.buff_model)
 983         {
 984                 self.buff_model.effects = self.effects;
 985                 self.buff_model.effects |= EF_LOWPRECISION;
 986                 self.buff_model.effects = self.buff_model.effects & EFMASK_CHEAP; // eat performance
 987
 988                 self.buff_model.alpha = self.alpha;
 989         }
 990
 991 #undef BUFF_ONADD
 992 #undef BUFF_ONREM
 993         return false;
 994 }
 995
 996 MUTATOR_HOOKFUNCTION(buffs, SpectateCopy)
 997 {SELFPARAM();
 998         self.buffs = other.buffs;
 999         return false;
1000 }
1001
1002 MUTATOR_HOOKFUNCTION(buffs, VehicleEnter)
1003 {
1004         vh_vehicle.buffs = vh_player.buffs;
1005         vh_player.buffs = 0;
1006         vh_vehicle.buff_time = max(0, vh_player.buff_time - time);
1007         vh_player.buff_time = 0;
1008         return false;
1009 }
1010
1011 MUTATOR_HOOKFUNCTION(buffs, VehicleExit)
1012 {
1013         vh_player.buffs = vh_player.oldbuffs = vh_vehicle.buffs;
1014         vh_vehicle.buffs = 0;
1015         vh_player.buff_time = time + vh_vehicle.buff_time;
1016         vh_vehicle.buff_time = 0;
1017         return false;
1018 }
1019
1020 MUTATOR_HOOKFUNCTION(buffs, PlayerRegen)
1021 {SELFPARAM();
1022         if(self.buffs & BUFF_MEDIC.m_itemid)
1023         {
1024                 regen_mod_rot = autocvar_g_buffs_medic_rot;
1025                 regen_mod_limit = regen_mod_max = autocvar_g_buffs_medic_max;
1026                 regen_mod_regen = autocvar_g_buffs_medic_regen;
1027         }
1028
1029         if(self.buffs & BUFF_SPEED.m_itemid)
1030                 regen_mod_regen = autocvar_g_buffs_speed_regen;
1031
1032         return false;
1033 }
1034
1035 MUTATOR_HOOKFUNCTION(buffs, GetCvars)
1036 {
1037         GetCvars_handleFloat(get_cvars_s, get_cvars_f, cvar_cl_buffs_autoreplace, "cl_buffs_autoreplace");
1038         return false;
1039 }
1040
1041 MUTATOR_HOOKFUNCTION(buffs, BuildMutatorsString)
1042 {
1043         ret_string = strcat(ret_string, ":Buffs");
1044         return false;
1045 }
1046
1047 MUTATOR_HOOKFUNCTION(buffs, BuildMutatorsPrettyString)
1048 {
1049         ret_string = strcat(ret_string, ", Buffs");
1050         return false;
1051 }
1052
1053 void buffs_DelayedInit()
1054 {
1055         if(autocvar_g_buffs_spawn_count > 0)
1056         if(find(world, classname, "item_buff") == world)
1057         {
1058                 float i;
1059                 for(i = 0; i < autocvar_g_buffs_spawn_count; ++i)
1060                 {
1061                         entity e = spawn();
1062                         e.spawnflags |= 64; // always randomize
1063                         e.velocity = randomvec() * 250; // this gets reset anyway if random location works
1064                         buff_Init(e);
1065                 }
1066         }
1067 }
1068 #endif