]> de.git.xonotic.org Git - xonotic/xonotic-data.pk3dir.git/blob - qcsrc/common/mutators/mutator/itemstime.qc
Merge branch 'master' into terencehill/quickmenu
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / mutators / mutator / itemstime.qc
1 REGISTER_MUTATOR(itemstime, true);
2
3 #ifdef SVQC
4 void IT_Write(entity e, int i, float f) {
5     if (!IS_REAL_CLIENT(e)) return;
6     msg_entity = e;
7     WriteByte(MSG_ONE, SVC_TEMPENTITY);
8     WriteMutator(MSG_ONE, itemstime);
9     WriteByte(MSG_ONE, i);
10     WriteFloat(MSG_ONE, f);
11 }
12 #endif
13
14 #ifdef CSQC
15 float ItemsTime_time[MAX_ITEMS];
16 float ItemsTime_availableTime[MAX_ITEMS];
17 MUTATOR_HOOKFUNCTION(itemstime, CSQC_Parse_TempEntity) {
18     if (MUTATOR_RETURNVALUE) return false;
19     if (!ReadMutatorEquals(mutator_argv_int_0, itemstime)) return false;
20     int i = ReadByte();
21     float f = ReadFloat();
22     ItemsTime_time[i] = f;
23     return true;
24 }
25 #endif
26
27 #ifdef CSQC
28 int autocvar_hud_panel_itemstime = 2;
29 float autocvar_hud_panel_itemstime_dynamicsize = 1;
30 float autocvar_hud_panel_itemstime_ratio = 2;
31 int autocvar_hud_panel_itemstime_iconalign;
32 bool autocvar_hud_panel_itemstime_progressbar = 0;
33 float autocvar_hud_panel_itemstime_progressbar_maxtime = 30;
34 string autocvar_hud_panel_itemstime_progressbar_name = "progressbar";
35 float autocvar_hud_panel_itemstime_progressbar_reduced;
36 bool autocvar_hud_panel_itemstime_hidespawned = 1;
37 bool autocvar_hud_panel_itemstime_hidelarge = false;
38 int autocvar_hud_panel_itemstime_text = 1;
39 #define hud_panel_itemstime_hidelarge autocvar_hud_panel_itemstime_hidelarge
40 #else
41 #define hud_panel_itemstime_hidelarge false
42 #endif
43
44 bool Item_ItemsTime_SpectatorOnly(GameItem it)
45 {
46     return (false
47     || it == ITEM_ArmorMega     || (it == ITEM_ArmorLarge && !hud_panel_itemstime_hidelarge)
48     || it == ITEM_HealthMega    || (it == ITEM_HealthLarge && !hud_panel_itemstime_hidelarge)
49     );
50 }
51
52 bool Item_ItemsTime_Allow(GameItem it, WepSet _weapons)
53 {
54     return (false
55     || it.instanceOfPowerup
56     || Item_ItemsTime_SpectatorOnly(it)
57     || (_weapons & WEPSET_SUPERWEAPONS)
58     );
59 }
60
61 #ifdef SVQC
62
63 float it_times[MAX_ITEMS];
64
65 void Item_ItemsTime_Init()
66 {
67     FOREACH(ITEMS, true, LAMBDA(
68         it_times[it.m_id] = -1;
69     ));
70 }
71
72 STATIC_INIT(ItemsTime_Init) {
73     // items time
74     Item_ItemsTime_Init();
75 }
76
77 void Item_ItemsTime_ResetTimes()
78 {
79     FOREACH(ITEMS, true, LAMBDA(
80         it_times[it.m_id] = (it_times[it.m_id] == -1) ? -1 : 0;
81     ));
82 }
83
84 void Item_ItemsTime_ResetTimesForPlayer(entity e)
85 {
86     FOREACH(ITEMS, true, LAMBDA(
87         IT_Write(e, it.m_id, (it_times[it.m_id] == -1) ? -1 : 0);
88     ));
89 }
90
91 void Item_ItemsTime_SetTimesForPlayer(entity e)
92 {
93     FOREACH(ITEMS, true, LAMBDA(
94         IT_Write(e, it.m_id, it_times[it.m_id]);
95     ));
96 }
97
98 void Item_ItemsTime_SetTime(entity e, float t)
99 {
100     if (!autocvar_sv_itemstime)
101         return;
102
103     GameItem item = e.itemdef;
104     it_times[item.m_id] = t;
105 }
106
107 void Item_ItemsTime_SetTimesForAllPlayers()
108 {
109     entity e;
110     FOR_EACH_REALCLIENT(e) if (warmup_stage || !IS_PLAYER(e))
111         Item_ItemsTime_SetTimesForPlayer(e);
112 }
113
114 float Item_ItemsTime_UpdateTime(entity e, float t)
115 {
116     bool isavailable = (t == 0);
117     if (e.weapons & WEPSET_SUPERWEAPONS)
118     {
119         for (entity head = world; (head = nextent(head)); )
120         {
121             if (clienttype(head) != CLIENTTYPE_NOTACLIENT || !(head.weapons & WEPSET_SUPERWEAPONS) || head.classname == "weapon_info")
122                 continue;
123             if (e == head)
124                 continue;
125
126             if (head.scheduledrespawntime <= time)
127                 isavailable = true;
128             else if (t == 0 || head.scheduledrespawntime < t)
129                 t = head.scheduledrespawntime;
130         }
131     }
132     else
133     {
134         for (entity head = world; (head = nextent(head)); )
135         {
136             if (head.itemdef != e.itemdef)
137                 continue;
138             if (e == head)
139                 continue;
140
141             if (head.scheduledrespawntime <= time)
142                 isavailable = true;
143             else if (t == 0 || head.scheduledrespawntime < t)
144                 t = head.scheduledrespawntime;
145         }
146     }
147     if (isavailable)
148         t = -t; // let know the client there's another available item
149     return t;
150 }
151
152 MUTATOR_HOOKFUNCTION(itemstime, reset_map_global) {
153     Item_ItemsTime_ResetTimes();
154     // ALL the times need to be reset before .reset()ing each item
155     // since Item_Reset schedules respawn of superweapons and powerups
156     for (self = world; (self = nextent(self)); )
157     if (IS_NOT_A_CLIENT(self))
158     {
159         if (self.reset)
160             Item_ItemsTime_SetTime(self, 0);
161     }
162     Item_ItemsTime_SetTimesForAllPlayers();
163 }
164
165 MUTATOR_HOOKFUNCTION(itemstime, MakePlayerObserver) {
166     Item_ItemsTime_SetTimesForPlayer(self);
167 }
168
169 MUTATOR_HOOKFUNCTION(itemstime, PlayerSpawn) {
170     if (warmup_stage) return;
171     Item_ItemsTime_ResetTimesForPlayer(self);
172 }
173
174 #endif
175
176 #ifdef CSQC
177
178 void DrawItemsTimeItem(vector myPos, vector mySize, float ar, entity item, float item_time, bool item_available, float item_availableTime)
179 {
180     float t = 0;
181     vector color = '0 0 0';
182     float picalpha;
183
184     if (autocvar_hud_panel_itemstime_hidespawned == 2)
185         picalpha = 1;
186     else if (item_available)
187     {
188         float BLINK_FACTOR = 0.15;
189         float BLINK_BASE = 0.85;
190         float BLINK_FREQ = 5;
191         picalpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ);
192     }
193     else
194         picalpha = 0.5;
195     t = floor(item_time - time + 0.999);
196     if (t < 5)
197         color = '0.7 0 0';
198     else if (t < 10)
199         color = '0.7 0.7 0';
200     else
201         color = '1 1 1';
202
203     vector picpos, numpos;
204     if (autocvar_hud_panel_itemstime_iconalign)
205     {
206         numpos = myPos;
207         picpos = myPos + eX * (ar - 1) * mySize_y;
208     }
209     else
210     {
211         numpos = myPos + eX * mySize_y;
212         picpos = myPos;
213     }
214
215     if (t > 0 && autocvar_hud_panel_itemstime_progressbar)
216     {
217         vector p_pos, p_size;
218         if (autocvar_hud_panel_itemstime_progressbar_reduced)
219         {
220             p_pos = numpos;
221             p_size = eX * ((ar - 1)/ar) * mySize_x + eY * mySize_y;
222         }
223         else
224         {
225             p_pos = myPos;
226             p_size = mySize;
227         }
228         HUD_Panel_DrawProgressBar(p_pos, p_size, autocvar_hud_panel_itemstime_progressbar_name, t/autocvar_hud_panel_itemstime_progressbar_maxtime, 0, autocvar_hud_panel_itemstime_iconalign, color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
229     }
230
231     if (t > 0 && autocvar_hud_panel_itemstime_text)
232         drawstring_aspect(numpos, ftos(t), eX * ((ar - 1)/ar) * mySize_x + eY * mySize_y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
233     else
234         picpos.x = myPos.x + mySize.x / 2 - mySize.y / 2;
235     if (item_availableTime)
236         drawpic_aspect_skin_expanding(picpos, item.m_icon, '1 1 0' * mySize_y, '1 1 1', panel_fg_alpha * picalpha, DRAWFLAG_NORMAL, item_availableTime);
237     drawpic_aspect_skin(picpos, item.m_icon, '1 1 0' * mySize_y, '1 1 1', panel_fg_alpha * picalpha, DRAWFLAG_NORMAL);
238 }
239
240 void HUD_ItemsTime()
241 {
242     if (!autocvar__hud_configure)
243     {
244         if (!(
245             (autocvar_hud_panel_itemstime == 1 && spectatee_status != 0)
246         ||      (autocvar_hud_panel_itemstime == 2 && (spectatee_status != 0 || warmup_stage))
247             )) { return; }
248     }
249     else
250     {
251         ItemsTime_time[ITEM_ArmorMega.m_id] = time + 0;
252         ItemsTime_time[ITEM_HealthMega.m_id] = time + 8;
253         ItemsTime_time[ITEM_Strength.m_id] = time + 0;
254         ItemsTime_time[ITEM_Shield.m_id] = time + 4;
255     }
256
257     int count = 0;
258     if (autocvar_hud_panel_itemstime_hidespawned == 1)
259         FOREACH(ITEMS, Item_ItemsTime_Allow(it, '0 0 0'), LAMBDA(
260             count += (ItemsTime_time[i] > time || -ItemsTime_time[i] > time);
261         ));
262     else if (autocvar_hud_panel_itemstime_hidespawned == 2)
263         FOREACH(ITEMS, Item_ItemsTime_Allow(it, '0 0 0'), LAMBDA(
264             count += (ItemsTime_time[i] > time);
265         ));
266     else
267         FOREACH(ITEMS, Item_ItemsTime_Allow(it, '0 0 0'), LAMBDA(
268             count += (ItemsTime_time[i] != -1);
269         ));
270     if (count == 0)
271         return;
272
273     HUD_Panel_UpdateCvars();
274
275     vector pos, mySize;
276     pos = panel_pos;
277     mySize = panel_size;
278
279     if (panel_bg_padding)
280     {
281         pos += '1 1 0' * panel_bg_padding;
282         mySize -= '2 2 0' * panel_bg_padding;
283     }
284
285     float rows, columns;
286     float ar = max(2, autocvar_hud_panel_itemstime_ratio) + 1;
287     rows = HUD_GetRowCount(count, mySize, ar);
288     columns = ceil(count/rows);
289
290     vector itemstime_size = eX * mySize.x*(1/columns) + eY * mySize.y*(1/rows);
291
292     vector offset = '0 0 0';
293     float newSize;
294     if (autocvar_hud_panel_itemstime_dynamicsize)
295     {
296         if (autocvar__hud_configure)
297         if (menu_enabled != 2)
298             HUD_Panel_DrawBg(1); // also draw the bg of the entire panel
299
300         // reduce panel to avoid spacing items
301         if (itemstime_size.x / itemstime_size.y < ar)
302         {
303             newSize = rows * itemstime_size.x / ar;
304             pos.y += (mySize.y - newSize) / 2;
305             mySize.y = newSize;
306             itemstime_size.y = mySize.y / rows;
307         }
308         else
309         {
310             newSize = columns * itemstime_size.y * ar;
311             pos.x += (mySize.x - newSize) / 2;
312             mySize.x = newSize;
313             itemstime_size.x = mySize.x / columns;
314         }
315         panel_pos = pos - '1 1 0' * panel_bg_padding;
316         panel_size = mySize + '2 2 0' * panel_bg_padding;
317     }
318     else
319     {
320         if (itemstime_size.x/itemstime_size.y > ar)
321         {
322             newSize = ar * itemstime_size.y;
323             offset.x = itemstime_size.x - newSize;
324             pos.x += offset.x/2;
325             itemstime_size.x = newSize;
326         }
327         else
328         {
329             newSize = 1/ar * itemstime_size.x;
330             offset.y = itemstime_size.y - newSize;
331             pos.y += offset.y/2;
332             itemstime_size.y = newSize;
333         }
334     }
335
336     HUD_Panel_DrawBg(1);
337
338     float row = 0, column = 0;
339     bool item_available;
340     FOREACH(ITEMS, Item_ItemsTime_Allow(it, '0 0 0') && ItemsTime_time[i] != -1, LAMBDA(
341         float item_time = ItemsTime_time[i];
342         if (item_time < -1)
343         {
344             item_available = true;
345             item_time = -item_time;
346         }
347         else
348             item_available = (item_time <= time);
349
350         if (ItemsTime_time[i] >= 0)
351         {
352             if (time <= ItemsTime_time[i])
353                 ItemsTime_availableTime[i] = 0;
354             else if (ItemsTime_availableTime[i] == 0)
355                 ItemsTime_availableTime[i] = time;
356         }
357         else if (ItemsTime_availableTime[i] == 0)
358             ItemsTime_availableTime[i] = time;
359
360         float f = (time - ItemsTime_availableTime[i]) * 2;
361         f = (f > 1) ? 0 : bound(0, f, 1);
362
363         if (autocvar_hud_panel_itemstime_hidespawned == 1)
364             if (!(ItemsTime_time[i] > time || -ItemsTime_time[i] > time))
365                 continue;
366
367         if (autocvar_hud_panel_itemstime_hidespawned == 2)
368             if (!(ItemsTime_time[i] > time))
369                 continue;
370
371         DrawItemsTimeItem(pos + eX * column * (itemstime_size.x + offset.x) + eY * row * (itemstime_size.y + offset.y), itemstime_size, ar, it, item_time, item_available, f);
372         ++row;
373         if (row >= rows)
374         {
375             row = 0;
376             column = column + 1;
377         }
378     ));
379 }
380
381 #endif