qcsrc/common/notifications.qc

   1 // ================================================
   2 //  Unified notification system, written by Samual
   3 //  Last updated: February, 2013
   4 // ================================================
   5
   6 entity Get_Notif_Ent(float net_type, float net_name)
   7 {
   8         switch(net_type)
   9         {
  10                 case MSG_INFO: return msg_info_notifs[net_name - 1];
  11                 case MSG_CENTER: return msg_center_notifs[net_name - 1];
  12                 case MSG_WEAPON: return msg_weapon_notifs[net_name - 1];
  13                 case MSG_DEATH: return msg_death_notifs[net_name - 1];
  14         }
  15         backtrace(sprintf("Get_Notif_Ent(%d, %d): Improper net type!\n", net_type, net_name));
  16         return world;
  17 }
  18
  19
  20 // ===============================
  21 //  Frontend Notification Pushing
  22 // ===============================
  23
  24 void Dump_Notifications(float fh, float alsoprint)
  25 {
  26         #define NOTIF_WRITE(a) { \
  27                 fputs(fh, a); \
  28                 if(alsoprint) { print(a); } }
  29         #define NOTIF_WRITE_SETA(name,default,text) { \
  30                 notif_msg = \
  31                         sprintf( \
  32                                 "seta notification_%s %d \"notif string: %s^7\"\n", \
  33                                 name, default, strreplace("\{1}", "", strreplace("\n", "\\n", text)) \
  34                         ); \
  35                 NOTIF_WRITE(notif_msg) }
  36
  37         string notif_msg;
  38         float i;
  39         entity e;
  40
  41         // Note: This warning only applies to the notifications.cfg file that is output...
  42
  43         // You ARE supposed to manually edit this function to add i.e. hard coded
  44         // notification variables for mutators or game modes or such and then
  45         // regenerate the notifications.cfg file from the new code.
  46
  47         NOTIF_WRITE("// ********************************************** //\n");
  48         NOTIF_WRITE("// ** WARNING - DO NOT MANUALLY EDIT THIS FILE ** //\n");
  49         NOTIF_WRITE("// **                                          ** //\n");
  50         NOTIF_WRITE("// **  This file is automatically generated    ** //\n");
  51         NOTIF_WRITE("// **  by code with the command 'dumpnotifs'.  ** //\n");
  52         NOTIF_WRITE("// **                                          ** //\n");
  53         NOTIF_WRITE("// **  If you add a new notification, please   ** //\n");
  54         NOTIF_WRITE("// **  regenerate this file with that command  ** //\n");
  55         NOTIF_WRITE("// **  making sure that the output matches     ** //\n");
  56         NOTIF_WRITE("// **  with the lists and defaults in code.    ** //\n");
  57         NOTIF_WRITE("// **                                          ** //\n");
  58         NOTIF_WRITE("// ********************************************** //\n");
  59
  60         NOTIF_WRITE("\n// Version number to identify mismatches between code and config file...\n");
  61         NOTIF_WRITE("// Increment NOTIF_VERSION in common/notifications.qh with any\n");
  62         NOTIF_WRITE("// new notifications or other changes to notif cvars/this config.\n");
  63
  64         NOTIF_WRITE(sprintf("set notification_version %d\n", NOTIF_VERSION));
  65
  66         // These notifications will also append their string as a comment...
  67         // This is not necessary, and does not matter if they vary between config versions,
  68         // it is just a semi-helpful tool for those who want to manually change their user settings.
  69
  70         NOTIF_WRITE(sprintf("\n// MSG_INFO notifications (count = %d):\n", NOTIF_INFO_COUNT));
  71         for(i = 1; i <= NOTIF_INFO_COUNT; ++i)
  72         {
  73                 e = Get_Notif_Ent(MSG_INFO, i);
  74                 if not(e) { backtrace("Dump_Notifications(): Missing notification entity!\n"); return; }
  75                 NOTIF_WRITE_SETA(e.nent_name, e.nent_default, e.nent_string);
  76         }
  77
  78         NOTIF_WRITE(sprintf("\n// MSG_CENTER notifications (count = %d):\n", NOTIF_CENTER_COUNT));
  79         for(i = 1; i <= NOTIF_CENTER_COUNT; ++i)
  80         {
  81                 e = Get_Notif_Ent(MSG_CENTER, i);
  82                 if not(e) { backtrace("Dump_Notifications(): Missing notification entity!\n"); return; }
  83                 NOTIF_WRITE_SETA(e.nent_name, e.nent_default, e.nent_string);
  84         }
  85
  86         NOTIF_WRITE(sprintf("\n// MSG_WEAPON notifications (count = %d):\n", NOTIF_WEAPON_COUNT));
  87         for(i = 1; i <= NOTIF_WEAPON_COUNT; ++i)
  88         {
  89                 e = Get_Notif_Ent(MSG_WEAPON, i);
  90                 if not(e) { backtrace("Dump_Notifications(): Missing notification entity!\n"); return; }
  91                 NOTIF_WRITE_SETA(e.nent_name, e.nent_default, sprintf("infoname: %s, centername: %s",
  92                         e.nent_msginfo.nent_name, e.nent_msgcenter.nent_name));
  93         }
  94
  95         NOTIF_WRITE(sprintf("\n// MSG_DEATH notifications (count = %d):\n", NOTIF_DEATH_COUNT));
  96         for(i = 1; i <= NOTIF_DEATH_COUNT; ++i)
  97         {
  98                 e = Get_Notif_Ent(MSG_DEATH, i);
  99                 if not(e) { backtrace("Dump_Notifications(): Missing notification entity!\n"); return; }
 100                 NOTIF_WRITE_SETA(e.nent_name, e.nent_default, sprintf("infoname: %s, centername: %s",
 101                         e.nent_msginfo.nent_name, e.nent_msgcenter.nent_name));
 102         }
 103
 104         // edit these to match whichever cvars are used for specific notification options
 105         NOTIF_WRITE("\n// HARD CODED notification variables:\n");
 106         NOTIF_WRITE("seta notification_show_sprees 1 \"Print information about sprees in death/kill messages\"\n");
 107         NOTIF_WRITE("seta notification_version_mismatch_client_error 0 \"Cause a notif error on client if the version in notifications.cfg mismatches the code\"\n");
 108         NOTIF_WRITE("seta notification_version_mismatch_server_error 1 \"Cause a notif error on server if the version in notifications.cfg mismatches the code\"\n");
 109         NOTIF_WRITE("seta notification_errors_are_fatal 1 \"If a notification fails upon initialization, cause a Host_Error to stop the program\"\n");
 110         NOTIF_WRITE("seta notification_ctf_pickup_team_verbose 1 \"Show extra information if a team mate picks up a flag\"\n");
 111         NOTIF_WRITE("seta notification_ctf_pickup_enemy_verbose 1 \"Show extra information if an enemy picks up a flag\"\n");
 112         NOTIF_WRITE("seta notification_ctf_capture_verbose 1 \"Show extra information when someone captures a flag\"\n");
 113         NOTIF_WRITE("seta notification_frag_verbose 1 \"Show extra information when you frag someone (or when you are fragged\"\n");
 114
 115         NOTIF_WRITE(sprintf("\n// Notification counts (total = %d): MSG_INFO = %d, MSG_CENTER = %d, MSG_WEAPON = %d, MSG_DEATH = %d\n",
 116                 (NOTIF_INFO_COUNT + NOTIF_CENTER_COUNT + NOTIF_WEAPON_COUNT + NOTIF_DEATH_COUNT),
 117                 NOTIF_INFO_COUNT, NOTIF_CENTER_COUNT, NOTIF_WEAPON_COUNT, NOTIF_DEATH_COUNT));
 118
 119         return;
 120         #undef NOTIF_WRITE_SETA
 121         #undef NOTIF_WRITE
 122 }
 123
 124 #ifdef SVQC
 125 void Notification_GetCvars()
 126 {
 127         GetCvars_handleFloat(get_cvars_s, get_cvars_f, FRAG_VERBOSE, "notification_frag_verbose");
 128 }
 129 #endif
 130
 131 string Local_Notification_sprintf(string input, string args,
 132         string s1, string s2, string s3, string s4,
 133         float f1, float f2, float f3, float f4)
 134 {
 135         #ifdef NOTIFICATIONS_DEBUG
 136         dprint(
 137                 sprintf("Local_Notification_sprintf('%s^7', '%s', %s, %s);\n",
 138                         strreplace("\n", "\\n", input),
 139                         args,
 140                         sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4),
 141                         sprintf("%d, %d, %d, %d", f1, f2, f3, f4)
 142                 )
 143         );
 144         #endif
 145
 146         string selected;
 147         float sel_num;
 148         for(sel_num = 0; sel_num < NOTIF_MAX_ARGS; ++sel_num) { arg_slot[sel_num] = ""; }
 149
 150         #ifdef CSQC
 151         string tmp_s;
 152         #endif
 153
 154         for(sel_num = 0;(args != "");)
 155         {
 156                 selected = car(args); args = cdr(args);
 157                 NOTIF_HIT_MAX(NOTIF_MAX_ARGS, "Local_Notification_sprintf")
 158                 switch(strtolower(selected))
 159                 {
 160                         #define ARG_CASE(prog,selected,result) \
 161                                 #ifdef CSQC \
 162                                         #if (prog == ARG_DOUBLE) || (prog == ARG_TRIPLE) || (prog == ARG_CSQC) \
 163                                                 case selected: { arg_slot[sel_num] = result; ++sel_num; break; } \
 164                                         #endif \
 165                                 #else \
 166                                         #if (prog == ARG_DOUBLE) || (prog == ARG_TRIPLE) || (prog == ARG_SVQC) \
 167                                                 case selected: { arg_slot[sel_num] = result; ++sel_num; break; } \
 168                                         #endif \
 169                                 #endif
 170                         NOTIF_ARGUMENT_LIST
 171                         #undef ARG_CASE
 172                         NOTIF_HIT_UNKNOWN(NOTIF_MAX_ARGS, "Local_Notification_sprintf")
 173                 }
 174         }
 175         return sprintf(input, arg_slot[0], arg_slot[1], arg_slot[2], arg_slot[3], arg_slot[4], arg_slot[5], arg_slot[6]);
 176 }
 177
 178 #ifdef CSQC
 179 void Local_Notification_HUD_Notify_Push(string icon, string hudargs, string s1, string s2, string s3, string s4)
 180 {
 181         string selected;
 182         float sel_num;
 183         arg_slot[0] = ""; arg_slot[1] = "";
 184
 185         for(sel_num = 0;(hudargs != "");)
 186         {
 187                 selected = car(hudargs); hudargs = cdr(hudargs);
 188                 NOTIF_HIT_MAX(NOTIF_MAX_HUDARGS, "Local_Notification_HUD_Notify_Push")
 189                 switch(strtolower(selected))
 190                 {
 191                         #define ARG_CASE(prog,selected,result) \
 192                                 #if (prog == ARG_TRIPLE) \
 193                                         case selected: { arg_slot[sel_num] = result; ++sel_num; break; } \
 194                                 #endif
 195                         NOTIF_ARGUMENT_LIST
 196                         #undef ARG_CASE
 197                         NOTIF_HIT_UNKNOWN(NOTIF_MAX_HUDARGS, "Local_Notification_HUD_Notify_Push")
 198                 }
 199         }
 200         HUD_Notify_Push(icon, arg_slot[0], arg_slot[1]);
 201 }
 202 #endif
 203
 204 void Local_Notification(float net_type, float net_name, ...count)
 205 {
 206         // check supplied type and name for errors
 207         string checkargs = "";
 208         #define CHECKARG_TYPENAME(type) case MSG_##type##: \
 209                 { if(!net_name || (net_name > NOTIF_##type##_COUNT)) \
 210                 { checkargs = sprintf("Improper name: %d!", net_name); } break; }
 211         switch(net_type)
 212         {
 213                 CHECKARG_TYPENAME(INFO)
 214                 CHECKARG_TYPENAME(CENTER)
 215                 CHECKARG_TYPENAME(WEAPON)
 216                 CHECKARG_TYPENAME(DEATH)
 217                 default: { checkargs = sprintf("Improper type: %d!", checkargs, net_type); break; }
 218         }
 219         #undef CHECKARG_TYPENAME
 220         if(checkargs != "") { backtrace(sprintf("Incorrect usage of Local_Notification: %s\n", checkargs)); return; }
 221
 222         entity notif = Get_Notif_Ent(net_type, net_name);
 223         if not(notif) { backtrace("Local_Notification: Could not find notification entity!\n"); return; }
 224         if not(notif.nent_enabled) { print("Local_Notification: Entity was disabled...\n"); return; }
 225
 226         if((notif.nent_stringcount + notif.nent_floatcount) > count)
 227         {
 228                 backtrace(sprintf(
 229                         strcat(
 230                                 "Not enough arguments for Local_Notification! ",
 231                                 "stringcount(%d) + floatcount(%d) > count(%d)\n",
 232                                 "Check the definition and function call for accuracy...?\n"
 233                         ),
 234                         notif.nent_stringcount, notif.nent_floatcount, count));
 235                 return;
 236         }
 237         else if((notif.nent_stringcount + notif.nent_floatcount) < count)
 238         {
 239                 backtrace(sprintf(
 240                         strcat(
 241                                 "Too many arguments for Local_Notification! ",
 242                                 "stringcount(%d) + floatcount(%d) < count(%d)\n",
 243                                 "Check the definition and function call for accuracy...?\n"
 244                         ),
 245                         notif.nent_stringcount, notif.nent_floatcount, count));
 246                 return;
 247         }
 248
 249         string s1 = ((0 < notif.nent_stringcount) ? ...(0, string) : "");
 250         string s2 = ((1 < notif.nent_stringcount) ? ...(1, string) : "");
 251         string s3 = ((2 < notif.nent_stringcount) ? ...(2, string) : "");
 252         string s4 = ((3 < notif.nent_stringcount) ? ...(3, string) : "");
 253         float f1 = ((0 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 0), float) : 0);
 254         float f2 = ((1 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 1), float) : 0);
 255         float f3 = ((2 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 2), float) : 0);
 256         float f4 = ((3 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 3), float) : 0);
 257
 258         #ifdef NOTIFICATIONS_DEBUG
 259         dprint(
 260                 sprintf("Local_Notification(%d, %s, %s, %s);\n",
 261                         net_type,
 262                         notif.nent_name,
 263                         sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4),
 264                         sprintf("%d, %d, %d, %d", f1, f2, f3, f4)
 265                 )
 266         );
 267         #endif
 268
 269         switch(net_type)
 270         {
 271                 case MSG_INFO:
 272                 {
 273                         print(
 274                                 Local_Notification_sprintf(
 275                                         notif.nent_string,
 276                                         notif.nent_args,
 277                                         s1, s2, s3, s4,
 278                                         f1, f2, f3, f4)
 279                         );
 280                         #ifdef CSQC
 281                         if(notif.nent_icon != "")
 282                         {
 283                                 Local_Notification_HUD_Notify_Push(
 284                                         notif.nent_icon,
 285                                         notif.nent_hudargs,
 286                                         s1, s2, s3, s4);
 287                         }
 288                         #endif
 289                         break;
 290                 }
 291
 292                 #ifdef CSQC
 293                 case MSG_CENTER:
 294                 {
 295                         centerprint_generic(
 296                                 notif.nent_cpid,
 297                                 Local_Notification_sprintf(
 298                                         notif.nent_string,
 299                                         notif.nent_args,
 300                                         s1, s2, s3, s4,
 301                                         f1, f2, f3, f4),
 302                                 0, 0);
 303                         break;
 304                 }
 305                 #endif
 306
 307                 case MSG_WEAPON:
 308                 case MSG_DEATH:
 309                 {
 310                         if(notif.nent_msginfo)
 311                         if(notif.nent_msginfo.nent_enabled)
 312                         {
 313                                 Local_Notification_WOVA(
 314                                         MSG_INFO,
 315                                         notif.nent_msginfo.nent_id,
 316                                         notif.nent_msginfo.nent_stringcount,
 317                                         notif.nent_msginfo.nent_floatcount,
 318                                         s1, s2, s3, s4,
 319                                         f1, f2, f3, f4);
 320                         }
 321                         #ifdef CSQC
 322                         if(notif.nent_msgcenter)
 323                         if(notif.nent_msgcenter.nent_enabled)
 324                         {
 325                                 Local_Notification_WOVA(
 326                                         MSG_CENTER,
 327                                         notif.nent_msgcenter.nent_id,
 328                                         notif.nent_msgcenter.nent_stringcount,
 329                                         notif.nent_msgcenter.nent_floatcount,
 330                                         s1, s2, s3, s4,
 331                                         f1, f2, f3, f4);
 332                         }
 333                         #endif
 334                         break;
 335                 }
 336         }
 337 }
 338
 339 // WOVA = Without Variable Arguments
 340 void Local_Notification_WOVA(float net_type, float net_name,
 341         float stringcount, float floatcount,
 342         string s1, string s2, string s3, string s4,
 343         float f1, float f2, float f3, float f4)
 344 {
 345         #define VARITEM(stringc,floatc,args) \
 346                 if((stringcount == stringc) && (floatcount == floatc)) \
 347                         { Local_Notification(net_type, net_name, args); return; }
 348         EIGHT_VARS_TO_VARARGS_VARLIST
 349         #undef VARITEM
 350         Local_Notification(net_type, net_name); // some notifications don't have any arguments at all
 351 }
 352
 353
 354 // =========================
 355 //  Notification Networking
 356 // =========================
 357
 358 #ifdef CSQC
 359 void Read_Notification(float is_new)
 360 {
 361         float net_type = ReadByte();
 362         float net_name = ReadShort();
 363
 364         entity notif = Get_Notif_Ent(net_type, net_name);
 365         if not(notif) { print("Read_Notification: Could not find notification entity!\n"); return; }
 366
 367         string s1 = ((0 < notif.nent_stringcount) ? ReadString() : "");
 368         string s2 = ((1 < notif.nent_stringcount) ? ReadString() : "");
 369         string s3 = ((2 < notif.nent_stringcount) ? ReadString() : "");
 370         string s4 = ((3 < notif.nent_stringcount) ? ReadString() : "");
 371         float f1 = ((0 < notif.nent_floatcount) ? ReadLong() : 0);
 372         float f2 = ((1 < notif.nent_floatcount) ? ReadLong() : 0);
 373         float f3 = ((2 < notif.nent_floatcount) ? ReadLong() : 0);
 374         float f4 = ((3 < notif.nent_floatcount) ? ReadLong() : 0);
 375
 376         #ifdef NOTIFICATIONS_DEBUG
 377         dprint(sprintf("Read_Notification(%d) at %f: net_name = %s.\n", is_new, time, notif.nent_name));
 378         #endif
 379
 380         if(is_new)
 381         {
 382                 Local_Notification_WOVA(
 383                         net_type, net_name,
 384                         notif.nent_stringcount,
 385                         notif.nent_floatcount,
 386                         s1, s2, s3, s4,
 387                         f1, f2, f3, f4);
 388         }
 389 }
 390 #endif
 391
 392 #ifdef SVQC
 393 void Net_Notification_Remove()
 394 {
 395         float i;
 396         for(i = 0; i < 4; ++i) { if(self.nent_strings[i]) { strunzone(self.nent_strings[i]); } }
 397         remove(self);
 398 }
 399
 400 float Net_Write_Notification(entity client, float sf)
 401 {
 402         float i, send = FALSE;
 403
 404         switch(self.nent_broadcast)
 405         {
 406                 case NOTIF_ONE: // send to one client and their spectator
 407                 {
 408                         if(
 409                                 (client == self.nent_client)
 410                                 ||
 411                                 (
 412                                         (client.classname == STR_SPECTATOR)
 413                                         &&
 414                                         (client.enemy == self.nent_client)
 415                                 )
 416                         ) { send = TRUE; }
 417                         break;
 418                 }
 419                 case NOTIF_ONE_ONLY: // send ONLY to one client
 420                 {
 421                         if(client == self.nent_client) { send = TRUE; }
 422                         break;
 423                 }
 424                 case NOTIF_TEAM: // send only to X team and their spectators
 425                 {
 426                         if(
 427                                 (client.team == self.nent_client.team)
 428                                 ||
 429                                 (
 430                                         (client.classname == STR_SPECTATOR)
 431                                         &&
 432                                         (client.enemy.team == self.nent_client.team)
 433                                 )
 434                         ) { send = TRUE; }
 435                         break;
 436                 }
 437                 case NOTIF_TEAM_EXCEPT: // send only to X team and their spectators, except for Y person and their spectators
 438                 {
 439                         if(
 440                                 (client != self.nent_client)
 441                                 &&
 442                                 (
 443                                         (client.team == self.nent_client.team)
 444                                         ||
 445                                         (
 446                                                 (client.classname == STR_SPECTATOR)
 447                                                 &&
 448                                                 (
 449                                                         (client.enemy != self.nent_client)
 450                                                         &&
 451                                                         (client.enemy.team == self.nent_client.team)
 452                                                 )
 453                                         )
 454                                 )
 455                         ) { send = TRUE; }
 456                         break;
 457                 }
 458                 case NOTIF_ANY: // send to everyone
 459                 {
 460                         send = TRUE;
 461                         break;
 462                 }
 463                 case NOTIF_ANY_EXCEPT: // send to everyone except X person and their spectators
 464                 {
 465                         if(
 466                                 (client != self.nent_client)
 467                                 &&
 468                                 !(
 469                                         (client.classname == STR_SPECTATOR)
 470                                         &&
 471                                         (client.enemy == self.nent_client)
 472                                 )
 473                         ) { send = TRUE; }
 474                         break;
 475                 }
 476                 default: { send = FALSE; break; }
 477         }
 478
 479         if(send)
 480         {
 481                 WriteByte(MSG_ENTITY, ENT_CLIENT_NOTIFICATION);
 482                 WriteByte(MSG_ENTITY, self.nent_net_type);
 483                 WriteShort(MSG_ENTITY, self.nent_net_name);
 484                 for(i = 0; i < self.nent_stringcount; ++i) { WriteString(MSG_ENTITY, self.nent_strings[i]); }
 485                 for(i = 0; i < self.nent_floatcount; ++i) { WriteLong(MSG_ENTITY, self.nent_floats[i]); }
 486         }
 487
 488         return send;
 489 }
 490
 491 void Send_Notification(float broadcast, entity client,
 492         float net_type, float net_name, ...count)
 493 {
 494         // check supplied broadcast, target, type, and name for errors
 495         string checkargs = "";
 496         #define CHECKARG_TYPENAME(type) case MSG_##type##: \
 497                 { if(!net_name || (net_name > NOTIF_##type##_COUNT)) \
 498                 { checkargs = sprintf("Improper name: %d!", net_name); } break; }
 499         switch(net_type)
 500         {
 501                 CHECKARG_TYPENAME(INFO)
 502                 CHECKARG_TYPENAME(CENTER)
 503                 CHECKARG_TYPENAME(WEAPON)
 504                 CHECKARG_TYPENAME(DEATH)
 505                 default: { checkargs = sprintf("Improper type: %d!", checkargs, net_type); break; }
 506         }
 507         #undef CHECKARG_TYPENAME
 508         if(checkargs != "") { checkargs = strcat(checkargs, " "); }
 509         switch(broadcast)
 510         {
 511                 case NOTIF_ONE:
 512                 case NOTIF_ONE_ONLY:
 513                 {
 514                         if(IS_NOT_A_CLIENT(client))
 515                                 { checkargs = sprintf("%sNo client provided!", checkargs); }
 516                         break;
 517                 }
 518
 519                 case NOTIF_ANY_EXCEPT:
 520                 {
 521                         if(IS_NOT_A_CLIENT(client))
 522                                 { checkargs = sprintf("%sException can't be a non-client!", checkargs); }
 523                         break;
 524                 }
 525
 526                 case NOTIF_ANY:
 527                 {
 528                         if(client)
 529                                 { checkargs = sprintf("%sEntity provided when world was required!", checkargs); }
 530                         break;
 531                 }
 532
 533                 case NOTIF_TEAM:
 534                 case NOTIF_TEAM_EXCEPT:
 535                 {
 536                         if not(teamplay) { checkargs = sprintf("%sTeamplay not active!", checkargs); }
 537                         else if(IS_NOT_A_CLIENT(client))
 538                         {
 539                                 if(broadcast == NOTIF_TEAM) { checkargs = sprintf("%sNo client provided!", checkargs); }
 540                                 else { checkargs = sprintf("%sException can't be a non-client!", checkargs); }
 541                         }
 542                         break;
 543                 }
 544
 545                 default: { checkargs = sprintf("%sImproper broadcast: %d!", checkargs, broadcast); break; }
 546         }
 547         if(checkargs != "") { backtrace(sprintf("Incorrect usage of Send_Notification: %s\n", checkargs)); return; }
 548
 549         // retreive counts for the arguments of this notification
 550         entity notif = Get_Notif_Ent(net_type, net_name);
 551         if not(notif) { backtrace("Send_Notification: Could not find notification entity!\n"); return; }
 552
 553         if((notif.nent_stringcount + notif.nent_floatcount) > count)
 554         {
 555                 backtrace(sprintf(
 556                         strcat(
 557                                 "Not enough arguments for Send_Notification! ",
 558                                 "stringcount(%d) + floatcount(%d) > count(%d)\n",
 559                                 "Check the definition and function call for accuracy...?\n"
 560                         ),
 561                         notif.nent_stringcount, notif.nent_floatcount, count));
 562                 return;
 563         }
 564         else if((notif.nent_stringcount + notif.nent_floatcount) < count)
 565         {
 566                 backtrace(sprintf(
 567                         strcat(
 568                                 "Too many arguments for Send_Notification! ",
 569                                 "stringcount(%d) + floatcount(%d) < count(%d)\n",
 570                                 "Check the definition and function call for accuracy...?\n"
 571                         ),
 572                         notif.nent_stringcount, notif.nent_floatcount, count));
 573                 return;
 574         }
 575
 576         #ifdef NOTIFICATIONS_DEBUG
 577         dprint(
 578                 sprintf("Send_Notification(%d, %d, %s, stringcount: %d, floatcount: %d, varargs: %d);\n",
 579                         broadcast,
 580                         net_type,
 581                         notif.nent_name,
 582                         notif.nent_stringcount,
 583                         notif.nent_floatcount,
 584                         count
 585                 )
 586         );
 587         #endif
 588
 589         entity net_notif = spawn();
 590         net_notif.nent_broadcast = broadcast;
 591         net_notif.nent_client = client;
 592         net_notif.nent_net_type = net_type;
 593         net_notif.nent_net_name = net_name;
 594         net_notif.nent_stringcount = notif.nent_stringcount;
 595         net_notif.nent_floatcount = notif.nent_floatcount;
 596
 597         float i;
 598         for(i = 0; i < net_notif.nent_stringcount; ++i) { net_notif.nent_strings[i] = strzone(...(i, string)); }
 599         for(i = 0; i < net_notif.nent_floatcount; ++i) { net_notif.nent_floats[i] = ...((net_notif.nent_stringcount + i), float); }
 600
 601         net_notif.think = Net_Notification_Remove;
 602         net_notif.nextthink = (time + 0.5);
 603
 604         Net_LinkEntity(net_notif, FALSE, 0, Net_Write_Notification);
 605
 606         if((!server_is_local) && (broadcast == NOTIF_ANY || broadcast == NOTIF_ANY_EXCEPT) && (net_type != MSG_CENTER))
 607         {
 608                 Local_Notification_WOVA(
 609                         net_type, net_name,
 610                         notif.nent_stringcount,
 611                         notif.nent_floatcount,
 612                         IFSTR(0), IFSTR(1), IFSTR(2), IFSTR(3),
 613                         IFFL(0), IFFL(1), IFFL(2), IFFL(3));
 614         }
 615 }
 616
 617 // WOVA = Without Variable Arguments
 618 void Send_Notification_WOVA(float broadcast, entity client,
 619         float net_type, float net_name,
 620         string s1, string s2, string s3, string s4,
 621         float f1, float f2, float f3, float f4)
 622 {
 623         entity notif = Get_Notif_Ent(net_type, net_name);
 624         #define VARITEM(stringc,floatc,args) \
 625                 if((notif.nent_stringcount == stringc) && (notif.nent_floatcount == floatc)) \
 626                         { Send_Notification(broadcast, client, net_type, net_name, args); return; }
 627         EIGHT_VARS_TO_VARARGS_VARLIST
 628         #undef VARITEM
 629         Send_Notification(broadcast, client, net_type, net_name); // some notifications don't have any arguments at all
 630 }
 631
 632
 633 // =============================
 634 //  LEGACY NOTIFICATION SYSTEMS
 635 // =============================
 636
 637 void Send_CSQC_Centerprint_Generic(entity e, float id, string s, float duration, float countdown_num)
 638 {
 639         if ((clienttype(e) == CLIENTTYPE_REAL) && (e.flags & FL_CLIENT))
 640         {
 641                 msg_entity = e;
 642                 WRITESPECTATABLE_MSG_ONE({
 643                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 644                         WriteByte(MSG_ONE, TE_CSQC_CENTERPRINT_GENERIC);
 645                         WriteByte(MSG_ONE, id);
 646                         WriteString(MSG_ONE, s);
 647                         if (id != 0 && s != "")
 648                         {
 649                                 WriteByte(MSG_ONE, duration);
 650                                 WriteByte(MSG_ONE, countdown_num);
 651                         }
 652                 });
 653         }
 654 }
 655 #endif // ifdef SVQC