qcsrc/common/mutators/mutator/overkill/sv_overkill.qc

   1 #include "sv_overkill.qh"
   2
   3 bool autocvar_g_overkill_powerups_replace;
   4
   5 bool autocvar_g_overkill_itemwaypoints = true;
   6
   7 .Weapon ok_lastwep[MAX_WEAPONSLOTS];
   8
   9 IntrusiveList g_overkill_items;
  10 STATIC_INIT()
  11 {
  12         g_overkill_items = IL_NEW();
  13         IL_PUSH(g_overkill_items, ITEM_HealthMega);
  14         IL_PUSH(g_overkill_items, ITEM_ArmorSmall);
  15         IL_PUSH(g_overkill_items, ITEM_ArmorMedium);
  16         IL_PUSH(g_overkill_items, ITEM_ArmorBig);
  17         IL_PUSH(g_overkill_items, ITEM_ArmorMega);
  18 }
  19
  20 /// \brief Returns a random classname of the overkill item.
  21 /// \param[in] prefix Prefix of the cvars that hold probabilities.
  22 /// \return Random classname of the overkill item.
  23 string RandomItems_GetRandomOverkillItemClassName(string prefix)
  24 {
  25         RandomSelection_Init();
  26         IL_EACH(g_overkill_items, !(it.spawnflags & ITEM_FLAG_MUTATORBLOCKED) &&
  27                 Item_IsDefinitionAllowed(it),
  28         {
  29                 string cvar_name = sprintf("g_%s_%s_probability", prefix,
  30                         it.m_canonical_spawnfunc);
  31                 if (!(cvar_type(cvar_name) & CVAR_TYPEFLAG_EXISTS))
  32                 {
  33                         LOG_WARNF("Random items: cvar %s doesn't exist.", cvar_name);
  34                         continue;
  35                 }
  36                 RandomSelection_AddString(it.m_canonical_spawnfunc, cvar(cvar_name), 1);
  37         });
  38         string cvar_name = sprintf("g_%s_weapon_okhmg_probability", prefix);
  39         if (!(cvar_type(cvar_name) & CVAR_TYPEFLAG_EXISTS))
  40         {
  41                 LOG_WARNF("Random items: cvar %s doesn't exist.", cvar_name);
  42         }
  43         else
  44         {
  45                 RandomSelection_AddString("weapon_okhmg", cvar(cvar_name), 1);
  46         }
  47         cvar_name = sprintf("g_%s_weapon_okrpc_probability", prefix);
  48         if (!(cvar_type(cvar_name) & CVAR_TYPEFLAG_EXISTS))
  49         {
  50                 LOG_WARNF("Random items: cvar %s doesn't exist.", cvar_name);
  51         }
  52         else
  53         {
  54                 RandomSelection_AddString("weapon_okrpc", cvar(cvar_name), 1);
  55         }
  56         return RandomSelection_chosen_string;
  57 }
  58
  59
  60 MUTATOR_HOOKFUNCTION(ok, RandomItems_GetRandomItemClassName)
  61 {
  62         M_ARGV(1, string) = RandomItems_GetRandomOverkillItemClassName(
  63                 M_ARGV(0, string));
  64         return true;
  65 }
  66
  67 MUTATOR_HOOKFUNCTION(ok, Damage_Calculate, CBC_ORDER_LAST)
  68 {
  69         entity frag_attacker = M_ARGV(1, entity);
  70         entity frag_target = M_ARGV(2, entity);
  71         float frag_deathtype = M_ARGV(3, float);
  72
  73         if(IS_PLAYER(frag_attacker) && (IS_PLAYER(frag_target) || IS_VEHICLE(frag_target) || IS_TURRET(frag_target)))
  74         if(DEATH_ISWEAPON(frag_deathtype, WEP_BLASTER))
  75         {
  76                 if(frag_attacker != frag_target)
  77                 if(!STAT(FROZEN, frag_target))
  78                 if(!IS_DEAD(frag_target))
  79                 {
  80                         Send_Notification(NOTIF_ONE, frag_attacker, MSG_CENTER, CENTER_SECONDARY_NODAMAGE);
  81                         M_ARGV(6, vector) = '0 0 0'; // force
  82                 }
  83
  84                 M_ARGV(4, float) = 0; // damage
  85         }
  86 }
  87
  88 void ok_DropItem(entity this, entity targ)
  89 {
  90         entity e = spawn();
  91         e.ok_item = true;
  92         Item_InitializeLoot(e, "item_armor_small", this.origin + '0 0 32',
  93                 '0 0 200' + normalize(targ.origin - this.origin) * 500, 5);
  94 }
  95
  96 MUTATOR_HOOKFUNCTION(ok, PlayerDies)
  97 {
  98         entity frag_attacker = M_ARGV(1, entity);
  99         entity frag_target = M_ARGV(2, entity);
 100
 101         entity targ = ((frag_attacker) ? frag_attacker : frag_target);
 102
 103         ok_DropItem(frag_target, targ);
 104
 105         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 106         {
 107                 .entity weaponentity = weaponentities[slot];
 108
 109                 frag_target.ok_lastwep[slot] = frag_target.(weaponentity).m_switchweapon;
 110         }
 111 }
 112
 113 MUTATOR_HOOKFUNCTION(ok, MonsterDropItem)
 114 {
 115         entity mon = M_ARGV(0, entity);
 116         entity olditem = M_ARGV(1, entity);
 117         entity frag_attacker = M_ARGV(2, entity);
 118
 119         delete(olditem);
 120
 121         M_ARGV(1, entity) = NULL;
 122
 123         ok_DropItem(mon, frag_attacker);
 124 }
 125
 126 MUTATOR_HOOKFUNCTION(ok, ForbidThrowCurrentWeapon)
 127 {
 128         return true;
 129 }
 130
 131 MUTATOR_HOOKFUNCTION(ok, PlayerPreThink)
 132 {
 133         if (game_stopped)
 134         {
 135                 return;
 136         }
 137         entity player = M_ARGV(0, entity);
 138         if (!IS_PLAYER(player) || IS_DEAD(player) || STAT(FROZEN, player))
 139         {
 140                 return;
 141         }
 142         if (!PHYS_INPUT_BUTTON_ATCK2(player) || forbidWeaponUse(player) ||
 143                 !(round_handler_IsActive() && !round_handler_IsRoundStarted()))
 144         {
 145                 return;
 146         }
 147         // Allow secondary blaster during countdown.
 148         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 149         {
 150                 .entity weaponentity = weaponentities[slot];
 151                 Weapon weapon = player.(weaponentity).m_weapon;
 152                 if (weapon == WEP_Null && slot != 0)
 153                 {
 154                         continue;
 155                 }
 156                 weapon.wr_think(weapon, player, weaponentity, 2);
 157         }
 158         PHYS_INPUT_BUTTON_ATCK2(player) = false;
 159 }
 160
 161 MUTATOR_HOOKFUNCTION(ok, ForbidRandomStartWeapons)
 162 {
 163         return true;
 164 }
 165
 166 MUTATOR_HOOKFUNCTION(ok, PlayerWeaponSelect)
 167 {
 168         entity player = M_ARGV(0, entity);
 169
 170         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 171         {
 172                 .entity weaponentity = weaponentities[slot];
 173                 entity thiswep = player.(weaponentity);
 174
 175                 if(player.ok_lastwep[slot] && player.ok_lastwep[slot] != WEP_Null)
 176                 {
 177                         Weapon newwep = player.ok_lastwep[slot];
 178                         if(player.ok_lastwep[slot] == WEP_OVERKILL_HMG)
 179                                 newwep = WEP_OVERKILL_MACHINEGUN;
 180                         if(player.ok_lastwep[slot] == WEP_OVERKILL_RPC)
 181                                 newwep = WEP_OVERKILL_NEX;
 182                         thiswep.m_switchweapon = newwep;
 183                         player.ok_lastwep[slot] = WEP_Null;
 184                 }
 185         }
 186 }
 187
 188 bool ok_HandleItemWaypoints(entity e)
 189 {
 190         if(!autocvar_g_overkill_itemwaypoints)
 191                 return false; // don't handle it
 192
 193         switch(e.itemdef)
 194         {
 195                 case ITEM_HealthMega: return true;
 196                 case ITEM_ArmorMedium: return true;
 197                 case ITEM_ArmorBig: return true;
 198                 case ITEM_ArmorMega: return true;
 199         }
 200
 201         return false;
 202 }
 203
 204 MUTATOR_HOOKFUNCTION(ok, Item_RespawnCountdown)
 205 {
 206         entity item = M_ARGV(0, entity);
 207         return ok_HandleItemWaypoints(item);
 208 }
 209
 210 MUTATOR_HOOKFUNCTION(ok, Item_ScheduleRespawn)
 211 {
 212         entity item = M_ARGV(0, entity);
 213         return ok_HandleItemWaypoints(item);
 214 }
 215
 216 MUTATOR_HOOKFUNCTION(ok, FilterItem)
 217 {
 218         entity item = M_ARGV(0, entity);
 219
 220         if (item.ok_item)
 221         {
 222                 return false;
 223         }
 224         switch(item.itemdef)
 225         {
 226                 case ITEM_HealthMega: return autocvar_g_overkill_filter_healthmega;
 227                 case ITEM_ArmorMedium: return autocvar_g_overkill_filter_armormedium;
 228                 case ITEM_ArmorBig: return autocvar_g_overkill_filter_armorbig;
 229                 case ITEM_ArmorMega: return autocvar_g_overkill_filter_armormega;
 230         }
 231         if (!autocvar_g_powerups || !autocvar_g_overkill_powerups_replace)
 232         {
 233                 return true;
 234         }
 235         if (item.classname == "item_strength")
 236         {
 237                 entity wep = new(weapon_okhmg);
 238                 setorigin(wep, item.origin);
 239                 wep.ok_item = true;
 240                 wep.noalign = Item_ShouldKeepPosition(item);
 241                 wep.cnt = item.cnt;
 242                 wep.team = item.team;
 243                 wep.respawntime = g_pickup_respawntime_superweapon;
 244                 wep.pickup_anyway = true;
 245                 wep.spawnfunc_checked = true;
 246                 Item_Initialize(wep, "weapon_okhmg"); // doesn't actually use spawnfunc
 247                 return true;
 248         }
 249         else if (item.classname == "item_shield")
 250         {
 251                 entity wep = new(weapon_okrpc);
 252                 setorigin(wep, item.origin);
 253                 wep.ok_item = true;
 254                 wep.noalign = Item_ShouldKeepPosition(item);
 255                 wep.cnt = item.cnt;
 256                 wep.team = item.team;
 257                 wep.respawntime = g_pickup_respawntime_superweapon;
 258                 wep.pickup_anyway = true;
 259                 wep.spawnfunc_checked = true;
 260                 Item_Initialize(wep, "weapon_okrpc"); // doesn't actually use spawnfunc
 261                 return true;
 262         }
 263         return true;
 264 }
 265
 266 MUTATOR_HOOKFUNCTION(ok, SetStartItems, CBC_ORDER_LAST)
 267 {
 268         WepSet ok_start_items = (WEPSET(OVERKILL_MACHINEGUN) | WEPSET(OVERKILL_NEX) | WEPSET(OVERKILL_SHOTGUN));
 269
 270         if(WEP_OVERKILL_RPC.weaponstart > 0) { ok_start_items |= WEPSET(OVERKILL_RPC); }
 271         if(WEP_OVERKILL_HMG.weaponstart > 0) { ok_start_items |= WEPSET(OVERKILL_HMG); }
 272
 273         start_items |= IT_UNLIMITED_WEAPON_AMMO;
 274         start_weapons = warmup_start_weapons = ok_start_items;
 275 }
 276
 277 MUTATOR_HOOKFUNCTION(ok, SetWeaponArena)
 278 {
 279         // turn weapon arena off
 280         M_ARGV(0, string) = "off";
 281 }
 282
 283 MUTATOR_HOOKFUNCTION(ok, BuildMutatorsString)
 284 {
 285         M_ARGV(0, string) = strcat(M_ARGV(0, string), ":OK");
 286 }
 287
 288 MUTATOR_HOOKFUNCTION(ok, BuildMutatorsPrettyString)
 289 {
 290         M_ARGV(0, string) = strcat(M_ARGV(0, string), ", Overkill");
 291 }
 292
 293 MUTATOR_HOOKFUNCTION(ok, SetModname)
 294 {
 295         M_ARGV(0, string) = "Overkill";
 296         return true;
 297 }
 298