Cleanse the touch functions of the other evil
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / mutators / mutator / sandbox / sandbox.qc
1 #ifdef IMPLEMENTATION
2 int autocvar_g_sandbox_info;
3 bool autocvar_g_sandbox_readonly;
4 string autocvar_g_sandbox_storage_name;
5 float autocvar_g_sandbox_storage_autosave;
6 bool autocvar_g_sandbox_storage_autoload;
7 float autocvar_g_sandbox_editor_flood;
8 int autocvar_g_sandbox_editor_maxobjects;
9 int autocvar_g_sandbox_editor_free;
10 float autocvar_g_sandbox_editor_distance_spawn;
11 float autocvar_g_sandbox_editor_distance_edit;
12 float autocvar_g_sandbox_object_scale_min;
13 float autocvar_g_sandbox_object_scale_max;
14 float autocvar_g_sandbox_object_material_velocity_min;
15 float autocvar_g_sandbox_object_material_velocity_factor;
16
17 float autosave_time;
18 void sandbox_Database_Load();
19
20 REGISTER_MUTATOR(sandbox, cvar("g_sandbox"))
21 {
22         MUTATOR_ONADD
23         {
24                 autosave_time = time + autocvar_g_sandbox_storage_autosave; // don't save the first server frame
25                 if(autocvar_g_sandbox_storage_autoload)
26                         sandbox_Database_Load();
27         }
28 }
29
30 const float MAX_STORAGE_ATTACHMENTS = 16;
31 float object_count;
32 .float object_flood;
33 .entity object_attach;
34 .string material;
35
36 .float touch_timer;
37 void sandbox_ObjectFunction_Touch(entity this, entity toucher)
38 {
39         // apply material impact effects
40
41         if(!this.material)
42                 return;
43         if(this.touch_timer > time)
44                 return; // don't execute each frame
45         this.touch_timer = time + 0.1;
46
47         // make particle count and sound volume depend on impact speed
48         float intensity;
49         intensity = vlen(this.velocity) + vlen(toucher.velocity);
50         if(intensity) // avoid divisions by 0
51                 intensity /= 2; // average the two velocities
52         if (!(intensity >= autocvar_g_sandbox_object_material_velocity_min))
53                 return; // impact not strong enough to do anything
54         // now offset intensity and apply it to the effects
55         intensity -= autocvar_g_sandbox_object_material_velocity_min; // start from minimum velocity, not actual velocity
56         intensity = bound(0, intensity * autocvar_g_sandbox_object_material_velocity_factor, 1);
57
58         _sound(this, CH_TRIGGER, strcat("object/impact_", this.material, "_", ftos(ceil(random() * 5)) , ".wav"), VOL_BASE * intensity, ATTEN_NORM);
59         Send_Effect_(strcat("impact_", this.material), this.origin, '0 0 0', ceil(intensity * 10)); // allow a count from 1 to 10
60 }
61
62 void sandbox_ObjectFunction_Think(entity this)
63 {
64         // decide if and how this object can be grabbed
65         if(autocvar_g_sandbox_readonly)
66                 this.grab = 0; // no grabbing
67         else if(autocvar_g_sandbox_editor_free < 2 && this.crypto_idfp)
68                 this.grab = 1; // owner only
69         else
70                 this.grab = 3; // anyone
71
72         // Object owner is stored via player UID, but we also need the owner as an entity (if the player is available on the server).
73         // Therefore, scan for all players, and update the owner as long as the player is present. We must always do this,
74         // since if the owning player disconnects, the object's owner should also be reset.
75
76         // bots can't have objects
77         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), LAMBDA(
78                 if(this.crypto_idfp == it.crypto_idfp)
79                 {
80                         this.realowner = it;
81                         break;
82                 }
83                 this.realowner = NULL;
84         ));
85
86         this.nextthink = time;
87
88         CSQCMODEL_AUTOUPDATE(this);
89 }
90
91 .float old_solid, old_movetype;
92 entity sandbox_ObjectEdit_Get(entity this, float permissions)
93 {
94         // Returns the traced entity if the player can edit it, and NULL if not.
95         // If permissions if false, the object is returned regardless of editing rights.
96         // Attached objects are SOLID_NOT and do not get traced.
97
98         crosshair_trace_plusvisibletriggers(this);
99         if(vdist(this.origin - trace_ent.origin, >, autocvar_g_sandbox_editor_distance_edit))
100                 return NULL; // out of trace range
101         if(trace_ent.classname != "object")
102                 return NULL; // entity is not an object
103         if(!permissions)
104                 return trace_ent; // don't check permissions, anyone can edit this object
105         if(trace_ent.crypto_idfp == "")
106                 return trace_ent; // the player who spawned this object did not have an UID, so anyone can edit it
107         if (!(trace_ent.realowner != this && autocvar_g_sandbox_editor_free < 2))
108                 return trace_ent; // object does not belong to the player, and players can only edit their own objects on this server
109         return NULL;
110 }
111
112 void sandbox_ObjectEdit_Scale(entity e, float f)
113 {
114         e.scale = f;
115         if(e.scale)
116         {
117                 e.scale = bound(autocvar_g_sandbox_object_scale_min, e.scale, autocvar_g_sandbox_object_scale_max);
118                 _setmodel(e, e.model); // reset mins and maxs based on mesh
119                 setsize(e, e.mins * e.scale, e.maxs * e.scale); // adapt bounding box size to model size
120         }
121 }
122
123 void sandbox_ObjectAttach_Remove(entity e);
124 void sandbox_ObjectAttach_Set(entity e, entity parent, string s)
125 {
126         // attaches e to parent on string s
127
128         // we can't attach to an attachment, for obvious reasons
129         sandbox_ObjectAttach_Remove(e);
130
131         e.old_solid = e.solid; // persist solidity
132         e.old_movetype = e.movetype; // persist physics
133         e.movetype = MOVETYPE_FOLLOW;
134         e.solid = SOLID_NOT;
135         e.takedamage = DAMAGE_NO;
136
137         setattachment(e, parent, s);
138         e.owner = parent;
139 }
140
141 void sandbox_ObjectAttach_Remove(entity e)
142 {
143         // detaches any object attached to e
144
145         entity head;
146         for(head = NULL; (head = find(head, classname, "object")); )
147         {
148                 if(head.owner == e)
149                 {
150                         vector org;
151                         org = gettaginfo(head, 0);
152                         setattachment(head, NULL, "");
153                         head.owner = NULL;
154
155                         // objects change origin and angles when detached, so apply previous position
156                         setorigin(head, org);
157                         head.angles = e.angles; // don't allow detached objects to spin or roll
158
159                         head.solid = head.old_solid; // restore persisted solidity
160                         head.movetype = head.old_movetype; // restore persisted physics
161                         head.takedamage = DAMAGE_AIM;
162                 }
163         }
164 }
165
166 entity sandbox_ObjectSpawn(entity this, float database)
167 {
168         // spawn a new object with default properties
169
170         entity e = new(object);
171         e.takedamage = DAMAGE_AIM;
172         e.damageforcescale = 1;
173         e.solid = SOLID_BBOX; // SOLID_BSP would be best, but can lag the server badly
174         e.movetype = MOVETYPE_TOSS;
175         e.frame = 0;
176         e.skin = 0;
177         e.material = string_null;
178         settouch(e, sandbox_ObjectFunction_Touch);
179         setthink(e, sandbox_ObjectFunction_Think);
180         e.nextthink = time;
181         //e.effects |= EF_SELECTABLE; // don't do this all the time, maybe just when editing objects?
182
183         if(!database)
184         {
185                 // set the object's owner via player UID
186                 // if the player does not have an UID, the owner cannot be stored and his objects may be edited by anyone
187                 if(this.crypto_idfp != "")
188                         e.crypto_idfp = strzone(this.crypto_idfp);
189                 else
190                         print_to(this, "^1SANDBOX - WARNING: ^7You spawned an object, but lack a player UID. ^1Your objects are not secured and can be edited by any player!");
191
192                 // set public object information
193                 e.netname = strzone(this.netname); // name of the owner
194                 e.message = strzone(strftime(true, "%d-%m-%Y %H:%M:%S")); // creation time
195                 e.message2 = strzone(strftime(true, "%d-%m-%Y %H:%M:%S")); // last editing time
196
197                 // set origin and direction based on player position and view angle
198                 makevectors(this.v_angle);
199                 WarpZone_TraceLine(this.origin + this.view_ofs, this.origin + this.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_spawn, MOVE_NORMAL, this);
200                 setorigin(e, trace_endpos);
201                 e.angles_y = this.v_angle.y;
202         }
203
204         CSQCMODEL_AUTOINIT(e);
205
206         object_count += 1;
207         return e;
208 }
209
210 void sandbox_ObjectRemove(entity e)
211 {
212         sandbox_ObjectAttach_Remove(e); // detach child objects
213
214         // if the object being removed has been selected for attachment by a player, unset it
215         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && it.object_attach == e, LAMBDA(it.object_attach = NULL));
216
217         if(e.material)  {       strunzone(e.material);  e.material = string_null;       }
218         if(e.crypto_idfp)       {       strunzone(e.crypto_idfp);       e.crypto_idfp = string_null;    }
219         if(e.netname)   {       strunzone(e.netname);   e.netname = string_null;        }
220         if(e.message)   {       strunzone(e.message);   e.message = string_null;        }
221         if(e.message2)  {       strunzone(e.message2);  e.message2 = string_null;       }
222         remove(e);
223         e = NULL;
224
225         object_count -= 1;
226 }
227
228 string port_string[MAX_STORAGE_ATTACHMENTS]; // fteqcc crashes if this isn't defined as a global
229
230 string sandbox_ObjectPort_Save(entity e, float database)
231 {
232         // save object properties, and return them as a string
233         float i = 0;
234         string s;
235         entity head;
236
237         for(head = NULL; (head = find(head, classname, "object")); )
238         {
239                 // the main object needs to be first in the array [0] with attached objects following
240                 float slot, physics, solidity;
241                 if(head == e) // this is the main object, place it first
242                 {
243                         slot = 0;
244                         solidity = head.solid; // applied solidity is normal solidity for children
245                         physics = head.movetype; // applied physics are normal physics for parents
246                 }
247                 else if(head.owner == e) // child object, list them in order
248                 {
249                         i += 1; // children start from 1
250                         slot = i;
251                         solidity = head.old_solid; // persisted solidity is normal solidity for children
252                         physics = head.old_movetype; // persisted physics are normal physics for children
253                         gettaginfo(head.owner, head.tag_index); // get the name of the tag our object is attached to, used further below
254                 }
255                 else
256                         continue;
257
258                 // ---------------- OBJECT PROPERTY STORAGE: SAVE ----------------
259                 if(slot)
260                 {
261                         // properties stored only for child objects
262                         if(gettaginfo_name)     port_string[slot] = strcat(port_string[slot], "\"", gettaginfo_name, "\" ");    else    port_string[slot] = strcat(port_string[slot], "\"\" "); // none
263                 }
264                 else
265                 {
266                         // properties stored only for parent objects
267                         if(database)
268                         {
269                                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.origin), " ");
270                                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.angles), " ");
271                         }
272                 }
273                 // properties stored for all objects
274                 port_string[slot] = strcat(port_string[slot], "\"", head.model, "\" ");
275                 port_string[slot] = strcat(port_string[slot], ftos(head.skin), " ");
276                 port_string[slot] = strcat(port_string[slot], ftos(head.alpha), " ");
277                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.colormod), " ");
278                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.glowmod), " ");
279                 port_string[slot] = strcat(port_string[slot], ftos(head.frame), " ");
280                 port_string[slot] = strcat(port_string[slot], ftos(head.scale), " ");
281                 port_string[slot] = strcat(port_string[slot], ftos(solidity), " ");
282                 port_string[slot] = strcat(port_string[slot], ftos(physics), " ");
283                 port_string[slot] = strcat(port_string[slot], ftos(head.damageforcescale), " ");
284                 if(head.material)       port_string[slot] = strcat(port_string[slot], "\"", head.material, "\" ");      else    port_string[slot] = strcat(port_string[slot], "\"\" "); // none
285                 if(database)
286                 {
287                         // properties stored only for the database
288                         if(head.crypto_idfp)    port_string[slot] = strcat(port_string[slot], "\"", head.crypto_idfp, "\" ");   else    port_string[slot] = strcat(port_string[slot], "\"\" "); // none
289                         port_string[slot] = strcat(port_string[slot], "\"", e.netname, "\" ");
290                         port_string[slot] = strcat(port_string[slot], "\"", e.message, "\" ");
291                         port_string[slot] = strcat(port_string[slot], "\"", e.message2, "\" ");
292                 }
293         }
294
295         // now apply the array to a simple string, with the ; symbol separating objects
296         s = "";
297         for(i = 0; i <= MAX_STORAGE_ATTACHMENTS; ++i)
298         {
299                 if(port_string[i])
300                         s = strcat(s, port_string[i], "; ");
301                 port_string[i] = string_null; // fully clear the string
302         }
303
304         return s;
305 }
306
307 entity sandbox_ObjectPort_Load(entity this, string s, float database)
308 {
309         // load object properties, and spawn a new object with them
310         float n, i;
311         entity e = NULL, parent = NULL;
312
313         // separate objects between the ; symbols
314         n = tokenizebyseparator(s, "; ");
315         for(i = 0; i < n; ++i)
316                 port_string[i] = argv(i);
317
318         // now separate and apply the properties of each object
319         for(i = 0; i < n; ++i)
320         {
321                 float argv_num;
322                 string tagname = string_null;
323                 argv_num = 0;
324                 tokenize_console(port_string[i]);
325                 e = sandbox_ObjectSpawn(this, database);
326
327                 // ---------------- OBJECT PROPERTY STORAGE: LOAD ----------------
328                 if(i)
329                 {
330                         // properties stored only for child objects
331                         if(argv(argv_num) != "")        tagname = argv(argv_num);       else tagname = string_null;     ++argv_num;
332                 }
333                 else
334                 {
335                         // properties stored only for parent objects
336                         if(database)
337                         {
338                                 setorigin(e, stov(argv(argv_num)));     ++argv_num;
339                                 e.angles = stov(argv(argv_num));        ++argv_num;
340                         }
341                         parent = e; // mark parent objects as such
342                 }
343                 // properties stored for all objects
344                 _setmodel(e, argv(argv_num));   ++argv_num;
345                 e.skin = stof(argv(argv_num));  ++argv_num;
346                 e.alpha = stof(argv(argv_num)); ++argv_num;
347                 e.colormod = stov(argv(argv_num));      ++argv_num;
348                 e.glowmod = stov(argv(argv_num));       ++argv_num;
349                 e.frame = stof(argv(argv_num)); ++argv_num;
350                 sandbox_ObjectEdit_Scale(e, stof(argv(argv_num)));      ++argv_num;
351                 e.solid = e.old_solid = stof(argv(argv_num));   ++argv_num;
352                 e.movetype = e.old_movetype = stof(argv(argv_num));     ++argv_num;
353                 e.damageforcescale = stof(argv(argv_num));      ++argv_num;
354                 if(e.material)  strunzone(e.material);  if(argv(argv_num) != "")        e.material = strzone(argv(argv_num));   else    e.material = string_null;       ++argv_num;
355                 if(database)
356                 {
357                         // properties stored only for the database
358                         if(e.crypto_idfp)       strunzone(e.crypto_idfp);       if(argv(argv_num) != "")        e.crypto_idfp = strzone(argv(argv_num));        else    e.crypto_idfp = string_null;    ++argv_num;
359                         if(e.netname)   strunzone(e.netname);   e.netname = strzone(argv(argv_num));    ++argv_num;
360                         if(e.message)   strunzone(e.message);   e.message = strzone(argv(argv_num));    ++argv_num;
361                         if(e.message2)  strunzone(e.message2);  e.message2 = strzone(argv(argv_num));   ++argv_num;
362                 }
363
364                 // attach last
365                 if(i)
366                         sandbox_ObjectAttach_Set(e, parent, tagname);
367         }
368
369         for(i = 0; i <= MAX_STORAGE_ATTACHMENTS; ++i)
370                 port_string[i] = string_null; // fully clear the string
371
372         return e;
373 }
374
375 void sandbox_Database_Save()
376 {
377         // saves all objects to the database file
378         entity head;
379         string file_name;
380         float file_get;
381
382         file_name = strcat("sandbox/storage_", autocvar_g_sandbox_storage_name, "_", GetMapname(), ".txt");
383         file_get = fopen(file_name, FILE_WRITE);
384         fputs(file_get, strcat("// sandbox storage \"", autocvar_g_sandbox_storage_name, "\" for map \"", GetMapname(), "\" last updated ", strftime(true, "%d-%m-%Y %H:%M:%S")));
385         fputs(file_get, strcat(" containing ", ftos(object_count), " objects\n"));
386
387         for(head = NULL; (head = find(head, classname, "object")); )
388         {
389                 // attached objects are persisted separately, ignore them here
390                 if(head.owner != NULL)
391                         continue;
392
393                 // use a line of text for each object, listing all properties
394                 fputs(file_get, strcat(sandbox_ObjectPort_Save(head, true), "\n"));
395         }
396         fclose(file_get);
397 }
398
399 void sandbox_Database_Load()
400 {
401         // loads all objects from the database file
402         string file_read, file_name;
403         float file_get, i;
404
405         file_name = strcat("sandbox/storage_", autocvar_g_sandbox_storage_name, "_", GetMapname(), ".txt");
406         file_get = fopen(file_name, FILE_READ);
407         if(file_get < 0)
408         {
409                 if(autocvar_g_sandbox_info > 0)
410                         LOG_INFO(strcat("^3SANDBOX - SERVER: ^7could not find storage file ^3", file_name, "^7, no objects were loaded\n"));
411         }
412         else
413         {
414                 for (;;)
415                 {
416                         file_read = fgets(file_get);
417                         if(file_read == "")
418                                 break;
419                         if(substring(file_read, 0, 2) == "//")
420                                 continue;
421                         if(substring(file_read, 0, 1) == "#")
422                                 continue;
423
424                         entity e;
425                         e = sandbox_ObjectPort_Load(NULL, file_read, true);
426
427                         if(e.material)
428                         {
429                                 // since objects are being loaded for the first time, precache material sounds for each
430                                 for (i = 1; i <= 5; i++) // 5 sounds in total
431                                         precache_sound(strcat("object/impact_", e.material, "_", ftos(i), ".wav"));
432                         }
433                 }
434                 if(autocvar_g_sandbox_info > 0)
435                         LOG_INFO(strcat("^3SANDBOX - SERVER: ^7successfully loaded storage file ^3", file_name, "\n"));
436         }
437         fclose(file_get);
438 }
439
440 MUTATOR_HOOKFUNCTION(sandbox, SV_ParseClientCommand)
441 {
442         if(MUTATOR_RETURNVALUE) // command was already handled?
443                 return;
444
445         entity player = M_ARGV(0, entity);
446         string cmd_name = M_ARGV(1, string);
447         int cmd_argc = M_ARGV(2, int);
448
449         if(cmd_name == "g_sandbox")
450         {
451                 if(autocvar_g_sandbox_readonly)
452                 {
453                         print_to(player, "^2SANDBOX - INFO: ^7Sandbox mode is active, but in read-only mode. Sandbox commands cannot be used");
454                         return true;
455                 }
456                 if(cmd_argc < 2)
457                 {
458                         print_to(player, "^2SANDBOX - INFO: ^7Sandbox mode is active. For usage information, type 'sandbox help'");
459                         return true;
460                 }
461
462                 switch(argv(1))
463                 {
464                         entity e;
465                         float i;
466                         string s;
467
468                         // ---------------- COMMAND: HELP ----------------
469                         case "help":
470                                 print_to(player, "You can use the following sandbox commands:");
471                                 print_to(player, "^7\"^2object_spawn ^3models/foo/bar.md3^7\" spawns a new object in front of the player, and gives it the specified model");
472                                 print_to(player, "^7\"^2object_remove^7\" removes the object the player is looking at. Players can only remove their own objects");
473                                 print_to(player, "^7\"^2object_duplicate ^3value^7\" duplicates the object, if the player has copying rights over the original");
474                                 print_to(player, "^3copy value ^7- copies the properties of the object to the specified client cvar");
475                                 print_to(player, "^3paste value ^7- spawns an object with the given properties. Properties or cvars must be specified as follows; eg1: \"0 1 2 ...\", eg2: \"$cl_cvar\"");
476                                 print_to(player, "^7\"^2object_attach ^3property value^7\" attaches one object to another. Players can only attach their own objects");
477                                 print_to(player, "^3get ^7- selects the object you are facing as the object to be attached");
478                                 print_to(player, "^3set value ^7- attaches the previously selected object to the object you are facing, on the specified bone");
479                                 print_to(player, "^3remove ^7- detaches all objects from the object you are facing");
480                                 print_to(player, "^7\"^2object_edit ^3property value^7\" edits the given property of the object. Players can only edit their own objects");
481                                 print_to(player, "^3skin value ^7- changes the skin of the object");
482                                 print_to(player, "^3alpha value ^7- sets object transparency");
483                                 print_to(player, "^3colormod \"value_x value_y value_z\" ^7- main object color");
484                                 print_to(player, "^3glowmod \"value_x value_y value_z\" ^7- glow object color");
485                                 print_to(player, "^3frame value ^7- object animation frame, for self-animated models");
486                                 print_to(player, "^3scale value ^7- changes object scale. 0.5 is half size and 2 is double size");
487                                 print_to(player, "^3solidity value ^7- object collisions, 0 = non-solid, 1 = solid");
488                                 print_to(player, "^3physics value ^7- object physics, 0 = static, 1 = movable, 2 = physical");
489                                 print_to(player, "^3force value ^7- amount of force applied to objects that are shot");
490                                 print_to(player, "^3material value ^7- sets the material of the object. Default materials are: metal, stone, wood, flesh");
491                                 print_to(player, "^7\"^2object_claim^7\" sets the player as the owner of the object, if he has the right to edit it");
492                                 print_to(player, "^7\"^2object_info ^3value^7\" shows public information about the object");
493                                 print_to(player, "^3object ^7- prints general information about the object, such as owner and creation / editing date");
494                                 print_to(player, "^3mesh ^7- prints information about the object's mesh, including skeletal bones");
495                                 print_to(player, "^3attachments ^7- prints information about the object's attachments");
496                                 print_to(player, "^7The ^1drag object ^7key can be used to grab and carry objects. Players can only grab their own objects");
497                                 return true;
498
499                         // ---------------- COMMAND: OBJECT, SPAWN ----------------
500                         case "object_spawn":
501                                 if(time < player.object_flood)
502                                 {
503                                         print_to(player, strcat("^1SANDBOX - WARNING: ^7Flood protection active. Please wait ^3", ftos(player.object_flood - time), " ^7seconds beofore spawning another object"));
504                                         return true;
505                                 }
506                                 player.object_flood = time + autocvar_g_sandbox_editor_flood;
507                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
508                                 {
509                                         print_to(player, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
510                                         return true;
511                                 }
512                                 if(cmd_argc < 3)
513                                 {
514                                         print_to(player, "^1SANDBOX - WARNING: ^7Attempted to spawn an object without specifying a model. Please specify the path to your model file after the 'object_spawn' command");
515                                         return true;
516                                 }
517                                 if (!(fexists(argv(2))))
518                                 {
519                                         print_to(player, "^1SANDBOX - WARNING: ^7Attempted to spawn an object with a non-existent model. Make sure the path to your model file is correct");
520                                         return true;
521                                 }
522
523                                 e = sandbox_ObjectSpawn(player, false);
524                                 _setmodel(e, argv(2));
525
526                                 if(autocvar_g_sandbox_info > 0)
527                                         LOG_INFO(strcat("^3SANDBOX - SERVER: ^7", player.netname, " spawned an object at origin ^3", vtos(e.origin), "\n"));
528                                 return true;
529
530                         // ---------------- COMMAND: OBJECT, REMOVE ----------------
531                         case "object_remove":
532                                 e = sandbox_ObjectEdit_Get(player, true);
533                                 if(e != NULL)
534                                 {
535                                         if(autocvar_g_sandbox_info > 0)
536                                                 LOG_INFO(strcat("^3SANDBOX - SERVER: ^7", player.netname, " removed an object at origin ^3", vtos(e.origin), "\n"));
537                                         sandbox_ObjectRemove(e);
538                                         return true;
539                                 }
540
541                                 print_to(player, "^1SANDBOX - WARNING: ^7Object could not be removed. Make sure you are facing an object that you have edit rights over");
542                                 return true;
543
544                         // ---------------- COMMAND: OBJECT, DUPLICATE ----------------
545                         case "object_duplicate":
546                                 switch(argv(2))
547                                 {
548                                         case "copy":
549                                                 // copies customizable properties of the selected object to the clipboard cvar
550                                                 e = sandbox_ObjectEdit_Get(player, autocvar_g_sandbox_editor_free); // can we copy objects we can't edit?
551                                                 if(e != NULL)
552                                                 {
553                                                         s = sandbox_ObjectPort_Save(e, false);
554                                                         s = strreplace("\"", "\\\"", s);
555                                                         stuffcmd(player, strcat("set ", argv(3), " \"", s, "\""));
556
557                                                         print_to(player, "^2SANDBOX - INFO: ^7Object copied to clipboard");
558                                                         return true;
559                                                 }
560                                                 print_to(player, "^1SANDBOX - WARNING: ^7Object could not be copied. Make sure you are facing an object that you have copy rights over");
561                                                 return true;
562
563                                         case "paste":
564                                                 // spawns a new object using the properties in the player's clipboard cvar
565                                                 if(time < player.object_flood)
566                                                 {
567                                                         print_to(player, strcat("^1SANDBOX - WARNING: ^7Flood protection active. Please wait ^3", ftos(player.object_flood - time), " ^7seconds beofore spawning another object"));
568                                                         return true;
569                                                 }
570                                                 player.object_flood = time + autocvar_g_sandbox_editor_flood;
571                                                 if(argv(3) == "") // no object in clipboard
572                                                 {
573                                                         print_to(player, "^1SANDBOX - WARNING: ^7No object in clipboard. You must copy an object before you can paste it");
574                                                         return true;
575                                                 }
576                                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
577                                                 {
578                                                         print_to(player, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
579                                                         return true;
580                                                 }
581                                                 e = sandbox_ObjectPort_Load(player, argv(3), false);
582
583                                                 print_to(player, "^2SANDBOX - INFO: ^7Object pasted successfully");
584                                                 if(autocvar_g_sandbox_info > 0)
585                                                         LOG_INFO(strcat("^3SANDBOX - SERVER: ^7", player.netname, " pasted an object at origin ^3", vtos(e.origin), "\n"));
586                                                 return true;
587                                 }
588                                 return true;
589
590                         // ---------------- COMMAND: OBJECT, ATTACH ----------------
591                         case "object_attach":
592                                 switch(argv(2))
593                                 {
594                                         case "get":
595                                                 // select e as the object as meant to be attached
596                                                 e = sandbox_ObjectEdit_Get(player, true);
597                                                 if(e != NULL)
598                                                 {
599                                                         player.object_attach = e;
600                                                         print_to(player, "^2SANDBOX - INFO: ^7Object selected for attachment");
601                                                         return true;
602                                                 }
603                                                 print_to(player, "^1SANDBOX - WARNING: ^7Object could not be selected for attachment. Make sure you are facing an object that you have edit rights over");
604                                                 return true;
605                                         case "set":
606                                                 if(player.object_attach == NULL)
607                                                 {
608                                                         print_to(player, "^1SANDBOX - WARNING: ^7No object selected for attachment. Please select an object to be attached first.");
609                                                         return true;
610                                                 }
611
612                                                 // attaches the previously selected object to e
613                                                 e = sandbox_ObjectEdit_Get(player, true);
614                                                 if(e != NULL)
615                                                 {
616                                                         sandbox_ObjectAttach_Set(player.object_attach, e, argv(3));
617                                                         player.object_attach = NULL; // object was attached, no longer keep it scheduled for attachment
618                                                         print_to(player, "^2SANDBOX - INFO: ^7Object attached successfully");
619                                                         if(autocvar_g_sandbox_info > 1)
620                                                                 LOG_INFO(strcat("^3SANDBOX - SERVER: ^7", player.netname, " attached objects at origin ^3", vtos(e.origin), "\n"));
621                                                         return true;
622                                                 }
623                                                 print_to(player, "^1SANDBOX - WARNING: ^7Object could not be attached to the parent. Make sure you are facing an object that you have edit rights over");
624                                                 return true;
625                                         case "remove":
626                                                 // removes e if it was attached
627                                                 e = sandbox_ObjectEdit_Get(player, true);
628                                                 if(e != NULL)
629                                                 {
630                                                         sandbox_ObjectAttach_Remove(e);
631                                                         print_to(player, "^2SANDBOX - INFO: ^7Child objects detached successfully");
632                                                         if(autocvar_g_sandbox_info > 1)
633                                                                 LOG_INFO(strcat("^3SANDBOX - SERVER: ^7", player.netname, " detached objects at origin ^3", vtos(e.origin), "\n"));
634                                                         return true;
635                                                 }
636                                                 print_to(player, "^1SANDBOX - WARNING: ^7Child objects could not be detached. Make sure you are facing an object that you have edit rights over");
637                                                 return true;
638                                 }
639                                 return true;
640
641                         // ---------------- COMMAND: OBJECT, EDIT ----------------
642                         case "object_edit":
643                                 if(argv(2) == "")
644                                 {
645                                         print_to(player, "^1SANDBOX - WARNING: ^7Too few parameters. You must specify a property to edit");
646                                         return true;
647                                 }
648
649                                 e = sandbox_ObjectEdit_Get(player, true);
650                                 if(e != NULL)
651                                 {
652                                         switch(argv(2))
653                                         {
654                                                 case "skin":
655                                                         e.skin = stof(argv(3));
656                                                         break;
657                                                 case "alpha":
658                                                         e.alpha = stof(argv(3));
659                                                         break;
660                                                 case "color_main":
661                                                         e.colormod = stov(argv(3));
662                                                         break;
663                                                 case "color_glow":
664                                                         e.glowmod = stov(argv(3));
665                                                         break;
666                                                 case "frame":
667                                                         e.frame = stof(argv(3));
668                                                         break;
669                                                 case "scale":
670                                                         sandbox_ObjectEdit_Scale(e, stof(argv(3)));
671                                                         break;
672                                                 case "solidity":
673                                                         switch(argv(3))
674                                                         {
675                                                                 case "0": // non-solid
676                                                                         e.solid = SOLID_TRIGGER;
677                                                                         break;
678                                                                 case "1": // solid
679                                                                         e.solid = SOLID_BBOX;
680                                                                         break;
681                                                                 default:
682                                                                         break;
683                                                         }
684                                                 case "physics":
685                                                         switch(argv(3))
686                                                         {
687                                                                 case "0": // static
688                                                                         e.movetype = MOVETYPE_NONE;
689                                                                         break;
690                                                                 case "1": // movable
691                                                                         e.movetype = MOVETYPE_TOSS;
692                                                                         break;
693                                                                 case "2": // physical
694                                                                         e.movetype = MOVETYPE_PHYSICS;
695                                                                         break;
696                                                                 default:
697                                                                         break;
698                                                         }
699                                                         break;
700                                                 case "force":
701                                                         e.damageforcescale = stof(argv(3));
702                                                         break;
703                                                 case "material":
704                                                         if(e.material)  strunzone(e.material);
705                                                         if(argv(3))
706                                                         {
707                                                                 for (i = 1; i <= 5; i++) // precache material sounds, 5 in total
708                                                                         precache_sound(strcat("object/impact_", argv(3), "_", ftos(i), ".wav"));
709                                                                 e.material = strzone(argv(3));
710                                                         }
711                                                         else
712                                                                 e.material = string_null; // no material
713                                                         break;
714                                                 default:
715                                                         print_to(player, "^1SANDBOX - WARNING: ^7Invalid object property. For usage information, type 'sandbox help'");
716                                                         return true;
717                                         }
718
719                                         // update last editing time
720                                         if(e.message2)  strunzone(e.message2);
721                                         e.message2 = strzone(strftime(true, "%d-%m-%Y %H:%M:%S"));
722
723                                         if(autocvar_g_sandbox_info > 1)
724                                                 LOG_INFO(strcat("^3SANDBOX - SERVER: ^7", player.netname, " edited property ^3", argv(2), " ^7of an object at origin ^3", vtos(e.origin), "\n"));
725                                         return true;
726                                 }
727
728                                 print_to(player, "^1SANDBOX - WARNING: ^7Object could not be edited. Make sure you are facing an object that you have edit rights over");
729                                 return true;
730
731                         // ---------------- COMMAND: OBJECT, CLAIM ----------------
732                         case "object_claim":
733                                 // if the player can edit an object but is not its owner, this can be used to claim that object
734                                 if(player.crypto_idfp == "")
735                                 {
736                                         print_to(player, "^1SANDBOX - WARNING: ^7You do not have a player UID, and cannot claim objects");
737                                         return true;
738                                 }
739                                 e = sandbox_ObjectEdit_Get(player, true);
740                                 if(e != NULL)
741                                 {
742                                         // update the owner's name
743                                         // Do this before checking if you're already the owner and skipping if such, so we
744                                         // also update the player's nickname if he changed it (but has the same player UID)
745                                         if(e.netname != player.netname)
746                                         {
747                                                 if(e.netname)   strunzone(e.netname);
748                                                 e.netname = strzone(player.netname);
749                                                 print_to(player, "^2SANDBOX - INFO: ^7Object owner name updated");
750                                         }
751
752                                         if(e.crypto_idfp == player.crypto_idfp)
753                                         {
754                                                 print_to(player, "^2SANDBOX - INFO: ^7Object is already yours, nothing to claim");
755                                                 return true;
756                                         }
757
758                                         if(e.crypto_idfp)       strunzone(e.crypto_idfp);
759                                         e.crypto_idfp = strzone(player.crypto_idfp);
760
761                                         print_to(player, "^2SANDBOX - INFO: ^7Object claimed successfully");
762                                 }
763                                 print_to(player, "^1SANDBOX - WARNING: ^7Object could not be claimed. Make sure you are facing an object that you have edit rights over");
764                                 return true;
765
766                         // ---------------- COMMAND: OBJECT, INFO ----------------
767                         case "object_info":
768                                 // prints public information about the object to the player
769                                 e = sandbox_ObjectEdit_Get(player, false);
770                                 if(e != NULL)
771                                 {
772                                         switch(argv(2))
773                                         {
774                                                 case "object":
775                                                         print_to(player, strcat("^2SANDBOX - INFO: ^7Object is owned by \"^7", e.netname, "^7\", created \"^3", e.message, "^7\", last edited \"^3", e.message2, "^7\""));
776                                                         return true;
777                                                 case "mesh":
778                                                         s = "";
779                                                         FOR_EACH_TAG(e)
780                                                                 s = strcat(s, "^7\"^5", gettaginfo_name, "^7\", ");
781                                                         print_to(player, strcat("^2SANDBOX - INFO: ^7Object mesh is \"^3", e.model, "^7\" at animation frame ^3", ftos(e.frame), " ^7containing the following tags: ", s));
782                                                         return true;
783                                                 case "attachments":
784                                                         // this should show the same info as 'mesh' but for attachments
785                                                         s = "";
786                                                         entity head;
787                                                         i = 0;
788                                                         for(head = NULL; (head = find(head, classname, "object")); )
789                                                         {
790                                                                 if(head.owner == e)
791                                                                 {
792                                                                         ++i; // start from 1
793                                                                         gettaginfo(e, head.tag_index);
794                                                                         s = strcat(s, "^1attachment ", ftos(i), "^7 has mesh \"^3", head.model, "^7\" at animation frame ^3", ftos(head.frame));
795                                                                         s = strcat(s, "^7 and is attached to bone \"^5", gettaginfo_name, "^7\", ");
796                                                                 }
797                                                         }
798                                                         if(i) // object contains attachments
799                                                                 print_to(player, strcat("^2SANDBOX - INFO: ^7Object contains the following ^1", ftos(i), "^7 attachment(s): ", s));
800                                                         else
801                                                                 print_to(player, "^2SANDBOX - INFO: ^7Object contains no attachments");
802                                                         return true;
803                                         }
804                                 }
805                                 print_to(player, "^1SANDBOX - WARNING: ^7No information could be found. Make sure you are facing an object");
806                                 return true;
807
808                         // ---------------- COMMAND: DEFAULT ----------------
809                         default:
810                                 print_to(player, "Invalid command. For usage information, type 'sandbox help'");
811                                 return true;
812                 }
813         }
814 }
815
816 MUTATOR_HOOKFUNCTION(sandbox, SV_StartFrame)
817 {
818         if(!autocvar_g_sandbox_storage_autosave)
819                 return;
820         if(time < autosave_time)
821                 return;
822         autosave_time = time + autocvar_g_sandbox_storage_autosave;
823
824         sandbox_Database_Save();
825
826         return true;
827 }
828 #endif