qcsrc/common/notifications.qc

   1 // ================================================
   2 //  Unified notification system, written by Samual
   3 //  Last updated: February, 2013
   4 // ================================================
   5
   6 entity Get_Notif_Ent(float net_type, float net_name)
   7 {
   8         switch(net_type)
   9         {
  10                 case MSG_INFO: return msg_info_notifs[net_name - 1];
  11                 case MSG_CENTER: return msg_center_notifs[net_name - 1];
  12                 case MSG_WEAPON: return msg_weapon_notifs[net_name - 1];
  13                 case MSG_DEATH: return msg_death_notifs[net_name - 1];
  14         }
  15         backtrace(sprintf("Get_Notif_Ent(%d, %d): Improper net type!\n", net_type, net_name));
  16         return world;
  17 }
  18
  19
  20 // ===============================
  21 //  Frontend Notification Pushing
  22 // ===============================
  23
  24 void Dump_Notifications(float fh, float alsoprint)
  25 {
  26         #define NOTIF_WRITE(a) { \
  27                 fputs(fh, a); \
  28                 if(alsoprint) { print(a); } }
  29         #define NOTIF_WRITE_SETA(name,default,text) { \
  30                 notif_msg = \
  31                         sprintf( \
  32                                 "seta notification_%s %d \"notif string: %s^7\"\n", \
  33                                 name, default, strreplace("\{3}", "", strreplace("\n", "\\n", text)) \
  34                         ); \
  35                 NOTIF_WRITE(notif_msg) }
  36
  37         string notif_msg;
  38         float i;
  39         entity e;
  40
  41         // Note: This warning only applies to the notifications.cfg file that is output...
  42
  43         // You ARE supposed to manually edit this function to add i.e. hard coded
  44         // notification variables for mutators or game modes or such and then
  45         // regenerate the notifications.cfg file from the new code.
  46
  47         NOTIF_WRITE("// ********************************************** //\n");
  48         NOTIF_WRITE("// ** WARNING - DO NOT MANUALLY EDIT THIS FILE ** //\n");
  49         NOTIF_WRITE("// **                                          ** //\n");
  50         NOTIF_WRITE("// **  This file is automatically generated    ** //\n");
  51         NOTIF_WRITE("// **  by code with the command 'dumpnotifs'.  ** //\n");
  52         NOTIF_WRITE("// **                                          ** //\n");
  53         NOTIF_WRITE("// **  If you add a new notification, please   ** //\n");
  54         NOTIF_WRITE("// **  regenerate this file with that command  ** //\n");
  55         NOTIF_WRITE("// **  making sure that the output matches     ** //\n");
  56         NOTIF_WRITE("// **  with the lists and defaults in code.    ** //\n");
  57         NOTIF_WRITE("// **                                          ** //\n");
  58         NOTIF_WRITE("// ********************************************** //\n");
  59
  60         // These notifications will also append their string as a comment...
  61         // This is not necessary, and does not matter if they vary between config versions,
  62         // it is just a semi-helpful tool for those who want to manually change their user settings.
  63
  64         NOTIF_WRITE(sprintf("\n// MSG_INFO notifications (count = %d):\n", NOTIF_INFO_COUNT));
  65         for(i = 1; i <= NOTIF_INFO_COUNT; ++i)
  66         {
  67                 e = Get_Notif_Ent(MSG_INFO, i);
  68                 if not(e) { backtrace("Dump_Notifications(): Missing notification entity!\n"); return; }
  69                 NOTIF_WRITE_SETA(e.nent_name, e.nent_default, e.nent_string);
  70         }
  71
  72         NOTIF_WRITE(sprintf("\n// MSG_CENTER notifications (count = %d):\n", NOTIF_CENTER_COUNT));
  73         for(i = 1; i <= NOTIF_CENTER_COUNT; ++i)
  74         {
  75                 e = Get_Notif_Ent(MSG_CENTER, i);
  76                 if not(e) { backtrace("Dump_Notifications(): Missing notification entity!\n"); return; }
  77                 NOTIF_WRITE_SETA(e.nent_name, e.nent_default, e.nent_string);
  78         }
  79
  80         NOTIF_WRITE(sprintf("\n// MSG_WEAPON notifications (count = %d):\n", NOTIF_WEAPON_COUNT));
  81         for(i = 1; i <= NOTIF_WEAPON_COUNT; ++i)
  82         {
  83                 e = Get_Notif_Ent(MSG_WEAPON, i);
  84                 if not(e) { backtrace("Dump_Notifications(): Missing notification entity!\n"); return; }
  85                 NOTIF_WRITE_SETA(e.nent_name, e.nent_default, sprintf("infoname: %s, centername: %s",
  86                         e.nent_msginfo.nent_name, e.nent_msgcenter.nent_name));
  87         }
  88
  89         NOTIF_WRITE(sprintf("\n// MSG_DEATH notifications (count = %d):\n", NOTIF_DEATH_COUNT));
  90         for(i = 1; i <= NOTIF_DEATH_COUNT; ++i)
  91         {
  92                 e = Get_Notif_Ent(MSG_DEATH, i);
  93                 if not(e) { backtrace("Dump_Notifications(): Missing notification entity!\n"); return; }
  94                 NOTIF_WRITE_SETA(e.nent_name, e.nent_default, sprintf("infoname: %s, centername: %s",
  95                         e.nent_msginfo.nent_name, e.nent_msgcenter.nent_name));
  96         }
  97
  98         // edit these to match whichever cvars are used for specific notification options
  99         NOTIF_WRITE("\n// HARD CODED notification variables:\n");
 100         NOTIF_WRITE("seta notification_allow_chatboxprint 1 \"Allow notifications to be printed to chat box by setting notification cvar to 2 (You can also set this cvar to 2 to force ALL notifications to be printed to the chatbox)\"\n");
 101         NOTIF_WRITE("seta notification_show_sprees 1 \"Print information about sprees in death/kill messages\"\n");
 102         NOTIF_WRITE("seta notification_show_sprees_center 1 \"Show spree information in MSG_CENTER messages... 0 = off, 1 = target (but only for first victim) and attacker\"\n");
 103         NOTIF_WRITE("seta notification_show_sprees_center_specialonly 1 \"Don't show spree information in MSG_CENTER messages if it isn't an achievement\"\n");
 104         NOTIF_WRITE("seta notification_show_sprees_info 3 \"Show spree information in MSG_INFO messages... 0 = off, 1 = target only, 2 = attacker only, 3 = target and attacker\"\n");
 105         NOTIF_WRITE("seta notification_show_sprees_info_newline 0 \"Show attacker spree information for MSG_INFO messages on a separate line than the death notification itself\"\n");
 106         NOTIF_WRITE("seta notification_show_sprees_info_specialonly 1 \"Don't show attacker spree information in MSG_INFO messages if it isn't an achievement\"\n");
 107         NOTIF_WRITE("seta notification_version_mismatch_client_error 0 \"Cause a notif error on client if the version in notifications.cfg mismatches the code\"\n");
 108         NOTIF_WRITE("seta notification_version_mismatch_server_error 1 \"Cause a notif error on server if the version in notifications.cfg mismatches the code\"\n");
 109         NOTIF_WRITE("seta notification_errors_are_fatal 1 \"If a notification fails upon initialization, cause a Host_Error to stop the program\"\n");
 110         NOTIF_WRITE("seta notification_ctf_pickup_team_verbose 1 \"Show extra information if a team mate picks up a flag\"\n");
 111         NOTIF_WRITE("seta notification_ctf_pickup_enemy_verbose 1 \"Show extra information if an enemy picks up a flag\"\n");
 112         NOTIF_WRITE("seta notification_ctf_capture_verbose 1 \"Show extra information when someone captures a flag\"\n");
 113         NOTIF_WRITE("seta notification_frag_verbose 1 \"Show extra information when you frag someone (or when you are fragged\"\n");
 114
 115         NOTIF_WRITE(sprintf("\n// Notification counts (total = %d): MSG_INFO = %d, MSG_CENTER = %d, MSG_WEAPON = %d, MSG_DEATH = %d\n",
 116                 (NOTIF_INFO_COUNT + NOTIF_CENTER_COUNT + NOTIF_WEAPON_COUNT + NOTIF_DEATH_COUNT),
 117                 NOTIF_INFO_COUNT, NOTIF_CENTER_COUNT, NOTIF_WEAPON_COUNT, NOTIF_DEATH_COUNT));
 118
 119         return;
 120         #undef NOTIF_WRITE_SETA
 121         #undef NOTIF_WRITE
 122 }
 123
 124 #ifdef SVQC
 125 void Notification_GetCvars()
 126 {
 127         GetCvars_handleFloat(get_cvars_s, get_cvars_f, FRAG_VERBOSE, "notification_frag_verbose");
 128 }
 129 #endif
 130
 131 string Local_Notification_sprintf(string input, string args,
 132         string s1, string s2, string s3, string s4,
 133         float f1, float f2, float f3, float f4)
 134 {
 135         #ifdef NOTIFICATIONS_DEBUG
 136         dprint(
 137                 sprintf("Local_Notification_sprintf('%s^7', '%s', %s, %s);\n",
 138                         strreplace("\n", "\\n", input),
 139                         args,
 140                         sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4),
 141                         sprintf("%d, %d, %d, %d", f1, f2, f3, f4)
 142                 )
 143         );
 144         #endif
 145
 146         string selected;
 147         float sel_num;
 148         for(sel_num = 0; sel_num < NOTIF_MAX_ARGS; ++sel_num) { arg_slot[sel_num] = ""; }
 149
 150         #ifdef CSQC
 151         string tmp_s;
 152         #endif
 153
 154         for(sel_num = 0;(args != "");)
 155         {
 156                 selected = car(args); args = cdr(args);
 157                 NOTIF_HIT_MAX(NOTIF_MAX_ARGS, "Local_Notification_sprintf")
 158                 switch(strtolower(selected))
 159                 {
 160                         #define ARG_CASE(prog,selected,result) \
 161                                 #ifdef CSQC \
 162                                         #if (prog == ARG_DOUBLE) || (prog == ARG_TRIPLE) || (prog == ARG_CSQC) \
 163                                                 case selected: { arg_slot[sel_num] = result; ++sel_num; break; } \
 164                                         #endif \
 165                                 #else \
 166                                         #if (prog == ARG_DOUBLE) || (prog == ARG_TRIPLE) || (prog == ARG_SVQC) \
 167                                                 case selected: { arg_slot[sel_num] = result; ++sel_num; break; } \
 168                                         #endif \
 169                                 #endif
 170                         NOTIF_ARGUMENT_LIST
 171                         #undef ARG_CASE
 172                         NOTIF_HIT_UNKNOWN(NOTIF_MAX_ARGS, "Local_Notification_sprintf")
 173                 }
 174         }
 175         return sprintf(input, arg_slot[0], arg_slot[1], arg_slot[2], arg_slot[3], arg_slot[4], arg_slot[5], arg_slot[6]);
 176 }
 177
 178 #ifdef CSQC
 179 void Local_Notification_HUD_Notify_Push(string icon, string hudargs, string s1, string s2, string s3, string s4)
 180 {
 181         string selected;
 182         float sel_num;
 183         arg_slot[0] = ""; arg_slot[1] = "";
 184
 185         for(sel_num = 0;(hudargs != "");)
 186         {
 187                 selected = car(hudargs); hudargs = cdr(hudargs);
 188                 NOTIF_HIT_MAX(NOTIF_MAX_HUDARGS, "Local_Notification_HUD_Notify_Push")
 189                 switch(strtolower(selected))
 190                 {
 191                         #define ARG_CASE(prog,selected,result) \
 192                                 #if (prog == ARG_TRIPLE) \
 193                                         case selected: { arg_slot[sel_num] = result; ++sel_num; break; } \
 194                                 #endif
 195                         NOTIF_ARGUMENT_LIST
 196                         #undef ARG_CASE
 197                         NOTIF_HIT_UNKNOWN(NOTIF_MAX_HUDARGS, "Local_Notification_HUD_Notify_Push")
 198                 }
 199         }
 200         HUD_Notify_Push(icon, arg_slot[0], arg_slot[1]);
 201 }
 202
 203 void Local_Notification_centerprint_generic(string input, string durcnt, float cpid, float f1, float f2)
 204 {
 205         string olddurcnt = durcnt;
 206         string selected;
 207         float sel_num;
 208         arg_slot[0] = ""; arg_slot[1] = "";
 209
 210         for(sel_num = 0;(durcnt != "");)
 211         {
 212                 selected = car(durcnt); durcnt = cdr(durcnt);
 213                 NOTIF_HIT_MAX(NOTIF_MAX_HUDARGS, "Local_Notification_centerprint_generic")
 214                 switch(strtolower(selected))
 215                 {
 216                         case "f1": { arg_slot[sel_num] = ftos(f1); ++sel_num; break; }
 217                         case "0": { arg_slot[sel_num] = "0"; ++sel_num; break; }
 218                         case "1": { arg_slot[sel_num] = "1"; ++sel_num; break; }
 219                         NOTIF_HIT_UNKNOWN(NOTIF_MAX_HUDARGS, "Local_Notification_centerprint_generic")
 220                 }
 221         }
 222
 223         #ifdef NOTIFICATIONS_DEBUG
 224         dprint(
 225                 sprintf("Local_Notification_centerprint_generic(%d, '%s^7', '%s', '%s', '%s');\n",
 226                         cpid,
 227                         strreplace("\n", "\\n", input),
 228                         olddurcnt,
 229                         arg_slot[0], arg_slot[1]
 230                 )
 231         );
 232         #endif
 233         centerprint_generic(cpid, input, stof(arg_slot[0]), stof(arg_slot[1]));
 234 }
 235 #endif
 236
 237 void Local_Notification(float net_type, float net_name, ...count)
 238 {
 239         // check supplied type and name for errors
 240         string checkargs = "";
 241         #define CHECKARG_TYPENAME(type) case MSG_##type##: \
 242                 { if(!net_name || (net_name > NOTIF_##type##_COUNT)) \
 243                 { checkargs = sprintf("Improper name: %d!", net_name); } break; }
 244         switch(net_type)
 245         {
 246                 CHECKARG_TYPENAME(INFO)
 247                 CHECKARG_TYPENAME(CENTER)
 248                 CHECKARG_TYPENAME(WEAPON)
 249                 CHECKARG_TYPENAME(DEATH)
 250                 default: { checkargs = sprintf("Improper type: %d!", checkargs, net_type); break; }
 251         }
 252         #undef CHECKARG_TYPENAME
 253         if(checkargs != "") { backtrace(sprintf("Incorrect usage of Local_Notification: %s\n", checkargs)); return; }
 254
 255         entity notif = Get_Notif_Ent(net_type, net_name);
 256         if not(notif) { backtrace("Local_Notification: Could not find notification entity!\n"); return; }
 257         if not(notif.nent_enabled) { print("Local_Notification: Entity was disabled...\n"); return; }
 258
 259         if((notif.nent_stringcount + notif.nent_floatcount) > count)
 260         {
 261                 backtrace(sprintf(
 262                         strcat(
 263                                 "Not enough arguments for Local_Notification(%d, %s, ...)! ",
 264                                 "stringcount(%d) + floatcount(%d) > count(%d)\n",
 265                                 "Check the definition and function call for accuracy...?\n"
 266                         ),
 267                         net_type, notif.nent_name, notif.nent_stringcount, notif.nent_floatcount, count));
 268                 return;
 269         }
 270         else if((notif.nent_stringcount + notif.nent_floatcount) < count)
 271         {
 272                 backtrace(sprintf(
 273                         strcat(
 274                                 "Too many arguments for Local_Notification(%d, %s, ...)! ",
 275                                 "stringcount(%d) + floatcount(%d) < count(%d)\n",
 276                                 "Check the definition and function call for accuracy...?\n"
 277                         ),
 278                         net_type, notif.nent_name, notif.nent_stringcount, notif.nent_floatcount, count));
 279                 return;
 280         }
 281
 282         string s1 = ((0 < notif.nent_stringcount) ? ...(0, string) : "");
 283         string s2 = ((1 < notif.nent_stringcount) ? ...(1, string) : "");
 284         string s3 = ((2 < notif.nent_stringcount) ? ...(2, string) : "");
 285         string s4 = ((3 < notif.nent_stringcount) ? ...(3, string) : "");
 286         float f1 = ((0 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 0), float) : 0);
 287         float f2 = ((1 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 1), float) : 0);
 288         float f3 = ((2 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 2), float) : 0);
 289         float f4 = ((3 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 3), float) : 0);
 290
 291         #ifdef NOTIFICATIONS_DEBUG
 292         dprint(
 293                 sprintf("Local_Notification(%d, %s, %s, %s);\n",
 294                         net_type,
 295                         notif.nent_name,
 296                         sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4),
 297                         sprintf("%d, %d, %d, %d", f1, f2, f3, f4)
 298                 )
 299         );
 300         #endif
 301
 302         switch(net_type)
 303         {
 304                 case MSG_INFO:
 305                 {
 306                         print(
 307                                 Local_Notification_sprintf(
 308                                         notif.nent_string,
 309                                         notif.nent_args,
 310                                         s1, s2, s3, s4,
 311                                         f1, f2, f3, f4)
 312                         );
 313                         #ifdef CSQC
 314                         if(notif.nent_icon != "")
 315                         {
 316                                 Local_Notification_HUD_Notify_Push(
 317                                         notif.nent_icon,
 318                                         notif.nent_hudargs,
 319                                         s1, s2, s3, s4);
 320                         }
 321                         #endif
 322                         break;
 323                 }
 324
 325                 #ifdef CSQC
 326                 case MSG_CENTER:
 327                 {
 328                         Local_Notification_centerprint_generic(
 329                                 Local_Notification_sprintf(
 330                                         notif.nent_string,
 331                                         notif.nent_args,
 332                                         s1, s2, s3, s4,
 333                                         f1, f2, f3, f4),
 334                                 notif.nent_durcnt,
 335                                 notif.nent_cpid,
 336                                 f1, f2);
 337                         break;
 338                 }
 339                 #endif
 340
 341                 case MSG_WEAPON:
 342                 case MSG_DEATH:
 343                 {
 344                         if(notif.nent_msginfo)
 345                         if(notif.nent_msginfo.nent_enabled)
 346                         {
 347                                 Local_Notification_WOVA(
 348                                         MSG_INFO,
 349                                         notif.nent_msginfo.nent_id,
 350                                         notif.nent_msginfo.nent_stringcount,
 351                                         notif.nent_msginfo.nent_floatcount,
 352                                         s1, s2, s3, s4,
 353                                         f1, f2, f3, f4);
 354                         }
 355                         #ifdef CSQC
 356                         if(notif.nent_msgcenter)
 357                         if(notif.nent_msgcenter.nent_enabled)
 358                         {
 359                                 Local_Notification_WOVA(
 360                                         MSG_CENTER,
 361                                         notif.nent_msgcenter.nent_id,
 362                                         notif.nent_msgcenter.nent_stringcount,
 363                                         notif.nent_msgcenter.nent_floatcount,
 364                                         s1, s2, s3, s4,
 365                                         f1, f2, f3, f4);
 366                         }
 367                         #endif
 368                         break;
 369                 }
 370         }
 371 }
 372
 373 // WOVA = Without Variable Arguments
 374 void Local_Notification_WOVA(float net_type, float net_name,
 375         float stringcount, float floatcount,
 376         string s1, string s2, string s3, string s4,
 377         float f1, float f2, float f3, float f4)
 378 {
 379         #define VARITEM(stringc,floatc,args) \
 380                 if((stringcount == stringc) && (floatcount == floatc)) \
 381                         { Local_Notification(net_type, net_name, args); return; }
 382         EIGHT_VARS_TO_VARARGS_VARLIST
 383         #undef VARITEM
 384         Local_Notification(net_type, net_name); // some notifications don't have any arguments at all
 385 }
 386
 387
 388 // =========================
 389 //  Notification Networking
 390 // =========================
 391
 392 #ifdef CSQC
 393 void Read_Notification(float is_new)
 394 {
 395         float net_type = ReadByte();
 396         float net_name = ReadShort();
 397
 398         entity notif = Get_Notif_Ent(net_type, net_name);
 399         if not(notif) { print("Read_Notification: Could not find notification entity!\n"); return; }
 400
 401         string s1 = ((0 < notif.nent_stringcount) ? ReadString() : "");
 402         string s2 = ((1 < notif.nent_stringcount) ? ReadString() : "");
 403         string s3 = ((2 < notif.nent_stringcount) ? ReadString() : "");
 404         string s4 = ((3 < notif.nent_stringcount) ? ReadString() : "");
 405         float f1 = ((0 < notif.nent_floatcount) ? ReadLong() : 0);
 406         float f2 = ((1 < notif.nent_floatcount) ? ReadLong() : 0);
 407         float f3 = ((2 < notif.nent_floatcount) ? ReadLong() : 0);
 408         float f4 = ((3 < notif.nent_floatcount) ? ReadLong() : 0);
 409
 410         #ifdef NOTIFICATIONS_DEBUG
 411         dprint(sprintf("Read_Notification(%d) at %f: net_name = %s.\n", is_new, time, notif.nent_name));
 412         #endif
 413
 414         if(is_new)
 415         {
 416                 Local_Notification_WOVA(
 417                         net_type, net_name,
 418                         notif.nent_stringcount,
 419                         notif.nent_floatcount,
 420                         s1, s2, s3, s4,
 421                         f1, f2, f3, f4);
 422         }
 423 }
 424 #endif
 425
 426 #ifdef SVQC
 427 void Net_Notification_Remove()
 428 {
 429         float i;
 430         for(i = 0; i < 4; ++i) { if(self.nent_strings[i]) { strunzone(self.nent_strings[i]); } }
 431         remove(self);
 432 }
 433
 434 float Net_Write_Notification(entity client, float sf)
 435 {
 436         float i, send = FALSE;
 437
 438         switch(self.nent_broadcast)
 439         {
 440                 case NOTIF_ONE: // send to one client and their spectator
 441                 {
 442                         if(
 443                                 (client == self.nent_client)
 444                                 ||
 445                                 (
 446                                         (client.classname == STR_SPECTATOR)
 447                                         &&
 448                                         (client.enemy == self.nent_client)
 449                                 )
 450                         ) { send = TRUE; }
 451                         break;
 452                 }
 453                 case NOTIF_ONE_ONLY: // send ONLY to one client
 454                 {
 455                         if(client == self.nent_client) { send = TRUE; }
 456                         break;
 457                 }
 458                 case NOTIF_TEAM: // send only to X team and their spectators
 459                 {
 460                         if(
 461                                 (client.team == self.nent_client.team)
 462                                 ||
 463                                 (
 464                                         (client.classname == STR_SPECTATOR)
 465                                         &&
 466                                         (client.enemy.team == self.nent_client.team)
 467                                 )
 468                         ) { send = TRUE; }
 469                         break;
 470                 }
 471                 case NOTIF_TEAM_EXCEPT: // send only to X team and their spectators, except for Y person and their spectators
 472                 {
 473                         if(
 474                                 (client != self.nent_client)
 475                                 &&
 476                                 (
 477                                         (client.team == self.nent_client.team)
 478                                         ||
 479                                         (
 480                                                 (client.classname == STR_SPECTATOR)
 481                                                 &&
 482                                                 (
 483                                                         (client.enemy != self.nent_client)
 484                                                         &&
 485                                                         (client.enemy.team == self.nent_client.team)
 486                                                 )
 487                                         )
 488                                 )
 489                         ) { send = TRUE; }
 490                         break;
 491                 }
 492                 case NOTIF_ANY: // send to everyone
 493                 {
 494                         send = TRUE;
 495                         break;
 496                 }
 497                 case NOTIF_ANY_EXCEPT: // send to everyone except X person and their spectators
 498                 {
 499                         if(
 500                                 (client != self.nent_client)
 501                                 &&
 502                                 !(
 503                                         (client.classname == STR_SPECTATOR)
 504                                         &&
 505                                         (client.enemy == self.nent_client)
 506                                 )
 507                         ) { send = TRUE; }
 508                         break;
 509                 }
 510                 default: { send = FALSE; break; }
 511         }
 512
 513         if(send)
 514         {
 515                 WriteByte(MSG_ENTITY, ENT_CLIENT_NOTIFICATION);
 516                 WriteByte(MSG_ENTITY, self.nent_net_type);
 517                 WriteShort(MSG_ENTITY, self.nent_net_name);
 518                 for(i = 0; i < self.nent_stringcount; ++i) { WriteString(MSG_ENTITY, self.nent_strings[i]); }
 519                 for(i = 0; i < self.nent_floatcount; ++i) { WriteLong(MSG_ENTITY, self.nent_floats[i]); }
 520         }
 521
 522         return send;
 523 }
 524
 525 void Send_Notification(float broadcast, entity client,
 526         float net_type, float net_name, ...count)
 527 {
 528         // check supplied broadcast, target, type, and name for errors
 529         string checkargs = "";
 530         #define CHECKARG_TYPENAME(type) case MSG_##type##: \
 531                 { if(!net_name || (net_name > NOTIF_##type##_COUNT)) \
 532                 { checkargs = sprintf("Improper name: %d!", net_name); } break; }
 533         switch(net_type)
 534         {
 535                 CHECKARG_TYPENAME(INFO)
 536                 CHECKARG_TYPENAME(CENTER)
 537                 CHECKARG_TYPENAME(WEAPON)
 538                 CHECKARG_TYPENAME(DEATH)
 539                 default: { checkargs = sprintf("Improper type: %d!", checkargs, net_type); break; }
 540         }
 541         #undef CHECKARG_TYPENAME
 542         if(checkargs != "") { checkargs = strcat(checkargs, " "); }
 543         switch(broadcast)
 544         {
 545                 case NOTIF_ONE:
 546                 case NOTIF_ONE_ONLY:
 547                 {
 548                         if(IS_NOT_A_CLIENT(client))
 549                                 { checkargs = sprintf("%sNo client provided!", checkargs); }
 550                         break;
 551                 }
 552
 553                 case NOTIF_ANY_EXCEPT:
 554                 {
 555                         if(IS_NOT_A_CLIENT(client))
 556                                 { checkargs = sprintf("%sException can't be a non-client!", checkargs); }
 557                         break;
 558                 }
 559
 560                 case NOTIF_ANY:
 561                 {
 562                         if(client)
 563                                 { checkargs = sprintf("%sEntity provided when world was required!", checkargs); }
 564                         break;
 565                 }
 566
 567                 case NOTIF_TEAM:
 568                 case NOTIF_TEAM_EXCEPT:
 569                 {
 570                         if not(teamplay) { checkargs = sprintf("%sTeamplay not active!", checkargs); }
 571                         else if(IS_NOT_A_CLIENT(client))
 572                         {
 573                                 if(broadcast == NOTIF_TEAM) { checkargs = sprintf("%sNo client provided!", checkargs); }
 574                                 else { checkargs = sprintf("%sException can't be a non-client!", checkargs); }
 575                         }
 576                         break;
 577                 }
 578
 579                 default: { checkargs = sprintf("%sImproper broadcast: %d!", checkargs, broadcast); break; }
 580         }
 581         if(checkargs != "") { backtrace(sprintf("Incorrect usage of Send_Notification: %s\n", checkargs)); return; }
 582
 583         // retreive counts for the arguments of this notification
 584         entity notif = Get_Notif_Ent(net_type, net_name);
 585         if not(notif) { backtrace("Send_Notification: Could not find notification entity!\n"); return; }
 586
 587         if((notif.nent_stringcount + notif.nent_floatcount) > count)
 588         {
 589                 backtrace(sprintf(
 590                         strcat(
 591                                 "Not enough arguments for Send_Notification(%d, %d, %s, ...)! ",
 592                                 "stringcount(%d) + floatcount(%d) > count(%d)\n",
 593                                 "Check the definition and function call for accuracy...?\n"
 594                         ),
 595                         broadcast, net_type, notif.nent_name, notif.nent_stringcount, notif.nent_floatcount, count));
 596                 return;
 597         }
 598         else if((notif.nent_stringcount + notif.nent_floatcount) < count)
 599         {
 600                 backtrace(sprintf(
 601                         strcat(
 602                                 "Too many arguments for Send_Notification(%d, %d, %s, ...)! ",
 603                                 "stringcount(%d) + floatcount(%d) < count(%d)\n",
 604                                 "Check the definition and function call for accuracy...?\n"
 605                         ),
 606                         broadcast, net_type, notif.nent_name, notif.nent_stringcount, notif.nent_floatcount, count));
 607                 return;
 608         }
 609
 610         #ifdef NOTIFICATIONS_DEBUG
 611         dprint(
 612                 sprintf("Send_Notification(%d, %d, %s, stringcount: %d, floatcount: %d, varargs: %d);\n",
 613                         broadcast,
 614                         net_type,
 615                         notif.nent_name,
 616                         notif.nent_stringcount,
 617                         notif.nent_floatcount,
 618                         count
 619                 )
 620         );
 621         #endif
 622
 623         entity net_notif = spawn();
 624         net_notif.nent_broadcast = broadcast;
 625         net_notif.nent_client = client;
 626         net_notif.nent_net_type = net_type;
 627         net_notif.nent_net_name = net_name;
 628         net_notif.nent_stringcount = notif.nent_stringcount;
 629         net_notif.nent_floatcount = notif.nent_floatcount;
 630
 631         float i;
 632         for(i = 0; i < net_notif.nent_stringcount; ++i) { net_notif.nent_strings[i] = strzone(...(i, string)); }
 633         for(i = 0; i < net_notif.nent_floatcount; ++i) { net_notif.nent_floats[i] = ...((net_notif.nent_stringcount + i), float); }
 634
 635         net_notif.think = Net_Notification_Remove;
 636         net_notif.nextthink = (time + 0.5);
 637
 638         Net_LinkEntity(net_notif, FALSE, 0, Net_Write_Notification);
 639
 640         if((!server_is_local) && (broadcast == NOTIF_ANY || broadcast == NOTIF_ANY_EXCEPT) && (net_type != MSG_CENTER))
 641         {
 642                 Local_Notification_WOVA(
 643                         net_type, net_name,
 644                         notif.nent_stringcount,
 645                         notif.nent_floatcount,
 646                         IFSTR(0), IFSTR(1), IFSTR(2), IFSTR(3),
 647                         IFFL(0), IFFL(1), IFFL(2), IFFL(3));
 648         }
 649 }
 650
 651 // WOVA = Without Variable Arguments
 652 void Send_Notification_WOVA(float broadcast, entity client,
 653         float net_type, float net_name,
 654         string s1, string s2, string s3, string s4,
 655         float f1, float f2, float f3, float f4)
 656 {
 657         entity notif = Get_Notif_Ent(net_type, net_name);
 658         #define VARITEM(stringc,floatc,args) \
 659                 if((notif.nent_stringcount == stringc) && (notif.nent_floatcount == floatc)) \
 660                         { Send_Notification(broadcast, client, net_type, net_name, args); return; }
 661         EIGHT_VARS_TO_VARARGS_VARLIST
 662         #undef VARITEM
 663         Send_Notification(broadcast, client, net_type, net_name); // some notifications don't have any arguments at all
 664 }
 665
 666
 667 // =============================
 668 //  LEGACY NOTIFICATION SYSTEMS
 669 // =============================
 670
 671 void Send_CSQC_Centerprint_Generic(entity e, float id, string s, float duration, float countdown_num)
 672 {
 673         if ((clienttype(e) == CLIENTTYPE_REAL) && (e.flags & FL_CLIENT))
 674         {
 675                 msg_entity = e;
 676                 WRITESPECTATABLE_MSG_ONE({
 677                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 678                         WriteByte(MSG_ONE, TE_CSQC_CENTERPRINT_GENERIC);
 679                         WriteByte(MSG_ONE, id);
 680                         WriteString(MSG_ONE, s);
 681                         if (id != 0 && s != "")
 682                         {
 683                                 WriteByte(MSG_ONE, duration);
 684                                 WriteByte(MSG_ONE, countdown_num);
 685                         }
 686                 });
 687         }
 688 }
 689 #endif // ifdef SVQC