qcsrc/common/notifications.qc

   1 // ================================================
   2 //  Unified notification system, written by Samual
   3 //  Last updated: February, 2013
   4 // ================================================
   5
   6 #ifndef MENUQC
   7 string arg_slot[8];
   8 string Fill_Notif_Args(string args, string input,
   9         string s1, string s2, string s3, string s4,
  10         float f1, float f2, float f3, float f4)
  11 {
  12         dprint(sprintf("Fill_Notif_Args('%s', '%s', %s, %s, %s, %s, %d, %d, %d, %d);\n",
  13                 args, input, s1, s2, s3, s4, f1, f2, f3, f4));
  14
  15         string selected, remaining = args;
  16         float sel_num = 0;
  17
  18         #ifdef CSQC
  19         string tmp_s;
  20         #endif
  21
  22         if((remaining != "") && (input != ""))
  23         {
  24                 for(;remaining;)
  25                 {
  26                         selected = car(remaining); remaining = cdr(remaining);
  27
  28                         switch(strtolower(selected))
  29                         {
  30                                 #define ADD_ARG_CASE(selected,result) case selected: { arg_slot[sel_num] = result; ++sel_num; break; }
  31
  32                                 ADD_ARG_CASE("s1", s1)
  33                                 ADD_ARG_CASE("s2", s2)
  34                                 ADD_ARG_CASE("s3", s3)
  35                                 ADD_ARG_CASE("s4", s4)
  36                                 ADD_ARG_CASE("f1", ftos(f1))
  37                                 ADD_ARG_CASE("f2", ftos(f2))
  38                                 ADD_ARG_CASE("f3", ftos(f3))
  39                                 ADD_ARG_CASE("f4", ftos(f4))
  40
  41                                 #ifdef CSQC // CSQC replacements
  42                                 ADD_ARG_CASE("pass_key",                ((((tmp_s = getcommandkey("pass", "+use")) != "pass") && !(strstrofs(tmp_s, "not bound", 0) >= 0)) ? sprintf(CCR(_(" ^F1(Press %s)")), tmp_s) : ""))
  43                                 ADD_ARG_CASE("frag_ping",               ((f2 != BOT_PING) ? sprintf(CCR(_("\n(Ping ^2%d^BG)")), f2) : ""))
  44                                 ADD_ARG_CASE("frag_stats",              sprintf(CCR(_("\n(Health ^1%d^BG / Armor ^2%d^BG)%s")), f1, f2, ((f3 != BOT_PING) ? sprintf(CCR(_(" (Ping ^2%d^BG)")), f3) : "")))
  45                                 //ADD_ARG_CASE("frag_pos",              ((Should_Print_Score_Pos(f1)) ? sprintf("\n^BG%s", Read_Score_Pos(f1)) : ""))
  46                                 ADD_ARG_CASE("spree_cen",               (((f1 == 3) || (f1 == 5) || (f1 == 10) || (f1 == 15) || (f1 == 20) || (f1 == 25) || (f1 == 30)) ? sprintf(normal_or_gentle(_("%d frag spree! "), _("%d score spree! ")), f1) : ""))
  47                                 ADD_ARG_CASE("spree_inf",               (((f1 == 3) || (f1 == 5) || (f1 == 10) || (f1 == 15) || (f1 == 20) || (f1 == 25) || (f1 == 30)) ? sprintf(normal_or_gentle(_("%d frag spree! "), _("%d score spree! ")), f1) : ""))
  48                                 ADD_ARG_CASE("spree_end",               ((f1 >= 3) ? sprintf(normal_or_gentle(_(", ending their %d frag spree"), _(", ending their %d score spree")), f1) : ""))
  49                                 ADD_ARG_CASE("spree_lost",              ((f1 >= 3) ? sprintf(normal_or_gentle(_(", losing their %d frag spree"), _(", losing their %d score spree")), f1) : ""))
  50                                 ADD_ARG_CASE("death_team",              Team_ColoredFullName(f1 - 1))
  51                                 ADD_ARG_CASE("weapon_name",     ftos(f1)) // weaponorder[f1].netname
  52
  53                                 #else // SVQC replacements
  54                                 ADD_ARG_CASE("spree_inf",               (((f1 == 3) || (f1 == 5) || (f1 == 10) || (f1 == 15) || (f1 == 20) || (f1 == 25) || (f1 == 30)) ? sprintf(normal_or_gentle(_("%d frag spree! "), _("%d score spree! ")), f1) : ""))
  55                                 ADD_ARG_CASE("spree_end",               ((f1 >= 3) ? sprintf(normal_or_gentle(_(", ending their %d frag spree"), _(", ending their %d score spree")), f1) : ""))
  56                                 ADD_ARG_CASE("spree_lost",              ((f1 >= 3) ? sprintf(normal_or_gentle(_(", losing their %d frag spree"), _(", losing their %d score spree")), f1) : ""))
  57                                 ADD_ARG_CASE("death_team",              Team_ColoredFullName(f1))
  58                                 ADD_ARG_CASE("weapon_name",             ftos(f1)) // weaponorder[f1].netname
  59                                 #endif
  60
  61                                 #undef ADD_ARG_CASE
  62                                 default: { print("Hit unknown token in selected string! '", selected, "'\n"); break; }
  63                         }
  64                         if(sel_num == 7) { print("Hit maximum arguments!\n"); break; }
  65                 }
  66
  67                 return sprintf(input, arg_slot[0], arg_slot[1], arg_slot[2], arg_slot[3], arg_slot[4], arg_slot[5], arg_slot[6], arg_slot[7]);
  68         }
  69
  70         return "";
  71 }
  72
  73 entity Get_Notif_Ent(float net_type, float net_name)
  74 {
  75         switch(net_type)
  76         {
  77                 case MSG_INFO: return msg_info_notifs[net_name - 1];
  78                 case MSG_CENTER: return msg_center_notifs[net_name - 1];
  79                 case MSG_WEAPON: return msg_weapon_notifs[net_name - 1];
  80                 case MSG_DEATH: return msg_death_notifs[net_name - 1];
  81         }
  82         backtrace(sprintf("Get_Notif_Ent(%d, %d): Improper net type!\n", net_type, net_name));
  83         return world;
  84 }
  85
  86 string Get_Notif_Name(float net_type, float net_name)
  87 {
  88         entity e = Get_Notif_Ent(net_type, net_name);
  89         if(e) { return e.nent_name; }
  90         backtrace(sprintf("Get_Notif_Name(%d, %d): Could not find entity!\n", net_type, net_name));
  91         return "";
  92 }
  93
  94 float Get_Notif_Infval(float net_type, float net_name)
  95 {
  96         entity e = Get_Notif_Ent(net_type, net_name);
  97         if(e) { return e.nent_infoname; }
  98         backtrace(sprintf("Get_Notif_Infval(%d, %d): Could not find entity!\n", net_type, net_name));
  99         return NO_MSG;
 100 }
 101
 102 float Get_Notif_Cenval(float net_type, float net_name)
 103 {
 104         entity e = Get_Notif_Ent(net_type, net_name);
 105         if(e) { return e.nent_centername; }
 106         backtrace(sprintf("Get_Notif_Cenval(%d, %d): Could not find entity!\n", net_type, net_name));
 107         return NO_MSG;
 108 }
 109
 110 float Get_Notif_Strnum(float net_type, float net_name)
 111 {
 112         entity e = Get_Notif_Ent(net_type, net_name);
 113         if(e) { return e.nent_stringcount; }
 114         backtrace(sprintf("Get_Notif_Strnum(%d, %d): Could not find entity!\n", net_type, net_name));
 115         return NO_MSG;
 116 }
 117
 118 float Get_Notif_Flnum(float net_type, float net_name)
 119 {
 120         entity e = Get_Notif_Ent(net_type, net_name);
 121         if(e) { return e.nent_floatcount; }
 122         backtrace(sprintf("Get_Notif_Flnum(%d, %d): Could not find entity!\n", net_type, net_name));
 123         return NO_MSG;
 124 }
 125 #endif // ifndef MENUQC
 126
 127
 128 // ===============================
 129 //  Frontend Notification Pushing
 130 // ===============================
 131
 132 void Dump_Notifications(float fh, float alsoprint)
 133 {
 134         float MSG_INFO_NOTIFS = 0, MSG_CENTER_NOTIFS = 0, MSG_WEAPON_NOTIFS = 0, MSG_DEATH_NOTIFS = 0;
 135
 136         #define NOTIF_WRITE(type,name,text) { \
 137                 ++##type##_NOTIFS; \
 138                 notif_msg = sprintf("seta %s 1 // %s - %s\n", name, #type, strreplace("\n", "\\n", text)); \
 139                 fputs(fh, notif_msg); \
 140                 if(alsoprint) { print(strreplace("^", "^^", notif_msg)); } }
 141
 142         #ifndef MENUQC
 143         string notif_msg;
 144         float i;
 145         entity e;
 146
 147         for(i = 0; i < NOTIF_INFO_COUNT; ++i) { e = Get_Notif_Ent(MSG_INFO, i); NOTIF_WRITE(MSG_INFO, e.nent_name, e.nent_string); }
 148         for(i = 0; i < NOTIF_CENTER_COUNT; ++i) { e = Get_Notif_Ent(MSG_CENTER, i); NOTIF_WRITE(MSG_CENTER, e.nent_name, e.nent_string); }
 149
 150         for(i = 0; i < NOTIF_WEAPON_COUNT; ++i) { e = Get_Notif_Ent(MSG_WEAPON, i); NOTIF_WRITE(MSG_WEAPON, e.nent_name, sprintf("infoname: %s, centername: %s",
 151                 Get_Notif_Name(MSG_INFO, Get_Notif_Infval(MSG_WEAPON, i)),
 152                 Get_Notif_Name(MSG_CENTER, Get_Notif_Cenval(MSG_WEAPON, i)))); }
 153
 154         for(i = 0; i < NOTIF_DEATH_COUNT; ++i) { e = Get_Notif_Ent(MSG_DEATH, i); NOTIF_WRITE(MSG_DEATH, e.nent_name, sprintf("infoname: %s, centername: %s",
 155                 Get_Notif_Name(MSG_INFO, Get_Notif_Infval(MSG_DEATH, i)),
 156                 Get_Notif_Name(MSG_CENTER, Get_Notif_Cenval(MSG_DEATH, i)))); }
 157
 158         #endif
 159
 160         print(sprintf("Notification counts: MSG_INFO = %d, MSG_CENTER = %d, MSG_WEAPON = %d, MSG_DEATH = %d\n",
 161                 MSG_INFO_NOTIFS, MSG_CENTER_NOTIFS, MSG_WEAPON_NOTIFS, MSG_DEATH_NOTIFS));
 162
 163         return;
 164         #undef NOTIF_WRITE
 165 }
 166
 167 #ifndef MENUQC
 168 #ifdef CSQC
 169 void HUD_Notify_Push(string icon, string attacker, string victim)
 170 {
 171         if(icon != "")
 172         {
 173                 --kn_index;
 174                 if (kn_index == -1) { kn_index = KN_MAX_ENTRIES-1; }
 175                 killnotify_times[kn_index] = time;
 176
 177                 // icon
 178                 if(killnotify_icon[kn_index]) { strunzone(killnotify_icon[kn_index]); }
 179                 killnotify_icon[kn_index] = strzone(icon);
 180
 181                 // attacker
 182                 if(killnotify_attackers[kn_index]) { strunzone(killnotify_attackers[kn_index]); }
 183                 killnotify_attackers[kn_index] = strzone(attacker);
 184
 185                 // victim
 186                 if(killnotify_victims[kn_index]) { strunzone(killnotify_victims[kn_index]); }
 187                 killnotify_victims[kn_index] = strzone(victim);
 188         }
 189 }
 190 #endif // ifdef CSQC
 191
 192 void Local_Notification(float net_type, float net_name, ...count)
 193 {
 194         // check supplied type and name for errors
 195         #ifdef NOTIFICATIONS_DEBUG
 196         {
 197                 #define CHECKARG_TYPENAME(type) case MSG_##type##: \
 198                         { if(!net_name || (net_name > NOTIF_##type##_COUNT)) \
 199                         { checkargs = sprintf("Improper name: %d!", net_name); } break; }
 200
 201                 string checkargs = "";
 202                 switch(net_type)
 203                 {
 204                         CHECKARG_TYPENAME(INFO)
 205                         CHECKARG_TYPENAME(CENTER)
 206                         CHECKARG_TYPENAME(WEAPON)
 207                         CHECKARG_TYPENAME(DEATH)
 208
 209                         default: { checkargs = sprintf("Improper type: %d!", checkargs, net_type); break; }
 210                 }
 211                 #undef CHECKARG_TYPENAME
 212
 213                 if(checkargs != "") { backtrace(sprintf("Incorrect usage of Local_Notification: %s\n", checkargs)); return; }
 214         }
 215         #endif
 216
 217         entity notif = Get_Notif_Ent(net_type, net_name);
 218         if not(notif) { backtrace("Local_Notification: Could not find notification entity! (This wasn't caught by usage check?...)\n"); return; }
 219         if not(notif.nent_enabled) { print("entity notification was disabled...\n"); return; }
 220
 221         string s1 = ((0 < notif.nent_stringcount) ? ...(0, string) : NO_STR_ARG);
 222         string s2 = ((1 < notif.nent_stringcount) ? ...(1, string) : NO_STR_ARG);
 223         string s3 = ((2 < notif.nent_stringcount) ? ...(2, string) : NO_STR_ARG);
 224         string s4 = ((3 < notif.nent_stringcount) ? ...(3, string) : NO_STR_ARG);
 225         float f1 = ((notif.nent_stringcount < count) ? ...(notif.nent_stringcount, float) : NO_FL_ARG);
 226         float f2 = (((notif.nent_stringcount + 1) < count) ? ...((notif.nent_stringcount + 1), float) : NO_FL_ARG);
 227         float f3 = (((notif.nent_stringcount + 2) < count) ? ...((notif.nent_stringcount + 2), float) : NO_FL_ARG);
 228         float f4 = (((notif.nent_stringcount + 3) < count) ? ...((notif.nent_stringcount + 3), float) : NO_FL_ARG);
 229
 230         #ifdef NOTIFICATIONS_DEBUG
 231         {
 232                 dprint(sprintf("Local_Notification(%d, %s, %s, %s, %s, %s, %d, %d, %d, %d);\n",
 233                         net_type, notif.nent_name,
 234                         s1, s2, s3, s4, f1, f2, f3, f4));
 235
 236                 if((notif.nent_stringcount + notif.nent_floatcount) > count)
 237                         { backtrace(sprintf(strcat("Not enough arguments for Send_Notification! stringcount(%d) + floatcount(%d) > count(%d)\n",
 238                         "Check the notification definition and function call for accuracy...?\n"), notif.nent_stringcount, notif.nent_floatcount, count)); return; }
 239                 else if((notif.nent_stringcount + notif.nent_floatcount) < count)
 240                         { backtrace(sprintf(strcat("Too many arguments for Send_Notification! stringcount(%d) + floatcount(%d) < count(%d)\n",
 241                         "Check the notification definition and function call for accuracy...?\n"), notif.nent_stringcount, notif.nent_floatcount, count)); return; }
 242         }
 243         #endif
 244
 245         switch(net_type)
 246         {
 247                 case MSG_INFO:
 248                 {
 249                         print(Fill_Notif_Args(notif.nent_args, notif.nent_string,
 250                                 s1, s2, s3, s4, f1, f2, f3, f4));
 251
 252                         #ifdef CSQC
 253                         if(notif.nent_icon != "") { HUD_Notify_Push(notif.nent_icon, s1, s2); }
 254                         #endif
 255                         break;
 256                 }
 257
 258                 #ifdef CSQC
 259                 case MSG_CENTER:
 260                 {
 261                         centerprint_generic(HANDLE_CPID(notif.nent_cpid),
 262                                 Fill_Notif_Args(notif.nent_args, notif.nent_string,
 263                                 s1, s2, s3, s4, f1, f2, f3, f4), 0, 0);
 264                         break;
 265                 }
 266                 #endif
 267
 268                 case MSG_WEAPON:
 269                 case MSG_DEATH:
 270                 {
 271                         if(notif.nent_infoname)
 272                         if(msg_info_notifs[notif.nent_infoname - 1].nent_enabled)
 273                         {
 274                                 Local_Notification_Without_VarArgs(MSG_INFO, notif.nent_infoname,
 275                                         Get_Notif_Strnum(MSG_INFO, notif.nent_infoname),
 276                                         Get_Notif_Flnum(MSG_INFO, notif.nent_infoname),
 277                                         s1, s2, s3, s4, f1, f2, f3, f4);
 278                         }
 279                         #ifdef CSQC \
 280                         if(notif.nent_centername)
 281                         if(msg_center_notifs[notif.nent_centername - 1].nent_enabled)
 282                         {
 283                                 Local_Notification_Without_VarArgs(MSG_CENTER, notif.nent_centername,
 284                                         Get_Notif_Strnum(MSG_CENTER, notif.nent_centername),
 285                                         Get_Notif_Flnum(MSG_CENTER, notif.nent_centername),
 286                                         s1, s2, s3, s4, f1, f2, f3, f4);
 287                         }
 288                         #endif \
 289                         break;
 290                 }
 291         }
 292 }
 293
 294 void Local_Notification_Without_VarArgs(float net_type, float net_name,
 295         float stringcount, float floatcount,
 296         string s1, string s2, string s3, string s4,
 297         float f1, float f2, float f3, float f4)
 298 {
 299         #define VARITEM(stringc,floatc,args) if((stringcount == stringc) && (floatcount == floatc)) { Local_Notification(net_type, net_name, args); return; }
 300         EIGHT_VARS_TO_VARARGS_VARLIST
 301         #undef VARITEM
 302
 303         Local_Notification(net_type, net_name); // some notifications don't have any arguments at all
 304 }
 305
 306
 307 // =========================
 308 //  Notification Networking
 309 // =========================
 310
 311 #ifdef CSQC
 312 void Read_Notification(float is_new)
 313 {
 314         float net_type = ReadByte();
 315         float net_name = ReadShort();
 316
 317         float stringcount = Get_Notif_Strnum(net_type, net_name);
 318         float floatcount = Get_Notif_Flnum(net_type, net_name);
 319
 320         string s1 = ((stringcount >= 1) ? ReadString() : NO_STR_ARG);
 321         string s2 = ((stringcount >= 2) ? ReadString() : NO_STR_ARG);
 322         string s3 = ((stringcount >= 3) ? ReadString() : NO_STR_ARG);
 323         string s4 = ((stringcount == 4) ? ReadString() : NO_STR_ARG);
 324         float f1 = ((floatcount >= 1) ? ReadLong() : NO_FL_ARG);
 325         float f2 = ((floatcount >= 2) ? ReadLong() : NO_FL_ARG);
 326         float f3 = ((floatcount >= 3) ? ReadLong() : NO_FL_ARG);
 327         float f4 = ((floatcount == 4) ? ReadLong() : NO_FL_ARG);
 328
 329         #ifdef NOTIFICATIONS_DEBUG
 330                 dprint(sprintf("Read_Notification(%d) at %f: net_name = %s.\n", is_new, time, Get_Notif_Name(net_type, net_name)));
 331         #endif
 332
 333         if(is_new) { Local_Notification_Without_VarArgs(net_type, net_name, stringcount, floatcount, s1, s2, s3, s4, f1, f2, f3, f4); }
 334 }
 335 #endif
 336
 337 #ifdef SVQC
 338 void Notification_Remove()
 339 {
 340         float i;
 341         for(i = 0; i < 4; ++i) { if(self.nent_strings[i]) { strunzone(self.nent_strings[i]); } }
 342         remove(self);
 343 }
 344
 345 float Write_Notification(entity client, float sf)
 346 {
 347         float i, send = FALSE;
 348
 349         switch(self.nent_broadcast)
 350         {
 351                 case NOTIF_ONE: { if((client == self.nent_client) || (client.classname == STR_SPECTATOR && client.enemy == self.nent_client)) { send = TRUE; } break; }
 352                 case NOTIF_ONE_ONLY: { if(client == self.nent_client) { send = TRUE; } break; }
 353                 case NOTIF_TEAM: { if((client.team == self.nent_client.team) || (client.classname == STR_SPECTATOR && client.enemy.team == self.nent_client.team)) { send = TRUE; } break; }
 354                 case NOTIF_TEAM_EXCEPT: { if(((client != self.nent_client) && (client.team == self.nent_client.team) && !(client.classname == STR_SPECTATOR && client.enemy == self.nent_client))) { send = TRUE; } break; }
 355                 case NOTIF_ANY: { send = TRUE; break; }
 356                 case NOTIF_ANY_EXCEPT: { if((client != self.nent_client) && !(client.classname == STR_SPECTATOR && client.enemy == self.nent_client)) { send = TRUE; } break; }
 357                 default: { send = FALSE; break; }
 358         }
 359
 360         if(send)
 361         {
 362                 WriteByte(MSG_ENTITY, ENT_CLIENT_NOTIFICATION);
 363                 WriteByte(MSG_ENTITY, self.nent_net_type);
 364                 WriteShort(MSG_ENTITY, self.nent_net_name);
 365                 for(i = 0; i < self.nent_stringcount; ++i) { WriteString(MSG_ENTITY, self.nent_strings[i]); }
 366                 for(i = 0; i < self.nent_floatcount; ++i) { WriteLong(MSG_ENTITY, self.nent_floats[i]); }
 367         }
 368
 369         return send;
 370 }
 371
 372 void Send_Notification(float broadcast, entity client,
 373         float net_type, float net_name, ...count)
 374 {
 375         // check supplied broadcast, target, type, and name for errors
 376         #ifdef NOTIFICATIONS_DEBUG
 377         {
 378                 #define CHECKARG_TYPENAME(type) case MSG_##type##: \
 379                         { if(!net_name || (net_name > NOTIF_##type##_COUNT)) \
 380                         { checkargs = sprintf("Improper name: %d!", net_name); } break; }
 381
 382                 string checkargs = "";
 383                 switch(net_type)
 384                 {
 385                         CHECKARG_TYPENAME(INFO)
 386                         CHECKARG_TYPENAME(CENTER)
 387                         CHECKARG_TYPENAME(WEAPON)
 388                         CHECKARG_TYPENAME(DEATH)
 389
 390                         default: { checkargs = sprintf("Improper type: %d!", checkargs, net_type); break; }
 391                 }
 392                 #undef CHECKARG_TYPENAME
 393
 394                 if(checkargs != "") { checkargs = strcat(checkargs, " "); }
 395                 switch(broadcast)
 396                 {
 397                         case NOTIF_ONE:
 398                         case NOTIF_ONE_ONLY: { if(clienttype(client) == CLIENTTYPE_NOTACLIENT) { checkargs = sprintf("%sNo client provided!", checkargs); } break; }
 399                         case NOTIF_ANY_EXCEPT: { if(clienttype(client) == CLIENTTYPE_NOTACLIENT) { checkargs = sprintf("%sException can't be a non-client!", checkargs); } break; }
 400                         case NOTIF_ANY: { if(client) { checkargs = sprintf("%sEntity provided when world was required!", checkargs); } break; }
 401
 402                         case NOTIF_TEAM:
 403                         case NOTIF_TEAM_EXCEPT:
 404                         {
 405                                 if not(teamplay) { checkargs = sprintf("%sTeamplay not active!", checkargs); }
 406                                 else if(clienttype(client) == CLIENTTYPE_NOTACLIENT)
 407                                 {
 408                                         if(broadcast == NOTIF_TEAM) { checkargs = sprintf("%sNo client provided!", checkargs); }
 409                                         else { checkargs = sprintf("%sException can't be a non-client!", checkargs); }
 410                                 }
 411                                 break;
 412                         }
 413
 414                         default: { checkargs = sprintf("%sImproper broadcast: %d!", checkargs, broadcast); break; }
 415                 }
 416
 417                 if(checkargs != "") { backtrace(sprintf("Incorrect usage of Send_Notification: %s\n", checkargs)); return; }
 418         }
 419         #endif
 420
 421         // retreive counts for the arguments of this notification
 422         float stringcount = Get_Notif_Strnum(net_type, net_name);
 423         float floatcount = Get_Notif_Flnum(net_type, net_name);
 424
 425         #ifdef NOTIFICATIONS_DEBUG
 426         {
 427                 dprint(sprintf("Send_Notification(%d, %d, %s, stringcount: %d, floatcount: %d, varargs: %d);\n",
 428                         broadcast, net_type, Get_Notif_Name(net_type, net_name), stringcount, floatcount, count));
 429
 430                 if((stringcount + floatcount) > count)
 431                         { backtrace(sprintf(strcat("Not enough arguments for Send_Notification! stringcount(%d) + floatcount(%d) > count(%d)\n",
 432                         "Check the notification definition and function call for accuracy...?\n"), stringcount, floatcount, count)); return; }
 433                 else if((stringcount + floatcount) < count)
 434                         { backtrace(sprintf(strcat("Too many arguments for Send_Notification! stringcount(%d) + floatcount(%d) < count(%d)\n",
 435                         "Check the notification definition and function call for accuracy...?\n"), stringcount, floatcount, count)); return; }
 436         }
 437         #endif
 438
 439         entity notif = spawn();
 440         notif.nent_broadcast = broadcast;
 441         notif.nent_client = client;
 442         notif.nent_net_type = net_type;
 443         notif.nent_net_name = net_name;
 444         notif.nent_stringcount = stringcount;
 445         notif.nent_floatcount = floatcount;
 446
 447         float i;
 448
 449         for(i = 0; i < stringcount; ++i) { notif.nent_strings[i] = strzone(...(i, string)); }
 450         for(i = 0; i < floatcount; ++i) { notif.nent_floats[i] = ...((stringcount + i), float); }
 451
 452         notif.think = Notification_Remove;
 453         notif.nextthink = (time + 0.5);
 454
 455         Net_LinkEntity(notif, FALSE, 0, Write_Notification);
 456
 457         if((!server_is_local) && (broadcast == NOTIF_ANY || broadcast == NOTIF_ANY_EXCEPT) && (net_type != MSG_CENTER))
 458                 { Local_Notification_Without_VarArgs(net_type, net_name, stringcount, floatcount,
 459                         IFSTR(0), IFSTR(1), IFSTR(2), IFSTR(3), IFFL(0), IFFL(1), IFFL(2), IFFL(3)); }
 460 }
 461
 462 void Send_Notification_Without_VarArgs(float broadcast, entity client,
 463         float net_type, float net_name,
 464         float stringcount, float floatcount,
 465         string s1, string s2, string s3, string s4,
 466         float f1, float f2, float f3, float f4)
 467 {
 468         #define VARITEM(stringc,floatc,args) if((stringcount == stringc) && (floatcount == floatc)) { Send_Notification(broadcast, client, net_type, net_name, args); return; }
 469         EIGHT_VARS_TO_VARARGS_VARLIST
 470         #undef VARITEM
 471
 472         Send_Notification(broadcast, client, net_type, net_name); // some notifications don't have any arguments at all
 473 }
 474
 475 void Send_Notification_Legacy_Wrapper(float broadcast, entity client,
 476         float net_type, float net_name,
 477         string s1, string s2,
 478         float f1, float f2, float f3)
 479 {
 480         float stringcount = Get_Notif_Strnum(net_type, net_name);
 481         float floatcount = Get_Notif_Flnum(net_type, net_name);
 482         Send_Notification_Without_VarArgs(broadcast, client, net_type, net_name, stringcount, floatcount, s1, s2, NO_STR_ARG, NO_STR_ARG, f1, f2, f3, NO_FL_ARG);
 483 }
 484
 485
 486 // =============================
 487 //  LEGACY NOTIFICATION SYSTEMS
 488 // =============================
 489
 490 void Send_CSQC_Centerprint_Generic(entity e, float id, string s, float duration, float countdown_num)
 491 {
 492         if ((clienttype(e) == CLIENTTYPE_REAL) && (e.flags & FL_CLIENT))
 493         {
 494                 msg_entity = e;
 495                 WRITESPECTATABLE_MSG_ONE({
 496                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 497                         WriteByte(MSG_ONE, TE_CSQC_CENTERPRINT_GENERIC);
 498                         WriteByte(MSG_ONE, id);
 499                         WriteString(MSG_ONE, s);
 500                         if (id != 0 && s != "")
 501                         {
 502                                 WriteByte(MSG_ONE, duration);
 503                                 WriteByte(MSG_ONE, countdown_num);
 504                         }
 505                 });
 506         }
 507 }
 508 void Send_CSQC_Centerprint_Generic_Expire(entity e, float id)
 509 {
 510         Send_CSQC_Centerprint_Generic(e, id, "", 1, 0);
 511 }
 512 #endif // ifdef SVQC
 513 #endif // ifndef MENUQC