qcsrc/common/mutators/mutator/nades/nades.qc

   1 #include "nades.qh"
   2
   3 #ifdef IMPLEMENTATION
   4
   5 #ifdef SVQC
   6 bool autocvar_g_nades_nade_small;
   7 #endif
   8
   9 REGISTER_STAT(NADES_SMALL, int, autocvar_g_nades_nade_small)
  10
  11 #ifndef MENUQC
  12 entity Nade_TrailEffect(int proj, int nade_team)
  13 {
  14     switch (proj)
  15     {
  16         case PROJECTILE_NADE:       return EFFECT_NADE_TRAIL(nade_team);
  17         case PROJECTILE_NADE_BURN:  return EFFECT_NADE_TRAIL_BURN(nade_team);
  18     }
  19
  20     FOREACH(Nades, true, LAMBDA(
  21         for (int j = 0; j < 2; j++)
  22         {
  23             if (it.m_projectile[j] == proj)
  24             {
  25                 string trail = it.m_trail[j].eent_eff_name;
  26                 if (trail) return it.m_trail[j];
  27                 break;
  28             }
  29         }
  30     ));
  31
  32     return EFFECT_Null;
  33 }
  34 #endif
  35
  36 #ifdef CSQC
  37 REGISTER_MUTATOR(cl_nades, true);
  38 MUTATOR_HOOKFUNCTION(cl_nades, HUD_Draw_overlay)
  39 {
  40         if (STAT(HEALING_ORB) <= time) return false;
  41         MUTATOR_ARGV(0, vector) = NADE_TYPE_HEAL.m_color;
  42         MUTATOR_ARGV(0, float) = STAT(HEALING_ORB_ALPHA);
  43         return true;
  44 }
  45 MUTATOR_HOOKFUNCTION(cl_nades, Ent_Projectile)
  46 {
  47         if (self.cnt == PROJECTILE_NAPALM_FOUNTAIN)
  48         {
  49                 self.modelindex = 0;
  50                 self.traileffect = EFFECT_FIREBALL.m_id;
  51                 return true;
  52         }
  53         if (Nade_FromProjectile(self.cnt) != NADE_TYPE_Null)
  54         {
  55                 setmodel(self, MDL_PROJECTILE_NADE);
  56                 entity trail = Nade_TrailEffect(self.cnt, self.team);
  57                 if (trail.eent_eff_name) self.traileffect = trail.m_id;
  58                 return true;
  59         }
  60 }
  61 MUTATOR_HOOKFUNCTION(cl_nades, EditProjectile)
  62 {
  63         if (self.cnt == PROJECTILE_NAPALM_FOUNTAIN)
  64         {
  65                 loopsound(self, CH_SHOTS_SINGLE, SND(FIREBALL_FLY2), VOL_BASE, ATTEN_NORM);
  66                 self.mins = '-16 -16 -16';
  67                 self.maxs = '16 16 16';
  68         }
  69
  70         entity nade_type = Nade_FromProjectile(self.cnt);
  71         if (nade_type == NADE_TYPE_Null) return;
  72         if(STAT(NADES_SMALL, NULL))
  73         {
  74                 self.mins = '-8 -8 -8';
  75                 self.maxs = '8 8 8';
  76         }
  77         else
  78         {
  79                 self.mins = '-16 -16 -16';
  80                 self.maxs = '16 16 16';
  81         }
  82         self.colormod = nade_type.m_color;
  83         self.move_movetype = MOVETYPE_BOUNCE;
  84         self.move_touch = func_null;
  85         self.scale = 1.5;
  86         self.avelocity = randomvec() * 720;
  87
  88         if (nade_type == NADE_TYPE_TRANSLOCATE || nade_type == NADE_TYPE_SPAWN)
  89                 self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
  90         else
  91                 self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY;
  92 }
  93 bool Projectile_isnade(int p)
  94 {
  95         return Nade_FromProjectile(p) != NADE_TYPE_Null;
  96 }
  97 void DrawAmmoNades(vector myPos, vector mySize, bool draw_expanding, float expand_time)
  98 {
  99         float bonusNades    = STAT(NADE_BONUS);
 100         float bonusProgress = STAT(NADE_BONUS_SCORE);
 101         float bonusType     = STAT(NADE_BONUS_TYPE);
 102         Nade def = Nades_from(bonusType);
 103         vector nadeColor    = def.m_color;
 104         string nadeIcon     = def.m_icon;
 105
 106         vector iconPos, textPos;
 107
 108         if(autocvar_hud_panel_ammo_iconalign)
 109         {
 110                 iconPos = myPos + eX * 2 * mySize.y;
 111                 textPos = myPos;
 112         }
 113         else
 114         {
 115                 iconPos = myPos;
 116                 textPos = myPos + eX * mySize.y;
 117         }
 118
 119         if(bonusNades > 0 || bonusProgress > 0)
 120         {
 121                 DrawNadeProgressBar(myPos, mySize, bonusProgress, nadeColor);
 122
 123                 if(autocvar_hud_panel_ammo_text)
 124                         drawstring_aspect(textPos, ftos(bonusNades), eX * (2/3) * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 125
 126                 if(draw_expanding)
 127                         drawpic_aspect_skin_expanding(iconPos, nadeIcon, '1 1 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, expand_time);
 128
 129                 drawpic_aspect_skin(iconPos, nadeIcon, '1 1 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 130         }
 131 }
 132 #endif
 133
 134 #ifdef SVQC
 135
 136 #include <common/gamemodes/all.qh>
 137 #include <common/monsters/spawn.qh>
 138 #include <common/monsters/sv_monsters.qh>
 139 #include <server/g_subs.qh>
 140
 141 REGISTER_MUTATOR(nades, cvar("g_nades"));
 142
 143 .float nade_time_primed;
 144
 145 .entity nade_spawnloc;
 146
 147 void nade_timer_think()
 148 {SELFPARAM();
 149         self.skin = 8 - (self.owner.wait - time) / (autocvar_g_nades_nade_lifetime / 10);
 150         self.nextthink = time;
 151         if(!self.owner || wasfreed(self.owner))
 152                 remove(self);
 153 }
 154
 155 void nade_burn_spawn(entity _nade)
 156 {
 157         CSQCProjectile(_nade, true, Nades_from(_nade.nade_type).m_projectile[true], true);
 158 }
 159
 160 void nade_spawn(entity _nade)
 161 {
 162         entity timer = new(nade_timer);
 163         setmodel(timer, MDL_NADE_TIMER);
 164         setattachment(timer, _nade, "");
 165         timer.colormap = _nade.colormap;
 166         timer.glowmod = _nade.glowmod;
 167         timer.think = nade_timer_think;
 168         timer.nextthink = time;
 169         timer.wait = _nade.wait;
 170         timer.owner = _nade;
 171         timer.skin = 10;
 172
 173         _nade.effects |= EF_LOWPRECISION;
 174
 175         CSQCProjectile(_nade, true, Nades_from(_nade.nade_type).m_projectile[false], true);
 176 }
 177
 178 void napalm_damage(float dist, float damage, float edgedamage, float burntime)
 179 {SELFPARAM();
 180         entity e;
 181         float d;
 182         vector p;
 183
 184         if ( damage < 0 )
 185                 return;
 186
 187         RandomSelection_Init();
 188         for(e = WarpZone_FindRadius(self.origin, dist, true); e; e = e.chain)
 189                 if(e.takedamage == DAMAGE_AIM)
 190                 if(self.realowner != e || autocvar_g_nades_napalm_selfdamage)
 191                 if(!IS_PLAYER(e) || !self.realowner || DIFF_TEAM(e, self))
 192                 if(!STAT(FROZEN, e))
 193                 {
 194                         p = e.origin;
 195                         p.x += e.mins.x + random() * (e.maxs.x - e.mins.x);
 196                         p.y += e.mins.y + random() * (e.maxs.y - e.mins.y);
 197                         p.z += e.mins.z + random() * (e.maxs.z - e.mins.z);
 198                         d = vlen(WarpZone_UnTransformOrigin(e, self.origin) - p);
 199                         if(d < dist)
 200                         {
 201                                 e.fireball_impactvec = p;
 202                                 RandomSelection_Add(e, 0, string_null, 1 / (1 + d), !Fire_IsBurning(e));
 203                         }
 204                 }
 205         if(RandomSelection_chosen_ent)
 206         {
 207                 d = vlen(WarpZone_UnTransformOrigin(RandomSelection_chosen_ent, self.origin) - RandomSelection_chosen_ent.fireball_impactvec);
 208                 d = damage + (edgedamage - damage) * (d / dist);
 209                 Fire_AddDamage(RandomSelection_chosen_ent, self.realowner, d * burntime, burntime, self.projectiledeathtype | HITTYPE_BOUNCE);
 210                 //trailparticles(self, particleeffectnum(EFFECT_FIREBALL_LASER), self.origin, RandomSelection_chosen_ent.fireball_impactvec);
 211                 Send_Effect(EFFECT_FIREBALL_LASER, self.origin, RandomSelection_chosen_ent.fireball_impactvec - self.origin, 1);
 212         }
 213 }
 214
 215
 216 void napalm_ball_think()
 217 {SELFPARAM();
 218         if(round_handler_IsActive())
 219         if(!round_handler_IsRoundStarted())
 220         {
 221                 remove(self);
 222                 return;
 223         }
 224
 225         if(time > self.pushltime)
 226         {
 227                 remove(self);
 228                 return;
 229         }
 230
 231         vector midpoint = ((self.absmin + self.absmax) * 0.5);
 232         if(pointcontents(midpoint) == CONTENT_WATER)
 233         {
 234                 self.velocity = self.velocity * 0.5;
 235
 236                 if(pointcontents(midpoint + '0 0 16') == CONTENT_WATER)
 237                         { self.velocity_z = 200; }
 238         }
 239
 240         self.angles = vectoangles(self.velocity);
 241
 242         napalm_damage(autocvar_g_nades_napalm_ball_radius,autocvar_g_nades_napalm_ball_damage,
 243                                   autocvar_g_nades_napalm_ball_damage,autocvar_g_nades_napalm_burntime);
 244
 245         self.nextthink = time + 0.1;
 246 }
 247
 248
 249 void nade_napalm_ball()
 250 {SELFPARAM();
 251         entity proj;
 252         vector kick;
 253
 254         spamsound(self, CH_SHOTS, SND(FIREBALL_FIRE), VOL_BASE, ATTEN_NORM);
 255
 256         proj = new(grenade);
 257         proj.owner = self.owner;
 258         proj.realowner = self.realowner;
 259         proj.team = self.owner.team;
 260         proj.bot_dodge = true;
 261         proj.bot_dodgerating = autocvar_g_nades_napalm_ball_damage;
 262         proj.movetype = MOVETYPE_BOUNCE;
 263         proj.projectiledeathtype = DEATH_NADE_NAPALM.m_id;
 264         PROJECTILE_MAKETRIGGER(proj);
 265         setmodel(proj, MDL_Null);
 266         proj.scale = 1;//0.5;
 267         setsize(proj, '-4 -4 -4', '4 4 4');
 268         setorigin(proj, self.origin);
 269         proj.think = napalm_ball_think;
 270         proj.nextthink = time;
 271         proj.damageforcescale = autocvar_g_nades_napalm_ball_damageforcescale;
 272         proj.effects = EF_LOWPRECISION | EF_FLAME;
 273
 274         kick.x =(random() - 0.5) * 2 * autocvar_g_nades_napalm_ball_spread;
 275         kick.y = (random() - 0.5) * 2 * autocvar_g_nades_napalm_ball_spread;
 276         kick.z = (random()/2+0.5) * autocvar_g_nades_napalm_ball_spread;
 277         proj.velocity = kick;
 278
 279         proj.pushltime = time + autocvar_g_nades_napalm_ball_lifetime;
 280
 281         proj.angles = vectoangles(proj.velocity);
 282         proj.flags = FL_PROJECTILE;
 283         proj.missile_flags = MIF_SPLASH | MIF_PROXY | MIF_ARC;
 284
 285         //CSQCProjectile(proj, true, PROJECTILE_NAPALM_FIRE, true);
 286 }
 287
 288
 289 void napalm_fountain_think()
 290 {SELFPARAM();
 291
 292         if(round_handler_IsActive())
 293         if(!round_handler_IsRoundStarted())
 294         {
 295                 remove(self);
 296                 return;
 297         }
 298
 299         if(time >= self.ltime)
 300         {
 301                 remove(self);
 302                 return;
 303         }
 304
 305         vector midpoint = ((self.absmin + self.absmax) * 0.5);
 306         if(pointcontents(midpoint) == CONTENT_WATER)
 307         {
 308                 self.velocity = self.velocity * 0.5;
 309
 310                 if(pointcontents(midpoint + '0 0 16') == CONTENT_WATER)
 311                         { self.velocity_z = 200; }
 312
 313                 UpdateCSQCProjectile(self);
 314         }
 315
 316         napalm_damage(autocvar_g_nades_napalm_fountain_radius, autocvar_g_nades_napalm_fountain_damage,
 317                 autocvar_g_nades_napalm_fountain_edgedamage, autocvar_g_nades_napalm_burntime);
 318
 319         self.nextthink = time + 0.1;
 320         if(time >= self.nade_special_time)
 321         {
 322                 self.nade_special_time = time + autocvar_g_nades_napalm_fountain_delay;
 323                 nade_napalm_ball();
 324         }
 325 }
 326
 327 void nade_napalm_boom()
 328 {SELFPARAM();
 329         entity fountain;
 330         int c;
 331         for (c = 0; c < autocvar_g_nades_napalm_ball_count; c++)
 332                 nade_napalm_ball();
 333
 334
 335         fountain = spawn();
 336         fountain.owner = self.owner;
 337         fountain.realowner = self.realowner;
 338         fountain.origin = self.origin;
 339         setorigin(fountain, fountain.origin);
 340         fountain.think = napalm_fountain_think;
 341         fountain.nextthink = time;
 342         fountain.ltime = time + autocvar_g_nades_napalm_fountain_lifetime;
 343         fountain.pushltime = fountain.ltime;
 344         fountain.team = self.team;
 345         fountain.movetype = MOVETYPE_TOSS;
 346         fountain.projectiledeathtype = DEATH_NADE_NAPALM.m_id;
 347         fountain.bot_dodge = true;
 348         fountain.bot_dodgerating = autocvar_g_nades_napalm_fountain_damage;
 349         fountain.nade_special_time = time;
 350         setsize(fountain, '-16 -16 -16', '16 16 16');
 351         CSQCProjectile(fountain, true, PROJECTILE_NAPALM_FOUNTAIN, true);
 352 }
 353
 354 void nade_ice_freeze(entity freezefield, entity frost_target, float freeze_time)
 355 {
 356         frost_target.frozen_by = freezefield.realowner;
 357         Send_Effect(EFFECT_ELECTRO_IMPACT, frost_target.origin, '0 0 0', 1);
 358         Freeze(frost_target, 1/freeze_time, 3, false);
 359
 360         Drop_Special_Items(frost_target);
 361 }
 362
 363 void nade_ice_think()
 364 {SELFPARAM();
 365
 366         if(round_handler_IsActive())
 367         if(!round_handler_IsRoundStarted())
 368         {
 369                 remove(self);
 370                 return;
 371         }
 372
 373         if(time >= self.ltime)
 374         {
 375                 if ( autocvar_g_nades_ice_explode )
 376                 {
 377                         entity expef = EFFECT_NADE_EXPLODE(self.realowner.team);
 378                         Send_Effect(expef, self.origin + '0 0 1', '0 0 0', 1);
 379                         sound(self, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 380
 381                         RadiusDamage(self, self.realowner, autocvar_g_nades_nade_damage, autocvar_g_nades_nade_edgedamage,
 382                                 autocvar_g_nades_nade_radius, self, world, autocvar_g_nades_nade_force, self.projectiledeathtype, self.enemy);
 383                         Damage_DamageInfo(self.origin, autocvar_g_nades_nade_damage, autocvar_g_nades_nade_edgedamage,
 384                                 autocvar_g_nades_nade_radius, '1 1 1' * autocvar_g_nades_nade_force, self.projectiledeathtype, 0, self);
 385                 }
 386                 remove(self);
 387                 return;
 388         }
 389
 390
 391         self.nextthink = time+0.1;
 392
 393         // gaussian
 394         float randomr;
 395         randomr = random();
 396         randomr = exp(-5*randomr*randomr)*autocvar_g_nades_nade_radius;
 397         float randomw;
 398         randomw = random()*M_PI*2;
 399         vector randomp;
 400         randomp.x = randomr*cos(randomw);
 401         randomp.y = randomr*sin(randomw);
 402         randomp.z = 1;
 403         Send_Effect(EFFECT_ELECTRO_MUZZLEFLASH, self.origin + randomp, '0 0 0', 1);
 404
 405         if(time >= self.nade_special_time)
 406         {
 407                 self.nade_special_time = time+0.7;
 408
 409                 Send_Effect(EFFECT_ELECTRO_IMPACT, self.origin, '0 0 0', 1);
 410                 Send_Effect(EFFECT_ICEFIELD, self.origin, '0 0 0', 1);
 411         }
 412
 413
 414         float current_freeze_time = self.ltime - time - 0.1;
 415
 416         entity e;
 417         for(e = findradius(self.origin, autocvar_g_nades_nade_radius); e; e = e.chain)
 418         if(e != self)
 419         if(!autocvar_g_nades_ice_teamcheck || (DIFF_TEAM(e, self.realowner) || e == self.realowner))
 420         if(e.takedamage && !IS_DEAD(e))
 421         if(e.health > 0)
 422         if(!e.revival_time || ((time - e.revival_time) >= 1.5))
 423         if(!STAT(FROZEN, e))
 424         if(current_freeze_time > 0)
 425                 nade_ice_freeze(self, e, current_freeze_time);
 426 }
 427
 428 void nade_ice_boom()
 429 {SELFPARAM();
 430         entity fountain;
 431         fountain = spawn();
 432         fountain.owner = self.owner;
 433         fountain.realowner = self.realowner;
 434         fountain.origin = self.origin;
 435         setorigin(fountain, fountain.origin);
 436         fountain.think = nade_ice_think;
 437         fountain.nextthink = time;
 438         fountain.ltime = time + autocvar_g_nades_ice_freeze_time;
 439         fountain.pushltime = fountain.wait = fountain.ltime;
 440         fountain.team = self.team;
 441         fountain.movetype = MOVETYPE_TOSS;
 442         fountain.projectiledeathtype = DEATH_NADE_ICE.m_id;
 443         fountain.bot_dodge = false;
 444         setsize(fountain, '-16 -16 -16', '16 16 16');
 445         fountain.nade_special_time = time+0.3;
 446         fountain.angles = self.angles;
 447
 448         if ( autocvar_g_nades_ice_explode )
 449         {
 450                 setmodel(fountain, MDL_PROJECTILE_GRENADE);
 451                 entity timer = new(nade_timer);
 452                 setmodel(timer, MDL_NADE_TIMER);
 453                 setattachment(timer, fountain, "");
 454                 timer.colormap = self.colormap;
 455                 timer.glowmod = self.glowmod;
 456                 timer.think = nade_timer_think;
 457                 timer.nextthink = time;
 458                 timer.wait = fountain.ltime;
 459                 timer.owner = fountain;
 460                 timer.skin = 10;
 461         }
 462         else
 463                 setmodel(fountain, MDL_Null);
 464 }
 465
 466 void nade_translocate_boom()
 467 {SELFPARAM();
 468         if(self.realowner.vehicle)
 469                 return;
 470
 471         vector locout = self.origin + '0 0 1' * (1 - self.realowner.mins.z - 24);
 472         tracebox(locout, self.realowner.mins, self.realowner.maxs, locout, MOVE_NOMONSTERS, self.realowner);
 473         locout = trace_endpos;
 474
 475         makevectors(self.realowner.angles);
 476
 477         MUTATOR_CALLHOOK(PortalTeleport, self.realowner);
 478
 479         TeleportPlayer(self, self.realowner, locout, self.realowner.angles, v_forward * vlen(self.realowner.velocity), '0 0 0', '0 0 0', TELEPORT_FLAGS_TELEPORTER);
 480 }
 481
 482 void nade_spawn_boom()
 483 {SELFPARAM();
 484         entity spawnloc = spawn();
 485         setorigin(spawnloc, self.origin);
 486         setsize(spawnloc, self.realowner.mins, self.realowner.maxs);
 487         spawnloc.movetype = MOVETYPE_NONE;
 488         spawnloc.solid = SOLID_NOT;
 489         spawnloc.drawonlytoclient = self.realowner;
 490         spawnloc.effects = EF_STARDUST;
 491         spawnloc.cnt = autocvar_g_nades_spawn_count;
 492
 493         if(self.realowner.nade_spawnloc)
 494         {
 495                 remove(self.realowner.nade_spawnloc);
 496                 self.realowner.nade_spawnloc = world;
 497         }
 498
 499         self.realowner.nade_spawnloc = spawnloc;
 500 }
 501
 502 void nade_heal_think()
 503 {SELFPARAM();
 504         if(time >= self.ltime)
 505         {
 506                 remove(self);
 507                 return;
 508         }
 509
 510         self.nextthink = time;
 511
 512         if(time >= self.nade_special_time)
 513         {
 514                 self.nade_special_time = time+0.25;
 515                 self.nade_show_particles = 1;
 516         }
 517         else
 518                 self.nade_show_particles = 0;
 519 }
 520
 521 void nade_heal_touch()
 522 {SELFPARAM();
 523         float maxhealth;
 524         float health_factor;
 525         if(IS_PLAYER(other) || IS_MONSTER(other))
 526         if(!IS_DEAD(other))
 527         if(!STAT(FROZEN, other))
 528         {
 529                 health_factor = autocvar_g_nades_heal_rate*frametime/2;
 530                 if ( other != self.realowner )
 531                 {
 532                         if ( SAME_TEAM(other,self) )
 533                                 health_factor *= autocvar_g_nades_heal_friend;
 534                         else
 535                                 health_factor *= autocvar_g_nades_heal_foe;
 536                 }
 537                 if ( health_factor > 0 )
 538                 {
 539                         maxhealth = (IS_MONSTER(other)) ? other.max_health : g_pickup_healthmega_max;
 540                         if ( other.health < maxhealth )
 541                         {
 542                                 if ( self.nade_show_particles )
 543                                         Send_Effect(EFFECT_HEALING, other.origin, '0 0 0', 1);
 544                                 other.health = min(other.health+health_factor, maxhealth);
 545                         }
 546                         other.pauserothealth_finished = max(other.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 547                 }
 548                 else if ( health_factor < 0 )
 549                 {
 550                         Damage(other,self,self.realowner,-health_factor,DEATH_NADE_HEAL.m_id,other.origin,'0 0 0');
 551                 }
 552
 553         }
 554
 555         if ( IS_REAL_CLIENT(other) || IS_VEHICLE(other) )
 556         {
 557                 entity show_red = (IS_VEHICLE(other)) ? other.owner : other;
 558                 show_red.stat_healing_orb = time+0.1;
 559                 show_red.stat_healing_orb_alpha = 0.75 * (self.ltime - time) / self.healer_lifetime;
 560         }
 561 }
 562
 563 void nade_heal_boom()
 564 {SELFPARAM();
 565         entity healer;
 566         healer = spawn();
 567         healer.owner = self.owner;
 568         healer.realowner = self.realowner;
 569         setorigin(healer, self.origin);
 570         healer.healer_lifetime = autocvar_g_nades_heal_time; // save the cvar
 571         healer.ltime = time + healer.healer_lifetime;
 572         healer.team = self.realowner.team;
 573         healer.bot_dodge = false;
 574         healer.solid = SOLID_TRIGGER;
 575         healer.touch = nade_heal_touch;
 576
 577         setmodel(healer, MDL_NADE_HEAL);
 578         healer.healer_radius = autocvar_g_nades_nade_radius;
 579         vector size = '1 1 1' * healer.healer_radius / 2;
 580         setsize(healer,-size,size);
 581
 582         Net_LinkEntity(healer, true, 0, healer_send);
 583
 584         healer.think = nade_heal_think;
 585         healer.nextthink = time;
 586         healer.SendFlags |= 1;
 587 }
 588
 589 void nade_monster_boom()
 590 {SELFPARAM();
 591         entity e = spawnmonster(self.pokenade_type, 0, self.realowner, self.realowner, self.origin, false, false, 1);
 592
 593         if(autocvar_g_nades_pokenade_monster_lifetime > 0)
 594                 e.monster_lifetime = time + autocvar_g_nades_pokenade_monster_lifetime;
 595         e.monster_skill = MONSTER_SKILL_INSANE;
 596 }
 597
 598 void nade_boom()
 599 {SELFPARAM();
 600         entity expef = NULL;
 601         bool nade_blast = true;
 602
 603         switch ( Nades_from(self.nade_type) )
 604         {
 605                 case NADE_TYPE_NAPALM:
 606                         nade_blast = autocvar_g_nades_napalm_blast;
 607                         expef = EFFECT_EXPLOSION_MEDIUM;
 608                         break;
 609                 case NADE_TYPE_ICE:
 610                         nade_blast = false;
 611                         expef = EFFECT_ELECTRO_COMBO; // hookbomb_explode electro_combo bigplasma_impact
 612                         break;
 613                 case NADE_TYPE_TRANSLOCATE:
 614                         nade_blast = false;
 615                         break;
 616                 case NADE_TYPE_MONSTER:
 617                 case NADE_TYPE_SPAWN:
 618                         nade_blast = false;
 619                         switch(self.realowner.team)
 620                         {
 621                                 case NUM_TEAM_1: expef = EFFECT_SPAWN_RED; break;
 622                                 case NUM_TEAM_2: expef = EFFECT_SPAWN_BLUE; break;
 623                                 case NUM_TEAM_3: expef = EFFECT_SPAWN_YELLOW; break;
 624                                 case NUM_TEAM_4: expef = EFFECT_SPAWN_PINK; break;
 625                                 default: expef = EFFECT_SPAWN_NEUTRAL; break;
 626                         }
 627                         break;
 628                 case NADE_TYPE_HEAL:
 629                         nade_blast = false;
 630                         expef = EFFECT_SPAWN_RED;
 631                         break;
 632
 633                 default:
 634                 case NADE_TYPE_NORMAL:
 635                         expef = EFFECT_NADE_EXPLODE(self.realowner.team);
 636                         break;
 637         }
 638
 639         if(expef)
 640                 Send_Effect(expef, findbetterlocation(self.origin, 8), '0 0 0', 1);
 641
 642         sound(self, CH_SHOTS_SINGLE, SND_Null, VOL_BASE, ATTEN_NORM);
 643         sound(self, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 644
 645         self.event_damage = func_null; // prevent somehow calling damage in the next call
 646
 647         if(nade_blast)
 648         {
 649                 RadiusDamage(self, self.realowner, autocvar_g_nades_nade_damage, autocvar_g_nades_nade_edgedamage,
 650                                  autocvar_g_nades_nade_radius, self, world, autocvar_g_nades_nade_force, self.projectiledeathtype, self.enemy);
 651                 Damage_DamageInfo(self.origin, autocvar_g_nades_nade_damage, autocvar_g_nades_nade_edgedamage, autocvar_g_nades_nade_radius, '1 1 1' * autocvar_g_nades_nade_force, self.projectiledeathtype, 0, self);
 652         }
 653
 654         if(self.takedamage)
 655         switch ( Nades_from(self.nade_type) )
 656         {
 657                 case NADE_TYPE_NAPALM: nade_napalm_boom(); break;
 658                 case NADE_TYPE_ICE: nade_ice_boom(); break;
 659                 case NADE_TYPE_TRANSLOCATE: nade_translocate_boom(); break;
 660                 case NADE_TYPE_SPAWN: nade_spawn_boom(); break;
 661                 case NADE_TYPE_HEAL: nade_heal_boom(); break;
 662                 case NADE_TYPE_MONSTER: nade_monster_boom(); break;
 663         }
 664
 665         FOREACH_ENTITY_ENT(aiment, self,
 666         {
 667                 if(it.classname == "grapplinghook")
 668                         RemoveGrapplingHook(it.realowner);
 669         });
 670
 671         remove(self);
 672 }
 673
 674 void nade_touch()
 675 {SELFPARAM();
 676         if(other)
 677                 UpdateCSQCProjectile(self);
 678
 679         if(other == self.realowner)
 680                 return; // no self impacts
 681         /*float is_weapclip = 0;
 682         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NODRAW)
 683         if (!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NONSOLID))
 684         if (!(trace_dphitcontents & DPCONTENTS_OPAQUE))
 685                 is_weapclip = 1;*/
 686         if(ITEM_TOUCH_NEEDKILL()) // || is_weapclip)
 687         {
 688                 FOREACH_ENTITY_ENT(aiment, self,
 689                 {
 690                         if(it.classname == "grapplinghook")
 691                                 RemoveGrapplingHook(it.realowner);
 692                 });
 693                 remove(self);
 694                 return;
 695         }
 696
 697         PROJECTILE_TOUCH;
 698
 699         //setsize(self, '-2 -2 -2', '2 2 2');
 700         //UpdateCSQCProjectile(self);
 701         if(self.health == self.max_health)
 702         {
 703                 spamsound(self, CH_SHOTS, SND(GRENADE_BOUNCE_RANDOM()), VOL_BASE, ATTEN_NORM);
 704                 return;
 705         }
 706
 707         self.enemy = other;
 708         nade_boom();
 709 }
 710
 711 void nade_beep()
 712 {SELFPARAM();
 713         sound(self, CH_SHOTS_SINGLE, SND_NADE_BEEP, VOL_BASE, 0.5 *(ATTEN_LARGE + ATTEN_MAX));
 714         self.think = nade_boom;
 715         self.nextthink = max(self.wait, time);
 716 }
 717
 718 void nade_damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 719 {
 720         if(ITEM_DAMAGE_NEEDKILL(deathtype))
 721         {
 722                 this.takedamage = DAMAGE_NO;
 723                 WITH(entity, self, this, nade_boom());
 724                 return;
 725         }
 726
 727         if(this.nade_type == NADE_TYPE_TRANSLOCATE.m_id || this.nade_type == NADE_TYPE_SPAWN.m_id)
 728                 return;
 729
 730         if (MUTATOR_CALLHOOK(Nade_Damage, DEATH_WEAPONOF(deathtype), force, damage)) {}
 731         else if(DEATH_ISWEAPON(deathtype, WEP_BLASTER))
 732         {
 733                 force *= 1.5;
 734                 damage = 0;
 735         }
 736         else if(DEATH_ISWEAPON(deathtype, WEP_VAPORIZER) && (deathtype & HITTYPE_SECONDARY))
 737         {
 738                 force *= 0.5; // too much
 739                 damage = 0;
 740         }
 741         else if(DEATH_ISWEAPON(deathtype, WEP_VORTEX) || DEATH_ISWEAPON(deathtype, WEP_VAPORIZER))
 742         {
 743                 force *= 6;
 744                 damage = this.max_health * 0.55;
 745         }
 746         else if(DEATH_ISWEAPON(deathtype, WEP_MACHINEGUN))
 747                 damage = this.max_health * 0.1;
 748         else if(DEATH_ISWEAPON(deathtype, WEP_SHOCKWAVE) || DEATH_ISWEAPON(deathtype, WEP_SHOTGUN)) // WEAPONTODO
 749         {
 750                 if(deathtype & HITTYPE_SECONDARY)
 751                 {
 752                         damage = this.max_health * 0.1;
 753                         force *= 10;
 754                 }
 755                 else
 756                         damage = this.max_health * 1.15;
 757         }
 758
 759         this.velocity += force;
 760         UpdateCSQCProjectile(this);
 761
 762         if(damage <= 0 || ((IS_ONGROUND(this)) && IS_PLAYER(attacker)))
 763                 return;
 764
 765         if(this.health == this.max_health)
 766         {
 767                 sound(this, CH_SHOTS_SINGLE, SND_Null, VOL_BASE, 0.5 *(ATTEN_LARGE + ATTEN_MAX));
 768                 this.nextthink = max(time + autocvar_g_nades_nade_lifetime, time);
 769                 this.think = nade_beep;
 770         }
 771
 772         this.health -= damage;
 773
 774         if ( this.nade_type != NADE_TYPE_HEAL.m_id || IS_PLAYER(attacker) )
 775                 this.realowner = attacker;
 776
 777         if(this.health <= 0)
 778                 WITH(entity, self, this, W_PrepareExplosionByDamage(attacker, nade_boom));
 779         else
 780                 nade_burn_spawn(this);
 781 }
 782
 783 void toss_nade(entity e, vector _velocity, float _time)
 784 {SELFPARAM();
 785         if(e.nade == world)
 786                 return;
 787
 788         entity _nade = e.nade;
 789         e.nade = world;
 790
 791         remove(e.fake_nade);
 792         e.fake_nade = world;
 793
 794         makevectors(e.v_angle);
 795
 796         W_SetupShot(e, false, false, "", CH_WEAPON_A, 0);
 797
 798         Kill_Notification(NOTIF_ONE_ONLY, e, MSG_CENTER_CPID, CPID_NADES);
 799
 800         vector offset = (v_forward * autocvar_g_nades_throw_offset.x)
 801                                   + (v_right * autocvar_g_nades_throw_offset.y)
 802                                   + (v_up * autocvar_g_nades_throw_offset.z);
 803         if(autocvar_g_nades_throw_offset == '0 0 0')
 804                 offset = '0 0 0';
 805
 806         setorigin(_nade, w_shotorg + offset + (v_right * 25) * -1);
 807         //setmodel(_nade, MDL_PROJECTILE_NADE);
 808         //setattachment(_nade, world, "");
 809         PROJECTILE_MAKETRIGGER(_nade);
 810         if(STAT(NADES_SMALL, e))
 811                 setsize(_nade, '-8 -8 -8', '8 8 8');
 812         else
 813                 setsize(_nade, '-16 -16 -16', '16 16 16');
 814         _nade.movetype = MOVETYPE_BOUNCE;
 815
 816         tracebox(_nade.origin, _nade.mins, _nade.maxs, _nade.origin, false, _nade);
 817         if (trace_startsolid)
 818                 setorigin(_nade, e.origin);
 819
 820         if(self.v_angle.x >= 70 && self.v_angle.x <= 110 && self.BUTTON_CROUCH)
 821                 _nade.velocity = '0 0 100';
 822         else if(autocvar_g_nades_nade_newton_style == 1)
 823                 _nade.velocity = e.velocity + _velocity;
 824         else if(autocvar_g_nades_nade_newton_style == 2)
 825                 _nade.velocity = _velocity;
 826         else
 827                 _nade.velocity = W_CalculateProjectileVelocity(e.velocity, _velocity, true);
 828
 829         _nade.touch = nade_touch;
 830         _nade.health = autocvar_g_nades_nade_health;
 831         _nade.max_health = _nade.health;
 832         _nade.takedamage = DAMAGE_AIM;
 833         _nade.event_damage = nade_damage;
 834         _nade.customizeentityforclient = func_null;
 835         _nade.exteriormodeltoclient = world;
 836         _nade.traileffectnum = 0;
 837         _nade.teleportable = true;
 838         _nade.pushable = true;
 839         _nade.gravity = 1;
 840         _nade.missile_flags = MIF_SPLASH | MIF_ARC;
 841         _nade.damagedbycontents = true;
 842         _nade.angles = vectoangles(_nade.velocity);
 843         _nade.flags = FL_PROJECTILE;
 844         _nade.projectiledeathtype = DEATH_NADE.m_id;
 845         _nade.toss_time = time;
 846         _nade.solid = SOLID_CORPSE; //((_nade.nade_type == NADE_TYPE_TRANSLOCATE) ? SOLID_CORPSE : SOLID_BBOX);
 847
 848         if(_nade.nade_type == NADE_TYPE_TRANSLOCATE.m_id || _nade.nade_type == NADE_TYPE_SPAWN.m_id)
 849                 _nade.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 850         else
 851                 _nade.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY;
 852
 853         nade_spawn(_nade);
 854
 855         if(_time)
 856         {
 857                 _nade.think = nade_boom;
 858                 _nade.nextthink = _time;
 859         }
 860
 861         e.nade_refire = time + autocvar_g_nades_nade_refire;
 862         e.nade_timer = 0;
 863 }
 864
 865 void nades_GiveBonus(entity player, float score)
 866 {
 867         if (autocvar_g_nades)
 868         if (autocvar_g_nades_bonus)
 869         if (IS_REAL_CLIENT(player))
 870         if (IS_PLAYER(player) && player.bonus_nades < autocvar_g_nades_bonus_max)
 871         if (STAT(FROZEN, player) == 0)
 872         if (!IS_DEAD(player))
 873         {
 874                 if ( player.bonus_nade_score < 1 )
 875                         player.bonus_nade_score += score/autocvar_g_nades_bonus_score_max;
 876
 877                 if ( player.bonus_nade_score >= 1 )
 878                 {
 879                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_NADE_BONUS);
 880                         play2(player, SND(KH_ALARM));
 881                         player.bonus_nades++;
 882                         player.bonus_nade_score -= 1;
 883                 }
 884         }
 885 }
 886
 887 /** Remove all bonus nades from a player */
 888 void nades_RemoveBonus(entity player)
 889 {
 890         player.bonus_nades = player.bonus_nade_score = 0;
 891 }
 892
 893 MUTATOR_HOOKFUNCTION(nades, PutClientInServer)
 894 {
 895         nades_RemoveBonus(self);
 896 }
 897
 898 float nade_customize()
 899 {SELFPARAM();
 900         //if(IS_SPEC(other)) { return false; }
 901         if(other == self.realowner || (IS_SPEC(other) && other.enemy == self.realowner))
 902         {
 903                 // somewhat hide the model, but keep the glow
 904                 //self.effects = 0;
 905                 if(self.traileffectnum)
 906                         self.traileffectnum = 0;
 907                 self.alpha = -1;
 908         }
 909         else
 910         {
 911                 //self.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 912                 if(!self.traileffectnum)
 913                         self.traileffectnum = _particleeffectnum(Nade_TrailEffect(Nades_from(self.nade_type).m_projectile[false], self.team).eent_eff_name);
 914                 self.alpha = 1;
 915         }
 916
 917         return true;
 918 }
 919
 920 void nade_prime()
 921 {SELFPARAM();
 922         if(autocvar_g_nades_bonus_only)
 923         if(!self.bonus_nades)
 924                 return; // only allow bonus nades
 925
 926         if(self.nade)
 927                 remove(self.nade);
 928
 929         if(self.fake_nade)
 930                 remove(self.fake_nade);
 931
 932         entity n = new(nade), fn = new(fake_nade);
 933
 934         if(self.items & ITEM_Strength.m_itemid && autocvar_g_nades_bonus_onstrength)
 935                 n.nade_type = self.nade_type;
 936         else if (self.bonus_nades >= 1)
 937         {
 938                 n.nade_type = self.nade_type;
 939                 n.pokenade_type = self.pokenade_type;
 940                 self.bonus_nades -= 1;
 941         }
 942         else
 943         {
 944                 n.nade_type = ((autocvar_g_nades_client_select) ? self.cvar_cl_nade_type : autocvar_g_nades_nade_type);
 945                 n.pokenade_type = ((autocvar_g_nades_client_select) ? self.cvar_cl_pokenade_type : autocvar_g_nades_pokenade_monster_type);
 946         }
 947
 948         n.nade_type = bound(1, n.nade_type, Nades_COUNT);
 949
 950         setmodel(n, MDL_PROJECTILE_NADE);
 951         //setattachment(n, self, "bip01 l hand");
 952         n.exteriormodeltoclient = self;
 953         n.customizeentityforclient = nade_customize;
 954         n.traileffectnum = _particleeffectnum(Nade_TrailEffect(Nades_from(n.nade_type).m_projectile[false], self.team).eent_eff_name);
 955         n.colormod = Nades_from(n.nade_type).m_color;
 956         n.realowner = self;
 957         n.colormap = self.colormap;
 958         n.glowmod = self.glowmod;
 959         n.wait = time + autocvar_g_nades_nade_lifetime;
 960         n.nade_time_primed = time;
 961         n.think = nade_beep;
 962         n.nextthink = max(n.wait - 3, time);
 963         n.projectiledeathtype = DEATH_NADE.m_id;
 964
 965         setmodel(fn, MDL_NADE_VIEW);
 966         .entity weaponentity = weaponentities[0]; // TODO: unhardcode
 967         setattachment(fn, self.(weaponentity), "");
 968         fn.realowner = fn.owner = self;
 969         fn.colormod = Nades_from(n.nade_type).m_color;
 970         fn.colormap = self.colormap;
 971         fn.glowmod = self.glowmod;
 972         fn.think = SUB_Remove_self;
 973         fn.nextthink = n.wait;
 974
 975         self.nade = n;
 976         self.fake_nade = fn;
 977 }
 978
 979 float CanThrowNade()
 980 {SELFPARAM();
 981         if(self.vehicle)
 982                 return false;
 983
 984         if(gameover)
 985                 return false;
 986
 987         if(IS_DEAD(self))
 988                 return false;
 989
 990         if (!autocvar_g_nades)
 991                 return false; // allow turning them off mid match
 992
 993         if(forbidWeaponUse(self))
 994                 return false;
 995
 996         if (!IS_PLAYER(self))
 997                 return false;
 998
 999         return true;
1000 }
1001
1002 .bool nade_altbutton;
1003
1004 void nades_CheckThrow()
1005 {SELFPARAM();
1006         if(!CanThrowNade())
1007                 return;
1008
1009         entity held_nade = self.nade;
1010         if (!held_nade)
1011         {
1012                 self.nade_altbutton = true;
1013                 if(time > self.nade_refire)
1014                 {
1015                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_NADE_THROW);
1016                         nade_prime();
1017                         self.nade_refire = time + autocvar_g_nades_nade_refire;
1018                 }
1019         }
1020         else
1021         {
1022                 self.nade_altbutton = false;
1023                 if (time >= held_nade.nade_time_primed + 1) {
1024                         makevectors(self.v_angle);
1025                         float _force = time - held_nade.nade_time_primed;
1026                         _force /= autocvar_g_nades_nade_lifetime;
1027                         _force = autocvar_g_nades_nade_minforce + (_force * (autocvar_g_nades_nade_maxforce - autocvar_g_nades_nade_minforce));
1028                         toss_nade(self, (v_forward * 0.75 + v_up * 0.2 + v_right * 0.05) * _force, 0);
1029                 }
1030         }
1031 }
1032
1033 void nades_Clear(entity player)
1034 {
1035         if(player.nade)
1036                 remove(player.nade);
1037         if(player.fake_nade)
1038                 remove(player.fake_nade);
1039
1040         player.nade = player.fake_nade = world;
1041         player.nade_timer = 0;
1042 }
1043
1044 MUTATOR_HOOKFUNCTION(nades, VehicleEnter)
1045 {
1046         if(vh_player.nade)
1047                 toss_nade(vh_player, '0 0 100', max(vh_player.nade.wait, time + 0.05));
1048
1049         return false;
1050 }
1051
1052 CLASS(NadeOffhand, OffhandWeapon)
1053     METHOD(NadeOffhand, offhand_think, void(NadeOffhand this, entity player, bool key_pressed))
1054     {
1055         entity held_nade = player.nade;
1056                 if (held_nade)
1057                 {
1058                         player.nade_timer = bound(0, (time - held_nade.nade_time_primed) / autocvar_g_nades_nade_lifetime, 1);
1059                         // LOG_TRACEF("%d %d\n", player.nade_timer, time - held_nade.nade_time_primed);
1060                         makevectors(player.angles);
1061                         held_nade.velocity = player.velocity;
1062                         setorigin(held_nade, player.origin + player.view_ofs + v_forward * 8 + v_right * -8 + v_up * 0);
1063                         held_nade.angles_y = player.angles.y;
1064
1065                         if (time + 0.1 >= held_nade.wait)
1066                                 toss_nade(player, '0 0 0', time + 0.05);
1067                 }
1068
1069         if (!CanThrowNade()) return;
1070         if (!(time > player.nade_refire)) return;
1071                 if (key_pressed) {
1072                         if (!held_nade) {
1073                                 nade_prime();
1074                                 held_nade = player.nade;
1075                         }
1076                 } else if (time >= held_nade.nade_time_primed + 1) {
1077                         if (held_nade) {
1078                                 makevectors(player.v_angle);
1079                                 float _force = time - held_nade.nade_time_primed;
1080                                 _force /= autocvar_g_nades_nade_lifetime;
1081                                 _force = autocvar_g_nades_nade_minforce + (_force * (autocvar_g_nades_nade_maxforce - autocvar_g_nades_nade_minforce));
1082                                 toss_nade(player, (v_forward * 0.7 + v_up * 0.2 + v_right * 0.1) * _force, 0);
1083                         }
1084                 }
1085     }
1086 ENDCLASS(NadeOffhand)
1087 NadeOffhand OFFHAND_NADE; STATIC_INIT(OFFHAND_NADE) { OFFHAND_NADE = NEW(NadeOffhand); }
1088
1089 MUTATOR_HOOKFUNCTION(nades, ForbidThrowCurrentWeapon, CBC_ORDER_LAST)
1090 {
1091         if (self.offhand != OFFHAND_NADE || (self.weapons & WEPSET(HOOK)) || autocvar_g_nades_override_dropweapon) {
1092                 nades_CheckThrow();
1093                 return true;
1094         }
1095         return false;
1096 }
1097
1098 MUTATOR_HOOKFUNCTION(nades, PlayerPreThink)
1099 {SELFPARAM();
1100         if (!IS_PLAYER(self)) { return false; }
1101
1102         if (self.nade && (self.offhand != OFFHAND_NADE || (self.weapons & WEPSET(HOOK)))) OFFHAND_NADE.offhand_think(OFFHAND_NADE, self, self.nade_altbutton);
1103
1104         if(IS_PLAYER(self))
1105         {
1106                 if ( autocvar_g_nades_bonus && autocvar_g_nades )
1107                 {
1108                         entity key;
1109                         float key_count = 0;
1110                         FOR_EACH_KH_KEY(key) if(key.owner == self) { ++key_count; }
1111
1112                         float time_score;
1113                         if(self.flagcarried || self.ballcarried) // this player is important
1114                                 time_score = autocvar_g_nades_bonus_score_time_flagcarrier;
1115                         else
1116                                 time_score = autocvar_g_nades_bonus_score_time;
1117
1118                         if(key_count)
1119                                 time_score = autocvar_g_nades_bonus_score_time_flagcarrier * key_count; // multiply by the number of keys the player is holding
1120
1121                         if(autocvar_g_nades_bonus_client_select)
1122                         {
1123                                 self.nade_type = self.cvar_cl_nade_type;
1124                                 self.pokenade_type = self.cvar_cl_pokenade_type;
1125                         }
1126                         else
1127                         {
1128                                 self.nade_type = autocvar_g_nades_bonus_type;
1129                                 self.pokenade_type = autocvar_g_nades_pokenade_monster_type;
1130                         }
1131
1132                         self.nade_type = bound(1, self.nade_type, Nades_COUNT);
1133
1134                         if(self.bonus_nade_score >= 0 && autocvar_g_nades_bonus_score_max)
1135                                 nades_GiveBonus(self, time_score / autocvar_g_nades_bonus_score_max);
1136                 }
1137                 else
1138                 {
1139                         self.bonus_nades = self.bonus_nade_score = 0;
1140                 }
1141         }
1142
1143         float n = 0;
1144         entity o = world;
1145         if(self.freezetag_frozen_timeout > 0 && time >= self.freezetag_frozen_timeout)
1146                 n = -1;
1147         else
1148         {
1149                 vector revive_extra_size = '1 1 1' * autocvar_g_freezetag_revive_extra_size;
1150                 n = 0;
1151                 FOREACH_CLIENT(IS_PLAYER(it) && it != self, LAMBDA(
1152                         if(!IS_DEAD(it))
1153                         if(STAT(FROZEN, it) == 0)
1154                         if(SAME_TEAM(it, self))
1155                         if(boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, it.absmin, it.absmax))
1156                         {
1157                                 if(!o)
1158                                         o = it;
1159                                 if(STAT(FROZEN, self) == 1)
1160                                         it.reviving = true;
1161                                 ++n;
1162                         }
1163                 ));
1164         }
1165
1166         if(n && STAT(FROZEN, self) == 3) // OK, there is at least one teammate reviving us
1167         {
1168                 self.revive_progress = bound(0, self.revive_progress + frametime * max(1/60, autocvar_g_freezetag_revive_speed), 1);
1169                 self.health = max(1, self.revive_progress * start_health);
1170
1171                 if(self.revive_progress >= 1)
1172                 {
1173                         Unfreeze(self);
1174
1175                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_FREEZETAG_REVIVED, o.netname);
1176                         Send_Notification(NOTIF_ONE, o, MSG_CENTER, CENTER_FREEZETAG_REVIVE, self.netname);
1177                 }
1178
1179                 FOREACH_CLIENT(IS_PLAYER(it) && it.reviving, LAMBDA(
1180                         other.revive_progress = self.revive_progress;
1181                         other.reviving = false;
1182                 ));
1183         }
1184
1185         return false;
1186 }
1187
1188 MUTATOR_HOOKFUNCTION(nades, PlayerSpawn)
1189 {SELFPARAM();
1190         if(autocvar_g_nades_spawn)
1191                 self.nade_refire = time + autocvar_g_spawnshieldtime;
1192         else
1193                 self.nade_refire  = time + autocvar_g_nades_nade_refire;
1194
1195         if(autocvar_g_nades_bonus_client_select)
1196                 self.nade_type = self.cvar_cl_nade_type;
1197
1198         self.nade_timer = 0;
1199
1200         if (!self.offhand) self.offhand = OFFHAND_NADE;
1201
1202         if(self.nade_spawnloc)
1203         {
1204                 setorigin(self, self.nade_spawnloc.origin);
1205                 self.nade_spawnloc.cnt -= 1;
1206
1207                 if(self.nade_spawnloc.cnt <= 0)
1208                 {
1209                         remove(self.nade_spawnloc);
1210                         self.nade_spawnloc = world;
1211                 }
1212         }
1213
1214         return false;
1215 }
1216
1217 MUTATOR_HOOKFUNCTION(nades, PlayerDies, CBC_ORDER_LAST)
1218 {
1219         if(frag_target.nade)
1220         if(!STAT(FROZEN, frag_target) || !autocvar_g_freezetag_revive_nade)
1221                 toss_nade(frag_target, '0 0 100', max(frag_target.nade.wait, time + 0.05));
1222
1223         float killcount_bonus = ((frag_attacker.killcount >= 1) ? bound(0, autocvar_g_nades_bonus_score_minor * frag_attacker.killcount, autocvar_g_nades_bonus_score_medium) : autocvar_g_nades_bonus_score_minor);
1224
1225         if(IS_PLAYER(frag_attacker))
1226         {
1227                 if (SAME_TEAM(frag_attacker, frag_target) || frag_attacker == frag_target)
1228                         nades_RemoveBonus(frag_attacker);
1229                 else if(frag_target.flagcarried)
1230                         nades_GiveBonus(frag_attacker, autocvar_g_nades_bonus_score_medium);
1231                 else if(autocvar_g_nades_bonus_score_spree && frag_attacker.killcount > 1)
1232                 {
1233                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
1234                                 case counta: { nades_GiveBonus(frag_attacker, autocvar_g_nades_bonus_score_spree); break; }
1235                         switch(frag_attacker.killcount)
1236                         {
1237                                 KILL_SPREE_LIST
1238                                 default: nades_GiveBonus(frag_attacker, autocvar_g_nades_bonus_score_minor); break;
1239                         }
1240                         #undef SPREE_ITEM
1241                 }
1242                 else
1243                         nades_GiveBonus(frag_attacker, killcount_bonus);
1244         }
1245
1246         nades_RemoveBonus(frag_target);
1247
1248         return false;
1249 }
1250
1251 MUTATOR_HOOKFUNCTION(nades, PlayerDamage_Calculate)
1252 {
1253         if(STAT(FROZEN, frag_target))
1254         if(autocvar_g_freezetag_revive_nade)
1255         if(frag_attacker == frag_target)
1256         if(frag_deathtype == DEATH_NADE.m_id)
1257         if(time - frag_inflictor.toss_time <= 0.1)
1258         {
1259                 Unfreeze(frag_target);
1260                 frag_target.health = autocvar_g_freezetag_revive_nade_health;
1261                 Send_Effect(EFFECT_ICEORGLASS, frag_target.origin, '0 0 0', 3);
1262                 frag_damage = 0;
1263                 frag_force = '0 0 0';
1264                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_FREEZETAG_REVIVED_NADE, frag_target.netname);
1265                 Send_Notification(NOTIF_ONE, frag_target, MSG_CENTER, CENTER_FREEZETAG_REVIVE_SELF);
1266         }
1267
1268         return false;
1269 }
1270
1271 MUTATOR_HOOKFUNCTION(nades, MonsterDies)
1272 {
1273         if(IS_PLAYER(frag_attacker))
1274         if(DIFF_TEAM(frag_attacker, frag_target))
1275         if(!(frag_target.spawnflags & MONSTERFLAG_SPAWNED))
1276                 nades_GiveBonus(frag_attacker, autocvar_g_nades_bonus_score_minor);
1277
1278         return false;
1279 }
1280
1281 MUTATOR_HOOKFUNCTION(nades, DropSpecialItems)
1282 {
1283         if(frag_target.nade)
1284                 toss_nade(frag_target, '0 0 0', time + 0.05);
1285
1286         return false;
1287 }
1288
1289 bool nades_RemovePlayer()
1290 {SELFPARAM();
1291         nades_Clear(self);
1292         nades_RemoveBonus(self);
1293         return false;
1294 }
1295
1296 MUTATOR_HOOKFUNCTION(nades, MakePlayerObserver) { nades_RemovePlayer(); }
1297 MUTATOR_HOOKFUNCTION(nades, ClientDisconnect) { nades_RemovePlayer(); }
1298 MUTATOR_HOOKFUNCTION(nades, reset_map_global) { nades_RemovePlayer(); }
1299
1300 MUTATOR_HOOKFUNCTION(nades, SpectateCopy)
1301 {SELFPARAM();
1302         self.nade_timer = other.nade_timer;
1303         self.nade_type = other.nade_type;
1304         self.pokenade_type = other.pokenade_type;
1305         self.bonus_nades = other.bonus_nades;
1306         self.bonus_nade_score = other.bonus_nade_score;
1307         self.stat_healing_orb = other.stat_healing_orb;
1308         self.stat_healing_orb_alpha = other.stat_healing_orb_alpha;
1309         return false;
1310 }
1311
1312 MUTATOR_HOOKFUNCTION(nades, GetCvars)
1313 {
1314         GetCvars_handleFloat(get_cvars_s, get_cvars_f, cvar_cl_nade_type, "cl_nade_type");
1315         GetCvars_handleString(get_cvars_s, get_cvars_f, cvar_cl_pokenade_type, "cl_pokenade_type");
1316
1317         return false;
1318 }
1319
1320 MUTATOR_HOOKFUNCTION(nades, BuildMutatorsString)
1321 {
1322         ret_string = strcat(ret_string, ":Nades");
1323         return false;
1324 }
1325
1326 MUTATOR_HOOKFUNCTION(nades, BuildMutatorsPrettyString)
1327 {
1328         ret_string = strcat(ret_string, ", Nades");
1329         return false;
1330 }
1331
1332 MUTATOR_HOOKFUNCTION(nades, BuildGameplayTipsString)
1333 {
1334         ret_string = strcat(ret_string, "\n\n^3nades^8 are enabled, press 'g' to use them\n");
1335         return false;
1336 }
1337
1338 #endif
1339 #endif