qcsrc/common/mutators/mutator/multijump/multijump.qc

   1 #ifdef IMPLEMENTATION
   2 #ifdef SVQC
   3         #include "../../../../server/antilag.qh"
   4 #endif
   5 #include "../../../physics.qh"
   6
   7 .int multijump_count;
   8 .bool multijump_ready;
   9 .bool cvar_cl_multijump;
  10
  11 #ifdef CSQC
  12
  13 #define PHYS_MULTIJUMP                          getstati(STAT_MULTIJUMP)
  14 #define PHYS_MULTIJUMP_SPEED            getstatf(STAT_MULTIJUMP_SPEED)
  15 #define PHYS_MULTIJUMP_ADD                      getstati(STAT_MULTIJUMP_ADD)
  16 #define PHYS_MULTIJUMP_MAXSPEED         getstatf(STAT_MULTIJUMP_MAXSPEED)
  17 #define PHYS_MULTIJUMP_DODGING          getstati(STAT_MULTIJUMP_DODGING)
  18
  19 #elif defined(SVQC)
  20
  21 int autocvar_g_multijump;
  22 float autocvar_g_multijump_add;
  23 float autocvar_g_multijump_speed;
  24 float autocvar_g_multijump_maxspeed;
  25 float autocvar_g_multijump_dodging = 1;
  26
  27 #define PHYS_MULTIJUMP                          autocvar_g_multijump
  28 #define PHYS_MULTIJUMP_SPEED            autocvar_g_multijump_speed
  29 #define PHYS_MULTIJUMP_ADD                      autocvar_g_multijump_add
  30 #define PHYS_MULTIJUMP_MAXSPEED         autocvar_g_multijump_maxspeed
  31 #define PHYS_MULTIJUMP_DODGING          autocvar_g_multijump_dodging
  32
  33 .float stat_multijump;
  34 .float stat_multijump_speed;
  35 .float stat_multijump_add;
  36 .float stat_multijump_maxspeed;
  37 .float stat_multijump_dodging;
  38
  39 void multijump_UpdateStats()
  40 {SELFPARAM();
  41         self.stat_multijump = PHYS_MULTIJUMP;
  42         self.stat_multijump_speed = PHYS_MULTIJUMP_SPEED;
  43         self.stat_multijump_add = PHYS_MULTIJUMP_ADD;
  44         self.stat_multijump_maxspeed = PHYS_MULTIJUMP_MAXSPEED;
  45         self.stat_multijump_dodging = PHYS_MULTIJUMP_DODGING;
  46 }
  47
  48 void multijump_AddStats()
  49 {
  50         addstat(STAT_MULTIJUMP, AS_INT, stat_multijump);
  51         addstat(STAT_MULTIJUMP_SPEED, AS_FLOAT, stat_multijump_speed);
  52         addstat(STAT_MULTIJUMP_ADD, AS_INT, stat_multijump_add);
  53         addstat(STAT_MULTIJUMP_MAXSPEED, AS_FLOAT, stat_multijump_maxspeed);
  54         addstat(STAT_MULTIJUMP_DODGING, AS_INT, stat_multijump_dodging);
  55 }
  56
  57 #endif
  58
  59 void PM_multijump()
  60 {SELFPARAM();
  61         if(!PHYS_MULTIJUMP) { return; }
  62
  63         if(IS_ONGROUND(self))
  64         {
  65                 self.multijump_count = 0;
  66         }
  67 }
  68
  69 bool PM_multijump_checkjump()
  70 {SELFPARAM();
  71         if(!PHYS_MULTIJUMP) { return false; }
  72
  73 #ifdef SVQC
  74         bool client_multijump = self.cvar_cl_multijump;
  75 #elif defined(CSQC)
  76         bool client_multijump = cvar("cl_multijump");
  77
  78         if(cvar("cl_multijump") > 1)
  79                 return false; // nope
  80 #endif
  81
  82         if (!IS_JUMP_HELD(self) && !IS_ONGROUND(self) && client_multijump) // jump button pressed this frame and we are in midair
  83                 self.multijump_ready = true;  // this is necessary to check that we released the jump button and pressed it again
  84         else
  85                 self.multijump_ready = false;
  86
  87         int phys_multijump = PHYS_MULTIJUMP;
  88
  89 #ifdef CSQC
  90         phys_multijump = (PHYS_MULTIJUMP) ? -1 : 0;
  91 #endif
  92
  93         if(!player_multijump && self.multijump_ready && (self.multijump_count < phys_multijump || phys_multijump == -1) && self.velocity_z > PHYS_MULTIJUMP_SPEED && (!PHYS_MULTIJUMP_MAXSPEED || vlen(self.velocity) <= PHYS_MULTIJUMP_MAXSPEED))
  94         {
  95                 if (PHYS_MULTIJUMP)
  96                 {
  97                         if (!PHYS_MULTIJUMP_ADD) // in this case we make the z velocity == jumpvelocity
  98                         {
  99                                 if (self.velocity_z < PHYS_JUMPVELOCITY)
 100                                 {
 101                                         player_multijump = true;
 102                                         self.velocity_z = 0;
 103                                 }
 104                         }
 105                         else
 106                                 player_multijump = true;
 107
 108                         if(player_multijump)
 109                         {
 110                                 if(PHYS_MULTIJUMP_DODGING)
 111                                 if(self.movement_x != 0 || self.movement_y != 0) // don't remove all speed if player isnt pressing any movement keys
 112                                 {
 113                                         float curspeed;
 114                                         vector wishvel, wishdir;
 115
 116 /*#ifdef SVQC
 117                                         curspeed = max(
 118                                                 vlen(vec2(self.velocity)), // current xy speed
 119                                                 vlen(vec2(antilag_takebackavgvelocity(self, max(self.lastteleporttime + sys_frametime, time - 0.25), time))) // average xy topspeed over the last 0.25 secs
 120                                         );
 121 #elif defined(CSQC)*/
 122                                         curspeed = vlen(vec2(self.velocity));
 123 //#endif
 124
 125                                         makevectors(self.v_angle_y * '0 1 0');
 126                                         wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 127                                         wishdir = normalize(wishvel);
 128
 129                                         self.velocity_x = wishdir_x * curspeed; // allow "dodging" at a multijump
 130                                         self.velocity_y = wishdir_y * curspeed;
 131                                         // keep velocity_z unchanged!
 132                                 }
 133                                 if (PHYS_MULTIJUMP > 0)
 134                                 {
 135                                         self.multijump_count += 1;
 136                                 }
 137                         }
 138                 }
 139                 self.multijump_ready = false; // require releasing and pressing the jump button again for the next jump
 140         }
 141
 142         return false;
 143 }
 144
 145 #ifdef SVQC
 146 REGISTER_MUTATOR(multijump, cvar("g_multijump"))
 147 {
 148         MUTATOR_ONADD
 149         {
 150                 multijump_AddStats();
 151         }
 152         return false;
 153 }
 154
 155 MUTATOR_HOOKFUNCTION(multijump, PlayerPhysics)
 156 {
 157         multijump_UpdateStats();
 158         PM_multijump();
 159
 160         return false;
 161 }
 162
 163 MUTATOR_HOOKFUNCTION(multijump, PlayerJump)
 164 {
 165         return PM_multijump_checkjump();
 166 }
 167
 168 MUTATOR_HOOKFUNCTION(multijump, GetCvars)
 169 {
 170         GetCvars_handleFloat(get_cvars_s, get_cvars_f, cvar_cl_multijump, "cl_multijump");
 171         return false;
 172 }
 173
 174 MUTATOR_HOOKFUNCTION(multijump, BuildMutatorsString)
 175 {
 176         ret_string = strcat(ret_string, ":multijump");
 177         return false;
 178 }
 179
 180 MUTATOR_HOOKFUNCTION(multijump, BuildMutatorsPrettyString)
 181 {
 182         ret_string = strcat(ret_string, ", Multi jump");
 183         return false;
 184 }
 185
 186 #endif
 187 #endif