qcsrc/common/mutators/mutator/damagetext/damagetext.qc

   1 #ifndef MUTATOR_DAMAGETEXT_H
   2 #define MUTATOR_DAMAGETEXT_H
   3
   4 #ifdef MENUQC
   5 #include <menu/xonotic/tab.qc>
   6 #endif
   7
   8 #endif
   9
  10 #ifdef IMPLEMENTATION
  11 REGISTER_MUTATOR(damagetext, true);
  12
  13 #if defined(CSQC) || defined(MENUQC)
  14 // no translatable cvar description please
  15 AUTOCVAR_SAVE(cl_damagetext,                    bool,   false,      "Draw damage dealt where you hit the enemy");
  16 AUTOCVAR_SAVE(cl_damagetext_format,             string, "-%3$$d",   "How to format the damage text. 1$ is health, 2$ is armor, 3$ is both");
  17 AUTOCVAR_SAVE(cl_damagetext_color,              vector, '1 1 0',    "Damage text color");
  18 AUTOCVAR_SAVE(cl_damagetext_color_per_weapon,   bool,   false,      "Damage text uses weapon color");
  19 AUTOCVAR_SAVE(cl_damagetext_size,               float,  8,          "Damage text font size");
  20 AUTOCVAR_SAVE(cl_damagetext_alpha_start,        float,  1,          "Damage text initial alpha");
  21 AUTOCVAR_SAVE(cl_damagetext_alpha_lifetime,     float,  3,          "Damage text lifetime in seconds");
  22 AUTOCVAR_SAVE(cl_damagetext_velocity,           vector, '0 0 20',   "Damage text move direction");
  23 AUTOCVAR_SAVE(cl_damagetext_offset,             vector, '0 -40 0',  "Damage text offset");
  24 AUTOCVAR_SAVE(cl_damagetext_accumulate_range,   float,  30,         "Damage text spawned within this range is accumulated");
  25 #endif
  26
  27 #ifdef CSQC
  28 CLASS(DamageText, Object)
  29     ATTRIB(DamageText, m_color, vector, autocvar_cl_damagetext_color)
  30     ATTRIB(DamageText, m_size, float, autocvar_cl_damagetext_size)
  31     ATTRIB(DamageText, alpha, float, autocvar_cl_damagetext_alpha_start)
  32     ATTRIB(DamageText, fade_rate, float, 1 / autocvar_cl_damagetext_alpha_lifetime)
  33     ATTRIB(DamageText, velocity, vector, autocvar_cl_damagetext_velocity)
  34     ATTRIB(DamageText, m_group, int, 0)
  35     ATTRIB(DamageText, m_damage, int, 0)
  36     ATTRIB(DamageText, m_armordamage, int, 0)
  37     ATTRIB(DamageText, m_deathtype, int, 0)
  38     ATTRIB(DamageText, time_prev, float, time)
  39
  40     void DamageText_draw2d(DamageText this) {
  41         float dt = time - this.time_prev;
  42         this.time_prev = time;
  43         setorigin(this, this.origin + dt * this.velocity);
  44         this.alpha -= dt * this.fade_rate;
  45         if (this.alpha < 0) remove(this);
  46         vector pos = project_3d_to_2d(this.origin) + autocvar_cl_damagetext_offset;
  47         if (pos.z >= 0 && this.m_size > 0) {
  48             pos.z = 0;
  49             vector rgb = this.m_color;
  50             if (autocvar_cl_damagetext_color_per_weapon) {
  51                 Weapon w = DEATH_WEAPONOF(this.m_deathtype);
  52                 if (w != WEP_Null) rgb = w.wpcolor;
  53             }
  54             string s = sprintf(autocvar_cl_damagetext_format, this.m_damage, this.m_armordamage, this.m_damage + this.m_armordamage);
  55             drawcolorcodedstring2(pos, s, this.m_size * '1 1 0', rgb, this.alpha, DRAWFLAG_NORMAL);
  56         }
  57     }
  58     ATTRIB(DamageText, draw2d, void(DamageText), DamageText_draw2d)
  59
  60     void DamageText_update(DamageText this, vector _origin, int _health, int _armor, int _deathtype) {
  61         this.m_damage = _health;
  62         this.m_armordamage = _armor;
  63         this.m_deathtype = _deathtype;
  64         setorigin(this, _origin);
  65         this.alpha = 1;
  66     }
  67
  68     CONSTRUCTOR(DamageText, int _group, vector _origin, int _health, int _armor, int _deathtype) {
  69         CONSTRUCT(DamageText);
  70         this.m_group = _group;
  71         DamageText_update(this, _origin, _health, _armor, _deathtype);
  72     }
  73 ENDCLASS(DamageText)
  74 #endif
  75
  76 REGISTER_NET_TEMP(damagetext)
  77
  78 #ifdef SVQC
  79 AUTOCVAR(sv_damagetext, int, 2, _("<= 0: disabled, >= 1: spectators, >= 2: players, >= 3: all players"));
  80 #define SV_DAMAGETEXT_DISABLED()        (autocvar_sv_damagetext <= 0 /* disabled */)
  81 #define SV_DAMAGETEXT_SPECTATORS_ONLY() (autocvar_sv_damagetext >= 1 /* spectators only */)
  82 #define SV_DAMAGETEXT_PLAYERS()         (autocvar_sv_damagetext >= 2 /* players */)
  83 #define SV_DAMAGETEXT_ALL()             (autocvar_sv_damagetext >= 3 /* all players */)
  84 MUTATOR_HOOKFUNCTION(damagetext, PlayerDamaged) {
  85     if (SV_DAMAGETEXT_DISABLED()) return;
  86     const entity attacker = MUTATOR_ARGV(0, entity);
  87     const entity hit = MUTATOR_ARGV(1, entity); if (hit == attacker) return;
  88     const int health = MUTATOR_ARGV(0, int);
  89     const int armor = MUTATOR_ARGV(1, int);
  90     const int deathtype = MUTATOR_ARGV(2, int);
  91     const vector location = hit.origin;
  92     FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(
  93         if (
  94             (SV_DAMAGETEXT_ALL()) ||
  95             (SV_DAMAGETEXT_PLAYERS() && it == attacker) ||
  96             (SV_DAMAGETEXT_SPECTATORS_ONLY() && IS_SPEC(it) && it.enemy == attacker) ||
  97             (SV_DAMAGETEXT_SPECTATORS_ONLY() && IS_OBSERVER(it))
  98         ) {
  99             msg_entity = it;
 100             WriteHeader(MSG_ONE, damagetext);
 101             WriteShort(MSG_ONE, health);
 102             WriteShort(MSG_ONE, armor);
 103             WriteEntity(MSG_ONE, hit);
 104             WriteCoord(MSG_ONE, location.x);
 105             WriteCoord(MSG_ONE, location.y);
 106             WriteCoord(MSG_ONE, location.z);
 107             WriteInt24_t(MSG_ONE, deathtype);
 108         }
 109     ));
 110 }
 111 #endif
 112
 113 #ifdef CSQC
 114 NET_HANDLE(damagetext, bool isNew)
 115 {
 116     int health = ReadShort();
 117     int armor = ReadShort();
 118     int group = ReadShort();
 119     vector location = vec3(ReadCoord(), ReadCoord(), ReadCoord());
 120     int deathtype = ReadInt24_t();
 121     return = true;
 122     if (autocvar_cl_damagetext) {
 123         if (autocvar_cl_damagetext_accumulate_range) {
 124             for (entity e = findradius(location, autocvar_cl_damagetext_accumulate_range); e; e = e.chain) {
 125                 if (e.instanceOfDamageText && e.m_group == group) {
 126                     DamageText_update(e, location, e.m_damage + health, e.m_armordamage + armor, deathtype);
 127                     return;
 128                 }
 129             }
 130         }
 131         NEW(DamageText, group, location, health, armor, deathtype);
 132     }
 133 }
 134 #endif
 135
 136 #ifdef MENUQC
 137 CLASS(XonoticDamageTextSettings, XonoticTab)
 138     #include <menu/gamesettings.qh>
 139     REGISTER_SETTINGS(damagetext, NEW(XonoticDamageTextSettings));
 140     ATTRIB(XonoticDamageTextSettings, title, string, _("Damage text"))
 141     ATTRIB(XonoticDamageTextSettings, intendedWidth, float, 0.9)
 142     ATTRIB(XonoticDamageTextSettings, rows, float, 15.5)
 143     ATTRIB(XonoticDamageTextSettings, columns, float, 5)
 144     INIT(XonoticDamageTextSettings) { this.configureDialog(this); }
 145     METHOD(XonoticDamageTextSettings, showNotify, void(entity this)) { loadAllCvars(this); }
 146     METHOD(XonoticDamageTextSettings, fill, void(entity this))
 147     {
 148         this.gotoRC(this, 0, 1); this.setFirstColumn(this, this.currentColumn);
 149             this.TD(this, 1, 3, makeXonoticCheckBox(0, "cl_damagetext", _("Draw damage numbers")));
 150         this.TR(this);
 151             this.TD(this, 1, 1, makeXonoticTextLabel(0, _("Font size:")));
 152             this.TD(this, 1, 2, makeXonoticSlider(0, 50, 1, "cl_damagetext_size"));
 153         this.TR(this);
 154             this.TD(this, 1, 1, makeXonoticTextLabel(0, _("Accumulate range:")));
 155             this.TD(this, 1, 2, makeXonoticSlider(0, 500, 1, "cl_damagetext_accumulate_range"));
 156         this.TR(this);
 157             this.TD(this, 1, 1, makeXonoticTextLabel(0, _("Lifetime:")));
 158             this.TD(this, 1, 2, makeXonoticSlider(0, 10, 1, "cl_damagetext_alpha_lifetime"));
 159         this.TR(this);
 160             this.TD(this, 1, 1, makeXonoticTextLabel(0, _("Color:")));
 161             this.TD(this, 2, 2, makeXonoticColorpickerString("cl_damagetext_color", "cl_damagetext_color"));
 162     }
 163 ENDCLASS(XonoticDamageTextSettings)
 164 #endif
 165 #endif