qcsrc/common/mutators/mutator/damagetext/damagetext.qc

   1 #ifndef MUTATOR_DAMAGETEXT_H
   2 #define MUTATOR_DAMAGETEXT_H
   3
   4 #ifdef MENUQC
   5 #include <menu/xonotic/tab.qc>
   6 #endif
   7
   8 #endif
   9
  10 #ifdef IMPLEMENTATION
  11 REGISTER_MUTATOR(damagetext, true);
  12
  13 #if defined(CSQC) || defined(MENUQC)
  14 // no translatable cvar description please
  15 AUTOCVAR_SAVE(cl_damagetext,                    bool,   false,      "Draw damage dealt where you hit the enemy");
  16 AUTOCVAR_SAVE(cl_damagetext_format,             string, "-{total}", "How to format the damage text. {health}, {armor}, {total}");
  17 AUTOCVAR_SAVE(cl_damagetext_color,              vector, '1 1 0',    "Damage text color");
  18 AUTOCVAR_SAVE(cl_damagetext_color_per_weapon,   bool,   false,      "Damage text uses weapon color");
  19 AUTOCVAR_SAVE(cl_damagetext_size,               float,  8,          "Damage text font size");
  20 AUTOCVAR_SAVE(cl_damagetext_alpha_start,        float,  1,          "Damage text initial alpha");
  21 AUTOCVAR_SAVE(cl_damagetext_alpha_lifetime,     float,  3,          "Damage text lifetime in seconds");
  22 AUTOCVAR_SAVE(cl_damagetext_velocity,           vector, '0 0 20',   "Damage text move direction");
  23 AUTOCVAR_SAVE(cl_damagetext_offset,             vector, '0 -40 0',  "Damage text offset");
  24 AUTOCVAR_SAVE(cl_damagetext_accumulate_range,   float,  30,         "Damage text spawned within this range is accumulated");
  25 #endif
  26
  27 #ifdef CSQC
  28 CLASS(DamageText, Object)
  29     ATTRIB(DamageText, m_color, vector, autocvar_cl_damagetext_color)
  30     ATTRIB(DamageText, m_size, float, autocvar_cl_damagetext_size)
  31     ATTRIB(DamageText, alpha, float, autocvar_cl_damagetext_alpha_start)
  32     ATTRIB(DamageText, fade_rate, float, 1 / autocvar_cl_damagetext_alpha_lifetime)
  33     ATTRIB(DamageText, velocity, vector, autocvar_cl_damagetext_velocity)
  34     ATTRIB(DamageText, m_group, int, 0)
  35     ATTRIB(DamageText, m_damage, int, 0)
  36     ATTRIB(DamageText, m_armordamage, int, 0)
  37     ATTRIB(DamageText, m_deathtype, int, 0)
  38     ATTRIB(DamageText, time_prev, float, time)
  39
  40     void DamageText_draw2d(DamageText this) {
  41         float dt = time - this.time_prev;
  42         this.time_prev = time;
  43         setorigin(this, this.origin + dt * this.velocity);
  44         this.alpha -= dt * this.fade_rate;
  45         if (this.alpha < 0) remove(this);
  46         vector pos = project_3d_to_2d(this.origin) + autocvar_cl_damagetext_offset;
  47         if (pos.z >= 0 && this.m_size > 0) {
  48             pos.z = 0;
  49             vector rgb = this.m_color;
  50             if (autocvar_cl_damagetext_color_per_weapon) {
  51                 Weapon w = DEATH_WEAPONOF(this.m_deathtype);
  52                 if (w != WEP_Null) rgb = w.wpcolor;
  53             }
  54             string s = autocvar_cl_damagetext_format;
  55             s = strreplace("{health}", sprintf("%d", this.m_damage), s);
  56             s = strreplace("{armor}",  sprintf("%d", this.m_armordamage), s);
  57             s = strreplace("{total}",  sprintf("%d", this.m_damage + this.m_armordamage), s);
  58             drawcolorcodedstring2(pos, s, this.m_size * '1 1 0', rgb, this.alpha, DRAWFLAG_NORMAL);
  59         }
  60     }
  61     ATTRIB(DamageText, draw2d, void(DamageText), DamageText_draw2d)
  62
  63     void DamageText_update(DamageText this, vector _origin, int _health, int _armor, int _deathtype) {
  64         this.m_damage = _health;
  65         this.m_armordamage = _armor;
  66         this.m_deathtype = _deathtype;
  67         setorigin(this, _origin);
  68         this.alpha = 1;
  69     }
  70
  71     CONSTRUCTOR(DamageText, int _group, vector _origin, int _health, int _armor, int _deathtype) {
  72         CONSTRUCT(DamageText);
  73         this.m_group = _group;
  74         DamageText_update(this, _origin, _health, _armor, _deathtype);
  75     }
  76 ENDCLASS(DamageText)
  77 #endif
  78
  79 REGISTER_NET_TEMP(damagetext)
  80
  81 #ifdef SVQC
  82 AUTOCVAR(sv_damagetext, int, 2, _("<= 0: disabled, >= 1: spectators, >= 2: players, >= 3: all players"));
  83 #define SV_DAMAGETEXT_DISABLED()        (autocvar_sv_damagetext <= 0 /* disabled */)
  84 #define SV_DAMAGETEXT_SPECTATORS_ONLY() (autocvar_sv_damagetext >= 1 /* spectators only */)
  85 #define SV_DAMAGETEXT_PLAYERS()         (autocvar_sv_damagetext >= 2 /* players */)
  86 #define SV_DAMAGETEXT_ALL()             (autocvar_sv_damagetext >= 3 /* all players */)
  87 MUTATOR_HOOKFUNCTION(damagetext, PlayerDamaged) {
  88     if (SV_DAMAGETEXT_DISABLED()) return;
  89     const entity attacker = MUTATOR_ARGV(0, entity);
  90     const entity hit = MUTATOR_ARGV(1, entity); if (hit == attacker) return;
  91     const int health = MUTATOR_ARGV(0, int);
  92     const int armor = MUTATOR_ARGV(1, int);
  93     const int deathtype = MUTATOR_ARGV(2, int);
  94     const vector location = hit.origin;
  95     FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(
  96         if (
  97             (SV_DAMAGETEXT_ALL()) ||
  98             (SV_DAMAGETEXT_PLAYERS() && it == attacker) ||
  99             (SV_DAMAGETEXT_SPECTATORS_ONLY() && IS_SPEC(it) && it.enemy == attacker) ||
 100             (SV_DAMAGETEXT_SPECTATORS_ONLY() && IS_OBSERVER(it))
 101         ) {
 102             msg_entity = it;
 103             WriteHeader(MSG_ONE, damagetext);
 104             WriteShort(MSG_ONE, rint(health));
 105             WriteShort(MSG_ONE, rint(armor));
 106             WriteEntity(MSG_ONE, hit);
 107             WriteCoord(MSG_ONE, location.x);
 108             WriteCoord(MSG_ONE, location.y);
 109             WriteCoord(MSG_ONE, location.z);
 110             WriteInt24_t(MSG_ONE, deathtype);
 111         }
 112     ));
 113 }
 114 #endif
 115
 116 #ifdef CSQC
 117 NET_HANDLE(damagetext, bool isNew)
 118 {
 119     int health = ReadShort();
 120     int armor = ReadShort();
 121     int group = ReadShort();
 122     vector location = vec3(ReadCoord(), ReadCoord(), ReadCoord());
 123     int deathtype = ReadInt24_t();
 124     return = true;
 125     if (autocvar_cl_damagetext) {
 126         if (autocvar_cl_damagetext_accumulate_range) {
 127             for (entity e = findradius(location, autocvar_cl_damagetext_accumulate_range); e; e = e.chain) {
 128                 if (e.instanceOfDamageText && e.m_group == group) {
 129                     DamageText_update(e, location, e.m_damage + health, e.m_armordamage + armor, deathtype);
 130                     return;
 131                 }
 132             }
 133         }
 134         NEW(DamageText, group, location, health, armor, deathtype);
 135     }
 136 }
 137 #endif
 138
 139 #ifdef MENUQC
 140 CLASS(XonoticDamageTextSettings, XonoticTab)
 141     #include <menu/gamesettings.qh>
 142     REGISTER_SETTINGS(damagetext, NEW(XonoticDamageTextSettings));
 143     ATTRIB(XonoticDamageTextSettings, title, string, _("Damage text"))
 144     ATTRIB(XonoticDamageTextSettings, intendedWidth, float, 0.9)
 145     ATTRIB(XonoticDamageTextSettings, rows, float, 15.5)
 146     ATTRIB(XonoticDamageTextSettings, columns, float, 5)
 147     INIT(XonoticDamageTextSettings) { this.configureDialog(this); }
 148     METHOD(XonoticDamageTextSettings, showNotify, void(entity this)) { loadAllCvars(this); }
 149     METHOD(XonoticDamageTextSettings, fill, void(entity this))
 150     {
 151         this.gotoRC(this, 0, 1); this.setFirstColumn(this, this.currentColumn);
 152             this.TD(this, 1, 3, makeXonoticCheckBox(0, "cl_damagetext", _("Draw damage numbers")));
 153         this.TR(this);
 154             this.TD(this, 1, 1, makeXonoticTextLabel(0, _("Font size:")));
 155             this.TD(this, 1, 2, makeXonoticSlider(0, 50, 1, "cl_damagetext_size"));
 156         this.TR(this);
 157             this.TD(this, 1, 1, makeXonoticTextLabel(0, _("Accumulate range:")));
 158             this.TD(this, 1, 2, makeXonoticSlider(0, 500, 1, "cl_damagetext_accumulate_range"));
 159         this.TR(this);
 160             this.TD(this, 1, 1, makeXonoticTextLabel(0, _("Lifetime:")));
 161             this.TD(this, 1, 2, makeXonoticSlider(0, 10, 1, "cl_damagetext_alpha_lifetime"));
 162         this.TR(this);
 163             this.TD(this, 1, 1, makeXonoticTextLabel(0, _("Color:")));
 164             this.TD(this, 2, 2, makeXonoticColorpickerString("cl_damagetext_color", "cl_damagetext_color"));
 165     }
 166 ENDCLASS(XonoticDamageTextSettings)
 167 #endif
 168 #endif