qcsrc/common/mutators/mutator/itemstime.qc

   1 REGISTER_MUTATOR(itemstime, true);
   2
   3 #ifdef SVQC
   4 void IT_Write(entity e, int i, float f) {
   5     if (!IS_REAL_CLIENT(e)) return;
   6     msg_entity = e;
   7     WriteByte(MSG_ONE, SVC_TEMPENTITY);
   8     WriteMutator(MSG_ONE, itemstime);
   9     WriteByte(MSG_ONE, i);
  10     WriteFloat(MSG_ONE, f);
  11 }
  12 #endif
  13
  14 #ifdef CSQC
  15 float ItemsTime_time[MAX_ITEMS];
  16 float ItemsTime_availableTime[MAX_ITEMS];
  17 MUTATOR_HOOKFUNCTION(itemstime, CSQC_Parse_TempEntity) {
  18     if (MUTATOR_RETURNVALUE) return false;
  19     if (!ReadMutatorEquals(mutator_argv_int_0, itemstime)) return false;
  20     int i = ReadByte();
  21     float f = ReadFloat();
  22     ItemsTime_time[i] = f;
  23     return true;
  24 }
  25 #endif
  26
  27 #ifdef CSQC
  28 int autocvar_hud_panel_itemstime = 2;
  29 float autocvar_hud_panel_itemstime_dynamicsize = 1;
  30 float autocvar_hud_panel_itemstime_ratio = 2;
  31 int autocvar_hud_panel_itemstime_iconalign;
  32 bool autocvar_hud_panel_itemstime_progressbar = 0;
  33 float autocvar_hud_panel_itemstime_progressbar_maxtime = 30;
  34 string autocvar_hud_panel_itemstime_progressbar_name = "progressbar";
  35 float autocvar_hud_panel_itemstime_progressbar_reduced;
  36 bool autocvar_hud_panel_itemstime_hidespawned = 1;
  37 bool autocvar_hud_panel_itemstime_hidelarge = false;
  38 int autocvar_hud_panel_itemstime_text = 1;
  39 #define hud_panel_itemstime_hidelarge autocvar_hud_panel_itemstime_hidelarge
  40 #endif
  41
  42 #ifdef SVQC
  43 #define hud_panel_itemstime_hidelarge false
  44 #endif
  45
  46 bool Item_ItemsTime_Allow(GameItem it, WepSet _weapons)
  47 {
  48     return (false
  49     || it.instanceOfPowerup
  50     || it == ITEM_ArmorMega     || (it == ITEM_ArmorLarge && !hud_panel_itemstime_hidelarge)
  51     || it == ITEM_HealthMega    || (it == ITEM_HealthLarge && !hud_panel_itemstime_hidelarge)
  52     || (_weapons & WEPSET_SUPERWEAPONS)
  53     );
  54 }
  55
  56 #ifdef SVQC
  57
  58 float it_times[MAX_ITEMS];
  59
  60 void Item_ItemsTime_Init()
  61 {
  62     FOREACH(ITEMS, true, LAMBDA(
  63         it_times[it.m_id] = -1;
  64     ));
  65 }
  66
  67 STATIC_INIT(ItemsTime_Init) {
  68     // items time
  69     Item_ItemsTime_Init();
  70 }
  71
  72 void Item_ItemsTime_ResetTimes()
  73 {
  74     FOREACH(ITEMS, true, LAMBDA(
  75         it_times[it.m_id] = (it_times[it.m_id] == -1) ? -1 : 0;
  76     ));
  77 }
  78
  79 void Item_ItemsTime_ResetTimesForPlayer(entity e)
  80 {
  81     FOREACH(ITEMS, true, LAMBDA(
  82         IT_Write(e, it.m_id, (it_times[it.m_id] == -1) ? -1 : 0);
  83     ));
  84 }
  85
  86 void Item_ItemsTime_SetTimesForPlayer(entity e)
  87 {
  88     FOREACH(ITEMS, true, LAMBDA(
  89         IT_Write(e, it.m_id, it_times[it.m_id]);
  90     ));
  91 }
  92
  93 void Item_ItemsTime_SetTime(entity e, float t)
  94 {
  95     if (!autocvar_sv_itemstime)
  96         return;
  97
  98     GameItem item = e.itemdef;
  99     it_times[item.m_id] = t;
 100 }
 101
 102 void Item_ItemsTime_SetTimesForAllPlayers()
 103 {
 104     entity e;
 105     FOR_EACH_REALCLIENT(e) if (warmup_stage || !IS_PLAYER(e))
 106         Item_ItemsTime_SetTimesForPlayer(e);
 107 }
 108
 109 float Item_ItemsTime_UpdateTime(entity e, float t)
 110 {
 111     bool isavailable = (t == 0);
 112     if (e.weapons & WEPSET_SUPERWEAPONS)
 113     {
 114         for (entity head = world; (head = nextent(head)); )
 115         {
 116             if (clienttype(head) != CLIENTTYPE_NOTACLIENT || !(head.weapons & WEPSET_SUPERWEAPONS) || head.classname == "weapon_info")
 117                 continue;
 118             if (e == head)
 119                 continue;
 120
 121             if (head.scheduledrespawntime <= time)
 122                 isavailable = true;
 123             else if (t == 0 || head.scheduledrespawntime < t)
 124                 t = head.scheduledrespawntime;
 125         }
 126     }
 127     else
 128     {
 129         for (entity head = world; (head = nextent(head)); )
 130         {
 131             if (head.itemdef != e.itemdef)
 132                 continue;
 133             if (e == head)
 134                 continue;
 135
 136             if (head.scheduledrespawntime <= time)
 137                 isavailable = true;
 138             else if (t == 0 || head.scheduledrespawntime < t)
 139                 t = head.scheduledrespawntime;
 140         }
 141     }
 142     if (isavailable)
 143         t = -t; // let know the client there's another available item
 144     return t;
 145 }
 146
 147 MUTATOR_HOOKFUNCTION(itemstime, reset_map_global) {
 148     Item_ItemsTime_ResetTimes();
 149 }
 150
 151 MUTATOR_HOOKFUNCTION(itemstime, MakePlayerObserver) {
 152     Item_ItemsTime_SetTimesForPlayer(self);
 153 }
 154
 155 MUTATOR_HOOKFUNCTION(itemstime, PlayerSpawn) {
 156     if (warmup_stage) return;
 157     Item_ItemsTime_ResetTimesForPlayer(self);
 158 }
 159
 160 #endif
 161
 162 #ifdef CSQC
 163
 164 void DrawItemsTimeItem(vector myPos, vector mySize, float ar, entity item, float item_time, bool item_available, float item_availableTime)
 165 {
 166     float t = 0;
 167     vector color = '0 0 0';
 168     float picalpha;
 169
 170     if (autocvar_hud_panel_itemstime_hidespawned == 2)
 171         picalpha = 1;
 172     else if (item_available)
 173     {
 174         float BLINK_FACTOR = 0.15;
 175         float BLINK_BASE = 0.85;
 176         float BLINK_FREQ = 5;
 177         picalpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ);
 178     }
 179     else
 180         picalpha = 0.5;
 181     t = floor(item_time - time + 0.999);
 182     if (t < 5)
 183         color = '0.7 0 0';
 184     else if (t < 10)
 185         color = '0.7 0.7 0';
 186     else
 187         color = '1 1 1';
 188
 189     vector picpos, numpos;
 190     if (autocvar_hud_panel_itemstime_iconalign)
 191     {
 192         numpos = myPos;
 193         picpos = myPos + eX * (ar - 1) * mySize_y;
 194     }
 195     else
 196     {
 197         numpos = myPos + eX * mySize_y;
 198         picpos = myPos;
 199     }
 200
 201     if (t > 0 && autocvar_hud_panel_itemstime_progressbar)
 202     {
 203         vector p_pos, p_size;
 204         if (autocvar_hud_panel_itemstime_progressbar_reduced)
 205         {
 206             p_pos = numpos;
 207             p_size = eX * ((ar - 1)/ar) * mySize_x + eY * mySize_y;
 208         }
 209         else
 210         {
 211             p_pos = myPos;
 212             p_size = mySize;
 213         }
 214         HUD_Panel_DrawProgressBar(p_pos, p_size, autocvar_hud_panel_itemstime_progressbar_name, t/autocvar_hud_panel_itemstime_progressbar_maxtime, 0, autocvar_hud_panel_itemstime_iconalign, color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 215     }
 216
 217     if (t > 0 && autocvar_hud_panel_itemstime_text)
 218         drawstring_aspect(numpos, ftos(t), eX * ((ar - 1)/ar) * mySize_x + eY * mySize_y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
 219     else
 220         picpos.x = myPos.x + mySize.x / 2 - mySize.y / 2;
 221     if (item_availableTime)
 222         drawpic_aspect_skin_expanding(picpos, item.m_icon, '1 1 0' * mySize_y, '1 1 1', panel_fg_alpha * picalpha, DRAWFLAG_NORMAL, item_availableTime);
 223     drawpic_aspect_skin(picpos, item.m_icon, '1 1 0' * mySize_y, '1 1 1', panel_fg_alpha * picalpha, DRAWFLAG_NORMAL);
 224 }
 225
 226 void HUD_ItemsTime()
 227 {
 228     if (!autocvar__hud_configure)
 229     {
 230         if (!(
 231             (autocvar_hud_panel_itemstime == 1 && spectatee_status != 0)
 232         ||      (autocvar_hud_panel_itemstime == 2 && (spectatee_status != 0 || warmup_stage))
 233             )) { return; }
 234     }
 235     else
 236     {
 237         ItemsTime_time[ITEM_ArmorMega.m_id] = time + 0;
 238         ItemsTime_time[ITEM_HealthMega.m_id] = time + 8;
 239         ItemsTime_time[ITEM_Strength.m_id] = time + 0;
 240         ItemsTime_time[ITEM_Shield.m_id] = time + 4;
 241     }
 242
 243     int count = 0;
 244     if (autocvar_hud_panel_itemstime_hidespawned == 1)
 245         FOREACH(ITEMS, Item_ItemsTime_Allow(it, '0 0 0'), LAMBDA(
 246             count += (ItemsTime_time[i] > time || -ItemsTime_time[i] > time);
 247         ));
 248     else if (autocvar_hud_panel_itemstime_hidespawned == 2)
 249         FOREACH(ITEMS, Item_ItemsTime_Allow(it, '0 0 0'), LAMBDA(
 250             count += (ItemsTime_time[i] > time);
 251         ));
 252     else
 253         FOREACH(ITEMS, Item_ItemsTime_Allow(it, '0 0 0'), LAMBDA(
 254             count += (ItemsTime_time[i] != -1);
 255         ));
 256     if (count == 0)
 257         return;
 258
 259     HUD_Panel_UpdateCvars();
 260
 261     vector pos, mySize;
 262     pos = panel_pos;
 263     mySize = panel_size;
 264
 265     if (panel_bg_padding)
 266     {
 267         pos += '1 1 0' * panel_bg_padding;
 268         mySize -= '2 2 0' * panel_bg_padding;
 269     }
 270
 271     float rows, columns;
 272     float ar = max(2, autocvar_hud_panel_itemstime_ratio) + 1;
 273     rows = HUD_GetRowCount(count, mySize, ar);
 274     columns = ceil(count/rows);
 275
 276     vector itemstime_size = eX * mySize.x*(1/columns) + eY * mySize.y*(1/rows);
 277
 278     vector offset = '0 0 0';
 279     float newSize;
 280     if (autocvar_hud_panel_itemstime_dynamicsize)
 281     {
 282         if (autocvar__hud_configure)
 283         if (menu_enabled != 2)
 284             HUD_Panel_DrawBg(1); // also draw the bg of the entire panel
 285
 286         // reduce panel to avoid spacing items
 287         if (itemstime_size.x / itemstime_size.y < ar)
 288         {
 289             newSize = rows * itemstime_size.x / ar;
 290             pos.y += (mySize.y - newSize) / 2;
 291             mySize.y = newSize;
 292             itemstime_size.y = mySize.y / rows;
 293         }
 294         else
 295         {
 296             newSize = columns * itemstime_size.y * ar;
 297             pos.x += (mySize.x - newSize) / 2;
 298             mySize.x = newSize;
 299             itemstime_size.x = mySize.x / columns;
 300         }
 301         panel_pos = pos - '1 1 0' * panel_bg_padding;
 302         panel_size = mySize + '2 2 0' * panel_bg_padding;
 303     }
 304     else
 305     {
 306         if (itemstime_size.x/itemstime_size.y > ar)
 307         {
 308             newSize = ar * itemstime_size.y;
 309             offset.x = itemstime_size.x - newSize;
 310             pos.x += offset.x/2;
 311             itemstime_size.x = newSize;
 312         }
 313         else
 314         {
 315             newSize = 1/ar * itemstime_size.x;
 316             offset.y = itemstime_size.y - newSize;
 317             pos.y += offset.y/2;
 318             itemstime_size.y = newSize;
 319         }
 320     }
 321
 322     HUD_Panel_DrawBg(1);
 323
 324     float row = 0, column = 0;
 325     bool item_available;
 326     FOREACH(ITEMS, Item_ItemsTime_Allow(it, '0 0 0') && ItemsTime_time[i] != -1, LAMBDA(
 327         float item_time = ItemsTime_time[i];
 328         if (item_time < -1)
 329         {
 330             item_available = true;
 331             item_time = -item_time;
 332         }
 333         else
 334             item_available = (item_time <= time);
 335
 336         if (ItemsTime_time[i] >= 0)
 337         {
 338             if (time <= ItemsTime_time[i])
 339                 ItemsTime_availableTime[i] = 0;
 340             else if (ItemsTime_availableTime[i] == 0)
 341                 ItemsTime_availableTime[i] = time;
 342         }
 343         else if (ItemsTime_availableTime[i] == 0)
 344             ItemsTime_availableTime[i] = time;
 345
 346         float f = (time - ItemsTime_availableTime[i]) * 2;
 347         f = (f > 1) ? 0 : bound(0, f, 1);
 348
 349         if (autocvar_hud_panel_itemstime_hidespawned == 1)
 350             if (!(ItemsTime_time[i] > time || -ItemsTime_time[i] > time))
 351                 continue;
 352
 353         if (autocvar_hud_panel_itemstime_hidespawned == 2)
 354             if (!(ItemsTime_time[i] > time))
 355                 continue;
 356
 357         DrawItemsTimeItem(pos + eX * column * (itemstime_size.x + offset.x) + eY * row * (itemstime_size.y + offset.y), itemstime_size, ar, it, item_time, item_available, f);
 358         ++row;
 359         if (row >= rows)
 360         {
 361             row = 0;
 362             column = column + 1;
 363         }
 364     ));
 365 }
 366
 367 #endif