qcsrc/common/notifications.qc

   1 // ================================================
   2 //  Unified notification system, written by Samual
   3 //  Last updated: August, 2013
   4 // ================================================
   5
   6 string Get_Notif_TypeName(float net_type)
   7 {
   8         switch(net_type)
   9         {
  10                 case MSG_ANNCE: return "MSG_ANNCE";
  11                 case MSG_INFO: return "MSG_INFO";
  12                 case MSG_CENTER: return "MSG_CENTER";
  13                 case MSG_CENTER_CPID: return "MSG_CENTER_CPID";
  14                 case MSG_MULTI: return "MSG_MULTI";
  15                 case MSG_CHOICE: return "MSG_CHOICE";
  16         }
  17         backtrace(sprintf("Get_Notif_TypeName(%d): Improper net type!\n", net_type));
  18         return "";
  19 }
  20
  21 entity Get_Notif_Ent(float net_type, float net_name)
  22 {
  23         switch(net_type)
  24         {
  25                 case MSG_ANNCE: return msg_annce_notifs[net_name - 1];
  26                 case MSG_INFO: return msg_info_notifs[net_name - 1];
  27                 case MSG_CENTER: return msg_center_notifs[net_name - 1];
  28                 case MSG_MULTI: return msg_multi_notifs[net_name - 1];
  29                 case MSG_CHOICE: return msg_choice_notifs[net_name - 1];
  30         }
  31         backtrace(sprintf("Get_Notif_Ent(%d, %d): Improper net type!\n", net_type, net_name));
  32         return world;
  33 }
  34
  35 #ifdef SVQC
  36 #ifdef NOTIFICATIONS_DEBUG
  37 string Get_Notif_BroadcastName(float broadcast)
  38 {
  39         switch(broadcast)
  40         {
  41                 case NOTIF_ONE: return "NOTIF_ONE";
  42                 case NOTIF_ONE_ONLY: return "NOTIF_ONE_ONLY";
  43                 case NOTIF_ALL_EXCEPT: return "NOTIF_ALL_EXCEPT";
  44                 case NOTIF_ALL: return "NOTIF_ALL";
  45                 case NOTIF_TEAM: return "NOTIF_TEAM";
  46                 case NOTIF_TEAM_EXCEPT: return "NOTIF_TEAM_EXCEPT";
  47         }
  48         backtrace(sprintf("Get_Notif_BroadcastName(%d): Improper broadcast!\n", broadcast));
  49         return "";
  50 }
  51 #endif
  52 #endif
  53
  54 string Notification_CheckArgs_TypeName(float net_type, float net_name)
  55 {
  56         // check supplied type and name for errors
  57         string checkargs = "";
  58         #define CHECKARG_TYPENAME(type) case MSG_##type##: \
  59                 { if(!net_name || (net_name > NOTIF_##type##_COUNT)) \
  60                 { checkargs = sprintf("Improper name: %d!", net_name); } break; }
  61         switch(net_type)
  62         {
  63                 CHECKARG_TYPENAME(ANNCE)
  64                 CHECKARG_TYPENAME(INFO)
  65                 CHECKARG_TYPENAME(CENTER)
  66                 CHECKARG_TYPENAME(MULTI)
  67                 CHECKARG_TYPENAME(CHOICE)
  68                 default: { checkargs = sprintf("Improper type: %d!", checkargs, net_type); break; }
  69         }
  70         #undef CHECKARG_TYPENAME
  71         return checkargs;
  72 }
  73
  74 #ifdef SVQC
  75 string Notification_CheckArgs(
  76         float broadcast, entity client,
  77         float net_type, float net_name)
  78 {
  79         // check supplied broadcast, target, type, and name for errors
  80         string checkargs = Notification_CheckArgs_TypeName(net_type, net_name);
  81         if(checkargs != "") { checkargs = strcat(checkargs, " "); }
  82         switch(broadcast)
  83         {
  84                 case NOTIF_ONE:
  85                 case NOTIF_ONE_ONLY:
  86                 {
  87                         if(IS_NOT_A_CLIENT(client))
  88                                 { checkargs = sprintf("%sNo client provided!", checkargs); }
  89                         break;
  90                 }
  91
  92                 case NOTIF_ALL_EXCEPT:
  93                 {
  94                         if(IS_NOT_A_CLIENT(client))
  95                                 { checkargs = sprintf("%sException can't be a non-client!", checkargs); }
  96                         break;
  97                 }
  98
  99                 case NOTIF_ALL:
 100                 {
 101                         if(client)
 102                                 { checkargs = sprintf("%sEntity provided when world was required!", checkargs); }
 103                         break;
 104                 }
 105
 106                 case NOTIF_TEAM:
 107                 {
 108                         if not(teamplay)
 109                                 { checkargs = sprintf("%sTeamplay not active!", checkargs); }
 110                         //else if not(client.team) { checkargs = sprintf("%sNo team provided!", checkargs); }
 111                         break;
 112                 }
 113
 114                 case NOTIF_TEAM_EXCEPT:
 115                 {
 116                         if not(teamplay)
 117                                 { checkargs = sprintf("%sTeamplay not active!", checkargs); }
 118                         else if(IS_NOT_A_CLIENT(client))
 119                                 { checkargs = sprintf("%sException can't be a non-client!", checkargs); }
 120                         break;
 121                 }
 122
 123                 default: { checkargs = sprintf("%sImproper broadcast: %d!", checkargs, broadcast); break; }
 124         }
 125         return checkargs;
 126 }
 127
 128 float Notification_ShouldSend(float broadcast, entity to_client, entity other_client)
 129 {
 130         switch(broadcast)
 131         {
 132                 case NOTIF_ONE: // send to one client and their spectator
 133                 {
 134                         if(
 135                                 (to_client == other_client)
 136                                 ||
 137                                 (
 138                                         IS_SPEC(to_client)
 139                                         &&
 140                                         (to_client.enemy == other_client)
 141                                 )
 142                         ) { return TRUE; }
 143                         break;
 144                 }
 145                 case NOTIF_ONE_ONLY: // send ONLY to one client
 146                 {
 147                         if(to_client == other_client) { return TRUE; }
 148                         break;
 149                 }
 150                 case NOTIF_TEAM: // send only to X team and their spectators
 151                 {
 152                         if(
 153                                 (to_client.team == other_client.team)
 154                                 ||
 155                                 (
 156                                         IS_SPEC(to_client)
 157                                         &&
 158                                         (to_client.enemy.team == other_client.team)
 159                                 )
 160                         ) { return TRUE; }
 161                         break;
 162                 }
 163                 case NOTIF_TEAM_EXCEPT: // send only to X team and their spectators, except for Y person and their spectators
 164                 {
 165                         if(
 166                                 (to_client != other_client)
 167                                 &&
 168                                 (
 169                                         (to_client.team == other_client.team)
 170                                         ||
 171                                         (
 172                                                 IS_SPEC(to_client)
 173                                                 &&
 174                                                 (
 175                                                         (to_client.enemy != other_client)
 176                                                         &&
 177                                                         (to_client.enemy.team == other_client.team)
 178                                                 )
 179                                         )
 180                                 )
 181                         ) { return TRUE; }
 182                         break;
 183                 }
 184                 case NOTIF_ALL: // send to everyone
 185                 {
 186                         return TRUE;
 187                 }
 188                 case NOTIF_ALL_EXCEPT: // send to everyone except X person and their spectators
 189                 {
 190                         if(
 191                                 (to_client != other_client)
 192                                 &&
 193                                 !(
 194                                         IS_SPEC(to_client)
 195                                         &&
 196                                         (to_client.enemy == other_client)
 197                                 )
 198                         ) { return TRUE; }
 199                         break;
 200                 }
 201         }
 202         return FALSE;
 203 }
 204
 205 #endif
 206
 207 // ===============================
 208 //  Initialization Core Functions
 209 // ===============================
 210
 211 // used by restartnotifs command to initialize notifications
 212 void Destroy_Notification_Entity(entity notif)
 213 {
 214         if(notif.nent_name != "") { strunzone(notif.nent_name); }
 215         if(notif.nent_snd != "") { strunzone(notif.nent_snd); }
 216         if(notif.nent_args != "") { strunzone(notif.nent_args); }
 217         if(notif.nent_hudargs != "") { strunzone(notif.nent_hudargs); }
 218         if(notif.nent_icon != "") { strunzone(notif.nent_icon); }
 219         if(notif.nent_durcnt != "") { strunzone(notif.nent_durcnt); }
 220         if(notif.nent_string != "") { strunzone(notif.nent_string); }
 221         remove(notif);
 222 }
 223
 224 void Destroy_All_Notifications(void)
 225 {
 226         entity notif;
 227         float i;
 228
 229         #define DESTROY_LOOP(type,count) \
 230                 for(i = 1; i <= count; ++i) \
 231                 { \
 232                         notif = Get_Notif_Ent(type, i); \
 233                         if not(notif) { backtrace("Destroy_All_Notifications(): Missing notification entity!\n"); return; } \
 234                         Destroy_Notification_Entity(notif); \
 235                 }
 236
 237         // kill all networked notifications and centerprints
 238         #ifdef SVQC
 239         Kill_Notification(NOTIF_ALL, world, 0, 0);
 240         #else
 241         reset_centerprint_messages();
 242         #endif
 243
 244         // kill all real notification entities
 245         DESTROY_LOOP(MSG_ANNCE, NOTIF_ANNCE_COUNT)
 246         DESTROY_LOOP(MSG_INFO, NOTIF_INFO_COUNT)
 247         DESTROY_LOOP(MSG_CENTER, NOTIF_CENTER_COUNT)
 248         DESTROY_LOOP(MSG_MULTI, NOTIF_MULTI_COUNT)
 249         DESTROY_LOOP(MSG_CHOICE, NOTIF_CHOICE_COUNT)
 250         #undef DESTROY_LOOP
 251 }
 252
 253 string Process_Notif_Line(
 254         float typeid,
 255         float chat,
 256         string input,
 257         string notiftype,
 258         string notifname,
 259         string stringtype)
 260 {
 261         #ifdef CSQC
 262         if(typeid == MSG_INFO)
 263         {
 264                 if((chat && autocvar_notification_allow_chatboxprint)
 265                         || (autocvar_notification_allow_chatboxprint == 2))
 266                 {
 267                         // pass 1: add ETX char at beginning of line
 268                         input = strcat("\{3}", input);
 269
 270                         // pass 2: add ETX char at end of each new line (so that
 271                         // messages with multiple lines are put through chatbox too)
 272                         input = strreplace("\n", "\n\{3}", input);
 273
 274                         // pass 3: strip trailing ETX char
 275                         if(substring(input, (strlen(input) - 1), 1) == "\{3}")
 276                                 { input = substring(input, 0, (strlen(input) - 1)); }
 277                 }
 278         }
 279         #endif
 280
 281         // done to both MSG_INFO and MSG_CENTER
 282         if(substring(input, (strlen(input) - 1), 1) == "\n")
 283         {
 284                 print(sprintf(
 285                         strcat(
 286                                 "^1TRAILING NEW LINE AT END OF NOTIFICATION: ",
 287                                 "^7net_type = %s, net_name = %s, string = %s.\n"
 288                         ),
 289                         notiftype,
 290                         notifname,
 291                         stringtype
 292                 ));
 293                 notif_error = TRUE;
 294                 input = substring(input, 1, (strlen(input) - 1));
 295         }
 296
 297         return input;
 298 }
 299
 300 string Process_Notif_Args(
 301         float arg_type,
 302         string args,
 303         string notiftype,
 304         string notifname)
 305 {
 306         string selected, remaining = args;
 307         float sel_num = 0;
 308
 309         for(;(remaining != "");)
 310         {
 311                 selected = car(remaining); remaining = cdr(remaining);
 312
 313                 switch(arg_type)
 314                 {
 315                         case 1: // normal args
 316                         {
 317                                 if(sel_num == NOTIF_MAX_ARGS)
 318                                 {
 319                                         print(sprintf(
 320                                                 strcat(
 321                                                         "^1NOTIFICATION HAS TOO MANY ARGUMENTS: ",
 322                                                         "^7net_type = %s, net_name = %s, max args = %d.\n"
 323                                                 ),
 324                                                 notiftype,
 325                                                 notifname,
 326                                                 NOTIF_MAX_ARGS
 327                                         ));
 328                                         notif_error = TRUE;
 329                                         break;
 330                                 }
 331
 332                                 switch(strtolower(selected))
 333                                 {
 334                                         #define ARG_CASE(prog,selected,result) \
 335                                                 #if (prog != ARG_DC) \
 336                                                         case selected: { ++sel_num; break; } \
 337                                                 #endif
 338                                         NOTIF_ARGUMENT_LIST
 339                                         #undef ARG_CASE
 340                                         default:
 341                                         {
 342                                                 print(sprintf(
 343                                                         strcat(
 344                                                                 "^1NOTIFICATION WITH UNKNOWN TOKEN IN ARGUMENT STRING: ",
 345                                                                 "^7net_type = %s, net_name = %s, args arg = '%s'.\n"
 346                                                         ),
 347                                                         notiftype,
 348                                                         notifname,
 349                                                         selected
 350                                                 ));
 351                                                 notif_error = TRUE;
 352                                                 break;
 353                                         }
 354                                 }
 355                                 break;
 356                         }
 357                         case 2: // hudargs
 358                         {
 359                                 if(sel_num == NOTIF_MAX_HUDARGS)
 360                                 {
 361                                         print(sprintf(
 362                                                 strcat(
 363                                                         "^1NOTIFICATION HAS TOO MANY ARGUMENTS: ",
 364                                                         "^7net_type = %s, net_name = %s, max hudargs = %d.\n"
 365                                                 ),
 366                                                 notiftype,
 367                                                 notifname,
 368                                                 NOTIF_MAX_HUDARGS
 369                                         ));
 370                                         notif_error = TRUE;
 371                                         break;
 372                                 }
 373
 374                                 switch(strtolower(selected))
 375                                 {
 376                                         #define ARG_CASE(prog,selected,result) \
 377                                                 #if (prog == ARG_CS_SV_HA) \
 378                                                         case selected: { ++sel_num; break; } \
 379                                                 #endif
 380                                         NOTIF_ARGUMENT_LIST
 381                                         #undef ARG_CASE
 382                                         default:
 383                                         {
 384                                                 print(sprintf(
 385                                                         strcat(
 386                                                                 "^1NOTIFICATION WITH UNKNOWN TOKEN IN ARGUMENT STRING: ",
 387                                                                 "^7net_type = %s, net_name = %s, hudargs arg = '%s'.\n"
 388                                                         ),
 389                                                         notiftype,
 390                                                         notifname,
 391                                                         selected
 392                                                 ));
 393                                                 notif_error = TRUE;
 394                                                 break;
 395                                         }
 396                                 }
 397                                 break;
 398                         }
 399                         case 3: // durcnt
 400                         {
 401                                 if(sel_num == NOTIF_MAX_DURCNT)
 402                                 {
 403                                         print(sprintf(
 404                                                 strcat(
 405                                                         "^1NOTIFICATION HAS TOO MANY ARGUMENTS: ",
 406                                                         "^7net_type = %s, net_name = %s, max durcnt = %d.\n"
 407                                                 ),
 408                                                 notiftype,
 409                                                 notifname,
 410                                                 NOTIF_MAX_DURCNT
 411                                         ));
 412                                         notif_error = TRUE;
 413                                         break;
 414                                 }
 415
 416                                 switch(strtolower(selected))
 417                                 {
 418                                         #define ARG_CASE(prog,selected,result) \
 419                                                 #if (prog == ARG_CS_SV_DC) || (prog == ARG_DC) \
 420                                                         case selected: { ++sel_num; break; } \
 421                                                 #endif
 422                                         NOTIF_ARGUMENT_LIST
 423                                         #undef ARG_CASE
 424                                         default:
 425                                         {
 426                                                 if(ftos(stof(selected)) != "") { ++sel_num; }
 427                                                 else
 428                                                 {
 429                                                         print(sprintf(
 430                                                                 strcat(
 431                                                                         "^1NOTIFICATION WITH UNKNOWN TOKEN IN ARGUMENT STRING: ",
 432                                                                         "^7net_type = %s, net_name = %s, durcnt arg = '%s'.\n"
 433                                                                 ),
 434                                                                 notiftype,
 435                                                                 notifname,
 436                                                                 selected
 437                                                         ));
 438                                                         notif_error = TRUE;
 439                                                 }
 440                                                 break;
 441                                         }
 442                                 }
 443                                 break;
 444                         }
 445                 }
 446         }
 447         return args;
 448 }
 449
 450 void Create_Notification_Entity(
 451         float var_default,
 452         float var_cvar,
 453         float typeid,
 454         float nameid,
 455         string namestring,
 456         float strnum,
 457         float flnum,
 458         /* MSG_ANNCE */
 459         float channel,
 460         string snd,
 461         float vol,
 462         float position,
 463         /* MSG_INFO & MSG_CENTER */
 464         string args,
 465         string hudargs,
 466         string icon,
 467         float cpid,
 468         string durcnt,
 469         string normal,
 470         string gentle,
 471         /* MSG_MULTI */
 472         float anncename,
 473         float infoname,
 474         float centername,
 475         /* MSG_CHOICE */
 476         float challow_def,
 477         float challow_var,
 478         float chtype,
 479         float optiona,
 480         float optionb)
 481 {
 482         // =====================
 483         //  Global Entity Setup
 484         // =====================
 485         entity notif = spawn();
 486         switch(typeid)
 487         {
 488                 case MSG_ANNCE:
 489                 {
 490                         msg_annce_notifs[nameid - 1] = notif;
 491                         notif.classname = "msg_annce_notification";
 492                         break;
 493                 }
 494                 case MSG_INFO:
 495                 {
 496                         msg_info_notifs[nameid - 1] = notif;
 497                         notif.classname = "msg_info_notification";
 498                         break;
 499                 }
 500                 case MSG_CENTER:
 501                 {
 502                         msg_center_notifs[nameid - 1] = notif;
 503                         notif.classname = "msg_center_notification";
 504                         break;
 505                 }
 506                 case MSG_MULTI:
 507                 {
 508                         msg_multi_notifs[nameid - 1] = notif;
 509                         notif.classname = "msg_multi_notification";
 510                         break;
 511                 }
 512                 case MSG_CHOICE:
 513                 {
 514                         msg_choice_notifs[nameid - 1] = notif;
 515                         notif.classname = "msg_choice_notification";
 516                         break;
 517                 }
 518
 519                 default:
 520                 {
 521                         error(sprintf(
 522                                 strcat(
 523                                         "^1NOTIFICATION WITH IMPROPER TYPE: ",
 524                                         "^7net_type = %d, net_name = %s.\n"
 525                                 ),
 526                                 typeid,
 527                                 namestring
 528                         ));
 529                         return; // It's not possible to recover from this one
 530                 }
 531         }
 532         notif.nent_default = var_default;
 533         notif.nent_enabled = (1 <= var_cvar);
 534         notif.nent_type = typeid;
 535         notif.nent_id = nameid;
 536         notif.nent_name = strzone(namestring);
 537
 538         string typestring = Get_Notif_TypeName(typeid);
 539
 540         // Other pre-notif-setup requisites
 541         notif_error = FALSE;
 542
 543         // ====================
 544         //  Notification Setup
 545         // ====================
 546         switch(typeid)
 547         {
 548                 case MSG_ANNCE:
 549                 {
 550                         // Set MSG_ANNCE information and handle precaching
 551                         #ifdef CSQC
 552                         if not(GENTLE && (var_cvar == 1))
 553                         {
 554                                 if(snd != "")
 555                                 {
 556                                         if(notif.nent_enabled)
 557                                         {
 558                                                 precache_sound(sprintf("announcer/%s/%s.wav", autocvar_cl_announcer, snd));
 559                                                 notif.nent_channel = channel;
 560                                                 notif.nent_snd = strzone(snd);
 561                                                 notif.nent_vol = vol;
 562                                                 notif.nent_position = position;
 563                                         }
 564                                 }
 565                                 else
 566                                 {
 567                                         print(sprintf(
 568                                                 strcat(
 569                                                         "^1NOTIFICATION WITH NO SOUND: ",
 570                                                         "^7net_type = %s, net_name = %s.\n"
 571                                                 ),
 572                                                 typestring,
 573                                                 namestring
 574                                         ));
 575                                         notif_error = TRUE;
 576                                 }
 577                         }
 578                         else { notif.nent_enabled = FALSE; }
 579                         #else
 580                         notif.nent_enabled = FALSE;
 581                         #endif
 582
 583                         break;
 584                 }
 585
 586                 case MSG_INFO:
 587                 case MSG_CENTER:
 588                 {
 589                         // Set MSG_INFO and MSG_CENTER string/float counts
 590                         notif.nent_stringcount = strnum;
 591                         notif.nent_floatcount = flnum;
 592
 593                         // Only initialize arguments if we're either a client or on a dedicated server
 594                         #ifdef SVQC
 595                         float should_process_args = server_is_dedicated;
 596                         #else
 597                         float should_process_args = TRUE;
 598                         #endif
 599
 600                         if(should_process_args)
 601                         {
 602                                 // ========================
 603                                 //  Process Main Arguments
 604                                 // ========================
 605                                 if(strnum + flnum)
 606                                 {
 607                                         if(args != "")
 608                                         {
 609                                                 notif.nent_args = strzone(
 610                                                         Process_Notif_Args(1, args, typestring, namestring));
 611                                         }
 612                                         else if((hudargs == "") && (durcnt ==""))
 613                                         {
 614                                                 print(sprintf(
 615                                                         strcat(
 616                                                                 "^1NOTIFICATION HAS ARG COUNTS BUT NO ARGS OR HUDARGS OR DURCNT: ",
 617                                                                 "^7net_type = %s, net_name = %s, strnum = %d, flnum = %d\n"
 618                                                         ),
 619                                                         typestring,
 620                                                         namestring,
 621                                                         strnum,
 622                                                         flnum
 623                                                 ));
 624                                                 notif_error = TRUE;
 625                                         }
 626                                 }
 627                                 else if(args != "")
 628                                 {
 629                                         notif.nent_args = strzone(
 630                                                 Process_Notif_Args(1, args, typestring, namestring));
 631                                 }
 632
 633
 634                                 // =======================================
 635                                 //  Process HUD and Centerprint Arguments
 636                                 //    Only processed on CSQC, as these
 637                                 //    args are only for HUD features.
 638                                 // =======================================
 639                                 #ifdef CSQC
 640                                 if(hudargs != "")
 641                                 {
 642                                         notif.nent_hudargs = strzone(
 643                                                 Process_Notif_Args(2, hudargs, typestring, namestring));
 644
 645                                         if(icon != "") { notif.nent_icon = strzone(icon); }
 646                                         else
 647                                         {
 648                                                 print(sprintf(
 649                                                         strcat(
 650                                                                 "^1NOTIFICATION HAS HUDARGS BUT NO ICON: ",
 651                                                                 "^7net_type = %s, net_name = %s.\n"
 652                                                         ),
 653                                                         typestring,
 654                                                         namestring
 655                                                 ));
 656                                                 notif_error = TRUE;
 657                                         }
 658                                 }
 659                                 else if(icon != "")
 660                                 {
 661                                         print(sprintf(
 662                                                 strcat(
 663                                                         "^1NOTIFICATION HAS ICON BUT NO HUDARGS: ",
 664                                                         "^7net_type = %s, net_name = %s.\n"
 665                                                 ),
 666                                                 typestring,
 667                                                 namestring
 668                                         ));
 669                                         notif_error = TRUE;
 670                                 }
 671
 672                                 if(durcnt != "")
 673                                 {
 674                                         notif.nent_durcnt = strzone(
 675                                                 Process_Notif_Args(3, durcnt, typestring, namestring));
 676
 677                                         if(cpid != NO_MSG) { notif.nent_cpid = cpid; }
 678                                         else
 679                                         {
 680                                                 print(sprintf(
 681                                                         strcat(
 682                                                                 "^1NOTIFICATION HAS DURCNT BUT NO CPID: ",
 683                                                                 "^7net_type = %s, net_name = %s.\n"
 684                                                         ),
 685                                                         typestring,
 686                                                         namestring
 687                                                 ));
 688                                                 notif_error = TRUE;
 689                                         }
 690                                 }
 691                                 else if(cpid != NO_MSG) { notif.nent_cpid = cpid; }
 692                                 #endif
 693
 694
 695                                 // ======================
 696                                 //  Process Notif String
 697                                 // ======================
 698                                 #define SET_NOTIF_STRING(string,stringname) \
 699                                         notif.nent_string = strzone(CCR( \
 700                                                 Process_Notif_Line( \
 701                                                         typeid, \
 702                                                         (var_cvar > 1), \
 703                                                         string, \
 704                                                         typestring, \
 705                                                         namestring, \
 706                                                         stringname \
 707                                                 )) \
 708                                         );
 709
 710                                 if(GENTLE)
 711                                 {
 712                                         if(gentle != "") { SET_NOTIF_STRING(gentle, "GENTLE") }
 713                                         else if(normal != "") { SET_NOTIF_STRING(normal, "NORMAL") }
 714                                 }
 715                                 else if(normal != "") { SET_NOTIF_STRING(normal, "NORMAL") }
 716
 717                                 #undef SET_NOTIF_STRING
 718
 719                                 // Check to make sure a string was chosen
 720                                 if(notif.nent_string == "")
 721                                 {
 722                                         print(sprintf(
 723                                                 strcat(
 724                                                         "^1EMPTY NOTIFICATION: ",
 725                                                         "^7net_type = %s, net_name = %s.\n"
 726                                                 ),
 727                                                 typestring,
 728                                                 namestring
 729                                         ));
 730                                         notif_error = TRUE;
 731                                 }
 732                         }
 733
 734                         break;
 735                 }
 736
 737                 case MSG_MULTI:
 738                 {
 739                         // Set MSG_MULTI string/float counts
 740                         if((anncename == NO_MSG) && (infoname == NO_MSG) && (centername == NO_MSG))
 741                         {
 742                                 print(sprintf(
 743                                         strcat(
 744                                                 "^1NOTIFICATION WITH NO SUBCALLS: ",
 745                                                 "^7net_type = %s, net_name = %s.\n"
 746                                         ),
 747                                         typestring,
 748                                         namestring
 749                                 ));
 750                                 notif_error = TRUE;
 751                         }
 752                         else
 753                         {
 754                                 // announcements don't actually need any arguments, so lets not even count them.
 755                                 if(anncename != NO_MSG) { notif.nent_msgannce = msg_annce_notifs[anncename - 1]; }
 756
 757                                 float infoname_stringcount = 0, infoname_floatcount = 0;
 758                                 float centername_stringcount = 0, centername_floatcount = 0;
 759
 760                                 if(infoname != NO_MSG)
 761                                 {
 762                                         notif.nent_msginfo = msg_info_notifs[infoname - 1];
 763                                         infoname_stringcount = notif.nent_msginfo.nent_stringcount;
 764                                         infoname_floatcount = notif.nent_msginfo.nent_floatcount;
 765                                 }
 766
 767                                 if(centername != NO_MSG)
 768                                 {
 769                                         notif.nent_msgcenter = msg_center_notifs[centername - 1];
 770                                         centername_stringcount = notif.nent_msgcenter.nent_stringcount;
 771                                         centername_floatcount = notif.nent_msgcenter.nent_floatcount;
 772                                 }
 773
 774                                 // set the requirements of THIS notification to the totals of its subcalls
 775                                 notif.nent_stringcount = max(infoname_stringcount, centername_stringcount);
 776                                 notif.nent_floatcount = max(infoname_floatcount, centername_floatcount);
 777                         }
 778
 779                         break;
 780                 }
 781
 782                 case MSG_CHOICE:
 783                 {
 784                         if((chtype == NO_MSG) || (optiona == NO_MSG) || (optionb == NO_MSG))
 785                         {
 786                                 print(sprintf(
 787                                         strcat(
 788                                                 "^1NOTIFICATION IS MISSING CHOICE PARAMS: ",
 789                                                 "^7net_type = %s, net_name = %s.\n"
 790                                         ),
 791                                         typestring,
 792                                         namestring
 793                                 ));
 794                                 notif_error = TRUE;
 795                         }
 796                         else
 797                         {
 798                                 switch(chtype)
 799                                 {
 800                                         case MSG_ANNCE:
 801                                         {
 802                                                 notif.nent_optiona = msg_annce_notifs[optiona - 1];
 803                                                 notif.nent_optionb = msg_annce_notifs[optionb - 1];
 804                                                 break;
 805                                         }
 806                                         case MSG_INFO:
 807                                         {
 808                                                 notif.nent_optiona = msg_info_notifs[optiona - 1];
 809                                                 notif.nent_optionb = msg_info_notifs[optionb - 1];
 810                                                 break;
 811                                         }
 812                                         case MSG_CENTER:
 813                                         {
 814                                                 notif.nent_optiona = msg_center_notifs[optiona - 1];
 815                                                 notif.nent_optionb = msg_center_notifs[optionb - 1];
 816                                                 break;
 817                                         }
 818                                         case MSG_MULTI:
 819                                         {
 820                                                 notif.nent_optiona = msg_multi_notifs[optiona - 1];
 821                                                 notif.nent_optionb = msg_multi_notifs[optionb - 1];
 822                                                 break;
 823                                         }
 824                                         case MSG_CHOICE: // should we REALLY allow nested options?...
 825                                         {
 826                                                 notif.nent_optiona = msg_choice_notifs[optiona - 1];
 827                                                 notif.nent_optionb = msg_choice_notifs[optionb - 1];
 828                                                 break;
 829                                         }
 830
 831                                         default:
 832                                         {
 833                                                 print(sprintf(
 834                                                         strcat(
 835                                                                 "^1NOTIFICATION WITH IMPROPER TYPE: ",
 836                                                                 "^7net_type = %d, net_name = %s.\n"
 837                                                         ),
 838                                                         typeid,
 839                                                         namestring
 840                                                 ));
 841                                                 notif_error = TRUE;
 842                                                 break;
 843                                         }
 844                                 }
 845                                 notif.nent_challow_def = challow_def; // 0: never allowed, 1: allowed in warmup, 2: always allowed
 846                                 notif.nent_challow_var = challow_var; // 0: never allowed, 1: allowed in warmup, 2: always allowed
 847                                 notif.nent_stringcount = max(notif.nent_optiona.nent_stringcount, notif.nent_optionb.nent_stringcount);
 848                                 notif.nent_floatcount = max(notif.nent_optiona.nent_floatcount, notif.nent_optionb.nent_floatcount);
 849
 850                                 /*#ifdef NOTIFICATIONS_DEBUG
 851                                 Debug_Notification(sprintf(
 852                                         "Create_Notification_Entity(...): MSG_CHOICE: %s\n%s\n%s\n",
 853                                         notif.nent_name,
 854                                         sprintf(
 855                                                 "^ optiona: %s %s : %d %d",
 856                                                 Get_Notif_TypeName(notif.nent_optiona.nent_type),
 857                                                 notif.nent_optiona.nent_name,
 858                                                 notif.nent_optiona.nent_stringcount,
 859                                                 notif.nent_optiona.nent_floatcount
 860                                         ),
 861                                         sprintf(
 862                                                 "^ optionb: %s %s : %d %d",
 863                                                 Get_Notif_TypeName(notif.nent_optionb.nent_type),
 864                                                 notif.nent_optionb.nent_name,
 865                                                 notif.nent_optionb.nent_stringcount,
 866                                                 notif.nent_optionb.nent_floatcount
 867                                         )
 868                                 ));
 869                                 #endif*/
 870                         }
 871                         break;
 872                 }
 873
 874                 default:
 875                 {
 876                         print(sprintf(
 877                                 strcat(
 878                                         "^1NOTIFICATION WITH IMPROPER TYPE: ",
 879                                         "^7net_type = %d, net_name = %s.\n"
 880                                 ),
 881                                 typeid,
 882                                 namestring
 883                         ));
 884                         notif_error = TRUE;
 885                         break;
 886                 }
 887         }
 888
 889         // now check to see if any errors happened
 890         if(notif_error)
 891         {
 892                 notif.nent_enabled = FALSE; // disable the notification so it can't cause trouble
 893                 notif_global_error = TRUE; // throw the red flag that an error happened on init
 894         }
 895 }
 896
 897
 898 // ===============
 899 //  Cvar Handling
 900 // ===============
 901
 902 // used by MSG_CHOICE to build list of choices
 903 #ifdef SVQC
 904 void Notification_GetCvars(void)
 905 {
 906         float i;
 907         for(i = 0; i <= NOTIF_CHOICE_COUNT; ++i)
 908         {
 909                 GetCvars_handleFloat(
 910                         get_cvars_s,
 911                         get_cvars_f,
 912                         msg_choice_choices[i],
 913                         sprintf("notification_%s", msg_choice_notifs[i].nent_name)
 914                 );
 915         }
 916 }
 917 #endif
 918
 919 // used to output notifications.cfg file
 920 void Dump_Notifications(float fh, float alsoprint)
 921 {
 922         #define NOTIF_WRITE(a) { \
 923                 fputs(fh, a); \
 924                 if(alsoprint) { print(a); } }
 925         #define NOTIF_WRITE_ENTITY(description) { \
 926                 notif_msg = \
 927                         sprintf( \
 928                                 "seta notification_%s \"%d\" \"%s\"\n", \
 929                                 e.nent_name, e.nent_default, description \
 930                         ); \
 931                 NOTIF_WRITE(notif_msg) }
 932         #define NOTIF_WRITE_ENTITY_CHOICE(descriptiona,descriptionb) { \
 933                 notif_msg = \
 934                         sprintf( \
 935                                 "seta notification_%s \"%d\" \"%s\"\n" \
 936                                 "seta notification_%s_ALLOWED \"%d\" \"%s\"\n", \
 937                                 e.nent_name, e.nent_default, descriptiona, \
 938                                 e.nent_name, e.nent_challow_def, descriptionb \
 939                         ); \
 940                 NOTIF_WRITE(notif_msg) }
 941         #define NOTIF_WRITE_HARDCODED(cvar,default,description) { \
 942                 notif_msg = \
 943                         sprintf( \
 944                                 "seta notification_%s \"%s\" \"%s\"\n", \
 945                                 cvar, default, description \
 946                         ); \
 947                 NOTIF_WRITE(notif_msg) }
 948
 949         string notif_msg;
 950         float i;
 951         entity e;
 952
 953         // Note: This warning only applies to the notifications.cfg file that is output...
 954
 955         // You ARE supposed to manually edit this function to add i.e. hard coded
 956         // notification variables for mutators or game modes or such and then
 957         // regenerate the notifications.cfg file from the new code.
 958
 959         NOTIF_WRITE("// ********************************************** //\n");
 960         NOTIF_WRITE("// ** WARNING - DO NOT MANUALLY EDIT THIS FILE ** //\n");
 961         NOTIF_WRITE("// **                                          ** //\n");
 962         NOTIF_WRITE("// **  This file is automatically generated    ** //\n");
 963         NOTIF_WRITE("// **  by code with the command 'dumpnotifs'.  ** //\n");
 964         NOTIF_WRITE("// **                                          ** //\n");
 965         NOTIF_WRITE("// **  If you add a new notification, please   ** //\n");
 966         NOTIF_WRITE("// **  regenerate this file with that command  ** //\n");
 967         NOTIF_WRITE("// **  making sure that the output matches     ** //\n");
 968         NOTIF_WRITE("// **  with the lists and defaults in code.    ** //\n");
 969         NOTIF_WRITE("// **                                          ** //\n");
 970         NOTIF_WRITE("// ********************************************** //\n");
 971
 972         // These notifications will also append their string as a comment...
 973         // This is not necessary, and does not matter if they vary between config versions,
 974         // it is just a semi-helpful tool for those who want to manually change their user settings.
 975
 976         NOTIF_WRITE(sprintf("\n// MSG_ANNCE notifications (count = %d):\n", NOTIF_ANNCE_COUNT));
 977         for(i = 1; i <= NOTIF_ANNCE_COUNT; ++i)
 978         {
 979                 e = Get_Notif_Ent(MSG_ANNCE, i);
 980                 if not(e) { backtrace("Dump_Notifications(): Missing notification entity!\n"); return; }
 981
 982                 NOTIF_WRITE_ENTITY(
 983                         "Notification control cvar: 0 = disabled, 1 = enabled if gentle mode is off, 2 = always enabled)"
 984                 );
 985         }
 986
 987         NOTIF_WRITE(sprintf("\n// MSG_INFO notifications (count = %d):\n", NOTIF_INFO_COUNT));
 988         for(i = 1; i <= NOTIF_INFO_COUNT; ++i)
 989         {
 990                 e = Get_Notif_Ent(MSG_INFO, i);
 991                 if not(e) { backtrace("Dump_Notifications(): Missing notification entity!\n"); return; }
 992
 993                 NOTIF_WRITE_ENTITY(
 994                         "Notification control cvar: 0 = off, 1 = print to console, "
 995                         "2 = print to console and chatbox (if notification_allow_chatboxprint is enabled)"
 996                 );
 997         }
 998
 999         NOTIF_WRITE(sprintf("\n// MSG_CENTER notifications (count = %d):\n", NOTIF_CENTER_COUNT));
