Declare more ints as ints
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / notifications.qc
1 #if defined(CSQC)
2 #elif defined(MENUQC)
3 #elif defined(SVQC)
4         #include "../dpdefs/progsdefs.qh"
5     #include "../dpdefs/dpextensions.qh"
6     #include "constants.qh"
7     #include "teams.qh"
8     #include "counting.qh"
9     #include "../server/autocvars.qh"
10     #include "../server/constants.qh"
11     #include "../server/defs.qh"
12     #include "notifications.qh"
13     #include "../server/mutators/mutators_include.qh"
14 #endif
15
16 // ================================================
17 //  Unified notification system, written by Samual
18 //  Last updated: August, 2013
19 // ================================================
20
21 string Get_Notif_TypeName(int net_type)
22 {
23         switch(net_type)
24         {
25                 case MSG_ANNCE: return "MSG_ANNCE";
26                 case MSG_INFO: return "MSG_INFO";
27                 case MSG_CENTER: return "MSG_CENTER";
28                 case MSG_CENTER_CPID: return "MSG_CENTER_CPID";
29                 case MSG_MULTI: return "MSG_MULTI";
30                 case MSG_CHOICE: return "MSG_CHOICE";
31         }
32         backtrace(sprintf("Get_Notif_TypeName(%d): Improper net type!\n", net_type));
33         return "";
34 }
35
36 entity Get_Notif_Ent(int net_type, int net_name)
37 {
38         switch(net_type)
39         {
40                 case MSG_ANNCE: return msg_annce_notifs[net_name - 1];
41                 case MSG_INFO: return msg_info_notifs[net_name - 1];
42                 case MSG_CENTER: return msg_center_notifs[net_name - 1];
43                 case MSG_MULTI: return msg_multi_notifs[net_name - 1];
44                 case MSG_CHOICE: return msg_choice_notifs[net_name - 1];
45         }
46         backtrace(sprintf("Get_Notif_Ent(%d, %d): Improper net type!\n", net_type, net_name));
47         return world;
48 }
49
50 #ifdef SVQC
51 #ifdef NOTIFICATIONS_DEBUG
52 string Get_Notif_BroadcastName(float broadcast)
53 {
54         switch(broadcast)
55         {
56                 case NOTIF_ONE: return "NOTIF_ONE";
57                 case NOTIF_ONE_ONLY: return "NOTIF_ONE_ONLY";
58                 case NOTIF_ALL_EXCEPT: return "NOTIF_ALL_EXCEPT";
59                 case NOTIF_ALL: return "NOTIF_ALL";
60                 case NOTIF_TEAM: return "NOTIF_TEAM";
61                 case NOTIF_TEAM_EXCEPT: return "NOTIF_TEAM_EXCEPT";
62         }
63         backtrace(sprintf("Get_Notif_BroadcastName(%d): Improper broadcast!\n", broadcast));
64         return "";
65 }
66 #endif
67 #endif
68
69 string Notification_CheckArgs_TypeName(float net_type, float net_name)
70 {
71         // check supplied type and name for errors
72         string checkargs = "";
73         #define CHECKARG_TYPENAME(type) case MSG_##type##: \
74                 { if(!net_name || (net_name > NOTIF_##type##_COUNT)) \
75                 { checkargs = sprintf("Improper name: %d!", net_name); } break; }
76         switch(net_type)
77         {
78                 CHECKARG_TYPENAME(ANNCE)
79                 CHECKARG_TYPENAME(INFO)
80                 CHECKARG_TYPENAME(CENTER)
81                 CHECKARG_TYPENAME(MULTI)
82                 CHECKARG_TYPENAME(CHOICE)
83                 default: { checkargs = sprintf("Improper type: %d!", checkargs, net_type); break; }
84         }
85         #undef CHECKARG_TYPENAME
86         return checkargs;
87 }
88
89 #ifdef SVQC
90 string Notification_CheckArgs(
91         float broadcast, entity client,
92         float net_type, float net_name)
93 {
94         // check supplied broadcast, target, type, and name for errors
95         string checkargs = Notification_CheckArgs_TypeName(net_type, net_name);
96         if(checkargs != "") { checkargs = strcat(checkargs, " "); }
97         switch(broadcast)
98         {
99                 case NOTIF_ONE:
100                 case NOTIF_ONE_ONLY:
101                 {
102                         if(IS_NOT_A_CLIENT(client))
103                                 { checkargs = sprintf("%sNo client provided!", checkargs); }
104                         break;
105                 }
106
107                 case NOTIF_ALL_EXCEPT:
108                 {
109                         if(IS_NOT_A_CLIENT(client))
110                                 { checkargs = sprintf("%sException can't be a non-client!", checkargs); }
111                         break;
112                 }
113
114                 case NOTIF_ALL:
115                 {
116                         if(client)
117                                 { checkargs = sprintf("%sEntity provided when world was required!", checkargs); }
118                         break;
119                 }
120
121                 case NOTIF_TEAM:
122                 {
123                         if (!teamplay)
124                                 { checkargs = sprintf("%sTeamplay not active!", checkargs); }
125                         //else if (!client.team) { checkargs = sprintf("%sNo team provided!", checkargs); }
126                         break;
127                 }
128
129                 case NOTIF_TEAM_EXCEPT:
130                 {
131                         if (!teamplay)
132                                 { checkargs = sprintf("%sTeamplay not active!", checkargs); }
133                         else if(IS_NOT_A_CLIENT(client))
134                                 { checkargs = sprintf("%sException can't be a non-client!", checkargs); }
135                         break;
136                 }
137
138                 default: { checkargs = sprintf("%sImproper broadcast: %d!", checkargs, broadcast); break; }
139         }
140         return checkargs;
141 }
142
143 float Notification_ShouldSend(float broadcast, entity to_client, entity other_client)
144 {
145         switch(broadcast)
146         {
147                 case NOTIF_ONE: // send to one client and their spectator
148                 {
149                         if(
150                                 (to_client == other_client)
151                                 ||
152                                 (
153                                         IS_SPEC(to_client)
154                                         &&
155                                         (to_client.enemy == other_client)
156                                 )
157                         ) { return true; }
158                         break;
159                 }
160                 case NOTIF_ONE_ONLY: // send ONLY to one client
161                 {
162                         if(to_client == other_client) { return true; }
163                         break;
164                 }
165                 case NOTIF_TEAM: // send only to X team and their spectators
166                 {
167                         if(
168                                 (to_client.team == other_client.team)
169                                 ||
170                                 (
171                                         IS_SPEC(to_client)
172                                         &&
173                                         (to_client.enemy.team == other_client.team)
174                                 )
175                         ) { return true; }
176                         break;
177                 }
178                 case NOTIF_TEAM_EXCEPT: // send only to X team and their spectators, except for Y person and their spectators
179                 {
180                         if(
181                                 (to_client != other_client)
182                                 &&
183                                 (
184                                         (to_client.team == other_client.team)
185                                         ||
186                                         (
187                                                 IS_SPEC(to_client)
188                                                 &&
189                                                 (
190                                                         (to_client.enemy != other_client)
191                                                         &&
192                                                         (to_client.enemy.team == other_client.team)
193                                                 )
194                                         )
195                                 )
196                         ) { return true; }
197                         break;
198                 }
199                 case NOTIF_ALL: // send to everyone
200                 {
201                         return true;
202                 }
203                 case NOTIF_ALL_EXCEPT: // send to everyone except X person and their spectators
204                 {
205                         if(
206                                 (to_client != other_client)
207                                 &&
208                                 !(
209                                         IS_SPEC(to_client)
210                                         &&
211                                         (to_client.enemy == other_client)
212                                 )
213                         ) { return true; }
214                         break;
215                 }
216         }
217         return false;
218 }
219
220 #endif
221
222 // ===============================
223 //  Initialization Core Functions
224 // ===============================
225
226 // used by restartnotifs command to initialize notifications
227 void Destroy_Notification_Entity(entity notif)
228 {
229         if(notif.nent_name != "") { strunzone(notif.nent_name); }
230         if(notif.nent_snd != "") { strunzone(notif.nent_snd); }
231         if(notif.nent_args != "") { strunzone(notif.nent_args); }
232         if(notif.nent_hudargs != "") { strunzone(notif.nent_hudargs); }
233         if(notif.nent_icon != "") { strunzone(notif.nent_icon); }
234         if(notif.nent_durcnt != "") { strunzone(notif.nent_durcnt); }
235         if(notif.nent_string != "") { strunzone(notif.nent_string); }
236         remove(notif);
237 }
238
239 void Destroy_All_Notifications(void)
240 {
241         entity notif;
242         int i;
243
244         #define DESTROY_LOOP(type,count) do { \
245                 for(i = 1; i <= count; ++i) \
246                 { \
247                         notif = Get_Notif_Ent(type, i); \
248                         if (!notif) { backtrace("Destroy_All_Notifications(): Missing notification entity!\n"); return; } \
249                         Destroy_Notification_Entity(notif); \
250                 } \
251         } while(0)
252
253         // kill all networked notifications and centerprints
254         #ifdef SVQC
255         Kill_Notification(NOTIF_ALL, world, 0, 0);
256         #else
257         reset_centerprint_messages();
258         #endif
259
260         // kill all real notification entities
261         DESTROY_LOOP(MSG_ANNCE, NOTIF_ANNCE_COUNT);
262         DESTROY_LOOP(MSG_INFO, NOTIF_INFO_COUNT);
263         DESTROY_LOOP(MSG_CENTER, NOTIF_CENTER_COUNT);
264         DESTROY_LOOP(MSG_MULTI, NOTIF_MULTI_COUNT);
265         DESTROY_LOOP(MSG_CHOICE, NOTIF_CHOICE_COUNT);
266         #undef DESTROY_LOOP
267 }
268
269 string Process_Notif_Line(
270         int typeId,
271         bool chat,
272         string input,
273         string notiftype,
274         string notifname,
275         string stringtype)
276 {
277         #ifdef CSQC
278         if(typeId == MSG_INFO)
279         {
280                 if((chat && autocvar_notification_allow_chatboxprint)
281                         || (autocvar_notification_allow_chatboxprint == 2))
282                 {
283                         // pass 1: add ETX char at beginning of line
284                         input = strcat("\{3}", input);
285
286                         // pass 2: add ETX char at end of each new line (so that
287                         // messages with multiple lines are put through chatbox too)
288                         input = strreplace("\n", "\n\{3}", input);
289
290                         // pass 3: strip trailing ETX char
291                         if(substring(input, (strlen(input) - 1), 1) == "\{3}")
292                                 { input = substring(input, 0, (strlen(input) - 1)); }
293                 }
294         }
295         #endif
296
297         // done to both MSG_INFO and MSG_CENTER
298         if(substring(input, (strlen(input) - 1), 1) == "\n")
299         {
300                 printf(
301                         strcat(
302                                 "^1TRAILING NEW LINE AT END OF NOTIFICATION: ",
303                                 "^7net_type = %s, net_name = %s, string = %s.\n"
304                         ),
305                         notiftype,
306                         notifname,
307                         stringtype
308                 );
309                 notif_error = true;
310                 input = substring(input, 1, (strlen(input) - 1));
311         }
312
313         return input;
314 }
315
316 string Process_Notif_Args(
317         float arg_type,
318         string args,
319         string notiftype,
320         string notifname)
321 {
322         string selected, remaining = args;
323         float sel_num = 0;
324
325         for (;(remaining != "");)
326         {
327                 selected = car(remaining); remaining = cdr(remaining);
328
329                 switch(arg_type)
330                 {
331                         case 1: // normal args
332                         {
333                                 if(sel_num == NOTIF_MAX_ARGS)
334                                 {
335                                         printf(
336                                                 strcat(
337                                                         "^1NOTIFICATION HAS TOO MANY ARGUMENTS: ",
338                                                         "^7net_type = %s, net_name = %s, max args = %d.\n"
339                                                 ),
340                                                 notiftype,
341                                                 notifname,
342                                                 NOTIF_MAX_ARGS
343                                         );
344                                         notif_error = true;
345                                         break;
346                                 }
347
348                                 switch(strtolower(selected))
349                                 {
350                                         #define ARG_CASE_ARG_CS_SV_HA(selected,result) case selected: { ++sel_num; break; }
351                                         #define ARG_CASE_ARG_CS_SV_DC(selected,result) case selected: { ++sel_num; break; }
352                                         #define ARG_CASE_ARG_CS_SV(selected,result)    case selected: { ++sel_num; break; }
353                                         #define ARG_CASE_ARG_CS(selected,result)       case selected: { ++sel_num; break; }
354                                         #define ARG_CASE_ARG_SV(selected,result)       case selected: { ++sel_num; break; }
355                                         #define ARG_CASE_ARG_DC(selected,result)
356                                         #define ARG_CASE(prog,selected,result)         ARG_CASE_##prog(selected,result)
357                                         NOTIF_ARGUMENT_LIST
358                                         #undef ARG_CASE
359                                         #undef ARG_CASE_ARG_DC
360                                         #undef ARG_CASE_ARG_SV
361                                         #undef ARG_CASE_ARG_CS
362                                         #undef ARG_CASE_ARG_CS_SV
363                                         #undef ARG_CASE_ARG_CS_SV_DC
364                                         #undef ARG_CASE_ARG_CS_SV_HA
365                                         default:
366                                         {
367                                                 printf(
368                                                         strcat(
369                                                                 "^1NOTIFICATION WITH UNKNOWN TOKEN IN ARGUMENT STRING: ",
370                                                                 "^7net_type = %s, net_name = %s, args arg = '%s'.\n"
371                                                         ),
372                                                         notiftype,
373                                                         notifname,
374                                                         selected
375                                                 );
376                                                 notif_error = true;
377                                                 break;
378                                         }
379                                 }
380                                 break;
381                         }
382                         case 2: // hudargs
383                         {
384                                 if(sel_num == NOTIF_MAX_HUDARGS)
385                                 {
386                                         printf(
387                                                 strcat(
388                                                         "^1NOTIFICATION HAS TOO MANY ARGUMENTS: ",
389                                                         "^7net_type = %s, net_name = %s, max hudargs = %d.\n"
390                                                 ),
391                                                 notiftype,
392                                                 notifname,
393                                                 NOTIF_MAX_HUDARGS
394                                         );
395                                         notif_error = true;
396                                         break;
397                                 }
398
399                                 switch(strtolower(selected))
400                                 {
401                                         #define ARG_CASE_ARG_CS_SV_HA(selected,result) case selected: { ++sel_num; break; }
402                                         #define ARG_CASE_ARG_CS_SV_DC(selected,result)
403                                         #define ARG_CASE_ARG_CS_SV(selected,result)
404                                         #define ARG_CASE_ARG_CS(selected,result)
405                                         #define ARG_CASE_ARG_SV(selected,result)
406                                         #define ARG_CASE_ARG_DC(selected,result)
407                                         #define ARG_CASE(prog,selected,result)         ARG_CASE_##prog(selected,result)
408                                         NOTIF_ARGUMENT_LIST
409                                         #undef ARG_CASE
410                                         #undef ARG_CASE_ARG_DC
411                                         #undef ARG_CASE_ARG_SV
412                                         #undef ARG_CASE_ARG_CS
413                                         #undef ARG_CASE_ARG_CS_SV
414                                         #undef ARG_CASE_ARG_CS_SV_DC
415                                         #undef ARG_CASE_ARG_CS_SV_HA
416                                         default:
417                                         {
418                                                 printf(
419                                                         strcat(
420                                                                 "^1NOTIFICATION WITH UNKNOWN TOKEN IN ARGUMENT STRING: ",
421                                                                 "^7net_type = %s, net_name = %s, hudargs arg = '%s'.\n"
422                                                         ),
423                                                         notiftype,
424                                                         notifname,
425                                                         selected
426                                                 );
427                                                 notif_error = true;
428                                                 break;
429                                         }
430                                 }
431                                 break;
432                         }
433                         case 3: // durcnt
434                         {
435                                 if(sel_num == NOTIF_MAX_DURCNT)
436                                 {
437                                         printf(
438                                                 strcat(
439                                                         "^1NOTIFICATION HAS TOO MANY ARGUMENTS: ",
440                                                         "^7net_type = %s, net_name = %s, max durcnt = %d.\n"
441                                                 ),
442                                                 notiftype,
443                                                 notifname,
444                                                 NOTIF_MAX_DURCNT
445                                         );
446                                         notif_error = true;
447                                         break;
448                                 }
449
450                                 switch(strtolower(selected))
451                                 {
452                                         #define ARG_CASE_ARG_CS_SV_HA(selected,result)
453                                         #define ARG_CASE_ARG_CS_SV_DC(selected,result) case selected: { ++sel_num; break; }
454                                         #define ARG_CASE_ARG_CS_SV(selected,result)
455                                         #define ARG_CASE_ARG_CS(selected,result)
456                                         #define ARG_CASE_ARG_SV(selected,result)
457                                         #define ARG_CASE_ARG_DC(selected,result)       case selected: { ++sel_num; break; }
458                                         #define ARG_CASE(prog,selected,result)         ARG_CASE_##prog(selected,result)
459                                         NOTIF_ARGUMENT_LIST
460                                         #undef ARG_CASE
461                                         #undef ARG_CASE_ARG_DC
462                                         #undef ARG_CASE_ARG_SV
463                                         #undef ARG_CASE_ARG_CS
464                                         #undef ARG_CASE_ARG_CS_SV
465                                         #undef ARG_CASE_ARG_CS_SV_DC
466                                         #undef ARG_CASE_ARG_CS_SV_HA
467                                         default:
468                                         {
469                                                 if(ftos(stof(selected)) != "") { ++sel_num; }
470                                                 else
471                                                 {
472                                                         printf(
473                                                                 strcat(
474                                                                         "^1NOTIFICATION WITH UNKNOWN TOKEN IN ARGUMENT STRING: ",
475                                                                         "^7net_type = %s, net_name = %s, durcnt arg = '%s'.\n"
476                                                                 ),
477                                                                 notiftype,
478                                                                 notifname,
479                                                                 selected
480                                                         );
481                                                         notif_error = true;
482                                                 }
483                                                 break;
484                                         }
485                                 }
486                                 break;
487                         }
488                 }
489         }
490         return args;
491 }
492
493 void Create_Notification_Entity(
494         float var_default,
495         float var_cvar,
496         int typeId,
497         int nameid,
498         string namestring,
499         int strnum,
500         int flnum,
501         /* MSG_ANNCE */
502         float channel,
503         string snd,
504         float vol,
505         float position,
506         /* MSG_INFO & MSG_CENTER */
507         string args,
508         string hudargs,
509         string icon,
510         float cpid,
511         string durcnt,
512         string normal,
513         string gentle,
514         /* MSG_MULTI */
515         int anncename,
516         int infoname,
517         int centername,
518         /* MSG_CHOICE */
519         float challow_def,
520         float challow_var,
521         int chtype,
522         int optiona,
523         int optionb)
524 {
525         // =====================
526         //  Global Entity Setup
527         // =====================
528         entity notif = spawn();
529         switch(typeId)
530         {
531                 case MSG_ANNCE:
532                 {
533                         msg_annce_notifs[nameid - 1] = notif;
534                         notif.classname = "msg_annce_notification";
535                         break;
536                 }
537                 case MSG_INFO:
538                 {
539                         msg_info_notifs[nameid - 1] = notif;
540                         notif.classname = "msg_info_notification";
541                         break;
542                 }
543                 case MSG_CENTER:
544                 {
545                         msg_center_notifs[nameid - 1] = notif;
546                         notif.classname = "msg_center_notification";
547                         break;
548                 }
549                 case MSG_MULTI:
550                 {
551                         msg_multi_notifs[nameid - 1] = notif;
552                         notif.classname = "msg_multi_notification";
553                         break;
554                 }
555                 case MSG_CHOICE:
556                 {
557                         msg_choice_notifs[nameid - 1] = notif;
558                         notif.classname = "msg_choice_notification";
559                         break;
560                 }
561
562                 default:
563                 {
564                         error(sprintf(
565                                 strcat(
566                                         "^1NOTIFICATION WITH IMPROPER TYPE: ",
567                                         "^7net_type = %d, net_name = %s.\n"
568                                 ),
569                                 typeId,
570                                 namestring
571                         ));
572                         return; // It's not possible to recover from this one
573                 }
574         }
575         notif.nent_default = var_default;
576         notif.nent_enabled = (1 <= var_cvar);
577         notif.nent_type = typeId;
578         notif.nent_id = nameid;
579         notif.nent_name = strzone(namestring);
580
581         string typestring = Get_Notif_TypeName(typeId);
582
583         // Other pre-notif-setup requisites
584         notif_error = false;
585
586         // ====================
587         //  Notification Setup
588         // ====================
589         switch(typeId)
590         {
591                 case MSG_ANNCE:
592                 {
593                         // Set MSG_ANNCE information and handle precaching
594                         #ifdef CSQC
595                         if (!(GENTLE && (var_cvar == 1)))
596                         {
597                                 if(snd != "")
598                                 {
599                                         if(notif.nent_enabled)
600                                         {
601                                                 precache_sound(sprintf("announcer/%s/%s.wav", autocvar_cl_announcer, snd));
602                                                 notif.nent_channel = channel;
603                                                 notif.nent_snd = strzone(snd);
604                                                 notif.nent_vol = vol;
605                                                 notif.nent_position = position;
606                                         }
607                                 }
608                                 else
609                                 {
610                                         printf(
611                                                 strcat(
612                                                         "^1NOTIFICATION WITH NO SOUND: ",
613                                                         "^7net_type = %s, net_name = %s.\n"
614                                                 ),
615                                                 typestring,
616                                                 namestring
617                                         );
618                                         notif_error = true;
619                                 }
620                         }
621                         else { notif.nent_enabled = false; }
622                         #else
623                         notif.nent_enabled = false;
624                         #endif
625
626                         break;
627                 }
628
629                 case MSG_INFO:
630                 case MSG_CENTER:
631                 {
632                         // Set MSG_INFO and MSG_CENTER string/float counts
633                         notif.nent_stringcount = strnum;
634                         notif.nent_floatcount = flnum;
635
636                         // Only initialize arguments if we're either a client or on a dedicated server
637                         #ifdef SVQC
638                         float should_process_args = server_is_dedicated;
639                         #else
640                         float should_process_args = true;
641                         #endif
642
643                         if(should_process_args)
644                         {
645                                 // ========================
646                                 //  Process Main Arguments
647                                 // ========================
648                                 if(strnum + flnum)
649                                 {
650                                         if(args != "")
651                                         {
652                                                 notif.nent_args = strzone(
653                                                         Process_Notif_Args(1, args, typestring, namestring));
654                                         }
655                                         else if((hudargs == "") && (durcnt ==""))
656                                         {
657                                                 printf(
658                                                         strcat(
659                                                                 "^1NOTIFICATION HAS ARG COUNTS BUT NO ARGS OR HUDARGS OR DURCNT: ",
660                                                                 "^7net_type = %s, net_name = %s, strnum = %d, flnum = %d\n"
661                                                         ),
662                                                         typestring,
663                                                         namestring,
664                                                         strnum,
665                                                         flnum
666                                                 );
667                                                 notif_error = true;
668                                         }
669                                 }
670                                 else if(args != "")
671                                 {
672                                         notif.nent_args = strzone(
673                                                 Process_Notif_Args(1, args, typestring, namestring));
674                                 }
675
676
677                                 // =======================================
678                                 //  Process HUD and Centerprint Arguments
679                                 //    Only processed on CSQC, as these
680                                 //    args are only for HUD features.
681                                 // =======================================
682                                 #ifdef CSQC
683                                 if(hudargs != "")
684                                 {
685                                         notif.nent_hudargs = strzone(
686                                                 Process_Notif_Args(2, hudargs, typestring, namestring));
687
688                                         if(icon != "") { notif.nent_icon = strzone(icon); }
689                                         else
690                                         {
691                                                 printf(
692                                                         strcat(
693                                                                 "^1NOTIFICATION HAS HUDARGS BUT NO ICON: ",
694                                                                 "^7net_type = %s, net_name = %s.\n"
695                                                         ),
696                                                         typestring,
697                                                         namestring
698                                                 );
699                                                 notif_error = true;
700                                         }
701                                 }
702                                 else if(icon != "")
703                                 {
704                                         printf(
705                                                 strcat(
706                                                         "^1NOTIFICATION HAS ICON BUT NO HUDARGS: ",
707                                                         "^7net_type = %s, net_name = %s.\n"
708                                                 ),
709                                                 typestring,
710                                                 namestring
711                                         );
712                                         notif_error = true;
713                                 }
714
715                                 if(durcnt != "")
716                                 {
717                                         notif.nent_durcnt = strzone(
718                                                 Process_Notif_Args(3, durcnt, typestring, namestring));
719
720                                         if(cpid != NO_MSG) { notif.nent_cpid = cpid; }
721                                         else
722                                         {
723                                                 printf(
724                                                         strcat(
725                                                                 "^1NOTIFICATION HAS DURCNT BUT NO CPID: ",
726                                                                 "^7net_type = %s, net_name = %s.\n"
727                                                         ),
728                                                         typestring,
729                                                         namestring
730                                                 );
731                                                 notif_error = true;
732                                         }
733                                 }
734                                 else if(cpid != NO_MSG) { notif.nent_cpid = cpid; }
735                                 #endif
736
737
738                                 // ======================
739                                 //  Process Notif String
740                                 // ======================
741                                 #define SET_NOTIF_STRING(string,stringname) do { \
742                                         notif.nent_string = strzone(CCR( \
743                                                 Process_Notif_Line( \
744                                                         typeId, \
745                                                         (var_cvar > 1), \
746                                                         string, \
747                                                         typestring, \
748                                                         namestring, \
749                                                         stringname \
750                                                 )) \
751                                         ); \
752                                 } while(0)
753
754                                 if(GENTLE)
755                                 {
756                                         if(gentle != "") { SET_NOTIF_STRING(gentle, "GENTLE"); }
757                                         else if(normal != "") { SET_NOTIF_STRING(normal, "NORMAL"); }
758                                 }
759                                 else if(normal != "") { SET_NOTIF_STRING(normal, "NORMAL"); }
760                                 #undef SET_NOTIF_STRING
761
762                                 // Check to make sure a string was chosen
763                                 if(notif.nent_string == "")
764                                 {
765                                         printf(
766                                                 strcat(
767                                                         "^1EMPTY NOTIFICATION: ",
768                                                         "^7net_type = %s, net_name = %s.\n"
769                                                 ),
770                                                 typestring,
771                                                 namestring
772                                         );
773                                         notif_error = true;
774                                 }
775                         }
776
777                         break;
778                 }
779
780                 case MSG_MULTI:
781                 {
782                         // Set MSG_MULTI string/float counts
783                         if((anncename == NO_MSG) && (infoname == NO_MSG) && (centername == NO_MSG))
784                         {
785                                 printf(
786                                         strcat(
787                                                 "^1NOTIFICATION WITH NO SUBCALLS: ",
788                                                 "^7net_type = %s, net_name = %s.\n"
789                                         ),
790                                         typestring,
791                                         namestring
792                                 );
793                                 notif_error = true;
794                         }
795                         else
796                         {
797                                 // announcements don't actually need any arguments, so lets not even count them.
798                                 if(anncename != NO_MSG) { notif.nent_msgannce = msg_annce_notifs[anncename - 1]; }
799
800                                 float infoname_stringcount = 0, infoname_floatcount = 0;
801                                 float centername_stringcount = 0, centername_floatcount = 0;
802
803                                 if(infoname != NO_MSG)
804                                 {
805                                         notif.nent_msginfo = msg_info_notifs[infoname - 1];
806                                         infoname_stringcount = notif.nent_msginfo.nent_stringcount;
807                                         infoname_floatcount = notif.nent_msginfo.nent_floatcount;
808                                 }
809
810                                 if(centername != NO_MSG)
811                                 {
812                                         notif.nent_msgcenter = msg_center_notifs[centername - 1];
813                                         centername_stringcount = notif.nent_msgcenter.nent_stringcount;
814                                         centername_floatcount = notif.nent_msgcenter.nent_floatcount;
815                                 }
816
817                                 // set the requirements of THIS notification to the totals of its subcalls
818                                 notif.nent_stringcount = max(infoname_stringcount, centername_stringcount);
819                                 notif.nent_floatcount = max(infoname_floatcount, centername_floatcount);
820                         }
821
822                         break;
823                 }
824
825                 case MSG_CHOICE:
826                 {
827                         if((chtype == NO_MSG) || (optiona == NO_MSG) || (optionb == NO_MSG))
828                         {
829                                 printf(
830                                         strcat(
831                                                 "^1NOTIFICATION IS MISSING CHOICE PARAMS: ",
832                                                 "^7net_type = %s, net_name = %s.\n"
833                                         ),
834                                         typestring,
835                                         namestring
836                                 );
837                                 notif_error = true;
838                         }
839                         else
840                         {
841                                 switch(chtype)
842                                 {
843                                         case MSG_ANNCE:
844                                         {
845                                                 notif.nent_optiona = msg_annce_notifs[optiona - 1];
846                                                 notif.nent_optionb = msg_annce_notifs[optionb - 1];
847                                                 break;
848                                         }
849                                         case MSG_INFO:
850                                         {
851                                                 notif.nent_optiona = msg_info_notifs[optiona - 1];
852                                                 notif.nent_optionb = msg_info_notifs[optionb - 1];
853                                                 break;
854                                         }
855                                         case MSG_CENTER:
856                                         {
857                                                 notif.nent_optiona = msg_center_notifs[optiona - 1];
858                                                 notif.nent_optionb = msg_center_notifs[optionb - 1];
859                                                 break;
860                                         }
861                                         case MSG_MULTI:
862                                         {
863                                                 notif.nent_optiona = msg_multi_notifs[optiona - 1];
864                                                 notif.nent_optionb = msg_multi_notifs[optionb - 1];
865                                                 break;
866                                         }
867                                         case MSG_CHOICE: // should we REALLY allow nested options?...
868                                         {
869                                                 notif.nent_optiona = msg_choice_notifs[optiona - 1];
870                                                 notif.nent_optionb = msg_choice_notifs[optionb - 1];
871                                                 break;
872                                         }
873
874                                         default:
875                                         {
876                                                 printf(
877                                                         strcat(
878                                                                 "^1NOTIFICATION WITH IMPROPER TYPE: ",
879                                                                 "^7net_type = %d, net_name = %s.\n"
880                                                         ),
881                                                         typeId,
882                                                         namestring
883                                                 );
884                                                 notif_error = true;
885                                                 break;
886                                         }
887                                 }
888                                 notif.nent_challow_def = challow_def; // 0: never allowed, 1: allowed in warmup, 2: always allowed
889                                 notif.nent_challow_var = challow_var; // 0: never allowed, 1: allowed in warmup, 2: always allowed
890                                 notif.nent_stringcount = max(notif.nent_optiona.nent_stringcount, notif.nent_optionb.nent_stringcount);
891                                 notif.nent_floatcount = max(notif.nent_optiona.nent_floatcount, notif.nent_optionb.nent_floatcount);
892
893                                 /*#ifdef NOTIFICATIONS_DEBUG
894                                 Debug_Notification(sprintf(
895                                         "Create_Notification_Entity(...): MSG_CHOICE: %s\n%s\n%s\n",
896                                         notif.nent_name,
897                                         sprintf(
898                                                 "^ optiona: %s %s : %d %d",
899                                                 Get_Notif_TypeName(notif.nent_optiona.nent_type),
900                                                 notif.nent_optiona.nent_name,
901                                                 notif.nent_optiona.nent_stringcount,
902                                                 notif.nent_optiona.nent_floatcount
903                                         ),
904                                         sprintf(
905                                                 "^ optionb: %s %s : %d %d",
906                                                 Get_Notif_TypeName(notif.nent_optionb.nent_type),
907                                                 notif.nent_optionb.nent_name,
908                                                 notif.nent_optionb.nent_stringcount,
909                                                 notif.nent_optionb.nent_floatcount
910                                         )
911                                 ));
912                                 #endif*/
913                         }
914                         break;
915                 }
916
917                 default:
918                 {
919                         printf(
920                                 strcat(
921                                         "^1NOTIFICATION WITH IMPROPER TYPE: ",
922                                         "^7net_type = %d, net_name = %s.\n"
923                                 ),
924                                 typeId,
925                                 namestring
926                         );
927                         notif_error = true;
928                         break;
929                 }
930         }
931
932         // now check to see if any errors happened
933         if(notif_error)
934         {
935                 notif.nent_enabled = false; // disable the notification so it can't cause trouble
936                 notif_global_error = true; // throw the red flag that an error happened on init
937         }
938 }
939
940
941 // ===============
942 //  Cvar Handling
943 // ===============
944
945 // used by MSG_CHOICE to build list of choices
946 #ifdef SVQC
947 void Notification_GetCvars(void)
948 {
949         for(int i = 0; i <= NOTIF_CHOICE_COUNT; ++i)
950         {
951                 GetCvars_handleFloat(
952                         get_cvars_s,
953                         get_cvars_f,
954                         msg_choice_choices[i],
955                         sprintf("notification_%s", msg_choice_notifs[i].nent_name)
956                 );
957         }
958 }
959 #endif
960
961 // used to output notifications.cfg file
962 void Dump_Notifications(float fh, float alsoprint)
963 {
964         #define NOTIF_WRITE(a) { \
965                 fputs(fh, a); \
966                 if(alsoprint) { print(a); } }
967         #define NOTIF_WRITE_ENTITY(description) { \
968                 notif_msg = \
969                         sprintf( \
970                                 "seta notification_%s \"%d\" \"%s\"\n", \
971                                 e.nent_name, e.nent_default, description \
972                         ); \
973                 NOTIF_WRITE(notif_msg) }
974         #define NOTIF_WRITE_ENTITY_CHOICE(descriptiona,descriptionb) { \
975                 notif_msg = \
976                         sprintf( \
977                                 "seta notification_%s \"%d\" \"%s\"\n" \
978                                 "seta notification_%s_ALLOWED \"%d\" \"%s\"\n", \
979                                 e.nent_name, e.nent_default, descriptiona, \
980                                 e.nent_name, e.nent_challow_def, descriptionb \
981                         ); \
982                 NOTIF_WRITE(notif_msg) }
983         #define NOTIF_WRITE_HARDCODED(cvar,default,description) { \
984                 notif_msg = \
985                         sprintf( \
986                                 "seta notification_%s \"%s\" \"%s\"\n", \
987                                 cvar, default, description \
988                         ); \
989                 NOTIF_WRITE(notif_msg) }
990
991         string notif_msg;
992         int i;
993         entity e;
994
995         // Note: This warning only applies to the notifications.cfg file that is output...
996
997         // You ARE supposed to manually edit this function to add i.e. hard coded
998         // notification variables for mutators or game modes or such and then
999         // regenerate the notifications.cfg file from the new code.
1000
1001         NOTIF_WRITE("// ********************************************** //\n");
1002         NOTIF_WRITE("// ** WARNING - DO NOT MANUALLY EDIT THIS FILE ** //\n");
1003         NOTIF_WRITE("// **                                          ** //\n");
1004         NOTIF_WRITE("// **  This file is automatically generated    ** //\n");
1005         NOTIF_WRITE("// **  by code with the command 'dumpnotifs'.  ** //\n");
1006         NOTIF_WRITE("// **                                          ** //\n");
1007         NOTIF_WRITE("// **  If you add a new notification, please   ** //\n");
1008         NOTIF_WRITE("// **  regenerate this file with that command  ** //\n");
1009         NOTIF_WRITE("// **  making sure that the output matches     ** //\n");
1010         NOTIF_WRITE("// **  with the lists and defaults in code.    ** //\n");
1011         NOTIF_WRITE("// **                                          ** //\n");
1012         NOTIF_WRITE("// ********************************************** //\n");
1013
1014         // These notifications will also append their string as a comment...
1015         // This is not necessary, and does not matter if they vary between config versions,
1016         // it is just a semi-helpful tool for those who want to manually change their user settings.
1017
1018         NOTIF_WRITE(sprintf("\n// MSG_ANNCE notifications (count = %d):\n", NOTIF_ANNCE_COUNT));
1019         for(i = 1; i <= NOTIF_ANNCE_COUNT; ++i)
1020         {
1021                 e = Get_Notif_Ent(MSG_ANNCE, i);
1022                 if (!e) { backtrace("Dump_Notifications(): Missing notification entity!\n"); return; }
1023
1024                 NOTIF_WRITE_ENTITY(
1025                         "0 = disabled, 1 = enabled if gentle mode is off, 2 = always enabled"
1026                 );
1027         }
1028
1029         NOTIF_WRITE(sprintf("\n// MSG_INFO notifications (count = %d):\n", NOTIF_INFO_COUNT));
1030         for(i = 1; i <= NOTIF_INFO_COUNT; ++i)
1031         {
1032                 e = Get_Notif_Ent(MSG_INFO, i);
1033                 if (!e) { backtrace("Dump_Notifications(): Missing notification entity!\n"); return; }
1034
1035                 NOTIF_WRITE_ENTITY(
1036                         "0 = off, 1 = print to console, "
1037                         "2 = print to console and chatbox (if notification_allow_chatboxprint is enabled)"
1038                 );
1039         }
1040
1041         NOTIF_WRITE(sprintf("\n// MSG_CENTER notifications (count = %d):\n", NOTIF_CENTER_COUNT));
1042         for(i = 1; i <= NOTIF_CENTER_COUNT; ++i)
1043         {
1044                 e = Get_Notif_Ent(MSG_CENTER, i);
1045                 if (!e) { backtrace("Dump_Notifications(): Missing notification entity!\n"); return; }
1046
1047                 NOTIF_WRITE_ENTITY(
1048                         "0 = off, 1 = centerprint"
1049                 );
1050         }
1051
1052         NOTIF_WRITE(sprintf("\n// MSG_MULTI notifications (count = %d):\n", NOTIF_MULTI_COUNT));
1053         for(i = 1; i <= NOTIF_MULTI_COUNT; ++i)
1054         {
1055                 e = Get_Notif_Ent(MSG_MULTI, i);
1056                 if (!e) { backtrace("Dump_Notifications(): Missing notification entity!\n"); return; }
1057
1058                 NOTIF_WRITE_ENTITY(
1059                         "Enable this multiple notification"
1060                 );
1061         }
1062
1063         NOTIF_WRITE(sprintf("\n// MSG_CHOICE notifications (count = %d):\n", NOTIF_CHOICE_COUNT));
1064         for(i = 1; i <= NOTIF_CHOICE_COUNT; ++i)
1065         {
1066                 e = Get_Notif_Ent(MSG_CHOICE, i);
1067                 if (!e) { backtrace("Dump_Notifications(): Missing notification entity!\n"); return; }
1068
1069                 NOTIF_WRITE_ENTITY_CHOICE(
1070                         "Choice for this notification 0 = off, 1 = default message, 2 = verbose message",
1071                         "Allow choice for this notification 0 = off, 1 = only in warmup mode, 2 = always"
1072                 );
1073         }
1074
1075         // edit these to match whichever cvars are used for specific notification options
1076         NOTIF_WRITE("\n// HARD CODED notification variables:\n");
1077
1078         NOTIF_WRITE_HARDCODED(
1079                 "allow_chatboxprint", "1",
1080                 "Allow INFO notifications to be printed to chat box"
1081                 "0 = do not allow, "
1082                 "1 = allow only if allowed by individual notification_INFO* cvars, "
1083                 "2 = force all INFO notifications to be printed to the chatbox"
1084         );
1085
1086         NOTIF_WRITE_HARDCODED(
1087                 "debug", "0",
1088                 "Print extra debug information on all notification function calls "
1089                 "(Requires -DNOTIFICATIONS_DEBUG flag to be enabled on QCSRC compilation)... "
1090                 "0 = disabled, 1 = dprint, 2 = print"
1091         );
1092
1093         NOTIF_WRITE_HARDCODED(
1094                 "errors_are_fatal", "1",
1095                 "If a notification fails upon initialization, cause a Host_Error to stop the program"
1096         );
1097
1098         NOTIF_WRITE_HARDCODED(
1099                 "item_centerprinttime", "1.5",
1100                 "How long to show item information centerprint messages (like 'You got the Electro' or such)"
1101         );
1102
1103         NOTIF_WRITE_HARDCODED(
1104                 "lifetime_mapload", "10",
1105                 "Amount of time that notification entities last immediately at mapload (in seconds) "
1106                 "to help prevent notifications from being lost on early init (like gamestart countdown)"
1107         );
1108
1109         NOTIF_WRITE_HARDCODED(
1110                 "lifetime_runtime", "0.5",
1111                 "Amount of time that notification entities last on the server during runtime (In seconds)"
1112         );
1113
1114         NOTIF_WRITE_HARDCODED(
1115                 "server_allows_location", "1",
1116                 "Server side cvar for allowing death messages to show location information too"
1117         );
1118
1119         NOTIF_WRITE_HARDCODED(
1120                 "show_location", "0",
1121                 "Append location information to MSG_INFO death/kill messages"
1122         );
1123
1124         NOTIF_WRITE_HARDCODED(
1125                 "show_location_string", "",
1126                 "Replacement string piped into sprintf, "
1127                 "so you can do different messages like this: ' at the %s' or ' (near %s)'"
1128         );
1129
1130         NOTIF_WRITE_HARDCODED(
1131                 "show_sprees", "1",
1132                 "Print information about sprees in death/kill messages"
1133         );
1134
1135         NOTIF_WRITE_HARDCODED(
1136                 "show_sprees_center", "1",
1137                 "Show spree information in MSG_CENTER messages... "
1138                 "0 = off, 1 = target (but only for first victim) and attacker"
1139         );
1140
1141         NOTIF_WRITE_HARDCODED(
1142                 "show_sprees_center_specialonly", "1",
1143                 "Don't show spree information in MSG_CENTER messages if it isn't an achievement"
1144         );
1145
1146         NOTIF_WRITE_HARDCODED(
1147                 "show_sprees_info", "3",
1148                 "Show spree information in MSG_INFO messages... "
1149                 "0 = off, 1 = target only, 2 = attacker only, 3 = target and attacker"
1150         );
1151
1152         NOTIF_WRITE_HARDCODED(
1153                 "show_sprees_info_newline", "1",
1154                 "Show attacker spree information for MSG_INFO messages on a separate line than the death notification itself"
1155         );
1156
1157         NOTIF_WRITE_HARDCODED(
1158                 "show_sprees_info_specialonly", "1",
1159                 "Don't show attacker spree information in MSG_INFO messages if it isn't an achievement"
1160         );
1161
1162         NOTIF_WRITE(sprintf(
1163                 strcat(
1164                         "\n// Notification counts (total = %d): ",
1165                         "MSG_ANNCE = %d, MSG_INFO = %d, MSG_CENTER = %d, MSG_MULTI = %d, MSG_CHOICE = %d\n"
1166                 ),
1167                 (
1168                         NOTIF_ANNCE_COUNT +
1169                         NOTIF_INFO_COUNT +
1170                         NOTIF_CENTER_COUNT +
1171                         NOTIF_MULTI_COUNT +
1172                         NOTIF_CHOICE_COUNT
1173                 ),
1174                 NOTIF_ANNCE_COUNT,
1175                 NOTIF_INFO_COUNT,
1176                 NOTIF_CENTER_COUNT,
1177                 NOTIF_MULTI_COUNT,
1178                 NOTIF_CHOICE_COUNT
1179         ));
1180
1181         return;
1182         #undef NOTIF_WRITE_HARDCODED
1183         #undef NOTIF_WRITE_ENTITY
1184         #undef NOTIF_WRITE
1185 }
1186
1187
1188 // ===============================
1189 //  Frontend Notification Pushing
1190 // ===============================
1191
1192 #ifdef NOTIFICATIONS_DEBUG
1193 void Debug_Notification(string input)
1194 {
1195         switch(autocvar_notification_debug)
1196         {
1197                 case 1: { dprint(input); break; }
1198                 case 2: { print(input); break; }
1199         }
1200 }
1201 #endif
1202
1203 string Local_Notification_sprintf(
1204         string input, string args,
1205         string s1, string s2, string s3, string s4,
1206         int f1, float f2, float f3, float f4)
1207 {
1208         #ifdef NOTIFICATIONS_DEBUG
1209         Debug_Notification(sprintf(
1210                 "Local_Notification_sprintf('%s^7', '%s', %s, %s);\n",
1211                 MakeConsoleSafe(input),
1212                 args,
1213                 MakeConsoleSafe(sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4)),
1214                 sprintf("%d, %d, %d, %d", f1, f2, f3, f4)
1215         ));
1216         #endif
1217
1218         string selected;
1219         int sel_num;
1220         for(sel_num = 0; sel_num < NOTIF_MAX_ARGS; ++sel_num) { arg_slot[sel_num] = ""; }
1221
1222         string tmp_s;
1223
1224         for(sel_num = 0;(args != "");)
1225         {
1226                 selected = car(args); args = cdr(args);
1227                 NOTIF_HIT_MAX(NOTIF_MAX_ARGS, "Local_Notification_sprintf");
1228                 switch(strtolower(selected))
1229                 {
1230                         #ifdef CSQC
1231                         #define ARG_CASE_ARG_CS_SV_HA(selected,result) case selected: { arg_slot[sel_num] = result; ++sel_num; break; }
1232                         #define ARG_CASE_ARG_CS_SV_DC(selected,result) case selected: { arg_slot[sel_num] = result; ++sel_num; break; }
1233                         #define ARG_CASE_ARG_CS_SV(selected,result)    case selected: { arg_slot[sel_num] = result; ++sel_num; break; }
1234                         #define ARG_CASE_ARG_CS(selected,result)       case selected: { arg_slot[sel_num] = result; ++sel_num; break; }
1235                         #define ARG_CASE_ARG_SV(selected,result)
1236                         #define ARG_CASE_ARG_DC(selected,result)
1237                         #else
1238                         #define ARG_CASE_ARG_CS_SV_HA(selected,result) case selected: { arg_slot[sel_num] = result; ++sel_num; break; }
1239                         #define ARG_CASE_ARG_CS_SV_DC(selected,result) case selected: { arg_slot[sel_num] = result; ++sel_num; break; }
1240                         #define ARG_CASE_ARG_CS_SV(selected,result)    case selected: { arg_slot[sel_num] = result; ++sel_num; break; }
1241                         #define ARG_CASE_ARG_CS(selected,result)
1242                         #define ARG_CASE_ARG_SV(selected,result)       case selected: { arg_slot[sel_num] = result; ++sel_num; break; }
1243                         #define ARG_CASE_ARG_DC(selected,result)
1244                         #endif
1245                         #define ARG_CASE(prog,selected,result)         ARG_CASE_##prog(selected,result)
1246                         NOTIF_ARGUMENT_LIST
1247                         #undef ARG_CASE
1248                         #undef ARG_CASE_ARG_DC
1249                         #undef ARG_CASE_ARG_SV
1250                         #undef ARG_CASE_ARG_CS
1251                         #undef ARG_CASE_ARG_CS_SV
1252                         #undef ARG_CASE_ARG_CS_SV_DC
1253                         #undef ARG_CASE_ARG_CS_SV_HA
1254                         default: NOTIF_HIT_UNKNOWN(NOTIF_MAX_ARGS, "Local_Notification_sprintf")
1255                 }
1256         }
1257         return sprintf(
1258                 strcat(input, "\n"),
1259                 arg_slot[0],
1260                 arg_slot[1],
1261                 arg_slot[2],
1262                 arg_slot[3],
1263                 arg_slot[4],
1264                 arg_slot[5],
1265                 arg_slot[6]
1266         );
1267 }
1268
1269 #ifdef CSQC
1270 void Local_Notification_sound(
1271         float soundchannel, string soundfile,
1272         float soundvolume, float soundposition)
1273 {
1274         if((soundfile != prev_soundfile) || (time >= (prev_soundtime + autocvar_cl_announcer_antispam)))
1275         {
1276                 #ifdef NOTIFICATIONS_DEBUG
1277                 Debug_Notification(sprintf(
1278                         "Local_Notification_sound(world, %f, '%s', %f, %f);\n",
1279                         soundchannel,
1280                         sprintf(
1281                                 "announcer/%s/%s.wav",
1282                                 autocvar_cl_announcer,
1283                                 soundfile
1284                         ),
1285                         soundvolume,
1286                         soundposition
1287                 ));
1288                 #endif
1289
1290                 sound(
1291                         world,
1292                         soundchannel,
1293                         sprintf(
1294                                 "announcer/%s/%s.wav",
1295                                 autocvar_cl_announcer,
1296                                 soundfile
1297                         ),
1298                         soundvolume,
1299                         soundposition
1300                 );
1301
1302                 if(prev_soundfile) { strunzone(prev_soundfile); }
1303                 prev_soundfile = strzone(soundfile);
1304                 prev_soundtime = time;
1305         }
1306         else
1307         {
1308                 #ifdef NOTIFICATIONS_DEBUG
1309                 Debug_Notification(sprintf(
1310                         strcat(
1311                                 "Local_Notification_sound(world, %f, '%s', %f, %f) ",
1312                                 "^1BLOCKED BY ANTISPAM:^7 prevsnd: '%s', timediff: %f, limit: %f\n"
1313                          ),
1314                         soundchannel,
1315                         sprintf(
1316                                 "announcer/%s/%s.wav",
1317                                 autocvar_cl_announcer,
1318                                 soundfile
1319                         ),
1320                         soundvolume,
1321                         soundposition,
1322                         prev_soundfile,
1323                         (time - prev_soundtime),
1324                         autocvar_cl_announcer_antispam
1325                 ));
1326                 #endif
1327         }
1328 }
1329
1330 void Local_Notification_HUD_Notify_Push(
1331         string icon, string hudargs,
1332         string s1, string s2, string s3, string s4,
1333         float f1, float f2, float f3, float f4)
1334 {
1335         string selected;
1336         arg_slot[0] = ""; arg_slot[1] = "";
1337
1338         int sel_num;
1339         for(sel_num = 0;(hudargs != "");)
1340         {
1341                 selected = car(hudargs); hudargs = cdr(hudargs);
1342                 NOTIF_HIT_MAX(NOTIF_MAX_HUDARGS, "Local_Notification_HUD_Notify_Push");
1343                 switch(strtolower(selected))
1344                 {
1345                         #define ARG_CASE_ARG_CS_SV_HA(selected,result) case selected: { arg_slot[sel_num] = result; ++sel_num; break; }
1346                         #define ARG_CASE_ARG_CS_SV_DC(selected,result)
1347                         #define ARG_CASE_ARG_CS_SV(selected,result)
1348                         #define ARG_CASE_ARG_CS(selected,result)
1349                         #define ARG_CASE_ARG_SV(selected,result)
1350                         #define ARG_CASE_ARG_DC(selected,result)
1351                         #define ARG_CASE(prog,selected,result)         ARG_CASE_##prog(selected,result)
1352                         NOTIF_ARGUMENT_LIST
1353                         #undef ARG_CASE
1354                         #undef ARG_CASE_ARG_DC
1355                         #undef ARG_CASE_ARG_SV
1356                         #undef ARG_CASE_ARG_CS
1357                         #undef ARG_CASE_ARG_CS_SV
1358                         #undef ARG_CASE_ARG_CS_SV_DC
1359                         #undef ARG_CASE_ARG_CS_SV_HA
1360                         default: NOTIF_HIT_UNKNOWN(NOTIF_MAX_HUDARGS, "Local_Notification_HUD_Notify_Push")
1361                 }
1362         }
1363         #ifdef NOTIFICATIONS_DEBUG
1364         Debug_Notification(sprintf(
1365                 "Local_Notification_HUD_Notify_Push('%s^7', '%s', %s, %s, %s);\n",
1366                 icon,
1367                 hudargs,
1368                 MakeConsoleSafe(sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4)),
1369                 sprintf("%d, %d, %d, %d", f1, f2, f3, f4),
1370                 MakeConsoleSafe(sprintf("'%s^7', '%s^7'", stof(arg_slot[0]), stof(arg_slot[1])))
1371         ));
1372         #endif
1373         HUD_Notify_Push(icon, arg_slot[0], arg_slot[1]);
1374 }
1375
1376 void Local_Notification_centerprint_generic(
1377         string input, string durcnt,
1378         int cpid, float f1, float f2)
1379 {
1380         arg_slot[0] = ""; arg_slot[1] = "";
1381
1382         for(int sel_num = 0;(durcnt != "");)
1383         {
1384                 string selected = car(durcnt); durcnt = cdr(durcnt);
1385                 NOTIF_HIT_MAX(NOTIF_MAX_DURCNT, "Local_Notification_centerprint_generic");
1386                 switch(strtolower(selected))
1387                 {
1388                         #define ARG_CASE_ARG_CS_SV_HA(selected,result)
1389                         #define ARG_CASE_ARG_CS_SV_DC(selected,result) case selected: { arg_slot[sel_num] = result; ++sel_num; break; }
1390                         #define ARG_CASE_ARG_CS_SV(selected,result)
1391                         #define ARG_CASE_ARG_CS(selected,result)
1392                         #define ARG_CASE_ARG_SV(selected,result)
1393                         #define ARG_CASE_ARG_DC(selected,result)       case selected: { arg_slot[sel_num] = result; ++sel_num; break; }
1394                         #define ARG_CASE(prog,selected,result)         ARG_CASE_##prog(selected,result)
1395                         NOTIF_ARGUMENT_LIST
1396                         #undef ARG_CASE
1397                         #undef ARG_CASE_ARG_DC
1398                         #undef ARG_CASE_ARG_SV
1399                         #undef ARG_CASE_ARG_CS
1400                         #undef ARG_CASE_ARG_CS_SV
1401                         #undef ARG_CASE_ARG_CS_SV_DC
1402                         #undef ARG_CASE_ARG_CS_SV_HA
1403                         default:
1404                         {
1405                                 if(ftos(stof(selected)) != "") { arg_slot[sel_num] = selected; ++sel_num; }
1406                                 else { NOTIF_HIT_UNKNOWN(NOTIF_MAX_DURCNT, "Local_Notification_centerprint_generic") }
1407                                 break;
1408                         }
1409                 }
1410         }
1411         #ifdef NOTIFICATIONS_DEBUG
1412         Debug_Notification(sprintf(
1413                 "Local_Notification_centerprint_generic('%s^7', '%s', %d, %d, %d, %d);\n",
1414                 MakeConsoleSafe(input),
1415                 durcnt,
1416                 f1, f2,
1417                 stof(arg_slot[0]),
1418                 stof(arg_slot[1])
1419         ));
1420         #endif
1421         centerprint_generic(cpid, input, stof(arg_slot[0]), stof(arg_slot[1]));
1422 }
1423 #endif
1424
1425 void Local_Notification(int net_type, int net_name, ...count)
1426 {
1427         // check if this should be aborted
1428         if(net_name == NOTIF_ABORT)
1429         {
1430                 #ifdef NOTIFICATIONS_DEBUG
1431                 Debug_Notification(sprintf(
1432                         "Local_Notification(%s, %s, ...);\n",
1433                         Get_Notif_TypeName(net_type),
1434                         "NOTIF_ABORT"
1435                 ));
1436                 #endif
1437                 return;
1438         }
1439
1440         // check supplied type and name for errors
1441         string checkargs = Notification_CheckArgs_TypeName(net_type, net_name);
1442         if(checkargs != "")
1443         {
1444                 #ifdef NOTIFICATIONS_DEBUG
1445                 Debug_Notification(sprintf(
1446                         "Local_Notification(%s, %d, ...);\n",
1447                         Get_Notif_TypeName(net_type),
1448                         Get_Notif_Ent(net_type, net_name).nent_name
1449                 ));
1450                 #endif
1451                 backtrace(sprintf("Incorrect usage of Local_Notification: %s\n", checkargs));
1452                 return;
1453         }
1454
1455         // retreive entity of this notification
1456         entity notif = Get_Notif_Ent(net_type, net_name);
1457         if (!notif)
1458         {
1459                 #ifdef NOTIFICATIONS_DEBUG
1460                 Debug_Notification(sprintf(
1461                         "Local_Notification(%s, %d, ...);\n",
1462                         Get_Notif_TypeName(net_type),
1463                         net_name
1464                 ));
1465                 #endif
1466                 backtrace("Local_Notification: Could not find notification entity!\n");
1467                 return;
1468         }
1469
1470         // check if the notification is enabled
1471         if (!notif.nent_enabled)
1472         {
1473                 #ifdef NOTIFICATIONS_DEBUG
1474                 Debug_Notification(sprintf(
1475                         "Local_Notification(%s, %s, ...): Entity was disabled...\n",
1476                         Get_Notif_TypeName(net_type),
1477                         notif.nent_name
1478                 ));
1479                 #endif
1480                 return;
1481         }
1482
1483         string s1 = ((0 < notif.nent_stringcount) ? ...(0, string) : "");
1484         string s2 = ((1 < notif.nent_stringcount) ? ...(1, string) : "");
1485         string s3 = ((2 < notif.nent_stringcount) ? ...(2, string) : "");
1486         string s4 = ((3 < notif.nent_stringcount) ? ...(3, string) : "");
1487         float f1 = ((0 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 0), float) : 0);
1488         float f2 = ((1 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 1), float) : 0);
1489         float f3 = ((2 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 2), float) : 0);
1490         float f4 = ((3 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 3), float) : 0);
1491
1492         #ifdef NOTIFICATIONS_DEBUG
1493         Debug_Notification(sprintf(
1494                 "Local_Notification(%s, %s, %s, %s);\n",
1495                 Get_Notif_TypeName(net_type),
1496                 notif.nent_name,
1497                 MakeConsoleSafe(sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4)),
1498                 sprintf("%d, %d, %d, %d", f1, f2, f3, f4)
1499         ));
1500         #endif
1501
1502         if((notif.nent_stringcount + notif.nent_floatcount) > count)
1503         {
1504                 backtrace(sprintf(
1505                         strcat(
1506                                 "Not enough arguments for Local_Notification(%s, %s, ...)! ",
1507                                 "stringcount(%d) + floatcount(%d) > count(%d)\n",
1508                                 "Check the definition and function call for accuracy...?\n"
1509                         ),
1510                         Get_Notif_TypeName(net_type),
1511                         notif.nent_name,
1512                         notif.nent_stringcount,
1513                         notif.nent_floatcount,
1514                         count
1515                 ));
1516                 return;
1517         }
1518         else if((notif.nent_stringcount + notif.nent_floatcount) < count)
1519         {
1520                 backtrace(sprintf(
1521                         strcat(
1522                                 "Too many arguments for Local_Notification(%s, %s, ...)! ",
1523                                 "stringcount(%d) + floatcount(%d) < count(%d)\n",
1524                                 "Check the definition and function call for accuracy...?\n"
1525                         ),
1526                         Get_Notif_TypeName(net_type),
1527                         notif.nent_name,
1528                         notif.nent_stringcount,
1529                         notif.nent_floatcount,
1530                         count
1531                 ));
1532                 return;
1533         }
1534
1535         switch(net_type)
1536         {
1537                 case MSG_ANNCE:
1538                 {
1539                         #ifdef CSQC
1540                         Local_Notification_sound(
1541                                 notif.nent_channel,
1542                                 notif.nent_snd,
1543                                 notif.nent_vol,
1544                                 notif.nent_position
1545                         );
1546                         #else
1547                         backtrace("MSG_ANNCE on server?... Please notify Samual immediately!\n");
1548                         #endif
1549                         break;
1550                 }
1551
1552                 case MSG_INFO:
1553                 {
1554                         print(
1555                                 Local_Notification_sprintf(
1556                                         notif.nent_string,
1557                                         notif.nent_args,
1558                                         s1, s2, s3, s4,
1559                                         f1, f2, f3, f4)
1560                         );
1561                         #ifdef CSQC
1562                         if(notif.nent_icon != "")
1563                         {
1564                                 Local_Notification_HUD_Notify_Push(
1565                                         notif.nent_icon,
1566                                         notif.nent_hudargs,
1567                                         s1, s2, s3, s4,
1568                                         f1, f2, f3, f4);
1569                         }
1570                         #endif
1571                         break;
1572                 }
1573
1574                 #ifdef CSQC
1575                 case MSG_CENTER:
1576                 {
1577                         Local_Notification_centerprint_generic(
1578                                 Local_Notification_sprintf(
1579                                         notif.nent_string,
1580                                         notif.nent_args,
1581                                         s1, s2, s3, s4,
1582                                         f1, f2, f3, f4),
1583                                 notif.nent_durcnt,
1584                                 notif.nent_cpid,
1585                                 f1, f2);
1586                         break;
1587                 }
1588                 #endif
1589
1590                 case MSG_MULTI:
1591                 {
1592                         if(notif.nent_msginfo)
1593                         if(notif.nent_msginfo.nent_enabled)
1594                         {
1595                                 Local_Notification_WOVA(
1596                                         MSG_INFO,
1597                                         notif.nent_msginfo.nent_id,
1598                                         notif.nent_msginfo.nent_stringcount,
1599                                         notif.nent_msginfo.nent_floatcount,
1600                                         s1, s2, s3, s4,
1601                                         f1, f2, f3, f4);
1602                         }
1603                         #ifdef CSQC
1604                         if(notif.nent_msgannce)
1605                         if(notif.nent_msgannce.nent_enabled)
1606                         {
1607                                 Local_Notification_WOVA(
1608                                         MSG_ANNCE,
1609                                         notif.nent_msgannce.nent_id,
1610                                         0, 0,
1611                                         "", "", "", "",
1612                                         0, 0, 0, 0);
1613                         }
1614                         if(notif.nent_msgcenter)
1615                         if(notif.nent_msgcenter.nent_enabled)
1616                         {
1617                                 Local_Notification_WOVA(
1618                                         MSG_CENTER,
1619                                         notif.nent_msgcenter.nent_id,
1620                                         notif.nent_msgcenter.nent_stringcount,
1621                                         notif.nent_msgcenter.nent_floatcount,
1622                                         s1, s2, s3, s4,
1623                                         f1, f2, f3, f4);
1624                         }
1625                         #endif
1626                         break;
1627                 }
1628
1629                 case MSG_CHOICE:
1630                 {
1631                         entity found_choice;
1632
1633                         if(notif.nent_challow_var && (warmup_stage || (notif.nent_challow_var == 2)))
1634                         {
1635                                 switch(cvar(sprintf("notification_%s", notif.nent_name)))
1636                                 {
1637                                         case 1: found_choice = notif.nent_optiona; break;
1638                                         case 2: found_choice = notif.nent_optionb; break;
1639                                         default: return; // not enabled anyway
1640                                 }
1641                         }
1642                         else { found_choice = notif.nent_optiona; }
1643
1644                         Local_Notification_WOVA(
1645                                 found_choice.nent_type,
1646                                 found_choice.nent_id,
1647                                 found_choice.nent_stringcount,
1648                                 found_choice.nent_floatcount,
1649                                 s1, s2, s3, s4,
1650                                 f1, f2, f3, f4);
1651                 }
1652         }
1653 }
1654
1655 // WOVA = Without Variable Arguments
1656 void Local_Notification_WOVA(
1657         int net_type, float net_name,
1658         float stringcount, float floatcount,
1659         string s1, string s2, string s3, string s4,
1660         float f1, float f2, float f3, float f4)
1661 {
1662         #define VARITEM(stringc,floatc,args) \
1663                 if((stringcount == stringc) && (floatcount == floatc)) \
1664                         { Local_Notification(net_type, net_name, args); return; }
1665         EIGHT_VARS_TO_VARARGS_VARLIST
1666         #undef VARITEM
1667         Local_Notification(net_type, net_name); // some notifications don't have any arguments at all
1668 }
1669
1670
1671 // =========================
1672 //  Notification Networking
1673 // =========================
1674
1675 #ifdef CSQC
1676 void Read_Notification(float is_new)
1677 {
1678         int net_type = ReadByte();
1679         int net_name = ReadShort();
1680
1681         entity notif;
1682
1683         if(net_type == MSG_CENTER_CPID)
1684         {
1685                 #ifdef NOTIFICATIONS_DEBUG
1686                 Debug_Notification(sprintf(
1687                         "Read_Notification(%d) at %f: net_type = %s, net_name = %d\n",
1688                         is_new,
1689                         time,
1690                         Get_Notif_TypeName(net_type),
1691                         net_name
1692                 ));
1693                 #endif
1694
1695                 if(is_new)
1696                 {
1697                         if(net_name == 0) { reset_centerprint_messages(); }
1698                         else if(net_name != NO_CPID)
1699                         {
1700                                 // in this case, net_name IS the cpid we want to kill
1701                                 centerprint_generic(net_name, "", 0, 0);
1702                         }
1703                         else
1704                         {
1705                                 backtrace(sprintf(
1706                                         "Read_Notification(%d) at %f: ^1TRIED TO KILL NO_CPID CENTERPRINT!\n",
1707                                         is_new,
1708                                         time
1709                                 ));
1710                         }
1711                 }
1712         }
1713         else
1714         {
1715                 notif = Get_Notif_Ent(net_type, net_name);
1716                 if (!notif) { backtrace("Read_Notification: Could not find notification entity!\n"); return; }
1717
1718                 #ifdef NOTIFICATIONS_DEBUG
1719                 Debug_Notification(sprintf(
1720                         "Read_Notification(%d) at %f: net_type = %s, net_name = %s\n",
1721                         is_new,
1722                         time,
1723                         Get_Notif_TypeName(net_type),
1724                         notif.nent_name
1725                 ));
1726                 #endif
1727
1728                 string s1 = ((0 < notif.nent_stringcount) ? ReadString() : "");
1729                 string s2 = ((1 < notif.nent_stringcount) ? ReadString() : "");
1730                 string s3 = ((2 < notif.nent_stringcount) ? ReadString() : "");
1731                 string s4 = ((3 < notif.nent_stringcount) ? ReadString() : "");
1732                 float f1 = ((0 < notif.nent_floatcount) ? ReadLong() : 0);
1733                 float f2 = ((1 < notif.nent_floatcount) ? ReadLong() : 0);
1734                 float f3 = ((2 < notif.nent_floatcount) ? ReadLong() : 0);
1735                 float f4 = ((3 < notif.nent_floatcount) ? ReadLong() : 0);
1736
1737                 if(is_new)
1738                 {
1739                         Local_Notification_WOVA(
1740                                 net_type, net_name,
1741                                 notif.nent_stringcount,
1742                                 notif.nent_floatcount,
1743                                 s1, s2, s3, s4,
1744                                 f1, f2, f3, f4);
1745                 }
1746         }
1747 }
1748 #endif
1749
1750 #ifdef SVQC
1751 void Net_Notification_Remove()
1752 {
1753         if (!self) { backtrace(sprintf("Net_Notification_Remove() at %f: Missing self!?\n", time)); return; }
1754
1755         #ifdef NOTIFICATIONS_DEBUG
1756         Debug_Notification(sprintf(
1757                 "Net_Notification_Remove() at %f: %s '%s - %s' notification\n",
1758                 time,
1759                 ((self.nent_net_name == -1) ? "Killed" : "Removed"),
1760                 Get_Notif_TypeName(self.nent_net_type),
1761                 self.owner.nent_name
1762         ));
1763         #endif
1764
1765         for(int i = 0; i < 4; ++i) { if(self.nent_strings[i]) { strunzone(self.nent_strings[i]); } }
1766         remove(self);
1767 }
1768
1769 float Net_Write_Notification(entity client, int sf)
1770 {
1771         if(Notification_ShouldSend(self.nent_broadcast, client, self.nent_client))
1772         {
1773                 WriteByte(MSG_ENTITY, ENT_CLIENT_NOTIFICATION);
1774                 WriteByte(MSG_ENTITY, self.nent_net_type);
1775                 WriteShort(MSG_ENTITY, self.nent_net_name);
1776                 for(int i = 0; i < self.nent_stringcount; ++i) { WriteString(MSG_ENTITY, self.nent_strings[i]); }
1777                 for(int i = 0; i < self.nent_floatcount; ++i) { WriteLong(MSG_ENTITY, self.nent_floats[i]); }
1778                 return true;
1779         }
1780         else { return false; }
1781 }
1782
1783 void Kill_Notification(
1784         float broadcast, entity client,
1785         float net_type, float net_name)
1786 {
1787         #ifdef NOTIFICATIONS_DEBUG
1788         Debug_Notification(sprintf(
1789                 "Kill_Notification(%s, '%s', %s, %d);\n",
1790                 Get_Notif_BroadcastName(broadcast),
1791                 client.netname,
1792                 (net_type ? Get_Notif_TypeName(net_type) : "0"),
1793                 net_name
1794         ));
1795         #endif
1796
1797         string checkargs = Notification_CheckArgs(broadcast, client, 1, 1);
1798         if(checkargs != "") { backtrace(sprintf("Incorrect usage of Kill_Notification: %s\n", checkargs)); return; }
1799
1800         entity notif, net_notif;
1801         float killed_cpid = NO_CPID;
1802
1803         switch(net_type)
1804         {
1805                 case 0:
1806                 {
1807                         killed_cpid = 0; // kill ALL centerprints
1808                         break;
1809                 }
1810
1811                 case MSG_CENTER:
1812                 {
1813                         if(net_name)
1814                         {
1815                                 entity notif = Get_Notif_Ent(net_type, net_name);
1816                                 if (!notif) { backtrace("Kill_Notification: Could not find notification entity!\n"); return; }
1817
1818                                 if(notif.nent_cpid)
1819                                         killed_cpid = notif.nent_cpid;
1820                                 else
1821                                         killed_cpid = NO_CPID;
1822                         }
1823                         else
1824                         {
1825                                 killed_cpid = 0; // kill ALL centerprints
1826                         }
1827                         break;
1828                 }
1829
1830                 case MSG_CENTER_CPID:
1831                 {
1832                         killed_cpid = net_name;
1833                         break;
1834                 }
1835         }
1836
1837         if(killed_cpid != NO_CPID)
1838         {
1839                 net_notif = spawn();
1840                 net_notif.classname = "net_kill_notification";
1841                 net_notif.nent_broadcast = broadcast;
1842                 net_notif.nent_client = client;
1843                 net_notif.nent_net_type = MSG_CENTER_CPID;
1844                 net_notif.nent_net_name = killed_cpid;
1845                 Net_LinkEntity(net_notif, false, autocvar_notification_lifetime_runtime, Net_Write_Notification);
1846         }
1847
1848         for(notif = world; (notif = find(notif, classname, "net_notification"));)
1849         {
1850                 if(net_type)
1851                 {
1852                         if((killed_cpid != NO_CPID) && (notif.nent_net_type == MSG_CENTER))
1853                         {
1854                                 if(notif.owner.nent_cpid == killed_cpid)
1855                                 {
1856                                         notif.nent_net_name = -1;
1857                                         notif.nextthink = time;
1858                                 }
1859                                 else { continue; } // we ARE looking for a specific CPID, don't kill everything else too
1860                         }
1861                         else if(notif.nent_net_type == net_type)
1862                         {
1863                                 if(net_name)
1864                                 {
1865                                         if(notif.nent_net_name == net_name) { notif.nent_net_name = -1; notif.nextthink = time; }
1866                                         else { continue; } // we ARE looking for a certain net_name, don't kill everything else too
1867                                 }
1868                                 else { notif.nent_net_name = -1; notif.nextthink = time; }
1869                         }
1870                         else { continue; } // we ARE looking for a certain net_type, don't kill everything else too
1871                 }
1872                 else { notif.nent_net_name = -1; notif.nextthink = time; }
1873         }
1874 }
1875
1876 void Send_Notification(
1877         float broadcast, entity client,
1878         float net_type, float net_name,
1879         ...count)
1880 {
1881         // check if this should be aborted
1882         if(net_name == NOTIF_ABORT)
1883         {
1884                 #ifdef NOTIFICATIONS_DEBUG
1885                 Debug_Notification(sprintf(
1886                         "Send_Notification(%s, '%s', %s, %s, ...);\n",
1887                         Get_Notif_BroadcastName(broadcast),
1888                         client.classname,
1889                         Get_Notif_TypeName(net_type),
1890                         "NOTIF_ABORT"
1891                 ));
1892                 #endif
1893                 return;
1894         }
1895
1896         // check supplied broadcast, target, type, and name for errors
1897         string checkargs = Notification_CheckArgs(broadcast, client, net_type, net_name);
1898         if(checkargs != "")
1899         {
1900                 #ifdef NOTIFICATIONS_DEBUG
1901                 Debug_Notification(sprintf(
1902                         "Send_Notification(%s, '%s', %s, %s, ...);\n",
1903                         Get_Notif_BroadcastName(broadcast),
1904                         client.classname,
1905                         Get_Notif_TypeName(net_type),
1906                         Get_Notif_Ent(net_type, net_name).nent_name
1907                 ));
1908                 #endif
1909                 backtrace(sprintf("Incorrect usage of Send_Notification: %s\n", checkargs));
1910                 return;
1911         }
1912
1913         // retreive entity of this notification
1914         entity notif = Get_Notif_Ent(net_type, net_name);
1915         if (!notif)
1916         {
1917                 #ifdef NOTIFICATIONS_DEBUG
1918                 Debug_Notification(sprintf(
1919                         "Send_Notification(%s, '%s', %s, %d, ...);\n",
1920                         Get_Notif_BroadcastName(broadcast),
1921                         client.classname,
1922                         Get_Notif_TypeName(net_type),
1923                         net_name
1924                 ));
1925                 #endif
1926                 backtrace("Send_Notification: Could not find notification entity!\n");
1927                 return;
1928         }
1929
1930         string s1 = ((0 < notif.nent_stringcount) ? ...(0, string) : "");
1931         string s2 = ((1 < notif.nent_stringcount) ? ...(1, string) : "");
1932         string s3 = ((2 < notif.nent_stringcount) ? ...(2, string) : "");
1933         string s4 = ((3 < notif.nent_stringcount) ? ...(3, string) : "");
1934         float f1 = ((0 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 0), float) : 0);
1935         float f2 = ((1 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 1), float) : 0);
1936         float f3 = ((2 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 2), float) : 0);
1937         float f4 = ((3 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 3), float) : 0);
1938
1939         #ifdef NOTIFICATIONS_DEBUG
1940         Debug_Notification(sprintf(
1941                 "Send_Notification(%s, %s, %s);\n",
1942                 sprintf(
1943                         "%s, '%s', %s, %s",
1944                         Get_Notif_BroadcastName(broadcast),
1945                         client.classname,
1946                         Get_Notif_TypeName(net_type),
1947                         notif.nent_name
1948                 ),
1949                 MakeConsoleSafe(sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4)),
1950                 sprintf("%d, %d, %d, %d", f1, f2, f3, f4)
1951         ));
1952         #endif
1953
1954         if((notif.nent_stringcount + notif.nent_floatcount) > count)
1955         {
1956                 backtrace(sprintf(
1957                         strcat(
1958                                 "Not enough arguments for Send_Notification(%s, ...)! ",
1959                                 "stringcount(%d) + floatcount(%d) > count(%d)\n",
1960                                 "Check the definition and function call for accuracy...?\n"
1961                         ),
1962                         sprintf(
1963                                 #ifdef NOTIFICATIONS_DEBUG
1964                                 "%s, '%s', %s, %s",
1965                                 Get_Notif_BroadcastName(broadcast),
1966                                 #else
1967                                 "%d, '%s', %s, %s",
1968                                 broadcast,
1969                                 #endif
1970                                 client.classname,
1971                                 Get_Notif_TypeName(net_type),
1972                                 notif.nent_name
1973                         ),
1974                         notif.nent_stringcount,
1975                         notif.nent_floatcount,
1976                         count
1977                 ));
1978                 return;
1979         }
1980         else if((notif.nent_stringcount + notif.nent_floatcount) < count)
1981         {
1982                 backtrace(sprintf(
1983                         strcat(
1984                                 "Too many arguments for Send_Notification(%s, ...)! ",
1985                                 "stringcount(%d) + floatcount(%d) < count(%d)\n",
1986                                 "Check the definition and function call for accuracy...?\n"
1987                         ),
1988                         sprintf(
1989                                 #ifdef NOTIFICATIONS_DEBUG
1990                                 "%s, '%s', %s, %s",
1991                                 Get_Notif_BroadcastName(broadcast),
1992                                 #else
1993                                 "%d, '%s', %s, %s",
1994                                 broadcast,
1995                                 #endif
1996                                 client.classname,
1997                                 Get_Notif_TypeName(net_type),
1998                                 notif.nent_name
1999                         ),
2000                         notif.nent_stringcount,
2001                         notif.nent_floatcount,
2002                         count
2003                 ));
2004                 return;
2005         }
2006
2007         if(
2008                 server_is_dedicated
2009                 &&
2010                 (
2011                         broadcast == NOTIF_ALL
2012                         ||
2013                         broadcast == NOTIF_ALL_EXCEPT
2014                 )
2015                 &&
2016                 !(
2017                         net_type == MSG_ANNCE
2018                         ||
2019                         net_type == MSG_CENTER
2020                 )
2021         )
2022         {
2023                 Local_Notification_WOVA(
2024                         net_type, net_name,
2025                         notif.nent_stringcount,
2026                         notif.nent_floatcount,
2027                         s1, s2, s3, s4,
2028                         f1, f2, f3, f4);
2029         }
2030
2031         if(net_type == MSG_CHOICE)
2032         {
2033                 // THIS GETS TRICKY... now we have to cycle through each possible player (checking broadcast)
2034                 // and then do an individual NOTIF_ONE_ONLY recursive call for each one depending on their option...
2035                 // It's slow, but it's better than the alternatives:
2036                 //   1. Constantly networking all info and letting client decide
2037                 //   2. Manually handling each separate call on per-usage basis (See old CTF usage of verbose)
2038                 entity found_choice;
2039
2040                 #define RECURSE_FROM_CHOICE(ent,action) do { \
2041                         if(notif.nent_challow_var && (warmup_stage || (notif.nent_challow_var == 2))) \
2042                         { \
2043                                 switch(ent.msg_choice_choices[net_name - 1]) \
2044                                 { \
2045                                         case 1: found_choice = notif.nent_optiona; break; \
2046                                         case 2: found_choice = notif.nent_optionb; break; \
2047                                         default: action; \
2048                                 } \
2049                         } \
2050                         else { found_choice = notif.nent_optiona; } \
2051                         Send_Notification_WOVA( \
2052                                 NOTIF_ONE_ONLY, \
2053                                 ent, \
2054                                 found_choice.nent_type, \
2055                                 found_choice.nent_id, \
2056                                 found_choice.nent_stringcount, \
2057                                 found_choice.nent_floatcount, \
2058                                 s1, s2, s3, s4, \
2059                                 f1, f2, f3, f4); \
2060                 } while(0)
2061
2062                 switch(broadcast)
2063                 {
2064                         case NOTIF_ONE_ONLY: // we can potentially save processing power with this broadcast method
2065                         {
2066                                 if(IS_REAL_CLIENT(client))
2067                                 {
2068                                         RECURSE_FROM_CHOICE(client, return);
2069                                 }
2070                                 break;
2071                         }
2072                         default:
2073                         {
2074                                 entity to;
2075                                 FOR_EACH_REALCLIENT(to)
2076                                 {
2077                                         if(Notification_ShouldSend(broadcast, to, client))
2078                                         {
2079                                                 RECURSE_FROM_CHOICE(to, continue);
2080                                         }
2081                                 }
2082                                 break;
2083                         }
2084                 }
2085         }
2086         else
2087         {
2088                 entity net_notif = spawn();
2089                 net_notif.owner = notif;
2090                 net_notif.classname = "net_notification";
2091                 net_notif.nent_broadcast = broadcast;
2092                 net_notif.nent_client = client;
2093                 net_notif.nent_net_type = net_type;
2094                 net_notif.nent_net_name = net_name;
2095                 net_notif.nent_stringcount = notif.nent_stringcount;
2096                 net_notif.nent_floatcount = notif.nent_floatcount;
2097
2098                 for(int i = 0; i < net_notif.nent_stringcount; ++i)
2099                         { net_notif.nent_strings[i] = strzone(...(i, string)); }
2100                 for(int i = 0; i < net_notif.nent_floatcount; ++i)
2101                         { net_notif.nent_floats[i] = ...((net_notif.nent_stringcount + i), float); }
2102
2103                 net_notif.think = Net_Notification_Remove;
2104                 net_notif.nextthink =
2105                         ((time > autocvar_notification_lifetime_mapload)
2106                         ?
2107                                 (time + autocvar_notification_lifetime_runtime)
2108                                 :
2109                                 autocvar_notification_lifetime_mapload
2110                         );
2111
2112                 Net_LinkEntity(net_notif, false, 0, Net_Write_Notification);
2113         }
2114 }
2115
2116 // WOVA = Without Variable Arguments
2117 void Send_Notification_WOVA(
2118         float broadcast, entity client,
2119         float net_type, float net_name,
2120         float stringcount, float floatcount,
2121         string s1, string s2, string s3, string s4,
2122         float f1, float f2, float f3, float f4)
2123 {
2124         #ifdef NOTIFICATIONS_DEBUG
2125         entity notif = Get_Notif_Ent(net_type, net_name);
2126         Debug_Notification(sprintf(
2127                 "Send_Notification_WOVA(%s, %d, %d, %s, %s);\n",
2128                 sprintf(
2129                         "%s, '%s', %s, %s",
2130                         Get_Notif_BroadcastName(broadcast),
2131                         client.classname,
2132                         Get_Notif_TypeName(net_type),
2133                         notif.nent_name
2134                 ),
2135                 stringcount,
2136                 floatcount,
2137                 MakeConsoleSafe(sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4)),
2138                 sprintf("%d, %d, %d, %d", f1, f2, f3, f4)
2139         ));
2140         #endif
2141
2142         #define VARITEM(stringc,floatc,args) \
2143                 if((stringcount == stringc) && (floatcount == floatc)) \
2144                         { Send_Notification(broadcast, client, net_type, net_name, args); return; }
2145         EIGHT_VARS_TO_VARARGS_VARLIST
2146         #undef VARITEM
2147         Send_Notification(broadcast, client, net_type, net_name); // some notifications don't have any arguments at all
2148 }
2149
2150 // WOCOVA = Without Counts Or Variable Arguments
2151 void Send_Notification_WOCOVA(
2152         float broadcast, entity client,
2153         float net_type, float net_name,
2154         string s1, string s2, string s3, string s4,
2155         float f1, float f2, float f3, float f4)
2156 {
2157         entity notif = Get_Notif_Ent(net_type, net_name);
2158
2159         #ifdef NOTIFICATIONS_DEBUG
2160         Debug_Notification(sprintf(
2161                 "Send_Notification_WOCOVA(%s, %s, %s);\n",
2162                 sprintf(
2163                         "%s, '%s', %s, %s",
2164                         Get_Notif_BroadcastName(broadcast),
2165                         client.classname,
2166                         Get_Notif_TypeName(net_type),
2167                         notif.nent_name
2168                 ),
2169                 MakeConsoleSafe(sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4)),
2170                 sprintf("%d, %d, %d, %d", f1, f2, f3, f4)
2171         ));
2172         #endif
2173
2174         #define VARITEM(stringc,floatc,args) \
2175                 if((notif.nent_stringcount == stringc) && (notif.nent_floatcount == floatc)) \
2176                         { Send_Notification(broadcast, client, net_type, net_name, args); return; }
2177         EIGHT_VARS_TO_VARARGS_VARLIST
2178         #undef VARITEM
2179         Send_Notification(broadcast, client, net_type, net_name); // some notifications don't have any arguments at all
2180 }
2181 #endif // ifdef SVQC