qcsrc/common/mutators/mutator/multijump/multijump.qc

   1 #ifdef IMPLEMENTATION
   2 #ifdef SVQC
   3         #include "../../../../server/antilag.qh"
   4 #endif
   5 #include "../../../physics.qh"
   6
   7 .int multijump_count;
   8 .bool multijump_ready;
   9 .bool cvar_cl_multijump;
  10
  11 #ifdef CSQC
  12
  13 #define PHYS_MULTIJUMP                          STAT(MULTIJUMP)
  14 #define PHYS_MULTIJUMP_SPEED            STAT(MULTIJUMP_SPEED)
  15 #define PHYS_MULTIJUMP_ADD                      STAT(MULTIJUMP_ADD)
  16 #define PHYS_MULTIJUMP_MAXSPEED         STAT(MULTIJUMP_MAXSPEED)
  17 #define PHYS_MULTIJUMP_DODGING          STAT(MULTIJUMP_DODGING)
  18
  19 #elif defined(SVQC)
  20
  21 int autocvar_g_multijump;
  22 float autocvar_g_multijump_add;
  23 float autocvar_g_multijump_speed;
  24 float autocvar_g_multijump_maxspeed;
  25 float autocvar_g_multijump_dodging = 1;
  26
  27 #define PHYS_MULTIJUMP                          autocvar_g_multijump
  28 #define PHYS_MULTIJUMP_SPEED            autocvar_g_multijump_speed
  29 #define PHYS_MULTIJUMP_ADD                      autocvar_g_multijump_add
  30 #define PHYS_MULTIJUMP_MAXSPEED         autocvar_g_multijump_maxspeed
  31 #define PHYS_MULTIJUMP_DODGING          autocvar_g_multijump_dodging
  32
  33 .float stat_multijump = _STAT(MULTIJUMP);
  34 .float stat_multijump_speed = _STAT(MULTIJUMP_SPEED);
  35 .float stat_multijump_add = _STAT(MULTIJUMP_ADD);
  36 .float stat_multijump_maxspeed = _STAT(MULTIJUMP_MAXSPEED);
  37 .float stat_multijump_dodging = _STAT(MULTIJUMP_DODGING);
  38
  39 void multijump_UpdateStats()
  40 {SELFPARAM();
  41         STAT(MULTIJUMP, this) = PHYS_MULTIJUMP;
  42         STAT(MULTIJUMP_SPEED, this) = PHYS_MULTIJUMP_SPEED;
  43         STAT(MULTIJUMP_ADD, this) = PHYS_MULTIJUMP_ADD;
  44         STAT(MULTIJUMP_MAXSPEED, this) = PHYS_MULTIJUMP_MAXSPEED;
  45         STAT(MULTIJUMP_DODGING, this) = PHYS_MULTIJUMP_DODGING;
  46 }
  47
  48 #endif
  49
  50 void PM_multijump()
  51 {SELFPARAM();
  52         if(!PHYS_MULTIJUMP) { return; }
  53
  54         if(IS_ONGROUND(self))
  55         {
  56                 self.multijump_count = 0;
  57         }
  58 }
  59
  60 bool PM_multijump_checkjump()
  61 {SELFPARAM();
  62         if(!PHYS_MULTIJUMP) { return false; }
  63
  64 #ifdef SVQC
  65         bool client_multijump = self.cvar_cl_multijump;
  66 #elif defined(CSQC)
  67         bool client_multijump = cvar("cl_multijump");
  68
  69         if(cvar("cl_multijump") > 1)
  70                 return false; // nope
  71 #endif
  72
  73         if (!IS_JUMP_HELD(self) && !IS_ONGROUND(self) && client_multijump) // jump button pressed this frame and we are in midair
  74                 self.multijump_ready = true;  // this is necessary to check that we released the jump button and pressed it again
  75         else
  76                 self.multijump_ready = false;
  77
  78         int phys_multijump = PHYS_MULTIJUMP;
  79
  80 #ifdef CSQC
  81         phys_multijump = (PHYS_MULTIJUMP) ? -1 : 0;
  82 #endif
  83
  84         if(!player_multijump && self.multijump_ready && (self.multijump_count < phys_multijump || phys_multijump == -1) && self.velocity_z > PHYS_MULTIJUMP_SPEED && (!PHYS_MULTIJUMP_MAXSPEED || vlen(self.velocity) <= PHYS_MULTIJUMP_MAXSPEED))
  85         {
  86                 if (PHYS_MULTIJUMP)
  87                 {
  88                         if (!PHYS_MULTIJUMP_ADD) // in this case we make the z velocity == jumpvelocity
  89                         {
  90                                 if (self.velocity_z < PHYS_JUMPVELOCITY)
  91                                 {
  92                                         player_multijump = true;
  93                                         self.velocity_z = 0;
  94                                 }
  95                         }
  96                         else
  97                                 player_multijump = true;
  98
  99                         if(player_multijump)
 100                         {
 101                                 if(PHYS_MULTIJUMP_DODGING)
 102                                 if(self.movement_x != 0 || self.movement_y != 0) // don't remove all speed if player isnt pressing any movement keys
 103                                 {
 104                                         float curspeed;
 105                                         vector wishvel, wishdir;
 106
 107 /*#ifdef SVQC
 108                                         curspeed = max(
 109                                                 vlen(vec2(self.velocity)), // current xy speed
 110                                                 vlen(vec2(antilag_takebackavgvelocity(self, max(self.lastteleporttime + sys_frametime, time - 0.25), time))) // average xy topspeed over the last 0.25 secs
 111                                         );
 112 #elif defined(CSQC)*/
 113                                         curspeed = vlen(vec2(self.velocity));
 114 //#endif
 115
 116                                         makevectors(self.v_angle_y * '0 1 0');
 117                                         wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 118                                         wishdir = normalize(wishvel);
 119
 120                                         self.velocity_x = wishdir_x * curspeed; // allow "dodging" at a multijump
 121                                         self.velocity_y = wishdir_y * curspeed;
 122                                         // keep velocity_z unchanged!
 123                                 }
 124                                 if (PHYS_MULTIJUMP > 0)
 125                                 {
 126                                         self.multijump_count += 1;
 127                                 }
 128                         }
 129                 }
 130                 self.multijump_ready = false; // require releasing and pressing the jump button again for the next jump
 131         }
 132
 133         return false;
 134 }
 135
 136 #ifdef SVQC
 137 REGISTER_MUTATOR(multijump, cvar("g_multijump"));
 138
 139 MUTATOR_HOOKFUNCTION(multijump, PlayerPhysics)
 140 {
 141         multijump_UpdateStats();
 142         PM_multijump();
 143
 144         return false;
 145 }
 146
 147 MUTATOR_HOOKFUNCTION(multijump, PlayerJump)
 148 {
 149         return PM_multijump_checkjump();
 150 }
 151
 152 MUTATOR_HOOKFUNCTION(multijump, GetCvars)
 153 {
 154         GetCvars_handleFloat(get_cvars_s, get_cvars_f, cvar_cl_multijump, "cl_multijump");
 155         return false;
 156 }
 157
 158 MUTATOR_HOOKFUNCTION(multijump, BuildMutatorsString)
 159 {
 160         ret_string = strcat(ret_string, ":multijump");
 161         return false;
 162 }
 163
 164 MUTATOR_HOOKFUNCTION(multijump, BuildMutatorsPrettyString)
 165 {
 166         ret_string = strcat(ret_string, ", Multi jump");
 167         return false;
 168 }
 169
 170 #endif
 171 #endif