1000         for(i = 1; i <= NOTIF_CENTER_COUNT; ++i)
1001         {
1002                 e = Get_Notif_Ent(MSG_CENTER, i);
1003                 if not(e) { backtrace("Dump_Notifications(): Missing notification entity!\n"); return; }
1004
1005                 NOTIF_WRITE_ENTITY(
1006                         "Notification control cvar: 0 = off, 1 = centerprint"
1007                 );
1008         }
1009
1010         NOTIF_WRITE(sprintf("\n// MSG_MULTI notifications (count = %d):\n", NOTIF_MULTI_COUNT));
1011         for(i = 1; i <= NOTIF_MULTI_COUNT; ++i)
1012         {
1013                 e = Get_Notif_Ent(MSG_MULTI, i);
1014                 if not(e) { backtrace("Dump_Notifications(): Missing notification entity!\n"); return; }
1015
1016                 NOTIF_WRITE_ENTITY(
1017                         "Notification control cvar: 0 = off, 1 = trigger subcalls"
1018                 );
1019         }
1020
1021         NOTIF_WRITE(sprintf("\n// MSG_CHOICE notifications (count = %d):\n", NOTIF_CHOICE_COUNT));
1022         for(i = 1; i <= NOTIF_CHOICE_COUNT; ++i)
1023         {
1024                 e = Get_Notif_Ent(MSG_CHOICE, i);
1025                 if not(e) { backtrace("Dump_Notifications(): Missing notification entity!\n"); return; }
1026
1027                 NOTIF_WRITE_ENTITY_CHOICE(
1028                         "Notification control cvar: 0 = off, 1 = trigger option A subcall, 2 = trigger option B subcall",
1029                         "Notification control cvar: 0 = off, 1 = allowed in warmup mode, 2 = always allowed"
1030                 );
1031         }
1032
1033         // edit these to match whichever cvars are used for specific notification options
1034         NOTIF_WRITE("\n// HARD CODED notification variables:\n");
1035
1036         NOTIF_WRITE_HARDCODED(
1037                 "allow_chatboxprint", "1",
1038                 "Allow notifications to be printed to chat box by setting notification cvar to 2 "
1039                 "(You can also set this cvar to 2 to force ALL notifications to be printed to the chatbox)"
1040         );
1041
1042         NOTIF_WRITE_HARDCODED(
1043                 "debug", "0",
1044                 "Print extra debug information on all notification function calls "
1045                 "(Requires -DNOTIFICATIONS_DEBUG flag to be enabled on QCSRC compilation)... "
1046                 "0 = disabled, 1 = dprint, 2 = print"
1047         );
1048
1049         NOTIF_WRITE_HARDCODED(
1050                 "errors_are_fatal", "1",
1051                 "If a notification fails upon initialization, cause a Host_Error to stop the program"
1052         );
1053
1054         NOTIF_WRITE_HARDCODED(
1055                 "item_centerprinttime", "1.5",
1056                 "How long to show item information centerprint messages (like 'You got the Electro' or such)"
1057         );
1058
1059         NOTIF_WRITE_HARDCODED(
1060                 "lifetime_mapload", "10",
1061                 "Amount of time that notification entities last immediately at mapload (in seconds) "
1062                 "to help prevent notifications from being lost on early init (like gamestart countdown)"
1063         );
1064
1065         NOTIF_WRITE_HARDCODED(
1066                 "lifetime_runtime", "0.5",
1067                 "Amount of time that notification entities last on the server during runtime (In seconds)"
1068         );
1069
1070         NOTIF_WRITE_HARDCODED(
1071                 "server_allows_location", "1",
1072                 "Server side cvar for allowing death messages to show location information too"
1073         );
1074
1075         NOTIF_WRITE_HARDCODED(
1076                 "show_location", "0",
1077                 "Append location information to MSG_INFO death/kill messages"
1078         );
1079
1080         NOTIF_WRITE_HARDCODED(
1081                 "show_location_string", "",
1082                 "Replacement string piped into sprintf, "
1083                 "so you can do different messages like this: ' at the %s' or ' (near %s)'"
1084         );
1085
1086         NOTIF_WRITE_HARDCODED(
1087                 "show_sprees", "1",
1088                 "Print information about sprees in death/kill messages"
1089         );
1090
1091         NOTIF_WRITE_HARDCODED(
1092                 "show_sprees_center", "1",
1093                 "Show spree information in MSG_CENTER messages... "
1094                 "0 = off, 1 = target (but only for first victim) and attacker"
1095         );
1096
1097         NOTIF_WRITE_HARDCODED(
1098                 "show_sprees_center_specialonly", "1",
1099                 "Don't show spree information in MSG_CENTER messages if it isn't an achievement"
1100         );
1101
1102         NOTIF_WRITE_HARDCODED(
1103                 "show_sprees_info", "3",
1104                 "Show spree information in MSG_INFO messages... "
1105                 "0 = off, 1 = target only, 2 = attacker only, 3 = target and attacker"
1106         );
1107
1108         NOTIF_WRITE_HARDCODED(
1109                 "show_sprees_info_newline", "1",
1110                 "Show attacker spree information for MSG_INFO messages on a separate line than the death notification itself"
1111         );
1112
1113         NOTIF_WRITE_HARDCODED(
1114                 "show_sprees_info_specialonly", "1",
1115                 "Don't show attacker spree information in MSG_INFO messages if it isn't an achievement"
1116         );
1117
1118         NOTIF_WRITE(sprintf(
1119                 strcat(
1120                         "\n// Notification counts (total = %d): ",
1121                         "MSG_ANNCE = %d, MSG_INFO = %d, MSG_CENTER = %d, MSG_MULTI = %d, MSG_CHOICE = %d\n"
1122                 ),
1123                 (
1124                         NOTIF_ANNCE_COUNT +
1125                         NOTIF_INFO_COUNT +
1126                         NOTIF_CENTER_COUNT +
1127                         NOTIF_MULTI_COUNT +
1128                         NOTIF_CHOICE_COUNT
1129                 ),
1130                 NOTIF_ANNCE_COUNT,
1131                 NOTIF_INFO_COUNT,
1132                 NOTIF_CENTER_COUNT,
1133                 NOTIF_MULTI_COUNT,
1134                 NOTIF_CHOICE_COUNT
1135         ));
1136
1137         return;
1138         #undef NOTIF_WRITE_HARDCODED
1139         #undef NOTIF_WRITE_ENTITY
1140         #undef NOTIF_WRITE
1141 }
1142
1143
1144 // ===============================
1145 //  Frontend Notification Pushing
1146 // ===============================
1147
1148 #ifdef NOTIFICATIONS_DEBUG
1149 void Debug_Notification(string input)
1150 {
1151         switch(autocvar_notification_debug)
1152         {
1153                 case 1: { dprint(input); break; }
1154                 case 2: { print(input); break; }
1155         }
1156 }
1157 #endif
1158
1159 string Local_Notification_sprintf(
1160         string input, string args,
1161         string s1, string s2, string s3, string s4,
1162         float f1, float f2, float f3, float f4)
1163 {
1164         #ifdef NOTIFICATIONS_DEBUG
1165         Debug_Notification(sprintf(
1166                 "Local_Notification_sprintf('%s^7', '%s', %s, %s);\n",
1167                 MakeConsoleSafe(input),
1168                 args,
1169                 MakeConsoleSafe(sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4)),
1170                 sprintf("%d, %d, %d, %d", f1, f2, f3, f4)
1171         ));
1172         #endif
1173
1174         string selected;
1175         float sel_num;
1176         for(sel_num = 0; sel_num < NOTIF_MAX_ARGS; ++sel_num) { arg_slot[sel_num] = ""; }
1177
1178         string tmp_s;
1179
1180         for(sel_num = 0;(args != "");)
1181         {
1182                 selected = car(args); args = cdr(args);
1183                 NOTIF_HIT_MAX(NOTIF_MAX_ARGS, "Local_Notification_sprintf")
1184                 switch(strtolower(selected))
1185                 {
1186                         #define ARG_CASE(prog,selected,result) \
1187                                 #ifdef CSQC \
1188                                         #if (prog != ARG_SV) && (prog != ARG_DC) \
1189                                                 case selected: { arg_slot[sel_num] = result; ++sel_num; break; } \
1190                                         #endif \
1191                                 #else \
1192                                         #if (prog != ARG_CS) && (prog != ARG_DC) \
1193                                                 case selected: { arg_slot[sel_num] = result; ++sel_num; break; } \
1194                                         #endif \
1195                                 #endif
1196                         NOTIF_ARGUMENT_LIST
1197                         #undef ARG_CASE
1198                         default: NOTIF_HIT_UNKNOWN(NOTIF_MAX_ARGS, "Local_Notification_sprintf")
1199                 }
1200         }
1201         return sprintf(
1202                 strcat(input, "\n"),
1203                 arg_slot[0],
1204                 arg_slot[1],
1205                 arg_slot[2],
1206                 arg_slot[3],
1207                 arg_slot[4],
1208                 arg_slot[5],
1209                 arg_slot[6]
1210         );
1211 }
1212
1213 #ifdef CSQC
1214 void Local_Notification_sound(
1215         float soundchannel, string soundfile,
1216         float soundvolume, float soundposition)
1217 {
1218         if((soundfile != prev_soundfile) || (time >= (prev_soundtime + autocvar_cl_announcer_antispam)))
1219         {
1220                 #ifdef NOTIFICATIONS_DEBUG
1221                 Debug_Notification(sprintf(
1222                         "Local_Notification_sound(world, %f, '%s', %f, %f);\n",
1223                         soundchannel,
1224                         sprintf(
1225                                 "announcer/%s/%s.wav",
1226                                 autocvar_cl_announcer,
1227                                 soundfile
1228                         ),
1229                         soundvolume,
1230                         soundposition
1231                 ));
1232                 #endif
1233
1234                 sound(
1235                         world,
1236                         soundchannel,
1237                         sprintf(
1238                                 "announcer/%s/%s.wav",
1239                                 autocvar_cl_announcer,
1240                                 soundfile
1241                         ),
1242                         soundvolume,
1243                         soundposition
1244                 );
1245
1246                 if(prev_soundfile) { strunzone(prev_soundfile); }
1247                 prev_soundfile = strzone(soundfile);
1248                 prev_soundtime = time;
1249         }
1250         else
1251         {
1252                 #ifdef NOTIFICATIONS_DEBUG
1253                 Debug_Notification(sprintf(
1254                         strcat(
1255                                 "Local_Notification_sound(world, %f, '%s', %f, %f) ",
1256                                 "^1BLOCKED BY ANTISPAM:^7 prevsnd: '%s', timediff: %f, limit: %f\n"
1257                          ),
1258                         soundchannel,
1259                         sprintf(
1260                                 "announcer/%s/%s.wav",
1261                                 autocvar_cl_announcer,
1262                                 soundfile
1263                         ),
1264                         soundvolume,
1265                         soundposition,
1266                         prev_soundfile,
1267                         (time - prev_soundtime),
1268                         autocvar_cl_announcer_antispam
1269                 ));
1270                 #endif
1271         }
1272 }
1273
1274 void Local_Notification_HUD_Notify_Push(
1275         string icon, string hudargs,
1276         string s1, string s2, string s3, string s4)
1277 {
1278         string selected;
1279         float sel_num;
1280         arg_slot[0] = ""; arg_slot[1] = "";
1281
1282         for(sel_num = 0;(hudargs != "");)
1283         {
1284                 selected = car(hudargs); hudargs = cdr(hudargs);
1285                 NOTIF_HIT_MAX(NOTIF_MAX_HUDARGS, "Local_Notification_HUD_Notify_Push")
1286                 switch(strtolower(selected))
1287                 {
1288                         #define ARG_CASE(prog,selected,result) \
1289                                 #if (prog == ARG_CS_SV_HA) \
1290                                         case selected: { arg_slot[sel_num] = result; ++sel_num; break; } \
1291                                 #endif
1292                         NOTIF_ARGUMENT_LIST
1293                         #undef ARG_CASE
1294                         default: NOTIF_HIT_UNKNOWN(NOTIF_MAX_HUDARGS, "Local_Notification_HUD_Notify_Push")
1295                 }
1296         }
1297         #ifdef NOTIFICATIONS_DEBUG
1298         Debug_Notification(sprintf(
1299                 "Local_Notification_HUD_Notify_Push('%s^7', '%s', %s, %s);\n",
1300                 icon,
1301                 hudargs,
1302                 MakeConsoleSafe(sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4)),
1303                 MakeConsoleSafe(sprintf("'%s^7', '%s^7'", stof(arg_slot[0]), stof(arg_slot[1])))
1304         ));
1305         #endif
1306         HUD_Notify_Push(icon, arg_slot[0], arg_slot[1]);
1307 }
1308
1309 void Local_Notification_centerprint_generic(
1310         string input, string durcnt,
1311         float cpid, float f1, float f2)
1312 {
1313         string selected;
1314         float sel_num;
1315         arg_slot[0] = ""; arg_slot[1] = "";
1316
1317         for(sel_num = 0;(durcnt != "");)
1318         {
1319                 selected = car(durcnt); durcnt = cdr(durcnt);
1320                 NOTIF_HIT_MAX(NOTIF_MAX_DURCNT, "Local_Notification_centerprint_generic")
1321                 switch(strtolower(selected))
1322                 {
1323                         #define ARG_CASE(prog,selected,result) \
1324                                 #if (prog == ARG_CS_SV_DC) || (prog == ARG_DC) \
1325                                         case selected: { arg_slot[sel_num] = result; ++sel_num; break; } \
1326                                 #endif
1327                         NOTIF_ARGUMENT_LIST
1328                         #undef ARG_CASE
1329                         default:
1330                         {
1331                                 if(ftos(stof(selected)) != "") { arg_slot[sel_num] = selected; ++sel_num; }
1332                                 else { NOTIF_HIT_UNKNOWN(NOTIF_MAX_DURCNT, "Local_Notification_centerprint_generic") }
1333                                 break;
1334                         }
1335                 }
1336         }
1337         #ifdef NOTIFICATIONS_DEBUG
1338         Debug_Notification(sprintf(
1339                 "Local_Notification_centerprint_generic('%s^7', '%s', %d, %d, %d, %d);\n",
1340                 MakeConsoleSafe(input),
1341                 durcnt,
1342                 f1, f2,
1343                 stof(arg_slot[0]),
1344                 stof(arg_slot[1])
1345         ));
1346         #endif
1347         centerprint_generic(cpid, input, stof(arg_slot[0]), stof(arg_slot[1]));
1348 }
1349 #endif
1350
1351 void Local_Notification(float net_type, float net_name, ...count)
1352 {
1353         // check if this should be aborted
1354         if(net_name == NOTIF_ABORT)
1355         {
1356                 #ifdef NOTIFICATIONS_DEBUG
1357                 Debug_Notification(sprintf(
1358                         "Local_Notification(%s, %s, ...);\n",
1359                         Get_Notif_TypeName(net_type),
1360                         "NOTIF_ABORT"
1361                 ));
1362                 #endif
1363                 return;
1364         }
1365
1366         // check supplied type and name for errors
1367         string checkargs = Notification_CheckArgs_TypeName(net_type, net_name);
1368         if(checkargs != "")
1369         {
1370                 #ifdef NOTIFICATIONS_DEBUG
1371                 Debug_Notification(sprintf(
1372                         "Local_Notification(%s, %d, ...);\n",
1373                         Get_Notif_TypeName(net_type),
1374                         Get_Notif_Ent(net_type, net_name).nent_name
1375                 ));
1376                 #endif
1377                 backtrace(sprintf("Incorrect usage of Local_Notification: %s\n", checkargs));
1378                 return;
1379         }
1380
1381         // retreive entity of this notification
1382         entity notif = Get_Notif_Ent(net_type, net_name);
1383         if not(notif)
1384         {
1385                 #ifdef NOTIFICATIONS_DEBUG
1386                 Debug_Notification(sprintf(
1387                         "Local_Notification(%s, %d, ...);\n",
1388                         Get_Notif_TypeName(net_type),
1389                         net_name
1390                 ));
1391                 #endif
1392                 backtrace("Local_Notification: Could not find notification entity!\n");
1393                 return;
1394         }
1395
1396         // check if the notification is enabled
1397         if not(notif.nent_enabled)
1398         {
1399                 #ifdef NOTIFICATIONS_DEBUG
1400                 Debug_Notification(sprintf(
1401                         "Local_Notification(%s, %s, ...): Entity was disabled...\n",
1402                         Get_Notif_TypeName(net_type),
1403                         notif.nent_name
1404                 ));
1405                 #endif
1406                 return;
1407         }
1408
1409         string s1 = ((0 < notif.nent_stringcount) ? ...(0, string) : "");
1410         string s2 = ((1 < notif.nent_stringcount) ? ...(1, string) : "");
1411         string s3 = ((2 < notif.nent_stringcount) ? ...(2, string) : "");
1412         string s4 = ((3 < notif.nent_stringcount) ? ...(3, string) : "");
1413         float f1 = ((0 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 0), float) : 0);
1414         float f2 = ((1 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 1), float) : 0);
1415         float f3 = ((2 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 2), float) : 0);
1416         float f4 = ((3 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 3), float) : 0);
1417
1418         #ifdef NOTIFICATIONS_DEBUG
1419         Debug_Notification(sprintf(
1420                 "Local_Notification(%s, %s, %s, %s);\n",
1421                 Get_Notif_TypeName(net_type),
1422                 notif.nent_name,
1423                 MakeConsoleSafe(sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4)),
1424                 sprintf("%d, %d, %d, %d", f1, f2, f3, f4)
1425         ));
1426         #endif
1427
1428         if((notif.nent_stringcount + notif.nent_floatcount) > count)
1429         {
1430                 backtrace(sprintf(
1431                         strcat(
1432                                 "Not enough arguments for Local_Notification(%s, %s, ...)! ",
1433                                 "stringcount(%d) + floatcount(%d) > count(%d)\n",
1434                                 "Check the definition and function call for accuracy...?\n"
1435                         ),
1436                         Get_Notif_TypeName(net_type),
1437                         notif.nent_name,
1438                         notif.nent_stringcount,
1439                         notif.nent_floatcount,
1440                         count
1441                 ));
1442                 return;
1443         }
1444         else if((notif.nent_stringcount + notif.nent_floatcount) < count)
1445         {
1446                 backtrace(sprintf(
1447                         strcat(
1448                                 "Too many arguments for Local_Notification(%s, %s, ...)! ",
1449                                 "stringcount(%d) + floatcount(%d) < count(%d)\n",
1450                                 "Check the definition and function call for accuracy...?\n"
1451                         ),
1452                         Get_Notif_TypeName(net_type),
1453                         notif.nent_name,
1454                         notif.nent_stringcount,
1455                         notif.nent_floatcount,
1456                         count
1457                 ));
1458                 return;
1459         }
1460
1461         switch(net_type)
1462         {
1463                 case MSG_ANNCE:
1464                 {
1465                         #ifdef CSQC
1466                         Local_Notification_sound(
1467                                 notif.nent_channel,
1468                                 notif.nent_snd,
1469                                 notif.nent_vol,
1470                                 notif.nent_position
1471                         );
1472                         #else
1473                         backtrace("MSG_ANNCE on server?... Please notify Samual immediately!\n");
1474                         #endif
1475                         break;
1476                 }
1477
1478                 case MSG_INFO:
1479                 {
1480                         print(
1481                                 Local_Notification_sprintf(
1482                                         notif.nent_string,
1483                                         notif.nent_args,
1484                                         s1, s2, s3, s4,
1485                                         f1, f2, f3, f4)
1486                         );
1487                         #ifdef CSQC
1488                         if(notif.nent_icon != "")
1489                         {
1490                                 Local_Notification_HUD_Notify_Push(
1491                                         notif.nent_icon,
1492                                         notif.nent_hudargs,
1493                                         s1, s2, s3, s4);
1494                         }
1495                         #endif
1496                         break;
1497                 }
1498
1499                 #ifdef CSQC
1500                 case MSG_CENTER:
1501                 {
1502                         Local_Notification_centerprint_generic(
1503                                 Local_Notification_sprintf(
1504                                         notif.nent_string,
1505                                         notif.nent_args,
1506                                         s1, s2, s3, s4,
1507                                         f1, f2, f3, f4),
1508                                 notif.nent_durcnt,
1509                                 notif.nent_cpid,
1510                                 f1, f2);
1511                         break;
1512                 }
1513                 #endif
1514
1515                 case MSG_MULTI:
1516                 {
1517                         if(notif.nent_msginfo)
1518                         if(notif.nent_msginfo.nent_enabled)
1519                         {
1520                                 Local_Notification_WOVA(
1521                                         MSG_INFO,
1522                                         notif.nent_msginfo.nent_id,
1523                                         notif.nent_msginfo.nent_stringcount,
1524                                         notif.nent_msginfo.nent_floatcount,
1525                                         s1, s2, s3, s4,
1526                                         f1, f2, f3, f4);
1527                         }
1528                         #ifdef CSQC
1529                         if(notif.nent_msgannce)
1530                         if(notif.nent_msgannce.nent_enabled)
1531                         {
1532                                 Local_Notification_WOVA(
1533                                         MSG_ANNCE,
1534                                         notif.nent_msgannce.nent_id,
1535                                         0, 0,
1536                                         "", "", "", "",
1537                                         0, 0, 0, 0);
1538                         }
1539                         if(notif.nent_msgcenter)
1540                         if(notif.nent_msgcenter.nent_enabled)
1541                         {
1542                                 Local_Notification_WOVA(
1543                                         MSG_CENTER,
1544                                         notif.nent_msgcenter.nent_id,
1545                                         notif.nent_msgcenter.nent_stringcount,
1546                                         notif.nent_msgcenter.nent_floatcount,
1547                                         s1, s2, s3, s4,
1548                                         f1, f2, f3, f4);
1549                         }
1550                         #endif
1551                         break;
1552                 }
1553
1554                 case MSG_CHOICE:
1555                 {
1556                         entity found_choice;
1557
1558                         if(notif.nent_challow_var && (warmup_stage || (notif.nent_challow_var == 2)))
1559                         {
1560                                 switch(cvar_string(sprintf("notification_%s", notif.nent_name)))
1561                                 {
1562                                         case 1: found_choice = notif.nent_optiona; break;
1563                                         case 2: found_choice = notif.nent_optionb; break;
1564                                         default: return; // not enabled anyway
1565                                 }
1566                         }
1567                         else { found_choice = notif.nent_optiona; }
1568
1569                         Local_Notification_WOVA(
1570                                 found_choice.nent_type,
1571                                 found_choice.nent_id,
1572                                 found_choice.nent_stringcount,
1573                                 found_choice.nent_floatcount,
1574                                 s1, s2, s3, s4,
1575                                 f1, f2, f3, f4);
1576                 }
1577         }
1578 }
1579
1580 // WOVA = Without Variable Arguments
1581 void Local_Notification_WOVA(
1582         float net_type, float net_name,
1583         float stringcount, float floatcount,
1584         string s1, string s2, string s3, string s4,
1585         float f1, float f2, float f3, float f4)
1586 {
1587         #define VARITEM(stringc,floatc,args) \
1588                 if((stringcount == stringc) && (floatcount == floatc)) \
1589                         { Local_Notification(net_type, net_name, args); return; }
1590         EIGHT_VARS_TO_VARARGS_VARLIST
1591         #undef VARITEM
1592         Local_Notification(net_type, net_name); // some notifications don't have any arguments at all
1593 }
1594
1595
1596 // =========================
1597 //  Notification Networking
1598 // =========================
1599
1600 #ifdef CSQC
1601 void Read_Notification(float is_new)
1602 {
1603         float net_type = ReadByte();
1604         float net_name = ReadShort();
1605
1606         entity notif;
1607
1608         if(net_type == MSG_CENTER_CPID)
1609         {
1610                 #ifdef NOTIFICATIONS_DEBUG
1611                 Debug_Notification(sprintf(
1612                         "Read_Notification(%d) at %f: net_type = %s, net_name = %d\n",
1613                         is_new,
1614                         time,
1615                         Get_Notif_TypeName(net_type),
1616                         net_name
1617                 ));
1618                 #endif
1619
1620                 if(is_new)
1621                 {
1622                         if(net_name == 0) { reset_centerprint_messages(); }
1623                         else if(net_name != NO_CPID)
1624                         {
1625                                 // in this case, net_name IS the cpid we want to kill
1626                                 centerprint_generic(net_name, "", 0, 0);
1627                         }
1628                         else
1629                         {
1630                                 backtrace(sprintf(
1631                                         "Read_Notification(%d) at %f: ^1TRIED TO KILL NO_CPID CENTERPRINT!\n",
1632                                         is_new,
1633                                         time
1634                                 ));
1635                         }
1636                 }
1637         }
1638         else
1639         {
1640                 notif = Get_Notif_Ent(net_type, net_name);
1641                 if not(notif) { backtrace("Read_Notification: Could not find notification entity!\n"); return; }
1642
1643                 #ifdef NOTIFICATIONS_DEBUG
1644                 Debug_Notification(sprintf(
1645                         "Read_Notification(%d) at %f: net_type = %s, net_name = %s\n",
1646                         is_new,
1647                         time,
1648                         Get_Notif_TypeName(net_type),
1649                         notif.nent_name
1650                 ));
1651                 #endif
1652
1653                 string s1 = ((0 < notif.nent_stringcount) ? ReadString() : "");
1654                 string s2 = ((1 < notif.nent_stringcount) ? ReadString() : "");
1655                 string s3 = ((2 < notif.nent_stringcount) ? ReadString() : "");
1656                 string s4 = ((3 < notif.nent_stringcount) ? ReadString() : "");
1657                 float f1 = ((0 < notif.nent_floatcount) ? ReadLong() : 0);
1658                 float f2 = ((1 < notif.nent_floatcount) ? ReadLong() : 0);
1659                 float f3 = ((2 < notif.nent_floatcount) ? ReadLong() : 0);
1660                 float f4 = ((3 < notif.nent_floatcount) ? ReadLong() : 0);
1661
1662                 if(is_new)
1663                 {
1664                         Local_Notification_WOVA(
1665                                 net_type, net_name,
1666                                 notif.nent_stringcount,
1667                                 notif.nent_floatcount,
1668                                 s1, s2, s3, s4,
1669                                 f1, f2, f3, f4);
1670                 }
1671         }
1672 }
1673 #endif
1674
1675 #ifdef SVQC
1676 void Net_Notification_Remove()
1677 {
1678         if not(self) { backtrace(sprintf("Net_Notification_Remove() at %f: Missing self!?\n", time)); return; }
1679
1680         #ifdef NOTIFICATIONS_DEBUG
1681         Debug_Notification(sprintf(
1682                 "Net_Notification_Remove() at %f: %s '%s - %s' notification\n",
1683                 time,
1684                 ((self.nent_net_name == -1) ? "Killed" : "Removed"),
1685                 Get_Notif_TypeName(self.nent_net_type),
1686                 self.owner.nent_name
1687         ));
1688         #endif
1689
1690         float i;
1691         for(i = 0; i < 4; ++i) { if(self.nent_strings[i]) { strunzone(self.nent_strings[i]); } }
1692         remove(self);
1693 }
1694
1695 float Net_Write_Notification(entity client, float sf)
1696 {
1697         if(Notification_ShouldSend(self.nent_broadcast, client, self.nent_client))
1698         {
1699                 float i;
1700                 WriteByte(MSG_ENTITY, ENT_CLIENT_NOTIFICATION);
1701                 WriteByte(MSG_ENTITY, self.nent_net_type);
1702                 WriteShort(MSG_ENTITY, self.nent_net_name);
1703                 for(i = 0; i < self.nent_stringcount; ++i) { WriteString(MSG_ENTITY, self.nent_strings[i]); }
1704                 for(i = 0; i < self.nent_floatcount; ++i) { WriteLong(MSG_ENTITY, self.nent_floats[i]); }
1705                 return TRUE;
1706         }
1707         else { return FALSE; }
1708 }
1709
1710 void Kill_Notification(
1711         float broadcast, entity client,
1712         float net_type, float net_name)
1713 {
1714         #ifdef NOTIFICATIONS_DEBUG
1715         Debug_Notification(sprintf(
1716                 "Kill_Notification(%s, '%s', %s, %d);\n",
1717                 Get_Notif_BroadcastName(broadcast),
1718                 client.netname,
1719                 (net_type ? Get_Notif_TypeName(net_type) : "0"),
1720                 net_name
1721         ));
1722         #endif
1723
1724         string checkargs = Notification_CheckArgs(broadcast, client, 1, 1);
1725         if(checkargs != "") { backtrace(sprintf("Incorrect usage of Kill_Notification: %s\n", checkargs)); return; }
1726
1727         entity notif, net_notif;
1728         float killed_cpid = NO_CPID;
1729
1730         switch(net_type)
1731         {
1732                 case 0:
1733                 {
1734                         killed_cpid = 0; // kill ALL centerprints
1735                         break;
1736                 }
1737
1738                 case MSG_CENTER:
1739                 {
1740                         if(net_name)
1741                         {
1742                                 entity notif = Get_Notif_Ent(net_type, net_name);
1743                                 if not(notif) { backtrace("Kill_Notification: Could not find notification entity!\n"); return; }
1744
1745                                 if(notif.nent_cpid)
1746                                         killed_cpid = notif.nent_cpid;
1747                                 else
1748                                         killed_cpid = NO_CPID;
1749                         }
1750                         else
1751                         {
1752                                 killed_cpid = 0; // kill ALL centerprints
1753                         }
1754                         break;
1755                 }
1756
1757                 case MSG_CENTER_CPID:
1758                 {
1759                         killed_cpid = net_name;
1760                         break;
1761                 }
1762         }
1763
1764         if(killed_cpid != NO_CPID)
1765         {
1766                 net_notif = spawn();
1767                 net_notif.classname = "net_kill_notification";
1768                 net_notif.nent_broadcast = broadcast;
1769                 net_notif.nent_client = client;
1770                 net_notif.nent_net_type = MSG_CENTER_CPID;
1771                 net_notif.nent_net_name = killed_cpid;
1772                 Net_LinkEntity(net_notif, FALSE, autocvar_notification_lifetime_runtime, Net_Write_Notification);
1773         }
1774
1775         for(notif = world; (notif = find(notif, classname, "net_notification"));)
1776         {
1777                 if(net_type)
1778                 {
1779                         if((killed_cpid != NO_CPID) && (notif.nent_net_type == MSG_CENTER))
1780                         {
1781                                 if(notif.owner.nent_cpid == killed_cpid)
1782                                 {
1783                                         notif.nent_net_name = -1;
1784                                         notif.nextthink = time;
1785                                 }
1786                                 else { continue; } // we ARE looking for a specific CPID, don't kill everything else too
1787                         }
1788                         else if(notif.nent_net_type == net_type)
1789                         {
1790                                 if(net_name)
1791                                 {
1792                                         if(notif.nent_net_name == net_name) { notif.nent_net_name = -1; notif.nextthink = time; }
1793                                         else { continue; } // we ARE looking for a certain net_name, don't kill everything else too
1794                                 }
1795                                 else { notif.nent_net_name = -1; notif.nextthink = time; }
1796                         }
1797                         else { continue; } // we ARE looking for a certain net_type, don't kill everything else too
1798                 }
1799                 else { notif.nent_net_name = -1; notif.nextthink = time; }
1800         }
1801 }
1802
1803 void Send_Notification(
1804         float broadcast, entity client,
1805         float net_type, float net_name,
1806         ...count)
1807 {
1808         // check if this should be aborted
1809         if(net_name == NOTIF_ABORT)
1810         {
1811                 #ifdef NOTIFICATIONS_DEBUG
1812                 Debug_Notification(sprintf(
1813                         "Send_Notification(%s, '%s', %s, %s, ...);\n",
1814                         Get_Notif_BroadcastName(broadcast),
1815                         client.classname,
1816                         Get_Notif_TypeName(net_type),
1817                         "NOTIF_ABORT"
1818                 ));
1819                 #endif
1820                 return;
1821         }
1822
1823         // check supplied broadcast, target, type, and name for errors
1824         string checkargs = Notification_CheckArgs(broadcast, client, net_type, net_name);
1825         if(checkargs != "")
1826         {
1827                 #ifdef NOTIFICATIONS_DEBUG
1828                 Debug_Notification(sprintf(
1829                         "Send_Notification(%s, '%s', %s, %s, ...);\n",
1830                         Get_Notif_BroadcastName(broadcast),
1831                         client.classname,
1832                         Get_Notif_TypeName(net_type),
1833                         Get_Notif_Ent(net_type, net_name).nent_name
1834                 ));
1835                 #endif
1836                 backtrace(sprintf("Incorrect usage of Send_Notification: %s\n", checkargs));
1837                 return;
1838         }
1839
1840         // retreive entity of this notification
1841         entity notif = Get_Notif_Ent(net_type, net_name);
1842         if not(notif)
1843         {
1844                 #ifdef NOTIFICATIONS_DEBUG
1845                 Debug_Notification(sprintf(
1846                         "Send_Notification(%s, '%s', %s, %d, ...);\n",
1847                         Get_Notif_BroadcastName(broadcast),
1848                         client.classname,
1849                         Get_Notif_TypeName(net_type),
1850                         net_name
1851                 ));
1852                 #endif
1853                 backtrace("Send_Notification: Could not find notification entity!\n");
1854                 return;
1855         }
1856
1857         string s1 = ((0 < notif.nent_stringcount) ? ...(0, string) : "");
1858         string s2 = ((1 < notif.nent_stringcount) ? ...(1, string) : "");
1859         string s3 = ((2 < notif.nent_stringcount) ? ...(2, string) : "");
1860         string s4 = ((3 < notif.nent_stringcount) ? ...(3, string) : "");
1861         float f1 = ((0 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 0), float) : 0);
1862         float f2 = ((1 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 1), float) : 0);
1863         float f3 = ((2 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 2), float) : 0);
1864         float f4 = ((3 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 3), float) : 0);
1865
1866         #ifdef NOTIFICATIONS_DEBUG
1867         Debug_Notification(sprintf(
1868                 "Send_Notification(%s, %s, %s);\n",
1869                 sprintf(
1870                         "%s, '%s', %s, %s",
1871                         Get_Notif_BroadcastName(broadcast),
1872                         client.classname,
1873                         Get_Notif_TypeName(net_type),
1874                         notif.nent_name
1875                 ),
1876                 MakeConsoleSafe(sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4)),
1877                 sprintf("%d, %d, %d, %d", f1, f2, f3, f4)
1878         ));
1879         #endif
1880
1881         if((notif.nent_stringcount + notif.nent_floatcount) > count)
1882         {
1883                 backtrace(sprintf(
1884                         strcat(
1885                                 "Not enough arguments for Send_Notification(%s, ...)! ",
1886                                 "stringcount(%d) + floatcount(%d) > count(%d)\n",
1887                                 "Check the definition and function call for accuracy...?\n"
1888                         ),
1889                         sprintf(
1890                                 #ifdef NOTIFICATIONS_DEBUG
1891                                 "%s, '%s', %s, %s",
1892                                 Get_Notif_BroadcastName(broadcast),
1893                                 #else
1894                                 "%d, '%s', %s, %s",
1895                                 broadcast,
1896                                 #endif
1897                                 client.classname,
1898                                 Get_Notif_TypeName(net_type),
1899                                 notif.nent_name
1900                         ),
1901                         notif.nent_stringcount,
1902                         notif.nent_floatcount,
1903                         count
1904                 ));
1905                 return;
1906         }
1907         else if((notif.nent_stringcount + notif.nent_floatcount) < count)
1908         {
1909                 backtrace(sprintf(
1910                         strcat(
1911                                 "Too many arguments for Send_Notification(%s, ...)! ",
1912                                 "stringcount(%d) + floatcount(%d) < count(%d)\n",
1913                                 "Check the definition and function call for accuracy...?\n"
1914                         ),
1915                         sprintf(
1916                                 #ifdef NOTIFICATIONS_DEBUG
1917                                 "%s, '%s', %s, %s",
1918                                 Get_Notif_BroadcastName(broadcast),
1919                                 #else
1920                                 "%d, '%s', %s, %s",
1921                                 broadcast,
1922                                 #endif
1923                                 client.classname,
1924                                 Get_Notif_TypeName(net_type),
1925                                 notif.nent_name
1926                         ),
1927                         notif.nent_stringcount,
1928                         notif.nent_floatcount,
1929                         count
1930                 ));
1931                 return;
1932         }
1933
1934         if(
1935                 server_is_dedicated
1936                 &&
1937                 (
1938                         broadcast == NOTIF_ALL
1939                         ||
1940                         broadcast == NOTIF_ALL_EXCEPT
1941                 )
1942                 &&
1943                 !(
1944                         net_type == MSG_ANNCE
1945                         ||
1946                         net_type == MSG_CENTER
1947                 )
1948         )
1949         {
1950                 Local_Notification_WOVA(
1951                         net_type, net_name,
1952                         notif.nent_stringcount,
1953                         notif.nent_floatcount,
1954                         s1, s2, s3, s4,
1955                         f1, f2, f3, f4);
1956         }
1957
1958         if(net_type == MSG_CHOICE)
1959         {
1960                 // THIS GETS TRICKY... now we have to cycle through each possible player (checking broadcast)
1961                 // and then do an individual NOTIF_ONE_ONLY recursive call for each one depending on their option...
1962                 // It's slow, but it's better than the alternatives:
1963                 //   1. Constantly networking all info and letting client decide
1964                 //   2. Manually handling each separate call on per-usage basis (See old CTF usage of verbose)
1965                 entity found_choice;
1966
1967                 #define RECURSE_FROM_CHOICE(ent,action) \
1968                         if(notif.nent_challow_var && (warmup_stage || (notif.nent_challow_var == 2))) \
1969                         { \
1970                                 switch(ent.msg_choice_choices[net_name]) \
1971                                 { \
1972                                         case 1: found_choice = notif.nent_optiona; break; \
1973                                         case 2: found_choice = notif.nent_optionb; break; \
1974                                         default: action; \
1975                                 } \
1976                         } \
1977                         else { found_choice = notif.nent_optiona; } \
1978                         Send_Notification_WOVA( \
1979                                 NOTIF_ONE_ONLY, \
1980                                 ent, \
1981                                 found_choice.nent_type, \
1982                                 found_choice.nent_id, \
1983                                 found_choice.nent_stringcount, \
1984                                 found_choice.nent_floatcount, \
1985                                 s1, s2, s3, s4, \
1986                                 f1, f2, f3, f4);
1987
1988                 switch(broadcast)
1989                 {
1990                         case NOTIF_ONE_ONLY: // we can potentially save processing power with this broadcast method
1991                         {
1992                                 if(IS_REAL_CLIENT(client))
1993                                         { RECURSE_FROM_CHOICE(client, return) }
1994                                 break;
1995                         }
1996                         default:
1997                         {
1998                                 entity to;
1999                                 FOR_EACH_REALCLIENT(to)
2000                                         { if(Notification_ShouldSend(broadcast, to, client))
2001                                                 { RECURSE_FROM_CHOICE(to, continue) } }
2002                                 break;
2003                         }
2004                 }
2005         }
2006         else
2007         {
2008                 entity net_notif = spawn();
2009                 net_notif.owner = notif;
2010                 net_notif.classname = "net_notification";
2011                 net_notif.nent_broadcast = broadcast;
2012                 net_notif.nent_client = client;
2013                 net_notif.nent_net_type = net_type;
2014                 net_notif.nent_net_name = net_name;
2015                 net_notif.nent_stringcount = notif.nent_stringcount;
2016                 net_notif.nent_floatcount = notif.nent_floatcount;
2017
2018                 float i;
2019                 for(i = 0; i < net_notif.nent_stringcount; ++i)
2020                         { net_notif.nent_strings[i] = strzone(...(i, string)); }
2021                 for(i = 0; i < net_notif.nent_floatcount; ++i)
2022                         { net_notif.nent_floats[i] = ...((net_notif.nent_stringcount + i), float); }
2023
2024                 net_notif.think = Net_Notification_Remove;
2025                 net_notif.nextthink =
2026                         ((time > autocvar_notification_lifetime_mapload)
2027                         ?
2028                                 (time + autocvar_notification_lifetime_runtime)
2029                                 :
2030                                 autocvar_notification_lifetime_mapload
2031                         );
2032
2033                 Net_LinkEntity(net_notif, FALSE, 0, Net_Write_Notification);
2034         }
2035 }
2036
2037 // WOVA = Without Variable Arguments
2038 void Send_Notification_WOVA(
2039         float broadcast, entity client,
2040         float net_type, float net_name,
2041         float stringcount, float floatcount,
2042         string s1, string s2, string s3, string s4,
2043         float f1, float f2, float f3, float f4)
2044 {
2045         #ifdef NOTIFICATIONS_DEBUG
2046         entity notif = Get_Notif_Ent(net_type, net_name);
2047         Debug_Notification(sprintf(
2048                 "Send_Notification_WOVA(%s, %d, %d, %s, %s);\n",
2049                 sprintf(
2050                         "%s, '%s', %s, %s",
2051                         Get_Notif_BroadcastName(broadcast),
2052                         client.classname,
2053                         Get_Notif_TypeName(net_type),
2054                         notif.nent_name
2055                 ),
2056                 stringcount,
2057                 floatcount,
2058                 MakeConsoleSafe(sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4)),
2059                 sprintf("%d, %d, %d, %d", f1, f2, f3, f4)
2060         ));
2061         #endif
2062
2063         #define VARITEM(stringc,floatc,args) \
2064                 if((stringcount == stringc) && (floatcount == floatc)) \
2065                         { Send_Notification(broadcast, client, net_type, net_name, args); return; }
2066         EIGHT_VARS_TO_VARARGS_VARLIST
2067         #undef VARITEM
2068         Send_Notification(broadcast, client, net_type, net_name); // some notifications don't have any arguments at all
2069 }
2070
2071 // WOCOVA = Without Counts Or Variable Arguments
2072 void Send_Notification_WOCOVA(
2073         float broadcast, entity client,
2074         float net_type, float net_name,
2075         string s1, string s2, string s3, string s4,
2076         float f1, float f2, float f3, float f4)
2077 {
2078         entity notif = Get_Notif_Ent(net_type, net_name);
2079
2080         #ifdef NOTIFICATIONS_DEBUG
2081         Debug_Notification(sprintf(
2082                 "Send_Notification_WOCOVA(%s, %s, %s);\n",
2083                 sprintf(
2084                         "%s, '%s', %s, %s",
2085                         Get_Notif_BroadcastName(broadcast),
2086                         client.classname,
2087                         Get_Notif_TypeName(net_type),
2088                         notif.nent_name
2089                 ),
2090                 MakeConsoleSafe(sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4)),
2091                 sprintf("%d, %d, %d, %d", f1, f2, f3, f4)
2092         ));
2093         #endif
2094
2095         #define VARITEM(stringc,floatc,args) \
2096                 if((notif.nent_stringcount == stringc) && (notif.nent_floatcount == floatc)) \
2097                         { Send_Notification(broadcast, client, net_type, net_name, args); return; }
2098         EIGHT_VARS_TO_VARARGS_VARLIST
2099         #undef VARITEM
2100         Send_Notification(broadcast, client, net_type, net_name); // some notifications don't have any arguments at all
2101 }
2102 #endif // ifdef SVQC