qcsrc/common/notifications.qc

   1 // ================================================
   2 //  Unified notification system, written by Samual
   3 //  Last updated: February, 2013
   4 // ================================================
   5
   6 #ifndef MENUQC
   7 entity Get_Notif_Ent(float net_type, float net_name)
   8 {
   9         switch(net_type)
  10         {
  11                 case MSG_INFO: return msg_info_notifs[net_name - 1];
  12                 case MSG_CENTER: return msg_center_notifs[net_name - 1];
  13                 case MSG_WEAPON: return msg_weapon_notifs[net_name - 1];
  14                 case MSG_DEATH: return msg_death_notifs[net_name - 1];
  15         }
  16         backtrace(sprintf("Get_Notif_Ent(%d, %d): Improper net type!\n", net_type, net_name));
  17         return world;
  18 }
  19
  20 string Get_Notif_Name(float net_type, float net_name)
  21 {
  22         entity e = Get_Notif_Ent(net_type, net_name);
  23         if(e) { return e.nent_name; }
  24         backtrace(sprintf("Get_Notif_Name(%d, %d): Could not find entity!\n", net_type, net_name));
  25         return "";
  26 }
  27
  28 float Get_Notif_Infval(float net_type, float net_name)
  29 {
  30         entity e = Get_Notif_Ent(net_type, net_name);
  31         if(e) { return e.nent_infoname; }
  32         backtrace(sprintf("Get_Notif_Infval(%d, %d): Could not find entity!\n", net_type, net_name));
  33         return NO_MSG;
  34 }
  35
  36 float Get_Notif_Cenval(float net_type, float net_name)
  37 {
  38         entity e = Get_Notif_Ent(net_type, net_name);
  39         if(e) { return e.nent_centername; }
  40         backtrace(sprintf("Get_Notif_Cenval(%d, %d): Could not find entity!\n", net_type, net_name));
  41         return NO_MSG;
  42 }
  43
  44 float Get_Notif_Strnum(float net_type, float net_name)
  45 {
  46         entity e = Get_Notif_Ent(net_type, net_name);
  47         if(e) { return e.nent_stringcount; }
  48         backtrace(sprintf("Get_Notif_Strnum(%d, %d): Could not find entity!\n", net_type, net_name));
  49         return NO_MSG;
  50 }
  51
  52 float Get_Notif_Flnum(float net_type, float net_name)
  53 {
  54         entity e = Get_Notif_Ent(net_type, net_name);
  55         if(e) { return e.nent_floatcount; }
  56         backtrace(sprintf("Get_Notif_Flnum(%d, %d): Could not find entity!\n", net_type, net_name));
  57         return NO_MSG;
  58 }
  59 #endif // ifndef MENUQC
  60
  61
  62 // ===============================
  63 //  Frontend Notification Pushing
  64 // ===============================
  65
  66 void Dump_Notifications(float fh, float alsoprint)
  67 {
  68         float MSG_INFO_NOTIFS = 0, MSG_CENTER_NOTIFS = 0, MSG_WEAPON_NOTIFS = 0, MSG_DEATH_NOTIFS = 0;
  69
  70         #define NOTIF_WRITE(type,name,text) { \
  71                 ++##type##_NOTIFS; \
  72                 notif_msg = sprintf("seta %s 1 // %s - %s\n", name, #type, strreplace("\n", "\\n", text)); \
  73                 fputs(fh, notif_msg); \
  74                 if(alsoprint) { print(strreplace("^", "^^", notif_msg)); } }
  75
  76         #ifndef MENUQC
  77         string notif_msg;
  78         float i;
  79         entity e;
  80
  81         for(i = 0; i < NOTIF_INFO_COUNT; ++i) {
  82                 e = Get_Notif_Ent(MSG_INFO, i);
  83                 NOTIF_WRITE(MSG_INFO, e.nent_name, e.nent_string); }
  84
  85         for(i = 0; i < NOTIF_CENTER_COUNT; ++i) {
  86                 e = Get_Notif_Ent(MSG_CENTER, i);
  87                 NOTIF_WRITE(MSG_CENTER, e.nent_name, e.nent_string); }
  88
  89         for(i = 0; i < NOTIF_WEAPON_COUNT; ++i) {
  90                 e = Get_Notif_Ent(MSG_WEAPON, i);
  91                 NOTIF_WRITE(MSG_WEAPON, e.nent_name, sprintf("infoname: %s, centername: %s",
  92                         Get_Notif_Name(MSG_INFO, Get_Notif_Infval(MSG_WEAPON, i)),
  93                         Get_Notif_Name(MSG_CENTER, Get_Notif_Cenval(MSG_WEAPON, i)) ) ); }
  94
  95         for(i = 0; i < NOTIF_DEATH_COUNT; ++i) {
  96                 e = Get_Notif_Ent(MSG_DEATH, i);
  97                 NOTIF_WRITE(MSG_DEATH, e.nent_name, sprintf("infoname: %s, centername: %s",
  98                         Get_Notif_Name(MSG_INFO, Get_Notif_Infval(MSG_DEATH, i)),
  99                         Get_Notif_Name(MSG_CENTER, Get_Notif_Cenval(MSG_DEATH, i)) ) ); }
 100
 101         #endif
 102
 103         print(sprintf("Notification counts: MSG_INFO = %d, MSG_CENTER = %d, MSG_WEAPON = %d, MSG_DEATH = %d\n",
 104                 MSG_INFO_NOTIFS, MSG_CENTER_NOTIFS, MSG_WEAPON_NOTIFS, MSG_DEATH_NOTIFS));
 105
 106         return;
 107         #undef NOTIF_WRITE
 108 }
 109
 110 #ifndef MENUQC
 111 string Local_Notification_sprintf(string input, string args,
 112         string s1, string s2, string s3, string s4,
 113         float f1, float f2, float f3, float f4)
 114 {
 115         #ifdef NOTIFICATIONS_DEBUG
 116         dprint(sprintf("Local_Notification_sprintf('%s^7', '%s', %s, %s);\n",
 117                 strreplace("\n", "\\n", input), args,
 118                 sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4),
 119                 sprintf("%d, %d, %d, %d", f1, f2, f3, f4)));
 120         #endif
 121
 122         string selected, remaining = args;
 123         float sel_num = 0;
 124
 125         #ifdef CSQC
 126         string tmp_s;
 127         #endif
 128
 129         arg_slot[0] = ""; arg_slot[1] = ""; arg_slot[2] = ""; arg_slot[3] = ""; arg_slot[4] = ""; arg_slot[5] = ""; arg_slot[6] = "";
 130
 131         if((remaining != "") && (input != ""))
 132         {
 133                 for(;remaining;)
 134                 {
 135                         selected = car(remaining); remaining = cdr(remaining);
 136
 137                         if(sel_num == 7) { backtrace("Local_Notification_sprintf: Hit maximum arguments!\n"); break; }
 138
 139                         switch(strtolower(selected))
 140                         {
 141                                 #define ARG_CASE(prog,selected,result) \
 142                                         #ifdef CSQC \
 143                                         #if (prog == ARG_BOTH) || (prog == ARG_CSQC) \
 144                                                 case selected: { arg_slot[sel_num] = result; ++sel_num; break; } \
 145                                         #endif \
 146                                         #else \
 147                                         #if (prog == ARG_BOTH) || (prog == ARG_SVQC) \
 148                                                 case selected: { arg_slot[sel_num] = result; ++sel_num; break; } \
 149                                         #endif \
 150                                         #endif
 151
 152                                 NOTIF_ARGUMENT_LIST
 153                                 #undef ARG_CASE
 154                                 default: { backtrace(sprintf("Local_Notification_sprintf: Hit unknown token in selected string! '%s'\n", selected)); break; }
 155                         }
 156                 }
 157
 158                 return sprintf(input, arg_slot[0], arg_slot[1], arg_slot[2], arg_slot[3], arg_slot[4], arg_slot[5], arg_slot[6]);
 159         }
 160
 161         return "";
 162 }
 163
 164 #ifdef CSQC
 165 void Local_Notification_HUD_Notify_Push(string icon, string hudargs, string s1, string s2)
 166 {
 167         string selected, remaining = hudargs;
 168         float sel_num = 0;
 169
 170         arg_slot[0] = ""; arg_slot[1] = "";
 171
 172         if(remaining != "")
 173         {
 174                 for(;remaining;)
 175                 {
 176                         selected = car(remaining); remaining = cdr(remaining);
 177
 178                         if(sel_num == 2) { backtrace("Local_Notification_HUD_Notify_Push: Hit maximum arguments!\n"); break; }
 179
 180                         switch(strtolower(selected))
 181                         {
 182                                 #define ARG_CASE(selected,result) case selected: { arg_slot[sel_num] = result; ++sel_num; break; }
 183                                 ARG_CASE("s1", s1)
 184                                 ARG_CASE("s2", s2)
 185                                 #undef ARG_CASE
 186                                 default: { backtrace(sprintf("Local_Notification_HUD_Notify_Push: Hit unknown token in selected string! '%s'\n", selected)); break; }
 187                         }
 188                 }
 189         }
 190
 191         HUD_Notify_Push(icon, arg_slot[0], arg_slot[1]);
 192 }
 193 #endif
 194
 195 void Local_Notification(float net_type, float net_name, ...count)
 196 {
 197         // check supplied type and name for errors
 198         #define CHECKARG_TYPENAME(type) case MSG_##type##: \
 199                 { if(!net_name || (net_name > NOTIF_##type##_COUNT)) \
 200                 { checkargs = sprintf("Improper name: %d!", net_name); } break; }
 201         string checkargs = "";
 202         switch(net_type)
 203         {
 204                 CHECKARG_TYPENAME(INFO)
 205                 CHECKARG_TYPENAME(CENTER)
 206                 CHECKARG_TYPENAME(WEAPON)
 207                 CHECKARG_TYPENAME(DEATH)
 208                 default: { checkargs = sprintf("Improper type: %d!", checkargs, net_type); break; }
 209         }
 210         #undef CHECKARG_TYPENAME
 211         if(checkargs != "") { backtrace(sprintf("Incorrect usage of Local_Notification: %s\n", checkargs)); return; }
 212
 213         entity notif = Get_Notif_Ent(net_type, net_name);
 214         if not(notif) { backtrace("Local_Notification: Could not find notification entity! (This wasn't caught by usage check?...)\n"); return; }
 215         if not(notif.nent_enabled) { print("entity notification was disabled...\n"); return; }
 216
 217         if((notif.nent_stringcount + notif.nent_floatcount) > count)
 218                 { backtrace(sprintf(strcat("Not enough arguments for Local_Notification! stringcount(%d) + floatcount(%d) > count(%d)\n",
 219                 "Check the notification definition and function call for accuracy...?\n"), notif.nent_stringcount, notif.nent_floatcount, count)); return; }
 220         else if((notif.nent_stringcount + notif.nent_floatcount) < count)
 221                 { backtrace(sprintf(strcat("Too many arguments for Local_Notification! stringcount(%d) + floatcount(%d) < count(%d)\n",
 222                 "Check the notification definition and function call for accuracy...?\n"), notif.nent_stringcount, notif.nent_floatcount, count)); return; }
 223
 224         string s1 = ((0 < notif.nent_stringcount) ? ...(0, string) : "");
 225         string s2 = ((1 < notif.nent_stringcount) ? ...(1, string) : "");
 226         string s3 = ((2 < notif.nent_stringcount) ? ...(2, string) : "");
 227         string s4 = ((3 < notif.nent_stringcount) ? ...(3, string) : "");
 228         float f1 = ((notif.nent_stringcount < count) ? ...(notif.nent_stringcount, float) : NO_FL_ARG);
 229         float f2 = (((notif.nent_stringcount + 1) < count) ? ...((notif.nent_stringcount + 1), float) : NO_FL_ARG);
 230         float f3 = (((notif.nent_stringcount + 2) < count) ? ...((notif.nent_stringcount + 2), float) : NO_FL_ARG);
 231         float f4 = (((notif.nent_stringcount + 3) < count) ? ...((notif.nent_stringcount + 3), float) : NO_FL_ARG);
 232
 233         #ifdef NOTIFICATIONS_DEBUG
 234         dprint(sprintf("Local_Notification(%d, %s, %s, %s);\n",
 235                 net_type, notif.nent_name,
 236                 sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4),
 237                 sprintf("%d, %d, %d, %d", f1, f2, f3, f4)));
 238         #endif
 239
 240         switch(net_type)
 241         {
 242                 case MSG_INFO:
 243                 {
 244                         print(Local_Notification_sprintf(notif.nent_string, notif.nent_args,
 245                                 s1, s2, s3, s4, f1, f2, f3, f4));
 246                         #ifdef CSQC
 247                         if(notif.nent_icon != "") { Local_Notification_HUD_Notify_Push(notif.nent_icon, notif.nent_hudargs, s1, s2); }
 248                         #endif
 249                         break;
 250                 }
 251
 252                 #ifdef CSQC
 253                 case MSG_CENTER:
 254                 {
 255                         centerprint_generic(notif.nent_cpid,
 256                                 Local_Notification_sprintf(notif.nent_string, notif.nent_args,
 257                                 s1, s2, s3, s4, f1, f2, f3, f4), 0, 0);
 258                         break;
 259                 }
 260                 #endif
 261
 262                 case MSG_WEAPON:
 263                 case MSG_DEATH:
 264                 {
 265                         if(notif.nent_infoname)
 266                         if(msg_info_notifs[notif.nent_infoname - 1].nent_enabled)
 267                         {
 268                                 Local_Notification_Without_VarArgs(MSG_INFO, notif.nent_infoname,
 269                                         Get_Notif_Strnum(MSG_INFO, notif.nent_infoname),
 270                                         Get_Notif_Flnum(MSG_INFO, notif.nent_infoname),
 271                                         s1, s2, s3, s4, f1, f2, f3, f4);
 272                         }
 273                         #ifdef CSQC
 274                         if(notif.nent_centername)
 275                         if(msg_center_notifs[notif.nent_centername - 1].nent_enabled)
 276                         {
 277                                 Local_Notification_Without_VarArgs(MSG_CENTER, notif.nent_centername,
 278                                         Get_Notif_Strnum(MSG_CENTER, notif.nent_centername),
 279                                         Get_Notif_Flnum(MSG_CENTER, notif.nent_centername),
 280                                         s1, s2, s3, s4, f1, f2, f3, f4);
 281                         }
 282                         #endif
 283                         break;
 284                 }
 285         }
 286 }
 287
 288 void Local_Notification_Without_VarArgs(float net_type, float net_name,
 289         float stringcount, float floatcount,
 290         string s1, string s2, string s3, string s4,
 291         float f1, float f2, float f3, float f4)
 292 {
 293         #define VARITEM(stringc,floatc,args) if((stringcount == stringc) && (floatcount == floatc)) { Local_Notification(net_type, net_name, args); return; }
 294         EIGHT_VARS_TO_VARARGS_VARLIST
 295         #undef VARITEM
 296
 297         Local_Notification(net_type, net_name); // some notifications don't have any arguments at all
 298 }
 299
 300
 301 // =========================
 302 //  Notification Networking
 303 // =========================
 304
 305 #ifdef CSQC
 306 void Read_Notification(float is_new)
 307 {
 308         float net_type = ReadByte();
 309         float net_name = ReadShort();
 310
 311         entity notif = Get_Notif_Ent(net_type, net_name);
 312         if not(notif) { print("Read_Notification: Could not find notification entity!\n"); return; }
 313         if not(notif.nent_enabled) { print("Read_Notification: Entity was disabled but networked anyway?!?...\n"); return; }
 314
 315         string s1 = ((0 < notif.nent_stringcount) ? ReadString() : "");
 316         string s2 = ((1 < notif.nent_stringcount) ? ReadString() : "");
 317         string s3 = ((2 < notif.nent_stringcount) ? ReadString() : "");
 318         string s4 = ((3 < notif.nent_stringcount) ? ReadString() : "");
 319         float f1 = ((0 < notif.nent_floatcount) ? ReadLong() : NO_FL_ARG);
 320         float f2 = ((1 < notif.nent_floatcount) ? ReadLong() : NO_FL_ARG);
 321         float f3 = ((2 < notif.nent_floatcount) ? ReadLong() : NO_FL_ARG);
 322         float f4 = ((3 < notif.nent_floatcount) ? ReadLong() : NO_FL_ARG);
 323
 324         #ifdef NOTIFICATIONS_DEBUG
 325         dprint(sprintf("Read_Notification(%d) at %f: net_name = %s.\n", is_new, time, notif.nent_name));
 326         #endif
 327
 328         if(is_new) { Local_Notification_Without_VarArgs(net_type, net_name, notif.nent_stringcount, notif.nent_floatcount, s1, s2, s3, s4, f1, f2, f3, f4); }
 329 }
 330 #endif
 331
 332 #ifdef SVQC
 333 void Notification_Remove()
 334 {
 335         float i;
 336         for(i = 0; i < 4; ++i) { if(self.nent_strings[i]) { strunzone(self.nent_strings[i]); } }
 337         remove(self);
 338 }
 339
 340 float Write_Notification(entity client, float sf)
 341 {
 342         float i, send = FALSE;
 343
 344         switch(self.nent_broadcast)
 345         {
 346                 case NOTIF_ONE: { if((client == self.nent_client) || (client.classname == STR_SPECTATOR && client.enemy == self.nent_client)) { send = TRUE; } break; }
 347                 case NOTIF_ONE_ONLY: { if(client == self.nent_client) { send = TRUE; } break; }
 348                 case NOTIF_TEAM: { if((client.team == self.nent_client.team) || (client.classname == STR_SPECTATOR && client.enemy.team == self.nent_client.team)) { send = TRUE; } break; }
 349                 case NOTIF_TEAM_EXCEPT: { if(((client != self.nent_client) && (client.team == self.nent_client.team) && !(client.classname == STR_SPECTATOR && client.enemy == self.nent_client))) { send = TRUE; } break; }
 350                 case NOTIF_ANY: { send = TRUE; break; }
 351                 case NOTIF_ANY_EXCEPT: { if((client != self.nent_client) && !(client.classname == STR_SPECTATOR && client.enemy == self.nent_client)) { send = TRUE; } break; }
 352                 default: { send = FALSE; break; }
 353         }
 354
 355         if(send)
 356         {
 357                 WriteByte(MSG_ENTITY, ENT_CLIENT_NOTIFICATION);
 358                 WriteByte(MSG_ENTITY, self.nent_net_type);
 359                 WriteShort(MSG_ENTITY, self.nent_net_name);
 360                 for(i = 0; i < self.nent_stringcount; ++i) { WriteString(MSG_ENTITY, self.nent_strings[i]); }
 361                 for(i = 0; i < self.nent_floatcount; ++i) { WriteLong(MSG_ENTITY, self.nent_floats[i]); }
 362         }
 363
 364         return send;
 365 }
 366
 367 void Send_Notification(float broadcast, entity client,
 368         float net_type, float net_name, ...count)
 369 {
 370         // check supplied broadcast, target, type, and name for errors
 371         #define CHECKARG_TYPENAME(type) case MSG_##type##: \
 372                 { if(!net_name || (net_name > NOTIF_##type##_COUNT)) \
 373                 { checkargs = sprintf("Improper name: %d!", net_name); } break; }
 374         string checkargs = "";
 375         switch(net_type)
 376         {
 377                 CHECKARG_TYPENAME(INFO)
 378                 CHECKARG_TYPENAME(CENTER)
 379                 CHECKARG_TYPENAME(WEAPON)
 380                 CHECKARG_TYPENAME(DEATH)
 381                 default: { checkargs = sprintf("Improper type: %d!", checkargs, net_type); break; }
 382         }
 383         #undef CHECKARG_TYPENAME
 384         if(checkargs != "") { checkargs = strcat(checkargs, " "); }
 385         switch(broadcast)
 386         {
 387                 case NOTIF_ONE:
 388                 case NOTIF_ONE_ONLY: { if(clienttype(client) == CLIENTTYPE_NOTACLIENT) { checkargs = sprintf("%sNo client provided!", checkargs); } break; }
 389                 case NOTIF_ANY_EXCEPT: { if(clienttype(client) == CLIENTTYPE_NOTACLIENT) { checkargs = sprintf("%sException can't be a non-client!", checkargs); } break; }
 390                 case NOTIF_ANY: { if(client) { checkargs = sprintf("%sEntity provided when world was required!", checkargs); } break; }
 391                 case NOTIF_TEAM:
 392                 case NOTIF_TEAM_EXCEPT:
 393                 {
 394                         if not(teamplay) { checkargs = sprintf("%sTeamplay not active!", checkargs); }
 395                         else if(clienttype(client) == CLIENTTYPE_NOTACLIENT)
 396                         {
 397                                 if(broadcast == NOTIF_TEAM) { checkargs = sprintf("%sNo client provided!", checkargs); }
 398                                 else { checkargs = sprintf("%sException can't be a non-client!", checkargs); }
 399                         }
 400                         break;
 401                 }
 402                 default: { checkargs = sprintf("%sImproper broadcast: %d!", checkargs, broadcast); break; }
 403         }
 404         if(checkargs != "") { backtrace(sprintf("Incorrect usage of Send_Notification: %s\n", checkargs)); return; }
 405
 406         // retreive counts for the arguments of this notification
 407         entity notif = Get_Notif_Ent(net_type, net_name);
 408         if not(notif) { backtrace("Send_Notification: Could not find notification entity! (This wasn't caught by usage check?...)\n"); return; }
 409         if not(notif.nent_enabled) { print("Send_Notification: Entity was disabled...\n"); return; }
 410
 411         if((notif.nent_stringcount + notif.nent_floatcount) > count)
 412                 { backtrace(sprintf(strcat("Not enough arguments for Send_Notification! stringcount(%d) + floatcount(%d) > count(%d)\n",
 413                 "Check the notification definition and function call for accuracy...?\n"), notif.nent_stringcount, notif.nent_floatcount, count)); return; }
 414         else if((notif.nent_stringcount + notif.nent_floatcount) < count)
 415                 { backtrace(sprintf(strcat("Too many arguments for Send_Notification! stringcount(%d) + floatcount(%d) < count(%d)\n",
 416                 "Check the notification definition and function call for accuracy...?\n"), notif.nent_stringcount, notif.nent_floatcount, count)); return; }
 417
 418         #ifdef NOTIFICATIONS_DEBUG
 419         dprint(sprintf("Send_Notification(%d, %d, %s, stringcount: %d, floatcount: %d, varargs: %d);\n",
 420                 broadcast, net_type, notif.nent_name, notif.nent_stringcount, notif.nent_floatcount, count));
 421         #endif
 422
 423         entity net_notif = spawn();
 424         net_notif.nent_broadcast = broadcast;
 425         net_notif.nent_client = client;
 426         net_notif.nent_net_type = net_type;
 427         net_notif.nent_net_name = net_name;
 428         net_notif.nent_stringcount = notif.nent_stringcount;
 429         net_notif.nent_floatcount = notif.nent_floatcount;
 430
 431         float i;
 432
 433         for(i = 0; i < net_notif.nent_stringcount; ++i) { net_notif.nent_strings[i] = strzone(...(i, string)); }
 434         for(i = 0; i < net_notif.nent_floatcount; ++i) { net_notif.nent_floats[i] = ...((net_notif.nent_stringcount + i), float); }
 435
 436         net_notif.think = Notification_Remove;
 437         net_notif.nextthink = (time + 0.5);
 438
 439         Net_LinkEntity(net_notif, FALSE, 0, Write_Notification);
 440
 441         if((!server_is_local) && (broadcast == NOTIF_ANY || broadcast == NOTIF_ANY_EXCEPT) && (net_type != MSG_CENTER))
 442                 { Local_Notification_Without_VarArgs(net_type, net_name, notif.nent_stringcount, notif.nent_floatcount,
 443                         IFSTR(0), IFSTR(1), IFSTR(2), IFSTR(3), IFFL(0), IFFL(1), IFFL(2), IFFL(3)); }
 444 }
 445
 446 void Send_Notification_Without_VarArgs(float broadcast, entity client,
 447         float net_type, float net_name,
 448         float stringcount, float floatcount,
 449         string s1, string s2, string s3, string s4,
 450         float f1, float f2, float f3, float f4)
 451 {
 452         #define VARITEM(stringc,floatc,args) if((stringcount == stringc) && (floatcount == floatc)) { Send_Notification(broadcast, client, net_type, net_name, args); return; }
 453         EIGHT_VARS_TO_VARARGS_VARLIST
 454         #undef VARITEM
 455
 456         Send_Notification(broadcast, client, net_type, net_name); // some notifications don't have any arguments at all
 457 }
 458
 459 void Send_Notification_Legacy_Wrapper(float broadcast, entity client,
 460         float net_type, float net_name,
 461         string s1, string s2,
 462         float f1, float f2, float f3)
 463 {
 464         float stringcount = Get_Notif_Strnum(net_type, net_name);
 465         float floatcount = Get_Notif_Flnum(net_type, net_name);
 466         Send_Notification_Without_VarArgs(broadcast, client, net_type, net_name, stringcount, floatcount, s1, s2, "", "", f1, f2, f3, NO_FL_ARG);
 467 }
 468
 469
 470 // =============================
 471 //  LEGACY NOTIFICATION SYSTEMS
 472 // =============================
 473
 474 void Send_CSQC_Centerprint_Generic(entity e, float id, string s, float duration, float countdown_num)
 475 {
 476         if ((clienttype(e) == CLIENTTYPE_REAL) && (e.flags & FL_CLIENT))
 477         {
 478                 msg_entity = e;
 479                 WRITESPECTATABLE_MSG_ONE({
 480                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 481                         WriteByte(MSG_ONE, TE_CSQC_CENTERPRINT_GENERIC);
 482                         WriteByte(MSG_ONE, id);
 483                         WriteString(MSG_ONE, s);
 484                         if (id != 0 && s != "")
 485                         {
 486                                 WriteByte(MSG_ONE, duration);
 487                                 WriteByte(MSG_ONE, countdown_num);
 488                         }
 489                 });
 490         }
 491 }
 492 void Send_CSQC_Centerprint_Generic_Expire(entity e, float id)
 493 {
 494         Send_CSQC_Centerprint_Generic(e, id, "", 1, 0);
 495 }
 496 #endif // ifdef SVQC
 497 #endif // ifndef MENUQC