qcsrc/common/notifications.qc

   1 // ================================================
   2 //  Unified notification system, written by Samual
   3 //  Last updated: February, 2013
   4 // ================================================
   5
   6 #ifndef MENUQC
   7 string arg_slot[8];
   8 string Fill_Notif_Args(string args, string input,
   9         string s1, string s2, string s3, string s4,
  10         float f1, float f2, float f3, float f4)
  11 {
  12         dprint(sprintf("Fill_Notif_Args('%s', '%s', %s, %s, %s, %s, %d, %d, %d, %d);\n",
  13                 args, input, s1, s2, s3, s4, f1, f2, f3, f4));
  14
  15         string selected, remaining = args;
  16         float sel_num = 0;
  17
  18         #ifdef CSQC
  19         string tmp_s;
  20         #endif
  21
  22         if((remaining != "") && (input != ""))
  23         {
  24                 for(;remaining;)
  25                 {
  26                         selected = car(remaining); remaining = cdr(remaining);
  27
  28                         switch(strtolower(selected))
  29                         {
  30                                 #define ADD_ARG_CASE(selected,result) case selected: { arg_slot[sel_num] = result; ++sel_num; break; }
  31
  32                                 ADD_ARG_CASE("s1", s1)
  33                                 ADD_ARG_CASE("s2", s2)
  34                                 ADD_ARG_CASE("s3", s3)
  35                                 ADD_ARG_CASE("s4", s4)
  36                                 ADD_ARG_CASE("f1", ftos(f1))
  37                                 ADD_ARG_CASE("f2", ftos(f2))
  38                                 ADD_ARG_CASE("f3", ftos(f3))
  39                                 ADD_ARG_CASE("f4", ftos(f4))
  40
  41                                 #ifdef CSQC // CSQC replacements
  42                                 ADD_ARG_CASE("pass_key",                ((((tmp_s = getcommandkey("pass", "+use")) != "pass") && !(strstrofs(tmp_s, "not bound", 0) >= 0)) ? sprintf(CCR(_(" ^F1(Press %s)")), tmp_s) : ""))
  43                                 ADD_ARG_CASE("frag_ping",               ((f2 != BOT_PING) ? sprintf(CCR(_("\n(Ping ^2%d^BG)")), f2) : ""))
  44                                 ADD_ARG_CASE("frag_stats",              sprintf(CCR(_("\n(Health ^1%d^BG / Armor ^2%d^BG)%s")), f1, f2, ((f3 != BOT_PING) ? sprintf(CCR(_(" (Ping ^2%d^BG)")), f3) : "")))
  45                                 //ADD_ARG_CASE("frag_pos",              ((Should_Print_Score_Pos(f1)) ? sprintf("\n^BG%s", Read_Score_Pos(f1)) : ""))
  46                                 ADD_ARG_CASE("spree_cen",               (((f1 == 3) || (f1 == 5) || (f1 == 10) || (f1 == 15) || (f1 == 20) || (f1 == 25) || (f1 == 30)) ? sprintf(normal_or_gentle(_("%d frag spree! "), _("%d score spree! ")), f1) : ""))
  47                                 ADD_ARG_CASE("spree_inf",               (((f1 == 3) || (f1 == 5) || (f1 == 10) || (f1 == 15) || (f1 == 20) || (f1 == 25) || (f1 == 30)) ? sprintf(normal_or_gentle(_("%d frag spree! "), _("%d score spree! ")), f1) : ""))
  48                                 ADD_ARG_CASE("spree_end",               ((f1 >= 3) ? sprintf(normal_or_gentle(_(", ending their %d frag spree"), _(", ending their %d score spree")), f1) : ""))
  49                                 ADD_ARG_CASE("spree_lost",              ((f1 >= 3) ? sprintf(normal_or_gentle(_(", losing their %d frag spree"), _(", losing their %d score spree")), f1) : ""))
  50                                 ADD_ARG_CASE("death_team",              Team_ColoredFullName(f1 - 1))
  51                                 ADD_ARG_CASE("weapon_name",     ftos(f1)) // weaponorder[f1].netname
  52
  53                                 #else // SVQC replacements
  54                                 ADD_ARG_CASE("spree_inf",               (((f1 == 3) || (f1 == 5) || (f1 == 10) || (f1 == 15) || (f1 == 20) || (f1 == 25) || (f1 == 30)) ? sprintf(normal_or_gentle(_("%d frag spree! "), _("%d score spree! ")), f1) : ""))
  55                                 ADD_ARG_CASE("spree_end",               ((f1 >= 3) ? sprintf(normal_or_gentle(_(", ending their %d frag spree"), _(", ending their %d score spree")), f1) : ""))
  56                                 ADD_ARG_CASE("spree_lost",              ((f1 >= 3) ? sprintf(normal_or_gentle(_(", losing their %d frag spree"), _(", losing their %d score spree")), f1) : ""))
  57                                 ADD_ARG_CASE("death_team",              Team_ColoredFullName(f1))
  58                                 ADD_ARG_CASE("weapon_name",             ftos(f1)) // weaponorder[f1].netname
  59                                 #endif
  60
  61                                 #undef ADD_ARG_CASE
  62                                 default: { print("Hit unknown token in selected string! '", selected, "'\n"); break; }
  63                         }
  64                         if(sel_num == 7) { print("Hit maximum arguments!\n"); break; }
  65                 }
  66
  67                 return sprintf(input, arg_slot[0], arg_slot[1], arg_slot[2], arg_slot[3], arg_slot[4], arg_slot[5], arg_slot[6], arg_slot[7]);
  68         }
  69
  70         return "";
  71 }
  72
  73 entity Get_Notif_Ent(float net_type, float net_name)
  74 {
  75         switch(net_type)
  76         {
  77                 case MSG_INFO: return msg_info_notifs[net_name - 1];
  78                 case MSG_CENTER: return msg_center_notifs[net_name - 1];
  79                 case MSG_WEAPON: return msg_weapon_notifs[net_name - 1];
  80                 case MSG_DEATH: return msg_death_notifs[net_name - 1];
  81         }
  82         backtrace(sprintf("Get_Notif_Ent(%d, %d): Improper net type!\n", net_type, net_name));
  83         return world;
  84 }
  85
  86 string Get_Notif_Name(float net_type, float net_name)
  87 {
  88         entity e = Get_Notif_Ent(net_type, net_name);
  89         if(e) { return e.nent_name; }
  90         backtrace(sprintf("Get_Notif_Name(%d, %d): Could not find entity!\n", net_type, net_name));
  91         return "";
  92 }
  93
  94 float Get_Notif_Infval(float net_type, float net_name)
  95 {
  96         entity e = Get_Notif_Ent(net_type, net_name);
  97         if(e) { return e.nent_infoname; }
  98         backtrace(sprintf("Get_Notif_Infval(%d, %d): Could not find entity!\n", net_type, net_name));
  99         return NO_MSG;
 100 }
 101
 102 float Get_Notif_Cenval(float net_type, float net_name)
 103 {
 104         entity e = Get_Notif_Ent(net_type, net_name);
 105         if(e) { return e.nent_centername; }
 106         backtrace(sprintf("Get_Notif_Cenval(%d, %d): Could not find entity!\n", net_type, net_name));
 107         return NO_MSG;
 108 }
 109
 110 float Get_Notif_Strnum(float net_type, float net_name)
 111 {
 112         entity e = Get_Notif_Ent(net_type, net_name);
 113         if(e) { return e.nent_stringcount; }
 114         backtrace(sprintf("Get_Notif_Strnum(%d, %d): Could not find entity!\n", net_type, net_name));
 115         return NO_MSG;
 116 }
 117
 118 float Get_Notif_Flnum(float net_type, float net_name)
 119 {
 120         entity e = Get_Notif_Ent(net_type, net_name);
 121         if(e) { return e.nent_floatcount; }
 122         backtrace(sprintf("Get_Notif_Flnum(%d, %d): Could not find entity!\n", net_type, net_name));
 123         return NO_MSG;
 124 }
 125 #endif // ifndef MENUQC
 126
 127
 128 // ===============================
 129 //  Frontend Notification Pushing
 130 // ===============================
 131
 132 void Dump_Notifications(float fh, float alsoprint)
 133 {
 134         float MSG_INFO_NOTIFS = 0, MSG_CENTER_NOTIFS = 0, MSG_WEAPON_NOTIFS = 0, MSG_DEATH_NOTIFS = 0;
 135
 136         #define NOTIF_WRITE(type,name,text) { \
 137                 ++##type##_NOTIFS; \
 138                 notif_msg = sprintf("seta %s 1 // %s - %s\n", name, #type, strreplace("\n", "\\n", text)); \
 139                 fputs(fh, notif_msg); \
 140                 if(alsoprint) { print(strreplace("^", "^^", notif_msg)); } }
 141
 142         #ifndef MENUQC
 143         string notif_msg;
 144         float i;
 145         entity e;
 146
 147         for(i = 0; i < NOTIF_INFO_COUNT; ++i) { e = Get_Notif_Ent(MSG_INFO, i); NOTIF_WRITE(MSG_INFO, e.nent_name, e.nent_normal); }
 148         for(i = 0; i < NOTIF_CENTER_COUNT; ++i) { e = Get_Notif_Ent(MSG_CENTER, i); NOTIF_WRITE(MSG_CENTER, e.nent_name, e.nent_normal); }
 149
 150         for(i = 0; i < NOTIF_WEAPON_COUNT; ++i) { e = Get_Notif_Ent(MSG_WEAPON, i); NOTIF_WRITE(MSG_WEAPON, e.nent_name, sprintf("infoname: %s, centername: %s",
 151                 Get_Notif_Name(MSG_INFO, Get_Notif_Infval(MSG_WEAPON, i)),
 152                 Get_Notif_Name(MSG_CENTER, Get_Notif_Cenval(MSG_WEAPON, i)))); }
 153
 154         for(i = 0; i < NOTIF_DEATH_COUNT; ++i) { e = Get_Notif_Ent(MSG_DEATH, i); NOTIF_WRITE(MSG_DEATH, e.nent_name, sprintf("infoname: %s, centername: %s",
 155                 Get_Notif_Name(MSG_INFO, Get_Notif_Infval(MSG_DEATH, i)),
 156                 Get_Notif_Name(MSG_CENTER, Get_Notif_Cenval(MSG_DEATH, i)))); }
 157
 158         #endif
 159
 160         print(sprintf("Notification counts: MSG_INFO = %d, MSG_CENTER = %d, MSG_WEAPON = %d, MSG_DEATH = %d\n",
 161                 MSG_INFO_NOTIFS, MSG_CENTER_NOTIFS, MSG_WEAPON_NOTIFS, MSG_DEATH_NOTIFS));
 162
 163         return;
 164         #undef NOTIF_WRITE
 165 }
 166
 167 #ifndef MENUQC
 168 #ifdef CSQC
 169 void HUD_Notify_Push(string icon, string attacker, string victim)
 170 {
 171         if(icon != "")
 172         {
 173                 --kn_index;
 174                 if (kn_index == -1) { kn_index = KN_MAX_ENTRIES-1; }
 175                 killnotify_times[kn_index] = time;
 176
 177                 // icon
 178                 if(killnotify_icon[kn_index]) { strunzone(killnotify_icon[kn_index]); }
 179                 killnotify_icon[kn_index] = strzone(icon);
 180
 181                 // attacker
 182                 if(killnotify_attackers[kn_index]) { strunzone(killnotify_attackers[kn_index]); }
 183                 killnotify_attackers[kn_index] = strzone(attacker);
 184
 185                 // victim
 186                 if(killnotify_victims[kn_index]) { strunzone(killnotify_victims[kn_index]); }
 187                 killnotify_victims[kn_index] = strzone(victim);
 188         }
 189 }
 190 #endif // ifdef CSQC
 191
 192 void Local_Notification(float net_type, float net_name, ...count)
 193 {
 194         // check supplied type and name for errors
 195         #ifdef NOTIFICATIONS_DEBUG
 196         {
 197                 #define CHECKARG_TYPENAME(type) case MSG_##type##: \
 198                         { if(!net_name || (net_name > NOTIF_##type##_COUNT)) \
 199                         { checkargs = sprintf("Improper name: %d!", net_name); } break; }
 200
 201                 string checkargs = "";
 202                 switch(net_type)
 203                 {
 204                         CHECKARG_TYPENAME(INFO)
 205                         CHECKARG_TYPENAME(CENTER)
 206                         CHECKARG_TYPENAME(WEAPON)
 207                         CHECKARG_TYPENAME(DEATH)
 208
 209                         default: { checkargs = sprintf("Improper type: %d!", checkargs, net_type); break; }
 210                 }
 211                 #undef CHECKARG_TYPENAME
 212
 213                 if(checkargs != "") { backtrace(sprintf("Incorrect usage of Local_Notification: %s\n", checkargs)); return; }
 214         }
 215         #endif
 216
 217         float stringcount = Get_Notif_Strnum(net_type, net_name);
 218         float floatcount = Get_Notif_Flnum(net_type, net_name);
 219
 220         string s1 = ((0 < stringcount) ? ...(0, string) : NO_STR_ARG);
 221         string s2 = ((1 < stringcount) ? ...(1, string) : NO_STR_ARG);
 222         string s3 = ((2 < stringcount) ? ...(2, string) : NO_STR_ARG);
 223         string s4 = ((3 < stringcount) ? ...(3, string) : NO_STR_ARG);
 224         float f1 = ((stringcount < count) ? ...(stringcount, float) : NO_FL_ARG);
 225         float f2 = (((stringcount + 1) < count) ? ...((stringcount + 1), float) : NO_FL_ARG);
 226         float f3 = (((stringcount + 2) < count) ? ...((stringcount + 2), float) : NO_FL_ARG);
 227         float f4 = (((stringcount + 3) < count) ? ...((stringcount + 3), float) : NO_FL_ARG);
 228
 229         #ifdef NOTIFICATIONS_DEBUG
 230         {
 231                 dprint(sprintf("Local_Notification(%d, %s, %s, %s, %s, %s, %d, %d, %d, %d);\n",
 232                         net_type, Get_Notif_Name(net_type, net_name),
 233                         s1, s2, s3, s4, f1, f2, f3, f4));
 234
 235                 if((stringcount + floatcount) > count)
 236                         { backtrace(sprintf("Not enough arguments for Local_Notification! stringcount(%d) + floatcount(%d) > count(%d) \
 237                         \nCheck the notification definition and function call for accuracy...?\n", stringcount, floatcount, count)); return; }
 238                 else if((stringcount + floatcount) < count)
 239                         { backtrace(sprintf("Too many arguments for Local_Notification! stringcount(%d) + floatcount(%d) < count(%d) \
 240                         \nCheck the notification definition and function call for accuracy...?\n", stringcount, floatcount, count)); return; }
 241         }
 242         #endif
 243
 244
 245         switch(net_type)
 246         {
 247                 case MSG_INFO:
 248                 {
 249                         #define MSG_INFO_NOTIF(name,strnum,flnum,args,hudargs,icon,normal,gentle) \
 250                                 case name: { CHECK_AUTOCVAR(name) \
 251                                 { \
 252                                         print(sprintf(CCR(normal_or_gentle(normal, gentle)), args)); \
 253                                         #ifdef CSQC \
 254                                                 if(icon != "") { HUD_Notify_Push(icon, hudargs); } \
 255                                         #endif \
 256                                 } return; }
 257
 258                         NOTIF_SWITCH_LIST(MSG_INFO, net_name, return)
 259
 260                         #undef MSG_INFO_NOTIF
 261                         break;
 262                 }
 263                 #ifdef CSQC
 264                 case MSG_CENTER:
 265                 {
 266                         #define MSG_CENTER_NOTIF(name,strnum,flnum,args,cpid,durcnt,normal,gentle) \
 267                                 case name: { CHECK_AUTOCVAR(name) \
 268                                 { \
 269                                         centerprint_generic(HANDLE_CPID(cpid), sprintf(CCR(normal_or_gentle(normal, gentle)), args), durcnt); \
 270                                 } return; }
 271
 272                         NOTIF_SWITCH_LIST(MSG_CENTER, net_name, return)
 273
 274                         #undef MSG_CENTER_NOTIF
 275                         break;
 276                 }
 277                 #endif
 278                 case MSG_WEAPON:
 279                 {
 280                         #define MSG_WEAPON_NOTIF(name,infoname,centername) \
 281                                 case name: { CHECK_AUTOCVAR(name) \
 282                                 { \
 283                                         #if infoname != NO_MSG \
 284                                                 Local_Notification_Without_VarArgs(MSG_INFO, infoname, \
 285                                                         Get_Notif_Strnum(MSG_INFO, infoname), \
 286                                                         Get_Notif_Flnum(MSG_INFO, infoname), \
 287                                                         s1, s2, s3, s4, f1, f2, f3, f4); \
 288                                         #endif \
 289                                         #ifdef CSQC \
 290                                                 #if centername != NO_MSG \
 291                                                         Local_Notification_Without_VarArgs(MSG_CENTER, centername, \
 292                                                                 Get_Notif_Strnum(MSG_CENTER, centername), \
 293                                                                 Get_Notif_Flnum(MSG_CENTER, centername), \
 294                                                                 s1, s2, s3, s4, f1, f2, f3, f4); \
 295                                                 #endif \
 296                                         #endif \
 297                                 } return; }
 298
 299                         NOTIF_SWITCH_LIST(MSG_WEAPON, net_name, return)
 300
 301                         #undef MSG_WEAPON_NOTIF
 302                         break;
 303                 }
 304                 case MSG_DEATH:
 305                 {
 306                         #define MSG_DEATH_NOTIF(name,infoname,centername) \
 307                                 case name: { CHECK_AUTOCVAR(name) \
 308                                 { \
 309                                         #if infoname != NO_MSG \
 310                                                 Local_Notification_Without_VarArgs(MSG_INFO, infoname, \
 311                                                         Get_Notif_Strnum(MSG_INFO, infoname), \
 312                                                         Get_Notif_Flnum(MSG_INFO, infoname), \
 313                                                         s1, s2, s3, s4, f1, f2, f3, f4); \
 314                                         #endif \
 315                                         #ifdef CSQC \
 316                                                 #if centername != NO_MSG \
 317                                                         Local_Notification_Without_VarArgs(MSG_CENTER, centername, \
 318                                                                 Get_Notif_Strnum(MSG_CENTER, centername), \
 319                                                                 Get_Notif_Flnum(MSG_CENTER, centername), \
 320                                                                 s1, s2, s3, s4, f1, f2, f3, f4); \
 321                                                 #endif \
 322                                         #endif \
 323                                 } return; }
 324
 325                         NOTIF_SWITCH_LIST(MSG_DEATH, net_name, return)
 326
 327                         #undef MSG_DEATH_NOTIF
 328                         break;
 329                 }
 330         }
 331 }
 332
 333 void Local_Notification_Without_VarArgs(float net_type, float net_name,
 334         float stringcount, float floatcount,
 335         string s1, string s2, string s3, string s4,
 336         float f1, float f2, float f3, float f4)
 337 {
 338         #define VARITEM(stringc,floatc,args) if((stringcount == stringc) && (floatcount == floatc)) { Local_Notification(net_type, net_name, args); return; }
 339         EIGHT_VARS_TO_VARARGS_VARLIST
 340         #undef VARITEM
 341
 342         Local_Notification(net_type, net_name); // some notifications don't have any arguments at all
 343 }
 344
 345
 346 // =========================
 347 //  Notification Networking
 348 // =========================
 349
 350 #ifdef CSQC
 351 void Read_Notification(float is_new)
 352 {
 353         float net_type = ReadByte();
 354         float net_name = ReadShort();
 355
 356         float stringcount = Get_Notif_Strnum(net_type, net_name);
 357         float floatcount = Get_Notif_Flnum(net_type, net_name);
 358
 359         string s1 = ((stringcount >= 1) ? ReadString() : NO_STR_ARG);
 360         string s2 = ((stringcount >= 2) ? ReadString() : NO_STR_ARG);
 361         string s3 = ((stringcount >= 3) ? ReadString() : NO_STR_ARG);
 362         string s4 = ((stringcount == 4) ? ReadString() : NO_STR_ARG);
 363         float f1 = ((floatcount >= 1) ? ReadLong() : NO_FL_ARG);
 364         float f2 = ((floatcount >= 2) ? ReadLong() : NO_FL_ARG);
 365         float f3 = ((floatcount >= 3) ? ReadLong() : NO_FL_ARG);
 366         float f4 = ((floatcount == 4) ? ReadLong() : NO_FL_ARG);
 367
 368         #ifdef NOTIFICATIONS_DEBUG
 369                 dprint(sprintf("Read_Notification(%d) at %f: net_name = %s.\n", is_new, time, Get_Notif_Name(net_type, net_name)));
 370         #endif
 371
 372         if(is_new) { Local_Notification_Without_VarArgs(net_type, net_name, stringcount, floatcount, s1, s2, s3, s4, f1, f2, f3, f4); }
 373 }
 374 #endif
 375
 376 #ifdef SVQC
 377 void Notification_Remove()
 378 {
 379         float i;
 380         for(i = 0; i < 4; ++i) { if(self.nent_strings[i]) { strunzone(self.nent_strings[i]); } }
 381         remove(self);
 382 }
 383
 384 float Write_Notification(entity client, float sf)
 385 {
 386         float i, send = FALSE;
 387
 388         switch(self.nent_broadcast)
 389         {
 390                 case NOTIF_ONE: { if((client == self.nent_client) || (client.classname == STR_SPECTATOR && client.enemy == self.nent_client)) { send = TRUE; } break; }
 391                 case NOTIF_ONE_ONLY: { if(client == self.nent_client) { send = TRUE; } break; }
 392                 case NOTIF_TEAM: { if((client.team == self.nent_client.team) || (client.classname == STR_SPECTATOR && client.enemy.team == self.nent_client.team)) { send = TRUE; } break; }
 393                 case NOTIF_TEAM_EXCEPT: { if(((client != self.nent_client) && (client.team == self.nent_client.team) && !(client.classname == STR_SPECTATOR && client.enemy == self.nent_client))) { send = TRUE; } break; }
 394                 case NOTIF_ANY: { send = TRUE; break; }
 395                 case NOTIF_ANY_EXCEPT: { if((client != self.nent_client) && !(client.classname == STR_SPECTATOR && client.enemy == self.nent_client)) { send = TRUE; } break; }
 396                 default: { send = FALSE; break; }
 397         }
 398
 399         if(send)
 400         {
 401                 WriteByte(MSG_ENTITY, ENT_CLIENT_NOTIFICATION);
 402                 WriteByte(MSG_ENTITY, self.nent_net_type);
 403                 WriteShort(MSG_ENTITY, self.nent_net_name);
 404                 for(i = 0; i < self.nent_stringcount; ++i) { WriteString(MSG_ENTITY, self.nent_strings[i]); }
 405                 for(i = 0; i < self.nent_floatcount; ++i) { WriteLong(MSG_ENTITY, self.nent_floats[i]); }
 406         }
 407
 408         return send;
 409 }
 410
 411 void Send_Notification(float broadcast, entity client,
 412         float net_type, float net_name, ...count)
 413 {
 414         // check supplied broadcast, target, type, and name for errors
 415         #ifdef NOTIFICATIONS_DEBUG
 416         {
 417                 #define CHECKARG_TYPENAME(type) case MSG_##type##: \
 418                         { if(!net_name || (net_name > NOTIF_##type##_COUNT)) \
 419                         { checkargs = sprintf("Improper name: %d!", net_name); } break; }
 420
 421                 string checkargs = "";
 422                 switch(net_type)
 423                 {
 424                         CHECKARG_TYPENAME(INFO)
 425                         CHECKARG_TYPENAME(CENTER)
 426                         CHECKARG_TYPENAME(WEAPON)
 427                         CHECKARG_TYPENAME(DEATH)
 428
 429                         default: { checkargs = sprintf("Improper type: %d!", checkargs, net_type); break; }
 430                 }
 431                 #undef CHECKARG_TYPENAME
 432
 433                 if(checkargs != "") { checkargs = strcat(checkargs, " "); }
 434                 switch(broadcast)
 435                 {
 436                         case NOTIF_ONE:
 437                         case NOTIF_ONE_ONLY: { if(clienttype(client) == CLIENTTYPE_NOTACLIENT) { checkargs = sprintf("%sNo client provided!", checkargs); } break; }
 438                         case NOTIF_ANY_EXCEPT: { if(clienttype(client) == CLIENTTYPE_NOTACLIENT) { checkargs = sprintf("%sException can't be a non-client!", checkargs); } break; }
 439                         case NOTIF_ANY: { if(client) { checkargs = sprintf("%sEntity provided when world was required!", checkargs); } break; }
 440
 441                         case NOTIF_TEAM:
 442                         case NOTIF_TEAM_EXCEPT:
 443                         {
 444                                 if not(teamplay) { checkargs = sprintf("%sTeamplay not active!", checkargs); }
 445                                 else if(clienttype(client) == CLIENTTYPE_NOTACLIENT)
 446                                 {
 447                                         if(broadcast == NOTIF_TEAM) { checkargs = sprintf("%sNo client provided!", checkargs); }
 448                                         else { checkargs = sprintf("%sException can't be a non-client!", checkargs); }
 449                                 }
 450                                 break;
 451                         }
 452
 453                         default: { checkargs = sprintf("%sImproper broadcast: %d!", checkargs, broadcast); break; }
 454                 }
 455
 456                 if(checkargs != "") { backtrace(sprintf("Incorrect usage of Send_Notification: %s\n", checkargs)); return; }
 457         }
 458         #endif
 459
 460         // retreive counts for the arguments of this notification
 461         float stringcount = Get_Notif_Strnum(net_type, net_name);
 462         float floatcount = Get_Notif_Flnum(net_type, net_name);
 463
 464         #ifdef NOTIFICATIONS_DEBUG
 465         {
 466                 dprint(sprintf("Send_Notification(%d, %d, %s, stringcount: %d, floatcount: %d, varargs: %d);\n",
 467                         broadcast, net_type, Get_Notif_Name(net_type, net_name), stringcount, floatcount, count));
 468
 469                 if((stringcount + floatcount) > count)
 470                         { backtrace(sprintf(strcat("Not enough arguments for Send_Notification! stringcount(%d) + floatcount(%d) > count(%d)\n",
 471                         "Check the notification definition and function call for accuracy...?\n"), stringcount, floatcount, count)); return; }
 472                 else if((stringcount + floatcount) < count)
 473                         { backtrace(sprintf(strcat("Too many arguments for Send_Notification! stringcount(%d) + floatcount(%d) < count(%d)\n",
 474                         "Check the notification definition and function call for accuracy...?\n"), stringcount, floatcount, count)); return; }
 475         }
 476         #endif
 477
 478         entity notif = spawn();
 479         notif.nent_broadcast = broadcast;
 480         notif.nent_client = client;
 481         notif.nent_net_type = net_type;
 482         notif.nent_net_name = net_name;
 483         notif.nent_stringcount = stringcount;
 484         notif.nent_floatcount = floatcount;
 485
 486         float i;
 487
 488         for(i = 0; i < stringcount; ++i) { notif.nent_strings[i] = strzone(...(i, string)); }
 489         for(i = 0; i < floatcount; ++i) { notif.nent_floats[i] = ...((stringcount + i), float); }
 490
 491         notif.think = Notification_Remove;
 492         notif.nextthink = (time + 0.5);
 493
 494         Net_LinkEntity(notif, FALSE, 0, Write_Notification);
 495
 496         if((!server_is_local) && (broadcast == NOTIF_ANY || broadcast == NOTIF_ANY_EXCEPT) && (net_type != MSG_CENTER))
 497                 { Local_Notification_Without_VarArgs(net_type, net_name, stringcount, floatcount,
 498                         IFSTR(0), IFSTR(1), IFSTR(2), IFSTR(3), IFFL(0), IFFL(1), IFFL(2), IFFL(3)); }
 499 }
 500
 501 void Send_Notification_Without_VarArgs(float broadcast, entity client,
 502         float net_type, float net_name,
 503         float stringcount, float floatcount,
 504         string s1, string s2, string s3, string s4,
 505         float f1, float f2, float f3, float f4)
 506 {
 507         #define VARITEM(stringc,floatc,args) if((stringcount == stringc) && (floatcount == floatc)) { Send_Notification(broadcast, client, net_type, net_name, args); return; }
 508         EIGHT_VARS_TO_VARARGS_VARLIST
 509         #undef VARITEM
 510
 511         Send_Notification(broadcast, client, net_type, net_name); // some notifications don't have any arguments at all
 512 }
 513
 514 void Send_Notification_Legacy_Wrapper(float broadcast, entity client,
 515         float net_type, float net_name,
 516         string s1, string s2,
 517         float f1, float f2, float f3)
 518 {
 519         float stringcount = Get_Notif_Strnum(net_type, net_name);
 520         float floatcount = Get_Notif_Flnum(net_type, net_name);
 521         Send_Notification_Without_VarArgs(broadcast, client, net_type, net_name, stringcount, floatcount, s1, s2, NO_STR_ARG, NO_STR_ARG, f1, f2, f3, NO_FL_ARG);
 522 }
 523
 524
 525 // =============================
 526 //  LEGACY NOTIFICATION SYSTEMS
 527 // =============================
 528
 529 void Send_CSQC_Centerprint_Generic(entity e, float id, string s, float duration, float countdown_num)
 530 {
 531         if ((clienttype(e) == CLIENTTYPE_REAL) && (e.flags & FL_CLIENT))
 532         {
 533                 msg_entity = e;
 534                 WRITESPECTATABLE_MSG_ONE({
 535                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 536                         WriteByte(MSG_ONE, TE_CSQC_CENTERPRINT_GENERIC);
 537                         WriteByte(MSG_ONE, id);
 538                         WriteString(MSG_ONE, s);
 539                         if (id != 0 && s != "")
 540                         {
 541                                 WriteByte(MSG_ONE, duration);
 542                                 WriteByte(MSG_ONE, countdown_num);
 543                         }
 544                 });
 545         }
 546 }
 547 void Send_CSQC_Centerprint_Generic_Expire(entity e, float id)
 548 {
 549         Send_CSQC_Centerprint_Generic(e, id, "", 1, 0);
 550 }
 551 #endif // ifdef SVQC
 552 #endif // ifndef MENUQC