qcsrc/common/mutators/mutator/damagetext/damagetext.qc

   1 #include "damagetext.qh"
   2
   3 #define DAMAGETEXT_PRECISION_MULTIPLIER 128
   4 #define DAMAGETEXT_SHORT_LIMIT 256 // the smallest value that we can't send as short - 2^15 (signed short) / DAMAGETEXT_PRECISION_MULTIPLIER
   5
   6 const int DTFLAG_SAMETEAM = BIT(0);
   7 const int DTFLAG_BIG_HEALTH = BIT(1);
   8 const int DTFLAG_BIG_ARMOR = BIT(2);
   9 const int DTFLAG_BIG_POTENTIAL = BIT(3);
  10 const int DTFLAG_NO_ARMOR = BIT(4);
  11 const int DTFLAG_NO_POTENTIAL = BIT(5);
  12
  13 REGISTER_MUTATOR(damagetext, true);
  14
  15 #if defined(CSQC) || defined(MENUQC)
  16 // no translatable cvar description please
  17 AUTOCVAR_SAVE(cl_damagetext,                        bool,   true,       "Draw damage dealt where you hit the enemy");
  18 AUTOCVAR_SAVE(cl_damagetext_format,                 string, "-{total}", "How to format the damage text. {health}, {armor}, {total}, {potential}: full damage not capped to target's health, {potential_health}: health damage not capped to target's health, {health(ph)}: shows potential_health too if different from health, {total(p)}: shows potential too if different from total");
  19 STATIC_INIT(DamageText_LegacyFormat) {
  20     if (strstrofs(autocvar_cl_damagetext_format, "{", 0) < 0) autocvar_cl_damagetext_format = "-{total}";
  21 }
  22 AUTOCVAR_SAVE(cl_damagetext_color,                  vector, '1 1 0',    "Damage text color");
  23 AUTOCVAR_SAVE(cl_damagetext_color_per_weapon,       bool,   false,      "Damage text uses weapon color");
  24 AUTOCVAR_SAVE(cl_damagetext_size,                   float,  8,          "Damage text font size");
  25 AUTOCVAR_SAVE(cl_damagetext_alpha_start,            float,  1,          "Damage text initial alpha");
  26 AUTOCVAR_SAVE(cl_damagetext_alpha_lifetime,         float,  3,          "Damage text lifetime in seconds");
  27 AUTOCVAR_SAVE(cl_damagetext_velocity,               vector, '0 0 20',   "Damage text move direction");
  28 AUTOCVAR_SAVE(cl_damagetext_offset,                 vector, '0 -40 0',  "Damage text offset");
  29 AUTOCVAR_SAVE(cl_damagetext_accumulate_range,       float,  30,         "Damage text spawned within this range is accumulated");
  30 AUTOCVAR_SAVE(cl_damagetext_accumulate_alpha_rel,   float,  0.65,       "Only update existing damage text when it's above this much percentage (0 to 1) of the starting alpha");
  31 AUTOCVAR_SAVE(cl_damagetext_friendlyfire,           bool,   true,       "Show damage text for friendlyfire too");
  32 AUTOCVAR_SAVE(cl_damagetext_friendlyfire_color,     vector, '1 0 0',    "Damage text color for friendlyfire");
  33 #endif
  34
  35 #ifdef CSQC
  36 CLASS(DamageText, Object)
  37     ATTRIB(DamageText, m_color, vector, autocvar_cl_damagetext_color);
  38     ATTRIB(DamageText, m_color_friendlyfire, vector, autocvar_cl_damagetext_friendlyfire_color);
  39     ATTRIB(DamageText, m_size, float, autocvar_cl_damagetext_size);
  40     ATTRIB(DamageText, alpha, float, autocvar_cl_damagetext_alpha_start);
  41     ATTRIB(DamageText, fade_rate, float, 1 / autocvar_cl_damagetext_alpha_lifetime);
  42     ATTRIB(DamageText, velocity, vector, autocvar_cl_damagetext_velocity);
  43     ATTRIB(DamageText, m_group, int, 0);
  44     ATTRIB(DamageText, m_friendlyfire, bool, false);
  45     ATTRIB(DamageText, m_damage, int, 0);
  46     ATTRIB(DamageText, m_armordamage, int, 0);
  47     ATTRIB(DamageText, m_potential_damage, int, 0);
  48     ATTRIB(DamageText, m_deathtype, int, 0);
  49     ATTRIB(DamageText, time_prev, float, time);
  50
  51     void DamageText_draw2d(DamageText this) {
  52         float dt = time - this.time_prev;
  53         this.time_prev = time;
  54         setorigin(this, this.origin + dt * this.velocity);
  55         this.alpha -= dt * this.fade_rate;
  56         if (this.alpha < 0) delete(this);
  57         vector pos = project_3d_to_2d(this.origin) + autocvar_cl_damagetext_offset;
  58         if (pos.z >= 0 && this.m_size > 0) {
  59             pos.z = 0;
  60             vector rgb;
  61             if (this.m_friendlyfire) {
  62                 rgb = this.m_color_friendlyfire;
  63             }
  64             else {
  65                 rgb = this.m_color;
  66             }
  67             if (autocvar_cl_damagetext_color_per_weapon) {
  68                 Weapon w = DEATH_WEAPONOF(this.m_deathtype);
  69                 if (w != WEP_Null) rgb = w.wpcolor;
  70             }
  71             string s = autocvar_cl_damagetext_format;
  72             s = strreplace("{health}", sprintf("%d", rint(this.m_damage / DAMAGETEXT_PRECISION_MULTIPLIER)), s);
  73             s = strreplace("{armor}",  sprintf("%d", rint(this.m_armordamage / DAMAGETEXT_PRECISION_MULTIPLIER)), s);
  74             s = strreplace("{total}",  sprintf("%d", rint((this.m_damage + this.m_armordamage) / DAMAGETEXT_PRECISION_MULTIPLIER)), s);
  75             s = strreplace("{potential}",  sprintf("%d", rint(this.m_potential_damage/DAMAGETEXT_PRECISION_MULTIPLIER)), s);
  76             s = strreplace("{potential_health}",  sprintf("%d", rint((this.m_potential_damage - this.m_armordamage)/DAMAGETEXT_PRECISION_MULTIPLIER)), s);
  77
  78             s = strreplace("{health(ph)}", (
  79                                 (rint(this.m_damage / DAMAGETEXT_PRECISION_MULTIPLIER) == rint((this.m_potential_damage - this.m_armordamage) / DAMAGETEXT_PRECISION_MULTIPLIER))
  80                                 ? sprintf("%d",      rint(this.m_damage / DAMAGETEXT_PRECISION_MULTIPLIER))
  81                                 : sprintf("%d (%d)", rint(this.m_damage / DAMAGETEXT_PRECISION_MULTIPLIER), rint((this.m_potential_damage - this.m_armordamage) / DAMAGETEXT_PRECISION_MULTIPLIER))
  82                 ), s);
  83             s = strreplace("{total(p)}", (
  84                                 (rint((this.m_damage + this.m_armordamage) / DAMAGETEXT_PRECISION_MULTIPLIER) == rint(this.m_potential_damage / DAMAGETEXT_PRECISION_MULTIPLIER))
  85                                 ? sprintf("%d",      rint((this.m_damage + this.m_armordamage) / DAMAGETEXT_PRECISION_MULTIPLIER))
  86                                 : sprintf("%d (%d)", rint((this.m_damage + this.m_armordamage) / DAMAGETEXT_PRECISION_MULTIPLIER), rint(this.m_potential_damage/DAMAGETEXT_PRECISION_MULTIPLIER))
  87                 ), s);
  88             drawcolorcodedstring2_builtin(pos, s, this.m_size * '1 1 0', rgb, this.alpha, DRAWFLAG_NORMAL);
  89         }
  90     }
  91     ATTRIB(DamageText, draw2d, void(DamageText), DamageText_draw2d);
  92
  93     void DamageText_update(DamageText this, vector _origin, int _health, int _armor, int _potential_damage, int _deathtype) {
  94         this.m_damage = _health;
  95         this.m_armordamage = _armor;
  96         this.m_potential_damage = _potential_damage;
  97         this.m_deathtype = _deathtype;
  98         setorigin(this, _origin);
  99         this.alpha = autocvar_cl_damagetext_alpha_start;
 100     }
 101
 102     CONSTRUCTOR(DamageText, int _group, vector _origin, int _health, int _armor, int _potential_damage, int _deathtype, bool _friendlyfire) {
 103         CONSTRUCT(DamageText);
 104         this.m_group = _group;
 105         this.m_friendlyfire = _friendlyfire;
 106         DamageText_update(this, _origin, _health, _armor, _potential_damage, _deathtype);
 107                 IL_PUSH(g_drawables_2d, this);
 108     }
 109 ENDCLASS(DamageText)
 110 #endif
 111
 112 REGISTER_NET_TEMP(damagetext)
 113
 114 #ifdef SVQC
 115 AUTOCVAR(sv_damagetext, int, 2, _("<= 0: disabled, >= 1: spectators, >= 2: players, >= 3: all players"));
 116 #define SV_DAMAGETEXT_DISABLED()        (autocvar_sv_damagetext <= 0 /* disabled */)
 117 #define SV_DAMAGETEXT_SPECTATORS_ONLY() (autocvar_sv_damagetext >= 1 /* spectators only */)
 118 #define SV_DAMAGETEXT_PLAYERS()         (autocvar_sv_damagetext >= 2 /* players */)
 119 #define SV_DAMAGETEXT_ALL()             (autocvar_sv_damagetext >= 3 /* all players */)
 120 MUTATOR_HOOKFUNCTION(damagetext, PlayerDamaged) {
 121     if (SV_DAMAGETEXT_DISABLED()) return;
 122     const entity attacker = M_ARGV(0, entity);
 123     const entity hit = M_ARGV(1, entity); if (hit == attacker) return;
 124     const float health = M_ARGV(2, float);
 125     const float armor = M_ARGV(3, float);
 126     const int deathtype = M_ARGV(5, int);
 127     const float potential_damage = M_ARGV(6, float);
 128     const vector location = hit.origin;
 129     FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(
 130         if (
 131             (SV_DAMAGETEXT_ALL()) ||
 132             (SV_DAMAGETEXT_PLAYERS() && it == attacker) ||
 133             (SV_DAMAGETEXT_SPECTATORS_ONLY() && IS_SPEC(it) && it.enemy == attacker) ||
 134             (SV_DAMAGETEXT_SPECTATORS_ONLY() && IS_OBSERVER(it))
 135         ) {
 136             int flags = 0;
 137             if (SAME_TEAM(hit, attacker)) flags |= DTFLAG_SAMETEAM;
 138             if (health >= DAMAGETEXT_SHORT_LIMIT) flags |= DTFLAG_BIG_HEALTH;
 139             if (armor >= DAMAGETEXT_SHORT_LIMIT) flags |= DTFLAG_BIG_ARMOR;
 140             if (potential_damage >= DAMAGETEXT_SHORT_LIMIT) flags |= DTFLAG_BIG_POTENTIAL;
 141             if (!armor) flags |= DTFLAG_NO_ARMOR;
 142             if (fabs((armor + health) - potential_damage) < 0.0001) flags |= DTFLAG_NO_POTENTIAL;
 143
 144             msg_entity = it;
 145             WriteHeader(MSG_ONE, damagetext);
 146             WriteEntity(MSG_ONE, hit);
 147             WriteCoord(MSG_ONE, location.x);
 148             WriteCoord(MSG_ONE, location.y);
 149             WriteCoord(MSG_ONE, location.z);
 150             WriteInt24_t(MSG_ONE, deathtype);
 151             WriteByte(MSG_ONE, flags);
 152
 153             // we need to send a few decimal places to minimize errors when accumulating damage
 154             // sending them multiplied saves bandwidth compared to using WriteCoord,
 155             // however if the multiplied damage would be too much for (signed) short, we send an int24
 156             if (flags & DTFLAG_BIG_HEALTH) WriteInt24_t(MSG_ONE, health * DAMAGETEXT_PRECISION_MULTIPLIER);
 157             else WriteShort(MSG_ONE, health * DAMAGETEXT_PRECISION_MULTIPLIER);
 158             if (!(flags & DTFLAG_NO_ARMOR))
 159             {
 160                 if (flags & DTFLAG_BIG_ARMOR) WriteInt24_t(MSG_ONE, armor * DAMAGETEXT_PRECISION_MULTIPLIER);
 161                 else WriteShort(MSG_ONE, armor * DAMAGETEXT_PRECISION_MULTIPLIER);
 162             }
 163             if (!(flags & DTFLAG_NO_POTENTIAL))
 164             {
 165                 if (flags & DTFLAG_BIG_POTENTIAL) WriteInt24_t(MSG_ONE, potential_damage * DAMAGETEXT_PRECISION_MULTIPLIER);
 166                 else WriteShort(MSG_ONE, potential_damage * DAMAGETEXT_PRECISION_MULTIPLIER);
 167                         }
 168         }
 169     ));
 170 }
 171 #endif
 172
 173 #ifdef CSQC
 174 NET_HANDLE(damagetext, bool isNew)
 175 {
 176     int group = ReadShort();
 177     vector location = vec3(ReadCoord(), ReadCoord(), ReadCoord());
 178     int deathtype = ReadInt24_t();
 179     int flags = ReadByte();
 180     bool friendlyfire = flags & DTFLAG_SAMETEAM;
 181
 182     int health, armor, potential_damage;
 183     if (flags & DTFLAG_BIG_HEALTH) health = ReadInt24_t();
 184     else health = ReadShort();
 185     if (flags & DTFLAG_NO_ARMOR) armor = 0;
 186     else if (flags & DTFLAG_BIG_ARMOR) armor = ReadInt24_t();
 187     else armor = ReadShort();
 188     if (flags & DTFLAG_NO_POTENTIAL) potential_damage = health + armor;
 189     else if (flags & DTFLAG_BIG_POTENTIAL) potential_damage = ReadInt24_t();
 190     else potential_damage = ReadShort();
 191
 192     return = true;
 193     if (autocvar_cl_damagetext) {
 194         if (friendlyfire && !autocvar_cl_damagetext_friendlyfire) {
 195             return;
 196         }
 197         if (autocvar_cl_damagetext_accumulate_range) {
 198             for (entity e = findradius(location, autocvar_cl_damagetext_accumulate_range); e; e = e.chain) {
 199                 if (e.instanceOfDamageText && e.m_group == group && e.alpha > autocvar_cl_damagetext_accumulate_alpha_rel * autocvar_cl_damagetext_alpha_start) {
 200                     DamageText_update(e, location, e.m_damage + health, e.m_armordamage + armor, e.m_potential_damage + potential_damage, deathtype);
 201                     return;
 202                 }
 203             }
 204         }
 205         make_impure(NEW(DamageText, group, location, health, armor, potential_damage, deathtype, friendlyfire));
 206     }
 207 }
 208 #endif
 209
 210 #ifdef MENUQC
 211
 212 #include <menu/gamesettings.qh>
 213
 214 CLASS(XonoticDamageTextSettings, XonoticTab)
 215     REGISTER_SETTINGS(damagetext, NEW(XonoticDamageTextSettings));
 216     ATTRIB(XonoticDamageTextSettings, title, string, _("Damage text"));
 217     ATTRIB(XonoticDamageTextSettings, intendedWidth, float, 0.9);
 218     ATTRIB(XonoticDamageTextSettings, rows, float, 15.5);
 219     ATTRIB(XonoticDamageTextSettings, columns, float, 5);
 220     INIT(XonoticDamageTextSettings) { this.configureDialog(this); }
 221     METHOD(XonoticDamageTextSettings, showNotify, void(entity this)) { loadAllCvars(this); }
 222     METHOD(XonoticDamageTextSettings, fill, void(entity this))
 223     {
 224         entity e;
 225         this.gotoRC(this, 0, 1); this.setFirstColumn(this, this.currentColumn);
 226             this.TD(this, 1, 3, makeXonoticCheckBox(0, "cl_damagetext", _("Draw damage numbers")));
 227         this.TR(this);
 228             this.TD(this, 1, 1, e = makeXonoticTextLabel(0, _("Font size:")));
 229                 setDependent(e, "cl_damagetext", 1, 1);
 230             this.TD(this, 1, 2, e = makeXonoticSlider(0, 50, 1, "cl_damagetext_size"));
 231                 setDependent(e, "cl_damagetext", 1, 1);
 232         this.TR(this);
 233             this.TD(this, 1, 1, e = makeXonoticTextLabel(0, _("Accumulate range:")));
 234                 setDependent(e, "cl_damagetext", 1, 1);
 235             this.TD(this, 1, 2, e = makeXonoticSlider(0, 500, 1, "cl_damagetext_accumulate_range"));
 236                 setDependent(e, "cl_damagetext", 1, 1);
 237         this.TR(this);
 238             this.TD(this, 1, 1, e = makeXonoticTextLabel(0, _("Lifetime:")));
 239                 setDependent(e, "cl_damagetext", 1, 1);
 240             this.TD(this, 1, 2, e = makeXonoticSlider(0, 10, 1, "cl_damagetext_alpha_lifetime"));
 241                 setDependent(e, "cl_damagetext", 1, 1);
 242         this.TR(this);
 243             this.TD(this, 1, 1, e = makeXonoticTextLabel(0, _("Color:")));
 244                 setDependent(e, "cl_damagetext", 1, 1);
 245             this.TD(this, 2, 2, e = makeXonoticColorpickerString("cl_damagetext_color", "cl_damagetext_color"));
 246                 setDependent(e, "cl_damagetext", 1, 1);
 247         this.TR(this);
 248         this.TR(this);
 249         // friendly fire
 250             this.TD(this, 1, 3, e = makeXonoticCheckBox(0, "cl_damagetext_friendlyfire", _("Draw damage numbers for friendly fire")));
 251                 setDependent(e, "cl_damagetext", 1, 1);
 252         this.TR(this);
 253             this.TD(this, 1, 1, e = makeXonoticTextLabel(0, _("Color:")));
 254                 setDependentAND(e, "cl_damagetext", 1, 1, "cl_damagetext_friendlyfire", 1, 1);
 255             this.TD(this, 2, 2, e = makeXonoticColorpickerString("cl_damagetext_friendlyfire_color", "cl_damagetext_friendlyfire_color"));
 256                 setDependentAND(e, "cl_damagetext", 1, 1, "cl_damagetext_friendlyfire", 1, 1);
 257         this.TR(this);
 258     }
 259 ENDCLASS(XonoticDamageTextSettings)
 260 #endif