qcsrc/common/mutators/mutator/buffs/buffs.qc

   1 #ifndef MUTATOR_BUFFS_H
   2 #define MUTATOR_BUFFS_H
   3
   4 #include "../instagib/module.inc"
   5
   6 bool  autocvar_g_buffs_effects;
   7 float autocvar_g_buffs_waypoint_distance;
   8 bool autocvar_g_buffs_randomize;
   9 float autocvar_g_buffs_random_lifetime;
  10 bool autocvar_g_buffs_random_location;
  11 int autocvar_g_buffs_random_location_attempts;
  12 int autocvar_g_buffs_spawn_count;
  13 bool autocvar_g_buffs_replace_powerups;
  14 float autocvar_g_buffs_cooldown_activate;
  15 float autocvar_g_buffs_cooldown_respawn;
  16 float autocvar_g_buffs_resistance_blockpercent;
  17 float autocvar_g_buffs_medic_survive_chance;
  18 float autocvar_g_buffs_medic_survive_health;
  19 float autocvar_g_buffs_medic_rot;
  20 float autocvar_g_buffs_medic_max;
  21 float autocvar_g_buffs_medic_regen;
  22 float autocvar_g_buffs_medic_heal_amount = 15;
  23 float autocvar_g_buffs_medic_heal_delay = 1;
  24 float autocvar_g_buffs_medic_heal_range = 400;
  25 float autocvar_g_buffs_vengeance_damage_multiplier;
  26 float autocvar_g_buffs_bash_force;
  27 float autocvar_g_buffs_bash_force_self;
  28 float autocvar_g_buffs_disability_slowtime;
  29 float autocvar_g_buffs_disability_speed;
  30 float autocvar_g_buffs_disability_rate;
  31 float autocvar_g_buffs_disability_weaponspeed;
  32 float autocvar_g_buffs_speed_speed;
  33 float autocvar_g_buffs_speed_rate;
  34 float autocvar_g_buffs_speed_weaponspeed;
  35 float autocvar_g_buffs_speed_damage_take;
  36 float autocvar_g_buffs_speed_regen;
  37 float autocvar_g_buffs_vampire_damage_steal;
  38 float autocvar_g_buffs_invisible_alpha;
  39 float autocvar_g_buffs_jump_height;
  40 float autocvar_g_buffs_inferno_burntime_factor;
  41 float autocvar_g_buffs_inferno_burntime_min_time;
  42 float autocvar_g_buffs_inferno_burntime_target_damage;
  43 float autocvar_g_buffs_inferno_burntime_target_time;
  44 float autocvar_g_buffs_inferno_damagemultiplier;
  45 float autocvar_g_buffs_swapper_range;
  46 float autocvar_g_buffs_magnet_range_item;
  47 float autocvar_g_buffs_magnet_range_buff = 200;
  48 float autocvar_g_buffs_luck_chance = 0.15;
  49 float autocvar_g_buffs_luck_damagemultiplier = 3;
  50
  51 // ammo
  52 .float buff_ammo_prev_infitems;
  53 .int buff_ammo_prev_clipload;
  54 // invisible
  55 .float buff_invisible_prev_alpha;
  56 // medic
  57 .float buff_medic_healtime;
  58 // disability
  59 .float buff_disability_time;
  60 .float buff_disability_effect_time;
  61 // common buff variables
  62 .float buff_effect_delay;
  63
  64 // buff definitions
  65 .float buff_active;
  66 .float buff_activetime;
  67 .float buff_activetime_updated;
  68 .entity buff_waypoint;
  69 .int oldbuffs; // for updating effects
  70 .entity buff_model; // controls effects (TODO: make csqc)
  71
  72 const vector BUFF_MIN = ('-16 -16 -20');
  73 const vector BUFF_MAX = ('16 16 20');
  74
  75 // client side options
  76 .float cvar_cl_buffs_autoreplace;
  77 #endif
  78
  79 #ifdef IMPLEMENTATION
  80
  81 #include <common/triggers/target/music.qh>
  82 #include <common/gamemodes/all.qh>
  83
  84 .float buff_time = _STAT(BUFF_TIME);
  85 void buffs_DelayedInit(entity this);
  86
  87 REGISTER_MUTATOR(buffs, cvar("g_buffs"))
  88 {
  89         MUTATOR_ONADD
  90         {
  91                 InitializeEntity(world, buffs_DelayedInit, INITPRIO_FINDTARGET);
  92         }
  93 }
  94
  95 bool buffs_BuffModel_Customize()
  96 {SELFPARAM();
  97         entity player, myowner;
  98         bool same_team;
  99
 100         player = WaypointSprite_getviewentity(other);
 101         myowner = self.owner;
 102         same_team = (SAME_TEAM(player, myowner) || SAME_TEAM(player, myowner));
 103
 104         if(myowner.alpha <= 0.5 && !same_team && myowner.alpha != 0)
 105                 return false;
 106
 107         if(MUTATOR_CALLHOOK(BuffModel_Customize, self, player))
 108                 return false;
 109
 110         if(player == myowner || (IS_SPEC(other) && other.enemy == myowner))
 111         {
 112                 // somewhat hide the model, but keep the glow
 113                 self.effects = 0;
 114                 self.alpha = -1;
 115         }
 116         else
 117         {
 118                 self.effects = EF_FULLBRIGHT | EF_LOWPRECISION;
 119                 self.alpha = 1;
 120         }
 121         return true;
 122 }
 123
 124 void buffs_BuffModel_Spawn(entity player)
 125 {
 126         player.buff_model = spawn();
 127         setmodel(player.buff_model, MDL_BUFF);
 128         setsize(player.buff_model, '0 0 -40', '0 0 40');
 129         setattachment(player.buff_model, player, "");
 130         setorigin(player.buff_model, '0 0 1' * (player.buff_model.maxs.z * 1));
 131         player.buff_model.owner = player;
 132         player.buff_model.scale = 0.7;
 133         player.buff_model.pflags = PFLAGS_FULLDYNAMIC;
 134         player.buff_model.light_lev = 200;
 135         player.buff_model.customizeentityforclient = buffs_BuffModel_Customize;
 136 }
 137
 138 vector buff_GlowColor(entity buff)
 139 {
 140         //if(buff.team) { return Team_ColorRGB(buff.team); }
 141         return buff.m_color;
 142 }
 143
 144 void buff_Effect(entity player, string eff)
 145 {SELFPARAM();
 146         if(!autocvar_g_buffs_effects) { return; }
 147
 148         if(time >= self.buff_effect_delay)
 149         {
 150                 Send_Effect_(eff, player.origin + ((player.mins + player.maxs) * 0.5), '0 0 0', 1);
 151                 self.buff_effect_delay = time + 0.05; // prevent spam
 152         }
 153 }
 154
 155 // buff item
 156 bool buff_Waypoint_visible_for_player(entity this, entity player, entity view)
 157 {
 158         if(!this.owner.buff_active && !this.owner.buff_activetime)
 159                 return false;
 160
 161         if (view.buffs)
 162         {
 163                 return view.cvar_cl_buffs_autoreplace == false || view.buffs != this.owner.buffs;
 164         }
 165
 166         return WaypointSprite_visible_for_player(this, player, view);
 167 }
 168
 169 void buff_Waypoint_Spawn(entity e)
 170 {
 171         entity buff = buff_FirstFromFlags(e.buffs);
 172         entity wp = WaypointSprite_Spawn(WP_Buff, 0, autocvar_g_buffs_waypoint_distance, e, '0 0 1' * e.maxs.z, world, e.team, e, buff_waypoint, true, RADARICON_Buff);
 173         wp.wp_extra = buff.m_id;
 174         WaypointSprite_UpdateTeamRadar(e.buff_waypoint, RADARICON_Buff, e.glowmod);
 175         e.buff_waypoint.waypointsprite_visible_for_player = buff_Waypoint_visible_for_player;
 176 }
 177
 178 void buff_SetCooldown(entity this, float cd)
 179 {
 180         cd = max(0, cd);
 181
 182         if(!this.buff_waypoint)
 183                 buff_Waypoint_Spawn(this);
 184
 185         WaypointSprite_UpdateBuildFinished(this.buff_waypoint, time + cd);
 186         this.buff_activetime = cd;
 187         this.buff_active = !cd;
 188 }
 189
 190 void buff_Respawn(entity this)
 191 {
 192         if(gameover) { return; }
 193
 194         vector oldbufforigin = this.origin;
 195         this.velocity = '0 0 200';
 196
 197         if(!MoveToRandomMapLocation(this, DPCONTENTS_SOLID | DPCONTENTS_CORPSE | DPCONTENTS_PLAYERCLIP, DPCONTENTS_SLIME | DPCONTENTS_LAVA | DPCONTENTS_SKY | DPCONTENTS_BODY | DPCONTENTS_DONOTENTER, Q3SURFACEFLAG_SKY,
 198                 ((autocvar_g_buffs_random_location_attempts > 0) ? autocvar_g_buffs_random_location_attempts : 10), 1024, 256))
 199         {
 200                 entity spot = SelectSpawnPoint(this, true);
 201                 setorigin(this, spot.origin);
 202                 this.velocity = ((randomvec() * 100) + '0 0 200');
 203                 this.angles = spot.angles;
 204         }
 205
 206         tracebox(this.origin, this.mins * 1.5, this.maxs * 1.5, this.origin, MOVE_NOMONSTERS, this);
 207
 208         setorigin(this, trace_endpos); // attempt to unstick
 209
 210         this.movetype = MOVETYPE_TOSS;
 211
 212         makevectors(this.angles);
 213         this.angles = '0 0 0';
 214         if(autocvar_g_buffs_random_lifetime > 0)
 215                 this.lifetime = time + autocvar_g_buffs_random_lifetime;
 216
 217         Send_Effect(EFFECT_ELECTRO_COMBO, oldbufforigin + ((this.mins + this.maxs) * 0.5), '0 0 0', 1);
 218         Send_Effect(EFFECT_ELECTRO_COMBO, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 219
 220         WaypointSprite_Ping(this.buff_waypoint);
 221
 222         sound(this, CH_TRIGGER, SND_KA_RESPAWN, VOL_BASE, ATTEN_NONE); // ATTEN_NONE (it's a sound intended to be heard anywhere)
 223 }
 224
 225 void buff_Touch(entity this)
 226 {
 227         if(gameover) { return; }
 228
 229         if(ITEM_TOUCH_NEEDKILL())
 230         {
 231                 buff_Respawn(self);
 232                 return;
 233         }
 234
 235         if((self.team && DIFF_TEAM(other, self))
 236         || (STAT(FROZEN, other))
 237         || (other.vehicle)
 238         || (!self.buff_active)
 239         )
 240         {
 241                 // can't touch this
 242                 return;
 243         }
 244
 245         if(MUTATOR_CALLHOOK(BuffTouch, self, other))
 246                 return;
 247
 248         if(!IS_PLAYER(other))
 249                 return; // incase mutator changed other
 250
 251         if (other.buffs)
 252         {
 253                 if (other.cvar_cl_buffs_autoreplace && other.buffs != self.buffs)
 254                 {
 255                         int buffid = buff_FirstFromFlags(other.buffs).m_id;
 256                         //Send_Notification(NOTIF_ONE, other, MSG_MULTI, ITEM_BUFF_DROP, other.buffs);
 257                         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_ITEM_BUFF_LOST, other.netname, buffid);
 258
 259                         other.buffs = 0;
 260                         //sound(other, CH_TRIGGER, SND_BUFF_LOST, VOL_BASE, ATTN_NORM);
 261                 }
 262                 else { return; } // do nothing
 263         }
 264
 265         self.owner = other;
 266         self.buff_active = false;
 267         self.lifetime = 0;
 268         int buffid = buff_FirstFromFlags(self.buffs).m_id;
 269         Send_Notification(NOTIF_ONE, other, MSG_MULTI, ITEM_BUFF_GOT, buffid);
 270         Send_Notification(NOTIF_ALL_EXCEPT, other, MSG_INFO, INFO_ITEM_BUFF, other.netname, buffid);
 271
 272         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(self), '0 0 0', 1);
 273         sound(other, CH_TRIGGER, SND_SHIELD_RESPAWN, VOL_BASE, ATTN_NORM);
 274         other.buffs |= (self.buffs);
 275 }
 276
 277 float buff_Available(entity buff)
 278 {
 279         if (buff == BUFF_Null)
 280                 return false;
 281         if (buff == BUFF_AMMO && ((start_items & IT_UNLIMITED_WEAPON_AMMO) || (start_items & IT_UNLIMITED_AMMO) || (cvar("g_melee_only"))))
 282                 return false;
 283         if (buff == BUFF_VAMPIRE && cvar("g_vampire"))
 284                 return false;
 285         return cvar(strcat("g_buffs_", buff.m_name));
 286 }
 287
 288 .int buff_seencount;
 289
 290 void buff_NewType(entity ent, float cb)
 291 {
 292         RandomSelection_Init();
 293         FOREACH(Buffs, buff_Available(it), LAMBDA(
 294                 it.buff_seencount += 1;
 295                 // if it's already been chosen, give it a lower priority
 296                 RandomSelection_Add(world, it.m_itemid, string_null, 1, max(0.2, 1 / it.buff_seencount));
 297         ));
 298         ent.buffs = RandomSelection_chosen_float;
 299 }
 300
 301 void buff_Think(entity this)
 302 {
 303         if(this.buffs != this.oldbuffs)
 304         {
 305                 entity buff = buff_FirstFromFlags(this.buffs);
 306                 this.color = buff.m_color;
 307                 this.glowmod = buff_GlowColor(buff);
 308                 this.skin = buff.m_skin;
 309
 310                 setmodel(this, MDL_BUFF);
 311
 312                 if(this.buff_waypoint)
 313                 {
 314                         //WaypointSprite_Disown(this.buff_waypoint, 1);
 315                         WaypointSprite_Kill(this.buff_waypoint);
 316                         buff_Waypoint_Spawn(this);
 317                         if(this.buff_activetime)
 318                                 WaypointSprite_UpdateBuildFinished(this.buff_waypoint, time + this.buff_activetime - frametime);
 319                 }
 320
 321                 this.oldbuffs = this.buffs;
 322         }
 323
 324         if(!gameover)
 325         if((round_handler_IsActive() && !round_handler_IsRoundStarted()) || time >= game_starttime)
 326         if(!this.buff_activetime_updated)
 327         {
 328                 buff_SetCooldown(this, this.buff_activetime);
 329                 this.buff_activetime_updated = true;
 330         }
 331
 332         if(!this.buff_active && !this.buff_activetime)
 333         if(!this.owner || STAT(FROZEN, this.owner) || IS_DEAD(this.owner) || !this.owner.iscreature || !(this.owner.buffs & this.buffs))
 334         {
 335                 buff_SetCooldown(this, autocvar_g_buffs_cooldown_respawn + frametime);
 336                 this.owner = world;
 337                 if(autocvar_g_buffs_randomize)
 338                         buff_NewType(this, this.buffs);
 339
 340                 if(autocvar_g_buffs_random_location || (this.spawnflags & 64))
 341                         buff_Respawn(this);
 342         }
 343
 344         if(this.buff_activetime)
 345         if(!gameover)
 346         if((round_handler_IsActive() && !round_handler_IsRoundStarted()) || time >= game_starttime)
 347         {
 348                 this.buff_activetime = max(0, this.buff_activetime - frametime);
 349
 350                 if(!this.buff_activetime)
 351                 {
 352                         this.buff_active = true;
 353                         sound(this, CH_TRIGGER, SND_STRENGTH_RESPAWN, VOL_BASE, ATTN_NORM);
 354                         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 355                 }
 356         }
 357
 358         if(this.buff_active)
 359         {
 360                 if(this.team && !this.buff_waypoint)
 361                         buff_Waypoint_Spawn(this);
 362
 363                 if(this.lifetime)
 364                 if(time >= this.lifetime)
 365                         buff_Respawn(this);
 366         }
 367
 368         this.nextthink = time;
 369         //this.angles_y = time * 110.1;
 370 }
 371
 372 void buff_Waypoint_Reset(entity this)
 373 {
 374         WaypointSprite_Kill(this.buff_waypoint);
 375
 376         if(this.buff_activetime) { buff_Waypoint_Spawn(this); }
 377 }
 378
 379 void buff_Reset(entity this)
 380 {
 381         if(autocvar_g_buffs_randomize)
 382                 buff_NewType(this, this.buffs);
 383         this.owner = world;
 384         buff_SetCooldown(this, autocvar_g_buffs_cooldown_activate);
 385         buff_Waypoint_Reset(this);
 386         this.buff_activetime_updated = false;
 387
 388         if(autocvar_g_buffs_random_location || (this.spawnflags & 64))
 389                 buff_Respawn(this);
 390 }
 391
 392 float buff_Customize()
 393 {SELFPARAM();
 394         entity player = WaypointSprite_getviewentity(other);
 395         if(!this.buff_active || (this.team && DIFF_TEAM(player, this)))
 396         {
 397                 this.alpha = 0.3;
 398                 if(this.effects & EF_FULLBRIGHT) { this.effects &= ~(EF_FULLBRIGHT); }
 399                 this.pflags = 0;
 400         }
 401         else
 402         {
 403                 this.alpha = 1;
 404                 if(!(this.effects & EF_FULLBRIGHT)) { this.effects |= EF_FULLBRIGHT; }
 405                 this.light_lev = 220 + 36 * sin(time);
 406                 this.pflags = PFLAGS_FULLDYNAMIC;
 407         }
 408         return true;
 409 }
 410
 411 void buff_Init(entity this)
 412 {
 413         if(!cvar("g_buffs")) { remove(this); return; }
 414
 415         if(!teamplay && this.team) { this.team = 0; }
 416
 417         entity buff = buff_FirstFromFlags(this.buffs);
 418
 419         if(!this.buffs || buff_Available(buff))
 420                 buff_NewType(this, 0);
 421
 422         this.classname = "item_buff";
 423         this.solid = SOLID_TRIGGER;
 424         this.flags = FL_ITEM;
 425         setthink(this, buff_Think);
 426         settouch(this, buff_Touch);
 427         this.reset = buff_Reset;
 428         this.nextthink = time + 0.1;
 429         this.gravity = 1;
 430         this.movetype = MOVETYPE_TOSS;
 431         this.scale = 1;
 432         this.skin = buff.m_skin;
 433         this.effects = EF_FULLBRIGHT | EF_STARDUST | EF_NOSHADOW;
 434         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY;
 435         this.customizeentityforclient = buff_Customize;
 436         //this.gravity = 100;
 437         this.color = buff.m_color;
 438         this.glowmod = buff_GlowColor(this);
 439         buff_SetCooldown(this, autocvar_g_buffs_cooldown_activate + game_starttime);
 440         this.buff_active = !this.buff_activetime;
 441         this.pflags = PFLAGS_FULLDYNAMIC;
 442
 443         if(this.spawnflags & 1)
 444                 this.noalign = true;
 445
 446         if(this.noalign)
 447                 this.movetype = MOVETYPE_NONE; // reset by random location
 448
 449         setmodel(this, MDL_BUFF);
 450         setsize(this, BUFF_MIN, BUFF_MAX);
 451
 452         if(cvar("g_buffs_random_location") || (this.spawnflags & 64))
 453                 buff_Respawn(this);
 454 }
 455
 456 void buff_Init_Compat(entity ent, entity replacement)
 457 {
 458         if (ent.spawnflags & 2)
 459                 ent.team = NUM_TEAM_1;
 460         else if (ent.spawnflags & 4)
 461                 ent.team = NUM_TEAM_2;
 462
 463         ent.buffs = replacement.m_itemid;
 464
 465         buff_Init(ent);
 466 }
 467
 468 void buff_SpawnReplacement(entity ent, entity old)
 469 {
 470         setorigin(ent, old.origin);
 471         ent.angles = old.angles;
 472         ent.noalign = (old.noalign || (old.spawnflags & 1));
 473
 474         buff_Init(ent);
 475 }
 476
 477 void buff_Vengeance_DelayedDamage(entity this)
 478 {
 479         if(this.enemy)
 480                 Damage(this.enemy, this.owner, this.owner, this.dmg, DEATH_BUFF.m_id, this.enemy.origin, '0 0 0');
 481
 482         remove(this);
 483         return;
 484 }
 485
 486 // note: only really useful in teamplay
 487 void buff_Medic_Heal(entity this)
 488 {
 489         FOREACH_CLIENT(IS_PLAYER(it) && it != this && vdist(it.origin - this.origin, <=, autocvar_g_buffs_medic_heal_range),
 490         {
 491                 if(SAME_TEAM(it, this))
 492                 if(it.health < autocvar_g_balance_health_regenstable)
 493                 {
 494                         Send_Effect(EFFECT_HEALING, it.origin, '0 0 0', 1);
 495                         it.health = bound(0, it.health + autocvar_g_buffs_medic_heal_amount, autocvar_g_balance_health_regenstable);
 496                 }
 497         });
 498 }
 499
 500 float buff_Inferno_CalculateTime(float x, float offset_x, float offset_y, float intersect_x, float intersect_y, float base)
 501 {
 502         return offset_y + (intersect_y - offset_y) * logn(((x - offset_x) * ((base - 1) / intersect_x)) + 1, base);
 503 }
 504
 505 // mutator hooks
 506 MUTATOR_HOOKFUNCTION(buffs, PlayerDamage_SplitHealthArmor)
 507 {
 508         if(frag_deathtype == DEATH_BUFF.m_id) { return false; }
 509
 510         if(frag_target.buffs & BUFF_RESISTANCE.m_itemid)
 511         {
 512                 vector v = healtharmor_applydamage(50, autocvar_g_buffs_resistance_blockpercent, frag_deathtype, frag_damage);
 513                 damage_take = v.x;
 514                 damage_save = v.y;
 515         }
 516
 517         return false;
 518 }
 519
 520 MUTATOR_HOOKFUNCTION(buffs, PlayerDamage_Calculate)
 521 {
 522         if(frag_deathtype == DEATH_BUFF.m_id) { return false; }
 523
 524         if(frag_target.buffs & BUFF_SPEED.m_itemid)
 525         if(frag_target != frag_attacker)
 526                 frag_damage *= autocvar_g_buffs_speed_damage_take;
 527
 528         if(frag_target.buffs & BUFF_MEDIC.m_itemid)
 529         if((frag_target.health - frag_damage) <= 0)
 530         if(!ITEM_DAMAGE_NEEDKILL(frag_deathtype))
 531         if(frag_attacker)
 532         if(random() <= autocvar_g_buffs_medic_survive_chance)
 533                 frag_damage = max(5, frag_target.health - autocvar_g_buffs_medic_survive_health);
 534
 535         if(frag_target.buffs & BUFF_JUMP.m_itemid)
 536         if(frag_deathtype == DEATH_FALL.m_id)
 537                 frag_damage = 0;
 538
 539         if(frag_target.buffs & BUFF_VENGEANCE.m_itemid)
 540         if(frag_attacker)
 541         if(frag_attacker != frag_target)
 542         if(!ITEM_DAMAGE_NEEDKILL(frag_deathtype))
 543         {
 544                 entity dmgent = spawn();
 545
 546                 dmgent.dmg = frag_damage * autocvar_g_buffs_vengeance_damage_multiplier;
 547                 dmgent.enemy = frag_attacker;
 548                 dmgent.owner = frag_target;
 549                 setthink(dmgent, buff_Vengeance_DelayedDamage);
 550                 dmgent.nextthink = time + 0.1;
 551         }
 552
 553         if(frag_target.buffs & BUFF_BASH.m_itemid)
 554         if(frag_attacker != frag_target)
 555                 frag_force = '0 0 0';
 556
 557         if(frag_attacker.buffs & BUFF_BASH.m_itemid)
 558         if(frag_force)
 559         if(frag_attacker == frag_target)
 560                 frag_force *= autocvar_g_buffs_bash_force_self;
 561         else
 562                 frag_force *= autocvar_g_buffs_bash_force;
 563
 564         if(frag_attacker.buffs & BUFF_DISABILITY.m_itemid)
 565         if(frag_target != frag_attacker)
 566                 frag_target.buff_disability_time = time + autocvar_g_buffs_disability_slowtime;
 567
 568         if(frag_target.buffs & BUFF_INFERNO.m_itemid)
 569         {
 570                 if(frag_deathtype == DEATH_FIRE.m_id)
 571                         frag_damage = 0;
 572                 if(frag_deathtype == DEATH_LAVA.m_id)
 573                         frag_damage *= 0.5; // TODO: cvarize?
 574         }
 575
 576         if(frag_attacker.buffs & BUFF_LUCK.m_itemid)
 577         if(frag_attacker != frag_target)
 578         if(autocvar_g_buffs_luck_damagemultiplier > 0)
 579         if(random() <= autocvar_g_buffs_luck_chance)
 580                 frag_damage *= autocvar_g_buffs_luck_damagemultiplier;
 581
 582         if(frag_attacker.buffs & BUFF_INFERNO.m_itemid)
 583         if(frag_target != frag_attacker) {
 584                 float btime = buff_Inferno_CalculateTime(
 585                         frag_damage,
 586                         0,
 587                         autocvar_g_buffs_inferno_burntime_min_time,
 588                         autocvar_g_buffs_inferno_burntime_target_damage,
 589                         autocvar_g_buffs_inferno_burntime_target_time,
 590                         autocvar_g_buffs_inferno_burntime_factor
 591                 );
 592                 Fire_AddDamage(frag_target, frag_attacker, (frag_damage * autocvar_g_buffs_inferno_damagemultiplier), btime, DEATH_BUFF.m_id);
 593         }
 594
 595         // this... is ridiculous (TODO: fix!)
 596         if(frag_attacker.buffs & BUFF_VAMPIRE.m_itemid)
 597         if(!frag_target.vehicle)
 598         if(!ITEM_DAMAGE_NEEDKILL(frag_deathtype))
 599         if(!IS_DEAD(frag_target))
 600         if(IS_PLAYER(frag_target) || IS_MONSTER(frag_target))
 601         if(frag_attacker != frag_target)
 602         if(!STAT(FROZEN, frag_target))
 603         if(frag_target.takedamage)
 604         if(DIFF_TEAM(frag_attacker, frag_target))
 605         {
 606                 frag_attacker.health = bound(0, frag_attacker.health + bound(0, frag_damage * autocvar_g_buffs_vampire_damage_steal, frag_target.health), g_pickup_healthsmall_max);
 607                 if(frag_target.armorvalue)
 608                         frag_attacker.armorvalue = bound(0, frag_attacker.armorvalue + bound(0, frag_damage * autocvar_g_buffs_vampire_damage_steal, frag_target.armorvalue), g_pickup_armorsmall_max);
 609         }
 610
 611         return false;
 612 }
 613
 614 MUTATOR_HOOKFUNCTION(buffs,PlayerSpawn)
 615 {SELFPARAM();
 616         self.buffs = 0;
 617         // reset timers here to prevent them continuing after re-spawn
 618         self.buff_disability_time = 0;
 619         self.buff_disability_effect_time = 0;
 620         return false;
 621 }
 622
 623 .float stat_sv_maxspeed;
 624 .float stat_sv_airspeedlimit_nonqw;
 625 .float stat_sv_jumpvelocity;
 626
 627 MUTATOR_HOOKFUNCTION(buffs, PlayerPhysics)
 628 {SELFPARAM();
 629         if(self.buffs & BUFF_SPEED.m_itemid)
 630         {
 631                 self.stat_sv_maxspeed *= autocvar_g_buffs_speed_speed;
 632                 self.stat_sv_airspeedlimit_nonqw *= autocvar_g_buffs_speed_speed;
 633         }
 634
 635         if(time < self.buff_disability_time)
 636         {
 637                 self.stat_sv_maxspeed *= autocvar_g_buffs_disability_speed;
 638                 self.stat_sv_airspeedlimit_nonqw *= autocvar_g_buffs_disability_speed;
 639         }
 640
 641         if(self.buffs & BUFF_JUMP.m_itemid)
 642         {
 643                 // automatically reset, no need to worry
 644                 self.stat_sv_jumpvelocity = autocvar_g_buffs_jump_height;
 645         }
 646
 647         return false;
 648 }
 649
 650 MUTATOR_HOOKFUNCTION(buffs, PlayerJump)
 651 {SELFPARAM();
 652         if(self.buffs & BUFF_JUMP.m_itemid)
 653                 player_jumpheight = autocvar_g_buffs_jump_height;
 654
 655         return false;
 656 }
 657
 658 MUTATOR_HOOKFUNCTION(buffs, MonsterMove)
 659 {SELFPARAM();
 660         if(time < self.buff_disability_time)
 661         {
 662                 monster_speed_walk *= autocvar_g_buffs_disability_speed;
 663                 monster_speed_run *= autocvar_g_buffs_disability_speed;
 664         }
 665
 666         return false;
 667 }
 668
 669 MUTATOR_HOOKFUNCTION(buffs, PlayerDies)
 670 {
 671         if(frag_target.buffs)
 672         {
 673                 int buffid = buff_FirstFromFlags(frag_target.buffs).m_id;
 674                 Send_Notification(NOTIF_ALL_EXCEPT, frag_target, MSG_INFO, INFO_ITEM_BUFF_LOST, frag_target.netname, buffid);
 675                 frag_target.buffs = 0;
 676
 677                 if(frag_target.buff_model)
 678                 {
 679                         remove(frag_target.buff_model);
 680                         frag_target.buff_model = world;
 681                 }
 682         }
 683         return false;
 684 }
 685
 686 MUTATOR_HOOKFUNCTION(buffs, PlayerUseKey, CBC_ORDER_FIRST)
 687 {SELFPARAM();
 688         if(MUTATOR_RETURNVALUE || gameover) { return false; }
 689         if(self.buffs)
 690         {
 691                 int buffid = buff_FirstFromFlags(self.buffs).m_id;
 692                 Send_Notification(NOTIF_ONE, self, MSG_MULTI, ITEM_BUFF_DROP, buffid);
 693                 Send_Notification(NOTIF_ALL_EXCEPT, self, MSG_INFO, INFO_ITEM_BUFF_LOST, self.netname, buffid);
 694
 695                 self.buffs = 0;
 696                 sound(self, CH_TRIGGER, SND_BUFF_LOST, VOL_BASE, ATTN_NORM);
 697                 return true;
 698         }
 699         return false;
 700 }
 701
 702 MUTATOR_HOOKFUNCTION(buffs, ForbidThrowCurrentWeapon)
 703 {SELFPARAM();
 704         if(MUTATOR_RETURNVALUE || gameover) { return false; }
 705
 706         if(self.buffs & BUFF_SWAPPER.m_itemid)
 707         {
 708                 float best_distance = autocvar_g_buffs_swapper_range;
 709                 entity closest = world;
 710                 FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
 711                         if(!IS_DEAD(it) && !STAT(FROZEN, it) && !it.vehicle)
 712                         if(DIFF_TEAM(it, self))
 713                         {
 714                                 float test = vlen2(self.origin - it.origin);
 715                                 if(test <= best_distance * best_distance)
 716                                 {
 717                                         best_distance = sqrt(test);
 718                                         closest = it;
 719                                 }
 720                         }
 721                 ));
 722
 723                 if(closest)
 724                 {
 725                         vector my_org, my_vel, my_ang, their_org, their_vel, their_ang;
 726
 727                         my_org = self.origin;
 728                         my_vel = self.velocity;
 729                         my_ang = self.angles;
 730                         their_org = closest.origin;
 731                         their_vel = closest.velocity;
 732                         their_ang = closest.angles;
 733
 734                         Drop_Special_Items(closest);
 735
 736                         MUTATOR_CALLHOOK(PortalTeleport, self); // initiate flag dropper
 737
 738                         setorigin(self, their_org);
 739                         setorigin(closest, my_org);
 740
 741                         closest.velocity = my_vel;
 742                         closest.angles = my_ang;
 743                         closest.fixangle = true;
 744                         closest.oldorigin = my_org;
 745                         closest.oldvelocity = my_vel;
 746                         self.velocity = their_vel;
 747                         self.angles = their_ang;
 748                         self.fixangle = true;
 749                         self.oldorigin = their_org;
 750                         self.oldvelocity = their_vel;
 751
 752                         // set pusher so self gets the kill if they fall into void
 753                         closest.pusher = self;
 754                         closest.pushltime = time + autocvar_g_maxpushtime;
 755                         closest.istypefrag = PHYS_INPUT_BUTTON_CHAT(closest);
 756
 757                         Send_Effect(EFFECT_ELECTRO_COMBO, their_org, '0 0 0', 1);
 758                         Send_Effect(EFFECT_ELECTRO_COMBO, my_org, '0 0 0', 1);
 759
 760                         sound(self, CH_TRIGGER, SND_KA_RESPAWN, VOL_BASE, ATTEN_NORM);
 761                         sound(closest, CH_TRIGGER, SND_KA_RESPAWN, VOL_BASE, ATTEN_NORM);
 762
 763                         // TODO: add a counter to handle how many times one can teleport, and a delay to prevent spam
 764                         self.buffs = 0;
 765                         return true;
 766                 }
 767         }
 768         return false;
 769 }
 770
 771 bool buffs_RemovePlayer(entity player)
 772 {
 773         if(player.buff_model)
 774         {
 775                 remove(player.buff_model);
 776                 player.buff_model = world;
 777         }
 778
 779         // also reset timers here to prevent them continuing after spectating
 780         player.buff_disability_time = 0;
 781         player.buff_disability_effect_time = 0;
 782
 783         return false;
 784 }
 785 MUTATOR_HOOKFUNCTION(buffs, MakePlayerObserver) { SELFPARAM(); return buffs_RemovePlayer(self); }
 786 MUTATOR_HOOKFUNCTION(buffs, ClientDisconnect) { SELFPARAM(); return buffs_RemovePlayer(self); }
 787
 788 MUTATOR_HOOKFUNCTION(buffs, CustomizeWaypoint)
 789 {SELFPARAM();
 790         entity e = WaypointSprite_getviewentity(other);
 791
 792         // if you have the invisibility powerup, sprites ALWAYS are restricted to your team
 793         // but only apply this to real players, not to spectators
 794         if((self.owner.flags & FL_CLIENT) && (self.owner.buffs & BUFF_INVISIBLE.m_itemid) && (e == other))
 795         if(DIFF_TEAM(self.owner, e))
 796                 return true;
 797
 798         return false;
 799 }
 800
 801 MUTATOR_HOOKFUNCTION(buffs, OnEntityPreSpawn, CBC_ORDER_LAST)
 802 {SELFPARAM();
 803         if(autocvar_g_buffs_replace_powerups)
 804         switch(self.classname)
 805         {
 806                 case "item_strength":
 807                 case "item_invincible":
 808                 {
 809                         entity e = spawn();
 810                         buff_SpawnReplacement(e, self);
 811                         return true;
 812                 }
 813         }
 814         return false;
 815 }
 816
 817 MUTATOR_HOOKFUNCTION(buffs, WeaponRateFactor)
 818 {SELFPARAM();
 819         if(self.buffs & BUFF_SPEED.m_itemid)
 820                 weapon_rate *= autocvar_g_buffs_speed_rate;
 821
 822         if(time < self.buff_disability_time)
 823                 weapon_rate *= autocvar_g_buffs_disability_rate;
 824
 825         return false;
 826 }
 827
 828 MUTATOR_HOOKFUNCTION(buffs, WeaponSpeedFactor)
 829 {SELFPARAM();
 830         if(self.buffs & BUFF_SPEED.m_itemid)
 831                 ret_float *= autocvar_g_buffs_speed_weaponspeed;
 832
 833         if(time < self.buff_disability_time)
 834                 ret_float *= autocvar_g_buffs_disability_weaponspeed;
 835
 836         return false;
 837 }
 838
 839 MUTATOR_HOOKFUNCTION(buffs, PlayerPreThink)
 840 {SELFPARAM();
 841         if(gameover || IS_DEAD(self)) { return false; }
 842
 843         if(time < self.buff_disability_time)
 844         if(time >= self.buff_disability_effect_time)
 845         {
 846                 Send_Effect(EFFECT_SMOKING, self.origin + ((self.mins + self.maxs) * 0.5), '0 0 0', 1);
 847                 self.buff_disability_effect_time = time + 0.5;
 848         }
 849
 850         // handle buff lost status
 851         // 1: notify everyone else
 852         // 2: notify carrier as well
 853         int buff_lost = 0;
 854
 855         if(self.buff_time)
 856         if(time >= self.buff_time)
 857                 buff_lost = 2;
 858
 859         if(STAT(FROZEN, self)) { buff_lost = 1; }
 860
 861         if(buff_lost)
 862         {
 863                 if(self.buffs)
 864                 {
 865                         int buffid = buff_FirstFromFlags(self.buffs).m_id;
 866                         Send_Notification(NOTIF_ALL_EXCEPT, self, MSG_INFO, INFO_ITEM_BUFF_LOST, self.netname, buffid);
 867                         if(buff_lost >= 2)
 868                         {
 869                                 Send_Notification(NOTIF_ONE, self, MSG_MULTI, ITEM_BUFF_DROP, buffid); // TODO: special timeout message?
 870                                 sound(self, CH_TRIGGER, SND_BUFF_LOST, VOL_BASE, ATTN_NORM);
 871                         }
 872                         self.buffs = 0;
 873                 }
 874         }
 875
 876         if(self.buffs & BUFF_MAGNET.m_itemid)
 877         {
 878                 vector pickup_size;
 879                 FOREACH_ENTITY_FLAGS(flags, FL_ITEM,
 880                 {
 881                         if(it.buffs)
 882                                 pickup_size = '1 1 1' * autocvar_g_buffs_magnet_range_buff;
 883                         else
 884                                 pickup_size = '1 1 1' * autocvar_g_buffs_magnet_range_item;
 885
 886                         if(boxesoverlap(self.absmin - pickup_size, self.absmax + pickup_size, it.absmin, it.absmax))
 887                         {
 888                                 if(gettouch(it))
 889                                 {
 890                                         entity oldother = other;
 891                                         other = self;
 892                                         WITHSELF(it, gettouch(it)(it));
 893                                         other = oldother;
 894                                 }
 895                         }
 896                 });
 897         }
 898
 899         if(self.buffs & BUFF_AMMO.m_itemid)
 900         if(self.clip_size)
 901                 self.clip_load = self.(weapon_load[PS(self).m_switchweapon.m_id]) = self.clip_size;
 902
 903         if((self.buffs & BUFF_INVISIBLE.m_itemid) && (self.oldbuffs & BUFF_INVISIBLE.m_itemid))
 904         if(self.alpha != autocvar_g_buffs_invisible_alpha)
 905                 self.alpha = autocvar_g_buffs_invisible_alpha; // powerups reset alpha, so we must enforce this (TODO)
 906
 907         if(self.buffs & BUFF_MEDIC.m_itemid)
 908         if(time >= self.buff_medic_healtime)
 909         {
 910                 buff_Medic_Heal(self);
 911                 self.buff_medic_healtime = time + autocvar_g_buffs_medic_heal_delay;
 912         }
 913
 914 #define BUFF_ONADD(b) if ( (self.buffs & (b).m_itemid) && !(self.oldbuffs & (b).m_itemid))
 915 #define BUFF_ONREM(b) if (!(self.buffs & (b).m_itemid) &&  (self.oldbuffs & (b).m_itemid))
 916
 917         if(self.buffs != self.oldbuffs)
 918         {
 919                 entity buff = buff_FirstFromFlags(self.buffs);
 920                 float bufftime = buff != BUFF_Null ? buff.m_time(buff) : 0;
 921                 self.buff_time = (bufftime) ? time + bufftime : 0;
 922
 923                 BUFF_ONADD(BUFF_AMMO)
 924                 {
 925                         self.buff_ammo_prev_infitems = (self.items & IT_UNLIMITED_WEAPON_AMMO);
 926                         self.items |= IT_UNLIMITED_WEAPON_AMMO;
 927
 928                         if(self.clip_load)
 929                                 self.buff_ammo_prev_clipload = self.clip_load;
 930                         self.clip_load = self.(weapon_load[PS(self).m_switchweapon.m_id]) = self.clip_size;
 931                 }
 932
 933                 BUFF_ONREM(BUFF_AMMO)
 934                 {
 935                         if(self.buff_ammo_prev_infitems)
 936                                 self.items |= IT_UNLIMITED_WEAPON_AMMO;
 937                         else
 938                                 self.items &= ~IT_UNLIMITED_WEAPON_AMMO;
 939
 940                         if(self.buff_ammo_prev_clipload)
 941                                 self.clip_load = self.buff_ammo_prev_clipload;
 942                 }
 943
 944                 BUFF_ONADD(BUFF_INVISIBLE)
 945                 {
 946                         if(time < self.strength_finished && g_instagib)
 947                                 self.alpha = autocvar_g_instagib_invis_alpha;
 948                         else
 949                                 self.alpha = self.buff_invisible_prev_alpha;
 950                         self.alpha = autocvar_g_buffs_invisible_alpha;
 951                 }
 952
 953                 BUFF_ONREM(BUFF_INVISIBLE)
 954                         self.alpha = self.buff_invisible_prev_alpha;
 955
 956                 self.oldbuffs = self.buffs;
 957                 if(self.buffs)
 958                 {
 959                         if(!self.buff_model)
 960                                 buffs_BuffModel_Spawn(self);
 961
 962                         self.buff_model.color = buff.m_color;
 963                         self.buff_model.glowmod = buff_GlowColor(self.buff_model);
 964                         self.buff_model.skin = buff.m_skin;
 965
 966                         self.effects |= EF_NOSHADOW;
 967                 }
 968                 else
 969                 {
 970                         remove(self.buff_model);
 971                         self.buff_model = world;
 972
 973                         self.effects &= ~(EF_NOSHADOW);
 974                 }
 975         }
 976
 977         if(self.buff_model)
 978         {
 979                 self.buff_model.effects = self.effects;
 980                 self.buff_model.effects |= EF_LOWPRECISION;
 981                 self.buff_model.effects = self.buff_model.effects & EFMASK_CHEAP; // eat performance
 982
 983                 self.buff_model.alpha = self.alpha;
 984         }
 985
 986 #undef BUFF_ONADD
 987 #undef BUFF_ONREM
 988         return false;
 989 }
 990
 991 MUTATOR_HOOKFUNCTION(buffs, SpectateCopy)
 992 {SELFPARAM();
 993         self.buffs = other.buffs;
 994         return false;
 995 }
 996
 997 MUTATOR_HOOKFUNCTION(buffs, VehicleEnter)
 998 {
 999         vh_vehicle.buffs = vh_player.buffs;
1000         vh_player.buffs = 0;
1001         vh_vehicle.buff_time = max(0, vh_player.buff_time - time);
1002         vh_player.buff_time = 0;
1003         return false;
1004 }
1005
1006 MUTATOR_HOOKFUNCTION(buffs, VehicleExit)
1007 {
1008         vh_player.buffs = vh_player.oldbuffs = vh_vehicle.buffs;
1009         vh_vehicle.buffs = 0;
1010         vh_player.buff_time = time + vh_vehicle.buff_time;
1011         vh_vehicle.buff_time = 0;
1012         return false;
1013 }
1014
1015 MUTATOR_HOOKFUNCTION(buffs, PlayerRegen)
1016 {SELFPARAM();
1017         if(self.buffs & BUFF_MEDIC.m_itemid)
1018         {
1019                 regen_mod_rot = autocvar_g_buffs_medic_rot;
1020                 regen_mod_limit = regen_mod_max = autocvar_g_buffs_medic_max;
1021                 regen_mod_regen = autocvar_g_buffs_medic_regen;
1022         }
1023
1024         if(self.buffs & BUFF_SPEED.m_itemid)
1025                 regen_mod_regen = autocvar_g_buffs_speed_regen;
1026
1027         return false;
1028 }
1029
1030 REPLICATE(cvar_cl_buffs_autoreplace, bool, "cl_buffs_autoreplace");
1031
1032 MUTATOR_HOOKFUNCTION(buffs, BuildMutatorsString)
1033 {
1034         ret_string = strcat(ret_string, ":Buffs");
1035         return false;
1036 }
1037
1038 MUTATOR_HOOKFUNCTION(buffs, BuildMutatorsPrettyString)
1039 {
1040         ret_string = strcat(ret_string, ", Buffs");
1041         return false;
1042 }
1043
1044 void buffs_DelayedInit(entity this)
1045 {
1046         if(autocvar_g_buffs_spawn_count > 0)
1047         if(find(world, classname, "item_buff") == world)
1048         {
1049                 float i;
1050                 for(i = 0; i < autocvar_g_buffs_spawn_count; ++i)
1051                 {
1052                         entity e = spawn();
1053                         e.spawnflags |= 64; // always randomize
1054                         e.velocity = randomvec() * 250; // this gets reset anyway if random location works
1055                         buff_Init(e);
1056                 }
1057         }
1058 }
1059 #endif